compiler/deSugar/DsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsExpr]{Matching expressions (Exprs)}
   5
   6 \begin{code}
   7 module DsExpr ( dsExpr, dsLExpr, dsLocalBinds, dsValBinds, dsLit ) where
   8
   9 #include "HsVersions.h"
  10 #if defined(GHCI) && defined(BREAKPOINT)
  11 import Foreign.StablePtr ( newStablePtr, castStablePtrToPtr )
  12 import GHC.Exts         ( Ptr(..), Int(..), addr2Int# )
  13 import IOEnv            ( ioToIOEnv )
  14 import PrelNames        ( breakpointJumpName, breakpointCondJumpName )
  15 import TysWiredIn       ( unitTy )
  16 import TypeRep          ( Type(..) )
  17 import TyCon            ( isUnLiftedTyCon )
  18 #endif
  19
  20 import Match            ( matchWrapper, matchSinglePat, matchEquations )
  21 import MatchLit         ( dsLit, dsOverLit )
  22 import DsBinds          ( dsLHsBinds, dsCoercion )
  23 import DsGRHSs          ( dsGuarded )
  24 import DsListComp       ( dsListComp, dsPArrComp )
  25 import DsUtils          ( mkErrorAppDs, mkStringExpr, mkConsExpr, mkNilExpr,
  26                           extractMatchResult, cantFailMatchResult, matchCanFail,
  27                           mkCoreTupTy, selectSimpleMatchVarL, lookupEvidence, selectMatchVar )
  28 import DsArrows         ( dsProcExpr )
  29 import DsMonad
  30
  31 #ifdef GHCI
  32         -- Template Haskell stuff iff bootstrapped
  33 import DsMeta           ( dsBracket )
  34 #endif
  35
  36 import HsSyn
  37 import TcHsSyn          ( hsPatType, mkVanillaTuplePat )
  38
  39 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  40 --     needs to see source types (newtypes etc), and sometimes not
  41 --     So WATCH OUT; check each use of split*Ty functions.
  42 -- Sigh.  This is a pain.
  43
  44 import TcType           ( tcSplitAppTy, tcSplitFunTys, tcTyConAppTyCon,
  45                           tcTyConAppArgs, isUnLiftedType, Type, mkAppTy )
  46 import Type             ( splitFunTys, isUnboxedTupleType, mkFunTy )
  47 import CoreSyn
  48 import CoreUtils        ( exprType, mkIfThenElse, bindNonRec )
  49
  50 import CostCentre       ( mkUserCC )
  51 import Id               ( Id, idType, idName, idDataCon )
  52 import PrelInfo         ( rEC_CON_ERROR_ID )
  53 import DataCon          ( DataCon, dataConWrapId, dataConFieldLabels, dataConInstOrigArgTys )
  54 import DataCon          ( isVanillaDataCon )
  55 import TyCon            ( FieldLabel, tyConDataCons )
  56 import TysWiredIn       ( tupleCon )
  57 import BasicTypes       ( RecFlag(..), Boxity(..), ipNameName )
  58 import PrelNames        ( toPName,
  59                           returnMName, bindMName, thenMName, failMName,
  60                           mfixName )
  61 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc )
  62 import Util             ( zipEqual, zipWithEqual )
  63 import Bag              ( bagToList )
  64 import Outputable
  65 import FastString
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71                 dsLocalBinds, dsValBinds
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 \begin{code}
  76 dsLocalBinds :: HsLocalBinds Id -> CoreExpr -> DsM CoreExpr
  77 dsLocalBinds EmptyLocalBinds    body = return body
  78 dsLocalBinds (HsValBinds binds) body = dsValBinds binds body
  79 dsLocalBinds (HsIPBinds binds)  body = dsIPBinds  binds body
  80
  81 -------------------------
  82 dsValBinds :: HsValBinds Id -> CoreExpr -> DsM CoreExpr
  83 dsValBinds (ValBindsOut binds _) body = foldrDs ds_val_bind body binds
  84
  85 -------------------------
  86 dsIPBinds (IPBinds ip_binds dict_binds) body
  87   = do  { prs <- dsLHsBinds dict_binds
  88         ; let inner = foldr (\(x,r) e -> Let (NonRec x r) e) body prs
  89         ; foldrDs ds_ip_bind inner ip_binds }
  90   where
  91     ds_ip_bind (L _ (IPBind n e)) body
  92       = dsLExpr e       `thenDs` \ e' ->
  93         returnDs (Let (NonRec (ipNameName n) e') body)
  94
  95 -------------------------
  96 ds_val_bind :: (RecFlag, LHsBinds Id) -> CoreExpr -> DsM CoreExpr
  97 -- Special case for bindings which bind unlifted variables
  98 -- We need to do a case right away, rather than building
  99 -- a tuple and doing selections.
 100 -- Silently ignore INLINE and SPECIALISE pragmas...
 101 ds_val_bind (NonRecursive, hsbinds) body
 102   | [L _ (AbsBinds [] [] exports binds)] <- bagToList hsbinds,
 103     (L loc bind : null_binds) <- bagToList binds,
 104     isBangHsBind bind
 105     || isUnboxedTupleBind bind
 106     || or [isUnLiftedType (idType g) | (_, g, _, _) <- exports]
 107   = let
 108       body_w_exports                  = foldr bind_export body exports
 109       bind_export (tvs, g, l, _) body = ASSERT( null tvs )
 110                                         bindNonRec g (Var l) body
 111     in
 112     ASSERT (null null_binds)
 113         -- Non-recursive, non-overloaded bindings only come in ones
 114         -- ToDo: in some bizarre case it's conceivable that there
 115         --       could be dict binds in the 'binds'.  (See the notes
 116         --       below.  Then pattern-match would fail.  Urk.)
 117     putSrcSpanDs loc    $
 118     case bind of
 119       FunBind { fun_id = L _ fun, fun_matches = matches, fun_co_fn = co_fn }
 120         -> matchWrapper (FunRhs (idName fun)) matches           `thenDs` \ (args, rhs) ->
 121            ASSERT( null args )  -- Functions aren't lifted
 122            ASSERT( isIdCoercion co_fn )
 123            returnDs (bindNonRec fun rhs body_w_exports)
 124
 125       PatBind {pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty }
 126         ->      -- let C x# y# = rhs in body
 127                 -- ==> case rhs of C x# y# -> body
 128            putSrcSpanDs loc                     $
 129            do { rhs <- dsGuarded grhss ty
 130               ; let upat = unLoc pat
 131                     eqn = EqnInfo { eqn_wrap = idWrapper, eqn_pats = [upat],
 132                                     eqn_rhs = cantFailMatchResult body_w_exports }
 133               ; var    <- selectMatchVar upat ty
 134               ; result <- matchEquations PatBindRhs [var] [eqn] (exprType body)
 135               ; return (scrungleMatch var rhs result) }
 136
 137       other -> pprPanic "dsLet: unlifted" (pprLHsBinds hsbinds $$ ppr body)
 138
 139
 140 -- Ordinary case for bindings; none should be unlifted
 141 ds_val_bind (is_rec, binds) body
 142   = do  { prs <- dsLHsBinds binds
 143         ; ASSERT( not (any (isUnLiftedType . idType . fst) prs) )
 144           case prs of
 145             []    -> return body
 146             other -> return (Let (Rec prs) body) }
 147         -- Use a Rec regardless of is_rec.
 148         -- Why? Because it allows the binds to be all
 149         -- mixed up, which is what happens in one rare case
 150         -- Namely, for an AbsBind with no tyvars and no dicts,
 151         --         but which does have dictionary bindings.
 152         -- See notes with TcSimplify.inferLoop [NO TYVARS]
 153         -- It turned out that wrapping a Rec here was the easiest solution
 154         --
 155         -- NB The previous case dealt with unlifted bindings, so we
 156         --    only have to deal with lifted ones now; so Rec is ok
 157
 158 isUnboxedTupleBind :: HsBind Id -> Bool
 159 isUnboxedTupleBind (PatBind { pat_rhs_ty = ty }) = isUnboxedTupleType ty
 160 isUnboxedTupleBind other                         = False
 161
 162 scrungleMatch :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 163 -- Returns something like (let var = scrut in body)
 164 -- but if var is an unboxed-tuple type, it inlines it in a fragile way
 165 -- Special case to handle unboxed tuple patterns; they can't appear nested
 166 -- The idea is that
 167 --      case e of (# p1, p2 #) -> rhs
 168 -- should desugar to
 169 --      case e of (# x1, x2 #) -> ... match p1, p2 ...
 170 -- NOT
 171 --      let x = e in case x of ....
 172 --
 173 -- But there may be a big
 174 --      let fail = ... in case e of ...
 175 -- wrapping the whole case, which complicates matters slightly
 176 -- It all seems a bit fragile.  Test is dsrun013.
 177
 178 scrungleMatch var scrut body
 179   | isUnboxedTupleType (idType var) = scrungle body
 180   | otherwise                       = bindNonRec var scrut body
 181   where
 182     scrungle (Case (Var x) bndr ty alts)
 183                     | x == var = Case scrut bndr ty alts
 184     scrungle (Let binds body)  = Let binds (scrungle body)
 185     scrungle other = panic ("scrungleMatch: tuple pattern:\n" ++ showSDoc (ppr other))
 186 \end{code}
 187
 188 %************************************************************************
 189 %*                                                                      *
 190 \subsection[DsExpr-vars-and-cons]{Variables, constructors, literals}
 191 %*                                                                      *
 192 %************************************************************************
 193
 194 \begin{code}
 195 dsLExpr :: LHsExpr Id -> DsM CoreExpr
 196 dsLExpr (L loc e) = putSrcSpanDs loc $ dsExpr e
 197
 198 dsExpr :: HsExpr Id -> DsM CoreExpr
 199
 200 dsExpr (HsPar e)              = dsLExpr e
 201 dsExpr (ExprWithTySigOut e _) = dsLExpr e
 202 dsExpr (HsVar var)            = returnDs (Var var)
 203 dsExpr (HsIPVar ip)           = returnDs (Var (ipNameName ip))
 204 dsExpr (HsLit lit)            = dsLit lit
 205 dsExpr (HsOverLit lit)        = dsOverLit lit
 206
 207 dsExpr (NegApp expr neg_expr)
 208   = do  { core_expr <- dsLExpr expr
 209         ; core_neg  <- dsExpr neg_expr
 210         ; return (core_neg `App` core_expr) }
 211
 212 dsExpr expr@(HsLam a_Match)
 213   = matchWrapper LambdaExpr a_Match     `thenDs` \ (binders, matching_code) ->
 214     returnDs (mkLams binders matching_code)
 215
 216 #if defined(GHCI) && defined(BREAKPOINT)
 217 dsExpr (HsApp (L _ (HsApp realFun@(L _ (HsCoerce _ fun)) (L loc arg))) _)
 218     | HsVar funId <- fun
 219     , idName funId `elem` [breakpointJumpName, breakpointCondJumpName]
 220     , ids <- filter (isValidType . idType) (extractIds arg)
 221     = do dsWarn (text "Extracted ids:" <+> ppr ids <+> ppr (map idType ids))
 222          stablePtr <- ioToIOEnv $ newStablePtr ids
 223          -- Yes, I know... I'm gonna burn in hell.
 224          let Ptr addr# = castStablePtrToPtr stablePtr
 225          funCore <- dsLExpr realFun
 226          argCore <- dsLExpr (L loc (HsLit (HsInt (fromIntegral (I# (addr2Int# addr#))))))
 227          hvalCore <- dsLExpr (L loc (extractHVals ids))
 228          return ((funCore `App` argCore) `App` hvalCore)
 229     where extractIds :: HsExpr Id -> [Id]
 230           extractIds (HsApp fn arg)
 231               | HsVar argId <- unLoc arg
 232               = argId:extractIds (unLoc fn)
 233               | TyApp arg' ts <- unLoc arg
 234               , HsVar argId <- unLoc arg'
 235               = error (showSDoc (ppr ts)) -- argId:extractIds (unLoc fn)
 236           extractIds x = []
 237           extractHVals ids = ExplicitList unitTy (map (L loc . HsVar) ids)
 238           -- checks for tyvars and unlifted kinds.
 239           isValidType (TyVarTy _) = False
 240           isValidType (FunTy a b) = isValidType a && isValidType b
 241           isValidType (NoteTy _ t) = isValidType t
 242           isValidType (AppTy a b) = isValidType a && isValidType b
 243           isValidType (TyConApp con ts) = not (isUnLiftedTyCon con) && all isValidType ts
 244           isValidType _ = True
 245 #endif
 246
 247 dsExpr expr@(HsApp fun arg)
 248   = dsLExpr fun         `thenDs` \ core_fun ->
 249     dsLExpr arg         `thenDs` \ core_arg ->
 250     returnDs (core_fun `App` core_arg)
 251 \end{code}
 252
 253 Operator sections.  At first it looks as if we can convert
 254 \begin{verbatim}
 255         (expr op)
 256 \end{verbatim}
 257 to
 258 \begin{verbatim}
 259         \x -> op expr x
 260 \end{verbatim}
 261
 262 But no!  expr might be a redex, and we can lose laziness badly this
 263 way.  Consider
 264 \begin{verbatim}
 265         map (expr op) xs
 266 \end{verbatim}
 267 for example.  So we convert instead to
 268 \begin{verbatim}
 269         let y = expr in \x -> op y x
 270 \end{verbatim}
 271 If \tr{expr} is actually just a variable, say, then the simplifier
 272 will sort it out.
 273
 274 \begin{code}
 275 dsExpr (OpApp e1 op _ e2)
 276   = dsLExpr op                                          `thenDs` \ core_op ->
 277     -- for the type of y, we need the type of op's 2nd argument
 278     dsLExpr e1                          `thenDs` \ x_core ->
 279     dsLExpr e2                          `thenDs` \ y_core ->
 280     returnDs (mkApps core_op [x_core, y_core])
 281
 282 dsExpr (SectionL expr op)
 283   = dsLExpr op                                          `thenDs` \ core_op ->
 284     -- for the type of y, we need the type of op's 2nd argument
 285     let
 286         (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 287         -- Must look through an implicit-parameter type;
 288         -- newtype impossible; hence Type.splitFunTys
 289     in
 290     dsLExpr expr                                `thenDs` \ x_core ->
 291     newSysLocalDs x_ty                  `thenDs` \ x_id ->
 292     newSysLocalDs y_ty                  `thenDs` \ y_id ->
 293
 294     returnDs (bindNonRec x_id x_core $
 295               Lam y_id (mkApps core_op [Var x_id, Var y_id]))
 296
 297 -- dsLExpr (SectionR op expr)   -- \ x -> op x expr
 298 dsExpr (SectionR op expr)
 299   = dsLExpr op                  `thenDs` \ core_op ->
 300     -- for the type of x, we need the type of op's 2nd argument
 301     let
 302         (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 303         -- See comment with SectionL
 304     in
 305     dsLExpr expr                                `thenDs` \ y_core ->
 306     newSysLocalDs x_ty                  `thenDs` \ x_id ->
 307     newSysLocalDs y_ty                  `thenDs` \ y_id ->
 308
 309     returnDs (bindNonRec y_id y_core $
 310               Lam x_id (mkApps core_op [Var x_id, Var y_id]))
 311
 312 dsExpr (HsSCC cc expr)
 313   = dsLExpr expr                        `thenDs` \ core_expr ->
 314     getModuleDs                 `thenDs` \ mod_name ->
 315     returnDs (Note (SCC (mkUserCC cc mod_name)) core_expr)
 316
 317
 318 -- hdaume: core annotation
 319
 320 dsExpr (HsCoreAnn fs expr)
 321   = dsLExpr expr        `thenDs` \ core_expr ->
 322     returnDs (Note (CoreNote $ unpackFS fs) core_expr)
 323
 324 dsExpr (HsCase discrim matches)
 325   = dsLExpr discrim                     `thenDs` \ core_discrim ->
 326     matchWrapper CaseAlt matches        `thenDs` \ ([discrim_var], matching_code) ->
 327     returnDs (scrungleMatch discrim_var core_discrim matching_code)
 328
 329 dsExpr (HsLet binds body)
 330   = dsLExpr body                `thenDs` \ body' ->
 331     dsLocalBinds binds body'
 332
 333 -- We need the `ListComp' form to use `deListComp' (rather than the "do" form)
 334 -- because the interpretation of `stmts' depends on what sort of thing it is.
 335 --
 336 dsExpr (HsDo ListComp stmts body result_ty)
 337   =     -- Special case for list comprehensions
 338     dsListComp stmts body elt_ty
 339   where
 340     [elt_ty] = tcTyConAppArgs result_ty
 341
 342 dsExpr (HsDo DoExpr stmts body result_ty)
 343   = dsDo stmts body result_ty
 344
 345 dsExpr (HsDo (MDoExpr tbl) stmts body result_ty)
 346   = dsMDo tbl stmts body result_ty
 347
 348 dsExpr (HsDo PArrComp stmts body result_ty)
 349   =     -- Special case for array comprehensions
 350     dsPArrComp (map unLoc stmts) body elt_ty
 351   where
 352     [elt_ty] = tcTyConAppArgs result_ty
 353
 354 dsExpr (HsIf guard_expr then_expr else_expr)
 355   = dsLExpr guard_expr  `thenDs` \ core_guard ->
 356     dsLExpr then_expr   `thenDs` \ core_then ->
 357     dsLExpr else_expr   `thenDs` \ core_else ->
 358     returnDs (mkIfThenElse core_guard core_then core_else)
 359 \end{code}
 360
 361
 362 \noindent
 363 \underline{\bf Type lambda and application}
 364 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 365 \begin{code}
 366 dsExpr (TyLam tyvars expr)
 367   = dsLExpr expr `thenDs` \ core_expr ->
 368     returnDs (mkLams tyvars core_expr)
 369
 370 dsExpr (TyApp expr tys)
 371   = dsLExpr expr                `thenDs` \ core_expr ->
 372     returnDs (mkTyApps core_expr tys)
 373 \end{code}
 374
 375
 376 \noindent
 377 \underline{\bf Various data construction things}
 378 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 379 \begin{code}
 380 dsExpr (ExplicitList ty xs)
 381   = go xs
 382   where
 383     go []     = returnDs (mkNilExpr ty)
 384     go (x:xs) = dsLExpr x                               `thenDs` \ core_x ->
 385                 go xs                                   `thenDs` \ core_xs ->
 386                 returnDs (mkConsExpr ty core_x core_xs)
 387
 388 -- we create a list from the array elements and convert them into a list using
 389 -- `PrelPArr.toP'
 390 --
 391 --  * the main disadvantage to this scheme is that `toP' traverses the list
 392 --   twice: once to determine the length and a second time to put to elements
 393 --   into the array; this inefficiency could be avoided by exposing some of
 394 --   the innards of `PrelPArr' to the compiler (ie, have a `PrelPArrBase') so
 395 --   that we can exploit the fact that we already know the length of the array
 396 --   here at compile time
 397 --
 398 dsExpr (ExplicitPArr ty xs)
 399   = dsLookupGlobalId toPName                            `thenDs` \toP      ->
 400     dsExpr (ExplicitList ty xs)                         `thenDs` \coreList ->
 401     returnDs (mkApps (Var toP) [Type ty, coreList])
 402
 403 dsExpr (ExplicitTuple expr_list boxity)
 404   = mappM dsLExpr expr_list       `thenDs` \ core_exprs  ->
 405     returnDs (mkConApp (tupleCon boxity (length expr_list))
 406                        (map (Type .  exprType) core_exprs ++ core_exprs))
 407
 408 dsExpr (ArithSeq expr (From from))
 409   = dsExpr expr           `thenDs` \ expr2 ->
 410     dsLExpr from          `thenDs` \ from2 ->
 411     returnDs (App expr2 from2)
 412
 413 dsExpr (ArithSeq expr (FromTo from two))
 414   = dsExpr expr           `thenDs` \ expr2 ->
 415     dsLExpr from          `thenDs` \ from2 ->
 416     dsLExpr two           `thenDs` \ two2 ->
 417     returnDs (mkApps expr2 [from2, two2])
 418
 419 dsExpr (ArithSeq expr (FromThen from thn))
 420   = dsExpr expr           `thenDs` \ expr2 ->
 421     dsLExpr from          `thenDs` \ from2 ->
 422     dsLExpr thn           `thenDs` \ thn2 ->
 423     returnDs (mkApps expr2 [from2, thn2])
 424
 425 dsExpr (ArithSeq expr (FromThenTo from thn two))
 426   = dsExpr expr           `thenDs` \ expr2 ->
 427     dsLExpr from          `thenDs` \ from2 ->
 428     dsLExpr thn           `thenDs` \ thn2 ->
 429     dsLExpr two           `thenDs` \ two2 ->
 430     returnDs (mkApps expr2 [from2, thn2, two2])
 431
 432 dsExpr (PArrSeq expr (FromTo from two))
 433   = dsExpr expr           `thenDs` \ expr2 ->
 434     dsLExpr from          `thenDs` \ from2 ->
 435     dsLExpr two           `thenDs` \ two2 ->
 436     returnDs (mkApps expr2 [from2, two2])
 437
 438 dsExpr (PArrSeq expr (FromThenTo from thn two))
 439   = dsExpr expr           `thenDs` \ expr2 ->
 440     dsLExpr from          `thenDs` \ from2 ->
 441     dsLExpr thn           `thenDs` \ thn2 ->
 442     dsLExpr two           `thenDs` \ two2 ->
 443     returnDs (mkApps expr2 [from2, thn2, two2])
 444
 445 dsExpr (PArrSeq expr _)
 446   = panic "DsExpr.dsExpr: Infinite parallel array!"
 447     -- the parser shouldn't have generated it and the renamer and typechecker
 448     -- shouldn't have let it through
 449 \end{code}
 450
 451 \noindent
 452 \underline{\bf Record construction and update}
 453 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 454 For record construction we do this (assuming T has three arguments)
 455 \begin{verbatim}
 456         T { op2 = e }
 457 ==>
 458         let err = /\a -> recConErr a
 459         T (recConErr t1 "M.lhs/230/op1")
 460           e
 461           (recConErr t1 "M.lhs/230/op3")
 462 \end{verbatim}
 463 @recConErr@ then converts its arugment string into a proper message
 464 before printing it as
 465 \begin{verbatim}
 466         M.lhs, line 230: missing field op1 was evaluated
 467 \end{verbatim}
 468
 469 We also handle @C{}@ as valid construction syntax for an unlabelled
 470 constructor @C@, setting all of @C@'s fields to bottom.
 471
 472 \begin{code}
 473 dsExpr (RecordCon (L _ data_con_id) con_expr rbinds)
 474   = dsExpr con_expr     `thenDs` \ con_expr' ->
 475     let
 476         (arg_tys, _) = tcSplitFunTys (exprType con_expr')
 477         -- A newtype in the corner should be opaque;
 478         -- hence TcType.tcSplitFunTys
 479
 480         mk_arg (arg_ty, lbl)    -- Selector id has the field label as its name
 481           = case [rhs | (L _ sel_id, rhs) <- rbinds, lbl == idName sel_id] of
 482               (rhs:rhss) -> ASSERT( null rhss )
 483                             dsLExpr rhs
 484               []         -> mkErrorAppDs rEC_CON_ERROR_ID arg_ty (showSDoc (ppr lbl))
 485         unlabelled_bottom arg_ty = mkErrorAppDs rEC_CON_ERROR_ID arg_ty ""
 486
 487         labels = dataConFieldLabels (idDataCon data_con_id)
 488         -- The data_con_id is guaranteed to be the wrapper id of the constructor
 489     in
 490
 491     (if null labels
 492         then mappM unlabelled_bottom arg_tys
 493         else mappM mk_arg (zipEqual "dsExpr:RecordCon" arg_tys labels))
 494         `thenDs` \ con_args ->
 495
 496     returnDs (mkApps con_expr' con_args)
 497 \end{code}
 498
 499 Record update is a little harder. Suppose we have the decl:
 500 \begin{verbatim}
 501         data T = T1 {op1, op2, op3 :: Int}
 502                | T2 {op4, op2 :: Int}
 503                | T3
 504 \end{verbatim}
 505 Then we translate as follows:
 506 \begin{verbatim}
 507         r { op2 = e }
 508 ===>
 509         let op2 = e in
 510         case r of
 511           T1 op1 _ op3 -> T1 op1 op2 op3
 512           T2 op4 _     -> T2 op4 op2
 513           other        -> recUpdError "M.lhs/230"
 514 \end{verbatim}
 515 It's important that we use the constructor Ids for @T1@, @T2@ etc on the
 516 RHSs, and do not generate a Core constructor application directly, because the constructor
 517 might do some argument-evaluation first; and may have to throw away some
 518 dictionaries.
 519
 520 \begin{code}
 521 dsExpr (RecordUpd record_expr [] record_in_ty record_out_ty)
 522   = dsLExpr record_expr
 523
 524 dsExpr expr@(RecordUpd record_expr rbinds record_in_ty record_out_ty)
 525   = dsLExpr record_expr         `thenDs` \ record_expr' ->
 526
 527         -- Desugar the rbinds, and generate let-bindings if
 528         -- necessary so that we don't lose sharing
 529
 530     let
 531         in_inst_tys  = tcTyConAppArgs record_in_ty      -- Newtype opaque
 532         out_inst_tys = tcTyConAppArgs record_out_ty     -- Newtype opaque
 533         in_out_ty    = mkFunTy record_in_ty record_out_ty
 534
 535         mk_val_arg field old_arg_id
 536           = case [rhs | (L _ sel_id, rhs) <- rbinds, field == idName sel_id] of
 537               (rhs:rest) -> ASSERT(null rest) rhs
 538               []         -> nlHsVar old_arg_id
 539
 540         mk_alt con
 541           = newSysLocalsDs (dataConInstOrigArgTys con in_inst_tys) `thenDs` \ arg_ids ->
 542                 -- This call to dataConInstOrigArgTys won't work for existentials
 543                 -- but existentials don't have record types anyway
 544             let
 545                 val_args = zipWithEqual "dsExpr:RecordUpd" mk_val_arg
 546                                         (dataConFieldLabels con) arg_ids
 547                 rhs = foldl (\a b -> nlHsApp a b)
 548                         (noLoc $ TyApp (nlHsVar (dataConWrapId con))
 549                                 out_inst_tys)
 550                           val_args
 551             in
 552             returnDs (mkSimpleMatch [noLoc $ ConPatOut (noLoc con) [] [] emptyLHsBinds
 553                                                        (PrefixCon (map nlVarPat arg_ids)) record_in_ty]
 554                                     rhs)
 555     in
 556         -- Record stuff doesn't work for existentials
 557         -- The type checker checks for this, but we need
 558         -- worry only about the constructors that are to be updated
 559     ASSERT2( all isVanillaDataCon cons_to_upd, ppr expr )
 560
 561         -- It's important to generate the match with matchWrapper,
 562         -- and the right hand sides with applications of the wrapper Id
 563         -- so that everything works when we are doing fancy unboxing on the
 564         -- constructor aguments.
 565     mappM mk_alt cons_to_upd                            `thenDs` \ alts ->
 566     matchWrapper RecUpd (MatchGroup alts in_out_ty)     `thenDs` \ ([discrim_var], matching_code) ->
 567
 568     returnDs (bindNonRec discrim_var record_expr' matching_code)
 569
 570   where
 571     updated_fields :: [FieldLabel]
 572     updated_fields = [ idName sel_id | (L _ sel_id,_) <- rbinds]
 573
 574         -- Get the type constructor from the record_in_ty
 575         -- so that we are sure it'll have all its DataCons
 576         -- (In GHCI, it's possible that some TyCons may not have all
 577         --  their constructors, in a module-loop situation.)
 578     tycon       = tcTyConAppTyCon record_in_ty
 579     data_cons   = tyConDataCons tycon
 580     cons_to_upd = filter has_all_fields data_cons
 581
 582     has_all_fields :: DataCon -> Bool
 583     has_all_fields con_id
 584       = all (`elem` con_fields) updated_fields
 585       where
 586         con_fields = dataConFieldLabels con_id
 587 \end{code}
 588
 589
 590 \noindent
 591 \underline{\bf Dictionary lambda and application}
 592 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 593 @DictLam@ and @DictApp@ turn into the regular old things.
 594 (OLD:) @DictFunApp@ also becomes a curried application, albeit slightly more
 595 complicated; reminiscent of fully-applied constructors.
 596 \begin{code}
 597 dsExpr (DictLam dictvars expr)
 598   = dsLExpr expr `thenDs` \ core_expr ->
 599     returnDs (mkLams dictvars core_expr)
 600
 601 ------------------
 602
 603 dsExpr (DictApp expr dicts)     -- becomes a curried application
 604   = dsLExpr expr                        `thenDs` \ core_expr ->
 605     returnDs (foldl (\f d -> f `App` (Var d)) core_expr dicts)
 606
 607 dsExpr (HsCoerce co_fn e) = dsCoercion co_fn (dsExpr e)
 608 \end{code}
 609
 610 Here is where we desugar the Template Haskell brackets and escapes
 611
 612 \begin{code}
 613 -- Template Haskell stuff
 614
 615 #ifdef GHCI     /* Only if bootstrapping */
 616 dsExpr (HsBracketOut x ps) = dsBracket x ps
 617 dsExpr (HsSpliceE s)       = pprPanic "dsExpr:splice" (ppr s)
 618 #endif
 619
 620 -- Arrow notation extension
 621 dsExpr (HsProc pat cmd) = dsProcExpr pat cmd
 622 \end{code}
 623
 624
 625 \begin{code}
 626
 627 #ifdef DEBUG
 628 -- HsSyn constructs that just shouldn't be here:
 629 dsExpr (ExprWithTySig _ _)  = panic "dsExpr:ExprWithTySig"
 630 #endif
 631
 632 \end{code}
 633
 634 %--------------------------------------------------------------------
 635
 636 Desugar 'do' and 'mdo' expressions (NOT list comprehensions, they're
 637 handled in DsListComp).  Basically does the translation given in the
 638 Haskell 98 report:
 639
 640 \begin{code}
 641 dsDo    :: [LStmt Id]
 642         -> LHsExpr Id
 643         -> Type                 -- Type of the whole expression
 644         -> DsM CoreExpr
 645
 646 dsDo stmts body result_ty
 647   = go (map unLoc stmts)
 648   where
 649     go [] = dsLExpr body
 650
 651     go (ExprStmt rhs then_expr _ : stmts)
 652       = do { rhs2 <- dsLExpr rhs
 653            ; then_expr2 <- dsExpr then_expr
 654            ; rest <- go stmts
 655            ; returnDs (mkApps then_expr2 [rhs2, rest]) }
 656
 657     go (LetStmt binds : stmts)
 658       = do { rest <- go stmts
 659            ; dsLocalBinds binds rest }
 660
 661     go (BindStmt pat rhs bind_op fail_op : stmts)
 662       = do { body  <- go stmts
 663            ; var   <- selectSimpleMatchVarL pat
 664            ; match <- matchSinglePat (Var var) (StmtCtxt DoExpr) pat
 665                                   result_ty (cantFailMatchResult body)
 666            ; match_code <- handle_failure pat match fail_op
 667            ; rhs'       <- dsLExpr rhs
 668            ; bind_op'   <- dsExpr bind_op
 669            ; returnDs (mkApps bind_op' [rhs', Lam var match_code]) }
 670
 671     -- In a do expression, pattern-match failure just calls
 672     -- the monadic 'fail' rather than throwing an exception
 673     handle_failure pat match fail_op
 674       | matchCanFail match
 675       = do { fail_op' <- dsExpr fail_op
 676            ; fail_msg <- mkStringExpr (mk_fail_msg pat)
 677            ; extractMatchResult match (App fail_op' fail_msg) }
 678       | otherwise
 679       = extractMatchResult match (error "It can't fail")
 680
 681 mk_fail_msg pat = "Pattern match failure in do expression at " ++
 682                   showSDoc (ppr (getLoc pat))
 683 \end{code}
 684
 685 Translation for RecStmt's:
 686 -----------------------------
 687 We turn (RecStmt [v1,..vn] stmts) into:
 688
 689   (v1,..,vn) <- mfix (\~(v1,..vn). do stmts
 690                                       return (v1,..vn))
 691
 692 \begin{code}
 693 dsMDo   :: PostTcTable
 694         -> [LStmt Id]
 695         -> LHsExpr Id
 696         -> Type                 -- Type of the whole expression
 697         -> DsM CoreExpr
 698
 699 dsMDo tbl stmts body result_ty
 700   = go (map unLoc stmts)
 701   where
 702     (m_ty, b_ty) = tcSplitAppTy result_ty       -- result_ty must be of the form (m b)
 703     mfix_id   = lookupEvidence tbl mfixName
 704     return_id = lookupEvidence tbl returnMName
 705     bind_id   = lookupEvidence tbl bindMName
 706     then_id   = lookupEvidence tbl thenMName
 707     fail_id   = lookupEvidence tbl failMName
 708     ctxt      = MDoExpr tbl
 709
 710     go [] = dsLExpr body
 711
 712     go (LetStmt binds : stmts)
 713       = do { rest <- go stmts
 714            ; dsLocalBinds binds rest }
 715
 716     go (ExprStmt rhs _ rhs_ty : stmts)
 717       = do { rhs2 <- dsLExpr rhs
 718            ; rest <- go stmts
 719            ; returnDs (mkApps (Var then_id) [Type rhs_ty, Type b_ty, rhs2, rest]) }
 720
 721     go (BindStmt pat rhs _ _ : stmts)
 722       = do { body  <- go stmts
 723            ; var   <- selectSimpleMatchVarL pat
 724            ; match <- matchSinglePat (Var var) (StmtCtxt ctxt) pat
 725                                   result_ty (cantFailMatchResult body)
 726            ; fail_msg   <- mkStringExpr (mk_fail_msg pat)
 727            ; let fail_expr = mkApps (Var fail_id) [Type b_ty, fail_msg]
 728            ; match_code <- extractMatchResult match fail_expr
 729
 730            ; rhs'       <- dsLExpr rhs
 731            ; returnDs (mkApps (Var bind_id) [Type (hsPatType pat), Type b_ty,
 732                                              rhs', Lam var match_code]) }
 733
 734     go (RecStmt rec_stmts later_ids rec_ids rec_rets binds : stmts)
 735       = ASSERT( length rec_ids > 0 )
 736         ASSERT( length rec_ids == length rec_rets )
 737         go (new_bind_stmt : let_stmt : stmts)
 738       where
 739         new_bind_stmt = mkBindStmt (mk_tup_pat later_pats) mfix_app
 740         let_stmt = LetStmt (HsValBinds (ValBindsOut [(Recursive, binds)] []))
 741
 742
 743                 -- Remove the later_ids that appear (without fancy coercions)
 744                 -- in rec_rets, because there's no need to knot-tie them separately
 745                 -- See Note [RecStmt] in HsExpr
 746         later_ids'   = filter (`notElem` mono_rec_ids) later_ids
 747         mono_rec_ids = [ id | HsVar id <- rec_rets ]
 748
 749         mfix_app = nlHsApp (noLoc $ TyApp (nlHsVar mfix_id) [tup_ty]) mfix_arg
 750         mfix_arg = noLoc $ HsLam (MatchGroup [mkSimpleMatch [mfix_pat] body]
 751                                              (mkFunTy tup_ty body_ty))
 752
 753         -- The rec_tup_pat must bind the rec_ids only; remember that the
 754         --      trimmed_laters may share the same Names
 755         -- Meanwhile, the later_pats must bind the later_vars
 756         rec_tup_pats = map mk_wild_pat later_ids' ++ map nlVarPat rec_ids
 757         later_pats   = map nlVarPat    later_ids' ++ map mk_later_pat rec_ids
 758         rets         = map nlHsVar     later_ids' ++ map noLoc rec_rets
 759
 760         mfix_pat = noLoc $ LazyPat $ mk_tup_pat rec_tup_pats
 761         body     = noLoc $ HsDo ctxt rec_stmts return_app body_ty
 762         body_ty = mkAppTy m_ty tup_ty
 763         tup_ty  = mkCoreTupTy (map idType (later_ids' ++ rec_ids))
 764                   -- mkCoreTupTy deals with singleton case
 765
 766         return_app  = nlHsApp (noLoc $ TyApp (nlHsVar return_id) [tup_ty])
 767                               (mk_ret_tup rets)
 768
 769         mk_wild_pat :: Id -> LPat Id
 770         mk_wild_pat v = noLoc $ WildPat $ idType v
 771
 772         mk_later_pat :: Id -> LPat Id
 773         mk_later_pat v | v `elem` later_ids' = mk_wild_pat v
 774                        | otherwise           = nlVarPat v
 775
 776         mk_tup_pat :: [LPat Id] -> LPat Id
 777         mk_tup_pat [p] = p
 778         mk_tup_pat ps  = noLoc $ mkVanillaTuplePat ps Boxed
 779
 780         mk_ret_tup :: [LHsExpr Id] -> LHsExpr Id
 781         mk_ret_tup [r] = r
 782         mk_ret_tup rs  = noLoc $ ExplicitTuple rs Boxed
 783 \end{code}