compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12 import TcRnMonad        -- temp
  13
  14 import CoreSyn
  15
  16 import DsCCall          ( dsCCall, mkFCall, boxResult, unboxArg, resultWrapper )
  17 import DsMonad
  18
  19 import HsSyn            ( ForeignDecl(..), ForeignExport(..), LForeignDecl,
  20                           ForeignImport(..), CImportSpec(..) )
  21 import DataCon          ( splitProductType_maybe )
  22 #ifdef DEBUG
  23 import DataCon          ( dataConSourceArity )
  24 import Type             ( isUnLiftedType )
  25 #endif
  26 import MachOp           ( machRepByteWidth, MachRep(..) )
  27 import SMRep            ( argMachRep, typeCgRep )
  28 import CoreUtils        ( exprType, mkInlineMe )
  29 import Id               ( Id, idType, idName, mkSysLocal, setInlinePragma )
  30 import Literal          ( Literal(..), mkStringLit )
  31 import Module           ( moduleFS )
  32 import Name             ( getOccString, NamedThing(..) )
  33 import Type             ( repType, coreEqType )
  34 import TcType           ( Type, mkFunTys, mkForAllTys, mkTyConApp,
  35                           mkFunTy, tcSplitTyConApp_maybe, tcSplitIOType_maybe,
  36                           tcSplitForAllTys, tcSplitFunTys, tcTyConAppArgs,
  37                         )
  38
  39 import BasicTypes       ( Boxity(..) )
  40 import HscTypes         ( ForeignStubs(..) )
  41 import ForeignCall      ( ForeignCall(..), CCallSpec(..),
  42                           Safety(..),
  43                           CExportSpec(..), CLabelString,
  44                           CCallConv(..), ccallConvToInt,
  45                           ccallConvAttribute
  46                         )
  47 import TysWiredIn       ( unitTy, tupleTyCon )
  48 import TysPrim          ( addrPrimTy, mkStablePtrPrimTy, alphaTy )
  49 import PrelNames        ( stablePtrTyConName, newStablePtrName, bindIOName,
  50                           checkDotnetResName )
  51 import BasicTypes       ( Activation( NeverActive ) )
  52 import SrcLoc           ( Located(..), unLoc )
  53 import Outputable
  54 import Maybe            ( fromJust, isNothing )
  55 import FastString
  56 \end{code}
  57
  58 Desugaring of @foreign@ declarations is naturally split up into
  59 parts, an @import@ and an @export@  part. A @foreign import@
  60 declaration
  61 \begin{verbatim}
  62   foreign import cc nm f :: prim_args -> IO prim_res
  63 \end{verbatim}
  64 is the same as
  65 \begin{verbatim}
  66   f :: prim_args -> IO prim_res
  67   f a1 ... an = _ccall_ nm cc a1 ... an
  68 \end{verbatim}
  69 so we reuse the desugaring code in @DsCCall@ to deal with these.
  70
  71 \begin{code}
  72 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  73                                 -- the occurrence analyser will sort it all out
  74
  75 dsForeigns :: [LForeignDecl Id]
  76            -> DsM (ForeignStubs, [Binding])
  77 dsForeigns []
  78   = returnDs (NoStubs, [])
  79 dsForeigns fos
  80   = foldlDs combine (ForeignStubs empty empty [] [], []) fos
  81  where
  82   combine stubs (L loc decl) = putSrcSpanDs loc (combine1 stubs decl)
  83
  84   combine1 (ForeignStubs acc_h acc_c acc_hdrs acc_feb, acc_f)
  85            (ForeignImport id _ spec depr)
  86     = traceIf (text "fi start" <+> ppr id)      `thenDs` \ _ ->
  87       dsFImport (unLoc id) spec                 `thenDs` \ (bs, h, c, mbhd) ->
  88       warnDepr depr                             `thenDs` \ _                ->
  89       traceIf (text "fi end" <+> ppr id)        `thenDs` \ _ ->
  90       returnDs (ForeignStubs (h $$ acc_h)
  91                              (c $$ acc_c)
  92                              (addH mbhd acc_hdrs)
  93                              acc_feb,
  94                 bs ++ acc_f)
  95
  96   combine1 (ForeignStubs acc_h acc_c acc_hdrs acc_feb, acc_f)
  97            (ForeignExport (L _ id) _ (CExport (CExportStatic ext_nm cconv)) depr)
  98     = dsFExport id (idType id)
  99                 ext_nm cconv False                 `thenDs` \(h, c, _, _) ->
 100       warnDepr depr                                `thenDs` \_              ->
 101       returnDs (ForeignStubs (h $$ acc_h) (c $$ acc_c) acc_hdrs (id:acc_feb),
 102                 acc_f)
 103
 104   addH Nothing  ls = ls
 105   addH (Just e) ls
 106    | e `elem` ls = ls
 107    | otherwise   = e:ls
 108
 109   warnDepr False = returnDs ()
 110   warnDepr True  = dsWarn msg
 111      where
 112        msg = ptext SLIT("foreign declaration uses deprecated non-standard syntax")
 113 \end{code}
 114
 115
 116 %************************************************************************
 117 %*                                                                      *
 118 \subsection{Foreign import}
 119 %*                                                                      *
 120 %************************************************************************
 121
 122 Desugaring foreign imports is just the matter of creating a binding
 123 that on its RHS unboxes its arguments, performs the external call
 124 (using the @CCallOp@ primop), before boxing the result up and returning it.
 125
 126 However, we create a worker/wrapper pair, thus:
 127
 128         foreign import f :: Int -> IO Int
 129 ==>
 130         f x = IO ( \s -> case x of { I# x# ->
 131                          case fw s x# of { (# s1, y# #) ->
 132                          (# s1, I# y# #)}})
 133
 134         fw s x# = ccall f s x#
 135
 136 The strictness/CPR analyser won't do this automatically because it doesn't look
 137 inside returned tuples; but inlining this wrapper is a Really Good Idea
 138 because it exposes the boxing to the call site.
 139
 140 \begin{code}
 141 dsFImport :: Id
 142           -> ForeignImport
 143           -> DsM ([Binding], SDoc, SDoc, Maybe FastString)
 144 dsFImport id (CImport cconv safety header lib spec)
 145   = dsCImport id spec cconv safety no_hdrs        `thenDs` \(ids, h, c) ->
 146     returnDs (ids, h, c, if no_hdrs then Nothing else Just header)
 147   where
 148     no_hdrs = nullFS header
 149
 150   -- FIXME: the `lib' field is needed for .NET ILX generation when invoking
 151   --        routines that are external to the .NET runtime, but GHC doesn't
 152   --        support such calls yet; if `nullFastString lib', the value was not given
 153 dsFImport id (DNImport spec)
 154   = dsFCall id (DNCall spec) True {- No headers -} `thenDs` \(ids, h, c) ->
 155     returnDs (ids, h, c, Nothing)
 156
 157 dsCImport :: Id
 158           -> CImportSpec
 159           -> CCallConv
 160           -> Safety
 161           -> Bool       -- True <=> no headers in the f.i decl
 162           -> DsM ([Binding], SDoc, SDoc)
 163 dsCImport id (CLabel cid) _ _ no_hdrs
 164  = resultWrapper (idType id) `thenDs` \ (resTy, foRhs) ->
 165    ASSERT(fromJust resTy `coreEqType` addrPrimTy)    -- typechecker ensures this
 166     let rhs = foRhs (mkLit (MachLabel cid Nothing)) in
 167     returnDs ([(setImpInline no_hdrs id, rhs)], empty, empty)
 168 dsCImport id (CFunction target) cconv safety no_hdrs
 169   = dsFCall id (CCall (CCallSpec target cconv safety)) no_hdrs
 170 dsCImport id CWrapper cconv _ _
 171   = dsFExportDynamic id cconv
 172
 173 setImpInline :: Bool    -- True <=> No #include headers
 174                         -- in the foreign import declaration
 175              -> Id -> Id
 176 -- If there is a #include header in the foreign import
 177 -- we make the worker non-inlinable, because we currently
 178 -- don't keep the #include stuff in the CCallId, and hence
 179 -- it won't be visible in the importing module, which can be
 180 -- fatal.
 181 -- (The #include stuff is just collected from the foreign import
 182 --  decls in a module.)
 183 -- If you want to do cross-module inlining of the c-calls themselves,
 184 -- put the #include stuff in the package spec, not the foreign
 185 -- import decl.
 186 setImpInline True  id = id
 187 setImpInline False id = id `setInlinePragma` NeverActive
 188 \end{code}
 189
 190
 191 %************************************************************************
 192 %*                                                                      *
 193 \subsection{Foreign calls}
 194 %*                                                                      *
 195 %************************************************************************
 196
 197 \begin{code}
 198 dsFCall fn_id fcall no_hdrs
 199   = let
 200         ty                   = idType fn_id
 201         (tvs, fun_ty)        = tcSplitForAllTys ty
 202         (arg_tys, io_res_ty) = tcSplitFunTys fun_ty
 203                 -- Must use tcSplit* functions because we want to
 204                 -- see that (IO t) in the corner
 205     in
 206     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 207     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 208
 209     let
 210         work_arg_ids  = [v | Var v <- val_args] -- All guaranteed to be vars
 211
 212         forDotnet =
 213          case fcall of
 214            DNCall{} -> True
 215            _        -> False
 216
 217         topConDs
 218           | forDotnet =
 219              dsLookupGlobalId checkDotnetResName `thenDs` \ check_id ->
 220              return (Just check_id)
 221           | otherwise = return Nothing
 222
 223         augmentResultDs
 224           | forDotnet =
 225                 newSysLocalDs addrPrimTy `thenDs` \ err_res ->
 226                 returnDs (\ (mb_res_ty, resWrap) ->
 227                               case mb_res_ty of
 228                                 Nothing -> (Just (mkTyConApp (tupleTyCon Unboxed 1)
 229                                                              [ addrPrimTy ]),
 230                                                  resWrap)
 231                                 Just x  -> (Just (mkTyConApp (tupleTyCon Unboxed 2)
 232                                                              [ x, addrPrimTy ]),
 233                                                  resWrap))
 234           | otherwise = returnDs id
 235     in
 236     augmentResultDs                                  `thenDs` \ augment ->
 237     topConDs                                         `thenDs` \ topCon ->
 238     boxResult augment topCon io_res_ty `thenDs` \ (ccall_result_ty, res_wrapper) ->
 239
 240     newUnique                                   `thenDs` \ ccall_uniq ->
 241     newUnique                                   `thenDs` \ work_uniq ->
 242     let
 243         -- Build the worker
 244         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 245         the_ccall_app = mkFCall ccall_uniq fcall val_args ccall_result_ty
 246         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 247         work_id       = setImpInline no_hdrs $  -- See comments with setImpInline
 248                         mkSysLocal FSLIT("$wccall") work_uniq worker_ty
 249
 250         -- Build the wrapper
 251         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 252         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 253         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 254     in
 255     returnDs ([(work_id, work_rhs), (fn_id, wrap_rhs)], empty, empty)
 256 \end{code}
 257
 258
 259 %************************************************************************
 260 %*                                                                      *
 261 \subsection{Foreign export}
 262 %*                                                                      *
 263 %************************************************************************
 264
 265 The function that does most of the work for `@foreign export@' declarations.
 266 (see below for the boilerplate code a `@foreign export@' declaration expands
 267  into.)
 268
 269 For each `@foreign export foo@' in a module M we generate:
 270 \begin{itemize}
 271 \item a C function `@foo@', which calls
 272 \item a Haskell stub `@M.$ffoo@', which calls
 273 \end{itemize}
 274 the user-written Haskell function `@M.foo@'.
 275
 276 \begin{code}
 277 dsFExport :: Id                 -- Either the exported Id,
 278                                 -- or the foreign-export-dynamic constructor
 279           -> Type               -- The type of the thing callable from C
 280           -> CLabelString       -- The name to export to C land
 281           -> CCallConv
 282           -> Bool               -- True => foreign export dynamic
 283                                 --         so invoke IO action that's hanging off
 284                                 --         the first argument's stable pointer
 285           -> DsM ( SDoc         -- contents of Module_stub.h
 286                  , SDoc         -- contents of Module_stub.c
 287                  , [MachRep]    -- primitive arguments expected by stub function
 288                  , Int          -- size of args to stub function
 289                  )
 290
 291 dsFExport fn_id ty ext_name cconv isDyn
 292    =
 293      let
 294         (_tvs,sans_foralls)             = tcSplitForAllTys ty
 295         (fe_arg_tys', orig_res_ty)      = tcSplitFunTys sans_foralls
 296         -- We must use tcSplits here, because we want to see
 297         -- the (IO t) in the corner of the type!
 298         fe_arg_tys | isDyn     = tail fe_arg_tys'
 299                    | otherwise = fe_arg_tys'
 300      in
 301         -- Look at the result type of the exported function, orig_res_ty
 302         -- If it's IO t, return         (t, True)
 303         -- If it's plain t, return      (t, False)
 304      (case tcSplitIOType_maybe orig_res_ty of
 305         Just (ioTyCon, res_ty) -> returnDs (res_ty, True)
 306                 -- The function already returns IO t
 307         Nothing                -> returnDs (orig_res_ty, False)
 308                 -- The function returns t
 309      )                                  `thenDs` \ (res_ty,             -- t
 310                                                     is_IO_res_ty) ->    -- Bool
 311      returnDs $
 312        mkFExportCBits ext_name
 313                       (if isDyn then Nothing else Just fn_id)
 314                       fe_arg_tys res_ty is_IO_res_ty cconv
 315 \end{code}
 316
 317 @foreign export dynamic@ lets you dress up Haskell IO actions
 318 of some fixed type behind an externally callable interface (i.e.,
 319 as a C function pointer). Useful for callbacks and stuff.
 320
 321 \begin{verbatim}
 322 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 323
 324 -- Haskell-visible constructor, which is generated from the above:
 325 -- SUP: No check for NULL from createAdjustor anymore???
 326
 327 f :: (Addr -> Int -> IO Int) -> IO Addr
 328 f cback =
 329    bindIO (newStablePtr cback)
 330           (\StablePtr sp# -> IO (\s1# ->
 331               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 332                  (# s2#, a# #) -> (# s2#, A# a# #)))
 333
 334 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 335 -- `special' foreign export that invokes the closure pointed to by the
 336 -- first argument.
 337 \end{verbatim}
 338
 339 \begin{code}
 340 dsFExportDynamic :: Id
 341                  -> CCallConv
 342                  -> DsM ([Binding], SDoc, SDoc)
 343 dsFExportDynamic id cconv
 344   =  newSysLocalDs ty                            `thenDs` \ fe_id ->
 345      getModuleDs                                `thenDs` \ mod_name ->
 346      let
 347         -- hack: need to get at the name of the C stub we're about to generate.
 348        fe_nm       = mkFastString (unpackFS (zEncodeFS (moduleFS mod_name)) ++ "_" ++ toCName fe_id)
 349      in
 350      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 351      dsLookupGlobalId newStablePtrName          `thenDs` \ newStablePtrId ->
 352      dsLookupTyCon stablePtrTyConName           `thenDs` \ stable_ptr_tycon ->
 353      let
 354         mk_stbl_ptr_app = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 355         stable_ptr_ty   = mkTyConApp stable_ptr_tycon [arg_ty]
 356         export_ty       = mkFunTy stable_ptr_ty arg_ty
 357      in
 358      dsLookupGlobalId bindIOName                `thenDs` \ bindIOId ->
 359      newSysLocalDs stable_ptr_ty                `thenDs` \ stbl_value ->
 360      dsFExport id export_ty fe_nm cconv True
 361                 `thenDs` \ (h_code, c_code, arg_reps, args_size) ->
 362      let
 363       stbl_app cont ret_ty = mkApps (Var bindIOId)
 364                                     [ Type stable_ptr_ty
 365                                     , Type ret_ty
 366                                     , mk_stbl_ptr_app
 367                                     , cont
 368                                     ]
 369        {-
 370         The arguments to the external function which will
 371         create a little bit of (template) code on the fly
 372         for allowing the (stable pointed) Haskell closure
 373         to be entered using an external calling convention
 374         (stdcall, ccall).
 375        -}
 376       adj_args      = [ mkIntLitInt (ccallConvToInt cconv)
 377                       , Var stbl_value
 378                       , mkLit (MachLabel fe_nm mb_sz_args)
 379                       , mkLit (mkStringLit arg_type_info)
 380                       ]
 381         -- name of external entry point providing these services.
 382         -- (probably in the RTS.)
 383       adjustor   = FSLIT("createAdjustor")
 384
 385       arg_type_info = map repCharCode arg_reps
 386       repCharCode F32 = 'f'
 387       repCharCode F64 = 'd'
 388       repCharCode I64 = 'l'
 389       repCharCode _   = 'i'
 390
 391         -- Determine the number of bytes of arguments to the stub function,
 392         -- so that we can attach the '@N' suffix to its label if it is a
 393         -- stdcall on Windows.
 394       mb_sz_args = case cconv of
 395                       StdCallConv -> Just args_size
 396                       _           -> Nothing
 397
 398      in
 399      dsCCall adjustor adj_args PlayRisky io_res_ty      `thenDs` \ ccall_adj ->
 400         -- PlayRisky: the adjustor doesn't allocate in the Haskell heap or do a callback
 401      let ccall_adj_ty = exprType ccall_adj
 402          ccall_io_adj = mkLams [stbl_value]                  $
 403                         Note (Coerce io_res_ty ccall_adj_ty)
 404                              ccall_adj
 405          io_app = mkLams tvs     $
 406                   mkLams [cback] $
 407                   stbl_app ccall_io_adj res_ty
 408          fed = (id `setInlinePragma` NeverActive, io_app)
 409                 -- Never inline the f.e.d. function, because the litlit
 410                 -- might not be in scope in other modules.
 411      in
 412      returnDs ([fed], h_code, c_code)
 413
 414  where
 415   ty                    = idType id
 416   (tvs,sans_foralls)    = tcSplitForAllTys ty
 417   ([arg_ty], io_res_ty) = tcSplitFunTys sans_foralls
 418   [res_ty]              = tcTyConAppArgs io_res_ty
 419         -- Must use tcSplit* to see the (IO t), which is a newtype
 420
 421 toCName :: Id -> String
 422 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 423 \end{code}
 424
 425 %*
 426 %
 427 \subsection{Generating @foreign export@ stubs}
 428 %
 429 %*
 430
 431 For each @foreign export@ function, a C stub function is generated.
 432 The C stub constructs the application of the exported Haskell function
 433 using the hugs/ghc rts invocation API.
 434
 435 \begin{code}
 436 mkFExportCBits :: FastString
 437                -> Maybe Id      -- Just==static, Nothing==dynamic
 438                -> [Type]
 439                -> Type
 440                -> Bool          -- True <=> returns an IO type
 441                -> CCallConv
 442                -> (SDoc,
 443                    SDoc,
 444                    [MachRep],   -- the argument reps
 445                    Int          -- total size of arguments
 446                   )
 447 mkFExportCBits c_nm maybe_target arg_htys res_hty is_IO_res_ty cc
 448  = (header_bits, c_bits,
 449     [rep | (_,_,_,rep) <- arg_info],  -- just the real args
 450     sum [ machRepByteWidth rep | (_,_,_,rep) <- aug_arg_info] -- all the args
 451     )
 452  where
 453   -- list the arguments to the C function
 454   arg_info :: [(SDoc,           -- arg name
 455                 SDoc,           -- C type
 456                 Type,           -- Haskell type
 457                 MachRep)]       -- the MachRep
 458   arg_info  = [ (text ('a':show n), showStgType ty, ty,
 459                  typeMachRep (getPrimTyOf ty))
 460               | (ty,n) <- zip arg_htys [1..] ]
 461
 462   -- add some auxiliary args; the stable ptr in the wrapper case, and
 463   -- a slot for the dummy return address in the wrapper + ccall case
 464   aug_arg_info
 465     | isNothing maybe_target = stable_ptr_arg : insertRetAddr cc arg_info
 466     | otherwise              = arg_info
 467
 468   stable_ptr_arg =
 469         (text "the_stableptr", text "StgStablePtr", undefined,
 470          typeMachRep (mkStablePtrPrimTy alphaTy))
 471
 472   -- stuff to do with the return type of the C function
 473   res_hty_is_unit = res_hty `coreEqType` unitTy -- Look through any newtypes
 474
 475   cResType | res_hty_is_unit = text "void"
 476            | otherwise       = showStgType res_hty
 477
 478   -- Now we can cook up the prototype for the exported function.
 479   pprCconv = case cc of
 480                 CCallConv   -> empty
 481                 StdCallConv -> text (ccallConvAttribute cc)
 482
 483   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 484
 485   fun_proto = cResType <+> pprCconv <+> ftext c_nm <>
 486               parens (hsep (punctuate comma (map (\(nm,ty,_,_) -> ty <+> nm)
 487                                                  aug_arg_info)))
 488
 489   -- the target which will form the root of what we ask rts_evalIO to run
 490   the_cfun
 491      = case maybe_target of
 492           Nothing    -> text "(StgClosure*)deRefStablePtr(the_stableptr)"
 493           Just hs_fn -> char '&' <> ppr hs_fn <> text "_closure"
 494
 495   cap = text "cap" <> comma
 496
 497   -- the expression we give to rts_evalIO
 498   expr_to_run
 499      = foldl appArg the_cfun arg_info -- NOT aug_arg_info
 500        where
 501           appArg acc (arg_cname, _, arg_hty, _)
 502              = text "rts_apply"
 503                <> parens (cap <> acc <> comma <> mkHObj arg_hty <> parens (cap <> arg_cname))
 504
 505   -- various other bits for inside the fn
 506   declareResult = text "HaskellObj ret;"
 507   declareCResult | res_hty_is_unit = empty
 508                  | otherwise       = cResType <+> text "cret;"
 509
 510   assignCResult | res_hty_is_unit = empty
 511                 | otherwise       =
 512                         text "cret=" <> unpackHObj res_hty <> parens (text "ret") <> semi
 513
 514   -- an extern decl for the fn being called
 515   extern_decl
 516      = case maybe_target of
 517           Nothing -> empty
 518           Just hs_fn -> text "extern StgClosure " <> ppr hs_fn <> text "_closure" <> semi
 519
 520
 521    -- Initialise foreign exports by registering a stable pointer from an
 522    -- __attribute__((constructor)) function.
 523    -- The alternative is to do this from stginit functions generated in
 524    -- codeGen/CodeGen.lhs; however, stginit functions have a negative impact
 525    -- on binary sizes and link times because the static linker will think that
 526    -- all modules that are imported directly or indirectly are actually used by
 527    -- the program.
 528    -- (this is bad for big umbrella modules like Graphics.Rendering.OpenGL)
 529
 530   initialiser
 531      = case maybe_target of
 532           Nothing -> empty
 533           Just hs_fn ->
 534             vcat
 535              [ text "static void stginit_export_" <> ppr hs_fn
 536                   <> text "() __attribute__((constructor));"
 537              , text "static void stginit_export_" <> ppr hs_fn <> text "()"
 538              , braces (text "getStablePtr"
 539                 <> parens (text "(StgPtr) &" <> ppr hs_fn <> text "_closure")
 540                 <> semi)
 541              ]
 542
 543   -- finally, the whole darn thing
 544   c_bits =
 545     space $$
 546     extern_decl $$
 547     fun_proto  $$
 548     vcat
 549      [ lbrace
 550      ,   text "Capability *cap;"
 551      ,   declareResult
 552      ,   declareCResult
 553      ,   text "cap = rts_lock();"
 554           -- create the application + perform it.
 555      ,   text "cap=rts_evalIO" <> parens (
 556                 cap <>
 557                 text "rts_apply" <> parens (
 558                     cap <>
 559                     text "(HaskellObj)"
 560                  <> text (if is_IO_res_ty
 561                                 then "runIO_closure"
 562                                 else "runNonIO_closure")
 563                  <> comma
 564                  <> expr_to_run
 565                 ) <+> comma
 566                <> text "&ret"
 567              ) <> semi
 568      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ftext c_nm)
 569                                                 <> comma <> text "cap") <> semi
 570      ,   assignCResult
 571      ,   text "rts_unlock(cap);"
 572      ,   if res_hty_is_unit then empty
 573             else text "return cret;"
 574      , rbrace
 575      ] $$
 576     initialiser
 577
 578 -- NB. the calculation here isn't strictly speaking correct.
 579 -- We have a primitive Haskell type (eg. Int#, Double#), and
 580 -- we want to know the size, when passed on the C stack, of
 581 -- the associated C type (eg. HsInt, HsDouble).  We don't have
 582 -- this information to hand, but we know what GHC's conventions
 583 -- are for passing around the primitive Haskell types, so we
 584 -- use that instead.  I hope the two coincide --SDM
 585 typeMachRep ty = argMachRep (typeCgRep ty)
 586
 587 mkHObj :: Type -> SDoc
 588 mkHObj t = text "rts_mk" <> text (showFFIType t)
 589
 590 unpackHObj :: Type -> SDoc
 591 unpackHObj t = text "rts_get" <> text (showFFIType t)
 592
 593 showStgType :: Type -> SDoc
 594 showStgType t = text "Hs" <> text (showFFIType t)
 595
 596 showFFIType :: Type -> String
 597 showFFIType t = getOccString (getName tc)
 598  where
 599   tc = case tcSplitTyConApp_maybe (repType t) of
 600             Just (tc,_) -> tc
 601             Nothing     -> pprPanic "showFFIType" (ppr t)
 602
 603 #if !defined(x86_64_TARGET_ARCH)
 604 insertRetAddr CCallConv args = ret_addr_arg : args
 605 insertRetAddr _ args = args
 606 #else
 607 -- On x86_64 we insert the return address after the 6th
 608 -- integer argument, because this is the point at which we
 609 -- need to flush a register argument to the stack (See rts/Adjustor.c for
 610 -- details).
 611 insertRetAddr CCallConv args = go 0 args
 612   where  go 6 args = ret_addr_arg : args
 613          go n (arg@(_,_,_,rep):args)
 614           | I64 <- rep = arg : go (n+1) args
 615           | otherwise  = arg : go n     args
 616          go n [] = []
 617 insertRetAddr _ args = args
 618 #endif
 619
 620 ret_addr_arg = (text "original_return_addr", text "void*", undefined,
 621                 typeMachRep addrPrimTy)
 622
 623 -- This function returns the primitive type associated with the boxed
 624 -- type argument to a foreign export (eg. Int ==> Int#).  It assumes
 625 -- that all the types we are interested in have a single constructor
 626 -- with a single primitive-typed argument, which is true for all of the legal
 627 -- foreign export argument types (see TcType.legalFEArgTyCon).
 628 getPrimTyOf :: Type -> Type
 629 getPrimTyOf ty =
 630   case splitProductType_maybe (repType ty) of
 631      Just (_, _, data_con, [prim_ty]) ->
 632         ASSERT(dataConSourceArity data_con == 1)
 633         ASSERT2(isUnLiftedType prim_ty, ppr prim_ty)
 634         prim_ty
 635      _other -> pprPanic "DsForeign.getPrimTyOf" (ppr ty)
 636 \end{code}