compiler/deSugar/DsMonad.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 @DsMonad@: monadery used in desugaring
   7
   8 \begin{code}
   9 module DsMonad (
  10         DsM, mapM, mapAndUnzipM,
  11         initDs, initDsTc, fixDs,
  12         foldlM, foldrM, ifOptM,
  13         Applicative(..),(<$>),
  14
  15         newLocalName,
  16         duplicateLocalDs, newSysLocalDs, newSysLocalsDs, newUniqueId,
  17         newFailLocalDs,
  18         getSrcSpanDs, putSrcSpanDs,
  19         getModuleDs,
  20         newUnique,
  21         UniqSupply, newUniqueSupply,
  22         getDOptsDs, getGhcModeDs, doptDs,
  23         dsLookupGlobal, dsLookupGlobalId, dsLookupTyCon, dsLookupDataCon,
  24         dsLookupClass,
  25
  26         DsMetaEnv, DsMetaVal(..), dsLookupMetaEnv, dsExtendMetaEnv,
  27
  28         -- Warnings
  29         DsWarning, warnDs, failWithDs,
  30
  31         -- Data types
  32         DsMatchContext(..),
  33         EquationInfo(..), MatchResult(..), DsWrapper, idDsWrapper,
  34         CanItFail(..), orFail
  35     ) where
  36
  37 import TcRnMonad
  38 import CoreSyn
  39 import HsSyn
  40 import TcIface
  41 import RdrName
  42 import HscTypes
  43 import Bag
  44 import DataCon
  45 import TyCon
  46 import Class
  47 import Id
  48 import Module
  49 import Var
  50 import Outputable
  51 import SrcLoc
  52 import Type
  53 import UniqSupply
  54 import Name
  55 import NameEnv
  56 import OccName
  57 import DynFlags
  58 import ErrUtils
  59 import MonadUtils
  60 import FastString
  61
  62 import Data.IORef
  63 \end{code}
  64
  65 %************************************************************************
  66 %*                                                                      *
  67                 Data types for the desugarer
  68 %*                                                                      *
  69 %************************************************************************
  70
  71 \begin{code}
  72 data DsMatchContext
  73   = DsMatchContext (HsMatchContext Name) SrcSpan
  74   | NoMatchContext
  75   deriving ()
  76
  77 data EquationInfo
  78   = EqnInfo { eqn_pats :: [Pat Id],     -- The patterns for an eqn
  79               eqn_rhs  :: MatchResult } -- What to do after match
  80
  81 instance Outputable EquationInfo where
  82     ppr (EqnInfo pats _) = ppr pats
  83
  84 type DsWrapper = CoreExpr -> CoreExpr
  85 idDsWrapper :: DsWrapper
  86 idDsWrapper e = e
  87
  88 -- The semantics of (match vs (EqnInfo wrap pats rhs)) is the MatchResult
  89 --      \fail. wrap (case vs of { pats -> rhs fail })
  90 -- where vs are not bound by wrap
  91
  92
  93 -- A MatchResult is an expression with a hole in it
  94 data MatchResult
  95   = MatchResult
  96         CanItFail       -- Tells whether the failure expression is used
  97         (CoreExpr -> DsM CoreExpr)
  98                         -- Takes a expression to plug in at the
  99                         -- failure point(s). The expression should
 100                         -- be duplicatable!
 101
 102 data CanItFail = CanFail | CantFail
 103
 104 orFail :: CanItFail -> CanItFail -> CanItFail
 105 orFail CantFail CantFail = CantFail
 106 orFail _        _        = CanFail
 107 \end{code}
 108
 109
 110 %************************************************************************
 111 %*                                                                      *
 112                 Monad stuff
 113 %*                                                                      *
 114 %************************************************************************
 115
 116 Now the mondo monad magic (yes, @DsM@ is a silly name)---carry around
 117 a @UniqueSupply@ and some annotations, which
 118 presumably include source-file location information:
 119 \begin{code}
 120 type DsM result = TcRnIf DsGblEnv DsLclEnv result
 121
 122 -- Compatibility functions
 123 fixDs :: (a -> DsM a) -> DsM a
 124 fixDs    = fixM
 125
 126 type DsWarning = (SrcSpan, SDoc)
 127         -- Not quite the same as a WarnMsg, we have an SDoc here
 128         -- and we'll do the print_unqual stuff later on to turn it
 129         -- into a Doc.
 130
 131 data DsGblEnv = DsGblEnv {
 132         ds_mod     :: Module,                   -- For SCC profiling
 133         ds_unqual  :: PrintUnqualified,
 134         ds_msgs    :: IORef Messages,           -- Warning messages
 135         ds_if_env  :: (IfGblEnv, IfLclEnv)      -- Used for looking up global,
 136                                                 -- possibly-imported things
 137     }
 138
 139 data DsLclEnv = DsLclEnv {
 140         ds_meta    :: DsMetaEnv,        -- Template Haskell bindings
 141         ds_loc     :: SrcSpan           -- to put in pattern-matching error msgs
 142      }
 143
 144 -- Inside [| |] brackets, the desugarer looks
 145 -- up variables in the DsMetaEnv
 146 type DsMetaEnv = NameEnv DsMetaVal
 147
 148 data DsMetaVal
 149    = Bound Id           -- Bound by a pattern inside the [| |].
 150                         -- Will be dynamically alpha renamed.
 151                         -- The Id has type THSyntax.Var
 152
 153    | Splice (HsExpr Id) -- These bindings are introduced by
 154                         -- the PendingSplices on a HsBracketOut
 155
 156 initDs  :: HscEnv
 157         -> Module -> GlobalRdrEnv -> TypeEnv
 158         -> DsM a
 159         -> IO (Messages, Maybe a)
 160 -- Print errors and warnings, if any arise
 161
 162 initDs hsc_env mod rdr_env type_env thing_inside
 163   = do  { msg_var <- newIORef (emptyBag, emptyBag)
 164         ; let dflags = hsc_dflags hsc_env
 165         ; (ds_gbl_env, ds_lcl_env) <- mkDsEnvs dflags mod rdr_env type_env msg_var
 166
 167         ; either_res <- initTcRnIf 'd' hsc_env ds_gbl_env ds_lcl_env $
 168                         tryM thing_inside       -- Catch exceptions (= errors during desugaring)
 169
 170         -- Display any errors and warnings
 171         -- Note: if -Werror is used, we don't signal an error here.
 172         ; msgs <- readIORef msg_var
 173
 174         ; let final_res | errorsFound dflags msgs = Nothing
 175                         | otherwise = case either_res of
 176                                         Right res -> Just res
 177                                         Left exn -> pprPanic "initDs" (text (show exn))
 178                 -- The (Left exn) case happens when the thing_inside throws
 179                 -- a UserError exception.  Then it should have put an error
 180                 -- message in msg_var, so we just discard the exception
 181
 182         ; return (msgs, final_res) }
 183
 184 initDsTc :: DsM a -> TcM a
 185 initDsTc thing_inside
 186   = do  { this_mod <- getModule
 187         ; tcg_env  <- getGblEnv
 188         ; msg_var  <- getErrsVar
 189         ; dflags   <- getDOpts
 190         ; let type_env = tcg_type_env tcg_env
 191               rdr_env  = tcg_rdr_env tcg_env
 192         ; ds_envs <- liftIO $ mkDsEnvs dflags this_mod rdr_env type_env msg_var
 193         ; setEnvs ds_envs thing_inside }
 194
 195 mkDsEnvs :: DynFlags -> Module -> GlobalRdrEnv -> TypeEnv -> IORef Messages -> IO (DsGblEnv, DsLclEnv)
 196 mkDsEnvs dflags mod rdr_env type_env msg_var
 197   = do -- TODO: unnecessarily monadic
 198        let     if_genv = IfGblEnv { if_rec_types = Just (mod, return type_env) }
 199                if_lenv = mkIfLclEnv mod (ptext (sLit "GHC error in desugarer lookup in") <+> ppr mod)
 200                gbl_env = DsGblEnv { ds_mod = mod,
 201                                     ds_if_env = (if_genv, if_lenv),
 202                                     ds_unqual = mkPrintUnqualified dflags rdr_env,
 203                                     ds_msgs = msg_var}
 204                lcl_env = DsLclEnv { ds_meta = emptyNameEnv,
 205                                     ds_loc = noSrcSpan }
 206
 207        return (gbl_env, lcl_env)
 208 \end{code}
 209
 210 %************************************************************************
 211 %*                                                                      *
 212                 Operations in the monad
 213 %*                                                                      *
 214 %************************************************************************
 215
 216 And all this mysterious stuff is so we can occasionally reach out and
 217 grab one or more names.  @newLocalDs@ isn't exported---exported
 218 functions are defined with it.  The difference in name-strings makes
 219 it easier to read debugging output.
 220
 221 \begin{code}
 222 -- Make a new Id with the same print name, but different type, and new unique
 223 newUniqueId :: Name -> Type -> DsM Id
 224 newUniqueId id = mkSysLocalM (occNameFS (nameOccName id))
 225
 226 duplicateLocalDs :: Id -> DsM Id
 227 duplicateLocalDs old_local = do
 228     uniq <- newUnique
 229     return (setIdUnique old_local uniq)
 230
 231 newSysLocalDs, newFailLocalDs :: Type -> DsM Id
 232 newSysLocalDs = mkSysLocalM (fsLit "ds")
 233 newFailLocalDs = mkSysLocalM (fsLit "fail")
 234
 235 newSysLocalsDs :: [Type] -> DsM [Id]
 236 newSysLocalsDs tys = mapM newSysLocalDs tys
 237 \end{code}
 238
 239 We can also reach out and either set/grab location information from
 240 the @SrcSpan@ being carried around.
 241
 242 \begin{code}
 243 getDOptsDs :: DsM DynFlags
 244 getDOptsDs = getDOpts
 245
 246 doptDs :: DynFlag -> TcRnIf gbl lcl Bool
 247 doptDs = doptM
 248
 249 getGhcModeDs :: DsM GhcMode
 250 getGhcModeDs =  getDOptsDs >>= return . ghcMode
 251
 252 getModuleDs :: DsM Module
 253 getModuleDs = do { env <- getGblEnv; return (ds_mod env) }
 254
 255 getSrcSpanDs :: DsM SrcSpan
 256 getSrcSpanDs = do { env <- getLclEnv; return (ds_loc env) }
 257
 258 putSrcSpanDs :: SrcSpan -> DsM a -> DsM a
 259 putSrcSpanDs new_loc thing_inside = updLclEnv (\ env -> env {ds_loc = new_loc}) thing_inside
 260
 261 warnDs :: SDoc -> DsM ()
 262 warnDs warn = do { env <- getGblEnv
 263                  ; loc <- getSrcSpanDs
 264                  ; let msg = mkWarnMsg loc (ds_unqual env)
 265                                       (ptext (sLit "Warning:") <+> warn)
 266                  ; updMutVar (ds_msgs env) (\ (w,e) -> (w `snocBag` msg, e)) }
 267
 268 failWithDs :: SDoc -> DsM a
 269 failWithDs err
 270   = do  { env <- getGblEnv
 271         ; loc <- getSrcSpanDs
 272         ; let msg = mkErrMsg loc (ds_unqual env) err
 273         ; updMutVar (ds_msgs env) (\ (w,e) -> (w, e `snocBag` msg))
 274         ; failM }
 275 \end{code}
 276
 277 \begin{code}
 278 instance MonadThings (IOEnv (Env DsGblEnv DsLclEnv)) where
 279     lookupThing = dsLookupGlobal
 280
 281 dsLookupGlobal :: Name -> DsM TyThing
 282 -- Very like TcEnv.tcLookupGlobal
 283 dsLookupGlobal name
 284   = do  { env <- getGblEnv
 285         ; setEnvs (ds_if_env env)
 286                   (tcIfaceGlobal name) }
 287
 288 dsLookupGlobalId :: Name -> DsM Id
 289 dsLookupGlobalId name
 290   = tyThingId <$> dsLookupGlobal name
 291
 292 dsLookupTyCon :: Name -> DsM TyCon
 293 dsLookupTyCon name
 294   = tyThingTyCon <$> dsLookupGlobal name
 295
 296 dsLookupDataCon :: Name -> DsM DataCon
 297 dsLookupDataCon name
 298   = tyThingDataCon <$> dsLookupGlobal name
 299
 300 dsLookupClass :: Name -> DsM Class
 301 dsLookupClass name
 302   = tyThingClass <$> dsLookupGlobal name
 303 \end{code}
 304
 305 \begin{code}
 306 dsLookupMetaEnv :: Name -> DsM (Maybe DsMetaVal)
 307 dsLookupMetaEnv name = do { env <- getLclEnv; return (lookupNameEnv (ds_meta env) name) }
 308
 309 dsExtendMetaEnv :: DsMetaEnv -> DsM a -> DsM a
 310 dsExtendMetaEnv menv thing_inside
 311   = updLclEnv (\env -> env { ds_meta = ds_meta env `plusNameEnv` menv }) thing_inside
 312 \end{code}