compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utilities for desugaring
   7
   8 This module exports some utility functions of no great interest.
   9
  10 \begin{code}
  11 module DsUtils (
  12         EquationInfo(..),
  13         firstPat, shiftEqns,
  14
  15         mkDsLet, mkDsLets,
  16
  17         MatchResult(..), CanItFail(..),
  18         cantFailMatchResult, alwaysFailMatchResult,
  19         extractMatchResult, combineMatchResults,
  20         adjustMatchResult,  adjustMatchResultDs,
  21         mkCoLetMatchResult, mkGuardedMatchResult,
  22         matchCanFail, mkEvalMatchResult,
  23         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  24         wrapBind, wrapBinds,
  25
  26         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  27         mkIntExpr, mkCharExpr,
  28         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  29
  30         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  31         mkTupleType, mkTupleCase, mkBigCoreTup,
  32         mkCoreTup, mkCoreTupTy, seqVar,
  33
  34         dsSyntaxTable, lookupEvidence,
  35
  36         selectSimpleMatchVarL, selectMatchVars, selectMatchVar
  37     ) where
  38
  39 #include "HsVersions.h"
  40
  41 import {-# SOURCE #-}   Match ( matchSimply )
  42 import {-# SOURCE #-}   DsExpr( dsExpr )
  43
  44 import HsSyn
  45 import TcHsSyn
  46 import CoreSyn
  47 import Constants
  48 import DsMonad
  49
  50 import CoreUtils
  51 import MkId
  52 import Id
  53 import Var
  54 import Name
  55 import Literal
  56 import TyCon
  57 import DataCon
  58 import Type
  59 import Coercion
  60 import TysPrim
  61 import TysWiredIn
  62 import BasicTypes
  63 import UniqSet
  64 import UniqSupply
  65 import PrelNames
  66 import Outputable
  67 import SrcLoc
  68 import Util
  69 import ListSetOps
  70 import FastString
  71 import Data.Char
  72
  73 #ifdef DEBUG
  74 import Util
  75 #endif
  76 \end{code}
  77
  78
  79
  80 %************************************************************************
  81 %*                                                                      *
  82                 Rebindable syntax
  83 %*                                                                      *
  84 %************************************************************************
  85
  86 \begin{code}
  87 dsSyntaxTable :: SyntaxTable Id
  88                -> DsM ([CoreBind],      -- Auxiliary bindings
  89                        [(Name,Id)])     -- Maps the standard name to its value
  90
  91 dsSyntaxTable rebound_ids
  92   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  93     return (concat binds_s, prs)
  94   where
  95         -- The cheapo special case can happen when we
  96         -- make an intermediate HsDo when desugaring a RecStmt
  97     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
  98     mk_bind (std_name, expr)
  99          = dsExpr expr                          `thenDs` \ rhs ->
 100            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 101            return ([NonRec id rhs], (std_name, id))
 102
 103 lookupEvidence :: [(Name, Id)] -> Name -> Id
 104 lookupEvidence prs std_name
 105   = assocDefault (mk_panic std_name) prs std_name
 106   where
 107     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext SLIT("Not found:") <+> ppr std_name)
 108 \end{code}
 109
 110
 111 %************************************************************************
 112 %*                                                                      *
 113 \subsection{Building lets}
 114 %*                                                                      *
 115 %************************************************************************
 116
 117 Use case, not let for unlifted types.  The simplifier will turn some
 118 back again.
 119
 120 \begin{code}
 121 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 122 mkDsLet (NonRec bndr rhs) body
 123   | isUnLiftedType (idType bndr)
 124   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 125 mkDsLet bind body
 126   = Let bind body
 127
 128 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 129 mkDsLets binds body = foldr mkDsLet body binds
 130 \end{code}
 131
 132
 133 %************************************************************************
 134 %*                                                                      *
 135 \subsection{ Selecting match variables}
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 We're about to match against some patterns.  We want to make some
 140 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 141 hand, which should indeed be bound to the pattern as a whole, then use it;
 142 otherwise, make one up.
 143
 144 \begin{code}
 145 selectSimpleMatchVarL :: LPat Id -> DsM Id
 146 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat)
 147
 148 -- (selectMatchVars ps tys) chooses variables of type tys
 149 -- to use for matching ps against.  If the pattern is a variable,
 150 -- we try to use that, to save inventing lots of fresh variables.
 151 --
 152 -- OLD, but interesting note:
 153 --    But even if it is a variable, its type might not match.  Consider
 154 --      data T a where
 155 --        T1 :: Int -> T Int
 156 --        T2 :: a   -> T a
 157 --
 158 --      f :: T a -> a -> Int
 159 --      f (T1 i) (x::Int) = x
 160 --      f (T2 i) (y::a)   = 0
 161 --    Then we must not choose (x::Int) as the matching variable!
 162 -- And nowadays we won't, because the (x::Int) will be wrapped in a CoPat
 163
 164 selectMatchVars :: [Pat Id] -> DsM [Id]
 165 selectMatchVars ps = mapM selectMatchVar ps
 166
 167 selectMatchVar (BangPat pat)   = selectMatchVar (unLoc pat)
 168 selectMatchVar (LazyPat pat)   = selectMatchVar (unLoc pat)
 169 selectMatchVar (ParPat pat)    = selectMatchVar (unLoc pat)
 170 selectMatchVar (VarPat var)    = return var
 171 selectMatchVar (AsPat var pat) = return (unLoc var)
 172 selectMatchVar other_pat       = newSysLocalDs (hsPatType other_pat)
 173                                   -- OK, better make up one...
 174 \end{code}
 175
 176
 177 %************************************************************************
 178 %*                                                                      *
 179 %* type synonym EquationInfo and access functions for its pieces        *
 180 %*                                                                      *
 181 %************************************************************************
 182 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 183
 184 The ``equation info'' used by @match@ is relatively complicated and
 185 worthy of a type synonym and a few handy functions.
 186
 187 \begin{code}
 188 firstPat :: EquationInfo -> Pat Id
 189 firstPat eqn = head (eqn_pats eqn)
 190
 191 shiftEqns :: [EquationInfo] -> [EquationInfo]
 192 -- Drop the first pattern in each equation
 193 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 194 \end{code}
 195
 196 Functions on MatchResults
 197
 198 \begin{code}
 199 matchCanFail :: MatchResult -> Bool
 200 matchCanFail (MatchResult CanFail _)  = True
 201 matchCanFail (MatchResult CantFail _) = False
 202
 203 alwaysFailMatchResult :: MatchResult
 204 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 205
 206 cantFailMatchResult :: CoreExpr -> MatchResult
 207 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 208
 209 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 210 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 211   = match_fn (error "It can't fail!")
 212
 213 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 214   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 215     match_fn if_it_fails                `thenDs` \ body ->
 216     returnDs (mkDsLet fail_bind body)
 217
 218
 219 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 220 combineMatchResults (MatchResult CanFail      body_fn1)
 221                     (MatchResult can_it_fail2 body_fn2)
 222   = MatchResult can_it_fail2 body_fn
 223   where
 224     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 225                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 226                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 227                    returnDs (Let fail_bind body1)
 228
 229 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 230   = match_result1
 231
 232 adjustMatchResult :: DsWrapper -> MatchResult -> MatchResult
 233 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 234   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 235                                       returnDs (encl_fn body))
 236
 237 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 238 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 239   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 240                                       encl_fn body)
 241
 242 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 243 wrapBinds [] e = e
 244 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 245
 246 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 247 wrapBind new old body
 248   | new==old    = body
 249   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 250   | otherwise   = Let (NonRec new (Var old)) body
 251
 252 seqVar :: Var -> CoreExpr -> CoreExpr
 253 seqVar var body = Case (Var var) var (exprType body)
 254                         [(DEFAULT, [], body)]
 255
 256 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 257 mkCoLetMatchResult bind = adjustMatchResult (mkDsLet bind)
 258
 259 mkEvalMatchResult :: Id -> Type -> MatchResult -> MatchResult
 260 mkEvalMatchResult var ty
 261   = adjustMatchResult (\e -> Case (Var var) var ty [(DEFAULT, [], e)])
 262
 263 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 264 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 265   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 266                                   returnDs (mkIfThenElse pred_expr body fail))
 267
 268 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 269                     -> Type                             -- Type of the case
 270                     -> [(Literal, MatchResult)]         -- Alternatives
 271                     -> MatchResult
 272 mkCoPrimCaseMatchResult var ty match_alts
 273   = MatchResult CanFail mk_case
 274   where
 275     mk_case fail
 276       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 277         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 278
 279     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 280     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 281                                                returnDs (LitAlt lit, [], body)
 282
 283
 284 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 285                     -> Type                                     -- Type of exp
 286                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 287                     -> MatchResult
 288 mkCoAlgCaseMatchResult var ty match_alts
 289   | isNewTyCon tycon            -- Newtype case; use a let
 290   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 291     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 292
 293   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 294   = MatchResult CanFail mk_parrCase
 295
 296   | otherwise                   -- Datatype case; use a case
 297   = MatchResult fail_flag mk_case
 298   where
 299     tycon = dataConTyCon con1
 300         -- [Interesting: becuase of GADTs, we can't rely on the type of
 301         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 302
 303         -- Stuff for newtype
 304     (con1, arg_ids1, match_result1) = head match_alts
 305     arg_id1     = head arg_ids1
 306     var_ty      = idType var
 307     (tc, ty_args) = splitNewTyConApp var_ty
 308     newtype_rhs = unwrapNewTypeBody tc ty_args (Var var)
 309
 310         -- Stuff for data types
 311     data_cons      = tyConDataCons tycon
 312     match_results  = [match_result | (_,_,match_result) <- match_alts]
 313
 314     fail_flag | exhaustive_case
 315               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 316               | otherwise
 317               = CanFail
 318
 319     wild_var = mkWildId (idType var)
 320     sorted_alts  = sortWith get_tag match_alts
 321     get_tag (con, _, _) = dataConTag con
 322     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 323                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 324
 325     mk_alt fail (con, args, MatchResult _ body_fn)
 326         = body_fn fail                          `thenDs` \ body ->
 327           newUniqueSupply                       `thenDs` \ us ->
 328           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 329
 330     mk_default fail | exhaustive_case = []
 331                     | otherwise       = [(DEFAULT, [], fail)]
 332
 333     un_mentioned_constructors
 334         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 335     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 336
 337         -- Stuff for parallel arrays
 338         --
 339         --  * the following is to desugar cases over fake constructors for
 340         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 341         --   case
 342         --
 343         -- Concerning `isPArrFakeAlts':
 344         --
 345         --  * it is *not* sufficient to just check the type of the type
 346         --   constructor, as we have to be careful not to confuse the real
 347         --   representation of parallel arrays with the fake constructors;
 348         --   moreover, a list of alternatives must not mix fake and real
 349         --   constructors (this is checked earlier on)
 350         --
 351         -- FIXME: We actually go through the whole list and make sure that
 352         --        either all or none of the constructors are fake parallel
 353         --        array constructors.  This is to spot equations that mix fake
 354         --        constructors with the real representation defined in
 355         --        `PrelPArr'.  It would be nicer to spot this situation
 356         --        earlier and raise a proper error message, but it can really
 357         --        only happen in `PrelPArr' anyway.
 358         --
 359     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 360     isPArrFakeAlts ((dcon, _, _):alts) =
 361       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 362         (True , True ) -> True
 363         (False, False) -> False
 364         _              ->
 365           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 366     --
 367     mk_parrCase fail =
 368       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 369       unboxAlt                                          `thenDs` \alt      ->
 370       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 371       where
 372         elemTy      = case splitTyConApp (idType var) of
 373                         (_, [elemTy]) -> elemTy
 374                         _               -> panic panicMsg
 375         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 376         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 377         --
 378         unboxAlt =
 379           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 380           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 381           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 382           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 383           where
 384             wild = mkWildId intPrimTy
 385             dft  = (DEFAULT, [], fail)
 386         --
 387         -- each alternative matches one array length (corresponding to one
 388         -- fake array constructor), so the match is on a literal; each
 389         -- alternative's body is extended by a local binding for each
 390         -- constructor argument, which are bound to array elements starting
 391         -- with the first
 392         --
 393         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 394           bodyFun fail                                  `thenDs` \body     ->
 395           returnDs (LitAlt lit, [], mkDsLets binds body)
 396           where
 397             lit   = MachInt $ toInteger (dataConSourceArity con)
 398             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 399             --
 400             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 401 \end{code}
 402
 403
 404 %************************************************************************
 405 %*                                                                      *
 406 \subsection{Desugarer's versions of some Core functions}
 407 %*                                                                      *
 408 %************************************************************************
 409
 410 \begin{code}
 411 mkErrorAppDs :: Id              -- The error function
 412              -> Type            -- Type to which it should be applied
 413              -> String          -- The error message string to pass
 414              -> DsM CoreExpr
 415
 416 mkErrorAppDs err_id ty msg
 417   = getSrcSpanDs                `thenDs` \ src_loc ->
 418     let
 419         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 420         core_msg = Lit (mkStringLit full_msg)
 421         -- mkStringLit returns a result of type String#
 422     in
 423     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 424 \end{code}
 425
 426
 427 *************************************************************
 428 %*                                                                      *
 429 \subsection{Making literals}
 430 %*                                                                      *
 431 %************************************************************************
 432
 433 \begin{code}
 434 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 435 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 436 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 437 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 438 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 439
 440 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 441 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 442
 443 mkIntegerExpr i
 444   | inIntRange i        -- Small enough, so start from an Int
 445   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 446     returnDs (mkSmallIntegerLit integer_dc i)
 447
 448 -- Special case for integral literals with a large magnitude:
 449 -- They are transformed into an expression involving only smaller
 450 -- integral literals. This improves constant folding.
 451
 452   | otherwise           -- Big, so start from a string
 453   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 454     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 455     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 456     let
 457         lit i = mkSmallIntegerLit integer_dc i
 458         plus a b  = Var plus_id  `App` a `App` b
 459         times a b = Var times_id `App` a `App` b
 460
 461         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 462         horner :: Integer -> Integer -> CoreExpr
 463         horner b i | abs q <= 1 = if r == 0 || r == i
 464                                   then lit i
 465                                   else lit r `plus` lit (i-r)
 466                    | r == 0     =               horner b q `times` lit b
 467                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 468                    where
 469                      (q,r) = i `quotRem` b
 470
 471     in
 472     returnDs (horner tARGET_MAX_INT i)
 473
 474 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 475
 476 mkStringExpr str = mkStringExprFS (mkFastString str)
 477
 478 mkStringExprFS str
 479   | nullFS str
 480   = returnDs (mkNilExpr charTy)
 481
 482   | lengthFS str == 1
 483   = let
 484         the_char = mkCharExpr (headFS str)
 485     in
 486     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 487
 488   | all safeChar chars
 489   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 490     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 491
 492   | otherwise
 493   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 494     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 495
 496   where
 497     chars = unpackFS str
 498     safeChar c = ord c >= 1 && ord c <= 0x7F
 499 \end{code}
 500
 501
 502 %************************************************************************
 503 %*                                                                      *
 504 \subsection[mkSelectorBind]{Make a selector bind}
 505 %*                                                                      *
 506 %************************************************************************
 507
 508 This is used in various places to do with lazy patterns.
 509 For each binder $b$ in the pattern, we create a binding:
 510 \begin{verbatim}
 511     b = case v of pat' -> b'
 512 \end{verbatim}
 513 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 514
 515 ToDo: making these bindings should really depend on whether there's
 516 much work to be done per binding.  If the pattern is complex, it
 517 should be de-mangled once, into a tuple (and then selected from).
 518 Otherwise the demangling can be in-line in the bindings (as here).
 519
 520 Boring!  Boring!  One error message per binder.  The above ToDo is
 521 even more helpful.  Something very similar happens for pattern-bound
 522 expressions.
 523
 524 \begin{code}
 525 mkSelectorBinds :: LPat Id      -- The pattern
 526                 -> CoreExpr     -- Expression to which the pattern is bound
 527                 -> DsM [(Id,CoreExpr)]
 528
 529 mkSelectorBinds (L _ (VarPat v)) val_expr
 530   = returnDs [(v, val_expr)]
 531
 532 mkSelectorBinds pat val_expr
 533   | isSingleton binders || is_simple_lpat pat
 534   =     -- Given   p = e, where p binds x,y
 535         -- we are going to make
 536         --      v = p   (where v is fresh)
 537         --      x = case v of p -> x
 538         --      y = case v of p -> x
 539
 540         -- Make up 'v'
 541         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 542         -- This does not matter after desugaring, but there's a subtle
 543         -- issue with implicit parameters. Consider
 544         --      (x,y) = ?i
 545         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 546         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 547         -- does it get that type?  So that when we abstract over it we get the
 548         -- right top-level type  (?i::Int) => ...)
 549         --
 550         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 551         -- efficient too.
 552     newSysLocalDs (hsLPatType pat)      `thenDs` \ val_var ->
 553
 554         -- For the error message we make one error-app, to avoid duplication.
 555         -- But we need it at different types... so we use coerce for that
 556     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 557                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 558     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 559     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 560     returnDs ( (val_var, val_expr) :
 561                (err_var, err_expr) :
 562                binds )
 563
 564
 565   | otherwise
 566   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 567                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 568     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 569     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 570     let
 571         mk_tup_bind binder
 572           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 573     in
 574     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 575   where
 576     binders     = collectPatBinders pat
 577     local_tuple = mkTupleExpr binders
 578     tuple_ty    = exprType local_tuple
 579
 580     mk_bind scrut_var err_var bndr_var
 581     -- (mk_bind sv err_var) generates
 582     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 583     -- Remember, pat binds bv
 584       = matchSimply (Var scrut_var) PatBindRhs pat
 585                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 586         returnDs (bndr_var, rhs_expr)
 587       where
 588         error_expr = mkCoerce co (Var err_var)
 589         co         = mkUnsafeCoercion (exprType (Var err_var)) (idType bndr_var)
 590
 591     is_simple_lpat p = is_simple_pat (unLoc p)
 592
 593     is_simple_pat (TuplePat ps Boxed _)        = all is_triv_lpat ps
 594     is_simple_pat (ConPatOut{ pat_args = ps }) = all is_triv_lpat (hsConArgs ps)
 595     is_simple_pat (VarPat _)                   = True
 596     is_simple_pat (ParPat p)                   = is_simple_lpat p
 597     is_simple_pat other                        = False
 598
 599     is_triv_lpat p = is_triv_pat (unLoc p)
 600
 601     is_triv_pat (VarPat v)  = True
 602     is_triv_pat (WildPat _) = True
 603     is_triv_pat (ParPat p)  = is_triv_lpat p
 604     is_triv_pat other       = False
 605 \end{code}
 606
 607
 608 %************************************************************************
 609 %*                                                                      *
 610                 Tuples
 611 %*                                                                      *
 612 %************************************************************************
 613
 614 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 615
 616 * If it has only one element, it is the identity function.
 617
 618 * If there are more elements than a big tuple can have, it nests
 619   the tuples.
 620
 621 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 622 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 623
 624 \begin{code}
 625 mkTupleExpr :: [Id] -> CoreExpr
 626 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 627
 628 -- corresponding type
 629 mkTupleType :: [Id] -> Type
 630 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 631
 632 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 633 mkBigCoreTup = mkBigTuple mkCoreTup
 634
 635 mkBigTuple :: ([a] -> a) -> [a] -> a
 636 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 637   where
 638         -- Each sub-list is short enough to fit in a tuple
 639     mk_big_tuple [as] = small_tuple as
 640     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 641
 642 chunkify :: [a] -> [[a]]
 643 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 644 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 645 chunkify xs
 646   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 647   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 648   where
 649     n_xs     = length xs
 650     split [] = []
 651     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 652 \end{code}
 653
 654
 655 @mkTupleSelector@ builds a selector which scrutises the given
 656 expression and extracts the one name from the list given.
 657 If you want the no-shadowing rule to apply, the caller
 658 is responsible for making sure that none of these names
 659 are in scope.
 660
 661 If there is just one id in the ``tuple'', then the selector is
 662 just the identity.
 663
 664 If it's big, it does nesting
 665         mkTupleSelector [a,b,c,d] b v e
 666           = case e of v {
 667                 (p,q) -> case p of p {
 668                            (a,b) -> b }}
 669 We use 'tpl' vars for the p,q, since shadowing does not matter.
 670
 671 In fact, it's more convenient to generate it innermost first, getting
 672
 673         case (case e of v
 674                 (p,q) -> p) of p
 675           (a,b) -> b
 676
 677 \begin{code}
 678 mkTupleSelector :: [Id]         -- The tuple args
 679                 -> Id           -- The selected one
 680                 -> Id           -- A variable of the same type as the scrutinee
 681                 -> CoreExpr     -- Scrutinee
 682                 -> CoreExpr
 683
 684 mkTupleSelector vars the_var scrut_var scrut
 685   = mk_tup_sel (chunkify vars) the_var
 686   where
 687     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 688     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 689                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 690         where
 691           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 692           tpl_vs  = mkTemplateLocals tpl_tys
 693           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 694                                          the_var `elem` gp ]
 695 \end{code}
 696
 697 A generalization of @mkTupleSelector@, allowing the body
 698 of the case to be an arbitrary expression.
 699
 700 If the tuple is big, it is nested:
 701
 702         mkTupleCase uniqs [a,b,c,d] body v e
 703           = case e of v { (p,q) ->
 704             case p of p { (a,b) ->
 705             case q of q { (c,d) ->
 706             body }}}
 707
 708 To avoid shadowing, we use uniqs to invent new variables p,q.
 709
 710 ToDo: eliminate cases where none of the variables are needed.
 711
 712 \begin{code}
 713 mkTupleCase
 714         :: UniqSupply   -- for inventing names of intermediate variables
 715         -> [Id]         -- the tuple args
 716         -> CoreExpr     -- body of the case
 717         -> Id           -- a variable of the same type as the scrutinee
 718         -> CoreExpr     -- scrutinee
 719         -> CoreExpr
 720
 721 mkTupleCase uniqs vars body scrut_var scrut
 722   = mk_tuple_case uniqs (chunkify vars) body
 723   where
 724     mk_tuple_case us [vars] body
 725       = mkSmallTupleCase vars body scrut_var scrut
 726     mk_tuple_case us vars_s body
 727       = let
 728             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 729         in
 730         mk_tuple_case us' (chunkify vars') body'
 731     one_tuple_case chunk_vars (us, vs, body)
 732       = let
 733             (us1, us2) = splitUniqSupply us
 734             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 735                         (mkCoreTupTy (map idType chunk_vars))
 736             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 737         in (us2, scrut_var:vs, body')
 738 \end{code}
 739
 740 The same, but with a tuple small enough not to need nesting.
 741
 742 \begin{code}
 743 mkSmallTupleCase
 744         :: [Id]         -- the tuple args
 745         -> CoreExpr     -- body of the case
 746         -> Id           -- a variable of the same type as the scrutinee
 747         -> CoreExpr     -- scrutinee
 748         -> CoreExpr
 749
 750 mkSmallTupleCase [var] body _scrut_var scrut
 751   = bindNonRec var scrut body
 752 mkSmallTupleCase vars body scrut_var scrut
 753 -- One branch no refinement?
 754   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 755 \end{code}
 756
 757 %************************************************************************
 758 %*                                                                      *
 759 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 760 %*                                                                      *
 761 %************************************************************************
 762
 763 Call the constructor Ids when building explicit lists, so that they
 764 interact well with rules.
 765
 766 \begin{code}
 767 mkNilExpr :: Type -> CoreExpr
 768 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 769
 770 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 771 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 772
 773 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 774 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 775
 776
 777 -- The next three functions make tuple types, constructors and selectors,
 778 -- with the rule that a 1-tuple is represented by the thing itselg
 779 mkCoreTupTy :: [Type] -> Type
 780 mkCoreTupTy [ty] = ty
 781 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 782
 783 mkCoreTup :: [CoreExpr] -> CoreExpr
 784 -- Builds exactly the specified tuple.
 785 -- No fancy business for big tuples
 786 mkCoreTup []  = Var unitDataConId
 787 mkCoreTup [c] = c
 788 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 789                          (map (Type . exprType) cs ++ cs)
 790
 791 mkCoreSel :: [Id]       -- The tuple args
 792           -> Id         -- The selected one
 793           -> Id         -- A variable of the same type as the scrutinee
 794           -> CoreExpr   -- Scrutinee
 795           -> CoreExpr
 796 -- mkCoreSel [x,y,z] x v e
 797 -- ===>  case e of v { (x,y,z) -> x
 798 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 799   = ASSERT(var == should_be_the_same_var)
 800     scrut
 801
 802 mkCoreSel vars the_var scrut_var scrut
 803   = ASSERT( notNull vars )
 804     Case scrut scrut_var (idType the_var)
 805          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 806 \end{code}
 807
 808
 809 %************************************************************************
 810 %*                                                                      *
 811 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 812 %*                                                                      *
 813 %************************************************************************
 814
 815 Generally, we handle pattern matching failure like this: let-bind a
 816 fail-variable, and use that variable if the thing fails:
 817 \begin{verbatim}
 818         let fail.33 = error "Help"
 819         in
 820         case x of
 821                 p1 -> ...
 822                 p2 -> fail.33
 823                 p3 -> fail.33
 824                 p4 -> ...
 825 \end{verbatim}
 826 Then
 827 \begin{itemize}
 828 \item
 829 If the case can't fail, then there'll be no mention of @fail.33@, and the
 830 simplifier will later discard it.
 831
 832 \item
 833 If it can fail in only one way, then the simplifier will inline it.
 834
 835 \item
 836 Only if it is used more than once will the let-binding remain.
 837 \end{itemize}
 838
 839 There's a problem when the result of the case expression is of
 840 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 841 there is every chance that someone will change the let into a case:
 842 \begin{verbatim}
 843         case error "Help" of
 844           fail.33 -> case ....
 845 \end{verbatim}
 846
 847 which is of course utterly wrong.  Rather than drop the condition that
 848 only boxed types can be let-bound, we just turn the fail into a function
 849 for the primitive case:
 850 \begin{verbatim}
 851         let fail.33 :: Void -> Int#
 852             fail.33 = \_ -> error "Help"
 853         in
 854         case x of
 855                 p1 -> ...
 856                 p2 -> fail.33 void
 857                 p3 -> fail.33 void
 858                 p4 -> ...
 859 \end{verbatim}
 860
 861 Now @fail.33@ is a function, so it can be let-bound.
 862
 863 \begin{code}
 864 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 865               -> DsM (CoreBind, -- Binds the newly-created fail variable
 866                                 -- to either the expression or \ _ -> expression
 867                       CoreExpr) -- Either the fail variable, or fail variable
 868                                 -- applied to unit tuple
 869 mkFailurePair expr
 870   | isUnLiftedType ty
 871   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 872     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 873     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 874               App (Var fail_fun_var) (Var unitDataConId))
 875
 876   | otherwise
 877   = newFailLocalDs ty           `thenDs` \ fail_var ->
 878     returnDs (NonRec fail_var expr, Var fail_var)
 879   where
 880     ty = exprType expr
 881 \end{code}
 882
 883