compiler/deSugar/Match.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 The @match@ function
   7
   8 \begin{code}
   9 module Match ( match, matchEquations, matchWrapper, matchSimply, matchSinglePat ) where
  10
  11 #include "HsVersions.h"
  12
  13 import {-#SOURCE#-} DsExpr (dsLExpr)
  14
  15 import DynFlags
  16 import HsSyn
  17 import TcHsSyn
  18 import Check
  19 import CoreSyn
  20 import Literal
  21 import CoreUtils
  22 import MkCore
  23 import DsMonad
  24 import DsBinds
  25 import DsGRHSs
  26 import DsUtils
  27 import Id
  28 import DataCon
  29 import MatchCon
  30 import MatchLit
  31 import Type
  32 import TysWiredIn
  33 import ListSetOps
  34 import SrcLoc
  35 import Maybes
  36 import Util
  37 import Name
  38 import Outputable
  39 import FastString
  40
  41 import qualified Data.Map as Map
  42 \end{code}
  43
  44 This function is a wrapper of @match@, it must be called from all the parts where
  45 it was called match, but only substitutes the firs call, ....
  46 if the associated flags are declared, warnings will be issued.
  47 It can not be called matchWrapper because this name already exists :-(
  48
  49 JJCQ 30-Nov-1997
  50
  51 \begin{code}
  52 matchCheck ::  DsMatchContext
  53             -> [Id]             -- Vars rep'ing the exprs we're matching with
  54             -> Type             -- Type of the case expression
  55             -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
  56             -> DsM MatchResult  -- Desugared result!
  57
  58 matchCheck ctx vars ty qs = do
  59     dflags <- getDOptsDs
  60     matchCheck_really dflags ctx vars ty qs
  61
  62 matchCheck_really :: DynFlags
  63                   -> DsMatchContext
  64                   -> [Id]
  65                   -> Type
  66                   -> [EquationInfo]
  67                   -> DsM MatchResult
  68 matchCheck_really dflags ctx vars ty qs
  69   | incomplete && shadow  = do
  70       dsShadowWarn ctx eqns_shadow
  71       dsIncompleteWarn ctx pats
  72       match vars ty qs
  73   | incomplete            = do
  74       dsIncompleteWarn ctx pats
  75       match vars ty qs
  76   | shadow                = do
  77       dsShadowWarn ctx eqns_shadow
  78       match vars ty qs
  79   | otherwise             =
  80       match vars ty qs
  81   where (pats, eqns_shadow) = check qs
  82         incomplete    = want_incomplete && (notNull pats)
  83         want_incomplete = case ctx of
  84                               DsMatchContext RecUpd _ ->
  85                                   dopt Opt_WarnIncompletePatternsRecUpd dflags
  86                               _ ->
  87                                   dopt Opt_WarnIncompletePatterns       dflags
  88         shadow        = dopt Opt_WarnOverlappingPatterns dflags
  89                         && not (null eqns_shadow)
  90 \end{code}
  91
  92 This variable shows the maximum number of lines of output generated for warnings.
  93 It will limit the number of patterns/equations displayed to@ maximum_output@.
  94
  95 (ToDo: add command-line option?)
  96
  97 \begin{code}
  98 maximum_output :: Int
  99 maximum_output = 4
 100 \end{code}
 101
 102 The next two functions create the warning message.
 103
 104 \begin{code}
 105 dsShadowWarn :: DsMatchContext -> [EquationInfo] -> DsM ()
 106 dsShadowWarn ctx@(DsMatchContext kind loc) qs
 107   = putSrcSpanDs loc (warnDs warn)
 108   where
 109     warn | qs `lengthExceeds` maximum_output
 110          = pp_context ctx (ptext (sLit "are overlapped"))
 111                       (\ f -> vcat (map (ppr_eqn f kind) (take maximum_output qs)) $$
 112                       ptext (sLit "..."))
 113          | otherwise
 114          = pp_context ctx (ptext (sLit "are overlapped"))
 115                       (\ f -> vcat $ map (ppr_eqn f kind) qs)
 116
 117
 118 dsIncompleteWarn :: DsMatchContext -> [ExhaustivePat] -> DsM ()
 119 dsIncompleteWarn ctx@(DsMatchContext kind loc) pats
 120   = putSrcSpanDs loc (warnDs warn)
 121         where
 122           warn = pp_context ctx (ptext (sLit "are non-exhaustive"))
 123                             (\_ -> hang (ptext (sLit "Patterns not matched:"))
 124                                    4 ((vcat $ map (ppr_incomplete_pats kind)
 125                                                   (take maximum_output pats))
 126                                       $$ dots))
 127
 128           dots | pats `lengthExceeds` maximum_output = ptext (sLit "...")
 129                | otherwise                           = empty
 130
 131 pp_context :: DsMatchContext -> SDoc -> ((SDoc -> SDoc) -> SDoc) -> SDoc
 132 pp_context (DsMatchContext kind _loc) msg rest_of_msg_fun
 133   = vcat [ptext (sLit "Pattern match(es)") <+> msg,
 134           sep [ptext (sLit "In") <+> ppr_match <> char ':', nest 4 (rest_of_msg_fun pref)]]
 135   where
 136     (ppr_match, pref)
 137         = case kind of
 138              FunRhs fun _ -> (pprMatchContext kind, \ pp -> ppr fun <+> pp)
 139              _            -> (pprMatchContext kind, \ pp -> pp)
 140
 141 ppr_pats :: Outputable a => [a] -> SDoc
 142 ppr_pats pats = sep (map ppr pats)
 143
 144 ppr_shadow_pats :: HsMatchContext Name -> [Pat Id] -> SDoc
 145 ppr_shadow_pats kind pats
 146   = sep [ppr_pats pats, matchSeparator kind, ptext (sLit "...")]
 147
 148 ppr_incomplete_pats :: HsMatchContext Name -> ExhaustivePat -> SDoc
 149 ppr_incomplete_pats _ (pats,[]) = ppr_pats pats
 150 ppr_incomplete_pats _ (pats,constraints) =
 151                          sep [ppr_pats pats, ptext (sLit "with"),
 152                               sep (map ppr_constraint constraints)]
 153
 154 ppr_constraint :: (Name,[HsLit]) -> SDoc
 155 ppr_constraint (var,pats) = sep [ppr var, ptext (sLit "`notElem`"), ppr pats]
 156
 157 ppr_eqn :: (SDoc -> SDoc) -> HsMatchContext Name -> EquationInfo -> SDoc
 158 ppr_eqn prefixF kind eqn = prefixF (ppr_shadow_pats kind (eqn_pats eqn))
 159 \end{code}
 160
 161
 162 %************************************************************************
 163 %*                                                                      *
 164                 The main matching function
 165 %*                                                                      *
 166 %************************************************************************
 167
 168 The function @match@ is basically the same as in the Wadler chapter,
 169 except it is monadised, to carry around the name supply, info about
 170 annotations, etc.
 171
 172 Notes on @match@'s arguments, assuming $m$ equations and $n$ patterns:
 173 \begin{enumerate}
 174 \item
 175 A list of $n$ variable names, those variables presumably bound to the
 176 $n$ expressions being matched against the $n$ patterns.  Using the
 177 list of $n$ expressions as the first argument showed no benefit and
 178 some inelegance.
 179
 180 \item
 181 The second argument, a list giving the ``equation info'' for each of
 182 the $m$ equations:
 183 \begin{itemize}
 184 \item
 185 the $n$ patterns for that equation, and
 186 \item
 187 a list of Core bindings [@(Id, CoreExpr)@ pairs] to be ``stuck on
 188 the front'' of the matching code, as in:
 189 \begin{verbatim}
 190 let <binds>
 191 in  <matching-code>
 192 \end{verbatim}
 193 \item
 194 and finally: (ToDo: fill in)
 195
 196 The right way to think about the ``after-match function'' is that it
 197 is an embryonic @CoreExpr@ with a ``hole'' at the end for the
 198 final ``else expression''.
 199 \end{itemize}
 200
 201 There is a type synonym, @EquationInfo@, defined in module @DsUtils@.
 202
 203 An experiment with re-ordering this information about equations (in
 204 particular, having the patterns available in column-major order)
 205 showed no benefit.
 206
 207 \item
 208 A default expression---what to evaluate if the overall pattern-match
 209 fails.  This expression will (almost?) always be
 210 a measly expression @Var@, unless we know it will only be used once
 211 (as we do in @glue_success_exprs@).
 212
 213 Leaving out this third argument to @match@ (and slamming in lots of
 214 @Var "fail"@s) is a positively {\em bad} idea, because it makes it
 215 impossible to share the default expressions.  (Also, it stands no
 216 chance of working in our post-upheaval world of @Locals@.)
 217 \end{enumerate}
 218
 219 Note: @match@ is often called via @matchWrapper@ (end of this module),
 220 a function that does much of the house-keeping that goes with a call
 221 to @match@.
 222
 223 It is also worth mentioning the {\em typical} way a block of equations
 224 is desugared with @match@.  At each stage, it is the first column of
 225 patterns that is examined.  The steps carried out are roughly:
 226 \begin{enumerate}
 227 \item
 228 Tidy the patterns in column~1 with @tidyEqnInfo@ (this may add
 229 bindings to the second component of the equation-info):
 230 \begin{itemize}
 231 \item
 232 Remove the `as' patterns from column~1.
 233 \item
 234 Make all constructor patterns in column~1 into @ConPats@, notably
 235 @ListPats@ and @TuplePats@.
 236 \item
 237 Handle any irrefutable (or ``twiddle'') @LazyPats@.
 238 \end{itemize}
 239 \item
 240 Now {\em unmix} the equations into {\em blocks} [w\/ local function
 241 @unmix_eqns@], in which the equations in a block all have variable
 242 patterns in column~1, or they all have constructor patterns in ...
 243 (see ``the mixture rule'' in SLPJ).
 244 \item
 245 Call @matchEqnBlock@ on each block of equations; it will do the
 246 appropriate thing for each kind of column-1 pattern, usually ending up
 247 in a recursive call to @match@.
 248 \end{enumerate}
 249
 250 We are a little more paranoid about the ``empty rule'' (SLPJ, p.~87)
 251 than the Wadler-chapter code for @match@ (p.~93, first @match@ clause).
 252 And gluing the ``success expressions'' together isn't quite so pretty.
 253
 254 This (more interesting) clause of @match@ uses @tidy_and_unmix_eqns@
 255 (a)~to get `as'- and `twiddle'-patterns out of the way (tidying), and
 256 (b)~to do ``the mixture rule'' (SLPJ, p.~88) [which really {\em
 257 un}mixes the equations], producing a list of equation-info
 258 blocks, each block having as its first column of patterns either all
 259 constructors, or all variables (or similar beasts), etc.
 260
 261 @match_unmixed_eqn_blks@ simply takes the place of the @foldr@ in the
 262 Wadler-chapter @match@ (p.~93, last clause), and @match_unmixed_blk@
 263 corresponds roughly to @matchVarCon@.
 264
 265 \begin{code}
 266 match :: [Id]             -- Variables rep\'ing the exprs we\'re matching with
 267       -> Type             -- Type of the case expression
 268       -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
 269       -> DsM MatchResult  -- Desugared result!
 270
 271 match [] ty eqns
 272   = ASSERT2( not (null eqns), ppr ty )
 273     return (foldr1 combineMatchResults match_results)
 274   where
 275     match_results = [ ASSERT( null (eqn_pats eqn) )
 276                       eqn_rhs eqn
 277                     | eqn <- eqns ]
 278
 279 match vars@(v:_) ty eqns
 280   = ASSERT( not (null eqns ) )
 281     do  {       -- Tidy the first pattern, generating
 282                 -- auxiliary bindings if necessary
 283           (aux_binds, tidy_eqns) <- mapAndUnzipM (tidyEqnInfo v) eqns
 284
 285                 -- Group the equations and match each group in turn
 286         ; let grouped = groupEquations tidy_eqns
 287
 288          -- print the view patterns that are commoned up to help debug
 289         ; ifDOptM Opt_D_dump_view_pattern_commoning (debug grouped)
 290
 291         ; match_results <- mapM match_group grouped
 292         ; return (adjustMatchResult (foldr1 (.) aux_binds) $
 293                   foldr1 combineMatchResults match_results) }
 294   where
 295     dropGroup :: [(PatGroup,EquationInfo)] -> [EquationInfo]
 296     dropGroup = map snd
 297
 298     match_group :: [(PatGroup,EquationInfo)] -> DsM MatchResult
 299     match_group [] = panic "match_group"
 300     match_group eqns@((group,_) : _)
 301         = case group of
 302             PgCon _    -> matchConFamily  vars ty (subGroup [(c,e) | (PgCon c, e) <- eqns])
 303             PgLit _    -> matchLiterals   vars ty (subGroup [(l,e) | (PgLit l, e) <- eqns])
 304             PgAny      -> matchVariables  vars ty (dropGroup eqns)
 305             PgN _      -> matchNPats      vars ty (dropGroup eqns)
 306             PgNpK _    -> matchNPlusKPats vars ty (dropGroup eqns)
 307             PgBang     -> matchBangs      vars ty (dropGroup eqns)
 308             PgCo _     -> matchCoercion   vars ty (dropGroup eqns)
 309             PgView _ _ -> matchView       vars ty (dropGroup eqns)
 310
 311     -- FIXME: we should also warn about view patterns that should be
 312     -- commoned up but are not
 313
 314     -- print some stuff to see what's getting grouped
 315     -- use -dppr-debug to see the resolution of overloaded lits
 316     debug eqns =
 317         let gs = map (\group -> foldr (\ (p,_) -> \acc ->
 318                                            case p of PgView e _ -> e:acc
 319                                                      _ -> acc) [] group) eqns
 320             maybeWarn [] = return ()
 321             maybeWarn l = warnDs (vcat l)
 322         in
 323           maybeWarn $ (map (\g -> text "Putting these view expressions into the same case:" <+> (ppr g))
 324                        (filter (not . null) gs))
 325
 326 matchVariables :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 327 -- Real true variables, just like in matchVar, SLPJ p 94
 328 -- No binding to do: they'll all be wildcards by now (done in tidy)
 329 matchVariables (_:vars) ty eqns = match vars ty (shiftEqns eqns)
 330 matchVariables [] _ _ = panic "matchVariables"
 331
 332 matchBangs :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 333 matchBangs (var:vars) ty eqns
 334   = do  { match_result <- match (var:vars) ty $
 335                           map (decomposeFirstPat getBangPat) eqns
 336         ; return (mkEvalMatchResult var ty match_result) }
 337 matchBangs [] _ _ = panic "matchBangs"
 338
 339 matchCoercion :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 340 -- Apply the coercion to the match variable and then match that
 341 matchCoercion (var:vars) ty (eqns@(eqn1:_))
 342   = do  { let CoPat co pat _ = firstPat eqn1
 343         ; var' <- newUniqueId var (hsPatType pat)
 344         ; match_result <- match (var':vars) ty $
 345                           map (decomposeFirstPat getCoPat) eqns
 346         ; co' <- dsHsWrapper co
 347         ; let rhs' = co' (Var var)
 348         ; return (mkCoLetMatchResult (NonRec var' rhs') match_result) }
 349 matchCoercion _ _ _ = panic "matchCoercion"
 350
 351 matchView :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 352 -- Apply the view function to the match variable and then match that
 353 matchView (var:vars) ty (eqns@(eqn1:_))
 354   = do  { -- we could pass in the expr from the PgView,
 355          -- but this needs to extract the pat anyway
 356          -- to figure out the type of the fresh variable
 357          let ViewPat viewExpr (L _ pat) _ = firstPat eqn1
 358          -- do the rest of the compilation
 359         ; var' <- newUniqueId var (hsPatType pat)
 360         ; match_result <- match (var':vars) ty $
 361                           map (decomposeFirstPat getViewPat) eqns
 362          -- compile the view expressions
 363         ; viewExpr' <- dsLExpr viewExpr
 364         ; return (mkViewMatchResult var' viewExpr' var match_result) }
 365 matchView _ _ _ = panic "matchView"
 366
 367 -- decompose the first pattern and leave the rest alone
 368 decomposeFirstPat :: (Pat Id -> Pat Id) -> EquationInfo -> EquationInfo
 369 decomposeFirstPat extractpat (eqn@(EqnInfo { eqn_pats = pat : pats }))
 370         = eqn { eqn_pats = extractpat pat : pats}
 371 decomposeFirstPat _ _ = panic "decomposeFirstPat"
 372
 373 getCoPat, getBangPat, getViewPat :: Pat Id -> Pat Id
 374 getCoPat (CoPat _ pat _)     = pat
 375 getCoPat _                   = panic "getCoPat"
 376 getBangPat (BangPat pat  )   = unLoc pat
 377 getBangPat _                 = panic "getBangPat"
 378 getViewPat (ViewPat _ pat _) = unLoc pat
 379 getViewPat _                 = panic "getBangPat"
 380 \end{code}
 381
 382 %************************************************************************
 383 %*                                                                      *
 384                 Tidying patterns
 385 %*                                                                      *
 386 %************************************************************************
 387
 388 Tidy up the leftmost pattern in an @EquationInfo@, given the variable @v@
 389 which will be scrutinised.  This means:
 390 \begin{itemize}
 391 \item
 392 Replace variable patterns @x@ (@x /= v@) with the pattern @_@,
 393 together with the binding @x = v@.
 394 \item
 395 Replace the `as' pattern @x@@p@ with the pattern p and a binding @x = v@.
 396 \item
 397 Removing lazy (irrefutable) patterns (you don't want to know...).
 398 \item
 399 Converting explicit tuple-, list-, and parallel-array-pats into ordinary
 400 @ConPats@.
 401 \item
 402 Convert the literal pat "" to [].
 403 \end{itemize}
 404
 405 The result of this tidying is that the column of patterns will include
 406 {\em only}:
 407 \begin{description}
 408 \item[@WildPats@:]
 409 The @VarPat@ information isn't needed any more after this.
 410
 411 \item[@ConPats@:]
 412 @ListPats@, @TuplePats@, etc., are all converted into @ConPats@.
 413
 414 \item[@LitPats@ and @NPats@:]
 415 @LitPats@/@NPats@ of ``known friendly types'' (Int, Char,
 416 Float,  Double, at least) are converted to unboxed form; e.g.,
 417 \tr{(NPat (HsInt i) _ _)} is converted to:
 418 \begin{verbatim}
 419 (ConPat I# _ _ [LitPat (HsIntPrim i)])
 420 \end{verbatim}
 421 \end{description}
 422
 423 \begin{code}
 424 tidyEqnInfo :: Id -> EquationInfo
 425             -> DsM (DsWrapper, EquationInfo)
 426         -- DsM'd because of internal call to dsLHsBinds
 427         --      and mkSelectorBinds.
 428         -- "tidy1" does the interesting stuff, looking at
 429         -- one pattern and fiddling the list of bindings.
 430         --
 431         -- POST CONDITION: head pattern in the EqnInfo is
 432         --      WildPat
 433         --      ConPat
 434         --      NPat
 435         --      LitPat
 436         --      NPlusKPat
 437         -- but no other
 438
 439 tidyEqnInfo _ (EqnInfo { eqn_pats = [] })
 440   = panic "tidyEqnInfo"
 441
 442 tidyEqnInfo v eqn@(EqnInfo { eqn_pats = pat : pats })
 443   = do { (wrap, pat') <- tidy1 v pat
 444        ; return (wrap, eqn { eqn_pats = do pat' : pats }) }
 445
 446 tidy1 :: Id                     -- The Id being scrutinised
 447       -> Pat Id                 -- The pattern against which it is to be matched
 448       -> DsM (DsWrapper,        -- Extra bindings to do before the match
 449               Pat Id)           -- Equivalent pattern
 450
 451 -------------------------------------------------------
 452 --      (pat', mr') = tidy1 v pat mr
 453 -- tidies the *outer level only* of pat, giving pat'
 454 -- It eliminates many pattern forms (as-patterns, variable patterns,
 455 -- list patterns, etc) yielding one of:
 456 --      WildPat
 457 --      ConPatOut
 458 --      LitPat
 459 --      NPat
 460 --      NPlusKPat
 461
 462 tidy1 v (ParPat pat)      = tidy1 v (unLoc pat)
 463 tidy1 v (SigPatOut pat _) = tidy1 v (unLoc pat)
 464 tidy1 _ (WildPat ty)      = return (idDsWrapper, WildPat ty)
 465
 466         -- case v of { x -> mr[] }
 467         -- = case v of { _ -> let x=v in mr[] }
 468 tidy1 v (VarPat var)
 469   = return (wrapBind var v, WildPat (idType var))
 470
 471         -- case v of { x@p -> mr[] }
 472         -- = case v of { p -> let x=v in mr[] }
 473 tidy1 v (AsPat (L _ var) pat)
 474   = do  { (wrap, pat') <- tidy1 v (unLoc pat)
 475         ; return (wrapBind var v . wrap, pat') }
 476
 477 {- now, here we handle lazy patterns:
 478     tidy1 v ~p bs = (v, v1 = case v of p -> v1 :
 479                         v2 = case v of p -> v2 : ... : bs )
 480
 481     where the v_i's are the binders in the pattern.
 482
 483     ToDo: in "v_i = ... -> v_i", are the v_i's really the same thing?
 484
 485     The case expr for v_i is just: match [v] [(p, [], \ x -> Var v_i)] any_expr
 486 -}
 487
 488 tidy1 v (LazyPat pat)
 489   = do  { sel_prs <- mkSelectorBinds pat (Var v)
 490         ; let sel_binds =  [NonRec b rhs | (b,rhs) <- sel_prs]
 491         ; return (mkCoreLets sel_binds, WildPat (idType v)) }
 492
 493 tidy1 _ (ListPat pats ty)
 494   = return (idDsWrapper, unLoc list_ConPat)
 495   where
 496     list_ty     = mkListTy ty
 497     list_ConPat = foldr (\ x y -> mkPrefixConPat consDataCon [x, y] list_ty)
 498                         (mkNilPat list_ty)
 499                         pats
 500
 501 -- Introduce fake parallel array constructors to be able to handle parallel
 502 -- arrays with the existing machinery for constructor pattern
 503 tidy1 _ (PArrPat pats ty)
 504   = return (idDsWrapper, unLoc parrConPat)
 505   where
 506     arity      = length pats
 507     parrConPat = mkPrefixConPat (parrFakeCon arity) pats (mkPArrTy ty)
 508
 509 tidy1 _ (TuplePat pats boxity ty)
 510   = return (idDsWrapper, unLoc tuple_ConPat)
 511   where
 512     arity = length pats
 513     tuple_ConPat = mkPrefixConPat (tupleCon boxity arity) pats ty
 514
 515 -- LitPats: we *might* be able to replace these w/ a simpler form
 516 tidy1 _ (LitPat lit)
 517   = return (idDsWrapper, tidyLitPat lit)
 518
 519 -- NPats: we *might* be able to replace these w/ a simpler form
 520 tidy1 _ (NPat lit mb_neg eq)
 521   = return (idDsWrapper, tidyNPat lit mb_neg eq)
 522
 523 -- BangPatterns: Pattern matching is already strict in constructors,
 524 -- tuples etc, so the last case strips off the bang for thoses patterns.
 525 tidy1 v (BangPat (L _ (LazyPat p)))       = tidy1 v (BangPat p)
 526 tidy1 v (BangPat (L _ (ParPat p)))        = tidy1 v (BangPat p)
 527 tidy1 _ p@(BangPat (L _(VarPat _)))       = return (idDsWrapper, p)
 528 tidy1 _ p@(BangPat (L _ (WildPat _)))     = return (idDsWrapper, p)
 529 tidy1 _ p@(BangPat (L _ (CoPat _ _ _)))   = return (idDsWrapper, p)
 530 tidy1 _ p@(BangPat (L _ (SigPatIn _ _)))  = return (idDsWrapper, p)
 531 tidy1 _ p@(BangPat (L _ (SigPatOut _ _))) = return (idDsWrapper, p)
 532 tidy1 v (BangPat (L _ (AsPat (L _ var) pat)))
 533   = do  { (wrap, pat') <- tidy1 v (BangPat pat)
 534         ; return (wrapBind var v . wrap, pat') }
 535 tidy1 v (BangPat (L _ p))                   = tidy1 v p
 536
 537 -- Everything else goes through unchanged...
 538
 539 tidy1 _ non_interesting_pat
 540   = return (idDsWrapper, non_interesting_pat)
 541 \end{code}
 542
 543 \noindent
 544 {\bf Previous @matchTwiddled@ stuff:}
 545
 546 Now we get to the only interesting part; note: there are choices for
 547 translation [from Simon's notes]; translation~1:
 548 \begin{verbatim}
 549 deTwiddle [s,t] e
 550 \end{verbatim}
 551 returns
 552 \begin{verbatim}
 553 [ w = e,
 554   s = case w of [s,t] -> s
 555   t = case w of [s,t] -> t
 556 ]
 557 \end{verbatim}
 558
 559 Here \tr{w} is a fresh variable, and the \tr{w}-binding prevents multiple
 560 evaluation of \tr{e}.  An alternative translation (No.~2):
 561 \begin{verbatim}
 562 [ w = case e of [s,t] -> (s,t)
 563   s = case w of (s,t) -> s
 564   t = case w of (s,t) -> t
 565 ]
 566 \end{verbatim}
 567
 568 %************************************************************************
 569 %*                                                                      *
 570 \subsubsection[improved-unmixing]{UNIMPLEMENTED idea for improved unmixing}
 571 %*                                                                      *
 572 %************************************************************************
 573
 574 We might be able to optimise unmixing when confronted by
 575 only-one-constructor-possible, of which tuples are the most notable
 576 examples.  Consider:
 577 \begin{verbatim}
 578 f (a,b,c) ... = ...
 579 f d ... (e:f) = ...
 580 f (g,h,i) ... = ...
 581 f j ...       = ...
 582 \end{verbatim}
 583 This definition would normally be unmixed into four equation blocks,
 584 one per equation.  But it could be unmixed into just one equation
 585 block, because if the one equation matches (on the first column),
 586 the others certainly will.
 587
 588 You have to be careful, though; the example
 589 \begin{verbatim}
 590 f j ...       = ...
 591 -------------------
 592 f (a,b,c) ... = ...
 593 f d ... (e:f) = ...
 594 f (g,h,i) ... = ...
 595 \end{verbatim}
 596 {\em must} be broken into two blocks at the line shown; otherwise, you
 597 are forcing unnecessary evaluation.  In any case, the top-left pattern
 598 always gives the cue.  You could then unmix blocks into groups of...
 599 \begin{description}
 600 \item[all variables:]
 601 As it is now.
 602 \item[constructors or variables (mixed):]
 603 Need to make sure the right names get bound for the variable patterns.
 604 \item[literals or variables (mixed):]
 605 Presumably just a variant on the constructor case (as it is now).
 606 \end{description}
 607
 608 %************************************************************************
 609 %*                                                                      *
 610 %*  matchWrapper: a convenient way to call @match@                      *
 611 %*                                                                      *
 612 %************************************************************************
 613 \subsection[matchWrapper]{@matchWrapper@: a convenient interface to @match@}
 614
 615 Calls to @match@ often involve similar (non-trivial) work; that work
 616 is collected here, in @matchWrapper@.  This function takes as
 617 arguments:
 618 \begin{itemize}
 619 \item
 620 Typchecked @Matches@ (of a function definition, or a case or lambda
 621 expression)---the main input;
 622 \item
 623 An error message to be inserted into any (runtime) pattern-matching
 624 failure messages.
 625 \end{itemize}
 626
 627 As results, @matchWrapper@ produces:
 628 \begin{itemize}
 629 \item
 630 A list of variables (@Locals@) that the caller must ``promise'' to
 631 bind to appropriate values; and
 632 \item
 633 a @CoreExpr@, the desugared output (main result).
 634 \end{itemize}
 635
 636 The main actions of @matchWrapper@ include:
 637 \begin{enumerate}
 638 \item
 639 Flatten the @[TypecheckedMatch]@ into a suitable list of
 640 @EquationInfo@s.
 641 \item
 642 Create as many new variables as there are patterns in a pattern-list
 643 (in any one of the @EquationInfo@s).
 644 \item
 645 Create a suitable ``if it fails'' expression---a call to @error@ using
 646 the error-string input; the {\em type} of this fail value can be found
 647 by examining one of the RHS expressions in one of the @EquationInfo@s.
 648 \item
 649 Call @match@ with all of this information!
 650 \end{enumerate}
 651
 652 \begin{code}
 653 matchWrapper :: HsMatchContext Name     -- For shadowing warning messages
 654              -> MatchGroup Id           -- Matches being desugared
 655              -> DsM ([Id], CoreExpr)    -- Results
 656 \end{code}
 657
 658  There is one small problem with the Lambda Patterns, when somebody
 659  writes something similar to:
 660 \begin{verbatim}
 661     (\ (x:xs) -> ...)
 662 \end{verbatim}
 663  he/she don't want a warning about incomplete patterns, that is done with
 664  the flag @opt_WarnSimplePatterns@.
 665  This problem also appears in the:
 666 \begin{itemize}
 667 \item @do@ patterns, but if the @do@ can fail
 668       it creates another equation if the match can fail
 669       (see @DsExpr.doDo@ function)
 670 \item @let@ patterns, are treated by @matchSimply@
 671    List Comprension Patterns, are treated by @matchSimply@ also
 672 \end{itemize}
 673
 674 We can't call @matchSimply@ with Lambda patterns,
 675 due to the fact that lambda patterns can have more than
 676 one pattern, and match simply only accepts one pattern.
 677
 678 JJQC 30-Nov-1997
 679
 680 \begin{code}
 681 matchWrapper ctxt (MatchGroup matches match_ty)
 682   = ASSERT( notNull matches )
 683     do  { eqns_info   <- mapM mk_eqn_info matches
 684         ; new_vars    <- selectMatchVars arg_pats
 685         ; result_expr <- matchEquations ctxt new_vars eqns_info rhs_ty
 686         ; return (new_vars, result_expr) }
 687   where
 688     arg_pats    = map unLoc (hsLMatchPats (head matches))
 689     n_pats      = length arg_pats
 690     (_, rhs_ty) = splitFunTysN n_pats match_ty
 691
 692     mk_eqn_info (L _ (Match pats _ grhss))
 693       = do { let upats = map unLoc pats
 694            ; match_result <- dsGRHSs ctxt upats grhss rhs_ty
 695            ; return (EqnInfo { eqn_pats = upats, eqn_rhs  = match_result}) }
 696
 697
 698 matchEquations  :: HsMatchContext Name
 699                 -> [Id] -> [EquationInfo] -> Type
 700                 -> DsM CoreExpr
 701 matchEquations ctxt vars eqns_info rhs_ty
 702   = do  { locn <- getSrcSpanDs
 703         ; let   ds_ctxt   = DsMatchContext ctxt locn
 704                 error_doc = matchContextErrString ctxt
 705
 706         ; match_result <- matchCheck ds_ctxt vars rhs_ty eqns_info
 707
 708         ; fail_expr <- mkErrorAppDs pAT_ERROR_ID rhs_ty error_doc
 709         ; extractMatchResult match_result fail_expr }
 710 \end{code}
 711
 712 %************************************************************************
 713 %*                                                                      *
 714 \subsection[matchSimply]{@matchSimply@: match a single expression against a single pattern}
 715 %*                                                                      *
 716 %************************************************************************
 717
 718 @mkSimpleMatch@ is a wrapper for @match@ which deals with the
 719 situation where we want to match a single expression against a single
 720 pattern. It returns an expression.
 721
 722 \begin{code}
 723 matchSimply :: CoreExpr                 -- Scrutinee
 724             -> HsMatchContext Name      -- Match kind
 725             -> LPat Id                  -- Pattern it should match
 726             -> CoreExpr                 -- Return this if it matches
 727             -> CoreExpr                 -- Return this if it doesn't
 728             -> DsM CoreExpr
 729 -- Do not warn about incomplete patterns; see matchSinglePat comments
 730 matchSimply scrut hs_ctx pat result_expr fail_expr = do
 731     let
 732       match_result = cantFailMatchResult result_expr
 733       rhs_ty       = exprType fail_expr
 734         -- Use exprType of fail_expr, because won't refine in the case of failure!
 735     match_result' <- matchSinglePat scrut hs_ctx pat rhs_ty match_result
 736     extractMatchResult match_result' fail_expr
 737
 738
 739 matchSinglePat :: CoreExpr -> HsMatchContext Name -> LPat Id
 740                -> Type -> MatchResult -> DsM MatchResult
 741 -- Do not warn about incomplete patterns
 742 -- Used for things like [ e | pat <- stuff ], where
 743 -- incomplete patterns are just fine
 744 matchSinglePat (Var var) _ (L _ pat) ty match_result
 745   = match [var] ty [EqnInfo { eqn_pats = [pat], eqn_rhs  = match_result }]
 746
 747 matchSinglePat scrut hs_ctx pat ty match_result = do
 748     var <- selectSimpleMatchVarL pat
 749     match_result' <- matchSinglePat (Var var) hs_ctx pat ty match_result
 750     return (adjustMatchResult (bindNonRec var scrut) match_result')
 751 \end{code}
 752
 753
 754 %************************************************************************
 755 %*                                                                      *
 756                 Pattern classification
 757 %*                                                                      *
 758 %************************************************************************
 759
 760 \begin{code}
 761 data PatGroup
 762   = PgAny               -- Immediate match: variables, wildcards,
 763                         --                  lazy patterns
 764   | PgCon DataCon       -- Constructor patterns (incl list, tuple)
 765   | PgLit Literal       -- Literal patterns
 766   | PgN   Literal       -- Overloaded literals
 767   | PgNpK Literal       -- n+k patterns
 768   | PgBang              -- Bang patterns
 769   | PgCo Type           -- Coercion patterns; the type is the type
 770                         --      of the pattern *inside*
 771   | PgView (LHsExpr Id) -- view pattern (e -> p):
 772                         -- the LHsExpr is the expression e
 773            Type         -- the Type is the type of p (equivalently, the result type of e)
 774
 775 groupEquations :: [EquationInfo] -> [[(PatGroup, EquationInfo)]]
 776 -- If the result is of form [g1, g2, g3],
 777 -- (a) all the (pg,eq) pairs in g1 have the same pg
 778 -- (b) none of the gi are empty
 779 -- The ordering of equations is unchanged
 780 groupEquations eqns
 781   = runs same_gp [(patGroup (firstPat eqn), eqn) | eqn <- eqns]
 782   where
 783     same_gp :: (PatGroup,EquationInfo) -> (PatGroup,EquationInfo) -> Bool
 784     (pg1,_) `same_gp` (pg2,_) = pg1 `sameGroup` pg2
 785
 786 subGroup :: Ord a => [(a, EquationInfo)] -> [[EquationInfo]]
 787 -- Input is a particular group.  The result sub-groups the
 788 -- equations by with particular constructor, literal etc they match.
 789 -- Each sub-list in the result has the same PatGroup
 790 -- See Note [Take care with pattern order]
 791 subGroup group
 792     = map reverse $ Map.elems $ foldl accumulate Map.empty group
 793   where
 794     accumulate pg_map (pg, eqn)
 795       = case Map.lookup pg pg_map of
 796           Just eqns -> Map.insert pg (eqn:eqns) pg_map
 797           Nothing   -> Map.insert pg [eqn]      pg_map
 798
 799     -- pg_map :: Map a [EquationInfo]
 800     -- Equations seen so far in reverse order of appearance
 801 \end{code}
 802
 803 Note [Take care with pattern order]
 804 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 805 In the subGroup function we must be very careful about pattern re-ordering,
 806 Consider the patterns [ (True, Nothing), (False, x), (True, y) ]
 807 Then in bringing together the patterns for True, we must not
 808 swap the Nothing and y!
 809
 810
 811 \begin{code}
 812 sameGroup :: PatGroup -> PatGroup -> Bool
 813 -- Same group means that a single case expression
 814 -- or test will suffice to match both, *and* the order
 815 -- of testing within the group is insignificant.
 816 sameGroup PgAny      PgAny      = True
 817 sameGroup PgBang     PgBang     = True
 818 sameGroup (PgCon _)  (PgCon _)  = True          -- One case expression
 819 sameGroup (PgLit _)  (PgLit _)  = True          -- One case expression
 820 sameGroup (PgN l1)   (PgN l2)   = l1==l2        -- Order is significant
 821 sameGroup (PgNpK l1) (PgNpK l2) = l1==l2        -- See Note [Grouping overloaded literal patterns]
 822 sameGroup (PgCo t1)  (PgCo t2)  = t1 `coreEqType` t2
 823         -- CoPats are in the same goup only if the type of the
 824         -- enclosed pattern is the same. The patterns outside the CoPat
 825         -- always have the same type, so this boils down to saying that
 826         -- the two coercions are identical.
 827 sameGroup (PgView e1 t1) (PgView e2 t2) = viewLExprEq (e1,t1) (e2,t2)
 828        -- ViewPats are in the same gorup iff the expressions
 829        -- are "equal"---conservatively, we use syntactic equality
 830 sameGroup _          _          = False
 831
 832 -- An approximation of syntactic equality used for determining when view
 833 -- exprs are in the same group.
 834 -- This function can always safely return false;
 835 -- but doing so will result in the application of the view function being repeated.
 836 --
 837 -- Currently: compare applications of literals and variables
 838 --            and anything else that we can do without involving other
 839 --            HsSyn types in the recursion
 840 --
 841 -- NB we can't assume that the two view expressions have the same type.  Consider
 842 --   f (e1 -> True) = ...
 843 --   f (e2 -> "hi") = ...
 844 viewLExprEq :: (LHsExpr Id,Type) -> (LHsExpr Id,Type) -> Bool
 845 viewLExprEq (e1,_) (e2,_) = lexp e1 e2
 846   where
 847     lexp :: LHsExpr Id -> LHsExpr Id -> Bool
 848     lexp e e' = exp (unLoc e) (unLoc e')
 849
 850     ---------
 851     exp :: HsExpr Id -> HsExpr Id -> Bool
 852     -- real comparison is on HsExpr's
 853     -- strip parens
 854     exp (HsPar (L _ e)) e'   = exp e e'
 855     exp e (HsPar (L _ e'))   = exp e e'
 856     -- because the expressions do not necessarily have the same type,
 857     -- we have to compare the wrappers
 858     exp (HsWrap h e) (HsWrap h' e') = wrap h h' && exp e e'
 859     exp (HsVar i) (HsVar i') =  i == i'
 860     -- the instance for IPName derives using the id, so this works if the
 861     -- above does
 862     exp (HsIPVar i) (HsIPVar i') = i == i'
 863     exp (HsOverLit l) (HsOverLit l') =
 864         -- Overloaded lits are equal if they have the same type
 865         -- and the data is the same.
 866         -- this is coarser than comparing the SyntaxExpr's in l and l',
 867         -- which resolve the overloading (e.g., fromInteger 1),
 868         -- because these expressions get written as a bunch of different variables
 869         -- (presumably to improve sharing)
 870         tcEqType (overLitType l) (overLitType l') && l == l'
 871     exp (HsApp e1 e2) (HsApp e1' e2') = lexp e1 e1' && lexp e2 e2'
 872     -- the fixities have been straightened out by now, so it's safe
 873     -- to ignore them?
 874     exp (OpApp l o _ ri) (OpApp l' o' _ ri') =
 875         lexp l l' && lexp o o' && lexp ri ri'
 876     exp (NegApp e n) (NegApp e' n') = lexp e e' && exp n n'
 877     exp (SectionL e1 e2) (SectionL e1' e2') =
 878         lexp e1 e1' && lexp e2 e2'
 879     exp (SectionR e1 e2) (SectionR e1' e2') =
 880         lexp e1 e1' && lexp e2 e2'
 881     exp (ExplicitTuple es1 _) (ExplicitTuple es2 _) =
 882         eq_list tup_arg es1 es2
 883     exp (HsIf _ e e1 e2) (HsIf _ e' e1' e2') =
 884         lexp e e' && lexp e1 e1' && lexp e2 e2'
 885
 886     -- Enhancement: could implement equality for more expressions
 887     --   if it seems useful
 888     -- But no need for HsLit, ExplicitList, ExplicitTuple,
 889     -- because they cannot be functions
 890     exp _ _  = False
 891
 892     ---------
 893     tup_arg (Present e1) (Present e2) = lexp e1 e2
 894     tup_arg (Missing t1) (Missing t2) = tcEqType t1 t2
 895     tup_arg _ _ = False
 896
 897     ---------
 898     wrap :: HsWrapper -> HsWrapper -> Bool
 899     -- Conservative, in that it demands that wrappers be
 900     -- syntactically identical and doesn't look under binders
 901     --
 902     -- Coarser notions of equality are possible
 903     -- (e.g., reassociating compositions,
 904     --        equating different ways of writing a coercion)
 905     wrap WpHole WpHole = True
 906     wrap (WpCompose w1 w2) (WpCompose w1' w2') = wrap w1 w1' && wrap w2 w2'
 907     wrap (WpCast c)  (WpCast c')     = tcEqType c c'
 908     wrap (WpEvApp et1) (WpEvApp et2) = ev_term et1 et2
 909     wrap (WpTyApp t) (WpTyApp t')    = tcEqType t t'
 910     -- Enhancement: could implement equality for more wrappers
 911     --   if it seems useful (lams and lets)
 912     wrap _ _ = False
 913
 914     ---------
 915     ev_term :: EvTerm -> EvTerm -> Bool
 916     ev_term (EvId a)       (EvId b)       = a==b
 917     ev_term (EvCoercion a) (EvCoercion b) = tcEqType a b
 918     ev_term _ _ = False
 919
 920     ---------
 921     eq_list :: (a->a->Bool) -> [a] -> [a] -> Bool
 922     eq_list _  []     []     = True
 923     eq_list _  []     (_:_)  = False
 924     eq_list _  (_:_)  []     = False
 925     eq_list eq (x:xs) (y:ys) = eq x y && eq_list eq xs ys
 926
 927 patGroup :: Pat Id -> PatGroup
 928 patGroup (WildPat {})                 = PgAny
 929 patGroup (BangPat {})                 = PgBang
 930 patGroup (ConPatOut { pat_con = dc }) = PgCon (unLoc dc)
 931 patGroup (LitPat lit)                 = PgLit (hsLitKey lit)
 932 patGroup (NPat olit mb_neg _)         = PgN   (hsOverLitKey olit (isJust mb_neg))
 933 patGroup (NPlusKPat _ olit _ _)       = PgNpK (hsOverLitKey olit False)
 934 patGroup (CoPat _ p _)                = PgCo  (hsPatType p)     -- Type of innelexp pattern
 935 patGroup (ViewPat expr p _)               = PgView expr (hsPatType (unLoc p))
 936 patGroup pat = pprPanic "patGroup" (ppr pat)
 937 \end{code}
 938
 939 Note [Grouping overloaded literal patterns]
 940 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 941 WATCH OUT!  Consider
 942
 943         f (n+1) = ...
 944         f (n+2) = ...
 945         f (n+1) = ...
 946
 947 We can't group the first and third together, because the second may match
 948 the same thing as the first.  Same goes for *overloaded* literal patterns
 949         f 1 True = ...
 950         f 2 False = ...
 951         f 1 False = ...
 952 If the first arg matches '1' but the second does not match 'True', we
 953 cannot jump to the third equation!  Because the same argument might
 954 match '2'!
 955 Hence we don't regard 1 and 2, or (n+1) and (n+2), as part of the same group.