compiler/ghci/ObjLink.lhs

   1 %
   2 % (c) The University of Glasgow, 2000-2006
   3 %
   4
   5 -- ---------------------------------------------------------------------------
   6 --      The dynamic linker for object code (.o .so .dll files)
   7 -- ---------------------------------------------------------------------------
   8
   9 Primarily, this module consists of an interface to the C-land dynamic linker.
  10
  11 \begin{code}
  12 {-# OPTIONS -#include "Linker.h" #-}
  13
  14 module ObjLink (
  15    initObjLinker,        -- :: IO ()
  16    loadDLL,              -- :: String -> IO (Maybe String)
  17    loadObj,              -- :: String -> IO ()
  18    unloadObj,            -- :: String -> IO ()
  19    insertSymbol,         -- :: String -> String -> Ptr a -> IO ()
  20    lookupSymbol,         -- :: String -> IO (Maybe (Ptr a))
  21    resolveObjs           -- :: IO SuccessFlag
  22   )  where
  23
  24 import Panic            ( panic )
  25 import BasicTypes       ( SuccessFlag, successIf )
  26 import Config           ( cLeadingUnderscore )
  27 import Outputable
  28
  29 import Control.Monad    ( when )
  30 import Foreign.C
  31 import Foreign          ( nullPtr )
  32 import GHC.Exts         ( Ptr(..), unsafeCoerce# )
  33
  34 -- ---------------------------------------------------------------------------
  35 -- RTS Linker Interface
  36 -- ---------------------------------------------------------------------------
  37
  38 insertSymbol :: String -> String -> Ptr a -> IO ()
  39 insertSymbol obj_name key symbol
  40     = let str = prefixUnderscore key
  41       in withCString obj_name $ \c_obj_name ->
  42          withCString str $ \c_str ->
  43           c_insertSymbol c_obj_name c_str symbol
  44
  45 lookupSymbol :: String -> IO (Maybe (Ptr a))
  46 lookupSymbol str_in = do
  47    let str = prefixUnderscore str_in
  48    withCString str $ \c_str -> do
  49      addr <- c_lookupSymbol c_str
  50      if addr == nullPtr
  51         then return Nothing
  52         else return (Just addr)
  53
  54 prefixUnderscore :: String -> String
  55 prefixUnderscore
  56  | cLeadingUnderscore == "YES" = ('_':)
  57  | otherwise                   = id
  58
  59 loadDLL :: String -> IO (Maybe String)
  60 -- Nothing      => success
  61 -- Just err_msg => failure
  62 loadDLL str = do
  63   maybe_errmsg <- withCString str $ \dll -> c_addDLL dll
  64   if maybe_errmsg == nullPtr
  65         then return Nothing
  66         else do str <- peekCString maybe_errmsg
  67                 return (Just str)
  68
  69 loadObj :: String -> IO ()
  70 loadObj str = do
  71    withCString str $ \c_str -> do
  72      r <- c_loadObj c_str
  73      when (r == 0) (panic "loadObj: failed")
  74
  75 unloadObj :: String -> IO ()
  76 unloadObj str =
  77    withCString str $ \c_str -> do
  78      r <- c_unloadObj c_str
  79      when (r == 0) (panic "unloadObj: failed")
  80
  81 resolveObjs :: IO SuccessFlag
  82 resolveObjs = do
  83    r <- c_resolveObjs
  84    return (successIf (r /= 0))
  85
  86 -- ---------------------------------------------------------------------------
  87 -- Foreign declaractions to RTS entry points which does the real work;
  88 -- ---------------------------------------------------------------------------
  89
  90 foreign import ccall unsafe "addDLL"       c_addDLL :: CString -> IO CString
  91 foreign import ccall unsafe "initLinker"   initObjLinker :: IO ()
  92 foreign import ccall unsafe "insertSymbol" c_insertSymbol :: CString -> CString -> Ptr a -> IO ()
  93 foreign import ccall unsafe "lookupSymbol" c_lookupSymbol :: CString -> IO (Ptr a)
  94 foreign import ccall unsafe "loadObj"      c_loadObj :: CString -> IO Int
  95 foreign import ccall unsafe "unloadObj"    c_unloadObj :: CString -> IO Int
  96 foreign import ccall unsafe "resolveObjs"  c_resolveObjs :: IO Int
  97
  98 \end{code}