compiler/hsSyn/HsDecls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsDecls]{Abstract syntax: global declarations}
   5
   6 Definitions for: @TyDecl@ and @oCnDecl@, @ClassDecl@,
   7 @InstDecl@, @DefaultDecl@ and @ForeignDecl@.
   8
   9 \begin{code}
  10 module HsDecls (
  11         HsDecl(..), LHsDecl, TyClDecl(..), LTyClDecl,
  12         InstDecl(..), LInstDecl, NewOrData(..),
  13         RuleDecl(..), LRuleDecl, RuleBndr(..),
  14         DefaultDecl(..), LDefaultDecl, SpliceDecl(..),
  15         ForeignDecl(..), LForeignDecl, ForeignImport(..), ForeignExport(..),
  16         CImportSpec(..), FoType(..),
  17         ConDecl(..), ResType(..), LConDecl,
  18         DeprecDecl(..),  LDeprecDecl,
  19         HsGroup(..),  emptyRdrGroup, emptyRnGroup, appendGroups,
  20         tcdName, tyClDeclNames, tyClDeclTyVars,
  21         isClassDecl, isSynDecl, isDataDecl,
  22         countTyClDecls,
  23         conDetailsTys,
  24         instDeclATs,
  25         collectRuleBndrSigTys,
  26     ) where
  27
  28 #include "HsVersions.h"
  29
  30 -- friends:
  31 import {-# SOURCE #-}   HsExpr( HsExpr, pprExpr )
  32         -- Because Expr imports Decls via HsBracket
  33
  34 import HsBinds          ( HsValBinds(..), HsBind, LHsBinds, plusHsValBinds,
  35                           Sig(..), LSig, LFixitySig, pprLHsBinds,
  36                           emptyValBindsIn, emptyValBindsOut )
  37 import HsPat            ( HsConDetails(..), hsConArgs )
  38 import HsImpExp         ( pprHsVar )
  39 import HsTypes
  40 import NameSet          ( NameSet )
  41 import HscTypes         ( DeprecTxt )
  42 import CoreSyn          ( RuleName )
  43 import Kind             ( Kind, pprKind )
  44 import BasicTypes       ( Activation(..) )
  45 import ForeignCall      ( CCallTarget(..), DNCallSpec, CCallConv, Safety,
  46                           CExportSpec(..), CLabelString )
  47
  48 -- others:
  49 import FunDeps          ( pprFundeps )
  50 import Class            ( FunDep )
  51 import Outputable
  52 import Util             ( count )
  53 import SrcLoc           ( Located(..), unLoc, noLoc )
  54 import FastString
  55 \end{code}
  56
  57
  58 %************************************************************************
  59 %*                                                                      *
  60 \subsection[HsDecl]{Declarations}
  61 %*                                                                      *
  62 %************************************************************************
  63
  64 \begin{code}
  65 type LHsDecl id = Located (HsDecl id)
  66
  67 data HsDecl id
  68   = TyClD       (TyClDecl id)
  69   | InstD       (InstDecl  id)
  70   | ValD        (HsBind id)
  71   | SigD        (Sig id)
  72   | DefD        (DefaultDecl id)
  73   | ForD        (ForeignDecl id)
  74   | DeprecD     (DeprecDecl id)
  75   | RuleD       (RuleDecl id)
  76   | SpliceD     (SpliceDecl id)
  77
  78 -- NB: all top-level fixity decls are contained EITHER
  79 -- EITHER SigDs
  80 -- OR     in the ClassDecls in TyClDs
  81 --
  82 -- The former covers
  83 --      a) data constructors
  84 --      b) class methods (but they can be also done in the
  85 --              signatures of class decls)
  86 --      c) imported functions (that have an IfacSig)
  87 --      d) top level decls
  88 --
  89 -- The latter is for class methods only
  90
  91 -- A [HsDecl] is categorised into a HsGroup before being
  92 -- fed to the renamer.
  93 data HsGroup id
  94   = HsGroup {
  95         hs_valds  :: HsValBinds id,
  96         hs_tyclds :: [LTyClDecl id],
  97         hs_instds :: [LInstDecl id],
  98
  99         hs_fixds  :: [LFixitySig id],
 100                 -- Snaffled out of both top-level fixity signatures,
 101                 -- and those in class declarations
 102
 103         hs_defds  :: [LDefaultDecl id],
 104         hs_fords  :: [LForeignDecl id],
 105         hs_depds  :: [LDeprecDecl id],
 106         hs_ruleds :: [LRuleDecl id]
 107   }
 108
 109 emptyGroup, emptyRdrGroup, emptyRnGroup :: HsGroup a
 110 emptyRdrGroup = emptyGroup { hs_valds = emptyValBindsIn }
 111 emptyRnGroup  = emptyGroup { hs_valds = emptyValBindsOut }
 112
 113 emptyGroup = HsGroup { hs_tyclds = [], hs_instds = [],
 114                        hs_fixds = [], hs_defds = [], hs_fords = [],
 115                        hs_depds = [], hs_ruleds = [],
 116                        hs_valds = error "emptyGroup hs_valds: Can't happen" }
 117
 118 appendGroups :: HsGroup a -> HsGroup a -> HsGroup a
 119 appendGroups
 120     HsGroup {
 121         hs_valds  = val_groups1,
 122         hs_tyclds = tyclds1,
 123         hs_instds = instds1,
 124         hs_fixds  = fixds1,
 125         hs_defds  = defds1,
 126         hs_fords  = fords1,
 127         hs_depds  = depds1,
 128         hs_ruleds = rulds1 }
 129     HsGroup {
 130         hs_valds  = val_groups2,
 131         hs_tyclds = tyclds2,
 132         hs_instds = instds2,
 133         hs_fixds  = fixds2,
 134         hs_defds  = defds2,
 135         hs_fords  = fords2,
 136         hs_depds  = depds2,
 137         hs_ruleds = rulds2 }
 138   =
 139     HsGroup {
 140         hs_valds  = val_groups1 `plusHsValBinds` val_groups2,
 141         hs_tyclds = tyclds1 ++ tyclds2,
 142         hs_instds = instds1 ++ instds2,
 143         hs_fixds  = fixds1 ++ fixds2,
 144         hs_defds  = defds1 ++ defds2,
 145         hs_fords  = fords1 ++ fords2,
 146         hs_depds  = depds1 ++ depds2,
 147         hs_ruleds = rulds1 ++ rulds2 }
 148 \end{code}
 149
 150 \begin{code}
 151 instance OutputableBndr name => Outputable (HsDecl name) where
 152     ppr (TyClD dcl)  = ppr dcl
 153     ppr (ValD binds) = ppr binds
 154     ppr (DefD def)   = ppr def
 155     ppr (InstD inst) = ppr inst
 156     ppr (ForD fd)    = ppr fd
 157     ppr (SigD sd)    = ppr sd
 158     ppr (RuleD rd)   = ppr rd
 159     ppr (DeprecD dd) = ppr dd
 160     ppr (SpliceD dd) = ppr dd
 161
 162 instance OutputableBndr name => Outputable (HsGroup name) where
 163     ppr (HsGroup { hs_valds  = val_decls,
 164                    hs_tyclds = tycl_decls,
 165                    hs_instds = inst_decls,
 166                    hs_fixds  = fix_decls,
 167                    hs_depds  = deprec_decls,
 168                    hs_fords  = foreign_decls,
 169                    hs_defds  = default_decls,
 170                    hs_ruleds = rule_decls })
 171         = vcat [ppr_ds fix_decls, ppr_ds default_decls,
 172                 ppr_ds deprec_decls, ppr_ds rule_decls,
 173                 ppr val_decls,
 174                 ppr_ds tycl_decls, ppr_ds inst_decls,
 175                 ppr_ds foreign_decls]
 176         where
 177           ppr_ds [] = empty
 178           ppr_ds ds = text "" $$ vcat (map ppr ds)
 179
 180 data SpliceDecl id = SpliceDecl (Located (HsExpr id))   -- Top level splice
 181
 182 instance OutputableBndr name => Outputable (SpliceDecl name) where
 183    ppr (SpliceDecl e) = ptext SLIT("$") <> parens (pprExpr (unLoc e))
 184 \end{code}
 185
 186
 187 %************************************************************************
 188 %*                                                                      *
 189 \subsection[TyDecl]{@data@, @newtype@ or @type@ (synonym) type declaration}
 190 %*                                                                      *
 191 %************************************************************************
 192
 193                 --------------------------------
 194                         THE NAMING STORY
 195                 --------------------------------
 196
 197 Here is the story about the implicit names that go with type, class,
 198 and instance decls.  It's a bit tricky, so pay attention!
 199
 200 "Implicit" (or "system") binders
 201 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 202   Each data type decl defines
 203         a worker name for each constructor
 204         to-T and from-T convertors
 205   Each class decl defines
 206         a tycon for the class
 207         a data constructor for that tycon
 208         the worker for that constructor
 209         a selector for each superclass
 210
 211 All have occurrence names that are derived uniquely from their parent
 212 declaration.
 213
 214 None of these get separate definitions in an interface file; they are
 215 fully defined by the data or class decl.  But they may *occur* in
 216 interface files, of course.  Any such occurrence must haul in the
 217 relevant type or class decl.
 218
 219 Plan of attack:
 220  - Ensure they "point to" the parent data/class decl
 221    when loading that decl from an interface file
 222    (See RnHiFiles.getSysBinders)
 223
 224  - When typechecking the decl, we build the implicit TyCons and Ids.
 225    When doing so we look them up in the name cache (RnEnv.lookupSysName),
 226    to ensure correct module and provenance is set
 227
 228 These are the two places that we have to conjure up the magic derived
 229 names.  (The actual magic is in OccName.mkWorkerOcc, etc.)
 230
 231 Default methods
 232 ~~~~~~~~~~~~~~~
 233  - Occurrence name is derived uniquely from the method name
 234    E.g. $dmmax
 235
 236  - If there is a default method name at all, it's recorded in
 237    the ClassOpSig (in HsBinds), in the DefMeth field.
 238    (DefMeth is defined in Class.lhs)
 239
 240 Source-code class decls and interface-code class decls are treated subtly
 241 differently, which has given me a great deal of confusion over the years.
 242 Here's the deal.  (We distinguish the two cases because source-code decls
 243 have (Just binds) in the tcdMeths field, whereas interface decls have Nothing.
 244
 245 In *source-code* class declarations:
 246
 247  - When parsing, every ClassOpSig gets a DefMeth with a suitable RdrName
 248    This is done by RdrHsSyn.mkClassOpSigDM
 249
 250  - The renamer renames it to a Name
 251
 252  - During typechecking, we generate a binding for each $dm for
 253    which there's a programmer-supplied default method:
 254         class Foo a where
 255           op1 :: <type>
 256           op2 :: <type>
 257           op1 = ...
 258    We generate a binding for $dmop1 but not for $dmop2.
 259    The Class for Foo has a NoDefMeth for op2 and a DefMeth for op1.
 260    The Name for $dmop2 is simply discarded.
 261
 262 In *interface-file* class declarations:
 263   - When parsing, we see if there's an explicit programmer-supplied default method
 264     because there's an '=' sign to indicate it:
 265         class Foo a where
 266           op1 = :: <type>       -- NB the '='
 267           op2   :: <type>
 268     We use this info to generate a DefMeth with a suitable RdrName for op1,
 269     and a NoDefMeth for op2
 270   - The interface file has a separate definition for $dmop1, with unfolding etc.
 271   - The renamer renames it to a Name.
 272   - The renamer treats $dmop1 as a free variable of the declaration, so that
 273     the binding for $dmop1 will be sucked in.  (See RnHsSyn.tyClDeclFVs)
 274     This doesn't happen for source code class decls, because they *bind* the default method.
 275
 276 Dictionary functions
 277 ~~~~~~~~~~~~~~~~~~~~
 278 Each instance declaration gives rise to one dictionary function binding.
 279
 280 The type checker makes up new source-code instance declarations
 281 (e.g. from 'deriving' or generic default methods --- see
 282 TcInstDcls.tcInstDecls1).  So we can't generate the names for
 283 dictionary functions in advance (we don't know how many we need).
 284
 285 On the other hand for interface-file instance declarations, the decl
 286 specifies the name of the dictionary function, and it has a binding elsewhere
 287 in the interface file:
 288         instance {Eq Int} = dEqInt
 289         dEqInt :: {Eq Int} <pragma info>
 290
 291 So again we treat source code and interface file code slightly differently.
 292
 293 Source code:
 294   - Source code instance decls have a Nothing in the (Maybe name) field
 295     (see data InstDecl below)
 296
 297   - The typechecker makes up a Local name for the dict fun for any source-code
 298     instance decl, whether it comes from a source-code instance decl, or whether
 299     the instance decl is derived from some other construct (e.g. 'deriving').
 300
 301   - The occurrence name it chooses is derived from the instance decl (just for
 302     documentation really) --- e.g. dNumInt.  Two dict funs may share a common
 303     occurrence name, but will have different uniques.  E.g.
 304         instance Foo [Int]  where ...
 305         instance Foo [Bool] where ...
 306     These might both be dFooList
 307
 308   - The CoreTidy phase externalises the name, and ensures the occurrence name is
 309     unique (this isn't special to dict funs).  So we'd get dFooList and dFooList1.
 310
 311   - We can take this relaxed approach (changing the occurrence name later)
 312     because dict fun Ids are not captured in a TyCon or Class (unlike default
 313     methods, say).  Instead, they are kept separately in the InstEnv.  This
 314     makes it easy to adjust them after compiling a module.  (Once we've finished
 315     compiling that module, they don't change any more.)
 316
 317
 318 Interface file code:
 319   - The instance decl gives the dict fun name, so the InstDecl has a (Just name)
 320     in the (Maybe name) field.
 321
 322   - RnHsSyn.instDeclFVs treats the dict fun name as free in the decl, so that we
 323     suck in the dfun binding
 324
 325
 326 \begin{code}
 327 -- TyClDecls are precisely the kind of declarations that can
 328 -- appear in interface files; or (internally) in GHC's interface
 329 -- for a module.  That's why (despite the misnomer) IfaceSig and ForeignType
 330 -- are both in TyClDecl
 331
 332 type LTyClDecl name = Located (TyClDecl name)
 333
 334 data TyClDecl name
 335   = ForeignType {
 336                 tcdLName    :: Located name,
 337                 tcdExtName  :: Maybe FastString,
 338                 tcdFoType   :: FoType
 339   }
 340
 341   | TyData {    tcdND     :: NewOrData,
 342                 tcdCtxt   :: LHsContext name,           -- Context
 343                 tcdLName  :: Located name,              -- Type constructor
 344                 tcdTyVars :: [LHsTyVarBndr name],       -- Type variables
 345                 tcdTyPats :: Maybe [LHsType name],      -- Type patterns
 346                 tcdKindSig:: Maybe Kind,                -- Optional kind sig;
 347                                                         -- (only for the 'where' form)
 348
 349                 tcdCons   :: [LConDecl name],           -- Data constructors
 350                         -- For data T a = T1 | T2 a          the LConDecls all have ResTyH98
 351                         -- For data T a where { T1 :: T a }  the LConDecls all have ResTyGADT
 352
 353                 tcdDerivs :: Maybe [LHsType name]
 354                         -- Derivings; Nothing => not specified
 355                         --            Just [] => derive exactly what is asked
 356                         -- These "types" must be of form
 357                         --      forall ab. C ty1 ty2
 358                         -- Typically the foralls and ty args are empty, but they
 359                         -- are non-empty for the newtype-deriving case
 360     }
 361
 362   | TySynonym { tcdLName  :: Located name,              -- type constructor
 363                 tcdTyVars :: [LHsTyVarBndr name],       -- type variables
 364                 tcdSynRhs :: LHsType name               -- synonym expansion
 365     }
 366
 367   | ClassDecl { tcdCtxt    :: LHsContext name,          -- Context...
 368                 tcdLName   :: Located name,             -- Name of the class
 369                 tcdTyVars  :: [LHsTyVarBndr name],      -- Class type variables
 370                 tcdFDs     :: [Located (FunDep name)],  -- Functional deps
 371                 tcdSigs    :: [LSig name],              -- Methods' signatures
 372                 tcdMeths   :: LHsBinds name,            -- Default methods
 373                 tcdATs     :: [LTyClDecl name]          -- Associated types; ie
 374                                                         --   only 'TyData'
 375                                                         --   and 'TySynonym'
 376     }
 377
 378 data NewOrData
 379   = NewType     -- "newtype Blah ..."
 380   | DataType    -- "data Blah ..."
 381   deriving( Eq )        -- Needed because Demand derives Eq
 382 \end{code}
 383
 384 Simple classifiers
 385
 386 \begin{code}
 387 isDataDecl, isSynDecl, isClassDecl :: TyClDecl name -> Bool
 388
 389 isSynDecl (TySynonym {}) = True
 390 isSynDecl other          = False
 391
 392 isDataDecl (TyData {}) = True
 393 isDataDecl other       = False
 394
 395 isClassDecl (ClassDecl {}) = True
 396 isClassDecl other          = False
 397 \end{code}
 398
 399 Dealing with names
 400
 401 \begin{code}
 402 tcdName :: TyClDecl name -> name
 403 tcdName decl = unLoc (tcdLName decl)
 404
 405 tyClDeclNames :: Eq name => TyClDecl name -> [Located name]
 406 -- Returns all the *binding* names of the decl, along with their SrcLocs
 407 -- The first one is guaranteed to be the name of the decl
 408 -- For record fields, the first one counts as the SrcLoc
 409 -- We use the equality to filter out duplicate field names
 410
 411 tyClDeclNames (TySynonym   {tcdLName = name})  = [name]
 412 tyClDeclNames (ForeignType {tcdLName = name})  = [name]
 413
 414 tyClDeclNames (ClassDecl {tcdLName = cls_name, tcdSigs = sigs, tcdATs = ats})
 415   = cls_name :
 416     concatMap (tyClDeclNames . unLoc) ats ++ [n | L _ (TypeSig n _) <- sigs]
 417
 418 tyClDeclNames (TyData {tcdLName = tc_name, tcdCons = cons})
 419   = tc_name : conDeclsNames (map unLoc cons)
 420
 421 tyClDeclTyVars (TySynonym {tcdTyVars = tvs}) = tvs
 422 tyClDeclTyVars (TyData    {tcdTyVars = tvs}) = tvs
 423 tyClDeclTyVars (ClassDecl {tcdTyVars = tvs}) = tvs
 424 tyClDeclTyVars (ForeignType {})              = []
 425 \end{code}
 426
 427 \begin{code}
 428 countTyClDecls :: [TyClDecl name] -> (Int, Int, Int, Int)
 429         -- class, data, newtype, synonym decls
 430 countTyClDecls decls
 431  = (count isClassDecl     decls,
 432     count isSynDecl       decls,
 433     count isDataTy        decls,
 434     count isNewTy         decls)
 435  where
 436    isDataTy TyData{tcdND=DataType} = True
 437    isDataTy _                      = False
 438
 439    isNewTy TyData{tcdND=NewType} = True
 440    isNewTy _                     = False
 441 \end{code}
 442
 443 \begin{code}
 444 instance OutputableBndr name
 445               => Outputable (TyClDecl name) where
 446
 447     ppr (ForeignType {tcdLName = ltycon})
 448         = hsep [ptext SLIT("foreign import type dotnet"), ppr ltycon]
 449
 450     ppr (TySynonym {tcdLName = ltycon, tcdTyVars = tyvars, tcdSynRhs = mono_ty})
 451       = hang (ptext SLIT("type") <+> pp_decl_head [] ltycon tyvars Nothing <+> equals)
 452              4 (ppr mono_ty)
 453
 454     ppr (TyData {tcdND = new_or_data, tcdCtxt = context, tcdLName = ltycon,
 455                  tcdTyVars = tyvars, tcdTyPats = typats, tcdKindSig = mb_sig,
 456                  tcdCons = condecls, tcdDerivs = derivings})
 457       = pp_tydecl (ppr new_or_data <+>
 458                    pp_decl_head (unLoc context) ltycon tyvars typats <+>
 459                    ppr_sig mb_sig)
 460                   (pp_condecls condecls)
 461                   derivings
 462       where
 463         ppr_sig Nothing = empty
 464         ppr_sig (Just kind) = dcolon <+> pprKind kind
 465
 466     ppr (ClassDecl {tcdCtxt = context, tcdLName = lclas, tcdTyVars = tyvars,
 467                     tcdFDs = fds,
 468                     tcdSigs = sigs, tcdMeths = methods, tcdATs = ats})
 469       | null sigs && null ats  -- No "where" part
 470       = top_matter
 471
 472       | otherwise       -- Laid out
 473       = sep [hsep [top_matter, ptext SLIT("where {")],
 474              nest 4 (sep [ sep (map ppr_semi ats)
 475                          , sep (map ppr_semi sigs)
 476                          , pprLHsBinds methods
 477                          , char '}'])]
 478       where
 479         top_matter    =     ptext SLIT("class")
 480                         <+> pp_decl_head (unLoc context) lclas tyvars Nothing
 481                         <+> pprFundeps (map unLoc fds)
 482         ppr_semi decl = ppr decl <> semi
 483
 484 pp_decl_head :: OutputableBndr name
 485    => HsContext name
 486    -> Located name
 487    -> [LHsTyVarBndr name]
 488    -> Maybe [LHsType name]
 489    -> SDoc
 490 pp_decl_head context thing tyvars Nothing       -- no explicit type patterns
 491   = hsep [pprHsContext context, ppr thing, interppSP tyvars]
 492 pp_decl_head context thing _      (Just typats) -- explicit type patterns
 493   = hsep [ pprHsContext context, ppr thing
 494          , hsep (map (pprParendHsType.unLoc) typats)]
 495
 496 pp_condecls cs@(L _ ConDecl{ con_res = ResTyGADT _ } : _) -- In GADT syntax
 497   = hang (ptext SLIT("where")) 2 (vcat (map ppr cs))
 498 pp_condecls cs                    -- In H98 syntax
 499   = equals <+> sep (punctuate (ptext SLIT(" |")) (map ppr cs))
 500
 501 pp_tydecl pp_head pp_decl_rhs derivings
 502   = hang pp_head 4 (sep [
 503         pp_decl_rhs,
 504         case derivings of
 505           Nothing          -> empty
 506           Just ds          -> hsep [ptext SLIT("deriving"), parens (interpp'SP ds)]
 507     ])
 508
 509 instance Outputable NewOrData where
 510   ppr NewType  = ptext SLIT("newtype")
 511   ppr DataType = ptext SLIT("data")
 512 \end{code}
 513
 514
 515 %************************************************************************
 516 %*                                                                      *
 517 \subsection[ConDecl]{A data-constructor declaration}
 518 %*                                                                      *
 519 %************************************************************************
 520
 521 \begin{code}
 522 type LConDecl name = Located (ConDecl name)
 523
 524 -- data T b = forall a. Eq a => MkT a b
 525 --   MkT :: forall b a. Eq a => MkT a b
 526
 527 -- data T b where
 528 --      MkT1 :: Int -> T Int
 529
 530 -- data T = Int `MkT` Int
 531 --        | MkT2
 532
 533 -- data T a where
 534 --      Int `MkT` Int :: T Int
 535
 536 data ConDecl name
 537   = ConDecl
 538     { con_name      :: Located name         -- Constructor name; this is used for the
 539                                             -- DataCon itself, and for the user-callable wrapper Id
 540
 541     , con_explicit  :: HsExplicitForAll     -- Is there an user-written forall? (cf. HStypes.HsForAllTy)
 542
 543     , con_qvars     :: [LHsTyVarBndr name]  -- ResTyH98: the constructor's existential type variables
 544                                             -- ResTyGADT:    all the constructor's quantified type variables
 545
 546     , con_cxt       :: LHsContext name      -- The context.  This *does not* include the
 547                                             -- "stupid theta" which lives only in the TyData decl
 548
 549     , con_details   :: HsConDetails name (LBangType name)       -- The main payload
 550
 551     , con_res       :: ResType name         -- Result type of the constructor
 552     }
 553
 554 data ResType name
 555    = ResTyH98           -- Constructor was declared using Haskell 98 syntax
 556    | ResTyGADT (LHsType name)   -- Constructor was declared using GADT-style syntax,
 557                                 --      and here is its result type
 558 \end{code}
 559
 560 \begin{code}
 561 conDeclsNames :: Eq name => [ConDecl name] -> [Located name]
 562   -- See tyClDeclNames for what this does
 563   -- The function is boringly complicated because of the records
 564   -- And since we only have equality, we have to be a little careful
 565 conDeclsNames cons
 566   = snd (foldl do_one ([], []) cons)
 567   where
 568     do_one (flds_seen, acc) (ConDecl { con_name = lname, con_details = RecCon flds })
 569         = (map unLoc new_flds ++ flds_seen, lname : [f | f <- new_flds] ++ acc)
 570         where
 571           new_flds = [ f | (f,_) <- flds, not (unLoc f `elem` flds_seen) ]
 572
 573     do_one (flds_seen, acc) c
 574         = (flds_seen, (con_name c):acc)
 575
 576 conDetailsTys details = map getBangType (hsConArgs details)
 577 \end{code}
 578
 579
 580 \begin{code}
 581 instance (OutputableBndr name) => Outputable (ConDecl name) where
 582     ppr = pprConDecl
 583
 584 pprConDecl (ConDecl con expl tvs cxt details ResTyH98)
 585   = sep [pprHsForAll expl tvs cxt, ppr_details con details]
 586   where
 587     ppr_details con (InfixCon t1 t2) = hsep [ppr t1, pprHsVar con, ppr t2]
 588     ppr_details con (PrefixCon tys)  = hsep (pprHsVar con : map ppr tys)
 589     ppr_details con (RecCon fields)  = ppr con <+> ppr_fields fields
 590
 591 pprConDecl (ConDecl con expl tvs cxt (PrefixCon arg_tys) (ResTyGADT res_ty))
 592   = ppr con <+> dcolon <+>
 593     sep [pprHsForAll expl tvs cxt, ppr (foldr mk_fun_ty res_ty arg_tys)]
 594   where
 595     mk_fun_ty a b = noLoc (HsFunTy a b)
 596 pprConDecl (ConDecl con expl tvs cxt (RecCon fields) (ResTyGADT res_ty))
 597   = sep [pprHsForAll expl tvs cxt, ppr con <+> ppr fields <+> dcolon <+> ppr res_ty]
 598
 599 ppr_fields fields = braces (sep (punctuate comma (map ppr_field fields)))
 600 ppr_field (n, ty) = ppr n <+> dcolon <+> ppr ty
 601 \end{code}
 602
 603 %************************************************************************
 604 %*                                                                      *
 605 \subsection[InstDecl]{An instance declaration
 606 %*                                                                      *
 607 %************************************************************************
 608
 609 \begin{code}
 610 type LInstDecl name = Located (InstDecl name)
 611
 612 data InstDecl name
 613   = InstDecl    (LHsType name)  -- Context => Class Instance-type
 614                                 -- Using a polytype means that the renamer conveniently
 615                                 -- figures out the quantified type variables for us.
 616                 (LHsBinds name)
 617                 [LSig name]     -- User-supplied pragmatic info
 618                 [LTyClDecl name]-- Associated types
 619
 620 instance (OutputableBndr name) => Outputable (InstDecl name) where
 621
 622     ppr (InstDecl inst_ty binds uprags ats)
 623       = vcat [hsep [ptext SLIT("instance"), ppr inst_ty, ptext SLIT("where")],
 624               nest 4 (ppr ats),
 625               nest 4 (ppr uprags),
 626               nest 4 (pprLHsBinds binds) ]
 627
 628 -- Extract the declarations of associated types from an instance
 629 --
 630 instDeclATs :: InstDecl name -> [LTyClDecl name]
 631 instDeclATs (InstDecl _ _ _ ats) = ats
 632 \end{code}
 633
 634 %************************************************************************
 635 %*                                                                      *
 636 \subsection[DefaultDecl]{A @default@ declaration}
 637 %*                                                                      *
 638 %************************************************************************
 639
 640 There can only be one default declaration per module, but it is hard
 641 for the parser to check that; we pass them all through in the abstract
 642 syntax, and that restriction must be checked in the front end.
 643
 644 \begin{code}
 645 type LDefaultDecl name = Located (DefaultDecl name)
 646
 647 data DefaultDecl name
 648   = DefaultDecl [LHsType name]
 649
 650 instance (OutputableBndr name)
 651               => Outputable (DefaultDecl name) where
 652
 653     ppr (DefaultDecl tys)
 654       = ptext SLIT("default") <+> parens (interpp'SP tys)
 655 \end{code}
 656
 657 %************************************************************************
 658 %*                                                                      *
 659 \subsection{Foreign function interface declaration}
 660 %*                                                                      *
 661 %************************************************************************
 662
 663 \begin{code}
 664
 665 -- foreign declarations are distinguished as to whether they define or use a
 666 -- Haskell name
 667 --
 668 --  * the Boolean value indicates whether the pre-standard deprecated syntax
 669 --   has been used
 670 --
 671 type LForeignDecl name = Located (ForeignDecl name)
 672
 673 data ForeignDecl name
 674   = ForeignImport (Located name) (LHsType name) ForeignImport  -- defines name
 675   | ForeignExport (Located name) (LHsType name) ForeignExport  -- uses name
 676
 677 -- Specification Of an imported external entity in dependence on the calling
 678 -- convention
 679 --
 680 data ForeignImport = -- import of a C entity
 681                      --
 682                      --  * the two strings specifying a header file or library
 683                      --   may be empty, which indicates the absence of a
 684                      --   header or object specification (both are not used
 685                      --   in the case of `CWrapper' and when `CFunction'
 686                      --   has a dynamic target)
 687                      --
 688                      --  * the calling convention is irrelevant for code
 689                      --   generation in the case of `CLabel', but is needed
 690                      --   for pretty printing
 691                      --
 692                      --  * `Safety' is irrelevant for `CLabel' and `CWrapper'
 693                      --
 694                      CImport  CCallConv       -- ccall or stdcall
 695                               Safety          -- safe or unsafe
 696                               FastString      -- name of C header
 697                               FastString      -- name of library object
 698                               CImportSpec     -- details of the C entity
 699
 700                      -- import of a .NET function
 701                      --
 702                    | DNImport DNCallSpec
 703
 704 -- details of an external C entity
 705 --
 706 data CImportSpec = CLabel    CLabelString     -- import address of a C label
 707                  | CFunction CCallTarget      -- static or dynamic function
 708                  | CWrapper                   -- wrapper to expose closures
 709                                               -- (former f.e.d.)
 710
 711 -- specification of an externally exported entity in dependence on the calling
 712 -- convention
 713 --
 714 data ForeignExport = CExport  CExportSpec    -- contains the calling convention
 715                    | DNExport                -- presently unused
 716
 717 -- abstract type imported from .NET
 718 --
 719 data FoType = DNType            -- In due course we'll add subtype stuff
 720             deriving (Eq)       -- Used for equality instance for TyClDecl
 721
 722
 723 -- pretty printing of foreign declarations
 724 --
 725
 726 instance OutputableBndr name => Outputable (ForeignDecl name) where
 727   ppr (ForeignImport n ty fimport) =
 728     ptext SLIT("foreign import") <+> ppr fimport <+>
 729     ppr n <+> dcolon <+> ppr ty
 730   ppr (ForeignExport n ty fexport) =
 731     ptext SLIT("foreign export") <+> ppr fexport <+>
 732     ppr n <+> dcolon <+> ppr ty
 733
 734 instance Outputable ForeignImport where
 735   ppr (DNImport                         spec) =
 736     ptext SLIT("dotnet") <+> ppr spec
 737   ppr (CImport  cconv safety header lib spec) =
 738     ppr cconv <+> ppr safety <+>
 739     char '"' <> pprCEntity header lib spec <> char '"'
 740     where
 741       pprCEntity header lib (CLabel lbl) =
 742         ptext SLIT("static") <+> ftext header <+> char '&' <>
 743         pprLib lib <> ppr lbl
 744       pprCEntity header lib (CFunction (StaticTarget lbl)) =
 745         ptext SLIT("static") <+> ftext header <+> char '&' <>
 746         pprLib lib <> ppr lbl
 747       pprCEntity header lib (CFunction (DynamicTarget)) =
 748         ptext SLIT("dynamic")
 749       pprCEntity _      _   (CWrapper) = ptext SLIT("wrapper")
 750       --
 751       pprLib lib | nullFS lib = empty
 752                  | otherwise  = char '[' <> ppr lib <> char ']'
 753
 754 instance Outputable ForeignExport where
 755   ppr (CExport  (CExportStatic lbl cconv)) =
 756     ppr cconv <+> char '"' <> ppr lbl <> char '"'
 757   ppr (DNExport                          ) =
 758     ptext SLIT("dotnet") <+> ptext SLIT("\"<unused>\"")
 759
 760 instance Outputable FoType where
 761   ppr DNType = ptext SLIT("type dotnet")
 762 \end{code}
 763
 764
 765 %************************************************************************
 766 %*                                                                      *
 767 \subsection{Transformation rules}
 768 %*                                                                      *
 769 %************************************************************************
 770
 771 \begin{code}
 772 type LRuleDecl name = Located (RuleDecl name)
 773
 774 data RuleDecl name
 775   = HsRule                      -- Source rule
 776         RuleName                -- Rule name
 777         Activation
 778         [RuleBndr name]         -- Forall'd vars; after typechecking this includes tyvars
 779         (Located (HsExpr name)) -- LHS
 780         NameSet                 -- Free-vars from the LHS
 781         (Located (HsExpr name)) -- RHS
 782         NameSet                 -- Free-vars from the RHS
 783
 784 data RuleBndr name
 785   = RuleBndr (Located name)
 786   | RuleBndrSig (Located name) (LHsType name)
 787
 788 collectRuleBndrSigTys :: [RuleBndr name] -> [LHsType name]
 789 collectRuleBndrSigTys bndrs = [ty | RuleBndrSig _ ty <- bndrs]
 790
 791 instance OutputableBndr name => Outputable (RuleDecl name) where
 792   ppr (HsRule name act ns lhs fv_lhs rhs fv_rhs)
 793         = sep [text "{-# RULES" <+> doubleQuotes (ftext name) <+> ppr act,
 794                nest 4 (pp_forall <+> pprExpr (unLoc lhs)),
 795                nest 4 (equals <+> pprExpr (unLoc rhs) <+> text "#-}") ]
 796         where
 797           pp_forall | null ns   = empty
 798                     | otherwise = text "forall" <+> fsep (map ppr ns) <> dot
 799
 800 instance OutputableBndr name => Outputable (RuleBndr name) where
 801    ppr (RuleBndr name) = ppr name
 802    ppr (RuleBndrSig name ty) = ppr name <> dcolon <> ppr ty
 803 \end{code}
 804
 805
 806 %************************************************************************
 807 %*                                                                      *
 808 \subsection[DeprecDecl]{Deprecations}
 809 %*                                                                      *
 810 %************************************************************************
 811
 812 We use exported entities for things to deprecate.
 813
 814 \begin{code}
 815 type LDeprecDecl name = Located (DeprecDecl name)
 816
 817 data DeprecDecl name = Deprecation name DeprecTxt
 818
 819 instance OutputableBndr name => Outputable (DeprecDecl name) where
 820     ppr (Deprecation thing txt)
 821       = hsep [text "{-# DEPRECATED", ppr thing, doubleQuotes (ppr txt), text "#-}"]
 822 \end{code}