compiler/hsSyn/HsDecls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsDecls]{Abstract syntax: global declarations}
   5
   6 Definitions for: @TyDecl@ and @oCnDecl@, @ClassDecl@,
   7 @InstDecl@, @DefaultDecl@ and @ForeignDecl@.
   8
   9 \begin{code}
  10 module HsDecls (
  11         HsDecl(..), LHsDecl, TyClDecl(..), LTyClDecl,
  12         InstDecl(..), LInstDecl, NewOrData(..),
  13         RuleDecl(..), LRuleDecl, RuleBndr(..),
  14         DefaultDecl(..), LDefaultDecl, SpliceDecl(..),
  15         ForeignDecl(..), LForeignDecl, ForeignImport(..), ForeignExport(..),
  16         CImportSpec(..), FoType(..),
  17         ConDecl(..), ResType(..), LConDecl,
  18         DeprecDecl(..),  LDeprecDecl,
  19         HsGroup(..),  emptyRdrGroup, emptyRnGroup, appendGroups,
  20         tcdName, tyClDeclNames, tyClDeclTyVars,
  21         isClassDecl, isTFunDecl, isSynDecl, isDataDecl, isKindSigDecl,
  22         isIdxTyDecl,
  23         countTyClDecls,
  24         conDetailsTys,
  25         instDeclATs,
  26         collectRuleBndrSigTys,
  27     ) where
  28
  29 #include "HsVersions.h"
  30
  31 -- friends:
  32 import {-# SOURCE #-}   HsExpr( HsExpr, pprExpr )
  33         -- Because Expr imports Decls via HsBracket
  34
  35 import HsBinds          ( HsValBinds(..), HsBind, LHsBinds, plusHsValBinds,
  36                           Sig(..), LSig, LFixitySig, pprLHsBinds,
  37                           emptyValBindsIn, emptyValBindsOut )
  38 import HsPat            ( HsConDetails(..), hsConArgs )
  39 import HsImpExp         ( pprHsVar )
  40 import HsTypes
  41 import NameSet          ( NameSet )
  42 import CoreSyn          ( RuleName )
  43 import {- Kind parts of -} Type         ( Kind, pprKind )
  44 import BasicTypes       ( Activation(..), DeprecTxt )
  45 import ForeignCall      ( CCallTarget(..), DNCallSpec, CCallConv, Safety,
  46                           CExportSpec(..), CLabelString )
  47
  48 -- others:
  49 import Class            ( FunDep, pprFundeps )
  50 import Outputable
  51 import Util             ( count )
  52 import SrcLoc           ( Located(..), unLoc, noLoc )
  53 import FastString
  54 import Maybe            ( isJust )
  55 \end{code}
  56
  57
  58 %************************************************************************
  59 %*                                                                      *
  60 \subsection[HsDecl]{Declarations}
  61 %*                                                                      *
  62 %************************************************************************
  63
  64 \begin{code}
  65 type LHsDecl id = Located (HsDecl id)
  66
  67 data HsDecl id
  68   = TyClD       (TyClDecl id)
  69   | InstD       (InstDecl  id)
  70   | ValD        (HsBind id)
  71   | SigD        (Sig id)
  72   | DefD        (DefaultDecl id)
  73   | ForD        (ForeignDecl id)
  74   | DeprecD     (DeprecDecl id)
  75   | RuleD       (RuleDecl id)
  76   | SpliceD     (SpliceDecl id)
  77
  78 -- NB: all top-level fixity decls are contained EITHER
  79 -- EITHER SigDs
  80 -- OR     in the ClassDecls in TyClDs
  81 --
  82 -- The former covers
  83 --      a) data constructors
  84 --      b) class methods (but they can be also done in the
  85 --              signatures of class decls)
  86 --      c) imported functions (that have an IfacSig)
  87 --      d) top level decls
  88 --
  89 -- The latter is for class methods only
  90
  91 -- A [HsDecl] is categorised into a HsGroup before being
  92 -- fed to the renamer.
  93 data HsGroup id
  94   = HsGroup {
  95         hs_valds  :: HsValBinds id,
  96         hs_tyclds :: [LTyClDecl id],
  97         hs_instds :: [LInstDecl id],
  98
  99         hs_fixds  :: [LFixitySig id],
 100                 -- Snaffled out of both top-level fixity signatures,
 101                 -- and those in class declarations
 102
 103         hs_defds  :: [LDefaultDecl id],
 104         hs_fords  :: [LForeignDecl id],
 105         hs_depds  :: [LDeprecDecl id],
 106         hs_ruleds :: [LRuleDecl id]
 107   }
 108
 109 emptyGroup, emptyRdrGroup, emptyRnGroup :: HsGroup a
 110 emptyRdrGroup = emptyGroup { hs_valds = emptyValBindsIn }
 111 emptyRnGroup  = emptyGroup { hs_valds = emptyValBindsOut }
 112
 113 emptyGroup = HsGroup { hs_tyclds = [], hs_instds = [],
 114                        hs_fixds = [], hs_defds = [], hs_fords = [],
 115                        hs_depds = [], hs_ruleds = [],
 116                        hs_valds = error "emptyGroup hs_valds: Can't happen" }
 117
 118 appendGroups :: HsGroup a -> HsGroup a -> HsGroup a
 119 appendGroups
 120     HsGroup {
 121         hs_valds  = val_groups1,
 122         hs_tyclds = tyclds1,
 123         hs_instds = instds1,
 124         hs_fixds  = fixds1,
 125         hs_defds  = defds1,
 126         hs_fords  = fords1,
 127         hs_depds  = depds1,
 128         hs_ruleds = rulds1 }
 129     HsGroup {
 130         hs_valds  = val_groups2,
 131         hs_tyclds = tyclds2,
 132         hs_instds = instds2,
 133         hs_fixds  = fixds2,
 134         hs_defds  = defds2,
 135         hs_fords  = fords2,
 136         hs_depds  = depds2,
 137         hs_ruleds = rulds2 }
 138   =
 139     HsGroup {
 140         hs_valds  = val_groups1 `plusHsValBinds` val_groups2,
 141         hs_tyclds = tyclds1 ++ tyclds2,
 142         hs_instds = instds1 ++ instds2,
 143         hs_fixds  = fixds1 ++ fixds2,
 144         hs_defds  = defds1 ++ defds2,
 145         hs_fords  = fords1 ++ fords2,
 146         hs_depds  = depds1 ++ depds2,
 147         hs_ruleds = rulds1 ++ rulds2 }
 148 \end{code}
 149
 150 \begin{code}
 151 instance OutputableBndr name => Outputable (HsDecl name) where
 152     ppr (TyClD dcl)  = ppr dcl
 153     ppr (ValD binds) = ppr binds
 154     ppr (DefD def)   = ppr def
 155     ppr (InstD inst) = ppr inst
 156     ppr (ForD fd)    = ppr fd
 157     ppr (SigD sd)    = ppr sd
 158     ppr (RuleD rd)   = ppr rd
 159     ppr (DeprecD dd) = ppr dd
 160     ppr (SpliceD dd) = ppr dd
 161
 162 instance OutputableBndr name => Outputable (HsGroup name) where
 163     ppr (HsGroup { hs_valds  = val_decls,
 164                    hs_tyclds = tycl_decls,
 165                    hs_instds = inst_decls,
 166                    hs_fixds  = fix_decls,
 167                    hs_depds  = deprec_decls,
 168                    hs_fords  = foreign_decls,
 169                    hs_defds  = default_decls,
 170                    hs_ruleds = rule_decls })
 171         = vcat [ppr_ds fix_decls, ppr_ds default_decls,
 172                 ppr_ds deprec_decls, ppr_ds rule_decls,
 173                 ppr val_decls,
 174                 ppr_ds tycl_decls, ppr_ds inst_decls,
 175                 ppr_ds foreign_decls]
 176         where
 177           ppr_ds [] = empty
 178           ppr_ds ds = text "" $$ vcat (map ppr ds)
 179
 180 data SpliceDecl id = SpliceDecl (Located (HsExpr id))   -- Top level splice
 181
 182 instance OutputableBndr name => Outputable (SpliceDecl name) where
 183    ppr (SpliceDecl e) = ptext SLIT("$") <> parens (pprExpr (unLoc e))
 184 \end{code}
 185
 186
 187 %************************************************************************
 188 %*                                                                      *
 189 \subsection[TyDecl]{@data@, @newtype@ or @type@ (synonym) type declaration}
 190 %*                                                                      *
 191 %************************************************************************
 192
 193                 --------------------------------
 194                         THE NAMING STORY
 195                 --------------------------------
 196
 197 Here is the story about the implicit names that go with type, class,
 198 and instance decls.  It's a bit tricky, so pay attention!
 199
 200 "Implicit" (or "system") binders
 201 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 202   Each data type decl defines
 203         a worker name for each constructor
 204         to-T and from-T convertors
 205   Each class decl defines
 206         a tycon for the class
 207         a data constructor for that tycon
 208         the worker for that constructor
 209         a selector for each superclass
 210
 211 All have occurrence names that are derived uniquely from their parent
 212 declaration.
 213
 214 None of these get separate definitions in an interface file; they are
 215 fully defined by the data or class decl.  But they may *occur* in
 216 interface files, of course.  Any such occurrence must haul in the
 217 relevant type or class decl.
 218
 219 Plan of attack:
 220  - Ensure they "point to" the parent data/class decl
 221    when loading that decl from an interface file
 222    (See RnHiFiles.getSysBinders)
 223
 224  - When typechecking the decl, we build the implicit TyCons and Ids.
 225    When doing so we look them up in the name cache (RnEnv.lookupSysName),
 226    to ensure correct module and provenance is set
 227
 228 These are the two places that we have to conjure up the magic derived
 229 names.  (The actual magic is in OccName.mkWorkerOcc, etc.)
 230
 231 Default methods
 232 ~~~~~~~~~~~~~~~
 233  - Occurrence name is derived uniquely from the method name
 234    E.g. $dmmax
 235
 236  - If there is a default method name at all, it's recorded in
 237    the ClassOpSig (in HsBinds), in the DefMeth field.
 238    (DefMeth is defined in Class.lhs)
 239
 240 Source-code class decls and interface-code class decls are treated subtly
 241 differently, which has given me a great deal of confusion over the years.
 242 Here's the deal.  (We distinguish the two cases because source-code decls
 243 have (Just binds) in the tcdMeths field, whereas interface decls have Nothing.
 244
 245 In *source-code* class declarations:
 246
 247  - When parsing, every ClassOpSig gets a DefMeth with a suitable RdrName
 248    This is done by RdrHsSyn.mkClassOpSigDM
 249
 250  - The renamer renames it to a Name
 251
 252  - During typechecking, we generate a binding for each $dm for
 253    which there's a programmer-supplied default method:
 254         class Foo a where
 255           op1 :: <type>
 256           op2 :: <type>
 257           op1 = ...
 258    We generate a binding for $dmop1 but not for $dmop2.
 259    The Class for Foo has a NoDefMeth for op2 and a DefMeth for op1.
 260    The Name for $dmop2 is simply discarded.
 261
 262 In *interface-file* class declarations:
 263   - When parsing, we see if there's an explicit programmer-supplied default method
 264     because there's an '=' sign to indicate it:
 265         class Foo a where
 266           op1 = :: <type>       -- NB the '='
 267           op2   :: <type>
 268     We use this info to generate a DefMeth with a suitable RdrName for op1,
 269     and a NoDefMeth for op2
 270   - The interface file has a separate definition for $dmop1, with unfolding etc.
 271   - The renamer renames it to a Name.
 272   - The renamer treats $dmop1 as a free variable of the declaration, so that
 273     the binding for $dmop1 will be sucked in.  (See RnHsSyn.tyClDeclFVs)
 274     This doesn't happen for source code class decls, because they *bind* the default method.
 275
 276 Dictionary functions
 277 ~~~~~~~~~~~~~~~~~~~~
 278 Each instance declaration gives rise to one dictionary function binding.
 279
 280 The type checker makes up new source-code instance declarations
 281 (e.g. from 'deriving' or generic default methods --- see
 282 TcInstDcls.tcInstDecls1).  So we can't generate the names for
 283 dictionary functions in advance (we don't know how many we need).
 284
 285 On the other hand for interface-file instance declarations, the decl
 286 specifies the name of the dictionary function, and it has a binding elsewhere
 287 in the interface file:
 288         instance {Eq Int} = dEqInt
 289         dEqInt :: {Eq Int} <pragma info>
 290
 291 So again we treat source code and interface file code slightly differently.
 292
 293 Source code:
 294   - Source code instance decls have a Nothing in the (Maybe name) field
 295     (see data InstDecl below)
 296
 297   - The typechecker makes up a Local name for the dict fun for any source-code
 298     instance decl, whether it comes from a source-code instance decl, or whether
 299     the instance decl is derived from some other construct (e.g. 'deriving').
 300
 301   - The occurrence name it chooses is derived from the instance decl (just for
 302     documentation really) --- e.g. dNumInt.  Two dict funs may share a common
 303     occurrence name, but will have different uniques.  E.g.
 304         instance Foo [Int]  where ...
 305         instance Foo [Bool] where ...
 306     These might both be dFooList
 307
 308   - The CoreTidy phase externalises the name, and ensures the occurrence name is
 309     unique (this isn't special to dict funs).  So we'd get dFooList and dFooList1.
 310
 311   - We can take this relaxed approach (changing the occurrence name later)
 312     because dict fun Ids are not captured in a TyCon or Class (unlike default
 313     methods, say).  Instead, they are kept separately in the InstEnv.  This
 314     makes it easy to adjust them after compiling a module.  (Once we've finished
 315     compiling that module, they don't change any more.)
 316
 317
 318 Interface file code:
 319   - The instance decl gives the dict fun name, so the InstDecl has a (Just name)
 320     in the (Maybe name) field.
 321
 322   - RnHsSyn.instDeclFVs treats the dict fun name as free in the decl, so that we
 323     suck in the dfun binding
 324
 325
 326 \begin{code}
 327 -- TyClDecls are precisely the kind of declarations that can
 328 -- appear in interface files; or (internally) in GHC's interface
 329 -- for a module.  That's why (despite the misnomer) IfaceSig and ForeignType
 330 -- are both in TyClDecl
 331
 332 -- Representation of indexed types
 333 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 334 -- Kind signatures of indexed types come in two flavours:
 335 --
 336 -- * kind signatures for type functions: variant `TyFunction' and
 337 --
 338 -- * kind signatures for indexed data types and newtypes : variant `TyData'
 339 --   iff a kind is present in `tcdKindSig' and there are no constructors in
 340 --   `tcdCons'.
 341 --
 342 -- Indexed types are represented by 'TyData' and 'TySynonym' using the field
 343 -- 'tcdTyPats::Maybe [LHsType name]', with the following meaning:
 344 --
 345 --   * If it is 'Nothing', we have a *vanilla* data type declaration or type
 346 --     synonym declaration and 'tcdVars' contains the type parameters of the
 347 --     type constructor.
 348 --
 349 --   * If it is 'Just pats', we have the definition of an indexed type Then,
 350 --     'pats' are type patterns for the type-indexes of the type constructor
 351 --     and 'tcdVars' are the variables in those patterns.  Hence, the arity of
 352 --     the indexed type (ie, the number of indexes) is 'length tcdTyPats' and
 353 --     *not* 'length tcdVars'.
 354 --
 355 -- In both cases, 'tcdVars' collects all variables we need to quantify over.
 356
 357 type LTyClDecl name = Located (TyClDecl name)
 358
 359 data TyClDecl name
 360   = ForeignType {
 361                 tcdLName    :: Located name,
 362                 tcdExtName  :: Maybe FastString,
 363                 tcdFoType   :: FoType
 364   }
 365
 366   | TyData {    tcdND     :: NewOrData,
 367                 tcdCtxt   :: LHsContext name,           -- Context
 368                 tcdLName  :: Located name,              -- Type constructor
 369                 tcdTyVars :: [LHsTyVarBndr name],       -- Type variables
 370                 tcdTyPats :: Maybe [LHsType name],      -- Type patterns
 371                 tcdKindSig:: Maybe Kind,                -- Optional kind sig;
 372                                                         -- (only for the
 373                                                         -- 'where' form and
 374                                                         -- indexed type sigs)
 375
 376                 tcdCons   :: [LConDecl name],           -- Data constructors
 377                         -- For data T a = T1 | T2 a          the LConDecls all have ResTyH98
 378                         -- For data T a where { T1 :: T a }  the LConDecls all have ResTyGADT
 379
 380                 tcdDerivs :: Maybe [LHsType name]
 381                         -- Derivings; Nothing => not specified
 382                         --            Just [] => derive exactly what is asked
 383                         -- These "types" must be of form
 384                         --      forall ab. C ty1 ty2
 385                         -- Typically the foralls and ty args are empty, but they
 386                         -- are non-empty for the newtype-deriving case
 387     }
 388
 389   | TyFunction {tcdLName  :: Located name,              -- type constructor
 390                 tcdTyVars :: [LHsTyVarBndr name],       -- type variables
 391                 tcdIso    :: Bool,                      -- injective type?
 392                 tcdKind   :: Kind                       -- result kind
 393     }
 394
 395   | TySynonym { tcdLName  :: Located name,              -- type constructor
 396                 tcdTyVars :: [LHsTyVarBndr name],       -- type variables
 397                 tcdTyPats :: Maybe [LHsType name],      -- Type patterns
 398                                                         -- 'Nothing' => vanilla
 399                                                         --   type synonym
 400                 tcdSynRhs :: LHsType name               -- synonym expansion
 401     }
 402
 403   | ClassDecl { tcdCtxt    :: LHsContext name,          -- Context...
 404                 tcdLName   :: Located name,             -- Name of the class
 405                 tcdTyVars  :: [LHsTyVarBndr name],      -- Class type variables
 406                 tcdFDs     :: [Located (FunDep name)],  -- Functional deps
 407                 tcdSigs    :: [LSig name],              -- Methods' signatures
 408                 tcdMeths   :: LHsBinds name,            -- Default methods
 409                 tcdATs     :: [LTyClDecl name]          -- Associated types; ie
 410                                                         --   only 'TyData',
 411                                                         --   'TyFunction',
 412                                                         --   and 'TySynonym'
 413     }
 414
 415 data NewOrData
 416   = NewType     -- "newtype Blah ..."
 417   | DataType    -- "data Blah ..."
 418   deriving( Eq )        -- Needed because Demand derives Eq
 419 \end{code}
 420
 421 Simple classifiers
 422
 423 \begin{code}
 424 isTFunDecl, isDataDecl, isSynDecl, isClassDecl, isKindSigDecl, isIdxTyDecl ::
 425   TyClDecl name -> Bool
 426
 427 -- type function kind signature
 428 isTFunDecl (TyFunction {}) = True
 429 isTFunDecl other           = False
 430
 431 -- vanilla Haskell type synonym
 432 isSynDecl (TySynonym {tcdTyPats = Nothing}) = True
 433 isSynDecl other                             = False
 434
 435 -- type equation (of a type function)
 436 isTEqnDecl (TySynonym {tcdTyPats = Just _}) = True
 437 isTEqnDecl other                            = False
 438
 439 isDataDecl (TyData {}) = True
 440 isDataDecl other       = False
 441
 442 isClassDecl (ClassDecl {}) = True
 443 isClassDecl other          = False
 444
 445 -- kind signature (for an indexed type)
 446 isKindSigDecl (TyFunction {}                   ) = True
 447 isKindSigDecl (TyData     {tcdKindSig = Just _,
 448                            tcdCons    = []    }) = True
 449 isKindSigDecl other                              = False
 450
 451 -- definition of an instance of an indexed type
 452 isIdxTyDecl tydecl
 453    | isTEqnDecl tydecl = True
 454    | isDataDecl tydecl = isJust (tcdTyPats tydecl)
 455    | otherwise         = False
 456 \end{code}
 457
 458 Dealing with names
 459
 460 \begin{code}
 461 tcdName :: TyClDecl name -> name
 462 tcdName decl = unLoc (tcdLName decl)
 463
 464 tyClDeclNames :: Eq name => TyClDecl name -> [Located name]
 465 -- Returns all the *binding* names of the decl, along with their SrcLocs
 466 -- The first one is guaranteed to be the name of the decl
 467 -- For record fields, the first one counts as the SrcLoc
 468 -- We use the equality to filter out duplicate field names
 469
 470 tyClDeclNames (TyFunction  {tcdLName = name})    = [name]
 471 tyClDeclNames (TySynonym   {tcdLName = name})    = [name]
 472 tyClDeclNames (ForeignType {tcdLName = name})    = [name]
 473
 474 tyClDeclNames (ClassDecl {tcdLName = cls_name, tcdSigs = sigs, tcdATs = ats})
 475   = cls_name :
 476     concatMap (tyClDeclNames . unLoc) ats ++ [n | L _ (TypeSig n _) <- sigs]
 477
 478 tyClDeclNames (TyData {tcdLName = tc_name, tcdCons = cons})
 479   = tc_name : conDeclsNames (map unLoc cons)
 480
 481 tyClDeclTyVars (TyFunction  {tcdTyVars = tvs}) = tvs
 482 tyClDeclTyVars (TySynonym   {tcdTyVars = tvs}) = tvs
 483 tyClDeclTyVars (TyData      {tcdTyVars = tvs}) = tvs
 484 tyClDeclTyVars (ClassDecl   {tcdTyVars = tvs}) = tvs
 485 tyClDeclTyVars (ForeignType {})                = []
 486 \end{code}
 487
 488 \begin{code}
 489 countTyClDecls :: [TyClDecl name] -> (Int, Int, Int, Int, Int, Int)
 490         -- class, synonym decls, type function signatures,
 491         -- type function equations, data, newtype
 492 countTyClDecls decls
 493  = (count isClassDecl     decls,
 494     count isSynDecl       decls,
 495     count isTFunDecl      decls,
 496     count isTEqnDecl      decls,
 497     count isDataTy        decls,
 498     count isNewTy         decls)
 499  where
 500    isDataTy TyData{tcdND=DataType} = True
 501    isDataTy _                      = False
 502
 503    isNewTy TyData{tcdND=NewType} = True
 504    isNewTy _                     = False
 505 \end{code}
 506
 507 \begin{code}
 508 instance OutputableBndr name
 509               => Outputable (TyClDecl name) where
 510
 511     ppr (ForeignType {tcdLName = ltycon})
 512         = hsep [ptext SLIT("foreign import type dotnet"), ppr ltycon]
 513
 514     ppr (TyFunction {tcdLName = ltycon, tcdTyVars = tyvars, tcdIso = iso,
 515                      tcdKind = kind})
 516       = typeMaybeIso <+> pp_decl_head [] ltycon tyvars Nothing <+>
 517         dcolon <+> pprKind kind
 518         where
 519           typeMaybeIso = if iso
 520                          then ptext SLIT("type iso")
 521                          else ptext SLIT("type")
 522
 523     ppr (TySynonym {tcdLName = ltycon, tcdTyVars = tyvars, tcdTyPats = typats,
 524                     tcdSynRhs = mono_ty})
 525       = hang (ptext SLIT("type") <+> pp_decl_head [] ltycon tyvars typats <+>
 526               equals)
 527              4 (ppr mono_ty)
 528
 529     ppr (TyData {tcdND = new_or_data, tcdCtxt = context, tcdLName = ltycon,
 530                  tcdTyVars = tyvars, tcdTyPats = typats, tcdKindSig = mb_sig,
 531                  tcdCons = condecls, tcdDerivs = derivings})
 532       = pp_tydecl (ppr new_or_data <+>
 533                    pp_decl_head (unLoc context) ltycon tyvars typats <+>
 534                    ppr_sig mb_sig)
 535                   (pp_condecls condecls)
 536                   derivings
 537       where
 538         ppr_sig Nothing = empty
 539         ppr_sig (Just kind) = dcolon <+> pprKind kind
 540
 541     ppr (ClassDecl {tcdCtxt = context, tcdLName = lclas, tcdTyVars = tyvars,
 542                     tcdFDs = fds,
 543                     tcdSigs = sigs, tcdMeths = methods, tcdATs = ats})
 544       | null sigs && null ats  -- No "where" part
 545       = top_matter
 546
 547       | otherwise       -- Laid out
 548       = sep [hsep [top_matter, ptext SLIT("where {")],
 549              nest 4 (sep [ sep (map ppr_semi ats)
 550                          , sep (map ppr_semi sigs)
 551                          , pprLHsBinds methods
 552                          , char '}'])]
 553       where
 554         top_matter    =     ptext SLIT("class")
 555                         <+> pp_decl_head (unLoc context) lclas tyvars Nothing
 556                         <+> pprFundeps (map unLoc fds)
 557         ppr_semi decl = ppr decl <> semi
 558
 559 pp_decl_head :: OutputableBndr name
 560    => HsContext name
 561    -> Located name
 562    -> [LHsTyVarBndr name]
 563    -> Maybe [LHsType name]
 564    -> SDoc
 565 pp_decl_head context thing tyvars Nothing       -- no explicit type patterns
 566   = hsep [pprHsContext context, ppr thing, interppSP tyvars]
 567 pp_decl_head context thing _      (Just typats) -- explicit type patterns
 568   = hsep [ pprHsContext context, ppr thing
 569          , hsep (map (pprParendHsType.unLoc) typats)]
 570
 571 pp_condecls cs@(L _ ConDecl{ con_res = ResTyGADT _ } : _) -- In GADT syntax
 572   = hang (ptext SLIT("where")) 2 (vcat (map ppr cs))
 573 pp_condecls cs                    -- In H98 syntax
 574   = equals <+> sep (punctuate (ptext SLIT(" |")) (map ppr cs))
 575
 576 pp_tydecl pp_head pp_decl_rhs derivings
 577   = hang pp_head 4 (sep [
 578         pp_decl_rhs,
 579         case derivings of
 580           Nothing          -> empty
 581           Just ds          -> hsep [ptext SLIT("deriving"), parens (interpp'SP ds)]
 582     ])
 583
 584 instance Outputable NewOrData where
 585   ppr NewType  = ptext SLIT("newtype")
 586   ppr DataType = ptext SLIT("data")
 587 \end{code}
 588
 589
 590 %************************************************************************
 591 %*                                                                      *
 592 \subsection[ConDecl]{A data-constructor declaration}
 593 %*                                                                      *
 594 %************************************************************************
 595
 596 \begin{code}
 597 type LConDecl name = Located (ConDecl name)
 598
 599 -- data T b = forall a. Eq a => MkT a b
 600 --   MkT :: forall b a. Eq a => MkT a b
 601
 602 -- data T b where
 603 --      MkT1 :: Int -> T Int
 604
 605 -- data T = Int `MkT` Int
 606 --        | MkT2
 607
 608 -- data T a where
 609 --      Int `MkT` Int :: T Int
 610
 611 data ConDecl name
 612   = ConDecl
 613     { con_name      :: Located name         -- Constructor name; this is used for the
 614                                             -- DataCon itself, and for the user-callable wrapper Id
 615
 616     , con_explicit  :: HsExplicitForAll     -- Is there an user-written forall? (cf. HStypes.HsForAllTy)
 617
 618     , con_qvars     :: [LHsTyVarBndr name]  -- ResTyH98: the constructor's existential type variables
 619                                             -- ResTyGADT:    all the constructor's quantified type variables
 620
 621     , con_cxt       :: LHsContext name      -- The context.  This *does not* include the
 622                                             -- "stupid theta" which lives only in the TyData decl
 623
 624     , con_details   :: HsConDetails name (LBangType name)       -- The main payload
 625
 626     , con_res       :: ResType name         -- Result type of the constructor
 627     }
 628
 629 data ResType name
 630    = ResTyH98           -- Constructor was declared using Haskell 98 syntax
 631    | ResTyGADT (LHsType name)   -- Constructor was declared using GADT-style syntax,
 632                                 --      and here is its result type
 633 \end{code}
 634
 635 \begin{code}
 636 conDeclsNames :: Eq name => [ConDecl name] -> [Located name]
 637   -- See tyClDeclNames for what this does
 638   -- The function is boringly complicated because of the records
 639   -- And since we only have equality, we have to be a little careful
 640 conDeclsNames cons
 641   = snd (foldl do_one ([], []) cons)
 642   where
 643     do_one (flds_seen, acc) (ConDecl { con_name = lname, con_details = RecCon flds })
 644         = (map unLoc new_flds ++ flds_seen, lname : [f | f <- new_flds] ++ acc)
 645         where
 646           new_flds = [ f | (f,_) <- flds, not (unLoc f `elem` flds_seen) ]
 647
 648     do_one (flds_seen, acc) c
 649         = (flds_seen, (con_name c):acc)
 650
 651 conDetailsTys details = map getBangType (hsConArgs details)
 652 \end{code}
 653
 654
 655 \begin{code}
 656 instance (OutputableBndr name) => Outputable (ConDecl name) where
 657     ppr = pprConDecl
 658
 659 pprConDecl (ConDecl con expl tvs cxt details ResTyH98)
 660   = sep [pprHsForAll expl tvs cxt, ppr_details con details]
 661   where
 662     ppr_details con (InfixCon t1 t2) = hsep [ppr t1, pprHsVar con, ppr t2]
 663     ppr_details con (PrefixCon tys)  = hsep (pprHsVar con : map ppr tys)
 664     ppr_details con (RecCon fields)  = ppr con <+> ppr_fields fields
 665
 666 pprConDecl (ConDecl con expl tvs cxt (PrefixCon arg_tys) (ResTyGADT res_ty))
 667   = ppr con <+> dcolon <+>
 668     sep [pprHsForAll expl tvs cxt, ppr (foldr mk_fun_ty res_ty arg_tys)]
 669   where
 670     mk_fun_ty a b = noLoc (HsFunTy a b)
 671 pprConDecl (ConDecl con expl tvs cxt (RecCon fields) (ResTyGADT res_ty))
 672   = sep [pprHsForAll expl tvs cxt, ppr con <+> ppr fields <+> dcolon <+> ppr res_ty]
 673
 674 ppr_fields fields = braces (sep (punctuate comma (map ppr_field fields)))
 675 ppr_field (n, ty) = ppr n <+> dcolon <+> ppr ty
 676 \end{code}
 677
 678 %************************************************************************
 679 %*                                                                      *
 680 \subsection[InstDecl]{An instance declaration
 681 %*                                                                      *
 682 %************************************************************************
 683
 684 \begin{code}
 685 type LInstDecl name = Located (InstDecl name)
 686
 687 data InstDecl name
 688   = InstDecl    (LHsType name)  -- Context => Class Instance-type
 689                                 -- Using a polytype means that the renamer conveniently
 690                                 -- figures out the quantified type variables for us.
 691                 (LHsBinds name)
 692                 [LSig name]     -- User-supplied pragmatic info
 693                 [LTyClDecl name]-- Associated types (ie, 'TyData' and
 694                                 -- 'TySynonym' only)
 695
 696 instance (OutputableBndr name) => Outputable (InstDecl name) where
 697
 698     ppr (InstDecl inst_ty binds uprags ats)
 699       = vcat [hsep [ptext SLIT("instance"), ppr inst_ty, ptext SLIT("where")],
 700               nest 4 (ppr ats),
 701               nest 4 (ppr uprags),
 702               nest 4 (pprLHsBinds binds) ]
 703
 704 -- Extract the declarations of associated types from an instance
 705 --
 706 instDeclATs :: InstDecl name -> [LTyClDecl name]
 707 instDeclATs (InstDecl _ _ _ ats) = ats
 708 \end{code}
 709
 710 %************************************************************************
 711 %*                                                                      *
 712 \subsection[DefaultDecl]{A @default@ declaration}
 713 %*                                                                      *
 714 %************************************************************************
 715
 716 There can only be one default declaration per module, but it is hard
 717 for the parser to check that; we pass them all through in the abstract
 718 syntax, and that restriction must be checked in the front end.
 719
 720 \begin{code}
 721 type LDefaultDecl name = Located (DefaultDecl name)
 722
 723 data DefaultDecl name
 724   = DefaultDecl [LHsType name]
 725
 726 instance (OutputableBndr name)
 727               => Outputable (DefaultDecl name) where
 728
 729     ppr (DefaultDecl tys)
 730       = ptext SLIT("default") <+> parens (interpp'SP tys)
 731 \end{code}
 732
 733 %************************************************************************
 734 %*                                                                      *
 735 \subsection{Foreign function interface declaration}
 736 %*                                                                      *
 737 %************************************************************************
 738
 739 \begin{code}
 740
 741 -- foreign declarations are distinguished as to whether they define or use a
 742 -- Haskell name
 743 --
 744 --  * the Boolean value indicates whether the pre-standard deprecated syntax
 745 --   has been used
 746 --
 747 type LForeignDecl name = Located (ForeignDecl name)
 748
 749 data ForeignDecl name
 750   = ForeignImport (Located name) (LHsType name) ForeignImport  -- defines name
 751   | ForeignExport (Located name) (LHsType name) ForeignExport  -- uses name
 752
 753 -- Specification Of an imported external entity in dependence on the calling
 754 -- convention
 755 --
 756 data ForeignImport = -- import of a C entity
 757                      --
 758                      --  * the two strings specifying a header file or library
 759                      --   may be empty, which indicates the absence of a
 760                      --   header or object specification (both are not used
 761                      --   in the case of `CWrapper' and when `CFunction'
 762                      --   has a dynamic target)
 763                      --
 764                      --  * the calling convention is irrelevant for code
 765                      --   generation in the case of `CLabel', but is needed
 766                      --   for pretty printing
 767                      --
 768                      --  * `Safety' is irrelevant for `CLabel' and `CWrapper'
 769                      --
 770                      CImport  CCallConv       -- ccall or stdcall
 771                               Safety          -- safe or unsafe
 772                               FastString      -- name of C header
 773                               FastString      -- name of library object
 774                               CImportSpec     -- details of the C entity
 775
 776                      -- import of a .NET function
 777                      --
 778                    | DNImport DNCallSpec
 779
 780 -- details of an external C entity
 781 --
 782 data CImportSpec = CLabel    CLabelString     -- import address of a C label
 783                  | CFunction CCallTarget      -- static or dynamic function
 784                  | CWrapper                   -- wrapper to expose closures
 785                                               -- (former f.e.d.)
 786
 787 -- specification of an externally exported entity in dependence on the calling
 788 -- convention
 789 --
 790 data ForeignExport = CExport  CExportSpec    -- contains the calling convention
 791                    | DNExport                -- presently unused
 792
 793 -- abstract type imported from .NET
 794 --
 795 data FoType = DNType            -- In due course we'll add subtype stuff
 796             deriving (Eq)       -- Used for equality instance for TyClDecl
 797
 798
 799 -- pretty printing of foreign declarations
 800 --
 801
 802 instance OutputableBndr name => Outputable (ForeignDecl name) where
 803   ppr (ForeignImport n ty fimport) =
 804     ptext SLIT("foreign import") <+> ppr fimport <+>
 805     ppr n <+> dcolon <+> ppr ty
 806   ppr (ForeignExport n ty fexport) =
 807     ptext SLIT("foreign export") <+> ppr fexport <+>
 808     ppr n <+> dcolon <+> ppr ty
 809
 810 instance Outputable ForeignImport where
 811   ppr (DNImport                         spec) =
 812     ptext SLIT("dotnet") <+> ppr spec
 813   ppr (CImport  cconv safety header lib spec) =
 814     ppr cconv <+> ppr safety <+>
 815     char '"' <> pprCEntity header lib spec <> char '"'
 816     where
 817       pprCEntity header lib (CLabel lbl) =
 818         ptext SLIT("static") <+> ftext header <+> char '&' <>
 819         pprLib lib <> ppr lbl
 820       pprCEntity header lib (CFunction (StaticTarget lbl)) =
 821         ptext SLIT("static") <+> ftext header <+> char '&' <>
 822         pprLib lib <> ppr lbl
 823       pprCEntity header lib (CFunction (DynamicTarget)) =
 824         ptext SLIT("dynamic")
 825       pprCEntity _      _   (CWrapper) = ptext SLIT("wrapper")
 826       --
 827       pprLib lib | nullFS lib = empty
 828                  | otherwise  = char '[' <> ppr lib <> char ']'
 829
 830 instance Outputable ForeignExport where
 831   ppr (CExport  (CExportStatic lbl cconv)) =
 832     ppr cconv <+> char '"' <> ppr lbl <> char '"'
 833   ppr (DNExport                          ) =
 834     ptext SLIT("dotnet") <+> ptext SLIT("\"<unused>\"")
 835
 836 instance Outputable FoType where
 837   ppr DNType = ptext SLIT("type dotnet")
 838 \end{code}
 839
 840
 841 %************************************************************************
 842 %*                                                                      *
 843 \subsection{Transformation rules}
 844 %*                                                                      *
 845 %************************************************************************
 846
 847 \begin{code}
 848 type LRuleDecl name = Located (RuleDecl name)
 849
 850 data RuleDecl name
 851   = HsRule                      -- Source rule
 852         RuleName                -- Rule name
 853         Activation
 854         [RuleBndr name]         -- Forall'd vars; after typechecking this includes tyvars
 855         (Located (HsExpr name)) -- LHS
 856         NameSet                 -- Free-vars from the LHS
 857         (Located (HsExpr name)) -- RHS
 858         NameSet                 -- Free-vars from the RHS
 859
 860 data RuleBndr name
 861   = RuleBndr (Located name)
 862   | RuleBndrSig (Located name) (LHsType name)
 863
 864 collectRuleBndrSigTys :: [RuleBndr name] -> [LHsType name]
 865 collectRuleBndrSigTys bndrs = [ty | RuleBndrSig _ ty <- bndrs]
 866
 867 instance OutputableBndr name => Outputable (RuleDecl name) where
 868   ppr (HsRule name act ns lhs fv_lhs rhs fv_rhs)
 869         = sep [text "{-# RULES" <+> doubleQuotes (ftext name) <+> ppr act,
 870                nest 4 (pp_forall <+> pprExpr (unLoc lhs)),
 871                nest 4 (equals <+> pprExpr (unLoc rhs) <+> text "#-}") ]
 872         where
 873           pp_forall | null ns   = empty
 874                     | otherwise = text "forall" <+> fsep (map ppr ns) <> dot
 875
 876 instance OutputableBndr name => Outputable (RuleBndr name) where
 877    ppr (RuleBndr name) = ppr name
 878    ppr (RuleBndrSig name ty) = ppr name <> dcolon <> ppr ty
 879 \end{code}
 880
 881
 882 %************************************************************************
 883 %*                                                                      *
 884 \subsection[DeprecDecl]{Deprecations}
 885 %*                                                                      *
 886 %************************************************************************
 887
 888 We use exported entities for things to deprecate.
 889
 890 \begin{code}
 891 type LDeprecDecl name = Located (DeprecDecl name)
 892
 893 data DeprecDecl name = Deprecation name DeprecTxt
 894
 895 instance OutputableBndr name => Outputable (DeprecDecl name) where
 896     ppr (Deprecation thing txt)
 897       = hsep [text "{-# DEPRECATED", ppr thing, doubleQuotes (ppr txt), text "#-}"]
 898 \end{code}