compiler/hsSyn/HsExpr.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 HsExpr: Abstract Haskell syntax: expressions
   7
   8 \begin{code}
   9 module HsExpr where
  10
  11 #include "HsVersions.h"
  12
  13 -- friends:
  14 import HsDecls
  15 import HsPat
  16 import HsLit
  17 import HsTypes
  18 import HsImpExp
  19 import HsBinds
  20
  21 -- others:
  22 import Var
  23 import Name
  24 import BasicTypes
  25 import DataCon
  26 import SrcLoc
  27 import Outputable
  28 import FastString
  29 \end{code}
  30
  31
  32 %************************************************************************
  33 %*                                                                      *
  34 \subsection{Expressions proper}
  35 %*                                                                      *
  36 %************************************************************************
  37
  38 \begin{code}
  39 type LHsExpr id = Located (HsExpr id)
  40
  41 -------------------------
  42 -- PostTcExpr is an evidence expression attached to the
  43 -- syntax tree by the type checker (c.f. postTcType)
  44 -- We use a PostTcTable where there are a bunch of pieces of
  45 -- evidence, more than is convenient to keep individually
  46 type PostTcExpr  = HsExpr Id
  47 type PostTcTable = [(Name, Id)]
  48
  49 noPostTcExpr :: PostTcExpr
  50 noPostTcExpr = HsLit (HsString FSLIT("noPostTcExpr"))
  51
  52 noPostTcTable :: PostTcTable
  53 noPostTcTable = []
  54
  55 -------------------------
  56 -- SyntaxExpr is like PostTcExpr, but it's filled in a little earlier,
  57 -- by the renamer.  It's used for rebindable syntax.
  58 -- E.g. (>>=) is filled in before the renamer by the appropriate Name
  59 --      for (>>=), and then instantiated by the type checker with its
  60 --      type args tec
  61
  62 type SyntaxExpr id = HsExpr id
  63
  64 noSyntaxExpr :: SyntaxExpr id   -- Before renaming, and sometimes after,
  65                                 -- (if the syntax slot makes no sense)
  66 noSyntaxExpr = HsLit (HsString FSLIT("noSyntaxExpr"))
  67
  68
  69 type SyntaxTable id = [(Name, SyntaxExpr id)]
  70 --      *** Currently used only for CmdTop (sigh) ***
  71 -- * Before the renamer, this list is noSyntaxTable
  72 --
  73 -- * After the renamer, it takes the form [(std_name, HsVar actual_name)]
  74 --   For example, for the 'return' op of a monad
  75 --      normal case:            (GHC.Base.return, HsVar GHC.Base.return)
  76 --      with rebindable syntax: (GHC.Base.return, return_22)
  77 --              where return_22 is whatever "return" is in scope
  78 --
  79 -- * After the type checker, it takes the form [(std_name, <expression>)]
  80 --      where <expression> is the evidence for the method
  81
  82 noSyntaxTable :: SyntaxTable id
  83 noSyntaxTable = []
  84
  85
  86 -------------------------
  87 data HsExpr id
  88   = HsVar       id              -- variable
  89   | HsIPVar     (IPName id)     -- implicit parameter
  90   | HsOverLit   (HsOverLit id)  -- Overloaded literals
  91   | HsLit       HsLit           -- Simple (non-overloaded) literals
  92
  93   | HsLam       (MatchGroup  id)        -- Currently always a single match
  94
  95   | HsApp       (LHsExpr id)            -- Application
  96                 (LHsExpr id)
  97
  98   -- Operator applications:
  99   -- NB Bracketed ops such as (+) come out as Vars.
 100
 101   -- NB We need an expr for the operator in an OpApp/Section since
 102   -- the typechecker may need to apply the operator to a few types.
 103
 104   | OpApp       (LHsExpr id)    -- left operand
 105                 (LHsExpr id)    -- operator
 106                 Fixity          -- Renamer adds fixity; bottom until then
 107                 (LHsExpr id)    -- right operand
 108
 109   | NegApp      (LHsExpr id)    -- negated expr
 110                 (SyntaxExpr id) -- Name of 'negate'
 111
 112   | HsPar       (LHsExpr id)    -- parenthesised expr
 113
 114   | SectionL    (LHsExpr id)    -- operand
 115                 (LHsExpr id)    -- operator
 116   | SectionR    (LHsExpr id)    -- operator
 117                 (LHsExpr id)    -- operand
 118
 119   | HsCase      (LHsExpr id)
 120                 (MatchGroup id)
 121
 122   | HsIf        (LHsExpr id)    --  predicate
 123                 (LHsExpr id)    --  then part
 124                 (LHsExpr id)    --  else part
 125
 126   | HsLet       (HsLocalBinds id) -- let(rec)
 127                 (LHsExpr  id)
 128
 129   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 130                                         -- because in this context we never use
 131                                         -- the PatGuard or ParStmt variant
 132                 [LStmt id]              -- "do":one or more stmts
 133                 (LHsExpr id)            -- The body; the last expression in the 'do'
 134                                         --           of [ body | ... ] in a list comp
 135                 PostTcType              -- Type of the whole expression
 136
 137   | ExplicitList                -- syntactic list
 138                 PostTcType      -- Gives type of components of list
 139                 [LHsExpr id]
 140
 141   | ExplicitPArr                -- syntactic parallel array: [:e1, ..., en:]
 142                 PostTcType      -- type of elements of the parallel array
 143                 [LHsExpr id]
 144
 145   | ExplicitTuple               -- tuple
 146                 [LHsExpr id]
 147                                 -- NB: Unit is ExplicitTuple []
 148                                 -- for tuples, we can get the types
 149                                 -- direct from the components
 150                 Boxity
 151
 152
 153         -- Record construction
 154   | RecordCon   (Located id)            -- The constructor.  After type checking
 155                                         -- it's the dataConWrapId of the constructor
 156                 PostTcExpr              -- Data con Id applied to type args
 157                 (HsRecordBinds id)
 158
 159         -- Record update
 160   | RecordUpd   (LHsExpr id)
 161                 (HsRecordBinds id)
 162                 [DataCon]               -- Filled in by the type checker to the *non-empty*
 163                                         -- list of DataCons that have all the upd'd fields
 164                 [PostTcType]            -- Argument types of *input* record type
 165                 [PostTcType]            --              and  *output* record type
 166         -- For a type family, the arg types are of the *instance* tycon, not the family tycon
 167
 168   | ExprWithTySig                       -- e :: type
 169                 (LHsExpr id)
 170                 (LHsType id)
 171
 172   | ExprWithTySigOut                    -- TRANSLATION
 173                 (LHsExpr id)
 174                 (LHsType Name)          -- Retain the signature for round-tripping purposes
 175
 176   | ArithSeq                            -- arithmetic sequence
 177                 PostTcExpr
 178                 (ArithSeqInfo id)
 179
 180   | PArrSeq                             -- arith. sequence for parallel array
 181                 PostTcExpr              -- [:e1..e2:] or [:e1, e2..e3:]
 182                 (ArithSeqInfo id)
 183
 184   | HsSCC       FastString      -- "set cost centre" (_scc_) annotation
 185                 (LHsExpr id)    -- expr whose cost is to be measured
 186
 187   | HsCoreAnn   FastString      -- hdaume: core annotation
 188                 (LHsExpr id)
 189
 190   -----------------------------------------------------------
 191   -- MetaHaskell Extensions
 192
 193   | HsBracket    (HsBracket id)
 194
 195   | HsBracketOut (HsBracket Name)       -- Output of the type checker is the *original*
 196                  [PendingSplice]        -- renamed expression, plus *typechecked* splices
 197                                         -- to be pasted back in by the desugarer
 198
 199   | HsSpliceE (HsSplice id)
 200
 201   -----------------------------------------------------------
 202   -- Arrow notation extension
 203
 204   | HsProc      (LPat id)               -- arrow abstraction, proc
 205                 (LHsCmdTop id)          -- body of the abstraction
 206                                         -- always has an empty stack
 207
 208   ---------------------------------------
 209   -- The following are commands, not expressions proper
 210
 211   | HsArrApp    -- Arrow tail, or arrow application (f -< arg)
 212         (LHsExpr id)    -- arrow expression, f
 213         (LHsExpr id)    -- input expression, arg
 214         PostTcType      -- type of the arrow expressions f,
 215                         -- of the form a t t', where arg :: t
 216         HsArrAppType    -- higher-order (-<<) or first-order (-<)
 217         Bool            -- True => right-to-left (f -< arg)
 218                         -- False => left-to-right (arg >- f)
 219
 220   | HsArrForm   -- Command formation,  (| e cmd1 .. cmdn |)
 221         (LHsExpr id)    -- the operator
 222                         -- after type-checking, a type abstraction to be
 223                         -- applied to the type of the local environment tuple
 224         (Maybe Fixity)  -- fixity (filled in by the renamer), for forms that
 225                         -- were converted from OpApp's by the renamer
 226         [LHsCmdTop id]  -- argument commands
 227
 228
 229   ---------------------------------------
 230   -- Haskell program coverage (Hpc) Support
 231
 232   | HsTick
 233      Int                                -- module-local tick number
 234      [id]                               -- variables in scope
 235      (LHsExpr id)                       -- sub-expression
 236
 237   | HsBinTick
 238      Int                                -- module-local tick number for True
 239      Int                                -- module-local tick number for False
 240      (LHsExpr id)                       -- sub-expression
 241
 242   | HsTickPragma                        -- A pragma introduced tick
 243      (FastString,(Int,Int),(Int,Int))   -- external span for this tick
 244      (LHsExpr id)
 245
 246   ---------------------------------------
 247   -- These constructors only appear temporarily in the parser.
 248   -- The renamer translates them into the Right Thing.
 249
 250   | EWildPat                    -- wildcard
 251
 252   | EAsPat      (Located id)    -- as pattern
 253                 (LHsExpr id)
 254
 255   | ELazyPat    (LHsExpr id) -- ~ pattern
 256
 257   | HsType      (LHsType id)     -- Explicit type argument; e.g  f {| Int |} x y
 258
 259   ---------------------------------------
 260   -- Finally, HsWrap appears only in typechecker output
 261
 262   |  HsWrap     HsWrapper       -- TRANSLATION
 263                 (HsExpr id)
 264
 265 type PendingSplice = (Name, LHsExpr Id) -- Typechecked splices, waiting to be
 266                                         -- pasted back in by the desugarer
 267 \end{code}
 268
 269 A @Dictionary@, unless of length 0 or 1, becomes a tuple.  A
 270 @ClassDictLam dictvars methods expr@ is, therefore:
 271 \begin{verbatim}
 272 \ x -> case x of ( dictvars-and-methods-tuple ) -> expr
 273 \end{verbatim}
 274
 275 \begin{code}
 276 instance OutputableBndr id => Outputable (HsExpr id) where
 277     ppr expr = pprExpr expr
 278 \end{code}
 279
 280 \begin{code}
 281 -----------------------
 282 -- pprExpr, pprLExpr, pprBinds call pprDeeper;
 283 -- the underscore versions do not
 284 pprLExpr :: OutputableBndr id => LHsExpr id -> SDoc
 285 pprLExpr (L _ e) = pprExpr e
 286
 287 pprExpr :: OutputableBndr id => HsExpr id -> SDoc
 288 pprExpr e | isAtomicHsExpr e || isQuietHsExpr e =            ppr_expr e
 289           | otherwise                           = pprDeeper (ppr_expr e)
 290
 291 isQuietHsExpr :: HsExpr id -> Bool
 292 -- Parentheses do display something, but it gives little info and
 293 -- if we go deeper when we go inside them then we get ugly things
 294 -- like (...)
 295 isQuietHsExpr (HsPar _) = True
 296 -- applications don't display anything themselves
 297 isQuietHsExpr (HsApp _ _) = True
 298 isQuietHsExpr (OpApp _ _ _ _) = True
 299 isQuietHsExpr _ = False
 300
 301 pprBinds :: OutputableBndr id => HsLocalBinds id -> SDoc
 302 pprBinds b = pprDeeper (ppr b)
 303
 304 -----------------------
 305 ppr_lexpr :: OutputableBndr id => LHsExpr id -> SDoc
 306 ppr_lexpr e = ppr_expr (unLoc e)
 307
 308 ppr_expr (HsVar v)       = pprHsVar v
 309 ppr_expr (HsIPVar v)     = ppr v
 310 ppr_expr (HsLit lit)     = ppr lit
 311 ppr_expr (HsOverLit lit) = ppr lit
 312 ppr_expr (HsPar e)       = parens (ppr_lexpr e)
 313
 314 ppr_expr (HsCoreAnn s e)
 315   = vcat [ptext SLIT("HsCoreAnn") <+> ftext s, ppr_lexpr e]
 316
 317 ppr_expr (HsApp e1 e2)
 318   = let (fun, args) = collect_args e1 [e2] in
 319     hang (ppr_lexpr fun) 2 (sep (map pprParendExpr args))
 320   where
 321     collect_args (L _ (HsApp fun arg)) args = collect_args fun (arg:args)
 322     collect_args fun args = (fun, args)
 323
 324 ppr_expr (OpApp e1 op fixity e2)
 325   = case unLoc op of
 326       HsVar v -> pp_infixly v
 327       _       -> pp_prefixly
 328   where
 329     pp_e1 = pprParendExpr e1            -- Add parens to make precedence clear
 330     pp_e2 = pprParendExpr e2
 331
 332     pp_prefixly
 333       = hang (ppr op) 2 (sep [pp_e1, pp_e2])
 334
 335     pp_infixly v
 336       = sep [nest 2 pp_e1, pprInfix v, nest 2 pp_e2]
 337
 338 ppr_expr (NegApp e _) = char '-' <+> pprParendExpr e
 339
 340 ppr_expr (SectionL expr op)
 341   = case unLoc op of
 342       HsVar v -> pp_infixly v
 343       _       -> pp_prefixly
 344   where
 345     pp_expr = pprParendExpr expr
 346
 347     pp_prefixly = hang (hsep [text " \\ x_ ->", ppr op])
 348                        4 (hsep [pp_expr, ptext SLIT("x_ )")])
 349     pp_infixly v = parens (sep [pp_expr, pprInfix v])
 350
 351 ppr_expr (SectionR op expr)
 352   = case unLoc op of
 353       HsVar v -> pp_infixly v
 354       _       -> pp_prefixly
 355   where
 356     pp_expr = pprParendExpr expr
 357
 358     pp_prefixly = hang (hsep [text "( \\ x_ ->", ppr op, ptext SLIT("x_")])
 359                        4 ((<>) pp_expr rparen)
 360     pp_infixly v
 361       = parens (sep [pprInfix v, pp_expr])
 362
 363 ppr_expr (HsLam matches)
 364   = pprMatches LambdaExpr matches
 365
 366 ppr_expr (HsCase expr matches)
 367   = sep [ sep [ptext SLIT("case"), nest 4 (ppr expr), ptext SLIT("of")],
 368             nest 2 (pprMatches CaseAlt matches) ]
 369
 370 ppr_expr (HsIf e1 e2 e3)
 371   = sep [hsep [ptext SLIT("if"), nest 2 (ppr e1), ptext SLIT("then")],
 372            nest 4 (ppr e2),
 373            ptext SLIT("else"),
 374            nest 4 (ppr e3)]
 375
 376 -- special case: let ... in let ...
 377 ppr_expr (HsLet binds expr@(L _ (HsLet _ _)))
 378   = sep [hang (ptext SLIT("let")) 2 (hsep [pprBinds binds, ptext SLIT("in")]),
 379          ppr_lexpr expr]
 380
 381 ppr_expr (HsLet binds expr)
 382   = sep [hang (ptext SLIT("let")) 2 (pprBinds binds),
 383          hang (ptext SLIT("in"))  2 (ppr expr)]
 384
 385 ppr_expr (HsDo do_or_list_comp stmts body _) = pprDo do_or_list_comp stmts body
 386
 387 ppr_expr (ExplicitList _ exprs)
 388   = brackets (pprDeeperList fsep (punctuate comma (map ppr_lexpr exprs)))
 389
 390 ppr_expr (ExplicitPArr _ exprs)
 391   = pa_brackets (pprDeeperList fsep (punctuate comma (map ppr_lexpr exprs)))
 392
 393 ppr_expr (ExplicitTuple exprs boxity)
 394   = tupleParens boxity (sep (punctuate comma (map ppr_lexpr exprs)))
 395
 396 ppr_expr (RecordCon con_id con_expr rbinds)
 397   = hang (ppr con_id) 2 (ppr rbinds)
 398
 399 ppr_expr (RecordUpd aexp rbinds _ _ _)
 400   = hang (pprParendExpr aexp) 2 (ppr rbinds)
 401
 402 ppr_expr (ExprWithTySig expr sig)
 403   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 404          4 (ppr sig)
 405 ppr_expr (ExprWithTySigOut expr sig)
 406   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 407          4 (ppr sig)
 408
 409 ppr_expr (ArithSeq expr info) = brackets (ppr info)
 410 ppr_expr (PArrSeq expr info)  = pa_brackets (ppr info)
 411
 412 ppr_expr EWildPat     = char '_'
 413 ppr_expr (ELazyPat e) = char '~' <> pprParendExpr e
 414 ppr_expr (EAsPat v e) = ppr v <> char '@' <> pprParendExpr e
 415
 416 ppr_expr (HsSCC lbl expr)
 417   = sep [ ptext SLIT("_scc_") <+> doubleQuotes (ftext lbl), pprParendExpr expr ]
 418
 419 ppr_expr (HsWrap co_fn e) = pprHsWrapper (pprExpr e) co_fn
 420 ppr_expr (HsType id)        = ppr id
 421
 422 ppr_expr (HsSpliceE s)       = pprSplice s
 423 ppr_expr (HsBracket b)       = pprHsBracket b
 424 ppr_expr (HsBracketOut e []) = ppr e
 425 ppr_expr (HsBracketOut e ps) = ppr e $$ ptext SLIT("pending") <+> ppr ps
 426
 427 ppr_expr (HsProc pat (L _ (HsCmdTop cmd _ _ _)))
 428   = hsep [ptext SLIT("proc"), ppr pat, ptext SLIT("->"), ppr cmd]
 429
 430 ppr_expr (HsTick tickId vars exp)
 431   = hcat [ptext SLIT("tick<"), ppr tickId,ptext SLIT(">("), hsep (map pprHsVar vars), ppr exp,ptext SLIT(")")]
 432 ppr_expr (HsBinTick tickIdTrue tickIdFalse exp)
 433   = hcat [ptext SLIT("bintick<"),
 434           ppr tickIdTrue,
 435           ptext SLIT(","),
 436           ppr tickIdFalse,
 437           ptext SLIT(">("),
 438           ppr exp,ptext SLIT(")")]
 439 ppr_expr (HsTickPragma externalSrcLoc exp)
 440   = hcat [ptext SLIT("tickpragma<"), ppr externalSrcLoc,ptext SLIT(">("), ppr exp,ptext SLIT(")")]
 441
 442 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp True)
 443   = hsep [ppr_lexpr arrow, ptext SLIT("-<"), ppr_lexpr arg]
 444 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp False)
 445   = hsep [ppr_lexpr arg, ptext SLIT(">-"), ppr_lexpr arrow]
 446 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp True)
 447   = hsep [ppr_lexpr arrow, ptext SLIT("-<<"), ppr_lexpr arg]
 448 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp False)
 449   = hsep [ppr_lexpr arg, ptext SLIT(">>-"), ppr_lexpr arrow]
 450
 451 ppr_expr (HsArrForm (L _ (HsVar v)) (Just _) [arg1, arg2])
 452   = sep [pprCmdArg (unLoc arg1), hsep [pprInfix v, pprCmdArg (unLoc arg2)]]
 453 ppr_expr (HsArrForm op _ args)
 454   = hang (ptext SLIT("(|") <> ppr_lexpr op)
 455          4 (sep (map (pprCmdArg.unLoc) args) <> ptext SLIT("|)"))
 456
 457 pprCmdArg :: OutputableBndr id => HsCmdTop id -> SDoc
 458 pprCmdArg (HsCmdTop cmd@(L _ (HsArrForm _ Nothing [])) _ _ _)
 459   = ppr_lexpr cmd
 460 pprCmdArg (HsCmdTop cmd _ _ _)
 461   = parens (ppr_lexpr cmd)
 462
 463 -- Put a var in backquotes if it's not an operator already
 464 pprInfix :: Outputable name => name -> SDoc
 465 pprInfix v | isOperator ppr_v = ppr_v
 466            | otherwise        = char '`' <> ppr_v <> char '`'
 467            where
 468              ppr_v = ppr v
 469
 470 -- add parallel array brackets around a document
 471 --
 472 pa_brackets :: SDoc -> SDoc
 473 pa_brackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 474 \end{code}
 475
 476 Parenthesize unless very simple:
 477 \begin{code}
 478 pprParendExpr :: OutputableBndr id => LHsExpr id -> SDoc
 479 pprParendExpr expr
 480   = let
 481         pp_as_was = pprLExpr expr
 482         -- Using pprLExpr makes sure that we go 'deeper'
 483         -- I think that is usually (always?) right
 484     in
 485     case unLoc expr of
 486       HsLit l              -> pp_as_was
 487       HsOverLit l          -> pp_as_was
 488       HsVar _              -> pp_as_was
 489       HsIPVar _            -> pp_as_was
 490       ExplicitList _ _     -> pp_as_was
 491       ExplicitPArr _ _     -> pp_as_was
 492       ExplicitTuple _ _    -> pp_as_was
 493       HsPar _              -> pp_as_was
 494       HsBracket _          -> pp_as_was
 495       HsBracketOut _ []    -> pp_as_was
 496       HsDo sc _ _ _
 497        | isListCompExpr sc -> pp_as_was
 498       _                    -> parens pp_as_was
 499
 500 isAtomicHsExpr :: HsExpr id -> Bool     -- A single token
 501 isAtomicHsExpr (HsVar {})     = True
 502 isAtomicHsExpr (HsLit {})     = True
 503 isAtomicHsExpr (HsOverLit {}) = True
 504 isAtomicHsExpr (HsIPVar {})   = True
 505 isAtomicHsExpr (HsWrap _ e)   = isAtomicHsExpr e
 506 isAtomicHsExpr (HsPar e)      = isAtomicHsExpr (unLoc e)
 507 isAtomicHsExpr e              = False
 508 \end{code}
 509
 510 %************************************************************************
 511 %*                                                                      *
 512 \subsection{Commands (in arrow abstractions)}
 513 %*                                                                      *
 514 %************************************************************************
 515
 516 We re-use HsExpr to represent these.
 517
 518 \begin{code}
 519 type HsCmd id = HsExpr id
 520
 521 type LHsCmd id = LHsExpr id
 522
 523 data HsArrAppType = HsHigherOrderApp | HsFirstOrderApp
 524 \end{code}
 525
 526 The legal constructors for commands are:
 527
 528   = HsArrApp ...                -- as above
 529
 530   | HsArrForm ...               -- as above
 531
 532   | HsApp       (HsCmd id)
 533                 (HsExpr id)
 534
 535   | HsLam       (Match  id)     -- kappa
 536
 537   -- the renamer turns this one into HsArrForm
 538   | OpApp       (HsExpr id)     -- left operand
 539                 (HsCmd id)      -- operator
 540                 Fixity          -- Renamer adds fixity; bottom until then
 541                 (HsCmd id)      -- right operand
 542
 543   | HsPar       (HsCmd id)      -- parenthesised command
 544
 545   | HsCase      (HsExpr id)
 546                 [Match id]      -- bodies are HsCmd's
 547                 SrcLoc
 548
 549   | HsIf        (HsExpr id)     --  predicate
 550                 (HsCmd id)      --  then part
 551                 (HsCmd id)      --  else part
 552                 SrcLoc
 553
 554   | HsLet       (HsLocalBinds id)       -- let(rec)
 555                 (HsCmd  id)
 556
 557   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 558                                         -- because in this context we never use
 559                                         -- the PatGuard or ParStmt variant
 560                 [Stmt id]       -- HsExpr's are really HsCmd's
 561                 PostTcType      -- Type of the whole expression
 562                 SrcLoc
 563
 564 Top-level command, introducing a new arrow.
 565 This may occur inside a proc (where the stack is empty) or as an
 566 argument of a command-forming operator.
 567
 568 \begin{code}
 569 type LHsCmdTop id = Located (HsCmdTop id)
 570
 571 data HsCmdTop id
 572   = HsCmdTop    (LHsCmd id)
 573                 [PostTcType]    -- types of inputs on the command's stack
 574                 PostTcType      -- return type of the command
 575                 (SyntaxTable id)
 576                                 -- after type checking:
 577                                 -- names used in the command's desugaring
 578 \end{code}
 579
 580 %************************************************************************
 581 %*                                                                      *
 582 \subsection{Record binds}
 583 %*                                                                      *
 584 %************************************************************************
 585
 586 \begin{code}
 587 type HsRecordBinds id = HsRecFields id (LHsExpr id)
 588 \end{code}
 589
 590
 591
 592 %************************************************************************
 593 %*                                                                      *
 594 \subsection{@Match@, @GRHSs@, and @GRHS@ datatypes}
 595 %*                                                                      *
 596 %************************************************************************
 597
 598 @Match@es are sets of pattern bindings and right hand sides for
 599 functions, patterns or case branches. For example, if a function @g@
 600 is defined as:
 601 \begin{verbatim}
 602 g (x,y) = y
 603 g ((x:ys),y) = y+1,
 604 \end{verbatim}
 605 then \tr{g} has two @Match@es: @(x,y) = y@ and @((x:ys),y) = y+1@.
 606
 607 It is always the case that each element of an @[Match]@ list has the
 608 same number of @pats@s inside it.  This corresponds to saying that
 609 a function defined by pattern matching must have the same number of
 610 patterns in each equation.
 611
 612 \begin{code}
 613 data MatchGroup id
 614   = MatchGroup
 615         [LMatch id]     -- The alternatives
 616         PostTcType      -- The type is the type of the entire group
 617                         --      t1 -> ... -> tn -> tr
 618                         -- where there are n patterns
 619
 620 type LMatch id = Located (Match id)
 621
 622 data Match id
 623   = Match
 624         [LPat id]               -- The patterns
 625         (Maybe (LHsType id))    -- A type signature for the result of the match
 626                                 --      Nothing after typechecking
 627         (GRHSs id)
 628
 629 matchGroupArity :: MatchGroup id -> Arity
 630 matchGroupArity (MatchGroup [] _)
 631   = panic "matchGroupArity"     -- MatchGroup is never empty
 632 matchGroupArity (MatchGroup (match:matches) _)
 633   = ASSERT( all ((== n_pats) . length . hsLMatchPats) matches )
 634         -- Assertion just checks that all the matches have the same number of pats
 635     n_pats
 636   where
 637     n_pats = length (hsLMatchPats match)
 638
 639 hsLMatchPats :: LMatch id -> [LPat id]
 640 hsLMatchPats (L _ (Match pats _ _)) = pats
 641
 642 -- GRHSs are used both for pattern bindings and for Matches
 643 data GRHSs id
 644   = GRHSs [LGRHS id]            -- Guarded RHSs
 645           (HsLocalBinds id)     -- The where clause
 646
 647 type LGRHS id = Located (GRHS id)
 648
 649 data GRHS id = GRHS [LStmt id]          -- Guards
 650                     (LHsExpr id)        -- Right hand side
 651 \end{code}
 652
 653 We know the list must have at least one @Match@ in it.
 654
 655 \begin{code}
 656 pprMatches :: (OutputableBndr id) => HsMatchContext id -> MatchGroup id -> SDoc
 657 pprMatches ctxt (MatchGroup matches ty) = vcat (map (pprMatch ctxt) (map unLoc matches))
 658                                           -- Don't print the type; it's only
 659                                           -- a place-holder before typechecking
 660
 661 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 662 pprFunBind :: (OutputableBndr id) => id -> MatchGroup id -> SDoc
 663 pprFunBind fun matches = pprMatches (FunRhs fun) matches
 664
 665 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 666 pprPatBind :: (OutputableBndr bndr, OutputableBndr id)
 667            => LPat bndr -> GRHSs id -> SDoc
 668 pprPatBind pat grhss = sep [ppr pat, nest 4 (pprGRHSs PatBindRhs grhss)]
 669
 670
 671 pprMatch :: OutputableBndr id => HsMatchContext id -> Match id -> SDoc
 672 pprMatch ctxt (Match pats maybe_ty grhss)
 673   = pp_name ctxt <+> sep [sep (map ppr pats),
 674                      ppr_maybe_ty,
 675                      nest 2 (pprGRHSs ctxt grhss)]
 676   where
 677     pp_name (FunRhs fun) = ppr fun      -- Not pprBndr; the AbsBinds will
 678                                         -- have printed the signature
 679     pp_name LambdaExpr   = char '\\'
 680     pp_name other        = empty
 681
 682     ppr_maybe_ty = case maybe_ty of
 683                         Just ty -> dcolon <+> ppr ty
 684                         Nothing -> empty
 685
 686
 687 pprGRHSs :: OutputableBndr id => HsMatchContext id -> GRHSs id -> SDoc
 688 pprGRHSs ctxt (GRHSs grhss binds)
 689   = vcat (map (pprGRHS ctxt . unLoc) grhss)
 690  $$ if isEmptyLocalBinds binds then empty
 691                                else text "where" $$ nest 4 (pprBinds binds)
 692
 693 pprGRHS :: OutputableBndr id => HsMatchContext id -> GRHS id -> SDoc
 694
 695 pprGRHS ctxt (GRHS [] expr)
 696  =  pp_rhs ctxt expr
 697
 698 pprGRHS ctxt (GRHS guards expr)
 699  = sep [char '|' <+> interpp'SP guards, pp_rhs ctxt expr]
 700
 701 pp_rhs ctxt rhs = matchSeparator ctxt <+> pprDeeper (ppr rhs)
 702 \end{code}
 703
 704 %************************************************************************
 705 %*                                                                      *
 706 \subsection{Do stmts and list comprehensions}
 707 %*                                                                      *
 708 %************************************************************************
 709
 710 \begin{code}
 711 type LStmt id = Located (Stmt id)
 712
 713 -- The SyntaxExprs in here are used *only* for do-notation, which
 714 -- has rebindable syntax.  Otherwise they are unused.
 715 data Stmt id
 716   = BindStmt    (LPat id)
 717                 (LHsExpr id)
 718                 (SyntaxExpr id)         -- The (>>=) operator
 719                 (SyntaxExpr id)         -- The fail operator
 720                 -- The fail operator is noSyntaxExpr
 721                 -- if the pattern match can't fail
 722
 723   | ExprStmt    (LHsExpr id)
 724                 (SyntaxExpr id)         -- The (>>) operator
 725                 PostTcType              -- Element type of the RHS (used for arrows)
 726
 727   | LetStmt     (HsLocalBinds id)
 728
 729         -- ParStmts only occur in a list comprehension
 730   | ParStmt     [([LStmt id], [id])]    -- After renaming, the ids are the binders
 731                                         -- bound by the stmts and used subsequently
 732
 733         -- Recursive statement (see Note [RecStmt] below)
 734   | RecStmt  [LStmt id]
 735                 --- The next two fields are only valid after renaming
 736              [id]       -- The ids are a subset of the variables bound by the stmts
 737                         -- that are used in stmts that follow the RecStmt
 738
 739              [id]       -- Ditto, but these variables are the "recursive" ones, that
 740                         -- are used before they are bound in the stmts of the RecStmt
 741                         -- From a type-checking point of view, these ones have to be monomorphic
 742
 743                 --- These fields are only valid after typechecking
 744              [PostTcExpr]       -- These expressions correspond
 745                                 -- 1-to-1 with the "recursive" [id], and are the expresions that
 746                                 -- should be returned by the recursion.  They may not quite be the
 747                                 -- Ids themselves, because the Id may be *polymorphic*, but
 748                                 -- the returned thing has to be *monomorphic*.
 749              (DictBinds id)     -- Method bindings of Ids bound by the RecStmt,
 750                                 -- and used afterwards
 751 \end{code}
 752
 753 ExprStmts are a bit tricky, because what they mean
 754 depends on the context.  Consider the following contexts:
 755
 756         A do expression of type (m res_ty)
 757         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 758         * ExprStmt E any_ty:   do { ....; E; ... }
 759                 E :: m any_ty
 760           Translation: E >> ...
 761
 762         A list comprehensions of type [elt_ty]
 763         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 764         * ExprStmt E Bool:   [ .. | .... E ]
 765                         [ .. | ..., E, ... ]
 766                         [ .. | .... | ..., E | ... ]
 767                 E :: Bool
 768           Translation: if E then fail else ...
 769
 770         A guard list, guarding a RHS of type rhs_ty
 771         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 772         * ExprStmt E Bool:   f x | ..., E, ... = ...rhs...
 773                 E :: Bool
 774           Translation: if E then fail else ...
 775
 776 Array comprehensions are handled like list comprehensions -=chak
 777
 778 Note [RecStmt]
 779 ~~~~~~~~~~~~~~
 780 Example:
 781         HsDo [ BindStmt x ex
 782
 783              , RecStmt [a::forall a. a -> a, b]
 784                        [a::Int -> Int,       c]
 785                        [ BindStmt b (return x)
 786                        , LetStmt a = ea
 787                        , BindStmt c ec ]
 788
 789              , return (a b) ]
 790
 791 Here, the RecStmt binds a,b,c; but
 792   - Only a,b are used in the stmts *following* the RecStmt,
 793         This 'a' is *polymorphic'
 794   - Only a,c are used in the stmts *inside* the RecStmt
 795         *before* their bindings
 796         This 'a' is monomorphic
 797
 798 Nota Bene: the two a's have different types, even though they
 799 have the same Name.
 800
 801
 802 \begin{code}
 803 instance OutputableBndr id => Outputable (Stmt id) where
 804     ppr stmt = pprStmt stmt
 805
 806 pprStmt (BindStmt pat expr _ _)   = hsep [ppr pat, ptext SLIT("<-"), ppr expr]
 807 pprStmt (LetStmt binds)           = hsep [ptext SLIT("let"), pprBinds binds]
 808 pprStmt (ExprStmt expr _ _)       = ppr expr
 809 pprStmt (ParStmt stmtss)          = hsep (map (\stmts -> ptext SLIT("| ") <> ppr stmts) stmtss)
 810 pprStmt (RecStmt segment _ _ _ _) = ptext SLIT("rec") <+> braces (vcat (map ppr segment))
 811
 812 pprDo :: OutputableBndr id => HsStmtContext any -> [LStmt id] -> LHsExpr id -> SDoc
 813 pprDo DoExpr      stmts body = ptext SLIT("do")  <+> pprDeeperList vcat (map ppr stmts ++ [ppr body])
 814 pprDo (MDoExpr _) stmts body = ptext SLIT("mdo") <+> pprDeeperList vcat (map ppr stmts ++ [ppr body])
 815 pprDo ListComp    stmts body = pprComp brackets    stmts body
 816 pprDo PArrComp    stmts body = pprComp pa_brackets stmts body
 817 pprDo other       stmts body = panic "pprDo"    -- PatGuard, ParStmtCxt
 818
 819 pprComp :: OutputableBndr id => (SDoc -> SDoc) -> [LStmt id] -> LHsExpr id -> SDoc
 820 pprComp brack quals body
 821   = brack $
 822         hang (ppr body <+> char '|')
 823              4 (interpp'SP quals)
 824 \end{code}
 825
 826 %************************************************************************
 827 %*                                                                      *
 828                 Template Haskell quotation brackets
 829 %*                                                                      *
 830 %************************************************************************
 831
 832 \begin{code}
 833 data HsSplice id  = HsSplice    --  $z  or $(f 4)
 834                         id              -- The id is just a unique name to
 835                         (LHsExpr id)    -- identify this splice point
 836
 837 instance OutputableBndr id => Outputable (HsSplice id) where
 838   ppr = pprSplice
 839
 840 pprSplice :: OutputableBndr id => HsSplice id -> SDoc
 841 pprSplice (HsSplice n e) = char '$' <> brackets (ppr n) <> pprParendExpr e
 842
 843
 844 data HsBracket id = ExpBr (LHsExpr id)          -- [|  expr  |]
 845                   | PatBr (LPat id)             -- [p| pat   |]
 846                   | DecBr (HsGroup id)          -- [d| decls |]
 847                   | TypBr (LHsType id)          -- [t| type  |]
 848                   | VarBr id                    -- 'x, ''T
 849
 850 instance OutputableBndr id => Outputable (HsBracket id) where
 851   ppr = pprHsBracket
 852
 853
 854 pprHsBracket (ExpBr e) = thBrackets empty (ppr e)
 855 pprHsBracket (PatBr p) = thBrackets (char 'p') (ppr p)
 856 pprHsBracket (DecBr d) = thBrackets (char 'd') (ppr d)
 857 pprHsBracket (TypBr t) = thBrackets (char 't') (ppr t)
 858 pprHsBracket (VarBr n) = char '\'' <> ppr n
 859         -- Infelicity: can't show ' vs '', because
 860         -- we can't ask n what its OccName is, because the
 861         -- pretty-printer for HsExpr doesn't ask for NamedThings
 862         -- But the pretty-printer for names will show the OccName class
 863
 864 thBrackets pp_kind pp_body = char '[' <> pp_kind <> char '|' <+>
 865                              pp_body <+> ptext SLIT("|]")
 866 \end{code}
 867
 868 %************************************************************************
 869 %*                                                                      *
 870 \subsection{Enumerations and list comprehensions}
 871 %*                                                                      *
 872 %************************************************************************
 873
 874 \begin{code}
 875 data ArithSeqInfo id
 876   = From            (LHsExpr id)
 877   | FromThen        (LHsExpr id)
 878                     (LHsExpr id)
 879   | FromTo          (LHsExpr id)
 880                     (LHsExpr id)
 881   | FromThenTo      (LHsExpr id)
 882                     (LHsExpr id)
 883                     (LHsExpr id)
 884 \end{code}
 885
 886 \begin{code}
 887 instance OutputableBndr id => Outputable (ArithSeqInfo id) where
 888     ppr (From e1)               = hcat [ppr e1, pp_dotdot]
 889     ppr (FromThen e1 e2)        = hcat [ppr e1, comma, space, ppr e2, pp_dotdot]
 890     ppr (FromTo e1 e3)  = hcat [ppr e1, pp_dotdot, ppr e3]
 891     ppr (FromThenTo e1 e2 e3)
 892       = hcat [ppr e1, comma, space, ppr e2, pp_dotdot, ppr e3]
 893
 894 pp_dotdot = ptext SLIT(" .. ")
 895 \end{code}
 896
 897
 898 %************************************************************************
 899 %*                                                                      *
 900 \subsection{HsMatchCtxt}
 901 %*                                                                      *
 902 %************************************************************************
 903
 904 \begin{code}
 905 data HsMatchContext id  -- Context of a Match
 906   = FunRhs id                   -- Function binding for f
 907   | CaseAlt                     -- Guard on a case alternative
 908   | LambdaExpr                  -- Pattern of a lambda
 909   | ProcExpr                    -- Pattern of a proc
 910   | PatBindRhs                  -- Pattern binding
 911   | RecUpd                      -- Record update [used only in DsExpr to tell matchWrapper
 912                                 --      what sort of runtime error message to generate]
 913   | StmtCtxt (HsStmtContext id) -- Pattern of a do-stmt or list comprehension
 914   deriving ()
 915
 916 data HsStmtContext id
 917   = ListComp
 918   | DoExpr
 919   | MDoExpr PostTcTable                 -- Recursive do-expression
 920                                         -- (tiresomely, it needs table
 921                                         --  of its return/bind ops)
 922   | PArrComp                            -- Parallel array comprehension
 923   | PatGuard (HsMatchContext id)        -- Pattern guard for specified thing
 924   | ParStmtCtxt (HsStmtContext id)      -- A branch of a parallel stmt
 925 \end{code}
 926
 927 \begin{code}
 928 isDoExpr :: HsStmtContext id -> Bool
 929 isDoExpr DoExpr      = True
 930 isDoExpr (MDoExpr _) = True
 931 isDoExpr _           = False
 932
 933 isListCompExpr :: HsStmtContext id -> Bool
 934 isListCompExpr ListComp = True
 935 isListCompExpr PArrComp = True
 936 isListCompExpr _        = False
 937 \end{code}
 938
 939 \begin{code}
 940 matchSeparator (FunRhs _)   = ptext SLIT("=")
 941 matchSeparator CaseAlt      = ptext SLIT("->")
 942 matchSeparator LambdaExpr   = ptext SLIT("->")
 943 matchSeparator ProcExpr     = ptext SLIT("->")
 944 matchSeparator PatBindRhs   = ptext SLIT("=")
 945 matchSeparator (StmtCtxt _) = ptext SLIT("<-")
 946 matchSeparator RecUpd       = panic "unused"
 947 \end{code}
 948
 949 \begin{code}
 950 pprMatchContext (FunRhs fun)      = ptext SLIT("the definition of") <+> quotes (ppr fun)
 951 pprMatchContext CaseAlt           = ptext SLIT("a case alternative")
 952 pprMatchContext RecUpd            = ptext SLIT("a record-update construct")
 953 pprMatchContext PatBindRhs        = ptext SLIT("a pattern binding")
 954 pprMatchContext LambdaExpr        = ptext SLIT("a lambda abstraction")
 955 pprMatchContext ProcExpr          = ptext SLIT("an arrow abstraction")
 956 pprMatchContext (StmtCtxt ctxt)   = ptext SLIT("a pattern binding in") $$ pprStmtContext ctxt
 957
 958 pprStmtContext (ParStmtCtxt c) = sep [ptext SLIT("a parallel branch of"), pprStmtContext c]
 959 pprStmtContext (PatGuard ctxt) = ptext SLIT("a pattern guard for") $$ pprMatchContext ctxt
 960 pprStmtContext DoExpr          = ptext SLIT("a 'do' expression")
 961 pprStmtContext (MDoExpr _)     = ptext SLIT("an 'mdo' expression")
 962 pprStmtContext ListComp        = ptext SLIT("a list comprehension")
 963 pprStmtContext PArrComp        = ptext SLIT("an array comprehension")
 964
 965 {-
 966 pprMatchRhsContext (FunRhs fun) = ptext SLIT("a right-hand side of function") <+> quotes (ppr fun)
 967 pprMatchRhsContext CaseAlt      = ptext SLIT("the body of a case alternative")
 968 pprMatchRhsContext PatBindRhs   = ptext SLIT("the right-hand side of a pattern binding")
 969 pprMatchRhsContext LambdaExpr   = ptext SLIT("the body of a lambda")
 970 pprMatchRhsContext ProcExpr     = ptext SLIT("the body of a proc")
 971 pprMatchRhsContext other        = panic "pprMatchRhsContext"    -- RecUpd, StmtCtxt
 972
 973 -- Used for the result statement of comprehension
 974 -- e.g. the 'e' in      [ e | ... ]
 975 --      or the 'r' in   f x = r
 976 pprStmtResultContext (PatGuard ctxt) = pprMatchRhsContext ctxt
 977 pprStmtResultContext other           = ptext SLIT("the result of") <+> pprStmtContext other
 978 -}
 979
 980 -- Used to generate the string for a *runtime* error message
 981 matchContextErrString (FunRhs fun)               = "function " ++ showSDoc (ppr fun)
 982 matchContextErrString CaseAlt                    = "case"
 983 matchContextErrString PatBindRhs                 = "pattern binding"
 984 matchContextErrString RecUpd                     = "record update"
 985 matchContextErrString LambdaExpr                 = "lambda"
 986 matchContextErrString ProcExpr                   = "proc"
 987 matchContextErrString (StmtCtxt (ParStmtCtxt c)) = matchContextErrString (StmtCtxt c)
 988 matchContextErrString (StmtCtxt (PatGuard _))    = "pattern guard"
 989 matchContextErrString (StmtCtxt DoExpr)          = "'do' expression"
 990 matchContextErrString (StmtCtxt (MDoExpr _))     = "'mdo' expression"
 991 matchContextErrString (StmtCtxt ListComp)        = "list comprehension"
 992 matchContextErrString (StmtCtxt PArrComp)        = "array comprehension"
 993 \end{code}