compiler/hsSyn/HsExpr.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 HsExpr: Abstract Haskell syntax: expressions
   7
   8 \begin{code}
   9 module HsExpr where
  10
  11 #include "HsVersions.h"
  12
  13 -- friends:
  14 import HsDecls
  15 import HsPat
  16 import HsLit
  17 import HsTypes
  18 import HsImpExp
  19 import HsBinds
  20
  21 -- others:
  22 import Var
  23 import Name
  24 import BasicTypes
  25 import DataCon
  26 import SrcLoc
  27 import Outputable
  28 import FastString
  29 \end{code}
  30
  31
  32 %************************************************************************
  33 %*                                                                      *
  34 \subsection{Expressions proper}
  35 %*                                                                      *
  36 %************************************************************************
  37
  38 \begin{code}
  39 type LHsExpr id = Located (HsExpr id)
  40
  41 -------------------------
  42 -- PostTcExpr is an evidence expression attached to the
  43 -- syntax tree by the type checker (c.f. postTcType)
  44 -- We use a PostTcTable where there are a bunch of pieces of
  45 -- evidence, more than is convenient to keep individually
  46 type PostTcExpr  = HsExpr Id
  47 type PostTcTable = [(Name, Id)]
  48
  49 noPostTcExpr :: PostTcExpr
  50 noPostTcExpr = HsLit (HsString FSLIT("noPostTcExpr"))
  51
  52 noPostTcTable :: PostTcTable
  53 noPostTcTable = []
  54
  55 -------------------------
  56 -- SyntaxExpr is like PostTcExpr, but it's filled in a little earlier,
  57 -- by the renamer.  It's used for rebindable syntax.
  58 -- E.g. (>>=) is filled in before the renamer by the appropriate Name
  59 --      for (>>=), and then instantiated by the type checker with its
  60 --      type args tec
  61
  62 type SyntaxExpr id = HsExpr id
  63
  64 noSyntaxExpr :: SyntaxExpr id   -- Before renaming, and sometimes after,
  65                                 -- (if the syntax slot makes no sense)
  66 noSyntaxExpr = HsLit (HsString FSLIT("noSyntaxExpr"))
  67
  68
  69 type SyntaxTable id = [(Name, SyntaxExpr id)]
  70 --      *** Currently used only for CmdTop (sigh) ***
  71 -- * Before the renamer, this list is noSyntaxTable
  72 --
  73 -- * After the renamer, it takes the form [(std_name, HsVar actual_name)]
  74 --   For example, for the 'return' op of a monad
  75 --      normal case:            (GHC.Base.return, HsVar GHC.Base.return)
  76 --      with rebindable syntax: (GHC.Base.return, return_22)
  77 --              where return_22 is whatever "return" is in scope
  78 --
  79 -- * After the type checker, it takes the form [(std_name, <expression>)]
  80 --      where <expression> is the evidence for the method
  81
  82 noSyntaxTable :: SyntaxTable id
  83 noSyntaxTable = []
  84
  85
  86 -------------------------
  87 data HsExpr id
  88   = HsVar       id              -- variable
  89   | HsIPVar     (IPName id)     -- implicit parameter
  90   | HsOverLit   (HsOverLit id)  -- Overloaded literals
  91   | HsLit       HsLit           -- Simple (non-overloaded) literals
  92
  93   | HsLam       (MatchGroup  id)        -- Currently always a single match
  94
  95   | HsApp       (LHsExpr id)            -- Application
  96                 (LHsExpr id)
  97
  98   -- Operator applications:
  99   -- NB Bracketed ops such as (+) come out as Vars.
 100
 101   -- NB We need an expr for the operator in an OpApp/Section since
 102   -- the typechecker may need to apply the operator to a few types.
 103
 104   | OpApp       (LHsExpr id)    -- left operand
 105                 (LHsExpr id)    -- operator
 106                 Fixity          -- Renamer adds fixity; bottom until then
 107                 (LHsExpr id)    -- right operand
 108
 109   | NegApp      (LHsExpr id)    -- negated expr
 110                 (SyntaxExpr id) -- Name of 'negate'
 111
 112   | HsPar       (LHsExpr id)    -- parenthesised expr
 113
 114   | SectionL    (LHsExpr id)    -- operand
 115                 (LHsExpr id)    -- operator
 116   | SectionR    (LHsExpr id)    -- operator
 117                 (LHsExpr id)    -- operand
 118
 119   | HsCase      (LHsExpr id)
 120                 (MatchGroup id)
 121
 122   | HsIf        (LHsExpr id)    --  predicate
 123                 (LHsExpr id)    --  then part
 124                 (LHsExpr id)    --  else part
 125
 126   | HsLet       (HsLocalBinds id) -- let(rec)
 127                 (LHsExpr  id)
 128
 129   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 130                                         -- because in this context we never use
 131                                         -- the PatGuard or ParStmt variant
 132                 [LStmt id]              -- "do":one or more stmts
 133                 (LHsExpr id)            -- The body; the last expression in the 'do'
 134                                         --           of [ body | ... ] in a list comp
 135                 PostTcType              -- Type of the whole expression
 136
 137   | ExplicitList                -- syntactic list
 138                 PostTcType      -- Gives type of components of list
 139                 [LHsExpr id]
 140
 141   | ExplicitPArr                -- syntactic parallel array: [:e1, ..., en:]
 142                 PostTcType      -- type of elements of the parallel array
 143                 [LHsExpr id]
 144
 145   | ExplicitTuple               -- tuple
 146                 [LHsExpr id]
 147                                 -- NB: Unit is ExplicitTuple []
 148                                 -- for tuples, we can get the types
 149                                 -- direct from the components
 150                 Boxity
 151
 152
 153         -- Record construction
 154   | RecordCon   (Located id)            -- The constructor.  After type checking
 155                                         -- it's the dataConWrapId of the constructor
 156                 PostTcExpr              -- Data con Id applied to type args
 157                 (HsRecordBinds id)
 158
 159         -- Record update
 160   | RecordUpd   (LHsExpr id)
 161                 (HsRecordBinds id)
 162                 [DataCon]               -- Filled in by the type checker to the *non-empty*
 163                                         -- list of DataCons that have all the upd'd fields
 164                 [PostTcType]            -- Argument types of *input* record type
 165                 [PostTcType]            --              and  *output* record type
 166         -- For a type family, the arg types are of the *instance* tycon, not the family tycon
 167
 168   | ExprWithTySig                       -- e :: type
 169                 (LHsExpr id)
 170                 (LHsType id)
 171
 172   | ExprWithTySigOut                    -- TRANSLATION
 173                 (LHsExpr id)
 174                 (LHsType Name)          -- Retain the signature for round-tripping purposes
 175
 176   | ArithSeq                            -- arithmetic sequence
 177                 PostTcExpr
 178                 (ArithSeqInfo id)
 179
 180   | PArrSeq                             -- arith. sequence for parallel array
 181                 PostTcExpr              -- [:e1..e2:] or [:e1, e2..e3:]
 182                 (ArithSeqInfo id)
 183
 184   | HsSCC       FastString      -- "set cost centre" (_scc_) annotation
 185                 (LHsExpr id)    -- expr whose cost is to be measured
 186
 187   | HsCoreAnn   FastString      -- hdaume: core annotation
 188                 (LHsExpr id)
 189
 190   -----------------------------------------------------------
 191   -- MetaHaskell Extensions
 192
 193   | HsBracket    (HsBracket id)
 194
 195   | HsBracketOut (HsBracket Name)       -- Output of the type checker is the *original*
 196                  [PendingSplice]        -- renamed expression, plus *typechecked* splices
 197                                         -- to be pasted back in by the desugarer
 198
 199   | HsSpliceE (HsSplice id)
 200
 201   -----------------------------------------------------------
 202   -- Arrow notation extension
 203
 204   | HsProc      (LPat id)               -- arrow abstraction, proc
 205                 (LHsCmdTop id)          -- body of the abstraction
 206                                         -- always has an empty stack
 207
 208   ---------------------------------------
 209   -- The following are commands, not expressions proper
 210
 211   | HsArrApp    -- Arrow tail, or arrow application (f -< arg)
 212         (LHsExpr id)    -- arrow expression, f
 213         (LHsExpr id)    -- input expression, arg
 214         PostTcType      -- type of the arrow expressions f,
 215                         -- of the form a t t', where arg :: t
 216         HsArrAppType    -- higher-order (-<<) or first-order (-<)
 217         Bool            -- True => right-to-left (f -< arg)
 218                         -- False => left-to-right (arg >- f)
 219
 220   | HsArrForm   -- Command formation,  (| e cmd1 .. cmdn |)
 221         (LHsExpr id)    -- the operator
 222                         -- after type-checking, a type abstraction to be
 223                         -- applied to the type of the local environment tuple
 224         (Maybe Fixity)  -- fixity (filled in by the renamer), for forms that
 225                         -- were converted from OpApp's by the renamer
 226         [LHsCmdTop id]  -- argument commands
 227
 228
 229   ---------------------------------------
 230   -- Haskell program coverage (Hpc) Support
 231
 232   | HsTick
 233      Int                                -- module-local tick number
 234      [id]                               -- variables in scope
 235      (LHsExpr id)                       -- sub-expression
 236
 237   | HsBinTick
 238      Int                                -- module-local tick number for True
 239      Int                                -- module-local tick number for False
 240      (LHsExpr id)                       -- sub-expression
 241
 242   | HsTickPragma                        -- A pragma introduced tick
 243      (FastString,(Int,Int),(Int,Int))   -- external span for this tick
 244      (LHsExpr id)
 245
 246   ---------------------------------------
 247   -- These constructors only appear temporarily in the parser.
 248   -- The renamer translates them into the Right Thing.
 249
 250   | EWildPat                    -- wildcard
 251
 252   | EAsPat      (Located id)    -- as pattern
 253                 (LHsExpr id)
 254
 255   | ELazyPat    (LHsExpr id) -- ~ pattern
 256
 257   | HsType      (LHsType id)     -- Explicit type argument; e.g  f {| Int |} x y
 258
 259   ---------------------------------------
 260   -- Finally, HsWrap appears only in typechecker output
 261
 262   |  HsWrap     HsWrapper       -- TRANSLATION
 263                 (HsExpr id)
 264
 265 type PendingSplice = (Name, LHsExpr Id) -- Typechecked splices, waiting to be
 266                                         -- pasted back in by the desugarer
 267 \end{code}
 268
 269 A @Dictionary@, unless of length 0 or 1, becomes a tuple.  A
 270 @ClassDictLam dictvars methods expr@ is, therefore:
 271 \begin{verbatim}
 272 \ x -> case x of ( dictvars-and-methods-tuple ) -> expr
 273 \end{verbatim}
 274
 275 \begin{code}
 276 instance OutputableBndr id => Outputable (HsExpr id) where
 277     ppr expr = pprExpr expr
 278 \end{code}
 279
 280 \begin{code}
 281 -- pprExpr and pprLExpr call pprDeeper;
 282 -- the underscore versions do not
 283 pprExpr :: OutputableBndr id => HsExpr id -> SDoc
 284 pprExpr  e = pprDeeper (ppr_expr e)
 285
 286 pprLExpr :: OutputableBndr id => LHsExpr id -> SDoc
 287 pprLExpr e = pprDeeper (ppr_expr (unLoc e))
 288
 289 pprBinds :: OutputableBndr id => HsLocalBinds id -> SDoc
 290 pprBinds b = pprDeeper (ppr b)
 291
 292 ppr_lexpr :: OutputableBndr id => LHsExpr id -> SDoc
 293 ppr_lexpr e = ppr_expr (unLoc e)
 294
 295 ppr_expr (HsVar v)       = pprHsVar v
 296 ppr_expr (HsIPVar v)     = ppr v
 297 ppr_expr (HsLit lit)     = ppr lit
 298 ppr_expr (HsOverLit lit) = ppr lit
 299 ppr_expr (HsPar e)       = parens (ppr_lexpr e)
 300
 301 ppr_expr (HsCoreAnn s e)
 302   = vcat [ptext SLIT("HsCoreAnn") <+> ftext s, ppr_lexpr e]
 303
 304 ppr_expr (HsApp e1 e2)
 305   = let (fun, args) = collect_args e1 [e2] in
 306     hang (ppr_lexpr fun) 2 (sep (map pprParendExpr args))
 307   where
 308     collect_args (L _ (HsApp fun arg)) args = collect_args fun (arg:args)
 309     collect_args fun args = (fun, args)
 310
 311 ppr_expr (OpApp e1 op fixity e2)
 312   = case unLoc op of
 313       HsVar v -> pp_infixly v
 314       _       -> pp_prefixly
 315   where
 316     pp_e1 = pprParendExpr e1            -- Add parens to make precedence clear
 317     pp_e2 = pprParendExpr e2
 318
 319     pp_prefixly
 320       = hang (ppr op) 2 (sep [pp_e1, pp_e2])
 321
 322     pp_infixly v
 323       = sep [nest 2 pp_e1, pprInfix v, nest 2 pp_e2]
 324
 325 ppr_expr (NegApp e _) = char '-' <+> pprParendExpr e
 326
 327 ppr_expr (SectionL expr op)
 328   = case unLoc op of
 329       HsVar v -> pp_infixly v
 330       _       -> pp_prefixly
 331   where
 332     pp_expr = pprParendExpr expr
 333
 334     pp_prefixly = hang (hsep [text " \\ x_ ->", ppr op])
 335                        4 (hsep [pp_expr, ptext SLIT("x_ )")])
 336     pp_infixly v = parens (sep [pp_expr, pprInfix v])
 337
 338 ppr_expr (SectionR op expr)
 339   = case unLoc op of
 340       HsVar v -> pp_infixly v
 341       _       -> pp_prefixly
 342   where
 343     pp_expr = pprParendExpr expr
 344
 345     pp_prefixly = hang (hsep [text "( \\ x_ ->", ppr op, ptext SLIT("x_")])
 346                        4 ((<>) pp_expr rparen)
 347     pp_infixly v
 348       = parens (sep [pprInfix v, pp_expr])
 349
 350 ppr_expr (HsLam matches)
 351   = pprMatches LambdaExpr matches
 352
 353 ppr_expr (HsCase expr matches)
 354   = sep [ sep [ptext SLIT("case"), nest 4 (ppr expr), ptext SLIT("of")],
 355             nest 2 (pprMatches CaseAlt matches) ]
 356
 357 ppr_expr (HsIf e1 e2 e3)
 358   = sep [hsep [ptext SLIT("if"), nest 2 (ppr e1), ptext SLIT("then")],
 359            nest 4 (ppr e2),
 360            ptext SLIT("else"),
 361            nest 4 (ppr e3)]
 362
 363 -- special case: let ... in let ...
 364 ppr_expr (HsLet binds expr@(L _ (HsLet _ _)))
 365   = sep [hang (ptext SLIT("let")) 2 (hsep [pprBinds binds, ptext SLIT("in")]),
 366          ppr_lexpr expr]
 367
 368 ppr_expr (HsLet binds expr)
 369   = sep [hang (ptext SLIT("let")) 2 (pprBinds binds),
 370          hang (ptext SLIT("in"))  2 (ppr expr)]
 371
 372 ppr_expr (HsDo do_or_list_comp stmts body _) = pprDo do_or_list_comp stmts body
 373
 374 ppr_expr (ExplicitList _ exprs)
 375   = brackets (pprDeeperList fsep (punctuate comma (map ppr_lexpr exprs)))
 376
 377 ppr_expr (ExplicitPArr _ exprs)
 378   = pa_brackets (pprDeeperList fsep (punctuate comma (map ppr_lexpr exprs)))
 379
 380 ppr_expr (ExplicitTuple exprs boxity)
 381   = tupleParens boxity (pprDeeperList sep (punctuate comma (map ppr_lexpr exprs)))
 382
 383 ppr_expr (RecordCon con_id con_expr rbinds)
 384   = pp_rbinds (ppr con_id) rbinds
 385
 386 ppr_expr (RecordUpd aexp rbinds _ _ _)
 387   = pp_rbinds (pprParendExpr aexp) rbinds
 388
 389 ppr_expr (ExprWithTySig expr sig)
 390   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 391          4 (ppr sig)
 392 ppr_expr (ExprWithTySigOut expr sig)
 393   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 394          4 (ppr sig)
 395
 396 ppr_expr (ArithSeq expr info) = brackets (ppr info)
 397 ppr_expr (PArrSeq expr info)  = pa_brackets (ppr info)
 398
 399 ppr_expr EWildPat     = char '_'
 400 ppr_expr (ELazyPat e) = char '~' <> pprParendExpr e
 401 ppr_expr (EAsPat v e) = ppr v <> char '@' <> pprParendExpr e
 402
 403 ppr_expr (HsSCC lbl expr)
 404   = sep [ ptext SLIT("_scc_") <+> doubleQuotes (ftext lbl), pprParendExpr expr ]
 405
 406 ppr_expr (HsWrap co_fn e) = pprHsWrapper (ppr_expr e) co_fn
 407 ppr_expr (HsType id)        = ppr id
 408
 409 ppr_expr (HsSpliceE s)       = pprSplice s
 410 ppr_expr (HsBracket b)       = pprHsBracket b
 411 ppr_expr (HsBracketOut e []) = ppr e
 412 ppr_expr (HsBracketOut e ps) = ppr e $$ ptext SLIT("pending") <+> ppr ps
 413
 414 ppr_expr (HsProc pat (L _ (HsCmdTop cmd _ _ _)))
 415   = hsep [ptext SLIT("proc"), ppr pat, ptext SLIT("->"), ppr cmd]
 416
 417 ppr_expr (HsTick tickId vars exp)
 418   = hcat [ptext SLIT("tick<"), ppr tickId,ptext SLIT(">("), hsep (map pprHsVar vars), ppr exp,ptext SLIT(")")]
 419 ppr_expr (HsBinTick tickIdTrue tickIdFalse exp)
 420   = hcat [ptext SLIT("bintick<"),
 421           ppr tickIdTrue,
 422           ptext SLIT(","),
 423           ppr tickIdFalse,
 424           ptext SLIT(">("),
 425           ppr exp,ptext SLIT(")")]
 426 ppr_expr (HsTickPragma externalSrcLoc exp)
 427   = hcat [ptext SLIT("tickpragma<"), ppr externalSrcLoc,ptext SLIT(">("), ppr exp,ptext SLIT(")")]
 428
 429 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp True)
 430   = hsep [ppr_lexpr arrow, ptext SLIT("-<"), ppr_lexpr arg]
 431 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp False)
 432   = hsep [ppr_lexpr arg, ptext SLIT(">-"), ppr_lexpr arrow]
 433 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp True)
 434   = hsep [ppr_lexpr arrow, ptext SLIT("-<<"), ppr_lexpr arg]
 435 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp False)
 436   = hsep [ppr_lexpr arg, ptext SLIT(">>-"), ppr_lexpr arrow]
 437
 438 ppr_expr (HsArrForm (L _ (HsVar v)) (Just _) [arg1, arg2])
 439   = sep [pprCmdArg (unLoc arg1), hsep [pprInfix v, pprCmdArg (unLoc arg2)]]
 440 ppr_expr (HsArrForm op _ args)
 441   = hang (ptext SLIT("(|") <> ppr_lexpr op)
 442          4 (sep (map (pprCmdArg.unLoc) args) <> ptext SLIT("|)"))
 443
 444 pprCmdArg :: OutputableBndr id => HsCmdTop id -> SDoc
 445 pprCmdArg (HsCmdTop cmd@(L _ (HsArrForm _ Nothing [])) _ _ _)
 446   = ppr_lexpr cmd
 447 pprCmdArg (HsCmdTop cmd _ _ _)
 448   = parens (ppr_lexpr cmd)
 449
 450 -- Put a var in backquotes if it's not an operator already
 451 pprInfix :: Outputable name => name -> SDoc
 452 pprInfix v | isOperator ppr_v = ppr_v
 453            | otherwise        = char '`' <> ppr_v <> char '`'
 454            where
 455              ppr_v = ppr v
 456
 457 -- add parallel array brackets around a document
 458 --
 459 pa_brackets :: SDoc -> SDoc
 460 pa_brackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 461 \end{code}
 462
 463 Parenthesize unless very simple:
 464 \begin{code}
 465 pprParendExpr :: OutputableBndr id => LHsExpr id -> SDoc
 466 pprParendExpr expr
 467   = let
 468         pp_as_was = pprLExpr expr
 469         -- Using pprLExpr makes sure that we go 'deeper'
 470         -- I think that is usually (always?) right
 471     in
 472     case unLoc expr of
 473       HsLit l           -> ppr l
 474       HsOverLit l       -> ppr l
 475
 476       HsVar _           -> pp_as_was
 477       HsIPVar _         -> pp_as_was
 478       ExplicitList _ _  -> pp_as_was
 479       ExplicitPArr _ _  -> pp_as_was
 480       ExplicitTuple _ _ -> pp_as_was
 481       HsPar _           -> pp_as_was
 482       HsBracket _       -> pp_as_was
 483       HsBracketOut _ [] -> pp_as_was
 484       _                 -> parens pp_as_was
 485 \end{code}
 486
 487 %************************************************************************
 488 %*                                                                      *
 489 \subsection{Commands (in arrow abstractions)}
 490 %*                                                                      *
 491 %************************************************************************
 492
 493 We re-use HsExpr to represent these.
 494
 495 \begin{code}
 496 type HsCmd id = HsExpr id
 497
 498 type LHsCmd id = LHsExpr id
 499
 500 data HsArrAppType = HsHigherOrderApp | HsFirstOrderApp
 501 \end{code}
 502
 503 The legal constructors for commands are:
 504
 505   = HsArrApp ...                -- as above
 506
 507   | HsArrForm ...               -- as above
 508
 509   | HsApp       (HsCmd id)
 510                 (HsExpr id)
 511
 512   | HsLam       (Match  id)     -- kappa
 513
 514   -- the renamer turns this one into HsArrForm
 515   | OpApp       (HsExpr id)     -- left operand
 516                 (HsCmd id)      -- operator
 517                 Fixity          -- Renamer adds fixity; bottom until then
 518                 (HsCmd id)      -- right operand
 519
 520   | HsPar       (HsCmd id)      -- parenthesised command
 521
 522   | HsCase      (HsExpr id)
 523                 [Match id]      -- bodies are HsCmd's
 524                 SrcLoc
 525
 526   | HsIf        (HsExpr id)     --  predicate
 527                 (HsCmd id)      --  then part
 528                 (HsCmd id)      --  else part
 529                 SrcLoc
 530
 531   | HsLet       (HsLocalBinds id)       -- let(rec)
 532                 (HsCmd  id)
 533
 534   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 535                                         -- because in this context we never use
 536                                         -- the PatGuard or ParStmt variant
 537                 [Stmt id]       -- HsExpr's are really HsCmd's
 538                 PostTcType      -- Type of the whole expression
 539                 SrcLoc
 540
 541 Top-level command, introducing a new arrow.
 542 This may occur inside a proc (where the stack is empty) or as an
 543 argument of a command-forming operator.
 544
 545 \begin{code}
 546 type LHsCmdTop id = Located (HsCmdTop id)
 547
 548 data HsCmdTop id
 549   = HsCmdTop    (LHsCmd id)
 550                 [PostTcType]    -- types of inputs on the command's stack
 551                 PostTcType      -- return type of the command
 552                 (SyntaxTable id)
 553                                 -- after type checking:
 554                                 -- names used in the command's desugaring
 555 \end{code}
 556
 557 %************************************************************************
 558 %*                                                                      *
 559 \subsection{Record binds}
 560 %*                                                                      *
 561 %************************************************************************
 562
 563 \begin{code}
 564 data HsRecordBinds id = HsRecordBinds [(Located id, LHsExpr id)]
 565
 566 recBindFields :: HsRecordBinds id -> [id]
 567 recBindFields (HsRecordBinds rbinds) = [unLoc field | (field,_) <- rbinds]
 568
 569 pp_rbinds :: OutputableBndr id => SDoc -> HsRecordBinds id -> SDoc
 570 pp_rbinds thing (HsRecordBinds rbinds)
 571   = hang thing
 572          4 (braces (pprDeeperList sep (punctuate comma (map (pp_rbind) rbinds))))
 573   where
 574     pp_rbind (v, e) = hsep [pprBndr LetBind (unLoc v), char '=', ppr e]
 575 \end{code}
 576
 577
 578
 579 %************************************************************************
 580 %*                                                                      *
 581 \subsection{@Match@, @GRHSs@, and @GRHS@ datatypes}
 582 %*                                                                      *
 583 %************************************************************************
 584
 585 @Match@es are sets of pattern bindings and right hand sides for
 586 functions, patterns or case branches. For example, if a function @g@
 587 is defined as:
 588 \begin{verbatim}
 589 g (x,y) = y
 590 g ((x:ys),y) = y+1,
 591 \end{verbatim}
 592 then \tr{g} has two @Match@es: @(x,y) = y@ and @((x:ys),y) = y+1@.
 593
 594 It is always the case that each element of an @[Match]@ list has the
 595 same number of @pats@s inside it.  This corresponds to saying that
 596 a function defined by pattern matching must have the same number of
 597 patterns in each equation.
 598
 599 \begin{code}
 600 data MatchGroup id
 601   = MatchGroup
 602         [LMatch id]     -- The alternatives
 603         PostTcType      -- The type is the type of the entire group
 604                         --      t1 -> ... -> tn -> tr
 605                         -- where there are n patterns
 606
 607 type LMatch id = Located (Match id)
 608
 609 data Match id
 610   = Match
 611         [LPat id]               -- The patterns
 612         (Maybe (LHsType id))    -- A type signature for the result of the match
 613                                 --      Nothing after typechecking
 614         (GRHSs id)
 615
 616 matchGroupArity :: MatchGroup id -> Arity
 617 matchGroupArity (MatchGroup [] _)
 618   = panic "matchGroupArity"     -- MatchGroup is never empty
 619 matchGroupArity (MatchGroup (match:matches) _)
 620   = ASSERT( all ((== n_pats) . length . hsLMatchPats) matches )
 621         -- Assertion just checks that all the matches have the same number of pats
 622     n_pats
 623   where
 624     n_pats = length (hsLMatchPats match)
 625
 626 hsLMatchPats :: LMatch id -> [LPat id]
 627 hsLMatchPats (L _ (Match pats _ _)) = pats
 628
 629 -- GRHSs are used both for pattern bindings and for Matches
 630 data GRHSs id
 631   = GRHSs [LGRHS id]            -- Guarded RHSs
 632           (HsLocalBinds id)     -- The where clause
 633
 634 type LGRHS id = Located (GRHS id)
 635
 636 data GRHS id = GRHS [LStmt id]          -- Guards
 637                     (LHsExpr id)        -- Right hand side
 638 \end{code}
 639
 640 We know the list must have at least one @Match@ in it.
 641
 642 \begin{code}
 643 pprMatches :: (OutputableBndr id) => HsMatchContext id -> MatchGroup id -> SDoc
 644 pprMatches ctxt (MatchGroup matches ty) = vcat (map (pprMatch ctxt) (map unLoc matches))
 645                                           -- Don't print the type; it's only
 646                                           -- a place-holder before typechecking
 647
 648 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 649 pprFunBind :: (OutputableBndr id) => id -> MatchGroup id -> SDoc
 650 pprFunBind fun matches = pprMatches (FunRhs fun) matches
 651
 652 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 653 pprPatBind :: (OutputableBndr bndr, OutputableBndr id)
 654            => LPat bndr -> GRHSs id -> SDoc
 655 pprPatBind pat grhss = sep [ppr pat, nest 4 (pprGRHSs PatBindRhs grhss)]
 656
 657
 658 pprMatch :: OutputableBndr id => HsMatchContext id -> Match id -> SDoc
 659 pprMatch ctxt (Match pats maybe_ty grhss)
 660   = pp_name ctxt <+> sep [sep (map ppr pats),
 661                      ppr_maybe_ty,
 662                      nest 2 (pprGRHSs ctxt grhss)]
 663   where
 664     pp_name (FunRhs fun) = ppr fun      -- Not pprBndr; the AbsBinds will
 665                                         -- have printed the signature
 666     pp_name LambdaExpr   = char '\\'
 667     pp_name other        = empty
 668
 669     ppr_maybe_ty = case maybe_ty of
 670                         Just ty -> dcolon <+> ppr ty
 671                         Nothing -> empty
 672
 673
 674 pprGRHSs :: OutputableBndr id => HsMatchContext id -> GRHSs id -> SDoc
 675 pprGRHSs ctxt (GRHSs grhss binds)
 676   = pprDeeper
 677     (vcat (map (pprGRHS ctxt . unLoc) grhss)
 678       $$
 679      if isEmptyLocalBinds binds then empty
 680      else text "where" $$ nest 4 (pprBinds binds))
 681
 682 pprGRHS :: OutputableBndr id => HsMatchContext id -> GRHS id -> SDoc
 683
 684 pprGRHS ctxt (GRHS [] expr)
 685  =  pp_rhs ctxt expr
 686
 687 pprGRHS ctxt (GRHS guards expr)
 688  = sep [char '|' <+> interpp'SP guards, pp_rhs ctxt expr]
 689
 690 pp_rhs ctxt rhs = matchSeparator ctxt <+> pprDeeper (ppr rhs)
 691 \end{code}
 692
 693 %************************************************************************
 694 %*                                                                      *
 695 \subsection{Do stmts and list comprehensions}
 696 %*                                                                      *
 697 %************************************************************************
 698
 699 \begin{code}
 700 type LStmt id = Located (Stmt id)
 701
 702 -- The SyntaxExprs in here are used *only* for do-notation, which
 703 -- has rebindable syntax.  Otherwise they are unused.
 704 data Stmt id
 705   = BindStmt    (LPat id)
 706                 (LHsExpr id)
 707                 (SyntaxExpr id)         -- The (>>=) operator
 708                 (SyntaxExpr id)         -- The fail operator
 709                 -- The fail operator is noSyntaxExpr
 710                 -- if the pattern match can't fail
 711
 712   | ExprStmt    (LHsExpr id)
 713                 (SyntaxExpr id)         -- The (>>) operator
 714                 PostTcType              -- Element type of the RHS (used for arrows)
 715
 716   | LetStmt     (HsLocalBinds id)
 717
 718         -- ParStmts only occur in a list comprehension
 719   | ParStmt     [([LStmt id], [id])]    -- After renaming, the ids are the binders
 720                                         -- bound by the stmts and used subsequently
 721
 722         -- Recursive statement (see Note [RecStmt] below)
 723   | RecStmt  [LStmt id]
 724                 --- The next two fields are only valid after renaming
 725              [id]       -- The ids are a subset of the variables bound by the stmts
 726                         -- that are used in stmts that follow the RecStmt
 727
 728              [id]       -- Ditto, but these variables are the "recursive" ones, that
 729                         -- are used before they are bound in the stmts of the RecStmt
 730                         -- From a type-checking point of view, these ones have to be monomorphic
 731
 732                 --- These fields are only valid after typechecking
 733              [PostTcExpr]       -- These expressions correspond
 734                                 -- 1-to-1 with the "recursive" [id], and are the expresions that
 735                                 -- should be returned by the recursion.  They may not quite be the
 736                                 -- Ids themselves, because the Id may be *polymorphic*, but
 737                                 -- the returned thing has to be *monomorphic*.
 738              (DictBinds id)     -- Method bindings of Ids bound by the RecStmt,
 739                                 -- and used afterwards
 740 \end{code}
 741
 742 ExprStmts are a bit tricky, because what they mean
 743 depends on the context.  Consider the following contexts:
 744
 745         A do expression of type (m res_ty)
 746         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 747         * ExprStmt E any_ty:   do { ....; E; ... }
 748                 E :: m any_ty
 749           Translation: E >> ...
 750
 751         A list comprehensions of type [elt_ty]
 752         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 753         * ExprStmt E Bool:   [ .. | .... E ]
 754                         [ .. | ..., E, ... ]
 755                         [ .. | .... | ..., E | ... ]
 756                 E :: Bool
 757           Translation: if E then fail else ...
 758
 759         A guard list, guarding a RHS of type rhs_ty
 760         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 761         * ExprStmt E Bool:   f x | ..., E, ... = ...rhs...
 762                 E :: Bool
 763           Translation: if E then fail else ...
 764
 765 Array comprehensions are handled like list comprehensions -=chak
 766
 767 Note [RecStmt]
 768 ~~~~~~~~~~~~~~
 769 Example:
 770         HsDo [ BindStmt x ex
 771
 772              , RecStmt [a::forall a. a -> a, b]
 773                        [a::Int -> Int,       c]
 774                        [ BindStmt b (return x)
 775                        , LetStmt a = ea
 776                        , BindStmt c ec ]
 777
 778              , return (a b) ]
 779
 780 Here, the RecStmt binds a,b,c; but
 781   - Only a,b are used in the stmts *following* the RecStmt,
 782         This 'a' is *polymorphic'
 783   - Only a,c are used in the stmts *inside* the RecStmt
 784         *before* their bindings
 785         This 'a' is monomorphic
 786
 787 Nota Bene: the two a's have different types, even though they
 788 have the same Name.
 789
 790
 791 \begin{code}
 792 instance OutputableBndr id => Outputable (Stmt id) where
 793     ppr stmt = pprStmt stmt
 794
 795 pprStmt (BindStmt pat expr _ _)   = hsep [ppr pat, ptext SLIT("<-"), ppr expr]
 796 pprStmt (LetStmt binds)           = hsep [ptext SLIT("let"), pprBinds binds]
 797 pprStmt (ExprStmt expr _ _)       = ppr expr
 798 pprStmt (ParStmt stmtss)          = hsep (map (\stmts -> ptext SLIT("| ") <> ppr stmts) stmtss)
 799 pprStmt (RecStmt segment _ _ _ _) = ptext SLIT("rec") <+> braces (vcat (map ppr segment))
 800
 801 pprDo :: OutputableBndr id => HsStmtContext any -> [LStmt id] -> LHsExpr id -> SDoc
 802 pprDo DoExpr      stmts body = ptext SLIT("do")  <+> pprDeeperList vcat (map ppr stmts ++ [ppr body])
 803 pprDo (MDoExpr _) stmts body = ptext SLIT("mdo") <+> pprDeeperList vcat (map ppr stmts ++ [ppr body])
 804 pprDo ListComp    stmts body = pprComp brackets    stmts body
 805 pprDo PArrComp    stmts body = pprComp pa_brackets stmts body
 806 pprDo other       stmts body = panic "pprDo"    -- PatGuard, ParStmtCxt
 807
 808 pprComp :: OutputableBndr id => (SDoc -> SDoc) -> [LStmt id] -> LHsExpr id -> SDoc
 809 pprComp brack quals body
 810   = brack $
 811         hang (ppr body <+> char '|')
 812              4 (interpp'SP quals)
 813 \end{code}
 814
 815 %************************************************************************
 816 %*                                                                      *
 817                 Template Haskell quotation brackets
 818 %*                                                                      *
 819 %************************************************************************
 820
 821 \begin{code}
 822 data HsSplice id  = HsSplice    --  $z  or $(f 4)
 823                         id              -- The id is just a unique name to
 824                         (LHsExpr id)    -- identify this splice point
 825
 826 instance OutputableBndr id => Outputable (HsSplice id) where
 827   ppr = pprSplice
 828
 829 pprSplice :: OutputableBndr id => HsSplice id -> SDoc
 830 pprSplice (HsSplice n e) = char '$' <> brackets (ppr n) <> pprParendExpr e
 831
 832
 833 data HsBracket id = ExpBr (LHsExpr id)          -- [|  expr  |]
 834                   | PatBr (LPat id)             -- [p| pat   |]
 835                   | DecBr (HsGroup id)          -- [d| decls |]
 836                   | TypBr (LHsType id)          -- [t| type  |]
 837                   | VarBr id                    -- 'x, ''T
 838
 839 instance OutputableBndr id => Outputable (HsBracket id) where
 840   ppr = pprHsBracket
 841
 842
 843 pprHsBracket (ExpBr e) = thBrackets empty (ppr e)
 844 pprHsBracket (PatBr p) = thBrackets (char 'p') (ppr p)
 845 pprHsBracket (DecBr d) = thBrackets (char 'd') (ppr d)
 846 pprHsBracket (TypBr t) = thBrackets (char 't') (ppr t)
 847 pprHsBracket (VarBr n) = char '\'' <> ppr n
 848         -- Infelicity: can't show ' vs '', because
 849         -- we can't ask n what its OccName is, because the
 850         -- pretty-printer for HsExpr doesn't ask for NamedThings
 851         -- But the pretty-printer for names will show the OccName class
 852
 853 thBrackets pp_kind pp_body = char '[' <> pp_kind <> char '|' <+>
 854                              pp_body <+> ptext SLIT("|]")
 855 \end{code}
 856
 857 %************************************************************************
 858 %*                                                                      *
 859 \subsection{Enumerations and list comprehensions}
 860 %*                                                                      *
 861 %************************************************************************
 862
 863 \begin{code}
 864 data ArithSeqInfo id
 865   = From            (LHsExpr id)
 866   | FromThen        (LHsExpr id)
 867                     (LHsExpr id)
 868   | FromTo          (LHsExpr id)
 869                     (LHsExpr id)
 870   | FromThenTo      (LHsExpr id)
 871                     (LHsExpr id)
 872                     (LHsExpr id)
 873 \end{code}
 874
 875 \begin{code}
 876 instance OutputableBndr id => Outputable (ArithSeqInfo id) where
 877     ppr (From e1)               = hcat [ppr e1, pp_dotdot]
 878     ppr (FromThen e1 e2)        = hcat [ppr e1, comma, space, ppr e2, pp_dotdot]
 879     ppr (FromTo e1 e3)  = hcat [ppr e1, pp_dotdot, ppr e3]
 880     ppr (FromThenTo e1 e2 e3)
 881       = hcat [ppr e1, comma, space, ppr e2, pp_dotdot, ppr e3]
 882
 883 pp_dotdot = ptext SLIT(" .. ")
 884 \end{code}
 885
 886
 887 %************************************************************************
 888 %*                                                                      *
 889 \subsection{HsMatchCtxt}
 890 %*                                                                      *
 891 %************************************************************************
 892
 893 \begin{code}
 894 data HsMatchContext id  -- Context of a Match
 895   = FunRhs id                   -- Function binding for f
 896   | CaseAlt                     -- Guard on a case alternative
 897   | LambdaExpr                  -- Pattern of a lambda
 898   | ProcExpr                    -- Pattern of a proc
 899   | PatBindRhs                  -- Pattern binding
 900   | RecUpd                      -- Record update [used only in DsExpr to tell matchWrapper
 901                                 --      what sort of runtime error message to generate]
 902   | StmtCtxt (HsStmtContext id) -- Pattern of a do-stmt or list comprehension
 903   deriving ()
 904
 905 data HsStmtContext id
 906   = ListComp
 907   | DoExpr
 908   | MDoExpr PostTcTable                 -- Recursive do-expression
 909                                         -- (tiresomely, it needs table
 910                                         --  of its return/bind ops)
 911   | PArrComp                            -- Parallel array comprehension
 912   | PatGuard (HsMatchContext id)        -- Pattern guard for specified thing
 913   | ParStmtCtxt (HsStmtContext id)      -- A branch of a parallel stmt
 914 \end{code}
 915
 916 \begin{code}
 917 isDoExpr :: HsStmtContext id -> Bool
 918 isDoExpr DoExpr      = True
 919 isDoExpr (MDoExpr _) = True
 920 isDoExpr other       = False
 921 \end{code}
 922
 923 \begin{code}
 924 matchSeparator (FunRhs _)   = ptext SLIT("=")
 925 matchSeparator CaseAlt      = ptext SLIT("->")
 926 matchSeparator LambdaExpr   = ptext SLIT("->")
 927 matchSeparator ProcExpr     = ptext SLIT("->")
 928 matchSeparator PatBindRhs   = ptext SLIT("=")
 929 matchSeparator (StmtCtxt _) = ptext SLIT("<-")
 930 matchSeparator RecUpd       = panic "unused"
 931 \end{code}
 932
 933 \begin{code}
 934 pprMatchContext (FunRhs fun)      = ptext SLIT("the definition of") <+> quotes (ppr fun)
 935 pprMatchContext CaseAlt           = ptext SLIT("a case alternative")
 936 pprMatchContext RecUpd            = ptext SLIT("a record-update construct")
 937 pprMatchContext PatBindRhs        = ptext SLIT("a pattern binding")
 938 pprMatchContext LambdaExpr        = ptext SLIT("a lambda abstraction")
 939 pprMatchContext ProcExpr          = ptext SLIT("an arrow abstraction")
 940 pprMatchContext (StmtCtxt ctxt)   = ptext SLIT("a pattern binding in") $$ pprStmtContext ctxt
 941
 942 pprStmtContext (ParStmtCtxt c) = sep [ptext SLIT("a parallel branch of"), pprStmtContext c]
 943 pprStmtContext (PatGuard ctxt) = ptext SLIT("a pattern guard for") $$ pprMatchContext ctxt
 944 pprStmtContext DoExpr          = ptext SLIT("a 'do' expression")
 945 pprStmtContext (MDoExpr _)     = ptext SLIT("an 'mdo' expression")
 946 pprStmtContext ListComp        = ptext SLIT("a list comprehension")
 947 pprStmtContext PArrComp        = ptext SLIT("an array comprehension")
 948
 949 {-
 950 pprMatchRhsContext (FunRhs fun) = ptext SLIT("a right-hand side of function") <+> quotes (ppr fun)
 951 pprMatchRhsContext CaseAlt      = ptext SLIT("the body of a case alternative")
 952 pprMatchRhsContext PatBindRhs   = ptext SLIT("the right-hand side of a pattern binding")
 953 pprMatchRhsContext LambdaExpr   = ptext SLIT("the body of a lambda")
 954 pprMatchRhsContext ProcExpr     = ptext SLIT("the body of a proc")
 955 pprMatchRhsContext other        = panic "pprMatchRhsContext"    -- RecUpd, StmtCtxt
 956
 957 -- Used for the result statement of comprehension
 958 -- e.g. the 'e' in      [ e | ... ]
 959 --      or the 'r' in   f x = r
 960 pprStmtResultContext (PatGuard ctxt) = pprMatchRhsContext ctxt
 961 pprStmtResultContext other           = ptext SLIT("the result of") <+> pprStmtContext other
 962 -}
 963
 964 -- Used to generate the string for a *runtime* error message
 965 matchContextErrString (FunRhs fun)               = "function " ++ showSDoc (ppr fun)
 966 matchContextErrString CaseAlt                    = "case"
 967 matchContextErrString PatBindRhs                 = "pattern binding"
 968 matchContextErrString RecUpd                     = "record update"
 969 matchContextErrString LambdaExpr                 = "lambda"
 970 matchContextErrString ProcExpr                   = "proc"
 971 matchContextErrString (StmtCtxt (ParStmtCtxt c)) = matchContextErrString (StmtCtxt c)
 972 matchContextErrString (StmtCtxt (PatGuard _))    = "pattern guard"
 973 matchContextErrString (StmtCtxt DoExpr)          = "'do' expression"
 974 matchContextErrString (StmtCtxt (MDoExpr _))     = "'mdo' expression"
 975 matchContextErrString (StmtCtxt ListComp)        = "list comprehension"
 976 matchContextErrString (StmtCtxt PArrComp)        = "array comprehension"
 977 \end{code}