compiler/hsSyn/HsPat.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[PatSyntax]{Abstract Haskell syntax---patterns}
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module HsPat (
  16         Pat(..), InPat, OutPat, LPat,
  17
  18         HsConDetails(..),
  19         HsConPatDetails, hsConPatArgs,
  20         HsRecFields(..), HsRecField(..), hsRecFields,
  21
  22         mkPrefixConPat, mkCharLitPat, mkNilPat, mkCoPat, mkCoPatCoI,
  23
  24         isBangHsBind,
  25         patsAreAllCons, isConPat, isSigPat, isWildPat,
  26         patsAreAllLits, isLitPat, isIrrefutableHsPat
  27     ) where
  28
  29 #include "HsVersions.h"
  30
  31 import {-# SOURCE #-} HsExpr            (SyntaxExpr, LHsExpr, pprLExpr)
  32
  33 -- friends:
  34 import HsBinds
  35 import HsLit
  36 import HsTypes
  37 import HsDoc
  38 import BasicTypes
  39 -- others:
  40 import Coercion
  41 import PprCore          ( {- instance OutputableBndr TyVar -} )
  42 import TysWiredIn
  43 import Var
  44 import DataCon
  45 import TyCon
  46 import Outputable
  47 import Type
  48 import SrcLoc
  49 \end{code}
  50
  51
  52 \begin{code}
  53 type InPat id  = LPat id        -- No 'Out' constructors
  54 type OutPat id = LPat id        -- No 'In' constructors
  55
  56 type LPat id = Located (Pat id)
  57
  58 data Pat id
  59   =     ------------ Simple patterns ---------------
  60     WildPat     PostTcType              -- Wild card
  61         -- The sole reason for a type on a WildPat is to
  62         -- support hsPatType :: Pat Id -> Type
  63
  64   | VarPat      id                      -- Variable
  65   | VarPatOut   id (DictBinds id)       -- Used only for overloaded Ids; the
  66                                         -- bindings give its overloaded instances
  67   | LazyPat     (LPat id)               -- Lazy pattern
  68   | AsPat       (Located id) (LPat id)  -- As pattern
  69   | ParPat      (LPat id)               -- Parenthesised pattern
  70   | BangPat     (LPat id)               -- Bang pattern
  71
  72         ------------ Lists, tuples, arrays ---------------
  73   | ListPat     [LPat id]               -- Syntactic list
  74                 PostTcType              -- The type of the elements
  75
  76   | TuplePat    [LPat id]               -- Tuple
  77                 Boxity                  -- UnitPat is TuplePat []
  78                 PostTcType
  79         -- You might think that the PostTcType was redundant, but it's essential
  80         --      data T a where
  81         --        T1 :: Int -> T Int
  82         --      f :: (T a, a) -> Int
  83         --      f (T1 x, z) = z
  84         -- When desugaring, we must generate
  85         --      f = /\a. \v::a.  case v of (t::T a, w::a) ->
  86         --                       case t of (T1 (x::Int)) ->
  87         -- Note the (w::a), NOT (w::Int), because we have not yet
  88         -- refined 'a' to Int.  So we must know that the second component
  89         -- of the tuple is of type 'a' not Int.  See selectMatchVar
  90
  91   | PArrPat     [LPat id]               -- Syntactic parallel array
  92                 PostTcType              -- The type of the elements
  93
  94         ------------ Constructor patterns ---------------
  95   | ConPatIn    (Located id)
  96                 (HsConPatDetails id)
  97
  98   | ConPatOut {
  99         pat_con   :: Located DataCon,
 100         pat_tvs   :: [TyVar],           -- Existentially bound type variables
 101                                         --   including any bound coercion variables
 102         pat_dicts :: [id],              -- Ditto dictionaries
 103         pat_binds :: DictBinds id,      -- Bindings involving those dictionaries
 104         pat_args  :: HsConPatDetails id,
 105         pat_ty    :: Type               -- The type of the pattern
 106     }
 107
 108         ------------ View patterns ---------------
 109   | ViewPat       (LHsExpr id)
 110                   (LPat id)
 111                   PostTcType        -- The overall type of the pattern
 112                                     -- (= the argument type of the view function)
 113                                     -- for hsPatType.
 114
 115         ------------ Literal and n+k patterns ---------------
 116   | LitPat          HsLit               -- Used for *non-overloaded* literal patterns:
 117                                         -- Int#, Char#, Int, Char, String, etc.
 118
 119   | NPat            (HsOverLit id)              -- ALWAYS positive
 120                     (Maybe (SyntaxExpr id))     -- Just (Name of 'negate') for negative
 121                                                 -- patterns, Nothing otherwise
 122                     (SyntaxExpr id)             -- Equality checker, of type t->t->Bool
 123
 124   | NPlusKPat       (Located id)        -- n+k pattern
 125                     (HsOverLit id)      -- It'll always be an HsIntegral
 126                     (SyntaxExpr id)     -- (>=) function, of type t->t->Bool
 127                     (SyntaxExpr id)     -- Name of '-' (see RnEnv.lookupSyntaxName)
 128
 129         ------------ Generics ---------------
 130   | TypePat         (LHsType id)        -- Type pattern for generic definitions
 131                                         -- e.g  f{| a+b |} = ...
 132                                         -- These show up only in class declarations,
 133                                         -- and should be a top-level pattern
 134
 135         ------------ Pattern type signatures ---------------
 136   | SigPatIn        (LPat id)           -- Pattern with a type signature
 137                     (LHsType id)
 138
 139   | SigPatOut       (LPat id)           -- Pattern with a type signature
 140                     Type
 141
 142         ------------ Pattern coercions (translation only) ---------------
 143   | CoPat       HsWrapper               -- If co::t1 -> t2, p::t2,
 144                                         -- then (CoPat co p) :: t1
 145                 (Pat id)                -- Why not LPat?  Ans: existing locn will do
 146                 Type                    -- Type of whole pattern, t1
 147         -- During desugaring a (CoPat co pat) turns into a cast with 'co' on
 148         -- the scrutinee, followed by a match on 'pat'
 149 \end{code}
 150
 151 HsConDetails is use for patterns/expressions *and* for data type declarations
 152
 153 \begin{code}
 154 data HsConDetails arg rec
 155   = PrefixCon [arg]             -- C p1 p2 p3
 156   | RecCon    rec               -- C { x = p1, y = p2 }
 157   | InfixCon  arg arg           -- p1 `C` p2
 158
 159 type HsConPatDetails id = HsConDetails (LPat id) (HsRecFields id (LPat id))
 160
 161 hsConPatArgs :: HsConPatDetails id -> [LPat id]
 162 hsConPatArgs (PrefixCon ps)   = ps
 163 hsConPatArgs (RecCon fs)      = map hsRecFieldArg (rec_flds fs)
 164 hsConPatArgs (InfixCon p1 p2) = [p1,p2]
 165 \end{code}
 166
 167 However HsRecFields is used only for patterns and expressions
 168 (not data type declarations)
 169
 170 \begin{code}
 171 data HsRecFields id arg         -- A bunch of record fields
 172                                 --      { x = 3, y = True }
 173         -- Used for both expressiona and patterns
 174   = HsRecFields { rec_flds   :: [HsRecField id arg],
 175                   rec_dotdot :: Maybe Int }
 176         -- Nothing => the normal case
 177         -- Just n  => the group uses ".." notation,
 178         --              and the first n elts of rec_flds
 179         --              were the user-written ones
 180         -- (In the latter case, the remaining elts of
 181         --  rec_flds are the non-user-written ones)
 182
 183 data HsRecField id arg = HsRecField {
 184         hsRecFieldId  :: Located id,
 185         hsRecFieldArg :: arg,
 186         hsRecPun      :: Bool           -- Note [Punning]
 187   }
 188
 189 -- Note [Punning]
 190 -- ~~~~~~~~~~~~~~
 191 -- If you write T { x, y = v+1 }, the HsRecFields will be
 192 --      HsRecField x x True ...
 193 --      HsRecField y (v+1) False ...
 194 -- That is, for "punned" field x is immediately expanded to x=x
 195 -- but with a punning flag so we can detect it later
 196 -- (e.g. when pretty printing)
 197
 198 hsRecFields :: HsRecFields id arg -> [id]
 199 hsRecFields rbinds = map (unLoc . hsRecFieldId) (rec_flds rbinds)
 200 \end{code}
 201
 202
 203 %************************************************************************
 204 %*                                                                      *
 205 %*              Printing patterns
 206 %*                                                                      *
 207 %************************************************************************
 208
 209 \begin{code}
 210 instance (OutputableBndr name) => Outputable (Pat name) where
 211     ppr = pprPat
 212
 213 pprPatBndr :: OutputableBndr name => name -> SDoc
 214 pprPatBndr var                  -- Print with type info if -dppr-debug is on
 215   = getPprStyle $ \ sty ->
 216     if debugStyle sty then
 217         parens (pprBndr LambdaBind var)         -- Could pass the site to pprPat
 218                                                 -- but is it worth it?
 219     else
 220         ppr var
 221
 222 pprPat :: (OutputableBndr name) => Pat name -> SDoc
 223 pprPat (VarPat var)       = pprPatBndr var
 224 pprPat (VarPatOut var bs) = parens (pprPatBndr var <+> braces (ppr bs))
 225 pprPat (WildPat _)        = char '_'
 226 pprPat (LazyPat pat)      = char '~' <> ppr pat
 227 pprPat (BangPat pat)      = char '!' <> ppr pat
 228 pprPat (AsPat name pat)   = parens (hcat [ppr name, char '@', ppr pat])
 229 pprPat (ViewPat expr pat _)   = parens (hcat [pprLExpr expr, text " -> ", ppr pat])
 230 pprPat (ParPat pat)       = parens (ppr pat)
 231 pprPat (ListPat pats _)     = brackets (interpp'SP pats)
 232 pprPat (PArrPat pats _)     = pabrackets (interpp'SP pats)
 233 pprPat (TuplePat pats bx _) = tupleParens bx (interpp'SP pats)
 234
 235 pprPat (ConPatIn con details) = pprUserCon con details
 236 pprPat (ConPatOut { pat_con = con, pat_tvs = tvs, pat_dicts = dicts,
 237                     pat_binds = binds, pat_args = details })
 238   = getPprStyle $ \ sty ->      -- Tiresome; in TcBinds.tcRhs we print out a
 239     if debugStyle sty then      -- typechecked Pat in an error message,
 240                                 -- and we want to make sure it prints nicely
 241         ppr con <+> sep [ hsep (map pprPatBndr tvs) <+> hsep (map pprPatBndr dicts),
 242                           pprLHsBinds binds, pprConArgs details]
 243     else pprUserCon con details
 244
 245 pprPat (LitPat s)             = ppr s
 246 pprPat (NPat l Nothing  _)  = ppr l
 247 pprPat (NPat l (Just _) _)  = char '-' <> ppr l
 248 pprPat (NPlusKPat n k _ _)    = hcat [ppr n, char '+', ppr k]
 249 pprPat (TypePat ty)           = ptext SLIT("{|") <> ppr ty <> ptext SLIT("|}")
 250 pprPat (CoPat co pat _)       = parens (pprHsWrapper (ppr pat) co)
 251 pprPat (SigPatIn pat ty)      = ppr pat <+> dcolon <+> ppr ty
 252 pprPat (SigPatOut pat ty)     = ppr pat <+> dcolon <+> ppr ty
 253
 254 pprUserCon c (InfixCon p1 p2) = ppr p1 <+> ppr c <+> ppr p2
 255 pprUserCon c details          = ppr c <+> pprConArgs details
 256
 257 pprConArgs (PrefixCon pats) = interppSP pats
 258 pprConArgs (InfixCon p1 p2) = interppSP [p1,p2]
 259 pprConArgs (RecCon rpats)   = ppr rpats
 260
 261 instance (OutputableBndr id, Outputable arg)
 262       => Outputable (HsRecFields id arg) where
 263   ppr (HsRecFields { rec_flds = flds, rec_dotdot = Nothing })
 264         = braces (fsep (punctuate comma (map ppr flds)))
 265   ppr (HsRecFields { rec_flds = flds, rec_dotdot = Just n })
 266         = braces (fsep (punctuate comma (map ppr (take n flds) ++ [dotdot])))
 267         where
 268           dotdot = ptext SLIT("..") <+> ifPprDebug (ppr (drop n flds))
 269
 270 instance (OutputableBndr id, Outputable arg)
 271       => Outputable (HsRecField id arg) where
 272   ppr (HsRecField { hsRecFieldId = f, hsRecFieldArg = arg,
 273                     hsRecPun = pun })
 274     = ppr f <+> (if pun then empty else equals <+> ppr arg)
 275
 276 -- add parallel array brackets around a document
 277 --
 278 pabrackets   :: SDoc -> SDoc
 279 pabrackets p  = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285 %*              Building patterns
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 \begin{code}
 290 mkPrefixConPat :: DataCon -> [OutPat id] -> Type -> OutPat id
 291 -- Make a vanilla Prefix constructor pattern
 292 mkPrefixConPat dc pats ty
 293   = noLoc $ ConPatOut { pat_con = noLoc dc, pat_tvs = [], pat_dicts = [],
 294                         pat_binds = emptyLHsBinds, pat_args = PrefixCon pats,
 295                         pat_ty = ty }
 296
 297 mkNilPat :: Type -> OutPat id
 298 mkNilPat ty = mkPrefixConPat nilDataCon [] ty
 299
 300 mkCharLitPat :: Char -> OutPat id
 301 mkCharLitPat c = mkPrefixConPat charDataCon [noLoc $ LitPat (HsCharPrim c)] charTy
 302
 303 mkCoPat :: HsWrapper -> Pat id -> Type -> Pat id
 304 mkCoPat co pat ty
 305   | isIdHsWrapper co = pat
 306   | otherwise        = CoPat co pat ty
 307
 308 mkCoPatCoI :: CoercionI -> Pat id -> Type -> Pat id
 309 mkCoPatCoI IdCo     pat ty = pat
 310 mkCoPatCoI (ACo co) pat ty = mkCoPat (WpCo co) pat ty
 311 \end{code}
 312
 313
 314 %************************************************************************
 315 %*                                                                      *
 316 %* Predicates for checking things about pattern-lists in EquationInfo   *
 317 %*                                                                      *
 318 %************************************************************************
 319
 320 \subsection[Pat-list-predicates]{Look for interesting things in patterns}
 321
 322 Unlike in the Wadler chapter, where patterns are either ``variables''
 323 or ``constructors,'' here we distinguish between:
 324 \begin{description}
 325 \item[unfailable:]
 326 Patterns that cannot fail to match: variables, wildcards, and lazy
 327 patterns.
 328
 329 These are the irrefutable patterns; the two other categories
 330 are refutable patterns.
 331
 332 \item[constructor:]
 333 A non-literal constructor pattern (see next category).
 334
 335 \item[literal patterns:]
 336 At least the numeric ones may be overloaded.
 337 \end{description}
 338
 339 A pattern is in {\em exactly one} of the above three categories; `as'
 340 patterns are treated specially, of course.
 341
 342 The 1.3 report defines what ``irrefutable'' and ``failure-free'' patterns are.
 343 \begin{code}
 344 isWildPat (WildPat _) = True
 345 isWildPat other       = False
 346
 347 patsAreAllCons :: [Pat id] -> Bool
 348 patsAreAllCons pat_list = all isConPat pat_list
 349
 350 isConPat (AsPat _ pat)   = isConPat (unLoc pat)
 351 isConPat (ConPatIn {})   = True
 352 isConPat (ConPatOut {})  = True
 353 isConPat (ListPat {})    = True
 354 isConPat (PArrPat {})    = True
 355 isConPat (TuplePat {})   = True
 356 isConPat other           = False
 357
 358 isSigPat (SigPatIn _ _)  = True
 359 isSigPat (SigPatOut _ _) = True
 360 isSigPat other           = False
 361
 362 patsAreAllLits :: [Pat id] -> Bool
 363 patsAreAllLits pat_list = all isLitPat pat_list
 364
 365 isLitPat (AsPat _ pat)          = isLitPat (unLoc pat)
 366 isLitPat (LitPat _)             = True
 367 isLitPat (NPat _ _ _)           = True
 368 isLitPat (NPlusKPat _ _ _ _)    = True
 369 isLitPat other                  = False
 370
 371 isBangHsBind :: HsBind id -> Bool
 372 -- In this module because HsPat is above HsBinds in the import graph
 373 isBangHsBind (PatBind { pat_lhs = L _ (BangPat p) }) = True
 374 isBangHsBind bind                                    = False
 375
 376 isIrrefutableHsPat :: LPat id -> Bool
 377 -- (isIrrefutableHsPat p) is true if matching against p cannot fail,
 378 -- in the sense of falling through to the next pattern.
 379 --      (NB: this is not quite the same as the (silly) defn
 380 --      in 3.17.2 of the Haskell 98 report.)
 381 --
 382 -- isIrrefutableHsPat returns False if it's in doubt; specifically
 383 -- on a ConPatIn it doesn't know the size of the constructor family
 384 -- But if it returns True, the pattern is definitely irrefutable
 385 isIrrefutableHsPat pat
 386   = go pat
 387   where
 388     go (L _ pat)         = go1 pat
 389
 390     go1 (WildPat _)         = True
 391     go1 (VarPat _)          = True
 392     go1 (VarPatOut _ _)     = True
 393     go1 (LazyPat pat)       = True
 394     go1 (BangPat pat)       = go pat
 395     go1 (CoPat _ pat _)     = go1 pat
 396     go1 (ParPat pat)        = go pat
 397     go1 (AsPat _ pat)       = go pat
 398     go1 (ViewPat _ pat _)   = go pat
 399     go1 (SigPatIn pat _)    = go pat
 400     go1 (SigPatOut pat _)   = go pat
 401     go1 (TuplePat pats _ _) = all go pats
 402     go1 (ListPat pats _)    = False
 403     go1 (PArrPat pats _)    = False     -- ?
 404
 405     go1 (ConPatIn _ _) = False  -- Conservative
 406     go1 (ConPatOut{ pat_con = L _ con, pat_args = details })
 407         =  isProductTyCon (dataConTyCon con)
 408         && all go (hsConPatArgs details)
 409
 410     go1 (LitPat _)         = False
 411     go1 (NPat _ _ _)       = False
 412     go1 (NPlusKPat _ _ _ _) = False
 413
 414     go1 (TypePat _)   = panic "isIrrefutableHsPat: type pattern"
 415 \end{code}
 416