compiler/hsSyn/HsTypes.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 HsTypes: Abstract syntax: user-defined types
   7
   8 \begin{code}
   9 module HsTypes (
  10         HsType(..), LHsType,
  11         HsTyVarBndr(..), LHsTyVarBndr,
  12         HsExplicitForAll(..),
  13         HsContext, LHsContext,
  14         HsPred(..), LHsPred,
  15
  16         LBangType, BangType, HsBang(..),
  17         getBangType, getBangStrictness,
  18
  19         mkExplicitHsForAllTy, mkImplicitHsForAllTy, hsExplicitTvs,
  20         hsTyVarName, hsTyVarNames, replaceTyVarName,
  21         hsLTyVarName, hsLTyVarNames, hsLTyVarLocName, hsLTyVarLocNames,
  22         splitHsInstDeclTy, splitHsFunType,
  23
  24         -- Type place holder
  25         PostTcType, placeHolderType,
  26
  27         -- Printing
  28         pprParendHsType, pprHsForAll, pprHsContext, ppr_hs_context, pprHsTyVarBndr
  29     ) where
  30
  31 #include "HsVersions.h"
  32
  33 import {-# SOURCE #-} HsExpr ( HsSplice, pprSplice )
  34
  35 import Type
  36 import HsDoc
  37 import BasicTypes
  38 import SrcLoc
  39 import StaticFlags
  40 import Outputable
  41 \end{code}
  42
  43
  44 %************************************************************************
  45 %*                                                                      *
  46 \subsection{Annotating the syntax}
  47 %*                                                                      *
  48 %************************************************************************
  49
  50 \begin{code}
  51 type PostTcType = Type          -- Used for slots in the abstract syntax
  52                                 -- where we want to keep slot for a type
  53                                 -- to be added by the type checker...but
  54                                 -- before typechecking it's just bogus
  55
  56 placeHolderType :: PostTcType   -- Used before typechecking
  57 placeHolderType  = panic "Evaluated the place holder for a PostTcType"
  58 \end{code}
  59
  60 %************************************************************************
  61 %*                                                                      *
  62 \subsection{Bang annotations}
  63 %*                                                                      *
  64 %************************************************************************
  65
  66 \begin{code}
  67 type LBangType name = Located (BangType name)
  68 type BangType name  = HsType name       -- Bangs are in the HsType data type
  69
  70 data HsBang = HsNoBang  -- Only used as a return value for getBangStrictness,
  71                         -- never appears on a HsBangTy
  72             | HsStrict  -- !
  73             | HsUnbox   -- {-# UNPACK #-} ! (GHC extension, meaning "unbox")
  74
  75 instance Outputable HsBang where
  76     ppr (HsNoBang) = empty
  77     ppr (HsStrict) = char '!'
  78     ppr (HsUnbox)  = ptext SLIT("!!")
  79
  80 getBangType :: LHsType a -> LHsType a
  81 getBangType (L _ (HsBangTy _ ty)) = ty
  82 getBangType ty                    = ty
  83
  84 getBangStrictness :: LHsType a -> HsBang
  85 getBangStrictness (L _ (HsBangTy s _)) = s
  86 getBangStrictness _                    = HsNoBang
  87 \end{code}
  88
  89
  90 %************************************************************************
  91 %*                                                                      *
  92 \subsection{Data types}
  93 %*                                                                      *
  94 %************************************************************************
  95
  96 This is the syntax for types as seen in type signatures.
  97
  98 \begin{code}
  99 type LHsContext name = Located (HsContext name)
 100
 101 type HsContext name = [LHsPred name]
 102
 103 type LHsPred name = Located (HsPred name)
 104
 105 data HsPred name = HsClassP name [LHsType name]
 106                  | HsIParam (IPName name) (LHsType name)
 107
 108 type LHsType name = Located (HsType name)
 109
 110 data HsType name
 111   = HsForAllTy  HsExplicitForAll        -- Renamer leaves this flag unchanged, to record the way
 112                                         -- the user wrote it originally, so that the printer can
 113                                         -- print it as the user wrote it
 114                 [LHsTyVarBndr name]     -- With ImplicitForAll, this is the empty list
 115                                         -- until the renamer fills in the variables
 116                 (LHsContext name)
 117                 (LHsType name)
 118
 119   | HsTyVar             name            -- Type variable or type constructor
 120
 121   | HsBangTy    HsBang (LHsType name)   -- Bang-style type annotations
 122
 123   | HsAppTy             (LHsType name)
 124                         (LHsType name)
 125
 126   | HsFunTy             (LHsType name)   -- function type
 127                         (LHsType name)
 128
 129   | HsListTy            (LHsType name)  -- Element type
 130
 131   | HsPArrTy            (LHsType name)  -- Elem. type of parallel array: [:t:]
 132
 133   | HsTupleTy           Boxity
 134                         [LHsType name]  -- Element types (length gives arity)
 135
 136   | HsOpTy              (LHsType name) (Located name) (LHsType name)
 137
 138   | HsParTy             (LHsType name)
 139         -- Parenthesis preserved for the precedence re-arrangement in RnTypes
 140         -- It's important that a * (b + c) doesn't get rearranged to (a*b) + c!
 141         --
 142         -- However, NB that toHsType doesn't add HsParTys (in an effort to keep
 143         -- interface files smaller), so when printing a HsType we may need to
 144         -- add parens.
 145
 146   | HsNumTy             Integer         -- Generics only
 147
 148   | HsPredTy            (HsPred name)   -- Only used in the type of an instance
 149                                         -- declaration, eg.  Eq [a] -> Eq a
 150                                         --                             ^^^^
 151                                         --                            HsPredTy
 152                                         -- Note no need for location info on the
 153                                         -- enclosed HsPred; the one on the type will do
 154
 155   | HsKindSig           (LHsType name)  -- (ty :: kind)
 156                         Kind            -- A type with a kind signature
 157
 158   | HsSpliceTy          (HsSplice name)
 159
 160   | HsDocTy             (LHsType name) (LHsDoc name) -- A documented type
 161
 162 data HsExplicitForAll = Explicit | Implicit
 163
 164 -----------------------
 165 -- Combine adjacent for-alls.
 166 -- The following awkward situation can happen otherwise:
 167 --      f :: forall a. ((Num a) => Int)
 168 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 169 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 170 -- but the export list abstracts f wrt [a].  Disaster.
 171 --
 172 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 173
 174 mkImplicitHsForAllTy     ctxt ty = mkHsForAllTy Implicit [] ctxt ty
 175 mkExplicitHsForAllTy tvs ctxt ty = mkHsForAllTy Explicit tvs ctxt ty
 176
 177 mkHsForAllTy :: HsExplicitForAll -> [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 178 -- Smart constructor for HsForAllTy
 179 mkHsForAllTy exp tvs (L _ []) ty = mk_forall_ty exp tvs ty
 180 mkHsForAllTy exp tvs ctxt ty = HsForAllTy exp tvs ctxt ty
 181
 182 -- mk_forall_ty makes a pure for-all type (no context)
 183 mk_forall_ty exp  tvs  (L _ (HsParTy ty))                   = mk_forall_ty exp tvs ty
 184 mk_forall_ty exp1 tvs1 (L _ (HsForAllTy exp2 tvs2 ctxt ty)) = mkHsForAllTy (exp1 `plus` exp2) (tvs1 ++ tvs2) ctxt ty
 185 mk_forall_ty exp  tvs  ty                                   = HsForAllTy exp tvs (L noSrcSpan []) ty
 186         -- Even if tvs is empty, we still make a HsForAll!
 187         -- In the Implicit case, this signals the place to do implicit quantification
 188         -- In the Explicit case, it prevents implicit quantification
 189         --      (see the sigtype production in Parser.y.pp)
 190         --      so that (forall. ty) isn't implicitly quantified
 191
 192 Implicit `plus` Implicit = Implicit
 193 exp1     `plus` exp2     = Explicit
 194
 195 hsExplicitTvs :: LHsType name -> [name]
 196 -- The explicitly-given forall'd type variables of a HsType
 197 hsExplicitTvs (L _ (HsForAllTy Explicit tvs _ _)) = hsLTyVarNames tvs
 198 hsExplicitTvs other                               = []
 199
 200 ---------------------
 201 type LHsTyVarBndr name = Located (HsTyVarBndr name)
 202
 203 data HsTyVarBndr name
 204   = UserTyVar name
 205   | KindedTyVar name Kind
 206         --  *** NOTA BENE *** A "monotype" in a pragma can have
 207         -- for-alls in it, (mostly to do with dictionaries).  These
 208         -- must be explicitly Kinded.
 209
 210 hsTyVarName :: HsTyVarBndr name -> name
 211 hsTyVarName (UserTyVar n)     = n
 212 hsTyVarName (KindedTyVar n _) = n
 213
 214 hsLTyVarName :: LHsTyVarBndr name -> name
 215 hsLTyVarName = hsTyVarName . unLoc
 216
 217 hsTyVarNames :: [HsTyVarBndr name] -> [name]
 218 hsTyVarNames tvs = map hsTyVarName tvs
 219
 220 hsLTyVarNames :: [LHsTyVarBndr name] -> [name]
 221 hsLTyVarNames = map hsLTyVarName
 222
 223 hsLTyVarLocName :: LHsTyVarBndr name -> Located name
 224 hsLTyVarLocName = fmap hsTyVarName
 225
 226 hsLTyVarLocNames :: [LHsTyVarBndr name] -> [Located name]
 227 hsLTyVarLocNames = map hsLTyVarLocName
 228
 229 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 230 replaceTyVarName (UserTyVar n)     n' = UserTyVar n'
 231 replaceTyVarName (KindedTyVar n k) n' = KindedTyVar n' k
 232 \end{code}
 233
 234
 235 \begin{code}
 236 splitHsInstDeclTy
 237     :: OutputableBndr name
 238     => HsType name
 239     -> ([LHsTyVarBndr name], HsContext name, name, [LHsType name])
 240         -- Split up an instance decl type, returning the pieces
 241
 242 splitHsInstDeclTy inst_ty
 243   = case inst_ty of
 244         HsParTy (L _ ty)              -> splitHsInstDeclTy ty
 245         HsForAllTy _ tvs cxt (L _ ty) -> split_tau tvs (unLoc cxt) ty
 246         other                         -> split_tau []  []          other
 247     -- The type vars should have been computed by now, even if they were implicit
 248   where
 249     split_tau tvs cxt (HsPredTy (HsClassP cls tys)) = (tvs, cxt, cls, tys)
 250     split_tau tvs cxt (HsParTy (L _ ty))            = split_tau tvs cxt ty
 251     split_tau _ _ other = pprPanic "splitHsInstDeclTy" (ppr inst_ty)
 252
 253 -- Splits HsType into the (init, last) parts
 254 -- Breaks up any parens in the result type:
 255 --      splitHsFunType (a -> (b -> c)) = ([a,b], c)
 256 splitHsFunType :: LHsType name -> ([LHsType name], LHsType name)
 257 splitHsFunType (L l (HsFunTy x y)) = (x:args, res)
 258   where
 259   (args, res) = splitHsFunType y
 260 splitHsFunType (L _ (HsParTy ty))  = splitHsFunType ty
 261 splitHsFunType other               = ([], other)
 262 \end{code}
 263
 264
 265 %************************************************************************
 266 %*                                                                      *
 267 \subsection{Pretty printing}
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 NB: these types get printed into interface files, so
 272     don't change the printing format lightly
 273
 274 \begin{code}
 275 instance (OutputableBndr name) => Outputable (HsType name) where
 276     ppr ty = pprHsType ty
 277
 278 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 279     ppr (UserTyVar name)        = ppr name
 280     ppr (KindedTyVar name kind) = pprHsTyVarBndr name kind
 281
 282 instance OutputableBndr name => Outputable (HsPred name) where
 283     ppr (HsClassP clas tys) = ppr clas <+> hsep (map (pprParendHsType.unLoc) tys)
 284     ppr (HsIParam n ty)    = hsep [ppr n, dcolon, ppr ty]
 285
 286 pprHsTyVarBndr :: Outputable name => name -> Kind -> SDoc
 287 pprHsTyVarBndr name kind | isLiftedTypeKind kind = ppr name
 288                          | otherwise             = hsep [ppr name, dcolon, pprParendKind kind]
 289
 290 pprHsForAll exp tvs cxt
 291   | show_forall = forall_part <+> pprHsContext (unLoc cxt)
 292   | otherwise   = pprHsContext (unLoc cxt)
 293   where
 294     show_forall =  opt_PprStyle_Debug
 295                 || (not (null tvs) && is_explicit)
 296     is_explicit = case exp of {Explicit -> True; Implicit -> False}
 297     forall_part = ptext SLIT("forall") <+> interppSP tvs <> dot
 298
 299 pprHsContext :: (OutputableBndr name) => HsContext name -> SDoc
 300 pprHsContext []  = empty
 301 pprHsContext cxt = ppr_hs_context cxt <+> ptext SLIT("=>")
 302
 303 ppr_hs_context []  = empty
 304 ppr_hs_context cxt = parens (interpp'SP cxt)
 305 \end{code}
 306
 307 \begin{code}
 308 pREC_TOP = (0 :: Int)  -- type   in ParseIface.y
 309 pREC_FUN = (1 :: Int)  -- btype  in ParseIface.y
 310                         -- Used for LH arg of (->)
 311 pREC_OP  = (2 :: Int)   -- Used for arg of any infix operator
 312                         -- (we don't keep their fixities around)
 313 pREC_CON = (3 :: Int)   -- Used for arg of type applicn:
 314                         -- always parenthesise unless atomic
 315
 316 maybeParen :: Int       -- Precedence of context
 317            -> Int       -- Precedence of top-level operator
 318            -> SDoc -> SDoc      -- Wrap in parens if (ctxt >= op)
 319 maybeParen ctxt_prec op_prec p | ctxt_prec >= op_prec = parens p
 320                                | otherwise            = p
 321
 322 -- printing works more-or-less as for Types
 323
 324 pprHsType, pprParendHsType :: (OutputableBndr name) => HsType name -> SDoc
 325
 326 pprHsType ty       = getPprStyle $ \sty -> ppr_mono_ty pREC_TOP (prepare sty ty)
 327 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 328
 329 -- Before printing a type
 330 -- (a) Remove outermost HsParTy parens
 331 -- (b) Drop top-level for-all type variables in user style
 332 --     since they are implicit in Haskell
 333 prepare sty (HsParTy ty)          = prepare sty (unLoc ty)
 334 prepare sty ty                    = ty
 335
 336 ppr_mono_lty ctxt_prec ty = ppr_mono_ty ctxt_prec (unLoc ty)
 337
 338 ppr_mono_ty ctxt_prec (HsForAllTy exp tvs ctxt ty)
 339   = maybeParen ctxt_prec pREC_FUN $
 340     sep [pprHsForAll exp tvs ctxt, ppr_mono_lty pREC_TOP ty]
 341
 342 -- gaw 2004
 343 ppr_mono_ty ctxt_prec (HsBangTy b ty)     = ppr b <> ppr ty
 344 ppr_mono_ty ctxt_prec (HsTyVar name)      = ppr name
 345 ppr_mono_ty ctxt_prec (HsFunTy ty1 ty2)   = ppr_fun_ty ctxt_prec ty1 ty2
 346 ppr_mono_ty ctxt_prec (HsTupleTy con tys) = tupleParens con (interpp'SP tys)
 347 ppr_mono_ty ctxt_prec (HsKindSig ty kind) = parens (ppr_mono_lty pREC_TOP ty <+> dcolon <+> pprKind kind)
 348 ppr_mono_ty ctxt_prec (HsListTy ty)       = brackets (ppr_mono_lty pREC_TOP ty)
 349 ppr_mono_ty ctxt_prec (HsPArrTy ty)       = pabrackets (ppr_mono_lty pREC_TOP ty)
 350 ppr_mono_ty ctxt_prec (HsPredTy pred)     = braces (ppr pred)
 351 ppr_mono_ty ctxt_prec (HsNumTy n)         = integer n  -- generics only
 352 ppr_mono_ty ctxt_prec (HsSpliceTy s)      = pprSplice s
 353
 354 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty)
 355   = maybeParen ctxt_prec pREC_CON $
 356     hsep [ppr_mono_lty pREC_FUN fun_ty, ppr_mono_lty pREC_CON arg_ty]
 357
 358 ppr_mono_ty ctxt_prec (HsOpTy ty1 op ty2)
 359   = maybeParen ctxt_prec pREC_OP $
 360     ppr_mono_lty pREC_OP ty1 <+> ppr op <+> ppr_mono_lty pREC_OP ty2
 361
 362 ppr_mono_ty ctxt_prec (HsParTy ty)
 363   = parens (ppr_mono_lty pREC_TOP ty)
 364   -- Put the parens in where the user did
 365   -- But we still use the precedence stuff to add parens because
 366   --    toHsType doesn't put in any HsParTys, so we may still need them
 367
 368 ppr_mono_ty ctxt_prec (HsDocTy ty doc)
 369   = ppr ty <+> ppr (unLoc doc)
 370
 371 --------------------------
 372 ppr_fun_ty ctxt_prec ty1 ty2
 373   = let p1 = ppr_mono_lty pREC_FUN ty1
 374         p2 = ppr_mono_lty pREC_TOP ty2
 375     in
 376     maybeParen ctxt_prec pREC_FUN $
 377     sep [p1, ptext SLIT("->") <+> p2]
 378
 379 --------------------------
 380 pabrackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 381 \end{code}
 382
 383