compiler/hsSyn/HsTypes.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 HsTypes: Abstract syntax: user-defined types
   7
   8 \begin{code}
   9 {-# LANGUAGE DeriveDataTypeable #-}
  10
  11 module HsTypes (
  12         HsType(..), LHsType,
  13         HsTyVarBndr(..), LHsTyVarBndr,
  14         HsExplicitFlag(..),
  15         HsContext, LHsContext,
  16         HsPred(..), LHsPred,
  17         HsQuasiQuote(..),
  18
  19         LBangType, BangType, HsBang(..),
  20         getBangType, getBangStrictness,
  21
  22         ConDeclField(..), pprConDeclFields,
  23
  24         mkExplicitHsForAllTy, mkImplicitHsForAllTy, hsExplicitTvs,
  25         hsTyVarName, hsTyVarNames, replaceTyVarName,
  26         hsTyVarKind, hsTyVarNameKind,
  27         hsLTyVarName, hsLTyVarNames, hsLTyVarLocName, hsLTyVarLocNames,
  28         splitHsInstDeclTy, splitHsFunType,
  29
  30         -- Type place holder
  31         PostTcType, placeHolderType, PostTcKind, placeHolderKind,
  32
  33         -- Printing
  34         pprParendHsType, pprHsForAll, pprHsContext, ppr_hs_context,
  35     ) where
  36
  37 import {-# SOURCE #-} HsExpr ( HsSplice, pprSplice )
  38
  39 import NameSet( FreeVars )
  40 import Type
  41 import HsDoc
  42 import BasicTypes
  43 import SrcLoc
  44 import StaticFlags
  45 import Outputable
  46 import FastString
  47
  48 import Data.Data
  49 \end{code}
  50
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection{Annotating the syntax}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 \begin{code}
  59 type PostTcKind = Kind
  60 type PostTcType = Type          -- Used for slots in the abstract syntax
  61                                 -- where we want to keep slot for a type
  62                                 -- to be added by the type checker...but
  63                                 -- before typechecking it's just bogus
  64
  65 placeHolderType :: PostTcType   -- Used before typechecking
  66 placeHolderType  = panic "Evaluated the place holder for a PostTcType"
  67
  68 placeHolderKind :: PostTcKind   -- Used before typechecking
  69 placeHolderKind  = panic "Evaluated the place holder for a PostTcKind"
  70 \end{code}
  71
  72 %************************************************************************
  73 %*                                                                      *
  74         Quasi quotes; used in types and elsewhere
  75 %*                                                                      *
  76 %************************************************************************
  77
  78 \begin{code}
  79 data HsQuasiQuote id = HsQuasiQuote
  80                            id           -- The quasi-quoter
  81                            SrcSpan      -- The span of the enclosed string
  82                            FastString   -- The enclosed string
  83   deriving (Data, Typeable)
  84
  85 instance OutputableBndr id => Outputable (HsQuasiQuote id) where
  86     ppr = ppr_qq
  87
  88 ppr_qq :: OutputableBndr id => HsQuasiQuote id -> SDoc
  89 ppr_qq (HsQuasiQuote quoter _ quote) =
  90     char '[' <> ppr quoter <> ptext (sLit "|") <>
  91     ppr quote <> ptext (sLit "|]")
  92 \end{code}
  93
  94
  95 %************************************************************************
  96 %*                                                                      *
  97 \subsection{Bang annotations}
  98 %*                                                                      *
  99 %************************************************************************
 100
 101 \begin{code}
 102 type LBangType name = Located (BangType name)
 103 type BangType name  = HsType name       -- Bangs are in the HsType data type
 104
 105 getBangType :: LHsType a -> LHsType a
 106 getBangType (L _ (HsBangTy _ ty)) = ty
 107 getBangType ty                    = ty
 108
 109 getBangStrictness :: LHsType a -> HsBang
 110 getBangStrictness (L _ (HsBangTy s _)) = s
 111 getBangStrictness _                    = HsNoBang
 112 \end{code}
 113
 114
 115 %************************************************************************
 116 %*                                                                      *
 117 \subsection{Data types}
 118 %*                                                                      *
 119 %************************************************************************
 120
 121 This is the syntax for types as seen in type signatures.
 122
 123 \begin{code}
 124 type LHsContext name = Located (HsContext name)
 125
 126 type HsContext name = [LHsPred name]
 127
 128 type LHsPred name = Located (HsPred name)
 129
 130 data HsPred name = HsClassP name [LHsType name]          -- class constraint
 131                  | HsEqualP (LHsType name) (LHsType name)-- equality constraint
 132                  | HsIParam (IPName name) (LHsType name)
 133                  deriving (Data, Typeable)
 134
 135 type LHsType name = Located (HsType name)
 136
 137 data HsType name
 138   = HsForAllTy  HsExplicitFlag          -- Renamer leaves this flag unchanged, to record the way
 139                                         -- the user wrote it originally, so that the printer can
 140                                         -- print it as the user wrote it
 141                 [LHsTyVarBndr name]     -- With ImplicitForAll, this is the empty list
 142                                         -- until the renamer fills in the variables
 143                 (LHsContext name)
 144                 (LHsType name)
 145
 146   | HsTyVar             name            -- Type variable or type constructor
 147
 148   | HsAppTy             (LHsType name)
 149                         (LHsType name)
 150
 151   | HsFunTy             (LHsType name)   -- function type
 152                         (LHsType name)
 153
 154   | HsListTy            (LHsType name)  -- Element type
 155
 156   | HsPArrTy            (LHsType name)  -- Elem. type of parallel array: [:t:]
 157
 158   | HsTupleTy           Boxity
 159                         [LHsType name]  -- Element types (length gives arity)
 160
 161   | HsOpTy              (LHsType name) (Located name) (LHsType name)
 162
 163   | HsParTy             (LHsType name)
 164         -- Parenthesis preserved for the precedence re-arrangement in RnTypes
 165         -- It's important that a * (b + c) doesn't get rearranged to (a*b) + c!
 166         --
 167         -- However, NB that toHsType doesn't add HsParTys (in an effort to keep
 168         -- interface files smaller), so when printing a HsType we may need to
 169         -- add parens.
 170
 171   | HsPredTy            (HsPred name)   -- Only used in the type of an instance
 172                                         -- declaration, eg.  Eq [a] -> Eq a
 173                                         --                             ^^^^
 174                                         --                            HsPredTy
 175                                         -- Note no need for location info on the
 176                                         -- Enclosed HsPred; the one on the type will do
 177
 178   | HsKindSig           (LHsType name)  -- (ty :: kind)
 179                         Kind            -- A type with a kind signature
 180
 181   | HsQuasiQuoteTy      (HsQuasiQuote name)
 182
 183   | HsSpliceTy          (HsSplice name)
 184                         FreeVars        -- Variables free in the splice (filled in by renamer)
 185                         PostTcKind
 186
 187   | HsDocTy             (LHsType name) LHsDocString -- A documented type
 188
 189   | HsBangTy    HsBang (LHsType name)   -- Bang-style type annotations
 190   | HsRecTy [ConDeclField name]         -- Only in data type declarations
 191
 192   | HsCoreTy Type       -- An escape hatch for tunnelling a *closed*
 193                         -- Core Type through HsSyn.
 194
 195   deriving (Data, Typeable)
 196
 197 data HsExplicitFlag = Explicit | Implicit deriving (Data, Typeable)
 198
 199 data ConDeclField name  -- Record fields have Haddoc docs on them
 200   = ConDeclField { cd_fld_name :: Located name,
 201                    cd_fld_type :: LBangType name,
 202                    cd_fld_doc  :: Maybe LHsDocString }
 203   deriving (Data, Typeable)
 204
 205 -----------------------
 206 -- Combine adjacent for-alls.
 207 -- The following awkward situation can happen otherwise:
 208 --      f :: forall a. ((Num a) => Int)
 209 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 210 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 211 -- but the export list abstracts f wrt [a].  Disaster.
 212 --
 213 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 214
 215 mkImplicitHsForAllTy ::                        LHsContext name -> LHsType name -> HsType name
 216 mkExplicitHsForAllTy :: [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 217 mkImplicitHsForAllTy     ctxt ty = mkHsForAllTy Implicit [] ctxt ty
 218 mkExplicitHsForAllTy tvs ctxt ty = mkHsForAllTy Explicit tvs ctxt ty
 219
 220 mkHsForAllTy :: HsExplicitFlag -> [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 221 -- Smart constructor for HsForAllTy
 222 mkHsForAllTy exp tvs (L _ []) ty = mk_forall_ty exp tvs ty
 223 mkHsForAllTy exp tvs ctxt ty = HsForAllTy exp tvs ctxt ty
 224
 225 -- mk_forall_ty makes a pure for-all type (no context)
 226 mk_forall_ty :: HsExplicitFlag -> [LHsTyVarBndr name] -> LHsType name -> HsType name
 227 mk_forall_ty exp  tvs  (L _ (HsParTy ty))                   = mk_forall_ty exp tvs ty
 228 mk_forall_ty exp1 tvs1 (L _ (HsForAllTy exp2 tvs2 ctxt ty)) = mkHsForAllTy (exp1 `plus` exp2) (tvs1 ++ tvs2) ctxt ty
 229 mk_forall_ty exp  tvs  ty                                   = HsForAllTy exp tvs (L noSrcSpan []) ty
 230         -- Even if tvs is empty, we still make a HsForAll!
 231         -- In the Implicit case, this signals the place to do implicit quantification
 232         -- In the Explicit case, it prevents implicit quantification
 233         --      (see the sigtype production in Parser.y.pp)
 234         --      so that (forall. ty) isn't implicitly quantified
 235
 236 plus :: HsExplicitFlag -> HsExplicitFlag -> HsExplicitFlag
 237 Implicit `plus` Implicit = Implicit
 238 _        `plus` _        = Explicit
 239
 240 hsExplicitTvs :: LHsType name -> [name]
 241 -- The explicitly-given forall'd type variables of a HsType
 242 hsExplicitTvs (L _ (HsForAllTy Explicit tvs _ _)) = hsLTyVarNames tvs
 243 hsExplicitTvs _                                   = []
 244
 245 ---------------------
 246 type LHsTyVarBndr name = Located (HsTyVarBndr name)
 247
 248 data HsTyVarBndr name
 249   = UserTyVar           -- No explicit kinding
 250          name           -- See Note [Printing KindedTyVars]
 251          PostTcKind
 252
 253   | KindedTyVar
 254          name
 255          Kind
 256       --  *** NOTA BENE *** A "monotype" in a pragma can have
 257       -- for-alls in it, (mostly to do with dictionaries).  These
 258       -- must be explicitly Kinded.
 259   deriving (Data, Typeable)
 260
 261 hsTyVarName :: HsTyVarBndr name -> name
 262 hsTyVarName (UserTyVar n _)   = n
 263 hsTyVarName (KindedTyVar n _) = n
 264
 265 hsTyVarKind :: HsTyVarBndr name -> Kind
 266 hsTyVarKind (UserTyVar _ k)   = k
 267 hsTyVarKind (KindedTyVar _ k) = k
 268
 269 hsTyVarNameKind :: HsTyVarBndr name -> (name, Kind)
 270 hsTyVarNameKind (UserTyVar n k)   = (n,k)
 271 hsTyVarNameKind (KindedTyVar n k) = (n,k)
 272
 273 hsLTyVarName :: LHsTyVarBndr name -> name
 274 hsLTyVarName = hsTyVarName . unLoc
 275
 276 hsTyVarNames :: [HsTyVarBndr name] -> [name]
 277 hsTyVarNames tvs = map hsTyVarName tvs
 278
 279 hsLTyVarNames :: [LHsTyVarBndr name] -> [name]
 280 hsLTyVarNames = map hsLTyVarName
 281
 282 hsLTyVarLocName :: LHsTyVarBndr name -> Located name
 283 hsLTyVarLocName = fmap hsTyVarName
 284
 285 hsLTyVarLocNames :: [LHsTyVarBndr name] -> [Located name]
 286 hsLTyVarLocNames = map hsLTyVarLocName
 287
 288 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 289 replaceTyVarName (UserTyVar _ k)   n' = UserTyVar n' k
 290 replaceTyVarName (KindedTyVar _ k) n' = KindedTyVar n' k
 291 \end{code}
 292
 293
 294 \begin{code}
 295 splitHsInstDeclTy
 296     :: OutputableBndr name
 297     => HsType name
 298     -> ([LHsTyVarBndr name], HsContext name, name, [LHsType name])
 299         -- Split up an instance decl type, returning the pieces
 300
 301 splitHsInstDeclTy inst_ty
 302   = case inst_ty of
 303         HsParTy (L _ ty)              -> splitHsInstDeclTy ty
 304         HsForAllTy _ tvs cxt (L _ ty) -> split_tau tvs (unLoc cxt) ty
 305         other                         -> split_tau []  []          other
 306     -- The type vars should have been computed by now, even if they were implicit
 307   where
 308     split_tau tvs cxt (HsPredTy (HsClassP cls tys)) = (tvs, cxt, cls, tys)
 309     split_tau tvs cxt (HsParTy (L _ ty))            = split_tau tvs cxt ty
 310     split_tau _ _ _ = pprPanic "splitHsInstDeclTy" (ppr inst_ty)
 311
 312 -- Splits HsType into the (init, last) parts
 313 -- Breaks up any parens in the result type:
 314 --      splitHsFunType (a -> (b -> c)) = ([a,b], c)
 315 splitHsFunType :: LHsType name -> ([LHsType name], LHsType name)
 316 splitHsFunType (L _ (HsFunTy x y)) = (x:args, res)
 317   where
 318   (args, res) = splitHsFunType y
 319 splitHsFunType (L _ (HsParTy ty))  = splitHsFunType ty
 320 splitHsFunType other               = ([], other)
 321 \end{code}
 322
 323
 324 %************************************************************************
 325 %*                                                                      *
 326 \subsection{Pretty printing}
 327 %*                                                                      *
 328 %************************************************************************
 329
 330 \begin{code}
 331 instance (OutputableBndr name) => Outputable (HsType name) where
 332     ppr ty = pprHsType ty
 333
 334 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 335     ppr (UserTyVar name _)      = ppr name
 336     ppr (KindedTyVar name kind) = hsep [ppr name, dcolon, pprParendKind kind]
 337
 338 instance OutputableBndr name => Outputable (HsPred name) where
 339     ppr (HsClassP clas tys) = ppr clas <+> hsep (map pprLHsType tys)
 340     ppr (HsEqualP t1 t2)    = hsep [pprLHsType t1, ptext (sLit "~"),
 341                                     pprLHsType t2]
 342     ppr (HsIParam n ty)     = hsep [ppr n, dcolon, ppr ty]
 343
 344 pprLHsType :: OutputableBndr name => LHsType name -> SDoc
 345 pprLHsType = pprParendHsType . unLoc
 346
 347 pprHsForAll :: OutputableBndr name => HsExplicitFlag -> [LHsTyVarBndr name] ->  LHsContext name -> SDoc
 348 pprHsForAll exp tvs cxt
 349   | show_forall = forall_part <+> pprHsContext (unLoc cxt)
 350   | otherwise   = pprHsContext (unLoc cxt)
 351   where
 352     show_forall =  opt_PprStyle_Debug
 353                 || (not (null tvs) && is_explicit)
 354     is_explicit = case exp of {Explicit -> True; Implicit -> False}
 355     forall_part = ptext (sLit "forall") <+> interppSP tvs <> dot
 356
 357 pprHsContext :: (OutputableBndr name) => HsContext name -> SDoc
 358 pprHsContext []         = empty
 359 pprHsContext [L _ pred]
 360    | noParenHsPred pred = ppr pred <+> darrow
 361 pprHsContext cxt        = ppr_hs_context cxt <+> darrow
 362
 363 noParenHsPred :: HsPred name -> Bool
 364 -- c.f. TypeRep.noParenPred
 365 noParenHsPred (HsClassP {}) = True
 366 noParenHsPred (HsEqualP {}) = True
 367 noParenHsPred (HsIParam {}) = False
 368
 369 ppr_hs_context :: (OutputableBndr name) => HsContext name -> SDoc
 370 ppr_hs_context []  = empty
 371 ppr_hs_context cxt = parens (interpp'SP cxt)
 372
 373 pprConDeclFields :: OutputableBndr name => [ConDeclField name] -> SDoc
 374 pprConDeclFields fields = braces (sep (punctuate comma (map ppr_fld fields)))
 375   where
 376     ppr_fld (ConDeclField { cd_fld_name = n, cd_fld_type = ty,
 377                             cd_fld_doc = doc })
 378         = ppr n <+> dcolon <+> ppr ty <+> ppr_mbDoc doc
 379 \end{code}
 380
 381 Note [Printing KindedTyVars]
 382 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 383 Trac #3830 reminded me that we should really only print the kind
 384 signature on a KindedTyVar if the kind signature was put there by the
 385 programmer.  During kind inference GHC now adds a PostTcKind to UserTyVars,
 386 rather than converting to KindedTyVars as before.
 387
 388 (As it happens, the message in #3830 comes out a different way now,
 389 and the problem doesn't show up; but having the flag on a KindedTyVar
 390 seems like the Right Thing anyway.)
 391
 392 \begin{code}
 393 pREC_TOP, pREC_FUN, pREC_OP, pREC_CON :: Int
 394 pREC_TOP = 0  -- type   in ParseIface.y
 395 pREC_FUN = 1  -- btype  in ParseIface.y
 396               -- Used for LH arg of (->)
 397 pREC_OP  = 2  -- Used for arg of any infix operator
 398               -- (we don't keep their fixities around)
 399 pREC_CON = 3  -- Used for arg of type applicn:
 400               -- always parenthesise unless atomic
 401
 402 maybeParen :: Int       -- Precedence of context
 403            -> Int       -- Precedence of top-level operator
 404            -> SDoc -> SDoc      -- Wrap in parens if (ctxt >= op)
 405 maybeParen ctxt_prec op_prec p | ctxt_prec >= op_prec = parens p
 406                                | otherwise            = p
 407
 408 -- printing works more-or-less as for Types
 409
 410 pprHsType, pprParendHsType :: (OutputableBndr name) => HsType name -> SDoc
 411
 412 pprHsType ty       = getPprStyle $ \sty -> ppr_mono_ty pREC_TOP (prepare sty ty)
 413 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 414
 415 -- Before printing a type
 416 -- (a) Remove outermost HsParTy parens
 417 -- (b) Drop top-level for-all type variables in user style
 418 --     since they are implicit in Haskell
 419 prepare :: PprStyle -> HsType name -> HsType name
 420 prepare sty (HsParTy ty)          = prepare sty (unLoc ty)
 421 prepare _   ty                    = ty
 422
 423 ppr_mono_lty :: (OutputableBndr name) => Int -> LHsType name -> SDoc
 424 ppr_mono_lty ctxt_prec ty = ppr_mono_ty ctxt_prec (unLoc ty)
 425
 426 ppr_mono_ty :: (OutputableBndr name) => Int -> HsType name -> SDoc
 427 ppr_mono_ty ctxt_prec (HsForAllTy exp tvs ctxt ty)
 428   = maybeParen ctxt_prec pREC_FUN $
 429     sep [pprHsForAll exp tvs ctxt, ppr_mono_lty pREC_TOP ty]
 430
 431 ppr_mono_ty _    (HsBangTy b ty)     = ppr b <> ppr ty
 432 ppr_mono_ty _    (HsQuasiQuoteTy qq) = ppr qq
 433 ppr_mono_ty _    (HsRecTy flds)      = pprConDeclFields flds
 434 ppr_mono_ty _    (HsTyVar name)      = ppr name
 435 ppr_mono_ty prec (HsFunTy ty1 ty2)   = ppr_fun_ty prec ty1 ty2
 436 ppr_mono_ty _    (HsTupleTy con tys) = tupleParens con (interpp'SP tys)
 437 ppr_mono_ty _    (HsKindSig ty kind) = parens (ppr_mono_lty pREC_TOP ty <+> dcolon <+> pprKind kind)
 438 ppr_mono_ty _    (HsListTy ty)       = brackets (ppr_mono_lty pREC_TOP ty)
 439 ppr_mono_ty _    (HsPArrTy ty)       = pabrackets (ppr_mono_lty pREC_TOP ty)
 440 ppr_mono_ty _    (HsPredTy pred)     = ppr pred
 441 ppr_mono_ty _    (HsSpliceTy s _ _)  = pprSplice s
 442 ppr_mono_ty _    (HsCoreTy ty)       = ppr ty
 443
 444 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty)
 445   = maybeParen ctxt_prec pREC_CON $
 446     hsep [ppr_mono_lty pREC_FUN fun_ty, ppr_mono_lty pREC_CON arg_ty]
 447
 448 ppr_mono_ty ctxt_prec (HsOpTy ty1 op ty2)
 449   = maybeParen ctxt_prec pREC_OP $
 450     ppr_mono_lty pREC_OP ty1 <+> ppr op <+> ppr_mono_lty pREC_OP ty2
 451
 452 ppr_mono_ty _         (HsParTy ty)
 453   = parens (ppr_mono_lty pREC_TOP ty)
 454   -- Put the parens in where the user did
 455   -- But we still use the precedence stuff to add parens because
 456   --    toHsType doesn't put in any HsParTys, so we may still need them
 457
 458 ppr_mono_ty ctxt_prec (HsDocTy ty doc)
 459   = maybeParen ctxt_prec pREC_OP $
 460     ppr_mono_lty pREC_OP ty <+> ppr (unLoc doc)
 461   -- we pretty print Haddock comments on types as if they were
 462   -- postfix operators
 463
 464 --------------------------
 465 ppr_fun_ty :: (OutputableBndr name) => Int -> LHsType name -> LHsType name -> SDoc
 466 ppr_fun_ty ctxt_prec ty1 ty2
 467   = let p1 = ppr_mono_lty pREC_FUN ty1
 468         p2 = ppr_mono_lty pREC_TOP ty2
 469     in
 470     maybeParen ctxt_prec pREC_FUN $
 471     sep [p1, ptext (sLit "->") <+> p2]
 472
 473 --------------------------
 474 pabrackets :: SDoc -> SDoc
 475 pabrackets p = ptext (sLit "[:") <> p <> ptext (sLit ":]")
 476 \end{code}
 477
 478