compiler/iface/BuildTyCl.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 module BuildTyCl (
   8         buildSynTyCon,
   9         buildAlgTyCon,
  10         buildDataCon,
  11         TcMethInfo, buildClass,
  12         mkAbstractTyConRhs,
  13         mkNewTyConRhs, mkDataTyConRhs
  14     ) where
  15
  16 #include "HsVersions.h"
  17
  18 import IfaceEnv
  19
  20 import DataCon
  21 import Var
  22 import VarSet
  23 import BasicTypes
  24 import Name
  25 import MkId
  26 import Class
  27 import TyCon
  28 import Type
  29 import Coercion
  30
  31 import TcRnMonad
  32 import Data.List        ( partition )
  33 import Outputable
  34 \end{code}
  35
  36
  37 \begin{code}
  38 ------------------------------------------------------
  39 buildSynTyCon :: Name -> [TyVar]
  40               -> SynTyConRhs
  41               -> Kind                   -- ^ Kind of the RHS
  42               -> TyConParent
  43               -> Maybe (TyCon, [Type])    -- ^ family instance if applicable
  44               -> TcRnIf m n TyCon
  45 buildSynTyCon tc_name tvs rhs rhs_kind parent mb_family
  46   | Just fam_inst_info <- mb_family
  47   = ASSERT( isNoParent parent )
  48     fixM $ \ tycon_rec -> do
  49     { fam_parent <- mkFamInstParentInfo tc_name tvs fam_inst_info tycon_rec
  50     ; return (mkSynTyCon tc_name kind tvs rhs fam_parent) }
  51
  52   | otherwise
  53   = return (mkSynTyCon tc_name kind tvs rhs parent)
  54   where
  55     kind = mkArrowKinds (map tyVarKind tvs) rhs_kind
  56
  57 ------------------------------------------------------
  58 buildAlgTyCon :: Name -> [TyVar]
  59               -> ThetaType              -- ^ Stupid theta
  60               -> AlgTyConRhs
  61               -> RecFlag
  62               -> Bool                   -- ^ True <=> want generics functions
  63               -> Bool                   -- ^ True <=> was declared in GADT syntax
  64               -> TyConParent
  65               -> Maybe (TyCon, [Type])  -- ^ family instance if applicable
  66               -> TcRnIf m n TyCon
  67
  68 buildAlgTyCon tc_name tvs stupid_theta rhs is_rec want_generics gadt_syn
  69               parent mb_family
  70   | Just fam_inst_info <- mb_family
  71   = -- We need to tie a knot as the coercion of a data instance depends
  72      -- on the instance representation tycon and vice versa.
  73     ASSERT( isNoParent parent )
  74     fixM $ \ tycon_rec -> do
  75     { fam_parent <- mkFamInstParentInfo tc_name tvs fam_inst_info tycon_rec
  76     ; return (mkAlgTyCon tc_name kind tvs stupid_theta rhs
  77                          fam_parent is_rec want_generics gadt_syn) }
  78
  79   | otherwise
  80   = return (mkAlgTyCon tc_name kind tvs stupid_theta rhs
  81                        parent is_rec want_generics gadt_syn)
  82   where
  83     kind = mkArrowKinds (map tyVarKind tvs) liftedTypeKind
  84
  85 -- | If a family tycon with instance types is given, the current tycon is an
  86 -- instance of that family and we need to
  87 --
  88 -- (1) create a coercion that identifies the family instance type and the
  89 --     representation type from Step (1); ie, it is of the form
  90 --         `Co tvs :: F ts ~ R tvs', where `Co' is the name of the coercion,
  91 --         `F' the family tycon and `R' the (derived) representation tycon,
  92 --         and
  93 -- (2) produce a `TyConParent' value containing the parent and coercion
  94 --     information.
  95 --
  96 mkFamInstParentInfo :: Name -> [TyVar]
  97                     -> (TyCon, [Type])
  98                     -> TyCon
  99                     -> TcRnIf m n TyConParent
 100 mkFamInstParentInfo tc_name tvs (family, instTys) rep_tycon
 101   = do { -- Create the coercion
 102        ; co_tycon_name <- newImplicitBinder tc_name mkInstTyCoOcc
 103        ; let co_tycon = mkFamInstCoercion co_tycon_name tvs
 104                                         family instTys rep_tycon
 105        ; return $ FamInstTyCon family instTys co_tycon }
 106
 107 ------------------------------------------------------
 108 mkAbstractTyConRhs :: AlgTyConRhs
 109 mkAbstractTyConRhs = AbstractTyCon
 110
 111 mkDataTyConRhs :: [DataCon] -> AlgTyConRhs
 112 mkDataTyConRhs cons
 113   = DataTyCon {
 114         data_cons = cons,
 115         is_enum = not (null cons) &&
 116                   all isNullarySrcDataCon cons
 117                   -- See Note [Enumeration types] in TyCon
 118     }
 119
 120 mkNewTyConRhs :: Name -> TyCon -> DataCon -> TcRnIf m n AlgTyConRhs
 121 -- ^ Monadic because it makes a Name for the coercion TyCon
 122 --   We pass the Name of the parent TyCon, as well as the TyCon itself,
 123 --   because the latter is part of a knot, whereas the former is not.
 124 mkNewTyConRhs tycon_name tycon con
 125   = do  { co_tycon_name <- newImplicitBinder tycon_name mkNewTyCoOcc
 126         ; let co_tycon = mkNewTypeCoercion co_tycon_name tycon etad_tvs etad_rhs
 127               cocon_maybe | all_coercions || isRecursiveTyCon tycon
 128                           = Just co_tycon
 129                           | otherwise
 130                           = Nothing
 131         ; traceIf (text "mkNewTyConRhs" <+> ppr cocon_maybe)
 132         ; return (NewTyCon { data_con    = con,
 133                              nt_rhs      = rhs_ty,
 134                              nt_etad_rhs = (etad_tvs, etad_rhs),
 135                              nt_co       = cocon_maybe } ) }
 136                              -- Coreview looks through newtypes with a Nothing
 137                              -- for nt_co, or uses explicit coercions otherwise
 138   where
 139         -- If all_coercions is True then we use coercions for all newtypes
 140         -- otherwise we use coercions for recursive newtypes and look through
 141         -- non-recursive newtypes
 142     all_coercions = True
 143     tvs    = tyConTyVars tycon
 144     inst_con_ty = applyTys (dataConUserType con) (mkTyVarTys tvs)
 145     rhs_ty = ASSERT( isFunTy inst_con_ty ) funArgTy inst_con_ty
 146         -- Instantiate the data con with the
 147         -- type variables from the tycon
 148         -- NB: a newtype DataCon has a type that must look like
 149         --        forall tvs.  <arg-ty> -> T tvs
 150         -- Note that we *can't* use dataConInstOrigArgTys here because
 151         -- the newtype arising from   class Foo a => Bar a where {}
 152         -- has a single argument (Foo a) that is a *type class*, so
 153         -- dataConInstOrigArgTys returns [].
 154
 155     etad_tvs :: [TyVar] -- Matched lazily, so that mkNewTypeCoercion can
 156     etad_rhs :: Type    -- return a TyCon without pulling on rhs_ty
 157                         -- See Note [Tricky iface loop] in LoadIface
 158     (etad_tvs, etad_rhs) = eta_reduce (reverse tvs) rhs_ty
 159
 160     eta_reduce :: [TyVar]               -- Reversed
 161                -> Type                  -- Rhs type
 162                -> ([TyVar], Type)       -- Eta-reduced version (tyvars in normal order)
 163     eta_reduce (a:as) ty | Just (fun, arg) <- splitAppTy_maybe ty,
 164                            Just tv <- getTyVar_maybe arg,
 165                            tv == a,
 166                            not (a `elemVarSet` tyVarsOfType fun)
 167                          = eta_reduce as fun
 168     eta_reduce tvs ty = (reverse tvs, ty)
 169
 170
 171 ------------------------------------------------------
 172 buildDataCon :: Name -> Bool
 173             -> [HsBang]
 174             -> [Name]                   -- Field labels
 175             -> [TyVar] -> [TyVar]       -- Univ and ext
 176             -> [(TyVar,Type)]           -- Equality spec
 177             -> ThetaType                -- Does not include the "stupid theta"
 178                                         -- or the GADT equalities
 179             -> [Type] -> Type           -- Argument and result types
 180             -> TyCon                    -- Rep tycon
 181             -> TcRnIf m n DataCon
 182 -- A wrapper for DataCon.mkDataCon that
 183 --   a) makes the worker Id
 184 --   b) makes the wrapper Id if necessary, including
 185 --      allocating its unique (hence monadic)
 186 buildDataCon src_name declared_infix arg_stricts field_lbls
 187              univ_tvs ex_tvs eq_spec ctxt arg_tys res_ty rep_tycon
 188   = do  { wrap_name <- newImplicitBinder src_name mkDataConWrapperOcc
 189         ; work_name <- newImplicitBinder src_name mkDataConWorkerOcc
 190         -- This last one takes the name of the data constructor in the source
 191         -- code, which (for Haskell source anyway) will be in the DataName name
 192         -- space, and puts it into the VarName name space
 193
 194         ; let
 195                 stupid_ctxt = mkDataConStupidTheta rep_tycon arg_tys univ_tvs
 196                 data_con = mkDataCon src_name declared_infix
 197                                      arg_stricts field_lbls
 198                                      univ_tvs ex_tvs eq_spec ctxt
 199                                      arg_tys res_ty rep_tycon
 200                                      stupid_ctxt dc_ids
 201                 dc_ids = mkDataConIds wrap_name work_name data_con
 202
 203         ; return data_con }
 204
 205
 206 -- The stupid context for a data constructor should be limited to
 207 -- the type variables mentioned in the arg_tys
 208 -- ToDo: Or functionally dependent on?
 209 --       This whole stupid theta thing is, well, stupid.
 210 mkDataConStupidTheta :: TyCon -> [Type] -> [TyVar] -> [PredType]
 211 mkDataConStupidTheta tycon arg_tys univ_tvs
 212   | null stupid_theta = []      -- The common case
 213   | otherwise         = filter in_arg_tys stupid_theta
 214   where
 215     tc_subst     = zipTopTvSubst (tyConTyVars tycon) (mkTyVarTys univ_tvs)
 216     stupid_theta = substTheta tc_subst (tyConStupidTheta tycon)
 217         -- Start by instantiating the master copy of the
 218         -- stupid theta, taken from the TyCon
 219
 220     arg_tyvars      = tyVarsOfTypes arg_tys
 221     in_arg_tys pred = not $ isEmptyVarSet $
 222                       tyVarsOfPred pred `intersectVarSet` arg_tyvars
 223 \end{code}
 224
 225
 226 ------------------------------------------------------
 227 \begin{code}
 228 type TcMethInfo = (Name, DefMethSpec, Type)  -- A temporary intermediate, to communicate
 229                                              -- between tcClassSigs and buildClass
 230
 231 buildClass :: Bool              -- True <=> do not include unfoldings
 232                                 --          on dict selectors
 233                                 -- Used when importing a class without -O
 234            -> Name -> [TyVar] -> ThetaType
 235            -> [FunDep TyVar]               -- Functional dependencies
 236            -> [TyThing]                    -- Associated types
 237            -> [TcMethInfo]                 -- Method info
 238            -> RecFlag                      -- Info for type constructor
 239            -> TcRnIf m n Class
 240
 241 buildClass no_unf class_name tvs sc_theta fds ats sig_stuff tc_isrec
 242   = do  { traceIf (text "buildClass")
 243         ; tycon_name <- newImplicitBinder class_name mkClassTyConOcc
 244         ; datacon_name <- newImplicitBinder class_name mkClassDataConOcc
 245                 -- The class name is the 'parent' for this datacon, not its tycon,
 246                 -- because one should import the class to get the binding for
 247                 -- the datacon
 248
 249         ; fixM (\ rec_clas -> do {      -- Only name generation inside loop
 250
 251         ; op_items <- mapM (mk_op_item rec_clas) sig_stuff
 252                         -- Build the selector id and default method id
 253
 254         ; let (eq_theta, dict_theta) = partition isEqPred sc_theta
 255
 256               -- We only make selectors for the *value* superclasses,
 257               -- not equality predicates
 258         ; sc_sel_names <- mapM  (newImplicitBinder class_name . mkSuperDictSelOcc)
 259                                 [1..length dict_theta]
 260         ; let sc_sel_ids = [ mkDictSelId no_unf sc_name rec_clas
 261                            | sc_name <- sc_sel_names]
 262               -- We number off the Dict superclass selectors, 1, 2, 3 etc so that we
 263               -- can construct names for the selectors. Thus
 264               --      class (C a, C b) => D a b where ...
 265               -- gives superclass selectors
 266               --      D_sc1, D_sc2
 267               -- (We used to call them D_C, but now we can have two different
 268               --  superclasses both called C!)
 269
 270         ; let use_newtype = null eq_theta && (length dict_theta + length sig_stuff == 1)
 271                 -- Use a newtype if the data constructor has
 272                 --      (a) exactly one value field
 273                 --      (b) no existential or equality-predicate fields
 274                 -- i.e. exactly one operation or superclass taken together
 275                 -- See note [Class newtypes and equality predicates]
 276
 277                 -- We play a bit fast and loose by treating the dictionary
 278                 -- superclasses as ordinary arguments.  That means that in
 279                 -- the case of
 280                 --     class C a => D a
 281                 -- we don't get a newtype with no arguments!
 282               args      = sc_sel_names ++ op_names
 283               op_tys    = [ty | (_,_,ty) <- sig_stuff]
 284               op_names  = [op | (op,_,_) <- sig_stuff]
 285               arg_tys   = map mkPredTy dict_theta ++ op_tys
 286               rec_tycon = classTyCon rec_clas
 287
 288         ; dict_con <- buildDataCon datacon_name
 289                                    False        -- Not declared infix
 290                                    (map (const HsNoBang) args)
 291                                    [{- No fields -}]
 292                                    tvs [{- no existentials -}]
 293                                    [{- No GADT equalities -}]
 294                                    eq_theta
 295                                    arg_tys
 296                                    (mkTyConApp rec_tycon (mkTyVarTys tvs))
 297                                    rec_tycon
 298
 299         ; rhs <- if use_newtype
 300                  then mkNewTyConRhs tycon_name rec_tycon dict_con
 301                  else return (mkDataTyConRhs [dict_con])
 302
 303         ; let { clas_kind = mkArrowKinds (map tyVarKind tvs) liftedTypeKind
 304
 305               ; tycon = mkClassTyCon tycon_name clas_kind tvs
 306                                      rhs rec_clas tc_isrec
 307                 -- A class can be recursive, and in the case of newtypes
 308                 -- this matters.  For example
 309                 --      class C a where { op :: C b => a -> b -> Int }
 310                 -- Because C has only one operation, it is represented by
 311                 -- a newtype, and it should be a *recursive* newtype.
 312                 -- [If we don't make it a recursive newtype, we'll expand the
 313                 -- newtype like a synonym, but that will lead to an infinite
 314                 -- type]
 315               ; atTyCons = [tycon | ATyCon tycon <- ats]
 316
 317               ; result = mkClass class_name tvs fds
 318                                  (eq_theta ++ dict_theta)  -- Equalities first
 319                                  (length eq_theta)         -- Number of equalities
 320                                  sc_sel_ids atTyCons
 321                                  op_items tycon
 322               }
 323         ; traceIf (text "buildClass" <+> ppr tycon)
 324         ; return result
 325         })}
 326   where
 327     mk_op_item :: Class -> TcMethInfo -> TcRnIf n m ClassOpItem
 328     mk_op_item rec_clas (op_name, dm_spec, _)
 329       = do { dm_info <- case dm_spec of
 330                           NoDM      -> return NoDefMeth
 331                           GenericDM -> return GenDefMeth
 332                           VanillaDM -> do { dm_name <- newImplicitBinder op_name mkDefaultMethodOcc
 333                                           ; return (DefMeth dm_name) }
 334            ; return (mkDictSelId no_unf op_name rec_clas, dm_info) }
 335 \end{code}
 336
 337 Note [Class newtypes and equality predicates]
 338 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339 Consider
 340         class (a ~ F b) => C a b where
 341           op :: a -> b
 342
 343 We cannot represent this by a newtype, even though it's not
 344 existential, and there's only one value field, because we do
 345 capture an equality predicate:
 346
 347         data C a b where
 348           MkC :: forall a b. (a ~ F b) => (a->b) -> C a b
 349
 350 We need to access this equality predicate when we get passes a C
 351 dictionary.  See Trac #2238
 352