compiler/iface/MkIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   4 %
   5
   6 \begin{code}
   7 module MkIface (
   8         mkUsageInfo,    -- Construct the usage info for a module
   9
  10         mkIface,        -- Build a ModIface from a ModGuts,
  11                         -- including computing version information
  12
  13         writeIfaceFile, -- Write the interface file
  14
  15         checkOldIface,  -- See if recompilation is required, by
  16                         -- comparing version information
  17
  18         tyThingToIfaceDecl -- Converting things to their Iface equivalents
  19  ) where
  20 \end{code}
  21
  22         -----------------------------------------------
  23                 MkIface.lhs deals with versioning
  24         -----------------------------------------------
  25
  26 Here's the version-related info in an interface file
  27
  28   module Foo 8          -- module-version
  29              3          -- export-list-version
  30              2          -- rule-version
  31     Usages:     -- Version info for what this compilation of Foo imported
  32         Baz 3           -- Module version
  33             [4]         -- The export-list version if Foo depended on it
  34             (g,2)       -- Function and its version
  35             (T,1)       -- Type and its version
  36
  37     <version> f :: Int -> Int {- Unfolding: \x -> Wib.t[2] x -}
  38                 -- The [2] says that f's unfolding
  39                 -- mentions verison 2 of Wib.t
  40
  41         -----------------------------------------------
  42                         Basic idea
  43         -----------------------------------------------
  44
  45 Basic idea:
  46   * In the mi_usages information in an interface, we record the
  47     version number of each free variable of the module
  48
  49   * In mkIface, we compute the version number of each exported thing A.f
  50     by comparing its A.f's info with its new info, and bumping its
  51     version number if it differs.  If A.f mentions B.g, and B.g's version
  52     number has changed, then we count A.f as having changed too.
  53
  54   * In checkOldIface we compare the mi_usages for the module with
  55     the actual version info for all each thing recorded in mi_usages
  56
  57
  58 Fixities
  59 ~~~~~~~~
  60 We count A.f as changing if its fixity changes
  61
  62 Rules
  63 ~~~~~
  64 If a rule changes, we want to recompile any module that might be
  65 affected by that rule.  For non-orphan rules, this is relatively easy.
  66 If module M defines f, and a rule for f, just arrange that the version
  67 number for M.f changes if any of the rules for M.f change.  Any module
  68 that does not depend on M.f can't be affected by the rule-change
  69 either.
  70
  71 Orphan rules (ones whose 'head function' is not defined in M) are
  72 harder.  Here's what we do.
  73
  74   * We have a per-module orphan-rule version number which changes if
  75     any orphan rule changes. (It's unaffected by non-orphan rules.)
  76
  77   * We record usage info for any orphan module 'below' this one,
  78     giving the orphan-rule version number.  We recompile if this
  79     changes.
  80
  81 The net effect is that if an orphan rule changes, we recompile every
  82 module above it.  That's very conservative, but it's devilishly hard
  83 to know what it might affect, so we just have to be conservative.
  84
  85 Instance decls
  86 ~~~~~~~~~~~~~~
  87 In an iface file we have
  88      module A where
  89         instance Eq a => Eq [a]  =  dfun29
  90         dfun29 :: ...
  91
  92 We have a version number for dfun29, covering its unfolding
  93 etc. Suppose we are compiling a module M that imports A only
  94 indirectly.  If typechecking M uses this instance decl, we record the
  95 dependency on A.dfun29 as if it were a free variable of the module
  96 (via the tcg_inst_usages accumulator).  That means that A will appear
  97 in M's usage list.  If the shape of the instance declaration changes,
  98 then so will dfun29's version, triggering a recompilation.
  99
 100 Adding an instance declaration, or changing an instance decl that is
 101 not currently used, is more tricky.  (This really only makes a
 102 difference when we have overlapping instance decls, because then the
 103 new instance decl might kick in to override the old one.)  We handle
 104 this in a very similar way that we handle rules above.
 105
 106   * For non-orphan instance decls, identify one locally-defined tycon/class
 107     mentioned in the decl.  Treat the instance decl as part of the defn of that
 108     tycon/class, so that if the shape of the instance decl changes, so does the
 109     tycon/class; that in turn will force recompilation of anything that uses
 110     that tycon/class.
 111
 112   * For orphan instance decls, act the same way as for orphan rules.
 113     Indeed, we use the same global orphan-rule version number.
 114
 115 mkUsageInfo
 116 ~~~~~~~~~~~
 117 mkUsageInfo figures out what the ``usage information'' for this
 118 moudule is; that is, what it must record in its interface file as the
 119 things it uses.
 120
 121 We produce a line for every module B below the module, A, currently being
 122 compiled:
 123         import B <n> ;
 124 to record the fact that A does import B indirectly.  This is used to decide
 125 to look to look for B.hi rather than B.hi-boot when compiling a module that
 126 imports A.  This line says that A imports B, but uses nothing in it.
 127 So we'll get an early bale-out when compiling A if B's version changes.
 128
 129 The usage information records:
 130
 131 \begin{itemize}
 132 \item   (a) anything reachable from its body code
 133 \item   (b) any module exported with a @module Foo@
 134 \item   (c) anything reachable from an exported item
 135 \end{itemize}
 136
 137 Why (b)?  Because if @Foo@ changes then this module's export list
 138 will change, so we must recompile this module at least as far as
 139 making a new interface file --- but in practice that means complete
 140 recompilation.
 141
 142 Why (c)?  Consider this:
 143 \begin{verbatim}
 144         module A( f, g ) where  |       module B( f ) where
 145           import B( f )         |         f = h 3
 146           g = ...               |         h = ...
 147 \end{verbatim}
 148
 149 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
 150 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
 151 *identical* to what it was before.  If anything about @B.f@ changes
 152 than anyone who imports @A@ should be recompiled in case they use
 153 @B.f@ (they'll get an early exit if they don't).  So, if anything
 154 about @B.f@ changes we'd better make sure that something in A.hi
 155 changes, and the convenient way to do that is to record the version
 156 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
 157 complete recompiation of A, which is overkill but it's the only way to
 158 write a new, slightly different, A.hi.
 159
 160 But the example is tricker.  Even if @B.f@ doesn't change at all,
 161 @B.h@ may do so, and this change may not be reflected in @f@'s version
 162 number.  But with -O, a module that imports A must be recompiled if
 163 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
 164 the occurrence of @B.f@ in the export list *just as if* it were in the
 165 code of A, and thereby haul in all the stuff reachable from it.
 166
 167         *** Conclusion: if A mentions B.f in its export list,
 168             behave just as if A mentioned B.f in its source code,
 169             and slurp in B.f and all its transitive closure ***
 170
 171 [NB: If B was compiled with -O, but A isn't, we should really *still*
 172 haul in all the unfoldings for B, in case the module that imports A *is*
 173 compiled with -O.  I think this is the case.]
 174
 175
 176 \begin{code}
 177 #include "HsVersions.h"
 178
 179 import IfaceSyn
 180 import IfaceType
 181 import LoadIface
 182 import Id
 183 import IdInfo
 184 import NewDemand
 185 import CoreSyn
 186 import Class
 187 import TyCon
 188 import DataCon
 189 import Type
 190 import TcType
 191 import TysPrim
 192 import InstEnv
 193 import FamInstEnv
 194 import TcRnMonad
 195 import HscTypes
 196
 197 import DynFlags
 198 import Name
 199 import NameEnv
 200 import NameSet
 201 import OccName
 202 import Module
 203 import BinIface
 204 import Unique
 205 import ErrUtils
 206 import Digraph
 207 import SrcLoc
 208 import PackageConfig    hiding ( Version )
 209 import Outputable
 210 import BasicTypes       hiding ( SuccessFlag(..) )
 211 import UniqFM
 212 import Util             hiding ( eqListBy )
 213 import FiniteMap
 214 import FastString
 215 import Maybes
 216
 217 import Control.Monad
 218 import Data.List
 219 \end{code}
 220
 221
 222
 223 %************************************************************************
 224 %*                                                                      *
 225 \subsection{Completing an interface}
 226 %*                                                                      *
 227 %************************************************************************
 228
 229 \begin{code}
 230 mkIface :: HscEnv
 231         -> Maybe ModIface       -- The old interface, if we have it
 232         -> ModGuts              -- Usages, deprecations, etc
 233         -> ModDetails           -- The trimmed, tidied interface
 234         -> IO (ModIface,        -- The new one, complete with decls and versions
 235                Bool)            -- True <=> there was an old Iface, and the new one
 236                                 --          is identical, so no need to write it
 237
 238 mkIface hsc_env maybe_old_iface
 239         (ModGuts{     mg_module    = this_mod,
 240                       mg_boot      = is_boot,
 241                       mg_usages    = usages,
 242                       mg_deps      = deps,
 243                       mg_rdr_env   = rdr_env,
 244                       mg_fix_env   = fix_env,
 245                       mg_deprecs   = src_deprecs })
 246         (ModDetails{  md_insts     = insts,
 247                       md_fam_insts = fam_insts,
 248                       md_rules     = rules,
 249                       md_types     = type_env,
 250                       md_exports   = exports })
 251
 252 -- NB:  notice that mkIface does not look at the bindings
 253 --      only at the TypeEnv.  The previous Tidy phase has
 254 --      put exactly the info into the TypeEnv that we want
 255 --      to expose in the interface
 256
 257   = do  { eps <- hscEPS hsc_env
 258         ; let   { entities = typeEnvElts type_env ;
 259                   decls  = [ tyThingToIfaceDecl entity
 260                            | entity <- entities,
 261                              not (isImplicitTyThing entity
 262                                   || isWiredInName (getName entity)) ]
 263                         -- Don't put implicit Ids and class tycons in
 264                         -- the interface file, Nor wired-in things; the
 265                         -- compiler knows about them anyhow
 266
 267                 ; fixities    = [(occ,fix) | FixItem occ fix _ <- nameEnvElts fix_env]
 268                 ; deprecs     = mkIfaceDeprec src_deprecs
 269                 ; iface_rules = map coreRuleToIfaceRule rules
 270                 ; iface_insts = map instanceToIfaceInst insts
 271                 ; iface_fam_insts = map famInstToIfaceFamInst fam_insts
 272
 273                 ; intermediate_iface = ModIface {
 274                         mi_module   = this_mod,
 275                         mi_boot     = is_boot,
 276                         mi_deps     = deps,
 277                         mi_usages   = usages,
 278                         mi_exports  = mkIfaceExports exports,
 279                         mi_insts    = sortLe le_inst iface_insts,
 280                         mi_fam_insts= sortLe le_fam_inst iface_fam_insts,
 281                         mi_rules    = sortLe le_rule iface_rules,
 282                         mi_fixities = fixities,
 283                         mi_deprecs  = deprecs,
 284                         mi_globals  = Just rdr_env,
 285
 286                         -- Left out deliberately: filled in by addVersionInfo
 287                         mi_mod_vers  = initialVersion,
 288                         mi_exp_vers  = initialVersion,
 289                         mi_rule_vers = initialVersion,
 290                         mi_orphan    = False,   -- Always set by addVersionInfo, but
 291                                                 -- it's a strict field, so we can't omit it.
 292                         mi_decls     = deliberatelyOmitted "decls",
 293                         mi_ver_fn    = deliberatelyOmitted "ver_fn",
 294
 295                         -- And build the cached values
 296                         mi_dep_fn = mkIfaceDepCache deprecs,
 297                         mi_fix_fn = mkIfaceFixCache fixities }
 298
 299                 -- Add version information
 300                 ; ext_ver_fn = mkParentVerFun hsc_env eps
 301                 ; (new_iface, no_change_at_all, pp_diffs, pp_orphs)
 302                         = _scc_ "versioninfo"
 303                          addVersionInfo ext_ver_fn maybe_old_iface
 304                                          intermediate_iface decls
 305                 }
 306
 307                 -- Debug printing
 308         ; when (isJust pp_orphs && dopt Opt_WarnOrphans dflags)
 309                (printDump (expectJust "mkIface" pp_orphs))
 310         ; when (dopt Opt_D_dump_hi_diffs dflags) (printDump pp_diffs)
 311         ; dumpIfSet_dyn dflags Opt_D_dump_hi "FINAL INTERFACE"
 312                         (pprModIface new_iface)
 313
 314         ; return (new_iface, no_change_at_all) }
 315   where
 316      r1 `le_rule`     r2      = ifRuleName        r1 <= ifRuleName        r2
 317      i1 `le_inst`     i2      = ifDFun            i1 <= ifDFun            i2
 318      i1 `le_fam_inst` i2      = ifFamInstTyConOcc i1 <= ifFamInstTyConOcc i2
 319
 320      dflags = hsc_dflags hsc_env
 321      deliberatelyOmitted x = panic ("Deliberately omitted: " ++ x)
 322      ifFamInstTyConOcc = nameOccName . ifaceTyConName . ifFamInstTyCon
 323
 324
 325 -----------------------------
 326 writeIfaceFile :: DynFlags -> ModLocation -> ModIface -> IO ()
 327 writeIfaceFile dflags location new_iface
 328     = do createDirectoryHierarchy (directoryOf hi_file_path)
 329          writeBinIface dflags hi_file_path new_iface
 330     where hi_file_path = ml_hi_file location
 331
 332
 333 -- -----------------------------------------------------------------------------
 334 -- Look up parents and versions of Names
 335
 336 -- This is like a global version of the mi_ver_fn field in each ModIface.
 337 -- Given a Name, it finds the ModIface, and then uses mi_ver_fn to get
 338 -- the parent and version info.
 339
 340 mkParentVerFun
 341         :: HscEnv                       -- needed to look up versions
 342         -> ExternalPackageState         -- ditto
 343         -> (Name -> (OccName,Version))
 344 mkParentVerFun hsc_env eps
 345   = \name ->
 346       let
 347         mod = nameModule name
 348         occ = nameOccName name
 349         iface = lookupIfaceByModule (hsc_dflags hsc_env) hpt pit mod `orElse`
 350                    pprPanic "lookupVers2" (ppr mod <+> ppr occ)
 351       in
 352         mi_ver_fn iface occ `orElse`
 353                  pprPanic "lookupVers1" (ppr mod <+> ppr occ)
 354   where
 355       hpt = hsc_HPT hsc_env
 356       pit = eps_PIT eps
 357
 358 -----------------------------------------------------------------------------
 359 -- Compute version numbers for local decls
 360
 361 addVersionInfo
 362         :: (Name -> (OccName,Version))  -- lookup parents and versions of names
 363         -> Maybe ModIface  -- The old interface, read from M.hi
 364         -> ModIface        -- The new interface (lacking decls)
 365         -> [IfaceDecl]     -- The new decls
 366         -> (ModIface,   -- Updated interface
 367             Bool,          -- True <=> no changes at all; no need to write Iface
 368             SDoc,          -- Differences
 369             Maybe SDoc) -- Warnings about orphans
 370
 371 addVersionInfo ver_fn Nothing new_iface new_decls
 372 -- No old interface, so definitely write a new one!
 373   = (new_iface { mi_orphan = anyNothing ifInstOrph (mi_insts new_iface)
 374                                 || anyNothing ifRuleOrph (mi_rules new_iface),
 375                 mi_decls  = [(initialVersion, decl) | decl <- new_decls],
 376                 mi_ver_fn = mkIfaceVerCache (zip (repeat initialVersion) new_decls)},
 377      False,
 378      ptext SLIT("No old interface file"),
 379      pprOrphans orph_insts orph_rules)
 380   where
 381     orph_insts = filter (isNothing . ifInstOrph) (mi_insts new_iface)
 382     orph_rules = filter (isNothing . ifRuleOrph) (mi_rules new_iface)
 383
 384 addVersionInfo ver_fn (Just old_iface@(ModIface {
 385                                            mi_mod_vers  = old_mod_vers,
 386                                            mi_exp_vers  = old_exp_vers,
 387                                            mi_rule_vers = old_rule_vers,
 388                                            mi_decls     = old_decls,
 389                                            mi_ver_fn    = old_decl_vers,
 390                                            mi_fix_fn    = old_fixities }))
 391                new_iface@(ModIface { mi_fix_fn = new_fixities })
 392                new_decls
 393  | no_change_at_all
 394  = (old_iface,  True,   ptext SLIT("Interface file unchanged"), pp_orphs)
 395  | otherwise
 396  = (final_iface, False, vcat [ptext SLIT("Interface file has changed"),
 397                               nest 2 pp_diffs], pp_orphs)
 398  where
 399     final_iface = new_iface {
 400                 mi_mod_vers  = bump_unless no_output_change old_mod_vers,
 401                 mi_exp_vers  = bump_unless no_export_change old_exp_vers,
 402                 mi_rule_vers = bump_unless no_rule_change   old_rule_vers,
 403                 mi_orphan    = not (null new_orph_rules && null new_orph_insts),
 404                 mi_decls     = decls_w_vers,
 405                 mi_ver_fn    = mkIfaceVerCache decls_w_vers }
 406
 407     decls_w_vers = [(add_vers decl, decl) | decl <- new_decls]
 408
 409     -------------------
 410     (old_non_orph_insts, old_orph_insts) =
 411         mkOrphMap ifInstOrph (mi_insts old_iface)
 412     (new_non_orph_insts, new_orph_insts) =
 413         mkOrphMap ifInstOrph (mi_insts new_iface)
 414     same_insts occ = eqMaybeBy  (eqListBy eqIfInst)
 415                                 (lookupOccEnv old_non_orph_insts occ)
 416                                 (lookupOccEnv new_non_orph_insts occ)
 417
 418     (old_non_orph_rules, old_orph_rules) =
 419         mkOrphMap ifRuleOrph (mi_rules old_iface)
 420     (new_non_orph_rules, new_orph_rules) =
 421         mkOrphMap ifRuleOrph (mi_rules new_iface)
 422     same_rules occ = eqMaybeBy  (eqListBy eqIfRule)
 423                                 (lookupOccEnv old_non_orph_rules occ)
 424                                 (lookupOccEnv new_non_orph_rules occ)
 425     -------------------
 426     -- Computing what changed
 427     no_output_change = no_decl_change   && no_rule_change &&
 428                        no_export_change && no_deprec_change
 429     no_export_change = mi_exports new_iface == mi_exports old_iface
 430                                 -- Kept sorted
 431     no_decl_change   = isEmptyOccSet changed_occs
 432     no_rule_change   = not (changedWrtNames changed_occs (eqListBy eqIfRule old_orph_rules new_orph_rules)
 433                          || changedWrtNames changed_occs (eqListBy eqIfInst old_orph_insts new_orph_insts))
 434     no_deprec_change = mi_deprecs new_iface == mi_deprecs old_iface
 435
 436         -- If the usages havn't changed either, we don't need to write the interface file
 437     no_other_changes = mi_usages new_iface == mi_usages old_iface &&
 438                        mi_deps new_iface == mi_deps old_iface
 439     no_change_at_all = no_output_change && no_other_changes
 440
 441     pp_diffs = vcat [pp_change no_export_change "Export list"
 442                         (ppr old_exp_vers <+> arrow <+> ppr (mi_exp_vers final_iface)),
 443                      pp_change no_rule_change "Rules"
 444                         (ppr old_rule_vers <+> arrow <+> ppr (mi_rule_vers final_iface)),
 445                      pp_change no_deprec_change "Deprecations" empty,
 446                      pp_change no_other_changes  "Usages" empty,
 447                      pp_decl_diffs]
 448     pp_change True  what info = empty
 449     pp_change False what info = text what <+> ptext SLIT("changed") <+> info
 450
 451     -------------------
 452     old_decl_env = mkOccEnv [(ifName decl, decl) | (_,decl) <- old_decls]
 453     same_fixity n = bool (old_fixities n == new_fixities n)
 454
 455     -------------------
 456     -- Adding version info
 457     new_version = bumpVersion old_mod_vers
 458                         -- Start from the old module version, not from
 459                         -- zero so that if you remove f, and then add
 460                         -- it again, you don't thereby reduce f's
 461                         -- version number
 462
 463     add_vers decl | occ `elemOccSet` changed_occs = new_version
 464                   | otherwise = snd (expectJust "add_vers" (old_decl_vers occ))
 465                                 -- If it's unchanged, there jolly well
 466                   where         -- should be an old version number
 467                     occ = ifName decl
 468
 469     -------------------
 470     -- Deciding which declarations have changed
 471
 472     -- For each local decl, the IfaceEq gives the list of things that
 473     -- must be unchanged for the declaration as a whole to be unchanged.
 474     eq_info :: [(OccName, IfaceEq)]
 475     eq_info = map check_eq new_decls
 476     check_eq new_decl
 477          | Just old_decl <- lookupOccEnv old_decl_env occ
 478          = (occ, new_decl `eqIfDecl` old_decl &&& eq_indirects new_decl)
 479          | otherwise {- No corresponding old decl -}
 480          = (occ, NotEqual)
 481         where
 482           occ = ifName new_decl
 483
 484     eq_indirects :: IfaceDecl -> IfaceEq
 485                 -- When seeing if two decls are the same, remember to
 486                 -- check whether any relevant fixity or rules have changed
 487     eq_indirects (IfaceId {ifName = occ}) = eq_ind_occ occ
 488     eq_indirects (IfaceClass {ifName = cls_occ, ifSigs = sigs})
 489         = same_insts cls_occ &&&
 490           eq_ind_occs [op | IfaceClassOp op _ _ <- sigs]
 491     eq_indirects (IfaceData {ifName = tc_occ, ifCons = cons})
 492         = same_insts tc_occ &&& same_fixity tc_occ &&&  -- The TyCon can have a fixity too
 493           eq_ind_occs (map ifConOcc (visibleIfConDecls cons))
 494     eq_indirects other = Equal  -- Synonyms and foreign declarations
 495
 496     eq_ind_occ :: OccName -> IfaceEq    -- For class ops and Ids; check fixity and rules
 497     eq_ind_occ occ = same_fixity occ &&& same_rules occ
 498     eq_ind_occs = foldr ((&&&) . eq_ind_occ) Equal
 499
 500     -- The Occs of declarations that changed.
 501     changed_occs :: OccSet
 502     changed_occs = computeChangedOccs ver_fn (mi_module new_iface)
 503                          (mi_usages old_iface) eq_info
 504
 505     -------------------
 506     -- Diffs
 507     pp_decl_diffs :: SDoc       -- Nothing => no changes
 508     pp_decl_diffs
 509         | isEmptyOccSet changed_occs = empty
 510         | otherwise
 511         = vcat [ptext SLIT("Changed occs:") <+> ppr (occSetElts changed_occs),
 512                 ptext SLIT("Version change for these decls:"),
 513                 nest 2 (vcat (map show_change new_decls))]
 514
 515     eq_env = mkOccEnv eq_info
 516     show_change new_decl
 517         | not (occ `elemOccSet` changed_occs) = empty
 518         | otherwise
 519         = vcat [ppr occ <+> ppr (old_decl_vers occ) <+> arrow <+> ppr new_version,
 520                 nest 2 why]
 521         where
 522           occ = ifName new_decl
 523           why = case lookupOccEnv eq_env occ of
 524                     Just (EqBut names) -> sep [ppr occ <> colon, ptext SLIT("Free vars (only) changed:"),
 525                                               nest 2 (braces (fsep (map ppr (occSetElts
 526                                                 (occs `intersectOccSet` changed_occs)))))]
 527                            where occs = mkOccSet (map nameOccName (nameSetToList names))
 528                     Just NotEqual
 529                         | Just old_decl <- lookupOccEnv old_decl_env occ
 530                         -> vcat [ptext SLIT("Old:") <+> ppr old_decl,
 531                          ptext SLIT("New:") <+> ppr new_decl]
 532                         | otherwise
 533                         -> ppr occ <+> ptext SLIT("only in new interface")
 534                     other -> pprPanic "MkIface.show_change" (ppr occ)
 535
 536     pp_orphs = pprOrphans new_orph_insts new_orph_rules
 537
 538
 539 pprOrphans insts rules
 540   | null insts && null rules = Nothing
 541   | otherwise
 542   = Just $ vcat [
 543         if null insts then empty else
 544              hang (ptext SLIT("Warning: orphan instances:"))
 545                 2 (vcat (map ppr insts)),
 546         if null rules then empty else
 547              hang (ptext SLIT("Warning: orphan rules:"))
 548                 2 (vcat (map ppr rules))
 549     ]
 550
 551 computeChangedOccs
 552         :: (Name -> (OccName,Version))     -- get parents and versions
 553         -> Module                       -- This module
 554         -> [Usage]                      -- Usages from old iface
 555         -> [(OccName, IfaceEq)]         -- decl names, equality conditions
 556         -> OccSet                       -- set of things that have changed
 557 computeChangedOccs ver_fn this_module old_usages eq_info
 558   = foldl add_changes emptyOccSet (stronglyConnComp edges)
 559   where
 560
 561     -- return True if an external name has changed
 562     name_changed :: Name -> Bool
 563     name_changed nm
 564         | Just ents <- lookupUFM usg_modmap (moduleName mod)
 565         = case lookupUFM ents parent_occ of
 566                 Nothing -> pprPanic "computeChangedOccs" (ppr nm)
 567                 Just v  -> v < new_version
 568         | otherwise = False -- must be in another package
 569       where
 570          mod = nameModule nm
 571          (parent_occ, new_version) = ver_fn nm
 572
 573     -- Turn the usages from the old ModIface into a mapping
 574     usg_modmap = listToUFM [ (usg_mod usg, listToUFM (usg_entities usg))
 575                            | usg <- old_usages ]
 576
 577     get_local_eq_info :: GenIfaceEq NameSet -> GenIfaceEq OccSet
 578     get_local_eq_info Equal = Equal
 579     get_local_eq_info NotEqual = NotEqual
 580     get_local_eq_info (EqBut ns) = foldNameSet f Equal ns
 581         where f name eq | nameModule name == this_module =
 582                           EqBut (unitOccSet (nameOccName name)) `and_occifeq` eq
 583                         | name_changed name = NotEqual
 584                         | otherwise = eq
 585
 586     local_eq_infos = mapSnd get_local_eq_info eq_info
 587
 588     edges :: [((OccName, OccIfaceEq), Unique, [Unique])]
 589     edges = [ (node, getUnique occ, map getUnique occs)
 590             | node@(occ, iface_eq) <- local_eq_infos
 591             , let occs = case iface_eq of
 592                            EqBut occ_set -> occSetElts occ_set
 593                            other -> [] ]
 594
 595     -- Changes in declarations
 596     add_changes :: OccSet -> SCC (OccName, OccIfaceEq) -> OccSet
 597     add_changes so_far (AcyclicSCC (occ, iface_eq))
 598         | changedWrt so_far iface_eq -- This one has changed
 599         = extendOccSet so_far occ
 600     add_changes so_far (CyclicSCC pairs)
 601         | changedWrt so_far (foldr1 and_occifeq iface_eqs)
 602                 -- One of this group has changed
 603         = extendOccSetList so_far occs
 604         where (occs, iface_eqs) = unzip pairs
 605     add_changes so_far other = so_far
 606
 607 type OccIfaceEq = GenIfaceEq OccSet
 608
 609 changedWrt :: OccSet -> OccIfaceEq -> Bool
 610 changedWrt so_far Equal        = False
 611 changedWrt so_far NotEqual     = True
 612 changedWrt so_far (EqBut kids) = so_far `intersectsOccSet` kids
 613
 614 changedWrtNames :: OccSet -> IfaceEq -> Bool
 615 changedWrtNames so_far Equal        = False
 616 changedWrtNames so_far NotEqual     = True
 617 changedWrtNames so_far (EqBut kids) =
 618   so_far `intersectsOccSet` mkOccSet (map nameOccName (nameSetToList kids))
 619
 620 and_occifeq :: OccIfaceEq -> OccIfaceEq -> OccIfaceEq
 621 Equal       `and_occifeq` x         = x
 622 NotEqual    `and_occifeq` x         = NotEqual
 623 EqBut nms   `and_occifeq` Equal       = EqBut nms
 624 EqBut nms   `and_occifeq` NotEqual    = NotEqual
 625 EqBut nms1  `and_occifeq` EqBut nms2  = EqBut (nms1 `unionOccSets` nms2)
 626
 627 ----------------------
 628 -- mkOrphMap partitions instance decls or rules into
 629 --      (a) an OccEnv for ones that are not orphans,
 630 --          mapping the local OccName to a list of its decls
 631 --      (b) a list of orphan decls
 632 mkOrphMap :: (decl -> Maybe OccName)    -- (Just occ) for a non-orphan decl, keyed by occ
 633                                         -- Nothing for an orphan decl
 634           -> [decl]                     -- Sorted into canonical order
 635           -> (OccEnv [decl],            -- Non-orphan decls associated with their key;
 636                                         --      each sublist in canonical order
 637               [decl])                   -- Orphan decls; in canonical order
 638 mkOrphMap get_key decls
 639   = foldl go (emptyOccEnv, []) decls
 640   where
 641     go (non_orphs, orphs) d
 642         | Just occ <- get_key d
 643         = (extendOccEnv_C (\ ds _ -> d:ds) non_orphs occ [d], orphs)
 644         | otherwise = (non_orphs, d:orphs)
 645
 646 anyNothing :: (a -> Maybe b) -> [a] -> Bool
 647 anyNothing p []     = False
 648 anyNothing p (x:xs) = isNothing (p x) || anyNothing p xs
 649
 650 ----------------------
 651 mkIfaceDeprec :: Deprecations -> IfaceDeprecs
 652 mkIfaceDeprec NoDeprecs        = NoDeprecs
 653 mkIfaceDeprec (DeprecAll t)    = DeprecAll t
 654 mkIfaceDeprec (DeprecSome env) = DeprecSome (sortLe (<=) (nameEnvElts env))
 655
 656 ----------------------
 657 bump_unless :: Bool -> Version -> Version
 658 bump_unless True  v = v -- True <=> no change
 659 bump_unless False v = bumpVersion v
 660 \end{code}
 661
 662
 663 %*********************************************************
 664 %*                                                      *
 665 \subsection{Keeping track of what we've slurped, and version numbers}
 666 %*                                                      *
 667 %*********************************************************
 668
 669
 670 \begin{code}
 671 mkUsageInfo :: HscEnv
 672             -> ModuleEnv (Module, Bool, SrcSpan)
 673             -> [(ModuleName, IsBootInterface)]
 674             -> NameSet -> IO [Usage]
 675 mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
 676   = do  { eps <- hscEPS hsc_env
 677         ; let usages = mk_usage_info (eps_PIT eps) hsc_env
 678                                      dir_imp_mods dep_mods used_names
 679         ; usages `seqList`  return usages }
 680          -- seq the list of Usages returned: occasionally these
 681          -- don't get evaluated for a while and we can end up hanging on to
 682          -- the entire collection of Ifaces.
 683
 684 mk_usage_info pit hsc_env dir_imp_mods dep_mods used_names
 685   = mapCatMaybes mkUsage dep_mods
 686         -- ToDo: do we need to sort into canonical order?
 687   where
 688     hpt = hsc_HPT hsc_env
 689     dflags = hsc_dflags hsc_env
 690
 691     -- ent_map groups together all the things imported and used
 692     -- from a particular module in this package
 693     ent_map :: ModuleEnv [OccName]
 694     ent_map  = foldNameSet add_mv emptyModuleEnv used_names
 695     add_mv name mv_map
 696         | isWiredInName name = mv_map  -- ignore wired-in names
 697         | otherwise
 698         = case nameModule_maybe name of
 699              Nothing  -> mv_map         -- ignore internal names
 700              Just mod -> extendModuleEnv_C add_item mv_map mod [occ]
 701                    where
 702                      occ = nameOccName name
 703                      add_item occs _ = occ:occs
 704
 705     depend_on_exports mod = case lookupModuleEnv dir_imp_mods mod of
 706                                 Just (_,no_imp,_) -> not no_imp
 707                                 Nothing           -> True
 708
 709     -- We want to create a Usage for a home module if
 710     --  a) we used something from; has something in used_names
 711     --  b) we imported all of it, even if we used nothing from it
 712     --          (need to recompile if its export list changes: export_vers)
 713     --  c) is a home-package orphan module (need to recompile if its
 714     --          instance decls change: rules_vers)
 715     mkUsage :: (ModuleName, IsBootInterface) -> Maybe Usage
 716     mkUsage (mod_name, _)
 717       |  isNothing maybe_iface          -- We can't depend on it if we didn't
 718       || (null used_occs                -- load its interface.
 719           && isNothing export_vers
 720           && not orphan_mod)
 721       = Nothing                 -- Record no usage info
 722
 723       | otherwise
 724       = Just (Usage { usg_name     = mod_name,
 725                       usg_mod      = mod_vers,
 726                       usg_exports  = export_vers,
 727                       usg_entities = fmToList ent_vers,
 728                       usg_rules    = rules_vers })
 729       where
 730         maybe_iface  = lookupIfaceByModule dflags hpt pit mod
 731                 -- In one-shot mode, the interfaces for home-package
 732                 -- modules accumulate in the PIT not HPT.  Sigh.
 733
 734         mod = mkModule (thisPackage dflags) mod_name
 735
 736         Just iface   = maybe_iface
 737         orphan_mod   = mi_orphan    iface
 738         version_env  = mi_ver_fn    iface
 739         mod_vers     = mi_mod_vers  iface
 740         rules_vers   = mi_rule_vers iface
 741         export_vers | depend_on_exports mod = Just (mi_exp_vers iface)
 742                     | otherwise             = Nothing
 743
 744         used_occs = lookupModuleEnv ent_map mod `orElse` []
 745
 746         -- Making a FiniteMap here ensures that (a) we remove duplicates
 747         -- when we have usages on several subordinates of a single parent,
 748         -- and (b) that the usages emerge in a canonical order, which
 749         -- is why we use FiniteMap rather than OccEnv: FiniteMap works
 750         -- using Ord on the OccNames, which is a lexicographic ordering.
 751         ent_vers :: FiniteMap OccName Version
 752         ent_vers = listToFM (map lookup_occ used_occs)
 753
 754         lookup_occ occ =
 755             case version_env occ of
 756                 Nothing -> pprTrace "hmm, strange" (ppr mod <+> ppr occ) $
 757                            (occ, initialVersion) -- does this ever happen?
 758                 Just (parent, version) -> (parent, version)
 759 \end{code}
 760
 761 \begin{code}
 762 mkIfaceExports :: [AvailInfo]
 763                -> [(Module, [GenAvailInfo OccName])]
 764   -- Group by module and sort by occurrence
 765   -- This keeps the list in canonical order
 766 mkIfaceExports exports
 767   = [ (mod, eltsFM avails)
 768     | (mod, avails) <- fmToList groupFM
 769     ]
 770   where
 771         -- Deliberately use FiniteMap rather than UniqFM so we
 772         -- get a canonical ordering
 773     groupFM :: ModuleEnv (FiniteMap FastString (GenAvailInfo OccName))
 774     groupFM = foldl add emptyModuleEnv exports
 775
 776     add env avail
 777       = extendModuleEnv_C add_avail env mod (unitFM avail_fs avail_occ)
 778       where
 779         avail_occ = availToOccs avail
 780         mod  = nameModule (availName avail)
 781         avail_fs = occNameFS (availName avail_occ)
 782         add_avail avail_fm _ = addToFM avail_fm avail_fs avail_occ
 783
 784     availToOccs (Avail n) = Avail (nameOccName n)
 785     availToOccs (AvailTC tc ns) = AvailTC (nameOccName tc) (map nameOccName ns)
 786 \end{code}
 787
 788
 789 %************************************************************************
 790 %*                                                                      *
 791         Load the old interface file for this module (unless
 792         we have it aleady), and check whether it is up to date
 793
 794 %*                                                                      *
 795 %************************************************************************
 796
 797 \begin{code}
 798 checkOldIface :: HscEnv
 799               -> ModSummary
 800               -> Bool                   -- Source unchanged
 801               -> Maybe ModIface         -- Old interface from compilation manager, if any
 802               -> IO (RecompileRequired, Maybe ModIface)
 803
 804 checkOldIface hsc_env mod_summary source_unchanged maybe_iface
 805   = do  { showPass (hsc_dflags hsc_env)
 806                    ("Checking old interface for " ++
 807                         showSDoc (ppr (ms_mod mod_summary))) ;
 808
 809         ; initIfaceCheck hsc_env $
 810           check_old_iface hsc_env mod_summary source_unchanged maybe_iface
 811      }
 812
 813 check_old_iface hsc_env mod_summary source_unchanged maybe_iface
 814  =  do  -- CHECK WHETHER THE SOURCE HAS CHANGED
 815     { ifM (not source_unchanged)
 816            (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 817
 818      -- If the source has changed and we're in interactive mode, avoid reading
 819      -- an interface; just return the one we might have been supplied with.
 820     ; ghc_mode <- getGhcMode
 821     ; if (ghc_mode == Interactive || ghc_mode == JustTypecheck)
 822          && not source_unchanged then
 823          return (outOfDate, maybe_iface)
 824       else
 825       case maybe_iface of {
 826         Just old_iface -> do -- Use the one we already have
 827           { traceIf (text "We already have the old interface for" <+> ppr (ms_mod mod_summary))
 828           ; recomp <- checkVersions hsc_env source_unchanged old_iface
 829           ; return (recomp, Just old_iface) }
 830
 831       ; Nothing -> do
 832
 833         -- Try and read the old interface for the current module
 834         -- from the .hi file left from the last time we compiled it
 835     { let iface_path = msHiFilePath mod_summary
 836     ; read_result <- readIface (ms_mod mod_summary) iface_path False
 837     ; case read_result of {
 838          Failed err -> do       -- Old interface file not found, or garbled; give up
 839                 { traceIf (text "FYI: cannot read old interface file:"
 840                                  $$ nest 4 err)
 841                 ; return (outOfDate, Nothing) }
 842
 843       ;  Succeeded iface -> do
 844
 845         -- We have got the old iface; check its versions
 846     { traceIf (text "Read the interface file" <+> text iface_path)
 847     ; recomp <- checkVersions hsc_env source_unchanged iface
 848     ; returnM (recomp, Just iface)
 849     }}}}}
 850 \end{code}
 851
 852 @recompileRequired@ is called from the HscMain.   It checks whether
 853 a recompilation is required.  It needs access to the persistent state,
 854 finder, etc, because it may have to load lots of interface files to
 855 check their versions.
 856
 857 \begin{code}
 858 type RecompileRequired = Bool
 859 upToDate  = False       -- Recompile not required
 860 outOfDate = True        -- Recompile required
 861
 862 checkVersions :: HscEnv
 863               -> Bool           -- True <=> source unchanged
 864               -> ModIface       -- Old interface
 865               -> IfG RecompileRequired
 866 checkVersions hsc_env source_unchanged iface
 867   | not source_unchanged
 868   = returnM outOfDate
 869   | otherwise
 870   = do  { traceHiDiffs (text "Considering whether compilation is required for" <+>
 871                         ppr (mi_module iface) <> colon)
 872
 873         -- Source code unchanged and no errors yet... carry on
 874
 875         -- First put the dependent-module info, read from the old interface, into the envt,
 876         -- so that when we look for interfaces we look for the right one (.hi or .hi-boot)
 877         --
 878         -- It's just temporary because either the usage check will succeed
 879         -- (in which case we are done with this module) or it'll fail (in which
 880         -- case we'll compile the module from scratch anyhow).
 881         --
 882         -- We do this regardless of compilation mode, although in --make mode
 883         -- all the dependent modules should be in the HPT already, so it's
 884         -- quite redundant
 885         ; updateEps_ $ \eps  -> eps { eps_is_boot = mod_deps }
 886
 887         ; let this_pkg = thisPackage (hsc_dflags hsc_env)
 888         ; checkList [checkModUsage this_pkg u | u <- mi_usages iface]
 889     }
 890   where
 891         -- This is a bit of a hack really
 892     mod_deps :: ModuleNameEnv (ModuleName, IsBootInterface)
 893     mod_deps = mkModDeps (dep_mods (mi_deps iface))
 894
 895 checkModUsage :: PackageId ->Usage -> IfG RecompileRequired
 896 -- Given the usage information extracted from the old
 897 -- M.hi file for the module being compiled, figure out
 898 -- whether M needs to be recompiled.
 899
 900 checkModUsage this_pkg (Usage { usg_name = mod_name, usg_mod = old_mod_vers,
 901                                 usg_rules = old_rule_vers,
 902                                 usg_exports = maybe_old_export_vers,
 903                                 usg_entities = old_decl_vers })
 904   =     -- Load the imported interface is possible
 905     let
 906         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
 907     in
 908     traceHiDiffs (text "Checking usages for module" <+> ppr mod_name) `thenM_`
 909
 910     let
 911         mod = mkModule this_pkg mod_name
 912     in
 913     loadInterface doc_str mod ImportBySystem            `thenM` \ mb_iface ->
 914         -- Load the interface, but don't complain on failure;
 915         -- Instead, get an Either back which we can test
 916
 917     case mb_iface of {
 918         Failed exn ->  (out_of_date (sep [ptext SLIT("Can't find version number for module"),
 919                                        ppr mod_name]));
 920                 -- Couldn't find or parse a module mentioned in the
 921                 -- old interface file.  Don't complain -- it might just be that
 922                 -- the current module doesn't need that import and it's been deleted
 923
 924         Succeeded iface ->
 925     let
 926         new_mod_vers    = mi_mod_vers  iface
 927         new_decl_vers   = mi_ver_fn    iface
 928         new_export_vers = mi_exp_vers  iface
 929         new_rule_vers   = mi_rule_vers iface
 930     in
 931         -- CHECK MODULE
 932     checkModuleVersion old_mod_vers new_mod_vers        `thenM` \ recompile ->
 933     if not recompile then
 934         returnM upToDate
 935     else
 936
 937         -- CHECK EXPORT LIST
 938     if checkExportList maybe_old_export_vers new_export_vers then
 939         out_of_date_vers (ptext SLIT("  Export list changed"))
 940                          (expectJust "checkModUsage" maybe_old_export_vers)
 941                          new_export_vers
 942     else
 943
 944         -- CHECK RULES
 945     if old_rule_vers /= new_rule_vers then
 946         out_of_date_vers (ptext SLIT("  Rules changed"))
 947                          old_rule_vers new_rule_vers
 948     else
 949
 950         -- CHECK ITEMS ONE BY ONE
 951     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenM` \ recompile ->
 952     if recompile then
 953         returnM outOfDate       -- This one failed, so just bail out now
 954     else
 955         up_to_date (ptext SLIT("  Great!  The bits I use are up to date"))
 956     }
 957
 958 ------------------------
 959 checkModuleVersion old_mod_vers new_mod_vers
 960   | new_mod_vers == old_mod_vers
 961   = up_to_date (ptext SLIT("Module version unchanged"))
 962
 963   | otherwise
 964   = out_of_date_vers (ptext SLIT("  Module version has changed"))
 965                      old_mod_vers new_mod_vers
 966
 967 ------------------------
 968 checkExportList Nothing  new_vers = upToDate
 969 checkExportList (Just v) new_vers = v /= new_vers
 970
 971 ------------------------
 972 checkEntityUsage new_vers (name,old_vers)
 973   = case new_vers name of
 974
 975         Nothing       ->        -- We used it before, but it ain't there now
 976                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
 977
 978         Just (_, new_vers)      -- It's there, but is it up to date?
 979           | new_vers == old_vers -> traceHiDiffs (text "  Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenM_`
 980                                     returnM upToDate
 981           | otherwise            -> out_of_date_vers (ptext SLIT("  Out of date:") <+> ppr name)
 982                                                      old_vers new_vers
 983
 984 up_to_date  msg = traceHiDiffs msg `thenM_` returnM upToDate
 985 out_of_date msg = traceHiDiffs msg `thenM_` returnM outOfDate
 986 out_of_date_vers msg old_vers new_vers
 987   = out_of_date (hsep [msg, ppr old_vers, ptext SLIT("->"), ppr new_vers])
 988
 989 ----------------------
 990 checkList :: [IfG RecompileRequired] -> IfG RecompileRequired
 991 -- This helper is used in two places
 992 checkList []             = returnM upToDate
 993 checkList (check:checks) = check        `thenM` \ recompile ->
 994                            if recompile then
 995                                 returnM outOfDate
 996                            else
 997                                 checkList checks
 998 \end{code}
 999
1000 %************************************************************************
1001 %*                                                                      *
1002                 Converting things to their Iface equivalents
1003 %*                                                                      *
1004 %************************************************************************
1005
1006 \begin{code}
1007 tyThingToIfaceDecl :: TyThing -> IfaceDecl
1008 -- Assumption: the thing is already tidied, so that locally-bound names
1009 --             (lambdas, for-alls) already have non-clashing OccNames
1010 -- Reason: Iface stuff uses OccNames, and the conversion here does
1011 --         not do tidying on the way
1012 tyThingToIfaceDecl (AnId id)
1013   = IfaceId { ifName   = getOccName id,
1014               ifType   = toIfaceType (idType id),
1015               ifIdInfo = info }
1016   where
1017     info = case toIfaceIdInfo (idInfo id) of
1018                 []    -> NoInfo
1019                 items -> HasInfo items
1020
1021 tyThingToIfaceDecl (AClass clas)
1022   = IfaceClass { ifCtxt   = toIfaceContext sc_theta,
1023                  ifName   = getOccName clas,
1024                  ifTyVars = toIfaceTvBndrs clas_tyvars,
1025                  ifFDs    = map toIfaceFD clas_fds,
1026                  ifATs    = map (tyThingToIfaceDecl . ATyCon) clas_ats,
1027                  ifSigs   = map toIfaceClassOp op_stuff,
1028                  ifRec    = boolToRecFlag (isRecursiveTyCon tycon) }
1029   where
1030     (clas_tyvars, clas_fds, sc_theta, _, clas_ats, op_stuff)
1031       = classExtraBigSig clas
1032     tycon = classTyCon clas
1033
1034     toIfaceClassOp (sel_id, def_meth)
1035         = ASSERT(sel_tyvars == clas_tyvars)
1036           IfaceClassOp (getOccName sel_id) def_meth (toIfaceType op_ty)
1037         where
1038                 -- Be careful when splitting the type, because of things
1039                 -- like         class Foo a where
1040                 --                op :: (?x :: String) => a -> a
1041                 -- and          class Baz a where
1042                 --                op :: (Ord a) => a -> a
1043           (sel_tyvars, rho_ty) = splitForAllTys (idType sel_id)
1044           op_ty                = funResultTy rho_ty
1045
1046     toIfaceFD (tvs1, tvs2) = (map getFS tvs1, map getFS tvs2)
1047
1048 tyThingToIfaceDecl (ATyCon tycon)
1049   | isSynTyCon tycon
1050   = IfaceSyn {  ifName   = getOccName tycon,
1051                 ifTyVars = toIfaceTvBndrs tyvars,
1052                 ifOpenSyn = syn_isOpen,
1053                 ifSynRhs  = toIfaceType syn_tyki }
1054
1055   | isAlgTyCon tycon
1056   = IfaceData { ifName    = getOccName tycon,
1057                 ifTyVars  = toIfaceTvBndrs tyvars,
1058                 ifCtxt    = toIfaceContext (tyConStupidTheta tycon),
1059                 ifCons    = ifaceConDecls (algTyConRhs tycon),
1060                 ifRec     = boolToRecFlag (isRecursiveTyCon tycon),
1061                 ifGadtSyntax = isGadtSyntaxTyCon tycon,
1062                 ifGeneric = tyConHasGenerics tycon,
1063                 ifFamInst = famInstToIface (tyConFamInst_maybe tycon)}
1064
1065   | isForeignTyCon tycon
1066   = IfaceForeign { ifName    = getOccName tycon,
1067                    ifExtName = tyConExtName tycon }
1068
1069   | isPrimTyCon tycon || isFunTyCon tycon
1070         -- Needed in GHCi for ':info Int#', for example
1071   = IfaceData { ifName    = getOccName tycon,
1072                 ifTyVars  = toIfaceTvBndrs (take (tyConArity tycon) alphaTyVars),
1073                 ifCtxt    = [],
1074                 ifCons    = IfAbstractTyCon,
1075                 ifGadtSyntax = False,
1076                 ifGeneric = False,
1077                 ifRec     = NonRecursive,
1078                 ifFamInst = Nothing }
1079
1080   | otherwise = pprPanic "toIfaceDecl" (ppr tycon)
1081   where
1082     tyvars = tyConTyVars tycon
1083     (syn_isOpen, syn_tyki) = case synTyConRhs tycon of
1084                                OpenSynTyCon ki -> (True , ki)
1085                                SynonymTyCon ty -> (False, ty)
1086
1087     ifaceConDecls (NewTyCon { data_con = con })    =
1088       IfNewTyCon  (ifaceConDecl con)
1089     ifaceConDecls (DataTyCon { data_cons = cons }) =
1090       IfDataTyCon (map ifaceConDecl cons)
1091     ifaceConDecls OpenDataTyCon                    = IfOpenDataTyCon
1092     ifaceConDecls OpenNewTyCon                     = IfOpenNewTyCon
1093     ifaceConDecls AbstractTyCon                    = IfAbstractTyCon
1094         -- The last case happens when a TyCon has been trimmed during tidying
1095         -- Furthermore, tyThingToIfaceDecl is also used
1096         -- in TcRnDriver for GHCi, when browsing a module, in which case the
1097         -- AbstractTyCon case is perfectly sensible.
1098
1099     ifaceConDecl data_con
1100         = IfCon   { ifConOcc     = getOccName (dataConName data_con),
1101                     ifConInfix   = dataConIsInfix data_con,
1102                     ifConUnivTvs = toIfaceTvBndrs (dataConUnivTyVars data_con),
1103                     ifConExTvs   = toIfaceTvBndrs (dataConExTyVars data_con),
1104                     ifConEqSpec  = to_eq_spec (dataConEqSpec data_con),
1105                     ifConCtxt    = toIfaceContext (dataConTheta data_con),
1106                     ifConArgTys  = map toIfaceType (dataConOrigArgTys data_con),
1107                     ifConFields  = map getOccName
1108                                        (dataConFieldLabels data_con),
1109                     ifConStricts = dataConStrictMarks data_con }
1110
1111     to_eq_spec spec = [(getOccName tv, toIfaceType ty) | (tv,ty) <- spec]
1112
1113     famInstToIface Nothing                    = Nothing
1114     famInstToIface (Just (famTyCon, instTys)) =
1115       Just (toIfaceTyCon famTyCon, map toIfaceType instTys)
1116
1117 tyThingToIfaceDecl (ADataCon dc)
1118  = pprPanic "toIfaceDecl" (ppr dc)      -- Should be trimmed out earlier
1119
1120
1121 getFS x = occNameFS (getOccName x)
1122
1123 --------------------------
1124 instanceToIfaceInst :: Instance -> IfaceInst
1125 instanceToIfaceInst ispec@(Instance { is_dfun = dfun_id, is_flag = oflag,
1126                                       is_cls = cls, is_tcs = mb_tcs,
1127                                       is_orph = orph })
1128   = IfaceInst { ifDFun    = getName dfun_id,
1129                 ifOFlag   = oflag,
1130                 ifInstCls = cls,
1131                 ifInstTys = map do_rough mb_tcs,
1132                 ifInstOrph = orph }
1133   where
1134     do_rough Nothing  = Nothing
1135     do_rough (Just n) = Just (toIfaceTyCon_name n)
1136
1137 --------------------------
1138 famInstToIfaceFamInst :: FamInst -> IfaceFamInst
1139 famInstToIfaceFamInst fi@(FamInst { fi_tycon = tycon,
1140                                             fi_fam = fam, fi_tcs = mb_tcs })
1141   = IfaceFamInst { ifFamInstTyCon  = toIfaceTyCon tycon
1142                  , ifFamInstFam    = fam
1143                  , ifFamInstTys    = map do_rough mb_tcs }
1144   where
1145     do_rough Nothing  = Nothing
1146     do_rough (Just n) = Just (toIfaceTyCon_name n)
1147
1148 --------------------------
1149 toIfaceIdInfo :: IdInfo -> [IfaceInfoItem]
1150 toIfaceIdInfo id_info
1151   = catMaybes [arity_hsinfo, caf_hsinfo, strict_hsinfo,
1152                inline_hsinfo, wrkr_hsinfo,  unfold_hsinfo]
1153   where
1154     ------------  Arity  --------------
1155     arity_info = arityInfo id_info
1156     arity_hsinfo | arity_info == 0 = Nothing
1157                  | otherwise       = Just (HsArity arity_info)
1158
1159     ------------ Caf Info --------------
1160     caf_info   = cafInfo id_info
1161     caf_hsinfo = case caf_info of
1162                    NoCafRefs -> Just HsNoCafRefs
1163                    _other    -> Nothing
1164
1165     ------------  Strictness  --------------
1166         -- No point in explicitly exporting TopSig
1167     strict_hsinfo = case newStrictnessInfo id_info of
1168                         Just sig | not (isTopSig sig) -> Just (HsStrictness sig)
1169                         _other                        -> Nothing
1170
1171     ------------  Worker  --------------
1172     work_info   = workerInfo id_info
1173     has_worker  = case work_info of { HasWorker _ _ -> True; other -> False }
1174     wrkr_hsinfo = case work_info of
1175                     HasWorker work_id wrap_arity ->
1176                         Just (HsWorker ((idName work_id)) wrap_arity)
1177                     NoWorker -> Nothing
1178
1179     ------------  Unfolding  --------------
1180     -- The unfolding is redundant if there is a worker
1181     unfold_info  = unfoldingInfo id_info
1182     rhs          = unfoldingTemplate unfold_info
1183     no_unfolding = neverUnfold unfold_info
1184                         -- The CoreTidy phase retains unfolding info iff
1185                         -- we want to expose the unfolding, taking into account
1186                         -- unconditional NOINLINE, etc.  See TidyPgm.addExternal
1187     unfold_hsinfo | no_unfolding = Nothing
1188                   | has_worker   = Nothing      -- Unfolding is implicit
1189                   | otherwise    = Just (HsUnfold (toIfaceExpr rhs))
1190
1191     ------------  Inline prag  --------------
1192     inline_prag = inlinePragInfo id_info
1193     inline_hsinfo | isAlwaysActive inline_prag     = Nothing
1194                   | no_unfolding && not has_worker = Nothing
1195                         -- If the iface file give no unfolding info, we
1196                         -- don't need to say when inlining is OK!
1197                   | otherwise                      = Just (HsInline inline_prag)
1198
1199 --------------------------
1200 coreRuleToIfaceRule :: CoreRule -> IfaceRule
1201 coreRuleToIfaceRule (BuiltinRule { ru_fn = fn})
1202   = pprTrace "toHsRule: builtin" (ppr fn) $
1203     bogusIfaceRule fn
1204
1205 coreRuleToIfaceRule (Rule { ru_name = name, ru_fn = fn,
1206                             ru_act = act, ru_bndrs = bndrs,
1207                             ru_args = args, ru_rhs = rhs, ru_orph = orph })
1208   = IfaceRule { ifRuleName  = name, ifActivation = act,
1209                 ifRuleBndrs = map toIfaceBndr bndrs,
1210                 ifRuleHead  = fn,
1211                 ifRuleArgs  = map do_arg args,
1212                 ifRuleRhs   = toIfaceExpr rhs,
1213                 ifRuleOrph  = orph }
1214   where
1215         -- For type args we must remove synonyms from the outermost
1216         -- level.  Reason: so that when we read it back in we'll
1217         -- construct the same ru_rough field as we have right now;
1218         -- see tcIfaceRule
1219     do_arg (Type ty) = IfaceType (toIfaceType (deNoteType ty))
1220     do_arg arg       = toIfaceExpr arg
1221
1222 bogusIfaceRule :: Name -> IfaceRule
1223 bogusIfaceRule id_name
1224   = IfaceRule { ifRuleName = FSLIT("bogus"), ifActivation = NeverActive,
1225         ifRuleBndrs = [], ifRuleHead = id_name, ifRuleArgs = [],
1226         ifRuleRhs = IfaceExt id_name, ifRuleOrph = Nothing }
1227
1228 ---------------------
1229 toIfaceExpr :: CoreExpr -> IfaceExpr
1230 toIfaceExpr (Var v)       = toIfaceVar v
1231 toIfaceExpr (Lit l)       = IfaceLit l
1232 toIfaceExpr (Type ty)     = IfaceType (toIfaceType ty)
1233 toIfaceExpr (Lam x b)     = IfaceLam (toIfaceBndr x) (toIfaceExpr b)
1234 toIfaceExpr (App f a)     = toIfaceApp f [a]
1235 toIfaceExpr (Case s x ty as) = IfaceCase (toIfaceExpr s) (getFS x) (toIfaceType ty) (map toIfaceAlt as)
1236 toIfaceExpr (Let b e)     = IfaceLet (toIfaceBind b) (toIfaceExpr e)
1237 toIfaceExpr (Cast e co)   = IfaceCast (toIfaceExpr e) (toIfaceType co)
1238 toIfaceExpr (Note n e)    = IfaceNote (toIfaceNote n) (toIfaceExpr e)
1239
1240 ---------------------
1241 toIfaceNote (SCC cc)      = IfaceSCC cc
1242 toIfaceNote InlineMe      = IfaceInlineMe
1243 toIfaceNote (CoreNote s)  = IfaceCoreNote s
1244
1245 ---------------------
1246 toIfaceBind (NonRec b r) = IfaceNonRec (toIfaceIdBndr b) (toIfaceExpr r)
1247 toIfaceBind (Rec prs)    = IfaceRec [(toIfaceIdBndr b, toIfaceExpr r) | (b,r) <- prs]
1248
1249 ---------------------
1250 toIfaceAlt (c,bs,r) = (toIfaceCon c, map getFS bs, toIfaceExpr r)
1251
1252 ---------------------
1253 toIfaceCon (DataAlt dc) | isTupleTyCon tc = IfaceTupleAlt (tupleTyConBoxity tc)
1254                         | otherwise       = IfaceDataAlt (getName dc)
1255                         where
1256                           tc = dataConTyCon dc
1257
1258 toIfaceCon (LitAlt l) = IfaceLitAlt l
1259 toIfaceCon DEFAULT    = IfaceDefault
1260
1261 ---------------------
1262 toIfaceApp (App f a) as = toIfaceApp f (a:as)
1263 toIfaceApp (Var v) as
1264   = case isDataConWorkId_maybe v of
1265         -- We convert the *worker* for tuples into IfaceTuples
1266         Just dc |  isTupleTyCon tc && saturated
1267                 -> IfaceTuple (tupleTyConBoxity tc) tup_args
1268           where
1269             val_args  = dropWhile isTypeArg as
1270             saturated = val_args `lengthIs` idArity v
1271             tup_args  = map toIfaceExpr val_args
1272             tc        = dataConTyCon dc
1273
1274         other -> mkIfaceApps (toIfaceVar v) as
1275
1276 toIfaceApp e as = mkIfaceApps (toIfaceExpr e) as
1277
1278 mkIfaceApps f as = foldl (\f a -> IfaceApp f (toIfaceExpr a)) f as
1279
1280 ---------------------
1281 toIfaceVar :: Id -> IfaceExpr
1282 toIfaceVar v
1283   | Just fcall <- isFCallId_maybe v = IfaceFCall fcall (toIfaceType (idType v))
1284           -- Foreign calls have special syntax
1285   | isExternalName name             = IfaceExt name
1286   | otherwise                       = IfaceLcl (getFS name)
1287   where
1288     name = idName v
1289 \end{code}