compiler/iface/TcIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Type checking of type signatures in interface files
   7
   8 \begin{code}
   9 module TcIface (
  10         tcImportDecl, checkWiredInTyCon, tcHiBootIface, typecheckIface,
  11         tcIfaceDecl, tcIfaceInst, tcIfaceFamInst, tcIfaceRules,
  12         tcIfaceVectInfo, tcIfaceAnnotations, tcIfaceGlobal, tcExtCoreBindings
  13  ) where
  14
  15 #include "HsVersions.h"
  16
  17 import IfaceSyn
  18 import LoadIface
  19 import IfaceEnv
  20 import BuildTyCl
  21 import TcRnMonad
  22 import TcType           ( tcSplitSigmaTy )
  23 import Type
  24 import TypeRep
  25 import HscTypes
  26 import Annotations
  27 import InstEnv
  28 import FamInstEnv
  29 import CoreSyn
  30 import CoreUtils
  31 import CoreUnfold
  32 import CoreLint
  33 import WorkWrap
  34 import Id
  35 import MkId
  36 import IdInfo
  37 import Class
  38 import TyCon
  39 import DataCon
  40 import TysWiredIn
  41 import Var              ( TyVar )
  42 import qualified Var
  43 import VarEnv
  44 import Name
  45 import NameEnv
  46 import OccName
  47 import Module
  48 import LazyUniqFM
  49 import UniqSupply
  50 import Outputable
  51 import ErrUtils
  52 import Maybes
  53 import SrcLoc
  54 import DynFlags
  55 import Util
  56 import FastString
  57 import BasicTypes (Arity)
  58
  59 import Control.Monad
  60 import Data.List
  61 import Data.Maybe
  62 \end{code}
  63
  64 This module takes
  65
  66         IfaceDecl -> TyThing
  67         IfaceType -> Type
  68         etc
  69
  70 An IfaceDecl is populated with RdrNames, and these are not renamed to
  71 Names before typechecking, because there should be no scope errors etc.
  72
  73         -- For (b) consider: f = \$(...h....)
  74         -- where h is imported, and calls f via an hi-boot file.
  75         -- This is bad!  But it is not seen as a staging error, because h
  76         -- is indeed imported.  We don't want the type-checker to black-hole
  77         -- when simplifying and compiling the splice!
  78         --
  79         -- Simple solution: discard any unfolding that mentions a variable
  80         -- bound in this module (and hence not yet processed).
  81         -- The discarding happens when forkM finds a type error.
  82
  83 %************************************************************************
  84 %*                                                                      *
  85 %*      tcImportDecl is the key function for "faulting in"              *
  86 %*      imported things
  87 %*                                                                      *
  88 %************************************************************************
  89
  90 The main idea is this.  We are chugging along type-checking source code, and
  91 find a reference to GHC.Base.map.  We call tcLookupGlobal, which doesn't find
  92 it in the EPS type envt.  So it
  93         1 loads GHC.Base.hi
  94         2 gets the decl for GHC.Base.map
  95         3 typechecks it via tcIfaceDecl
  96         4 and adds it to the type env in the EPS
  97
  98 Note that DURING STEP 4, we may find that map's type mentions a type
  99 constructor that also
 100
 101 Notice that for imported things we read the current version from the EPS
 102 mutable variable.  This is important in situations like
 103         ...$(e1)...$(e2)...
 104 where the code that e1 expands to might import some defns that
 105 also turn out to be needed by the code that e2 expands to.
 106
 107 \begin{code}
 108 tcImportDecl :: Name -> TcM TyThing
 109 -- Entry point for *source-code* uses of importDecl
 110 tcImportDecl name
 111   | Just thing <- wiredInNameTyThing_maybe name
 112   = do  { when (needWiredInHomeIface thing)
 113                (initIfaceTcRn (loadWiredInHomeIface name))
 114                 -- See Note [Loading instances for wired-in things]
 115         ; return thing }
 116   | otherwise
 117   = do  { traceIf (text "tcImportDecl" <+> ppr name)
 118         ; mb_thing <- initIfaceTcRn (importDecl name)
 119         ; case mb_thing of
 120             Succeeded thing -> return thing
 121             Failed err      -> failWithTc err }
 122
 123 importDecl :: Name -> IfM lcl (MaybeErr Message TyThing)
 124 -- Get the TyThing for this Name from an interface file
 125 -- It's not a wired-in thing -- the caller caught that
 126 importDecl name
 127   = ASSERT( not (isWiredInName name) )
 128     do  { traceIf nd_doc
 129
 130         -- Load the interface, which should populate the PTE
 131         ; mb_iface <- ASSERT2( isExternalName name, ppr name )
 132                       loadInterface nd_doc (nameModule name) ImportBySystem
 133         ; case mb_iface of {
 134                 Failed err_msg  -> return (Failed err_msg) ;
 135                 Succeeded _ -> do
 136
 137         -- Now look it up again; this time we should find it
 138         { eps <- getEps
 139         ; case lookupTypeEnv (eps_PTE eps) name of
 140             Just thing -> return (Succeeded thing)
 141             Nothing    -> return (Failed not_found_msg)
 142     }}}
 143   where
 144     nd_doc = ptext (sLit "Need decl for") <+> ppr name
 145     not_found_msg = hang (ptext (sLit "Can't find interface-file declaration for") <+>
 146                                 pprNameSpace (occNameSpace (nameOccName name)) <+> ppr name)
 147                        2 (vcat [ptext (sLit "Probable cause: bug in .hi-boot file, or inconsistent .hi file"),
 148                                 ptext (sLit "Use -ddump-if-trace to get an idea of which file caused the error")])
 149 \end{code}
 150
 151 %************************************************************************
 152 %*                                                                      *
 153            Checks for wired-in things
 154 %*                                                                      *
 155 %************************************************************************
 156
 157 Note [Loading instances for wired-in things]
 158 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 159 We need to make sure that we have at least *read* the interface files
 160 for any module with an instance decl or RULE that we might want.
 161
 162 * If the instance decl is an orphan, we have a whole separate mechanism
 163   (loadOprhanModules)
 164
 165 * If the instance decl not an orphan, then the act of looking at the
 166   TyCon or Class will force in the defining module for the
 167   TyCon/Class, and hence the instance decl
 168
 169 * BUT, if the TyCon is a wired-in TyCon, we don't really need its interface;
 170   but we must make sure we read its interface in case it has instances or
 171   rules.  That is what LoadIface.loadWiredInHomeInterface does.  It's called
 172   from TcIface.{tcImportDecl, checkWiredInTyCon, ifCheckWiredInThing}
 173
 174 * HOWEVER, only do this for TyCons.  There are no wired-in Classes.  There
 175   are some wired-in Ids, but we don't want to load their interfaces. For
 176   example, Control.Exception.Base.recSelError is wired in, but that module
 177   is compiled late in the base library, and we don't want to force it to
 178   load before it's been compiled!
 179
 180 All of this is done by the type checker. The renamer plays no role.
 181 (It used to, but no longer.)
 182
 183
 184 \begin{code}
 185 checkWiredInTyCon :: TyCon -> TcM ()
 186 -- Ensure that the home module of the TyCon (and hence its instances)
 187 -- are loaded. See Note [Loading instances for wired-in things]
 188 -- It might not be a wired-in tycon (see the calls in TcUnify),
 189 -- in which case this is a no-op.
 190 checkWiredInTyCon tc
 191   | not (isWiredInName tc_name)
 192   = return ()
 193   | otherwise
 194   = do  { mod <- getModule
 195         ; ASSERT( isExternalName tc_name )
 196           when (mod /= nameModule tc_name)
 197                (initIfaceTcRn (loadWiredInHomeIface tc_name))
 198                 -- Don't look for (non-existent) Float.hi when
 199                 -- compiling Float.lhs, which mentions Float of course
 200                 -- A bit yukky to call initIfaceTcRn here
 201         }
 202   where
 203     tc_name = tyConName tc
 204
 205 ifCheckWiredInThing :: TyThing -> IfL ()
 206 -- Even though we are in an interface file, we want to make
 207 -- sure the instances of a wired-in thing are loaded (imagine f :: Double -> Double)
 208 -- Ditto want to ensure that RULES are loaded too
 209 -- See Note [Loading instances for wired-in things]
 210 ifCheckWiredInThing thing
 211   = do  { mod <- getIfModule
 212                 -- Check whether we are typechecking the interface for this
 213                 -- very module.  E.g when compiling the base library in --make mode
 214                 -- we may typecheck GHC.Base.hi. At that point, GHC.Base is not in
 215                 -- the HPT, so without the test we'll demand-load it into the PIT!
 216                 -- C.f. the same test in checkWiredInTyCon above
 217         ; let name = getName thing
 218         ; ASSERT2( isExternalName name, ppr name )
 219           when (needWiredInHomeIface thing && mod /= nameModule name)
 220                (loadWiredInHomeIface name) }
 221
 222 needWiredInHomeIface :: TyThing -> Bool
 223 -- Only for TyCons; see Note [Loading instances for wired-in things]
 224 needWiredInHomeIface (ATyCon {}) = True
 225 needWiredInHomeIface _           = False
 226 \end{code}
 227
 228 %************************************************************************
 229 %*                                                                      *
 230                 Type-checking a complete interface
 231 %*                                                                      *
 232 %************************************************************************
 233
 234 Suppose we discover we don't need to recompile.  Then we must type
 235 check the old interface file.  This is a bit different to the
 236 incremental type checking we do as we suck in interface files.  Instead
 237 we do things similarly as when we are typechecking source decls: we
 238 bring into scope the type envt for the interface all at once, using a
 239 knot.  Remember, the decls aren't necessarily in dependency order --
 240 and even if they were, the type decls might be mutually recursive.
 241
 242 \begin{code}
 243 typecheckIface :: ModIface      -- Get the decls from here
 244                -> TcRnIf gbl lcl ModDetails
 245 typecheckIface iface
 246   = initIfaceTc iface $ \ tc_env_var -> do
 247         -- The tc_env_var is freshly allocated, private to
 248         -- type-checking this particular interface
 249         {       -- Get the right set of decls and rules.  If we are compiling without -O
 250                 -- we discard pragmas before typechecking, so that we don't "see"
 251                 -- information that we shouldn't.  From a versioning point of view
 252                 -- It's not actually *wrong* to do so, but in fact GHCi is unable
 253                 -- to handle unboxed tuples, so it must not see unfoldings.
 254           ignore_prags <- doptM Opt_IgnoreInterfacePragmas
 255
 256                 -- Typecheck the decls.  This is done lazily, so that the knot-tying
 257                 -- within this single module work out right.  In the If monad there is
 258                 -- no global envt for the current interface; instead, the knot is tied
 259                 -- through the if_rec_types field of IfGblEnv
 260         ; names_w_things <- loadDecls ignore_prags (mi_decls iface)
 261         ; let type_env = mkNameEnv names_w_things
 262         ; writeMutVar tc_env_var type_env
 263
 264                 -- Now do those rules, instances and annotations
 265         ; insts     <- mapM tcIfaceInst    (mi_insts     iface)
 266         ; fam_insts <- mapM tcIfaceFamInst (mi_fam_insts iface)
 267         ; rules     <- tcIfaceRules ignore_prags (mi_rules iface)
 268         ; anns      <- tcIfaceAnnotations  (mi_anns iface)
 269
 270                 -- Vectorisation information
 271         ; vect_info <- tcIfaceVectInfo (mi_module iface) type_env
 272                                        (mi_vect_info iface)
 273
 274                 -- Exports
 275         ; exports <- ifaceExportNames (mi_exports iface)
 276
 277                 -- Finished
 278         ; traceIf (vcat [text "Finished typechecking interface for" <+> ppr (mi_module iface),
 279                          text "Type envt:" <+> ppr type_env])
 280         ; return $ ModDetails { md_types     = type_env
 281                               , md_insts     = insts
 282                               , md_fam_insts = fam_insts
 283                               , md_rules     = rules
 284                               , md_anns      = anns
 285                               , md_vect_info = vect_info
 286                               , md_exports   = exports
 287                               }
 288     }
 289 \end{code}
 290
 291
 292 %************************************************************************
 293 %*                                                                      *
 294                 Type and class declarations
 295 %*                                                                      *
 296 %************************************************************************
 297
 298 \begin{code}
 299 tcHiBootIface :: HscSource -> Module -> TcRn ModDetails
 300 -- Load the hi-boot iface for the module being compiled,
 301 -- if it indeed exists in the transitive closure of imports
 302 -- Return the ModDetails, empty if no hi-boot iface
 303 tcHiBootIface hsc_src mod
 304   | isHsBoot hsc_src            -- Already compiling a hs-boot file
 305   = return emptyModDetails
 306   | otherwise
 307   = do  { traceIf (text "loadHiBootInterface" <+> ppr mod)
 308
 309         ; mode <- getGhcMode
 310         ; if not (isOneShot mode)
 311                 -- In --make and interactive mode, if this module has an hs-boot file
 312                 -- we'll have compiled it already, and it'll be in the HPT
 313                 --
 314                 -- We check wheher the interface is a *boot* interface.
 315                 -- It can happen (when using GHC from Visual Studio) that we
 316                 -- compile a module in TypecheckOnly mode, with a stable,
 317                 -- fully-populated HPT.  In that case the boot interface isn't there
 318                 -- (it's been replaced by the mother module) so we can't check it.
 319                 -- And that's fine, because if M's ModInfo is in the HPT, then
 320                 -- it's been compiled once, and we don't need to check the boot iface
 321           then do { hpt <- getHpt
 322                   ; case lookupUFM hpt (moduleName mod) of
 323                       Just info | mi_boot (hm_iface info)
 324                                 -> return (hm_details info)
 325                       _ -> return emptyModDetails }
 326           else do
 327
 328         -- OK, so we're in one-shot mode.
 329         -- In that case, we're read all the direct imports by now,
 330         -- so eps_is_boot will record if any of our imports mention us by
 331         -- way of hi-boot file
 332         { eps <- getEps
 333         ; case lookupUFM (eps_is_boot eps) (moduleName mod) of {
 334             Nothing -> return emptyModDetails ; -- The typical case
 335
 336             Just (_, False) -> failWithTc moduleLoop ;
 337                 -- Someone below us imported us!
 338                 -- This is a loop with no hi-boot in the way
 339
 340             Just (_mod, True) ->        -- There's a hi-boot interface below us
 341
 342     do  { read_result <- findAndReadIface
 343                                 need mod
 344                                 True    -- Hi-boot file
 345
 346         ; case read_result of
 347                 Failed err               -> failWithTc (elaborate err)
 348                 Succeeded (iface, _path) -> typecheckIface iface
 349     }}}}
 350   where
 351     need = ptext (sLit "Need the hi-boot interface for") <+> ppr mod
 352                  <+> ptext (sLit "to compare against the Real Thing")
 353
 354     moduleLoop = ptext (sLit "Circular imports: module") <+> quotes (ppr mod)
 355                      <+> ptext (sLit "depends on itself")
 356
 357     elaborate err = hang (ptext (sLit "Could not find hi-boot interface for") <+>
 358                           quotes (ppr mod) <> colon) 4 err
 359 \end{code}
 360
 361
 362 %************************************************************************
 363 %*                                                                      *
 364                 Type and class declarations
 365 %*                                                                      *
 366 %************************************************************************
 367
 368 When typechecking a data type decl, we *lazily* (via forkM) typecheck
 369 the constructor argument types.  This is in the hope that we may never
 370 poke on those argument types, and hence may never need to load the
 371 interface files for types mentioned in the arg types.
 372
 373 E.g.
 374         data Foo.S = MkS Baz.T
 375 Mabye we can get away without even loading the interface for Baz!
 376
 377 This is not just a performance thing.  Suppose we have
 378         data Foo.S = MkS Baz.T
 379         data Baz.T = MkT Foo.S
 380 (in different interface files, of course).
 381 Now, first we load and typecheck Foo.S, and add it to the type envt.
 382 If we do explore MkS's argument, we'll load and typecheck Baz.T.
 383 If we explore MkT's argument we'll find Foo.S already in the envt.
 384
 385 If we typechecked constructor args eagerly, when loading Foo.S we'd try to
 386 typecheck the type Baz.T.  So we'd fault in Baz.T... and then need Foo.S...
 387 which isn't done yet.
 388
 389 All very cunning. However, there is a rather subtle gotcha which bit
 390 me when developing this stuff.  When we typecheck the decl for S, we
 391 extend the type envt with S, MkS, and all its implicit Ids.  Suppose
 392 (a bug, but it happened) that the list of implicit Ids depended in
 393 turn on the constructor arg types.  Then the following sequence of
 394 events takes place:
 395         * we build a thunk <t> for the constructor arg tys
 396         * we build a thunk for the extended type environment (depends on <t>)
 397         * we write the extended type envt into the global EPS mutvar
 398
 399 Now we look something up in the type envt
 400         * that pulls on <t>
 401         * which reads the global type envt out of the global EPS mutvar
 402         * but that depends in turn on <t>
 403
 404 It's subtle, because, it'd work fine if we typechecked the constructor args
 405 eagerly -- they don't need the extended type envt.  They just get the extended
 406 type envt by accident, because they look at it later.
 407
 408 What this means is that the implicitTyThings MUST NOT DEPEND on any of
 409 the forkM stuff.
 410
 411
 412 \begin{code}
 413 tcIfaceDecl :: Bool     -- True <=> discard IdInfo on IfaceId bindings
 414             -> IfaceDecl
 415             -> IfL TyThing
 416
 417 tcIfaceDecl ignore_prags (IfaceId {ifName = occ_name, ifType = iface_type,
 418                                    ifIdDetails = details, ifIdInfo = info})
 419   = do  { name <- lookupIfaceTop occ_name
 420         ; ty <- tcIfaceType iface_type
 421         ; details <- tcIdDetails ty details
 422         ; info <- tcIdInfo ignore_prags name ty info
 423         ; return (AnId (mkGlobalId details name ty info)) }
 424
 425 tcIfaceDecl _ (IfaceData {ifName = occ_name,
 426                           ifTyVars = tv_bndrs,
 427                           ifCtxt = ctxt, ifGadtSyntax = gadt_syn,
 428                           ifCons = rdr_cons,
 429                           ifRec = is_rec,
 430                           ifGeneric = want_generic,
 431                           ifFamInst = mb_family })
 432   = do  { tc_name <- lookupIfaceTop occ_name
 433         ; bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 434
 435         { tycon <- fixM ( \ tycon -> do
 436             { stupid_theta <- tcIfaceCtxt ctxt
 437             ; famInst <-
 438                 case mb_family of
 439                   Nothing         -> return Nothing
 440                   Just (fam, tys) ->
 441                     do { famTyCon <- tcIfaceTyCon fam
 442                        ; insttys <- mapM tcIfaceType tys
 443                        ; return $ Just (famTyCon, insttys)
 444                        }
 445             ; cons <- tcIfaceDataCons tc_name tycon tyvars rdr_cons
 446             ; buildAlgTyCon tc_name tyvars stupid_theta
 447                             cons is_rec want_generic gadt_syn famInst
 448             })
 449         ; traceIf (text "tcIfaceDecl4" <+> ppr tycon)
 450         ; return (ATyCon tycon)
 451     }}
 452
 453 tcIfaceDecl _ (IfaceSyn {ifName = occ_name, ifTyVars = tv_bndrs,
 454                          ifSynRhs = mb_rhs_ty,
 455                          ifSynKind = kind, ifFamInst = mb_family})
 456    = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 457      { tc_name <- lookupIfaceTop occ_name
 458      ; rhs_kind <- tcIfaceType kind     -- Note [Synonym kind loop]
 459      ; ~(rhs, fam) <- forkM (mk_doc tc_name) $
 460                       do { rhs <- tc_syn_rhs rhs_kind mb_rhs_ty
 461                          ; fam <- tc_syn_fam mb_family
 462                          ; return (rhs, fam) }
 463      ; tycon <- buildSynTyCon tc_name tyvars rhs rhs_kind fam
 464      ; return $ ATyCon tycon
 465      }
 466    where
 467      mk_doc n = ptext (sLit "Type syonym") <+> ppr n
 468      tc_syn_rhs kind Nothing   = return (OpenSynTyCon kind Nothing)
 469      tc_syn_rhs _    (Just ty) = do { rhs_ty <- tcIfaceType ty
 470                                     ; return (SynonymTyCon rhs_ty) }
 471      tc_syn_fam Nothing
 472        = return Nothing
 473      tc_syn_fam (Just (fam, tys))
 474        = do { famTyCon <- tcIfaceTyCon fam
 475             ; insttys <- mapM tcIfaceType tys
 476             ; return $ Just (famTyCon, insttys) }
 477
 478 tcIfaceDecl ignore_prags
 479             (IfaceClass {ifCtxt = rdr_ctxt, ifName = occ_name,
 480                          ifTyVars = tv_bndrs, ifFDs = rdr_fds,
 481                          ifATs = rdr_ats, ifSigs = rdr_sigs,
 482                          ifRec = tc_isrec })
 483 -- ToDo: in hs-boot files we should really treat abstract classes specially,
 484 --       as we do abstract tycons
 485   = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 486     { cls_name <- lookupIfaceTop occ_name
 487     ; ctxt <- tcIfaceCtxt rdr_ctxt
 488     ; sigs <- mapM tc_sig rdr_sigs
 489     ; fds  <- mapM tc_fd rdr_fds
 490     ; ats' <- mapM (tcIfaceDecl ignore_prags) rdr_ats
 491     ; let ats = map (setAssocFamilyPermutation tyvars) ats'
 492     ; cls  <- buildClass ignore_prags cls_name tyvars ctxt fds ats sigs tc_isrec
 493     ; return (AClass cls) }
 494   where
 495    tc_sig (IfaceClassOp occ dm rdr_ty)
 496      = do { op_name <- lookupIfaceTop occ
 497           ; op_ty   <- forkM (mk_doc op_name rdr_ty) (tcIfaceType rdr_ty)
 498                 -- Must be done lazily for just the same reason as the
 499                 -- type of a data con; to avoid sucking in types that
 500                 -- it mentions unless it's necessray to do so
 501           ; return (op_name, dm, op_ty) }
 502
 503    mk_doc op_name op_ty = ptext (sLit "Class op") <+> sep [ppr op_name, ppr op_ty]
 504
 505    tc_fd (tvs1, tvs2) = do { tvs1' <- mapM tcIfaceTyVar tvs1
 506                            ; tvs2' <- mapM tcIfaceTyVar tvs2
 507                            ; return (tvs1', tvs2') }
 508
 509 tcIfaceDecl _ (IfaceForeign {ifName = rdr_name, ifExtName = ext_name})
 510   = do  { name <- lookupIfaceTop rdr_name
 511         ; return (ATyCon (mkForeignTyCon name ext_name
 512                                          liftedTypeKind 0)) }
 513
 514 tcIfaceDataCons :: Name -> TyCon -> [TyVar] -> IfaceConDecls -> IfL AlgTyConRhs
 515 tcIfaceDataCons tycon_name tycon _ if_cons
 516   = case if_cons of
 517         IfAbstractTyCon  -> return mkAbstractTyConRhs
 518         IfOpenDataTyCon  -> return mkOpenDataTyConRhs
 519         IfDataTyCon cons -> do  { data_cons <- mapM tc_con_decl cons
 520                                 ; return (mkDataTyConRhs data_cons) }
 521         IfNewTyCon con   -> do  { data_con <- tc_con_decl con
 522                                 ; mkNewTyConRhs tycon_name tycon data_con }
 523   where
 524     tc_con_decl (IfCon { ifConInfix = is_infix,
 525                          ifConUnivTvs = univ_tvs, ifConExTvs = ex_tvs,
 526                          ifConOcc = occ, ifConCtxt = ctxt, ifConEqSpec = spec,
 527                          ifConArgTys = args, ifConFields = field_lbls,
 528                          ifConStricts = stricts})
 529      = bindIfaceTyVars univ_tvs $ \ univ_tyvars -> do
 530        bindIfaceTyVars ex_tvs    $ \ ex_tyvars -> do
 531         { name  <- lookupIfaceTop occ
 532         ; eq_spec <- tcIfaceEqSpec spec
 533         ; theta <- tcIfaceCtxt ctxt     -- Laziness seems not worth the bother here
 534                 -- At one stage I thought that this context checking *had*
 535                 -- to be lazy, because of possible mutual recursion between the
 536                 -- type and the classe:
 537                 -- E.g.
 538                 --      class Real a where { toRat :: a -> Ratio Integer }
 539                 --      data (Real a) => Ratio a = ...
 540                 -- But now I think that the laziness in checking class ops breaks
 541                 -- the loop, so no laziness needed
 542
 543         -- Read the argument types, but lazily to avoid faulting in
 544         -- the component types unless they are really needed
 545         ; arg_tys <- forkM (mk_doc name) (mapM tcIfaceType args)
 546         ; lbl_names <- mapM lookupIfaceTop field_lbls
 547
 548         -- Remember, tycon is the representation tycon
 549         ; let orig_res_ty = mkFamilyTyConApp tycon
 550                                 (substTyVars (mkTopTvSubst eq_spec) univ_tyvars)
 551
 552         ; buildDataCon name is_infix {- Not infix -}
 553                        stricts lbl_names
 554                        univ_tyvars ex_tyvars
 555                        eq_spec theta
 556                        arg_tys orig_res_ty tycon
 557         }
 558     mk_doc con_name = ptext (sLit "Constructor") <+> ppr con_name
 559
 560 tcIfaceEqSpec :: [(OccName, IfaceType)] -> IfL [(TyVar, Type)]
 561 tcIfaceEqSpec spec
 562   = mapM do_item spec
 563   where
 564     do_item (occ, if_ty) = do { tv <- tcIfaceTyVar (occNameFS occ)
 565                               ; ty <- tcIfaceType if_ty
 566                               ; return (tv,ty) }
 567 \end{code}
 568
 569 Note [Synonym kind loop]
 570 ~~~~~~~~~~~~~~~~~~~~~~~~
 571 Notice that we eagerly grab the *kind* from the interface file, but
 572 build a forkM thunk for the *rhs* (and family stuff).  To see why,
 573 consider this (Trac #2412)
 574
 575 M.hs:       module M where { import X; data T = MkT S }
 576 X.hs:       module X where { import {-# SOURCE #-} M; type S = T }
 577 M.hs-boot:  module M where { data T }
 578
 579 When kind-checking M.hs we need S's kind.  But we do not want to
 580 find S's kind from (typeKind S-rhs), because we don't want to look at
 581 S-rhs yet!  Since S is imported from X.hi, S gets just one chance to
 582 be defined, and we must not do that until we've finished with M.T.
 583
 584 Solution: record S's kind in the interface file; now we can safely
 585 look at it.
 586
 587 %************************************************************************
 588 %*                                                                      *
 589                 Instances
 590 %*                                                                      *
 591 %************************************************************************
 592
 593 \begin{code}
 594 tcIfaceInst :: IfaceInst -> IfL Instance
 595 tcIfaceInst (IfaceInst { ifDFun = dfun_occ, ifOFlag = oflag,
 596                          ifInstCls = cls, ifInstTys = mb_tcs })
 597   = do  { dfun    <- forkM (ptext (sLit "Dict fun") <+> ppr dfun_occ) $
 598                      tcIfaceExtId dfun_occ
 599         ; let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 600         ; return (mkImportedInstance cls mb_tcs' dfun oflag) }
 601
 602 tcIfaceFamInst :: IfaceFamInst -> IfL FamInst
 603 tcIfaceFamInst (IfaceFamInst { ifFamInstTyCon = tycon,
 604                                ifFamInstFam = fam, ifFamInstTys = mb_tcs })
 605 --      { tycon'  <- forkM (ptext (sLit "Inst tycon") <+> ppr tycon) $
 606 -- the above line doesn't work, but this below does => CPP in Haskell = evil!
 607     = do tycon'  <- forkM (text ("Inst tycon") <+> ppr tycon) $
 608                     tcIfaceTyCon tycon
 609          let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 610          return (mkImportedFamInst fam mb_tcs' tycon')
 611 \end{code}
 612
 613
 614 %************************************************************************
 615 %*                                                                      *
 616                 Rules
 617 %*                                                                      *
 618 %************************************************************************
 619
 620 We move a IfaceRule from eps_rules to eps_rule_base when all its LHS free vars
 621 are in the type environment.  However, remember that typechecking a Rule may
 622 (as a side effect) augment the type envt, and so we may need to iterate the process.
 623
 624 \begin{code}
 625 tcIfaceRules :: Bool            -- True <=> ignore rules
 626              -> [IfaceRule]
 627              -> IfL [CoreRule]
 628 tcIfaceRules ignore_prags if_rules
 629   | ignore_prags = return []
 630   | otherwise    = mapM tcIfaceRule if_rules
 631
 632 tcIfaceRule :: IfaceRule -> IfL CoreRule
 633 tcIfaceRule (IfaceRule {ifRuleName = name, ifActivation = act, ifRuleBndrs = bndrs,
 634                         ifRuleHead = fn, ifRuleArgs = args, ifRuleRhs = rhs })
 635   = do  { ~(bndrs', args', rhs') <-
 636                 -- Typecheck the payload lazily, in the hope it'll never be looked at
 637                 forkM (ptext (sLit "Rule") <+> ftext name) $
 638                 bindIfaceBndrs bndrs                      $ \ bndrs' ->
 639                 do { args' <- mapM tcIfaceExpr args
 640                    ; rhs'  <- tcIfaceExpr rhs
 641                    ; return (bndrs', args', rhs') }
 642         ; let mb_tcs = map ifTopFreeName args
 643         ; return (Rule { ru_name = name, ru_fn = fn, ru_act = act,
 644                           ru_bndrs = bndrs', ru_args = args',
 645                           ru_rhs = rhs',
 646                           ru_rough = mb_tcs,
 647                           ru_local = False }) } -- An imported RULE is never for a local Id
 648                                                 -- or, even if it is (module loop, perhaps)
 649                                                 -- we'll just leave it in the non-local set
 650   where
 651         -- This function *must* mirror exactly what Rules.topFreeName does
 652         -- We could have stored the ru_rough field in the iface file
 653         -- but that would be redundant, I think.
 654         -- The only wrinkle is that we must not be deceived by
 655         -- type syononyms at the top of a type arg.  Since
 656         -- we can't tell at this point, we are careful not
 657         -- to write them out in coreRuleToIfaceRule
 658     ifTopFreeName :: IfaceExpr -> Maybe Name
 659     ifTopFreeName (IfaceType (IfaceTyConApp tc _ )) = Just (ifaceTyConName tc)
 660     ifTopFreeName (IfaceApp f _)                    = ifTopFreeName f
 661     ifTopFreeName (IfaceExt n)                      = Just n
 662     ifTopFreeName _                                 = Nothing
 663 \end{code}
 664
 665
 666 %************************************************************************
 667 %*                                                                      *
 668                 Annotations
 669 %*                                                                      *
 670 %************************************************************************
 671
 672 \begin{code}
 673 tcIfaceAnnotations :: [IfaceAnnotation] -> IfL [Annotation]
 674 tcIfaceAnnotations = mapM tcIfaceAnnotation
 675
 676 tcIfaceAnnotation :: IfaceAnnotation -> IfL Annotation
 677 tcIfaceAnnotation (IfaceAnnotation target serialized) = do
 678     target' <- tcIfaceAnnTarget target
 679     return $ Annotation {
 680         ann_target = target',
 681         ann_value = serialized
 682     }
 683
 684 tcIfaceAnnTarget :: IfaceAnnTarget -> IfL (AnnTarget Name)
 685 tcIfaceAnnTarget (NamedTarget occ) = do
 686     name <- lookupIfaceTop occ
 687     return $ NamedTarget name
 688 tcIfaceAnnTarget (ModuleTarget mod) = do
 689     return $ ModuleTarget mod
 690
 691 \end{code}
 692
 693
 694 %************************************************************************
 695 %*                                                                      *
 696                 Vectorisation information
 697 %*                                                                      *
 698 %************************************************************************
 699
 700 \begin{code}
 701 tcIfaceVectInfo :: Module -> TypeEnv  -> IfaceVectInfo -> IfL VectInfo
 702 tcIfaceVectInfo mod typeEnv (IfaceVectInfo
 703                              { ifaceVectInfoVar        = vars
 704                              , ifaceVectInfoTyCon      = tycons
 705                              , ifaceVectInfoTyConReuse = tyconsReuse
 706                              })
 707   = do { vVars     <- mapM vectVarMapping vars
 708        ; tyConRes1 <- mapM vectTyConMapping      tycons
 709        ; tyConRes2 <- mapM vectTyConReuseMapping tyconsReuse
 710        ; let (vTyCons, vDataCons, vPAs, vIsos) = unzip4 (tyConRes1 ++ tyConRes2)
 711        ; return $ VectInfo
 712                   { vectInfoVar     = mkVarEnv  vVars
 713                   , vectInfoTyCon   = mkNameEnv vTyCons
 714                   , vectInfoDataCon = mkNameEnv (concat vDataCons)
 715                   , vectInfoPADFun  = mkNameEnv vPAs
 716                   , vectInfoIso     = mkNameEnv vIsos
 717                   }
 718        }
 719   where
 720     vectVarMapping name
 721       = do { vName <- lookupOrig mod (mkVectOcc (nameOccName name))
 722            ; let { var  = lookupVar name
 723                  ; vVar = lookupVar vName
 724                  }
 725            ; return (var, (var, vVar))
 726            }
 727     vectTyConMapping name
 728       = do { vName   <- lookupOrig mod (mkVectTyConOcc (nameOccName name))
 729            ; paName  <- lookupOrig mod (mkPADFunOcc    (nameOccName name))
 730            ; isoName <- lookupOrig mod (mkVectIsoOcc   (nameOccName name))
 731            ; let { tycon    = lookupTyCon name
 732                  ; vTycon   = lookupTyCon vName
 733                  ; paTycon  = lookupVar paName
 734                  ; isoTycon = lookupVar isoName
 735                  }
 736            ; vDataCons <- mapM vectDataConMapping (tyConDataCons tycon)
 737            ; return ((name, (tycon, vTycon)),    -- (T, T_v)
 738                      vDataCons,                  -- list of (Ci, Ci_v)
 739                      (vName, (vTycon, paTycon)), -- (T_v, paT)
 740                      (name, (tycon, isoTycon)))  -- (T, isoT)
 741            }
 742     vectTyConReuseMapping name
 743       = do { paName  <- lookupOrig mod (mkPADFunOcc    (nameOccName name))
 744            ; isoName <- lookupOrig mod (mkVectIsoOcc   (nameOccName name))
 745            ; let { tycon      = lookupTyCon name
 746                  ; paTycon    = lookupVar paName
 747                  ; isoTycon   = lookupVar isoName
 748                  ; vDataCons  = [ (dataConName dc, (dc, dc))
 749                                 | dc <- tyConDataCons tycon]
 750                  }
 751            ; return ((name, (tycon, tycon)),     -- (T, T)
 752                      vDataCons,                  -- list of (Ci, Ci)
 753                      (name, (tycon, paTycon)),   -- (T, paT)
 754                      (name, (tycon, isoTycon)))  -- (T, isoT)
 755            }
 756     vectDataConMapping datacon
 757       = do { let name = dataConName datacon
 758            ; vName <- lookupOrig mod (mkVectDataConOcc (nameOccName name))
 759            ; let vDataCon = lookupDataCon vName
 760            ; return (name, (datacon, vDataCon))
 761            }
 762     --
 763     lookupVar name = case lookupTypeEnv typeEnv name of
 764                        Just (AnId var) -> var
 765                        Just _         ->
 766                          panic "TcIface.tcIfaceVectInfo: not an id"
 767                        Nothing        ->
 768                          panic "TcIface.tcIfaceVectInfo: unknown name"
 769     lookupTyCon name = case lookupTypeEnv typeEnv name of
 770                          Just (ATyCon tc) -> tc
 771                          Just _         ->
 772                            panic "TcIface.tcIfaceVectInfo: not a tycon"
 773                          Nothing        ->
 774                            panic "TcIface.tcIfaceVectInfo: unknown name"
 775     lookupDataCon name = case lookupTypeEnv typeEnv name of
 776                            Just (ADataCon dc) -> dc
 777                            Just _         ->
 778                              panic "TcIface.tcIfaceVectInfo: not a datacon"
 779                            Nothing        ->
 780                              panic "TcIface.tcIfaceVectInfo: unknown name"
 781 \end{code}
 782
 783 %************************************************************************
 784 %*                                                                      *
 785                         Types
 786 %*                                                                      *
 787 %************************************************************************
 788
 789 \begin{code}
 790 tcIfaceType :: IfaceType -> IfL Type
 791 tcIfaceType (IfaceTyVar n)        = do { tv <- tcIfaceTyVar n; return (TyVarTy tv) }
 792 tcIfaceType (IfaceAppTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (AppTy t1' t2') }
 793 tcIfaceType (IfaceFunTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (FunTy t1' t2') }
 794 tcIfaceType (IfaceTyConApp tc ts) = do { tc' <- tcIfaceTyCon tc; ts' <- tcIfaceTypes ts; return (mkTyConApp tc' ts') }
 795 tcIfaceType (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' -> do { t' <- tcIfaceType t; return (ForAllTy tv' t') }
 796 tcIfaceType (IfacePredTy st)      = do { st' <- tcIfacePredType st; return (PredTy st') }
 797
 798 tcIfaceTypes :: [IfaceType] -> IfL [Type]
 799 tcIfaceTypes tys = mapM tcIfaceType tys
 800
 801 -----------------------------------------
 802 tcIfacePredType :: IfacePredType -> IfL PredType
 803 tcIfacePredType (IfaceClassP cls ts) = do { cls' <- tcIfaceClass cls; ts' <- tcIfaceTypes ts; return (ClassP cls' ts') }
 804 tcIfacePredType (IfaceIParam ip t)   = do { ip' <- newIPName ip; t' <- tcIfaceType t; return (IParam ip' t') }
 805 tcIfacePredType (IfaceEqPred t1 t2)  = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (EqPred t1' t2') }
 806
 807 -----------------------------------------
 808 tcIfaceCtxt :: IfaceContext -> IfL ThetaType
 809 tcIfaceCtxt sts = mapM tcIfacePredType sts
 810 \end{code}
 811
 812
 813 %************************************************************************
 814 %*                                                                      *
 815                         Core
 816 %*                                                                      *
 817 %************************************************************************
 818
 819 \begin{code}
 820 tcIfaceExpr :: IfaceExpr -> IfL CoreExpr
 821 tcIfaceExpr (IfaceType ty)
 822   = Type <$> tcIfaceType ty
 823
 824 tcIfaceExpr (IfaceLcl name)
 825   = Var <$> tcIfaceLclId name
 826
 827 tcIfaceExpr (IfaceTick modName tickNo)
 828   = Var <$> tcIfaceTick modName tickNo
 829
 830 tcIfaceExpr (IfaceExt gbl)
 831   = Var <$> tcIfaceExtId gbl
 832
 833 tcIfaceExpr (IfaceLit lit)
 834   = return (Lit lit)
 835
 836 tcIfaceExpr (IfaceFCall cc ty) = do
 837     ty' <- tcIfaceType ty
 838     u <- newUnique
 839     return (Var (mkFCallId u cc ty'))
 840
 841 tcIfaceExpr (IfaceTuple boxity args)  = do
 842     args' <- mapM tcIfaceExpr args
 843     -- Put the missing type arguments back in
 844     let con_args = map (Type . exprType) args' ++ args'
 845     return (mkApps (Var con_id) con_args)
 846   where
 847     arity = length args
 848     con_id = dataConWorkId (tupleCon boxity arity)
 849
 850
 851 tcIfaceExpr (IfaceLam bndr body)
 852   = bindIfaceBndr bndr $ \bndr' ->
 853     Lam bndr' <$> tcIfaceExpr body
 854
 855 tcIfaceExpr (IfaceApp fun arg)
 856   = App <$> tcIfaceExpr fun <*> tcIfaceExpr arg
 857
 858 tcIfaceExpr (IfaceCase scrut case_bndr ty alts)  = do
 859     scrut' <- tcIfaceExpr scrut
 860     case_bndr_name <- newIfaceName (mkVarOccFS case_bndr)
 861     let
 862         scrut_ty   = exprType scrut'
 863         case_bndr' = mkLocalId case_bndr_name scrut_ty
 864         tc_app     = splitTyConApp scrut_ty
 865                 -- NB: Won't always succeed (polymoprhic case)
 866                 --     but won't be demanded in those cases
 867                 -- NB: not tcSplitTyConApp; we are looking at Core here
 868                 --     look through non-rec newtypes to find the tycon that
 869                 --     corresponds to the datacon in this case alternative
 870
 871     extendIfaceIdEnv [case_bndr'] $ do
 872      alts' <- mapM (tcIfaceAlt scrut' tc_app) alts
 873      ty' <- tcIfaceType ty
 874      return (Case scrut' case_bndr' ty' alts')
 875
 876 tcIfaceExpr (IfaceLet (IfaceNonRec bndr rhs) body) = do
 877     rhs' <- tcIfaceExpr rhs
 878     id   <- tcIfaceLetBndr bndr
 879     body' <- extendIfaceIdEnv [id] (tcIfaceExpr body)
 880     return (Let (NonRec id rhs') body')
 881
 882 tcIfaceExpr (IfaceLet (IfaceRec pairs) body) = do
 883     ids <- mapM tcIfaceLetBndr bndrs
 884     extendIfaceIdEnv ids $ do
 885      rhss' <- mapM tcIfaceExpr rhss
 886      body' <- tcIfaceExpr body
 887      return (Let (Rec (ids `zip` rhss')) body')
 888   where
 889     (bndrs, rhss) = unzip pairs
 890
 891 tcIfaceExpr (IfaceCast expr co) = do
 892     expr' <- tcIfaceExpr expr
 893     co' <- tcIfaceType co
 894     return (Cast expr' co')
 895
 896 tcIfaceExpr (IfaceNote note expr) = do
 897     expr' <- tcIfaceExpr expr
 898     case note of
 899         IfaceInlineMe     -> return (Note InlineMe   expr')
 900         IfaceSCC cc       -> return (Note (SCC cc)   expr')
 901         IfaceCoreNote n   -> return (Note (CoreNote n) expr')
 902
 903 -------------------------
 904 tcIfaceAlt :: CoreExpr -> (TyCon, [Type])
 905            -> (IfaceConAlt, [FastString], IfaceExpr)
 906            -> IfL (AltCon, [TyVar], CoreExpr)
 907 tcIfaceAlt _ _ (IfaceDefault, names, rhs)
 908   = ASSERT( null names ) do
 909     rhs' <- tcIfaceExpr rhs
 910     return (DEFAULT, [], rhs')
 911
 912 tcIfaceAlt _ _ (IfaceLitAlt lit, names, rhs)
 913   = ASSERT( null names ) do
 914     rhs' <- tcIfaceExpr rhs
 915     return (LitAlt lit, [], rhs')
 916
 917 -- A case alternative is made quite a bit more complicated
 918 -- by the fact that we omit type annotations because we can
 919 -- work them out.  True enough, but its not that easy!
 920 tcIfaceAlt scrut (tycon, inst_tys) (IfaceDataAlt data_occ, arg_strs, rhs)
 921   = do  { con <- tcIfaceDataCon data_occ
 922         ; when (debugIsOn && not (con `elem` tyConDataCons tycon))
 923                (failIfM (ppr scrut $$ ppr con $$ ppr tycon $$ ppr (tyConDataCons tycon)))
 924         ; tcIfaceDataAlt con inst_tys arg_strs rhs }
 925
 926 tcIfaceAlt _ (tycon, inst_tys) (IfaceTupleAlt _boxity, arg_occs, rhs)
 927   = ASSERT( isTupleTyCon tycon )
 928     do  { let [data_con] = tyConDataCons tycon
 929         ; tcIfaceDataAlt data_con inst_tys arg_occs rhs }
 930
 931 tcIfaceDataAlt :: DataCon -> [Type] -> [FastString] -> IfaceExpr
 932                -> IfL (AltCon, [TyVar], CoreExpr)
 933 tcIfaceDataAlt con inst_tys arg_strs rhs
 934   = do  { us <- newUniqueSupply
 935         ; let uniqs = uniqsFromSupply us
 936         ; let (ex_tvs, co_tvs, arg_ids)
 937                       = dataConRepFSInstPat arg_strs uniqs con inst_tys
 938               all_tvs = ex_tvs ++ co_tvs
 939
 940         ; rhs' <- extendIfaceTyVarEnv all_tvs   $
 941                   extendIfaceIdEnv arg_ids      $
 942                   tcIfaceExpr rhs
 943         ; return (DataAlt con, all_tvs ++ arg_ids, rhs') }
 944 \end{code}
 945
 946
 947 \begin{code}
 948 tcExtCoreBindings :: [IfaceBinding] -> IfL [CoreBind]   -- Used for external core
 949 tcExtCoreBindings []     = return []
 950 tcExtCoreBindings (b:bs) = do_one b (tcExtCoreBindings bs)
 951
 952 do_one :: IfaceBinding -> IfL [CoreBind] -> IfL [CoreBind]
 953 do_one (IfaceNonRec bndr rhs) thing_inside
 954   = do  { rhs' <- tcIfaceExpr rhs
 955         ; bndr' <- newExtCoreBndr bndr
 956         ; extendIfaceIdEnv [bndr'] $ do
 957         { core_binds <- thing_inside
 958         ; return (NonRec bndr' rhs' : core_binds) }}
 959
 960 do_one (IfaceRec pairs) thing_inside
 961   = do  { bndrs' <- mapM newExtCoreBndr bndrs
 962         ; extendIfaceIdEnv bndrs' $ do
 963         { rhss' <- mapM tcIfaceExpr rhss
 964         ; core_binds <- thing_inside
 965         ; return (Rec (bndrs' `zip` rhss') : core_binds) }}
 966   where
 967     (bndrs,rhss) = unzip pairs
 968 \end{code}
 969
 970
 971 %************************************************************************
 972 %*                                                                      *
 973                 IdInfo
 974 %*                                                                      *
 975 %************************************************************************
 976
 977 \begin{code}
 978 tcIdDetails :: Type -> IfaceIdDetails -> IfL IdDetails
 979 tcIdDetails _  IfVanillaId = return VanillaId
 980 tcIdDetails _  IfDFunId    = return DFunId
 981 tcIdDetails ty (IfRecSelId naughty)
 982   = return (RecSelId { sel_tycon = tc, sel_naughty = naughty })
 983   where
 984     (_, _, tau) = tcSplitSigmaTy ty
 985     tc = tyConAppTyCon (funArgTy tau)
 986     -- A bit fragile. Relies on the selector type looking like
 987     --    forall abc. (stupid-context) => T a b c -> blah
 988
 989 tcIdInfo :: Bool -> Name -> Type -> IfaceIdInfo -> IfL IdInfo
 990 tcIdInfo ignore_prags name ty info
 991   | ignore_prags = return vanillaIdInfo
 992   | otherwise    = case info of
 993                         NoInfo       -> return vanillaIdInfo
 994                         HasInfo info -> foldlM tcPrag init_info info
 995   where
 996     -- Set the CgInfo to something sensible but uninformative before
 997     -- we start; default assumption is that it has CAFs
 998     init_info = vanillaIdInfo
 999
1000     tcPrag :: IdInfo -> IfaceInfoItem -> IfL IdInfo
1001     tcPrag info HsNoCafRefs         = return (info `setCafInfo`   NoCafRefs)
1002     tcPrag info (HsArity arity)     = return (info `setArityInfo` arity)
1003     tcPrag info (HsStrictness str)  = return (info `setAllStrictnessInfo` Just str)
1004
1005         -- The next two are lazy, so they don't transitively suck stuff in
1006     tcPrag info (HsWorker nm arity) = tcWorkerInfo ty info nm arity
1007     tcPrag info (HsInline inline_prag) = return (info `setInlinePragInfo` inline_prag)
1008     tcPrag info (HsUnfold expr) = do
1009           maybe_expr' <- tcPragExpr name expr
1010           let
1011                 -- maybe_expr' doesn't get looked at if the unfolding
1012                 -- is never inspected; so the typecheck doesn't even happen
1013                 unfold_info = case maybe_expr' of
1014                                 Nothing    -> noUnfolding
1015                                 Just expr' -> mkTopUnfolding expr'
1016           return (info `setUnfoldingInfoLazily` unfold_info)
1017 \end{code}
1018
1019 \begin{code}
1020 tcWorkerInfo :: Type -> IdInfo -> Name -> Arity -> IfL IdInfo
1021 tcWorkerInfo ty info wkr arity
1022   = do  { mb_wkr_id <- forkM_maybe doc (tcIfaceExtId wkr)
1023
1024         -- We return without testing maybe_wkr_id, but as soon as info is
1025         -- looked at we will test it.  That's ok, because its outside the
1026         -- knot; and there seems no big reason to further defer the
1027         -- tcIfaceId lookup.  (Contrast with tcPragExpr, where postponing walking
1028         -- over the unfolding until it's actually used does seem worth while.)
1029         ; us <- newUniqueSupply
1030
1031         ; return (case mb_wkr_id of
1032                      Nothing     -> info
1033                      Just wkr_id -> add_wkr_info us wkr_id info) }
1034   where
1035     doc = text "Worker for" <+> ppr wkr
1036     add_wkr_info us wkr_id info
1037         = info `setUnfoldingInfoLazily`  mk_unfolding us wkr_id
1038                `setWorkerInfo`           HasWorker wkr_id arity
1039
1040     mk_unfolding us wkr_id = mkTopUnfolding (initUs_ us (mkWrapper ty strict_sig) wkr_id)
1041
1042         -- We are relying here on strictness info always appearing
1043         -- before worker info,  fingers crossed ....
1044     strict_sig = case newStrictnessInfo info of
1045                    Just sig -> sig
1046                    Nothing  -> pprPanic "Worker info but no strictness for" (ppr wkr)
1047 \end{code}
1048
1049 For unfoldings we try to do the job lazily, so that we never type check
1050 an unfolding that isn't going to be looked at.
1051
1052 \begin{code}
1053 tcPragExpr :: Name -> IfaceExpr -> IfL (Maybe CoreExpr)
1054 tcPragExpr name expr
1055   = forkM_maybe doc $ do
1056     core_expr' <- tcIfaceExpr expr
1057
1058                 -- Check for type consistency in the unfolding
1059     ifOptM Opt_DoCoreLinting $ do
1060         in_scope <- get_in_scope_ids
1061         case lintUnfolding noSrcLoc in_scope core_expr' of
1062           Nothing       -> return ()
1063           Just fail_msg -> pprPanic "Iface Lint failure" (hang doc 2 fail_msg)
1064
1065     return core_expr'
1066   where
1067     doc = text "Unfolding of" <+> ppr name
1068     get_in_scope_ids    -- Urgh; but just for linting
1069         = setLclEnv () $
1070           do    { env <- getGblEnv
1071                 ; case if_rec_types env of {
1072                           Nothing -> return [] ;
1073                           Just (_, get_env) -> do
1074                 { type_env <- get_env
1075                 ; return (typeEnvIds type_env) }}}
1076 \end{code}
1077
1078
1079
1080 %************************************************************************
1081 %*                                                                      *
1082                 Getting from Names to TyThings
1083 %*                                                                      *
1084 %************************************************************************
1085
1086 \begin{code}
1087 tcIfaceGlobal :: Name -> IfL TyThing
1088 tcIfaceGlobal name
1089   | Just thing <- wiredInNameTyThing_maybe name
1090         -- Wired-in things include TyCons, DataCons, and Ids
1091   = do { ifCheckWiredInThing thing; return thing }
1092   | otherwise
1093   = do  { env <- getGblEnv
1094         ; case if_rec_types env of {    -- Note [Tying the knot]
1095             Just (mod, get_type_env)
1096                 | nameIsLocalOrFrom mod name
1097                 -> do           -- It's defined in the module being compiled
1098                 { type_env <- setLclEnv () get_type_env         -- yuk
1099                 ; case lookupNameEnv type_env name of
1100                         Just thing -> return thing
1101                         Nothing   -> pprPanic "tcIfaceGlobal (local): not found:"
1102                                                 (ppr name $$ ppr type_env) }
1103
1104           ; _ -> do
1105
1106         { hsc_env <- getTopEnv
1107         ; mb_thing <- liftIO (lookupTypeHscEnv hsc_env name)
1108         ; case mb_thing of {
1109             Just thing -> return thing ;
1110             Nothing    -> do
1111
1112         { mb_thing <- importDecl name   -- It's imported; go get it
1113         ; case mb_thing of
1114             Failed err      -> failIfM err
1115             Succeeded thing -> return thing
1116     }}}}}
1117
1118 -- Note [Tying the knot]
1119 -- ~~~~~~~~~~~~~~~~~~~~~
1120 -- The if_rec_types field is used in two situations:
1121 --
1122 -- a) Compiling M.hs, which indiretly imports Foo.hi, which mentions M.T
1123 --    Then we look up M.T in M's type environment, which is splatted into if_rec_types
1124 --    after we've built M's type envt.
1125 --
1126 -- b) In ghc --make, during the upsweep, we encounter M.hs, whose interface M.hi
1127 --    is up to date.  So we call typecheckIface on M.hi.  This splats M.T into
1128 --    if_rec_types so that the (lazily typechecked) decls see all the other decls
1129 --
1130 -- In case (b) it's important to do the if_rec_types check *before* looking in the HPT
1131 -- Because if M.hs also has M.hs-boot, M.T will *already be* in the HPT, but in its
1132 -- emasculated form (e.g. lacking data constructors).
1133
1134 tcIfaceTyCon :: IfaceTyCon -> IfL TyCon
1135 tcIfaceTyCon IfaceIntTc         = tcWiredInTyCon intTyCon
1136 tcIfaceTyCon IfaceBoolTc        = tcWiredInTyCon boolTyCon
1137 tcIfaceTyCon IfaceCharTc        = tcWiredInTyCon charTyCon
1138 tcIfaceTyCon IfaceListTc        = tcWiredInTyCon listTyCon
1139 tcIfaceTyCon IfacePArrTc        = tcWiredInTyCon parrTyCon
1140 tcIfaceTyCon (IfaceTupTc bx ar) = tcWiredInTyCon (tupleTyCon bx ar)
1141 tcIfaceTyCon (IfaceTc name)     = do { thing <- tcIfaceGlobal name
1142                                      ; return (check_tc (tyThingTyCon thing)) }
1143   where
1144     check_tc tc
1145      | debugIsOn = case toIfaceTyCon tc of
1146                    IfaceTc _ -> tc
1147                    _         -> pprTrace "check_tc" (ppr tc) tc
1148      | otherwise = tc
1149 -- we should be okay just returning Kind constructors without extra loading
1150 tcIfaceTyCon IfaceLiftedTypeKindTc   = return liftedTypeKindTyCon
1151 tcIfaceTyCon IfaceOpenTypeKindTc     = return openTypeKindTyCon
1152 tcIfaceTyCon IfaceUnliftedTypeKindTc = return unliftedTypeKindTyCon
1153 tcIfaceTyCon IfaceArgTypeKindTc      = return argTypeKindTyCon
1154 tcIfaceTyCon IfaceUbxTupleKindTc     = return ubxTupleKindTyCon
1155
1156 -- Even though we are in an interface file, we want to make
1157 -- sure the instances and RULES of this tycon are loaded
1158 -- Imagine: f :: Double -> Double
1159 tcWiredInTyCon :: TyCon -> IfL TyCon
1160 tcWiredInTyCon tc = do { ifCheckWiredInThing (ATyCon tc)
1161                        ; return tc }
1162
1163 tcIfaceClass :: Name -> IfL Class
1164 tcIfaceClass name = do { thing <- tcIfaceGlobal name
1165                        ; return (tyThingClass thing) }
1166
1167 tcIfaceDataCon :: Name -> IfL DataCon
1168 tcIfaceDataCon name = do { thing <- tcIfaceGlobal name
1169                          ; case thing of
1170                                 ADataCon dc -> return dc
1171                                 _       -> pprPanic "tcIfaceExtDC" (ppr name$$ ppr thing) }
1172
1173 tcIfaceExtId :: Name -> IfL Id
1174 tcIfaceExtId name = do { thing <- tcIfaceGlobal name
1175                        ; case thing of
1176                           AnId id -> return id
1177                           _       -> pprPanic "tcIfaceExtId" (ppr name$$ ppr thing) }
1178 \end{code}
1179
1180 %************************************************************************
1181 %*                                                                      *
1182                 Bindings
1183 %*                                                                      *
1184 %************************************************************************
1185
1186 \begin{code}
1187 bindIfaceBndr :: IfaceBndr -> (CoreBndr -> IfL a) -> IfL a
1188 bindIfaceBndr (IfaceIdBndr (fs, ty)) thing_inside
1189   = do  { name <- newIfaceName (mkVarOccFS fs)
1190         ; ty' <- tcIfaceType ty
1191         ; let id = mkLocalId name ty'
1192         ; extendIfaceIdEnv [id] (thing_inside id) }
1193 bindIfaceBndr (IfaceTvBndr bndr) thing_inside
1194   = bindIfaceTyVar bndr thing_inside
1195
1196 bindIfaceBndrs :: [IfaceBndr] -> ([CoreBndr] -> IfL a) -> IfL a
1197 bindIfaceBndrs []     thing_inside = thing_inside []
1198 bindIfaceBndrs (b:bs) thing_inside
1199   = bindIfaceBndr b     $ \ b' ->
1200     bindIfaceBndrs bs   $ \ bs' ->
1201     thing_inside (b':bs')
1202
1203 -----------------------
1204 tcIfaceLetBndr :: IfaceLetBndr -> IfL Id
1205 tcIfaceLetBndr (IfLetBndr fs ty info)
1206   = do  { name <- newIfaceName (mkVarOccFS fs)
1207         ; ty' <- tcIfaceType ty
1208         ; case info of
1209                 NoInfo    -> return (mkLocalId name ty')
1210                 HasInfo i -> return (mkLocalIdWithInfo name ty' (tc_info i)) }
1211   where
1212         -- Similar to tcIdInfo, but much simpler
1213     tc_info [] = vanillaIdInfo
1214     tc_info (HsInline p     : i) = tc_info i `setInlinePragInfo` p
1215     tc_info (HsArity a      : i) = tc_info i `setArityInfo` a
1216     tc_info (HsStrictness s : i) = tc_info i `setAllStrictnessInfo` Just s
1217     tc_info (other          : i) = pprTrace "tcIfaceLetBndr: discarding unexpected IdInfo"
1218                                             (ppr other) (tc_info i)
1219
1220 -----------------------
1221 newExtCoreBndr :: IfaceLetBndr -> IfL Id
1222 newExtCoreBndr (IfLetBndr var ty _)    -- Ignoring IdInfo for now
1223   = do  { mod <- getIfModule
1224         ; name <- newGlobalBinder mod (mkVarOccFS var) noSrcSpan
1225         ; ty' <- tcIfaceType ty
1226         ; return (mkLocalId name ty') }
1227
1228 -----------------------
1229 bindIfaceTyVar :: IfaceTvBndr -> (TyVar -> IfL a) -> IfL a
1230 bindIfaceTyVar (occ,kind) thing_inside
1231   = do  { name <- newIfaceName (mkTyVarOccFS occ)
1232         ; tyvar <- mk_iface_tyvar name kind
1233         ; extendIfaceTyVarEnv [tyvar] (thing_inside tyvar) }
1234
1235 bindIfaceTyVars :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
1236 bindIfaceTyVars bndrs thing_inside
1237   = do  { names <- newIfaceNames (map mkTyVarOccFS occs)
1238         ; tyvars <- zipWithM mk_iface_tyvar names kinds
1239         ; extendIfaceTyVarEnv tyvars (thing_inside tyvars) }
1240   where
1241     (occs,kinds) = unzip bndrs
1242
1243 mk_iface_tyvar :: Name -> IfaceKind -> IfL TyVar
1244 mk_iface_tyvar name ifKind
1245    = do { kind <- tcIfaceType ifKind
1246         ; if isCoercionKind kind then
1247                 return (Var.mkCoVar name kind)
1248           else
1249                 return (Var.mkTyVar name kind) }
1250 \end{code}
1251