compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2006
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 -- | Types for the per-module compiler
   8 module HscTypes (
   9         -- * compilation state
  10         HscEnv(..), hscEPS,
  11         FinderCache, FindResult(..), ModLocationCache,
  12         Target(..), TargetId(..), pprTarget, pprTargetId,
  13         ModuleGraph, emptyMG,
  14
  15         -- * Information about modules
  16         ModDetails(..), emptyModDetails,
  17         ModGuts(..), CgGuts(..), ForeignStubs(..),
  18         ImportedMods,
  19
  20         ModSummary(..), ms_mod_name, showModMsg, isBootSummary,
  21         msHsFilePath, msHiFilePath, msObjFilePath,
  22
  23         -- * Information about the module being compiled
  24         HscSource(..), isHsBoot, hscSourceString,       -- Re-exported from DriverPhases
  25
  26         -- * State relating to modules in this package
  27         HomePackageTable, HomeModInfo(..), emptyHomePackageTable,
  28         hptInstances, hptRules, hptVectInfo,
  29
  30         -- * State relating to known packages
  31         ExternalPackageState(..), EpsStats(..), addEpsInStats,
  32         PackageTypeEnv, PackageIfaceTable, emptyPackageIfaceTable,
  33         lookupIfaceByModule, emptyModIface,
  34
  35         PackageInstEnv, PackageRuleBase,
  36
  37
  38         -- * Annotations
  39         prepareAnnotations,
  40
  41         -- * Interactive context
  42         InteractiveContext(..), emptyInteractiveContext,
  43         icPrintUnqual, extendInteractiveContext,
  44         substInteractiveContext,
  45         mkPrintUnqualified, pprModulePrefix,
  46
  47         -- * Interfaces
  48         ModIface(..), mkIfaceWarnCache, mkIfaceHashCache, mkIfaceFixCache,
  49         emptyIfaceWarnCache,
  50
  51         -- * Fixity
  52         FixityEnv, FixItem(..), lookupFixity, emptyFixityEnv,
  53
  54         -- * TyThings and type environments
  55         TyThing(..),
  56         tyThingClass, tyThingTyCon, tyThingDataCon, tyThingId,
  57         implicitTyThings, isImplicitTyThing,
  58
  59         TypeEnv, lookupType, lookupTypeHscEnv, mkTypeEnv, emptyTypeEnv,
  60         extendTypeEnv, extendTypeEnvList, extendTypeEnvWithIds, lookupTypeEnv,
  61         typeEnvElts, typeEnvClasses, typeEnvTyCons, typeEnvIds,
  62         typeEnvDataCons,
  63
  64         -- * MonadThings
  65         MonadThings(..),
  66
  67         -- * Information on imports and exports
  68         WhetherHasOrphans, IsBootInterface, Usage(..),
  69         Dependencies(..), noDependencies,
  70         NameCache(..), OrigNameCache, OrigIParamCache,
  71         Avails, availsToNameSet, availsToNameEnv, availName, availNames,
  72         GenAvailInfo(..), AvailInfo, RdrAvailInfo,
  73         IfaceExport,
  74
  75         -- * Warnings
  76         Warnings(..), WarningTxt(..), plusWarns,
  77
  78         -- * Linker stuff
  79         Linkable(..), isObjectLinkable,
  80         Unlinked(..), CompiledByteCode,
  81         isObject, nameOfObject, isInterpretable, byteCodeOfObject,
  82
  83         -- * Program coverage
  84         HpcInfo(..), emptyHpcInfo, isHpcUsed, AnyHpcUsage,
  85
  86         -- * Breakpoints
  87         ModBreaks (..), BreakIndex, emptyModBreaks,
  88
  89         -- * Vectorisation information
  90         VectInfo(..), IfaceVectInfo(..), noVectInfo, plusVectInfo,
  91         noIfaceVectInfo,
  92
  93         -- * Compilation errors and warnings
  94         SourceError, GhcApiError, mkSrcErr, srcErrorMessages, mkApiErr,
  95         throwOneError, handleSourceError,
  96         handleFlagWarnings, printOrThrowWarnings,
  97     ) where
  98
  99 #include "HsVersions.h"
 100
 101 #ifdef GHCI
 102 import ByteCodeAsm      ( CompiledByteCode )
 103 import {-# SOURCE #-}  InteractiveEval ( Resume )
 104 #endif
 105
 106 import HsSyn
 107 import RdrName
 108 import Name
 109 import NameEnv
 110 import NameSet
 111 import Module
 112 import InstEnv          ( InstEnv, Instance )
 113 import FamInstEnv       ( FamInstEnv, FamInst )
 114 import Rules            ( RuleBase )
 115 import CoreSyn          ( CoreBind )
 116 import VarEnv
 117 import Var
 118 import Id
 119 import Type
 120
 121 import Annotations
 122 import Class            ( Class, classAllSelIds, classATs, classTyCon )
 123 import TyCon
 124 import DataCon          ( DataCon, dataConImplicitIds, dataConWrapId )
 125 import PrelNames        ( gHC_PRIM )
 126 import Packages hiding ( Version(..) )
 127 import DynFlags         ( DynFlags(..), isOneShot, HscTarget (..), dopt,
 128                           DynFlag(..) )
 129 import DriverPhases     ( HscSource(..), isHsBoot, hscSourceString, Phase )
 130 import BasicTypes       ( IPName, defaultFixity, WarningTxt(..) )
 131 import OptimizationFuel ( OptFuelState )
 132 import IfaceSyn
 133 import CoreSyn          ( CoreRule )
 134 import Maybes           ( orElse, expectJust, catMaybes )
 135 import Outputable
 136 import BreakArray
 137 import SrcLoc           ( SrcSpan, Located(..) )
 138 import UniqFM           ( lookupUFM, eltsUFM, emptyUFM )
 139 import UniqSupply       ( UniqSupply )
 140 import FastString
 141 import StringBuffer     ( StringBuffer )
 142 import Fingerprint
 143 import MonadUtils
 144 import Data.Dynamic     ( Typeable )
 145 import qualified Data.Dynamic as Dyn
 146 import Bag
 147 import ErrUtils
 148
 149 import System.FilePath
 150 import System.Time      ( ClockTime )
 151 import Data.IORef
 152 import Data.Array       ( Array, array )
 153 import Data.List
 154 import Data.Map (Map)
 155 import Control.Monad    ( mplus, guard, liftM, when )
 156 import Exception
 157
 158 -- -----------------------------------------------------------------------------
 159 -- Source Errors
 160
 161 -- When the compiler (HscMain) discovers errors, it throws an
 162 -- exception in the IO monad.
 163
 164 mkSrcErr :: ErrorMessages -> SourceError
 165 srcErrorMessages :: SourceError -> ErrorMessages
 166 mkApiErr :: SDoc -> GhcApiError
 167
 168 throwOneError :: MonadIO m => ErrMsg -> m ab
 169 throwOneError err = liftIO $ throwIO $ mkSrcErr $ unitBag err
 170
 171 -- | A source error is an error that is caused by one or more errors in the
 172 -- source code.  A 'SourceError' is thrown by many functions in the
 173 -- compilation pipeline.  Inside GHC these errors are merely printed via
 174 -- 'log_action', but API clients may treat them differently, for example,
 175 -- insert them into a list box.  If you want the default behaviour, use the
 176 -- idiom:
 177 --
 178 -- > handleSourceError printExceptionAndWarnings $ do
 179 -- >   ... api calls that may fail ...
 180 --
 181 -- The 'SourceError's error messages can be accessed via 'srcErrorMessages'.
 182 -- This list may be empty if the compiler failed due to @-Werror@
 183 -- ('Opt_WarnIsError').
 184 --
 185 -- See 'printExceptionAndWarnings' for more information on what to take care
 186 -- of when writing a custom error handler.
 187 data SourceError = SourceError ErrorMessages
 188
 189 instance Show SourceError where
 190   show (SourceError msgs) = unlines . map show . bagToList $ msgs
 191     -- ToDo: is there some nicer way to print this?
 192
 193 sourceErrorTc :: Dyn.TyCon
 194 sourceErrorTc = Dyn.mkTyCon "SourceError"
 195 {-# NOINLINE sourceErrorTc #-}
 196 instance Typeable SourceError where
 197   typeOf _ = Dyn.mkTyConApp sourceErrorTc []
 198
 199 instance Exception SourceError
 200
 201 mkSrcErr = SourceError
 202
 203 -- | Perform the given action and call the exception handler if the action
 204 -- throws a 'SourceError'.  See 'SourceError' for more information.
 205 handleSourceError :: (ExceptionMonad m) =>
 206                      (SourceError -> m a) -- ^ exception handler
 207                   -> m a -- ^ action to perform
 208                   -> m a
 209 handleSourceError handler act =
 210   gcatch act (\(e :: SourceError) -> handler e)
 211
 212 srcErrorMessages (SourceError msgs) = msgs
 213
 214 -- | XXX: what exactly is an API error?
 215 data GhcApiError = GhcApiError SDoc
 216
 217 instance Show GhcApiError where
 218   show (GhcApiError msg) = showSDoc msg
 219
 220 ghcApiErrorTc :: Dyn.TyCon
 221 ghcApiErrorTc = Dyn.mkTyCon "GhcApiError"
 222 {-# NOINLINE ghcApiErrorTc #-}
 223 instance Typeable GhcApiError where
 224   typeOf _ = Dyn.mkTyConApp ghcApiErrorTc []
 225
 226 instance Exception GhcApiError
 227
 228 mkApiErr = GhcApiError
 229
 230 -- | Given a bag of warnings, turn them into an exception if
 231 -- -Werror is enabled, or print them out otherwise.
 232 printOrThrowWarnings :: DynFlags -> Bag WarnMsg -> IO ()
 233 printOrThrowWarnings dflags warns
 234   | dopt Opt_WarnIsError dflags
 235   = when (not (isEmptyBag warns)) $ do
 236       throwIO $ mkSrcErr $ warns `snocBag` warnIsErrorMsg
 237   | otherwise
 238   = printBagOfWarnings dflags warns
 239
 240 handleFlagWarnings :: DynFlags -> [Located String] -> IO ()
 241 handleFlagWarnings dflags warns
 242  = when (dopt Opt_WarnDeprecatedFlags dflags) $ do
 243         -- It would be nicer if warns :: [Located Message], but that
 244         -- has circular import problems.
 245       let bag = listToBag [ mkPlainWarnMsg loc (text warn)
 246                           | L loc warn <- warns ]
 247
 248       printOrThrowWarnings dflags bag
 249 \end{code}
 250
 251 \begin{code}
 252 -- | Hscenv is like 'Session', except that some of the fields are immutable.
 253 -- An HscEnv is used to compile a single module from plain Haskell source
 254 -- code (after preprocessing) to either C, assembly or C--.  Things like
 255 -- the module graph don't change during a single compilation.
 256 --
 257 -- Historical note: \"hsc\" used to be the name of the compiler binary,
 258 -- when there was a separate driver and compiler.  To compile a single
 259 -- module, the driver would invoke hsc on the source code... so nowadays
 260 -- we think of hsc as the layer of the compiler that deals with compiling
 261 -- a single module.
 262 data HscEnv
 263   = HscEnv {
 264         hsc_dflags :: DynFlags,
 265                 -- ^ The dynamic flag settings
 266
 267         hsc_targets :: [Target],
 268                 -- ^ The targets (or roots) of the current session
 269
 270         hsc_mod_graph :: ModuleGraph,
 271                 -- ^ The module graph of the current session
 272
 273         hsc_IC :: InteractiveContext,
 274                 -- ^ The context for evaluating interactive statements
 275
 276         hsc_HPT    :: HomePackageTable,
 277                 -- ^ The home package table describes already-compiled
 278                 -- home-package modules, /excluding/ the module we
 279                 -- are compiling right now.
 280                 -- (In one-shot mode the current module is the only
 281                 --  home-package module, so hsc_HPT is empty.  All other
 282                 --  modules count as \"external-package\" modules.
 283                 --  However, even in GHCi mode, hi-boot interfaces are
 284                 --  demand-loaded into the external-package table.)
 285                 --
 286                 -- 'hsc_HPT' is not mutable because we only demand-load
 287                 -- external packages; the home package is eagerly
 288                 -- loaded, module by module, by the compilation manager.
 289                 --
 290                 -- The HPT may contain modules compiled earlier by @--make@
 291                 -- but not actually below the current module in the dependency
 292                 -- graph.
 293
 294                 -- (This changes a previous invariant: changed Jan 05.)
 295
 296         hsc_EPS :: {-# UNPACK #-} !(IORef ExternalPackageState),
 297                 -- ^ Information about the currently loaded external packages.
 298                 -- This is mutable because packages will be demand-loaded during
 299                 -- a compilation run as required.
 300
 301         hsc_NC  :: {-# UNPACK #-} !(IORef NameCache),
 302                 -- ^ As with 'hsc_EPS', this is side-effected by compiling to
 303                 -- reflect sucking in interface files.  They cache the state of
 304                 -- external interface files, in effect.
 305
 306         hsc_FC   :: {-# UNPACK #-} !(IORef FinderCache),
 307                 -- ^ The cached result of performing finding in the file system
 308         hsc_MLC  :: {-# UNPACK #-} !(IORef ModLocationCache),
 309                 -- ^ This caches the location of modules, so we don't have to
 310                 -- search the filesystem multiple times. See also 'hsc_FC'.
 311
 312         hsc_OptFuel :: OptFuelState,
 313                 -- ^ Settings to control the use of \"optimization fuel\":
 314                 -- by limiting the number of transformations,
 315                 -- we can use binary search to help find compiler bugs.
 316
 317         hsc_type_env_var :: Maybe (Module, IORef TypeEnv)
 318                 -- ^ Used for one-shot compilation only, to initialise
 319                 -- the 'IfGblEnv'. See 'TcRnTypes.tcg_type_env_var' for
 320                 -- 'TcRunTypes.TcGblEnv'
 321  }
 322
 323 hscEPS :: HscEnv -> IO ExternalPackageState
 324 hscEPS hsc_env = readIORef (hsc_EPS hsc_env)
 325
 326 -- | A compilation target.
 327 --
 328 -- A target may be supplied with the actual text of the
 329 -- module.  If so, use this instead of the file contents (this
 330 -- is for use in an IDE where the file hasn't been saved by
 331 -- the user yet).
 332 data Target = Target
 333       { targetId           :: TargetId  -- ^ module or filename
 334       , targetAllowObjCode :: Bool      -- ^ object code allowed?
 335       , targetContents     :: Maybe (StringBuffer,ClockTime)
 336                                         -- ^ in-memory text buffer?
 337       }
 338
 339 data TargetId
 340   = TargetModule ModuleName
 341         -- ^ A module name: search for the file
 342   | TargetFile FilePath (Maybe Phase)
 343         -- ^ A filename: preprocess & parse it to find the module name.
 344         -- If specified, the Phase indicates how to compile this file
 345         -- (which phase to start from).  Nothing indicates the starting phase
 346         -- should be determined from the suffix of the filename.
 347   deriving Eq
 348
 349 pprTarget :: Target -> SDoc
 350 pprTarget (Target id obj _) =
 351    (if obj then char '*' else empty) <> pprTargetId id
 352
 353 instance Outputable Target where
 354     ppr = pprTarget
 355
 356 pprTargetId :: TargetId -> SDoc
 357 pprTargetId (TargetModule m) = ppr m
 358 pprTargetId (TargetFile f _) = text f
 359
 360 instance Outputable TargetId where
 361     ppr = pprTargetId
 362
 363 -- | Helps us find information about modules in the home package
 364 type HomePackageTable  = ModuleNameEnv HomeModInfo
 365         -- Domain = modules in the home package that have been fully compiled
 366         -- "home" package name cached here for convenience
 367
 368 -- | Helps us find information about modules in the imported packages
 369 type PackageIfaceTable = ModuleEnv ModIface
 370         -- Domain = modules in the imported packages
 371
 372 emptyHomePackageTable :: HomePackageTable
 373 emptyHomePackageTable  = emptyUFM
 374
 375 emptyPackageIfaceTable :: PackageIfaceTable
 376 emptyPackageIfaceTable = emptyModuleEnv
 377
 378 -- | Information about modules in the package being compiled
 379 data HomeModInfo
 380   = HomeModInfo {
 381       hm_iface    :: !ModIface,
 382         -- ^ The basic loaded interface file: every loaded module has one of
 383         -- these, even if it is imported from another package
 384       hm_details  :: !ModDetails,
 385         -- ^ Extra information that has been created from the 'ModIface' for
 386         -- the module, typically during typechecking
 387       hm_linkable :: !(Maybe Linkable)
 388         -- ^ The actual artifact we would like to link to access things in
 389         -- this module.
 390         --
 391         -- 'hm_linkable' might be Nothing:
 392         --
 393         --   1. If this is an .hs-boot module
 394         --
 395         --   2. Temporarily during compilation if we pruned away
 396         --      the old linkable because it was out of date.
 397         --
 398         -- After a complete compilation ('GHC.load'), all 'hm_linkable' fields
 399         -- in the 'HomePackageTable' will be @Just@.
 400         --
 401         -- When re-linking a module ('HscMain.HscNoRecomp'), we construct the
 402         -- 'HomeModInfo' by building a new 'ModDetails' from the old
 403         -- 'ModIface' (only).
 404     }
 405
 406 -- | Find the 'ModIface' for a 'Module', searching in both the loaded home
 407 -- and external package module information
 408 lookupIfaceByModule
 409         :: DynFlags
 410         -> HomePackageTable
 411         -> PackageIfaceTable
 412         -> Module
 413         -> Maybe ModIface
 414 lookupIfaceByModule dflags hpt pit mod
 415   | modulePackageId mod == thisPackage dflags
 416   =     -- The module comes from the home package, so look first
 417         -- in the HPT.  If it's not from the home package it's wrong to look
 418         -- in the HPT, because the HPT is indexed by *ModuleName* not Module
 419     fmap hm_iface (lookupUFM hpt (moduleName mod))
 420     `mplus` lookupModuleEnv pit mod
 421
 422   | otherwise = lookupModuleEnv pit mod         -- Look in PIT only
 423
 424 -- If the module does come from the home package, why do we look in the PIT as well?
 425 -- (a) In OneShot mode, even home-package modules accumulate in the PIT
 426 -- (b) Even in Batch (--make) mode, there is *one* case where a home-package
 427 --     module is in the PIT, namely GHC.Prim when compiling the base package.
 428 -- We could eliminate (b) if we wanted, by making GHC.Prim belong to a package
 429 -- of its own, but it doesn't seem worth the bother.
 430 \end{code}
 431
 432
 433 \begin{code}
 434 hptInstances :: HscEnv -> (ModuleName -> Bool) -> ([Instance], [FamInst])
 435 -- ^ Find all the instance declarations (of classes and families) that are in
 436 -- modules imported by this one, directly or indirectly, and are in the Home
 437 -- Package Table.  This ensures that we don't see instances from modules @--make@
 438 -- compiled before this one, but which are not below this one.
 439 hptInstances hsc_env want_this_module
 440   = let (insts, famInsts) = unzip $ flip hptAllThings hsc_env $ \mod_info -> do
 441                 guard (want_this_module (moduleName (mi_module (hm_iface mod_info))))
 442                 let details = hm_details mod_info
 443                 return (md_insts details, md_fam_insts details)
 444     in (concat insts, concat famInsts)
 445
 446 hptVectInfo :: HscEnv -> VectInfo
 447 -- ^ Get the combined VectInfo of all modules in the home package table.  In
 448 -- contrast to instances and rules, we don't care whether the modules are
 449 -- \"below\" us in the dependency sense.  The VectInfo of those modules not \"below\"
 450 -- us does not affect the compilation of the current module.
 451 hptVectInfo = concatVectInfo . hptAllThings ((: []) . md_vect_info . hm_details)
 452
 453 hptRules :: HscEnv -> [(ModuleName, IsBootInterface)] -> [CoreRule]
 454 -- ^ Get rules from modules \"below\" this one (in the dependency sense)
 455 hptRules = hptSomeThingsBelowUs (md_rules . hm_details) False
 456
 457
 458 hptAnns :: HscEnv -> Maybe [(ModuleName, IsBootInterface)] -> [Annotation]
 459 -- ^ Get annotations from modules \"below\" this one (in the dependency sense)
 460 hptAnns hsc_env (Just deps) = hptSomeThingsBelowUs (md_anns . hm_details) False hsc_env deps
 461 hptAnns hsc_env Nothing = hptAllThings (md_anns . hm_details) hsc_env
 462
 463 hptAllThings :: (HomeModInfo -> [a]) -> HscEnv -> [a]
 464 hptAllThings extract hsc_env = concatMap extract (eltsUFM (hsc_HPT hsc_env))
 465
 466 hptSomeThingsBelowUs :: (HomeModInfo -> [a]) -> Bool -> HscEnv -> [(ModuleName, IsBootInterface)] -> [a]
 467 -- Get things from modules \"below\" this one (in the dependency sense)
 468 -- C.f Inst.hptInstances
 469 hptSomeThingsBelowUs extract include_hi_boot hsc_env deps
 470  | isOneShot (ghcMode (hsc_dflags hsc_env)) = []
 471   | otherwise
 472   = let
 473         hpt = hsc_HPT hsc_env
 474     in
 475     [ thing
 476     |   -- Find each non-hi-boot module below me
 477       (mod, is_boot_mod) <- deps
 478     , include_hi_boot || not is_boot_mod
 479
 480         -- unsavoury: when compiling the base package with --make, we
 481         -- sometimes try to look up RULES etc for GHC.Prim.  GHC.Prim won't
 482         -- be in the HPT, because we never compile it; it's in the EPT
 483         -- instead.  ToDo: clean up, and remove this slightly bogus
 484         -- filter:
 485     , mod /= moduleName gHC_PRIM
 486
 487         -- Look it up in the HPT
 488     , let things = case lookupUFM hpt mod of
 489                     Just info -> extract info
 490                     Nothing -> pprTrace "WARNING in hptSomeThingsBelowUs" msg []
 491           msg = vcat [ptext (sLit "missing module") <+> ppr mod,
 492                       ptext (sLit "Probable cause: out-of-date interface files")]
 493                         -- This really shouldn't happen, but see Trac #962
 494
 495         -- And get its dfuns
 496     , thing <- things ]
 497 \end{code}
 498
 499 %************************************************************************
 500 %*                                                                      *
 501 \subsection{Dealing with Annotations}
 502 %*                                                                      *
 503 %************************************************************************
 504
 505 \begin{code}
 506 prepareAnnotations :: HscEnv -> Maybe ModGuts -> IO AnnEnv
 507 -- ^ Deal with gathering annotations in from all possible places
 508 --   and combining them into a single 'AnnEnv'
 509 prepareAnnotations hsc_env mb_guts
 510   = do { eps <- hscEPS hsc_env
 511        ; let -- Extract annotations from the module being compiled if supplied one
 512             mb_this_module_anns = fmap (mkAnnEnv . mg_anns) mb_guts
 513         -- Extract dependencies of the module if we are supplied one,
 514         -- otherwise load annotations from all home package table
 515         -- entries regardless of dependency ordering.
 516             home_pkg_anns  = (mkAnnEnv . hptAnns hsc_env) $ fmap (dep_mods . mg_deps) mb_guts
 517             other_pkg_anns = eps_ann_env eps
 518             ann_env        = foldl1' plusAnnEnv $ catMaybes [mb_this_module_anns,
 519                                                              Just home_pkg_anns,
 520                                                              Just other_pkg_anns]
 521
 522        ; return ann_env }
 523 \end{code}
 524
 525 %************************************************************************
 526 %*                                                                      *
 527 \subsection{The Finder cache}
 528 %*                                                                      *
 529 %************************************************************************
 530
 531 \begin{code}
 532 -- | The 'FinderCache' maps home module names to the result of
 533 -- searching for that module.  It records the results of searching for
 534 -- modules along the search path.  On @:load@, we flush the entire
 535 -- contents of this cache.
 536 --
 537 -- Although the @FinderCache@ range is 'FindResult' for convenience ,
 538 -- in fact it will only ever contain 'Found' or 'NotFound' entries.
 539 --
 540 type FinderCache = ModuleNameEnv FindResult
 541
 542 -- | The result of searching for an imported module.
 543 data FindResult
 544   = Found ModLocation Module
 545         -- ^ The module was found
 546   | NoPackage PackageId
 547         -- ^ The requested package was not found
 548   | FoundMultiple [PackageId]
 549         -- ^ _Error_: both in multiple packages
 550
 551   | NotFound          -- Not found
 552       { fr_paths       :: [FilePath]       -- Places where I looked
 553
 554       , fr_pkg         :: Maybe PackageId  -- Just p => module is in this package's
 555                                            --           manifest, but couldn't find
 556                                            --           the .hi file
 557
 558       , fr_mods_hidden :: [PackageId]      -- Module is in these packages,
 559                                            --   but the *module* is hidden
 560
 561       , fr_pkgs_hidden :: [PackageId]      -- Module is in these packages,
 562                                            --   but the *package* is hidden
 563
 564       , fr_suggestions :: [Module]         -- Possible mis-spelled modules
 565       }
 566
 567 -- | Cache that remembers where we found a particular module.  Contains both
 568 -- home modules and package modules.  On @:load@, only home modules are
 569 -- purged from this cache.
 570 type ModLocationCache = ModuleEnv ModLocation
 571 \end{code}
 572
 573 %************************************************************************
 574 %*                                                                      *
 575 \subsection{Symbol tables and Module details}
 576 %*                                                                      *
 577 %************************************************************************
 578
 579 \begin{code}
 580 -- | A 'ModIface' plus a 'ModDetails' summarises everything we know
 581 -- about a compiled module.  The 'ModIface' is the stuff *before* linking,
 582 -- and can be written out to an interface file. The 'ModDetails is after
 583 -- linking and can be completely recovered from just the 'ModIface'.
 584 --
 585 -- When we read an interface file, we also construct a 'ModIface' from it,
 586 -- except that we explicitly make the 'mi_decls' and a few other fields empty;
 587 -- as when reading we consolidate the declarations etc. into a number of indexed
 588 -- maps and environments in the 'ExternalPackageState'.
 589 data ModIface
 590    = ModIface {
 591         mi_module   :: !Module,             -- ^ Name of the module we are for
 592         mi_iface_hash :: !Fingerprint,      -- ^ Hash of the whole interface
 593         mi_mod_hash :: !Fingerprint,        -- ^ Hash of the ABI only
 594
 595         mi_orphan   :: !WhetherHasOrphans,  -- ^ Whether this module has orphans
 596         mi_finsts   :: !WhetherHasFamInst,  -- ^ Whether this module has family instances
 597         mi_boot     :: !IsBootInterface,    -- ^ Read from an hi-boot file?
 598
 599         mi_deps     :: Dependencies,
 600                 -- ^ The dependencies of the module.  This is
 601                 -- consulted for directly-imported modules, but not
 602                 -- for anything else (hence lazy)
 603
 604         mi_usages   :: [Usage],
 605                 -- ^ Usages; kept sorted so that it's easy to decide
 606                 -- whether to write a new iface file (changing usages
 607                 -- doesn't affect the hash of this module)
 608
 609                 -- NOT STRICT!  we read this field lazily from the interface file
 610                 -- It is *only* consulted by the recompilation checker
 611
 612                 -- Exports
 613                 -- Kept sorted by (mod,occ), to make version comparisons easier
 614         mi_exports  :: ![IfaceExport],
 615                 -- ^ Records the modules that are the declaration points for things
 616                 -- exported by this module, and the 'OccName's of those things
 617
 618         mi_exp_hash :: !Fingerprint,    -- ^ Hash of export list
 619
 620         mi_fixities :: [(OccName,Fixity)],
 621                 -- ^ Fixities
 622
 623                 -- NOT STRICT!  we read this field lazily from the interface file
 624
 625         mi_warns  :: Warnings,
 626                 -- ^ Warnings
 627
 628                 -- NOT STRICT!  we read this field lazily from the interface file
 629
 630         mi_anns  :: [IfaceAnnotation],
 631                 -- ^ Annotations
 632
 633                 -- NOT STRICT!  we read this field lazily from the interface file
 634
 635                 -- Type, class and variable declarations
 636                 -- The hash of an Id changes if its fixity or deprecations change
 637                 --      (as well as its type of course)
 638                 -- Ditto data constructors, class operations, except that
 639                 -- the hash of the parent class/tycon changes
 640         mi_decls :: [(Fingerprint,IfaceDecl)],  -- ^ Sorted type, variable, class etc. declarations
 641
 642         mi_globals  :: !(Maybe GlobalRdrEnv),
 643                 -- ^ Binds all the things defined at the top level in
 644                 -- the /original source/ code for this module. which
 645                 -- is NOT the same as mi_exports, nor mi_decls (which
 646                 -- may contains declarations for things not actually
 647                 -- defined by the user).  Used for GHCi and for inspecting
 648                 -- the contents of modules via the GHC API only.
 649                 --
 650                 -- (We need the source file to figure out the
 651                 -- top-level environment, if we didn't compile this module
 652                 -- from source then this field contains @Nothing@).
 653                 --
 654                 -- Strictly speaking this field should live in the
 655                 -- 'HomeModInfo', but that leads to more plumbing.
 656
 657                 -- Instance declarations and rules
 658         mi_insts     :: [IfaceInst],                    -- ^ Sorted class instance
 659         mi_fam_insts :: [IfaceFamInst],                 -- ^ Sorted family instances
 660         mi_rules     :: [IfaceRule],                    -- ^ Sorted rules
 661         mi_orphan_hash :: !Fingerprint, -- ^ Hash for orphan rules and
 662                                         -- class and family instances
 663                                         -- combined
 664
 665         mi_vect_info :: !IfaceVectInfo, -- ^ Vectorisation information
 666
 667                 -- Cached environments for easy lookup
 668                 -- These are computed (lazily) from other fields
 669                 -- and are not put into the interface file
 670         mi_warn_fn  :: Name -> Maybe WarningTxt,        -- ^ Cached lookup for 'mi_warns'
 671         mi_fix_fn  :: OccName -> Fixity,                -- ^ Cached lookup for 'mi_fixities'
 672         mi_hash_fn :: OccName -> Maybe (OccName, Fingerprint),
 673                         -- ^ Cached lookup for 'mi_decls'.
 674                         -- The @Nothing@ in 'mi_hash_fn' means that the thing
 675                         -- isn't in decls. It's useful to know that when
 676                         -- seeing if we are up to date wrt. the old interface.
 677                         -- The 'OccName' is the parent of the name, if it has one.
 678         mi_hpc    :: !AnyHpcUsage
 679                 -- ^ True if this program uses Hpc at any point in the program.
 680      }
 681
 682 -- | The 'ModDetails' is essentially a cache for information in the 'ModIface'
 683 -- for home modules only. Information relating to packages will be loaded into
 684 -- global environments in 'ExternalPackageState'.
 685 data ModDetails
 686    = ModDetails {
 687         -- The next two fields are created by the typechecker
 688         md_exports   :: [AvailInfo],
 689         md_types     :: !TypeEnv,       -- ^ Local type environment for this particular module
 690         md_insts     :: ![Instance],    -- ^ 'DFunId's for the instances in this module
 691         md_fam_insts :: ![FamInst],
 692         md_rules     :: ![CoreRule],    -- ^ Domain may include 'Id's from other modules
 693         md_anns      :: ![Annotation],  -- ^ Annotations present in this module: currently
 694                                         -- they only annotate things also declared in this module
 695         md_vect_info :: !VectInfo       -- ^ Module vectorisation information
 696      }
 697
 698 emptyModDetails :: ModDetails
 699 emptyModDetails = ModDetails { md_types = emptyTypeEnv,
 700                                md_exports = [],
 701                                md_insts     = [],
 702                                md_rules     = [],
 703                                md_fam_insts = [],
 704                                md_anns      = [],
 705                                md_vect_info = noVectInfo
 706                              }
 707
 708 -- | Records the modules directly imported by a module for extracting e.g. usage information
 709 type ImportedMods = ModuleEnv [(ModuleName, Bool, SrcSpan)]
 710 -- TODO: we are not actually using the codomain of this type at all, so it can be
 711 -- replaced with ModuleEnv ()
 712
 713 -- | A ModGuts is carried through the compiler, accumulating stuff as it goes
 714 -- There is only one ModGuts at any time, the one for the module
 715 -- being compiled right now.  Once it is compiled, a 'ModIface' and
 716 -- 'ModDetails' are extracted and the ModGuts is dicarded.
 717 data ModGuts
 718   = ModGuts {
 719         mg_module    :: !Module,         -- ^ Module being compiled
 720         mg_boot      :: IsBootInterface, -- ^ Whether it's an hs-boot module
 721         mg_exports   :: ![AvailInfo],    -- ^ What it exports
 722         mg_deps      :: !Dependencies,   -- ^ What it depends on, directly or
 723                                          -- otherwise
 724         mg_dir_imps  :: !ImportedMods,   -- ^ Directly-imported modules; used to
 725                                          -- generate initialisation code
 726         mg_used_names:: !NameSet,        -- ^ What the module needed (used in 'MkIface.mkIface')
 727
 728         mg_rdr_env   :: !GlobalRdrEnv,   -- ^ Top-level lexical environment
 729
 730         -- These fields all describe the things **declared in this module**
 731         mg_fix_env   :: !FixityEnv,      -- ^ Fixities declared in this module
 732                                          -- TODO: I'm unconvinced this is actually used anywhere
 733         mg_types     :: !TypeEnv,        -- ^ Types declared in this module
 734         mg_insts     :: ![Instance],     -- ^ Class instances declared in this module
 735         mg_fam_insts :: ![FamInst],      -- ^ Family instances declared in this module
 736         mg_rules     :: ![CoreRule],     -- ^ Before the core pipeline starts, contains
 737                                          -- See Note [Overall plumbing for rules] in Rules.lhs
 738         mg_binds     :: ![CoreBind],     -- ^ Bindings for this module
 739         mg_foreign   :: !ForeignStubs,   -- ^ Foreign exports declared in this module
 740         mg_warns     :: !Warnings,       -- ^ Warnings declared in the module
 741         mg_anns      :: [Annotation],    -- ^ Annotations declared in this module
 742         mg_hpc_info  :: !HpcInfo,        -- ^ Coverage tick boxes in the module
 743         mg_modBreaks :: !ModBreaks,      -- ^ Breakpoints for the module
 744         mg_vect_info :: !VectInfo,       -- ^ Pool of vectorised declarations in the module
 745
 746         -- The next two fields are unusual, because they give instance
 747         -- environments for *all* modules in the home package, including
 748         -- this module, rather than for *just* this module.
 749         -- Reason: when looking up an instance we don't want to have to
 750         --        look at each module in the home package in turn
 751         mg_inst_env     :: InstEnv,
 752         -- ^ Class instance environment from /home-package/ modules (including
 753         -- this one); c.f. 'tcg_inst_env'
 754         mg_fam_inst_env :: FamInstEnv
 755         -- ^ Type-family instance enviroment for /home-package/ modules
 756         -- (including this one); c.f. 'tcg_fam_inst_env'
 757     }
 758
 759 -- The ModGuts takes on several slightly different forms:
 760 --
 761 -- After simplification, the following fields change slightly:
 762 --      mg_rules        Orphan rules only (local ones now attached to binds)
 763 --      mg_binds        With rules attached
 764
 765 -- The ModGuts takes on several slightly different forms:
 766 --
 767 -- After simplification, the following fields change slightly:
 768 --      mg_rules        Orphan rules only (local ones now attached to binds)
 769 --      mg_binds        With rules attached
 770
 771
 772 ---------------------------------------------------------
 773 -- The Tidy pass forks the information about this module:
 774 --      * one lot goes to interface file generation (ModIface)
 775 --        and later compilations (ModDetails)
 776 --      * the other lot goes to code generation (CgGuts)
 777
 778 -- | A restricted form of 'ModGuts' for code generation purposes
 779 data CgGuts
 780   = CgGuts {
 781         cg_module   :: !Module, -- ^ Module being compiled
 782
 783         cg_tycons   :: [TyCon],
 784                 -- ^ Algebraic data types (including ones that started
 785                 -- life as classes); generate constructors and info
 786                 -- tables. Includes newtypes, just for the benefit of
 787                 -- External Core
 788
 789         cg_binds    :: [CoreBind],
 790                 -- ^ The tidied main bindings, including
 791                 -- previously-implicit bindings for record and class
 792                 -- selectors, and data construtor wrappers.  But *not*
 793                 -- data constructor workers; reason: we we regard them
 794                 -- as part of the code-gen of tycons
 795
 796         cg_dir_imps :: ![Module],
 797                 -- ^ Directly-imported modules; used to generate
 798                 -- initialisation code
 799
 800         cg_foreign  :: !ForeignStubs,   -- ^ Foreign export stubs
 801         cg_dep_pkgs :: ![PackageId],    -- ^ Dependent packages, used to
 802                                         -- generate #includes for C code gen
 803         cg_hpc_info :: !HpcInfo,        -- ^ Program coverage tick box information
 804         cg_modBreaks :: !ModBreaks      -- ^ Module breakpoints
 805     }
 806
 807 -----------------------------------
 808 -- | Foreign export stubs
 809 data ForeignStubs = NoStubs             -- ^ We don't have any stubs
 810                   | ForeignStubs
 811                         SDoc
 812                         SDoc
 813                    -- ^ There are some stubs. Parameters:
 814                    --
 815                    --  1) Header file prototypes for
 816                    --     "foreign exported" functions
 817                    --
 818                    --  2) C stubs to use when calling
 819                    --     "foreign exported" functions
 820 \end{code}
 821
 822 \begin{code}
 823 emptyModIface :: Module -> ModIface
 824 emptyModIface mod
 825   = ModIface { mi_module   = mod,
 826                mi_iface_hash = fingerprint0,
 827                mi_mod_hash = fingerprint0,
 828                mi_orphan   = False,
 829                mi_finsts   = False,
 830                mi_boot     = False,
 831                mi_deps     = noDependencies,
 832                mi_usages   = [],
 833                mi_exports  = [],
 834                mi_exp_hash = fingerprint0,
 835                mi_fixities = [],
 836                mi_warns    = NoWarnings,
 837                mi_anns     = [],
 838                mi_insts     = [],
 839                mi_fam_insts = [],
 840                mi_rules     = [],
 841                mi_decls     = [],
 842                mi_globals   = Nothing,
 843                mi_orphan_hash = fingerprint0,
 844                mi_vect_info = noIfaceVectInfo,
 845                mi_warn_fn    = emptyIfaceWarnCache,
 846                mi_fix_fn    = emptyIfaceFixCache,
 847                mi_hash_fn   = emptyIfaceHashCache,
 848                mi_hpc       = False
 849     }
 850 \end{code}
 851
 852
 853 %************************************************************************
 854 %*                                                                      *
 855 \subsection{The interactive context}
 856 %*                                                                      *
 857 %************************************************************************
 858
 859 \begin{code}
 860 -- | Interactive context, recording information relevant to GHCi
 861 data InteractiveContext
 862   = InteractiveContext {
 863         ic_toplev_scope :: [Module],    -- ^ The context includes the "top-level" scope of
 864                                         -- these modules
 865
 866         ic_exports :: [(Module, Maybe (ImportDecl RdrName))],           -- ^ The context includes just the exported parts of these
 867                                         -- modules
 868
 869         ic_rn_gbl_env :: GlobalRdrEnv,  -- ^ The contexts' cached 'GlobalRdrEnv', built from
 870                                         -- 'ic_toplev_scope' and 'ic_exports'
 871
 872         ic_tmp_ids :: [Id]              -- ^ Names bound during interaction with the user.
 873                                         -- Later Ids shadow earlier ones with the same OccName.
 874
 875 #ifdef GHCI
 876         , ic_resume :: [Resume]         -- ^ The stack of breakpoint contexts
 877 #endif
 878
 879         , ic_cwd :: Maybe FilePath      -- virtual CWD of the program
 880     }
 881
 882
 883 emptyInteractiveContext :: InteractiveContext
 884 emptyInteractiveContext
 885   = InteractiveContext { ic_toplev_scope = [],
 886                          ic_exports = [],
 887                          ic_rn_gbl_env = emptyGlobalRdrEnv,
 888                          ic_tmp_ids = []
 889 #ifdef GHCI
 890                          , ic_resume = []
 891 #endif
 892                          , ic_cwd = Nothing
 893                        }
 894
 895 icPrintUnqual :: DynFlags -> InteractiveContext -> PrintUnqualified
 896 icPrintUnqual dflags ictxt = mkPrintUnqualified dflags (ic_rn_gbl_env ictxt)
 897
 898
 899 extendInteractiveContext
 900         :: InteractiveContext
 901         -> [Id]
 902         -> InteractiveContext
 903 extendInteractiveContext ictxt ids
 904   = ictxt { ic_tmp_ids =  snub ((ic_tmp_ids ictxt \\ ids) ++ ids)
 905                           -- NB. must be this way around, because we want
 906                           -- new ids to shadow existing bindings.
 907           }
 908     where snub = map head . group . sort
 909
 910 substInteractiveContext :: InteractiveContext -> TvSubst -> InteractiveContext
 911 substInteractiveContext ictxt subst | isEmptyTvSubst subst = ictxt
 912 substInteractiveContext ictxt@InteractiveContext{ic_tmp_ids=ids} subst
 913   = ictxt { ic_tmp_ids = map subst_ty ids }
 914   where
 915    subst_ty id = id `setIdType` substTy subst (idType id)
 916 \end{code}
 917
 918 %************************************************************************
 919 %*                                                                      *
 920         Building a PrintUnqualified
 921 %*                                                                      *
 922 %************************************************************************
 923
 924 Note [Printing original names]
 925 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 926 Deciding how to print names is pretty tricky.  We are given a name
 927 P:M.T, where P is the package name, M is the defining module, and T is
 928 the occurrence name, and we have to decide in which form to display
 929 the name given a GlobalRdrEnv describing the current scope.
 930
 931 Ideally we want to display the name in the form in which it is in
 932 scope.  However, the name might not be in scope at all, and that's
 933 where it gets tricky.  Here are the cases:
 934
 935  1. T uniquely maps to  P:M.T      --->  "T"      NameUnqual
 936  2. There is an X for which X.T
 937        uniquely maps to  P:M.T     --->  "X.T"    NameQual X
 938  3. There is no binding for "M.T"  --->  "M.T"    NameNotInScope1
 939  4. Otherwise                      --->  "P:M.T"  NameNotInScope2
 940
 941 (3) and (4) apply when the entity P:M.T is not in the GlobalRdrEnv at
 942 all. In these cases we still want to refer to the name as "M.T", *but*
 943 "M.T" might mean something else in the current scope (e.g. if there's
 944 an "import X as M"), so to avoid confusion we avoid using "M.T" if
 945 there's already a binding for it.  Instead we write P:M.T.
 946
 947 There's one further subtlety: in case (3), what if there are two
 948 things around, P1:M.T and P2:M.T?  Then we don't want to print both of
 949 them as M.T!  However only one of the modules P1:M and P2:M can be
 950 exposed (say P2), so we use M.T for that, and P1:M.T for the other one.
 951 This is handled by the qual_mod component of PrintUnqualified, inside
 952 the (ppr mod) of case (3), in Name.pprModulePrefix
 953
 954 \begin{code}
 955 -- | Creates some functions that work out the best ways to format
 956 -- names for the user according to a set of heuristics
 957 mkPrintUnqualified :: DynFlags -> GlobalRdrEnv -> PrintUnqualified
 958 mkPrintUnqualified dflags env = (qual_name, qual_mod)
 959   where
 960   qual_name mod occ     -- The (mod,occ) pair is the original name of the thing
 961         | [gre] <- unqual_gres, right_name gre = NameUnqual
 962                 -- If there's a unique entity that's in scope unqualified with 'occ'
 963                 -- AND that entity is the right one, then we can use the unqualified name
 964
 965         | [gre] <- qual_gres = NameQual (get_qual_mod (gre_prov gre))
 966
 967         | null qual_gres =
 968               if null (lookupGRE_RdrName (mkRdrQual (moduleName mod) occ) env)
 969                    then NameNotInScope1
 970                    else NameNotInScope2
 971
 972         | otherwise = panic "mkPrintUnqualified"
 973       where
 974         right_name gre = nameModule_maybe (gre_name gre) == Just mod
 975
 976         unqual_gres = lookupGRE_RdrName (mkRdrUnqual occ) env
 977         qual_gres   = filter right_name (lookupGlobalRdrEnv env occ)
 978
 979         get_qual_mod LocalDef      = moduleName mod
 980         get_qual_mod (Imported is) = ASSERT( not (null is) ) is_as (is_decl (head is))
 981
 982     -- we can mention a module P:M without the P: qualifier iff
 983     -- "import M" would resolve unambiguously to P:M.  (if P is the
 984     -- current package we can just assume it is unqualified).
 985
 986   qual_mod mod
 987      | modulePackageId mod == thisPackage dflags = False
 988
 989      | [pkgconfig] <- [pkg | (pkg,exposed_module) <- lookup,
 990                              exposed pkg && exposed_module],
 991        packageConfigId pkgconfig == modulePackageId mod
 992         -- this says: we are given a module P:M, is there just one exposed package
 993         -- that exposes a module M, and is it package P?
 994      = False
 995
 996      | otherwise = True
 997      where lookup = lookupModuleInAllPackages dflags (moduleName mod)
 998 \end{code}
 999
1000
1001 %************************************************************************
1002 %*                                                                      *
1003                 TyThing
1004 %*                                                                      *
1005 %************************************************************************
1006
1007 \begin{code}
1008 -- | Determine the 'TyThing's brought into scope by another 'TyThing'
1009 -- /other/ than itself. For example, Id's don't have any implicit TyThings
1010 -- as they just bring themselves into scope, but classes bring their
1011 -- dictionary datatype, type constructor and some selector functions into
1012 -- scope, just for a start!
1013
1014 -- N.B. the set of TyThings returned here *must* match the set of
1015 -- names returned by LoadIface.ifaceDeclSubBndrs, in the sense that
1016 -- TyThing.getOccName should define a bijection between the two lists.
1017 -- This invariant is used in LoadIface.loadDecl (see note [Tricky iface loop])
1018 -- The order of the list does not matter.
1019 implicitTyThings :: TyThing -> [TyThing]
1020
1021 -- For data and newtype declarations:
1022 implicitTyThings (ATyCon tc)
1023   =   -- fields (names of selectors)
1024       -- (possibly) implicit coercion and family coercion
1025       --   depending on whether it's a newtype or a family instance or both
1026     implicitCoTyCon tc ++
1027       -- for each data constructor in order,
1028       --   the contructor, worker, and (possibly) wrapper
1029     concatMap (extras_plus . ADataCon) (tyConDataCons tc)
1030
1031 implicitTyThings (AClass cl)
1032   = -- dictionary datatype:
1033     --    [extras_plus:]
1034     --      type constructor
1035     --    [recursive call:]
1036     --      (possibly) newtype coercion; definitely no family coercion here
1037     --      data constructor
1038     --      worker
1039     --      (no wrapper by invariant)
1040     extras_plus (ATyCon (classTyCon cl)) ++
1041     -- associated types
1042     --    No extras_plus (recursive call) for the classATs, because they
1043     --    are only the family decls; they have no implicit things
1044     map ATyCon (classATs cl) ++
1045     -- superclass and operation selectors
1046     map AnId (classAllSelIds cl)
1047
1048 implicitTyThings (ADataCon dc) =
1049     -- For data cons add the worker and (possibly) wrapper
1050     map AnId (dataConImplicitIds dc)
1051
1052 implicitTyThings (AnId _)   = []
1053
1054 -- add a thing and recursive call
1055 extras_plus :: TyThing -> [TyThing]
1056 extras_plus thing = thing : implicitTyThings thing
1057
1058 -- For newtypes and indexed data types (and both),
1059 -- add the implicit coercion tycon
1060 implicitCoTyCon :: TyCon -> [TyThing]
1061 implicitCoTyCon tc
1062   = map ATyCon . catMaybes $ [-- Just if newtype, Nothing if not
1063                               newTyConCo_maybe tc,
1064                               -- Just if family instance, Nothing if not
1065                                 tyConFamilyCoercion_maybe tc]
1066
1067 -- sortByOcc = sortBy (\ x -> \ y -> getOccName x < getOccName y)
1068
1069
1070 -- | Returns @True@ if there should be no interface-file declaration
1071 -- for this thing on its own: either it is built-in, or it is part
1072 -- of some other declaration, or it is generated implicitly by some
1073 -- other declaration.
1074 isImplicitTyThing :: TyThing -> Bool
1075 isImplicitTyThing (ADataCon _)  = True
1076 isImplicitTyThing (AnId     id) = isImplicitId id
1077 isImplicitTyThing (AClass   _)  = False
1078 isImplicitTyThing (ATyCon   tc) = isImplicitTyCon tc
1079
1080 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
1081 extendTypeEnvWithIds env ids
1082   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
1083 \end{code}
1084
1085 %************************************************************************
1086 %*                                                                      *
1087                 TypeEnv
1088 %*                                                                      *
1089 %************************************************************************
1090
1091 \begin{code}
1092 -- | A map from 'Name's to 'TyThing's, constructed by typechecking
1093 -- local declarations or interface files
1094 type TypeEnv = NameEnv TyThing
1095
1096 emptyTypeEnv    :: TypeEnv
1097 typeEnvElts     :: TypeEnv -> [TyThing]
1098 typeEnvClasses  :: TypeEnv -> [Class]
1099 typeEnvTyCons   :: TypeEnv -> [TyCon]
1100 typeEnvIds      :: TypeEnv -> [Id]
1101 typeEnvDataCons :: TypeEnv -> [DataCon]
1102 lookupTypeEnv   :: TypeEnv -> Name -> Maybe TyThing
1103
1104 emptyTypeEnv        = emptyNameEnv
1105 typeEnvElts     env = nameEnvElts env
1106 typeEnvClasses  env = [cl | AClass cl   <- typeEnvElts env]
1107 typeEnvTyCons   env = [tc | ATyCon tc   <- typeEnvElts env]
1108 typeEnvIds      env = [id | AnId id     <- typeEnvElts env]
1109 typeEnvDataCons env = [dc | ADataCon dc <- typeEnvElts env]
1110
1111 mkTypeEnv :: [TyThing] -> TypeEnv
1112 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
1113
1114 lookupTypeEnv = lookupNameEnv
1115
1116 -- Extend the type environment
1117 extendTypeEnv :: TypeEnv -> TyThing -> TypeEnv
1118 extendTypeEnv env thing = extendNameEnv env (getName thing) thing
1119
1120 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
1121 extendTypeEnvList env things = foldl extendTypeEnv env things
1122 \end{code}
1123
1124 \begin{code}
1125 -- | Find the 'TyThing' for the given 'Name' by using all the resources
1126 -- at our disposal: the compiled modules in the 'HomePackageTable' and the
1127 -- compiled modules in other packages that live in 'PackageTypeEnv'. Note
1128 -- that this does NOT look up the 'TyThing' in the module being compiled: you
1129 -- have to do that yourself, if desired
1130 lookupType :: DynFlags
1131            -> HomePackageTable
1132            -> PackageTypeEnv
1133            -> Name
1134            -> Maybe TyThing
1135
1136 lookupType dflags hpt pte name
1137   -- in one-shot, we don't use the HPT
1138   | not (isOneShot (ghcMode dflags)) && modulePackageId mod == this_pkg
1139   = do hm <- lookupUFM hpt (moduleName mod) -- Maybe monad
1140        lookupNameEnv (md_types (hm_details hm)) name
1141   | otherwise
1142   = lookupNameEnv pte name
1143   where mod = ASSERT( isExternalName name ) nameModule name
1144         this_pkg = thisPackage dflags
1145
1146 -- | As 'lookupType', but with a marginally easier-to-use interface
1147 -- if you have a 'HscEnv'
1148 lookupTypeHscEnv :: HscEnv -> Name -> IO (Maybe TyThing)
1149 lookupTypeHscEnv hsc_env name = do
1150     eps <- readIORef (hsc_EPS hsc_env)
1151     return $! lookupType dflags hpt (eps_PTE eps) name
1152   where
1153     dflags = hsc_dflags hsc_env
1154     hpt = hsc_HPT hsc_env
1155 \end{code}
1156
1157 \begin{code}
1158 -- | Get the 'TyCon' from a 'TyThing' if it is a type constructor thing. Panics otherwise
1159 tyThingTyCon :: TyThing -> TyCon
1160 tyThingTyCon (ATyCon tc) = tc
1161 tyThingTyCon other       = pprPanic "tyThingTyCon" (pprTyThing other)
1162
1163 -- | Get the 'Class' from a 'TyThing' if it is a class thing. Panics otherwise
1164 tyThingClass :: TyThing -> Class
1165 tyThingClass (AClass cls) = cls
1166 tyThingClass other        = pprPanic "tyThingClass" (pprTyThing other)
1167
1168 -- | Get the 'DataCon' from a 'TyThing' if it is a data constructor thing. Panics otherwise
1169 tyThingDataCon :: TyThing -> DataCon
1170 tyThingDataCon (ADataCon dc) = dc
1171 tyThingDataCon other         = pprPanic "tyThingDataCon" (pprTyThing other)
1172
1173 -- | Get the 'Id' from a 'TyThing' if it is a id *or* data constructor thing. Panics otherwise
1174 tyThingId :: TyThing -> Id
1175 tyThingId (AnId id)     = id
1176 tyThingId (ADataCon dc) = dataConWrapId dc
1177 tyThingId other         = pprPanic "tyThingId" (pprTyThing other)
1178 \end{code}
1179
1180 %************************************************************************
1181 %*                                                                      *
1182 \subsection{MonadThings and friends}
1183 %*                                                                      *
1184 %************************************************************************
1185
1186 \begin{code}
1187 -- | Class that abstracts out the common ability of the monads in GHC
1188 -- to lookup a 'TyThing' in the monadic environment by 'Name'. Provides
1189 -- a number of related convenience functions for accessing particular
1190 -- kinds of 'TyThing'
1191 class Monad m => MonadThings m where
1192         lookupThing :: Name -> m TyThing
1193
1194         lookupId :: Name -> m Id
1195         lookupId = liftM tyThingId . lookupThing
1196
1197         lookupDataCon :: Name -> m DataCon
1198         lookupDataCon = liftM tyThingDataCon . lookupThing
1199
1200         lookupTyCon :: Name -> m TyCon
1201         lookupTyCon = liftM tyThingTyCon . lookupThing
1202
1203         lookupClass :: Name -> m Class
1204         lookupClass = liftM tyThingClass . lookupThing
1205 \end{code}
1206
1207 \begin{code}
1208 -- | Constructs cache for the 'mi_hash_fn' field of a 'ModIface'
1209 mkIfaceHashCache :: [(Fingerprint,IfaceDecl)]
1210                  -> (OccName -> Maybe (OccName, Fingerprint))
1211 mkIfaceHashCache pairs
1212   = \occ -> lookupOccEnv env occ
1213   where
1214     env = foldr add_decl emptyOccEnv pairs
1215     add_decl (v,d) env0 = foldr add_imp env1 (ifaceDeclSubBndrs d)
1216       where
1217           decl_name = ifName d
1218           env1 = extendOccEnv env0 decl_name (decl_name, v)
1219           add_imp bndr env = extendOccEnv env bndr (decl_name, v)
1220
1221 emptyIfaceHashCache :: OccName -> Maybe (OccName, Fingerprint)
1222 emptyIfaceHashCache _occ = Nothing
1223 \end{code}
1224
1225 %************************************************************************
1226 %*                                                                      *
1227 \subsection{Auxiliary types}
1228 %*                                                                      *
1229 %************************************************************************
1230
1231 These types are defined here because they are mentioned in ModDetails,
1232 but they are mostly elaborated elsewhere
1233
1234 \begin{code}
1235 ------------------ Warnings -------------------------
1236 -- | Warning information for a module
1237 data Warnings
1238   = NoWarnings                          -- ^ Nothing deprecated
1239   | WarnAll WarningTxt                  -- ^ Whole module deprecated
1240   | WarnSome [(OccName,WarningTxt)]     -- ^ Some specific things deprecated
1241
1242      -- Only an OccName is needed because
1243      --    (1) a deprecation always applies to a binding
1244      --        defined in the module in which the deprecation appears.
1245      --    (2) deprecations are only reported outside the defining module.
1246      --        this is important because, otherwise, if we saw something like
1247      --
1248      --        {-# DEPRECATED f "" #-}
1249      --        f = ...
1250      --        h = f
1251      --        g = let f = undefined in f
1252      --
1253      --        we'd need more information than an OccName to know to say something
1254      --        about the use of f in h but not the use of the locally bound f in g
1255      --
1256      --        however, because we only report about deprecations from the outside,
1257      --        and a module can only export one value called f,
1258      --        an OccName suffices.
1259      --
1260      --        this is in contrast with fixity declarations, where we need to map
1261      --        a Name to its fixity declaration.
1262   deriving( Eq )
1263
1264 -- | Constructs the cache for the 'mi_warn_fn' field of a 'ModIface'
1265 mkIfaceWarnCache :: Warnings -> Name -> Maybe WarningTxt
1266 mkIfaceWarnCache NoWarnings  = \_ -> Nothing
1267 mkIfaceWarnCache (WarnAll t) = \_ -> Just t
1268 mkIfaceWarnCache (WarnSome pairs) = lookupOccEnv (mkOccEnv pairs) . nameOccName
1269
1270 emptyIfaceWarnCache :: Name -> Maybe WarningTxt
1271 emptyIfaceWarnCache _ = Nothing
1272
1273 plusWarns :: Warnings -> Warnings -> Warnings
1274 plusWarns d NoWarnings = d
1275 plusWarns NoWarnings d = d
1276 plusWarns _ (WarnAll t) = WarnAll t
1277 plusWarns (WarnAll t) _ = WarnAll t
1278 plusWarns (WarnSome v1) (WarnSome v2) = WarnSome (v1 ++ v2)
1279 \end{code}
1280 \begin{code}
1281 -- | A collection of 'AvailInfo' - several things that are \"available\"
1282 type Avails       = [AvailInfo]
1283 -- | 'Name'd things that are available
1284 type AvailInfo    = GenAvailInfo Name
1285 -- | 'RdrName'd things that are available
1286 type RdrAvailInfo = GenAvailInfo OccName
1287
1288 -- | Records what things are "available", i.e. in scope
1289 data GenAvailInfo name  = Avail name     -- ^ An ordinary identifier in scope
1290                         | AvailTC name
1291                                   [name] -- ^ A type or class in scope. Parameters:
1292                                          --
1293                                          --  1) The name of the type or class
1294                                          --
1295                                          --  2) The available pieces of type or class.
1296                                          --     NB: If the type or class is itself
1297                                          --     to be in scope, it must be in this list.
1298                                          --     Thus, typically: @AvailTC Eq [Eq, ==, \/=]@
1299                         deriving( Eq )
1300                         -- Equality used when deciding if the interface has changed
1301
1302 -- | The original names declared of a certain module that are exported
1303 type IfaceExport = (Module, [GenAvailInfo OccName])
1304
1305 availsToNameSet :: [AvailInfo] -> NameSet
1306 availsToNameSet avails = foldr add emptyNameSet avails
1307       where add avail set = addListToNameSet set (availNames avail)
1308
1309 availsToNameEnv :: [AvailInfo] -> NameEnv AvailInfo
1310 availsToNameEnv avails = foldr add emptyNameEnv avails
1311      where add avail env = extendNameEnvList env
1312                                 (zip (availNames avail) (repeat avail))
1313
1314 -- | Just the main name made available, i.e. not the available pieces
1315 -- of type or class brought into scope by the 'GenAvailInfo'
1316 availName :: GenAvailInfo name -> name
1317 availName (Avail n)     = n
1318 availName (AvailTC n _) = n
1319
1320 -- | All names made available by the availability information
1321 availNames :: GenAvailInfo name -> [name]
1322 availNames (Avail n)      = [n]
1323 availNames (AvailTC _ ns) = ns
1324
1325 instance Outputable n => Outputable (GenAvailInfo n) where
1326    ppr = pprAvail
1327
1328 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
1329 pprAvail (Avail n)      = ppr n
1330 pprAvail (AvailTC n ns) = ppr n <> braces (hsep (punctuate comma (map ppr ns)))
1331 \end{code}
1332
1333 \begin{code}
1334 -- | Creates cached lookup for the 'mi_fix_fn' field of 'ModIface'
1335 mkIfaceFixCache :: [(OccName, Fixity)] -> OccName -> Fixity
1336 mkIfaceFixCache pairs
1337   = \n -> lookupOccEnv env n `orElse` defaultFixity
1338   where
1339    env = mkOccEnv pairs
1340
1341 emptyIfaceFixCache :: OccName -> Fixity
1342 emptyIfaceFixCache _ = defaultFixity
1343
1344 -- | Fixity environment mapping names to their fixities
1345 type FixityEnv = NameEnv FixItem
1346
1347 -- | Fixity information for an 'Name'. We keep the OccName in the range
1348 -- so that we can generate an interface from it
1349 data FixItem = FixItem OccName Fixity
1350
1351 instance Outputable FixItem where
1352   ppr (FixItem occ fix) = ppr fix <+> ppr occ
1353
1354 emptyFixityEnv :: FixityEnv
1355 emptyFixityEnv = emptyNameEnv
1356
1357 lookupFixity :: FixityEnv -> Name -> Fixity
1358 lookupFixity env n = case lookupNameEnv env n of
1359                         Just (FixItem _ fix) -> fix
1360                         Nothing         -> defaultFixity
1361 \end{code}
1362
1363
1364 %************************************************************************
1365 %*                                                                      *
1366 \subsection{WhatsImported}
1367 %*                                                                      *
1368 %************************************************************************
1369
1370 \begin{code}
1371 -- | Records whether a module has orphans. An \"orphan\" is one of:
1372 --
1373 -- * An instance declaration in a module other than the definition
1374 --   module for one of the type constructors or classes in the instance head
1375 --
1376 -- * A transformation rule in a module other than the one defining
1377 --   the function in the head of the rule
1378 type WhetherHasOrphans   = Bool
1379
1380 -- | Does this module define family instances?
1381 type WhetherHasFamInst = Bool
1382
1383 -- | Did this module originate from a *-boot file?
1384 type IsBootInterface = Bool
1385
1386 -- | Dependency information about modules and packages below this one
1387 -- in the import hierarchy.
1388 --
1389 -- Invariant: the dependencies of a module @M@ never includes @M@.
1390 --
1391 -- Invariant: none of the lists contain duplicates.
1392 data Dependencies
1393   = Deps { dep_mods   :: [(ModuleName, IsBootInterface)]
1394                         -- ^ Home-package module dependencies
1395          , dep_pkgs   :: [PackageId]
1396                         -- ^ External package dependencies
1397          , dep_orphs  :: [Module]
1398                         -- ^ Orphan modules (whether home or external pkg),
1399                         -- *not* including family instance orphans as they
1400                         -- are anyway included in 'dep_finsts'
1401          , dep_finsts :: [Module]
1402                         -- ^ Modules that contain family instances (whether the
1403                         -- instances are from the home or an external package)
1404          }
1405   deriving( Eq )
1406         -- Equality used only for old/new comparison in MkIface.addVersionInfo
1407
1408         -- See 'TcRnTypes.ImportAvails' for details on dependencies.
1409
1410 noDependencies :: Dependencies
1411 noDependencies = Deps [] [] [] []
1412
1413 -- | Records modules that we depend on by making a direct import from
1414 data Usage
1415   = UsagePackageModule {
1416         usg_mod      :: Module,
1417            -- ^ External package module depended on
1418         usg_mod_hash :: Fingerprint
1419     }                                           -- ^ Module from another package
1420   | UsageHomeModule {
1421         usg_mod_name :: ModuleName,
1422             -- ^ Name of the module
1423         usg_mod_hash :: Fingerprint,
1424             -- ^ Cached module fingerprint
1425         usg_entities :: [(OccName,Fingerprint)],
1426             -- ^ Entities we depend on, sorted by occurrence name and fingerprinted.
1427             -- NB: usages are for parent names only, e.g. type constructors
1428             -- but not the associated data constructors.
1429         usg_exports  :: Maybe Fingerprint
1430             -- ^ Fingerprint for the export list we used to depend on this module,
1431             -- if we depend on the export list
1432     }                                           -- ^ Module from the current package
1433     deriving( Eq )
1434         -- The export list field is (Just v) if we depend on the export list:
1435         --      i.e. we imported the module directly, whether or not we
1436         --           enumerated the things we imported, or just imported
1437         --           everything
1438         -- We need to recompile if M's exports change, because
1439         -- if the import was    import M,       we might now have a name clash
1440         --                                      in the importing module.
1441         -- if the import was    import M(x)     M might no longer export x
1442         -- The only way we don't depend on the export list is if we have
1443         --                      import M()
1444         -- And of course, for modules that aren't imported directly we don't
1445         -- depend on their export lists
1446 \end{code}
1447
1448
1449 %************************************************************************
1450 %*                                                                      *
1451                 The External Package State
1452 %*                                                                      *
1453 %************************************************************************
1454
1455 \begin{code}
1456 type PackageTypeEnv    = TypeEnv
1457 type PackageRuleBase   = RuleBase
1458 type PackageInstEnv    = InstEnv
1459 type PackageFamInstEnv = FamInstEnv
1460 type PackageVectInfo   = VectInfo
1461 type PackageAnnEnv     = AnnEnv
1462
1463 -- | Information about other packages that we have slurped in by reading
1464 -- their interface files
1465 data ExternalPackageState
1466   = EPS {
1467         eps_is_boot :: !(ModuleNameEnv (ModuleName, IsBootInterface)),
1468                 -- ^ In OneShot mode (only), home-package modules
1469                 -- accumulate in the external package state, and are
1470                 -- sucked in lazily.  For these home-pkg modules
1471                 -- (only) we need to record which are boot modules.
1472                 -- We set this field after loading all the
1473                 -- explicitly-imported interfaces, but before doing
1474                 -- anything else
1475                 --
1476                 -- The 'ModuleName' part is not necessary, but it's useful for
1477                 -- debug prints, and it's convenient because this field comes
1478                 -- direct from 'TcRnTypes.imp_dep_mods'
1479
1480         eps_PIT :: !PackageIfaceTable,
1481                 -- ^ The 'ModIface's for modules in external packages
1482                 -- whose interfaces we have opened.
1483                 -- The declarations in these interface files are held in the
1484                 -- 'eps_decls', 'eps_inst_env', 'eps_fam_inst_env' and 'eps_rules'
1485                 -- fields of this record, not in the 'mi_decls' fields of the
1486                 -- interface we have sucked in.
1487                 --
1488                 -- What /is/ in the PIT is:
1489                 --
1490                 -- * The Module
1491                 --
1492                 -- * Fingerprint info
1493                 --
1494                 -- * Its exports
1495                 --
1496                 -- * Fixities
1497                 --
1498                 -- * Deprecations and warnings
1499
1500         eps_PTE :: !PackageTypeEnv,
1501                 -- ^ Result of typechecking all the external package
1502                 -- interface files we have sucked in. The domain of
1503                 -- the mapping is external-package modules
1504
1505         eps_inst_env     :: !PackageInstEnv,   -- ^ The total 'InstEnv' accumulated
1506                                                -- from all the external-package modules
1507         eps_fam_inst_env :: !PackageFamInstEnv,-- ^ The total 'FamInstEnv' accumulated
1508                                                -- from all the external-package modules
1509         eps_rule_base    :: !PackageRuleBase,  -- ^ The total 'RuleEnv' accumulated
1510                                                -- from all the external-package modules
1511         eps_vect_info    :: !PackageVectInfo,  -- ^ The total 'VectInfo' accumulated
1512                                                -- from all the external-package modules
1513         eps_ann_env      :: !PackageAnnEnv,    -- ^ The total 'AnnEnv' accumulated
1514                                                -- from all the external-package modules
1515
1516         eps_mod_fam_inst_env :: !(ModuleEnv FamInstEnv), -- ^ The family instances accumulated from external
1517                                                          -- packages, keyed off the module that declared them
1518
1519         eps_stats :: !EpsStats                 -- ^ Stastics about what was loaded from external packages
1520   }
1521
1522 -- | Accumulated statistics about what we are putting into the 'ExternalPackageState'.
1523 -- \"In\" means stuff that is just /read/ from interface files,
1524 -- \"Out\" means actually sucked in and type-checked
1525 data EpsStats = EpsStats { n_ifaces_in
1526                          , n_decls_in, n_decls_out
1527                          , n_rules_in, n_rules_out
1528                          , n_insts_in, n_insts_out :: !Int }
1529
1530 addEpsInStats :: EpsStats -> Int -> Int -> Int -> EpsStats
1531 -- ^ Add stats for one newly-read interface
1532 addEpsInStats stats n_decls n_insts n_rules
1533   = stats { n_ifaces_in = n_ifaces_in stats + 1
1534           , n_decls_in  = n_decls_in stats + n_decls
1535           , n_insts_in  = n_insts_in stats + n_insts
1536           , n_rules_in  = n_rules_in stats + n_rules }
1537 \end{code}
1538
1539 Names in a NameCache are always stored as a Global, and have the SrcLoc
1540 of their binding locations.
1541
1542 Actually that's not quite right.  When we first encounter the original
1543 name, we might not be at its binding site (e.g. we are reading an
1544 interface file); so we give it 'noSrcLoc' then.  Later, when we find
1545 its binding site, we fix it up.
1546
1547 \begin{code}
1548 -- | The NameCache makes sure that there is just one Unique assigned for
1549 -- each original name; i.e. (module-name, occ-name) pair and provides
1550 -- something of a lookup mechanism for those names.
1551 data NameCache
1552  = NameCache {  nsUniqs :: UniqSupply,
1553                 -- ^ Supply of uniques
1554                 nsNames :: OrigNameCache,
1555                 -- ^ Ensures that one original name gets one unique
1556                 nsIPs   :: OrigIParamCache
1557                 -- ^ Ensures that one implicit parameter name gets one unique
1558    }
1559
1560 -- | Per-module cache of original 'OccName's given 'Name's
1561 type OrigNameCache   = ModuleEnv (OccEnv Name)
1562
1563 -- | Module-local cache of implicit parameter 'OccName's given 'Name's
1564 type OrigIParamCache = Map (IPName OccName) (IPName Name)
1565 \end{code}
1566
1567
1568
1569 %************************************************************************
1570 %*                                                                      *
1571                 The module graph and ModSummary type
1572         A ModSummary is a node in the compilation manager's
1573         dependency graph, and it's also passed to hscMain
1574 %*                                                                      *
1575 %************************************************************************
1576
1577 \begin{code}
1578 -- | A ModuleGraph contains all the nodes from the home package (only).
1579 -- There will be a node for each source module, plus a node for each hi-boot
1580 -- module.
1581 --
1582 -- The graph is not necessarily stored in topologically-sorted order.  Use
1583 -- 'GHC.topSortModuleGraph' and 'Digraph.flattenSCC' to achieve this.
1584 type ModuleGraph = [ModSummary]
1585
1586 emptyMG :: ModuleGraph
1587 emptyMG = []
1588
1589 -- | A single node in a 'ModuleGraph. The nodes of the module graph are one of:
1590 --
1591 -- * A regular Haskell source module
1592 --
1593 -- * A hi-boot source module
1594 --
1595 -- * An external-core source module
1596 data ModSummary
1597    = ModSummary {
1598         ms_mod       :: Module,                 -- ^ Identity of the module
1599         ms_hsc_src   :: HscSource,              -- ^ The module source either plain Haskell, hs-boot or external core
1600         ms_location  :: ModLocation,            -- ^ Location of the various files belonging to the module
1601         ms_hs_date   :: ClockTime,              -- ^ Timestamp of source file
1602         ms_obj_date  :: Maybe ClockTime,        -- ^ Timestamp of object, if we have one
1603         ms_srcimps   :: [Located (ImportDecl RdrName)], -- ^ Source imports of the module
1604         ms_imps      :: [Located (ImportDecl RdrName)], -- ^ Non-source imports of the module
1605         ms_hspp_file :: FilePath,               -- ^ Filename of preprocessed source file
1606         ms_hspp_opts :: DynFlags,               -- ^ Cached flags from @OPTIONS@, @INCLUDE@
1607                                                 -- and @LANGUAGE@ pragmas in the modules source code
1608         ms_hspp_buf  :: Maybe StringBuffer      -- ^ The actual preprocessed source, if we have it
1609      }
1610
1611 ms_mod_name :: ModSummary -> ModuleName
1612 ms_mod_name = moduleName . ms_mod
1613
1614 -- The ModLocation contains both the original source filename and the
1615 -- filename of the cleaned-up source file after all preprocessing has been
1616 -- done.  The point is that the summariser will have to cpp/unlit/whatever
1617 -- all files anyway, and there's no point in doing this twice -- just
1618 -- park the result in a temp file, put the name of it in the location,
1619 -- and let @compile@ read from that file on the way back up.
1620
1621 -- The ModLocation is stable over successive up-sweeps in GHCi, wheres
1622 -- the ms_hs_date and imports can, of course, change
1623
1624 msHsFilePath, msHiFilePath, msObjFilePath :: ModSummary -> FilePath
1625 msHsFilePath  ms = expectJust "msHsFilePath" (ml_hs_file  (ms_location ms))
1626 msHiFilePath  ms = ml_hi_file  (ms_location ms)
1627 msObjFilePath ms = ml_obj_file (ms_location ms)
1628
1629 -- | Did this 'ModSummary' originate from a hs-boot file?
1630 isBootSummary :: ModSummary -> Bool
1631 isBootSummary ms = isHsBoot (ms_hsc_src ms)
1632
1633 instance Outputable ModSummary where
1634    ppr ms
1635       = sep [text "ModSummary {",
1636              nest 3 (sep [text "ms_hs_date = " <> text (show (ms_hs_date ms)),
1637                           text "ms_mod =" <+> ppr (ms_mod ms)
1638                                 <> text (hscSourceString (ms_hsc_src ms)) <> comma,
1639                           text "ms_imps =" <+> ppr (ms_imps ms),
1640                           text "ms_srcimps =" <+> ppr (ms_srcimps ms)]),
1641              char '}'
1642             ]
1643
1644 showModMsg :: HscTarget -> Bool -> ModSummary -> String
1645 showModMsg target recomp mod_summary
1646   = showSDoc $
1647         hsep [text (mod_str ++ replicate (max 0 (16 - length mod_str)) ' '),
1648               char '(', text (normalise $ msHsFilePath mod_summary) <> comma,
1649               case target of
1650                   HscInterpreted | recomp
1651                              -> text "interpreted"
1652                   HscNothing -> text "nothing"
1653                   _          -> text (normalise $ msObjFilePath mod_summary),
1654               char ')']
1655  where
1656     mod     = moduleName (ms_mod mod_summary)
1657     mod_str = showSDoc (ppr mod) ++ hscSourceString (ms_hsc_src mod_summary)
1658 \end{code}
1659
1660
1661 %************************************************************************
1662 %*                                                                      *
1663 \subsection{Hpc Support}
1664 %*                                                                      *
1665 %************************************************************************
1666
1667 \begin{code}
1668 -- | Information about a modules use of Haskell Program Coverage
1669 data HpcInfo
1670   = HpcInfo
1671      { hpcInfoTickCount :: Int
1672      , hpcInfoHash      :: Int
1673      }
1674   | NoHpcInfo
1675      { hpcUsed          :: AnyHpcUsage  -- ^ Is hpc used anywhere on the module \*tree\*?
1676      }
1677
1678 -- | This is used to signal if one of my imports used HPC instrumentation
1679 -- even if there is no module-local HPC usage
1680 type AnyHpcUsage = Bool
1681
1682 emptyHpcInfo :: AnyHpcUsage -> HpcInfo
1683 emptyHpcInfo = NoHpcInfo
1684
1685 -- | Find out if HPC is used by this module or any of the modules
1686 -- it depends upon
1687 isHpcUsed :: HpcInfo -> AnyHpcUsage
1688 isHpcUsed (HpcInfo {})                   = True
1689 isHpcUsed (NoHpcInfo { hpcUsed = used }) = used
1690 \end{code}
1691
1692 %************************************************************************
1693 %*                                                                      *
1694 \subsection{Vectorisation Support}
1695 %*                                                                      *
1696 %************************************************************************
1697
1698 The following information is generated and consumed by the vectorisation
1699 subsystem.  It communicates the vectorisation status of declarations from one
1700 module to another.
1701
1702 Why do we need both f and f_v in the ModGuts/ModDetails/EPS version VectInfo
1703 below?  We need to know `f' when converting to IfaceVectInfo.  However, during
1704 vectorisation, we need to know `f_v', whose `Var' we cannot lookup based
1705 on just the OccName easily in a Core pass.
1706
1707 \begin{code}
1708 -- | Vectorisation information for 'ModGuts', 'ModDetails' and 'ExternalPackageState'.
1709 data VectInfo
1710   = VectInfo {
1711       vectInfoVar     :: VarEnv  (Var    , Var  ),   -- ^ @(f, f_v)@ keyed on @f@
1712       vectInfoTyCon   :: NameEnv (TyCon  , TyCon),   -- ^ @(T, T_v)@ keyed on @T@
1713       vectInfoDataCon :: NameEnv (DataCon, DataCon), -- ^ @(C, C_v)@ keyed on @C@
1714       vectInfoPADFun  :: NameEnv (TyCon  , Var),     -- ^ @(T_v, paT)@ keyed on @T_v@
1715       vectInfoIso     :: NameEnv (TyCon  , Var)      -- ^ @(T, isoT)@ keyed on @T@
1716     }
1717
1718 -- | Vectorisation information for 'ModIface': a slightly less low-level view
1719 data IfaceVectInfo
1720   = IfaceVectInfo {
1721       ifaceVectInfoVar        :: [Name],
1722         -- ^ All variables in here have a vectorised variant
1723       ifaceVectInfoTyCon      :: [Name],
1724         -- ^ All 'TyCon's in here have a vectorised variant;
1725         -- the name of the vectorised variant and those of its
1726         -- data constructors are determined by 'OccName.mkVectTyConOcc'
1727         -- and 'OccName.mkVectDataConOcc'; the names of
1728         -- the isomorphisms are determined by 'OccName.mkVectIsoOcc'
1729       ifaceVectInfoTyConReuse :: [Name]
1730         -- ^ The vectorised form of all the 'TyCon's in here coincides with
1731         -- the unconverted form; the name of the isomorphisms is determined
1732         -- by 'OccName.mkVectIsoOcc'
1733     }
1734
1735 noVectInfo :: VectInfo
1736 noVectInfo = VectInfo emptyVarEnv emptyNameEnv emptyNameEnv emptyNameEnv emptyNameEnv
1737
1738 plusVectInfo :: VectInfo -> VectInfo -> VectInfo
1739 plusVectInfo vi1 vi2 =
1740   VectInfo (vectInfoVar     vi1 `plusVarEnv`  vectInfoVar     vi2)
1741            (vectInfoTyCon   vi1 `plusNameEnv` vectInfoTyCon   vi2)
1742            (vectInfoDataCon vi1 `plusNameEnv` vectInfoDataCon vi2)
1743            (vectInfoPADFun  vi1 `plusNameEnv` vectInfoPADFun  vi2)
1744            (vectInfoIso     vi1 `plusNameEnv` vectInfoIso     vi2)
1745
1746 concatVectInfo :: [VectInfo] -> VectInfo
1747 concatVectInfo = foldr plusVectInfo noVectInfo
1748
1749 noIfaceVectInfo :: IfaceVectInfo
1750 noIfaceVectInfo = IfaceVectInfo [] [] []
1751 \end{code}
1752
1753 %************************************************************************
1754 %*                                                                      *
1755 \subsection{Linkable stuff}
1756 %*                                                                      *
1757 %************************************************************************
1758
1759 This stuff is in here, rather than (say) in Linker.lhs, because the Linker.lhs
1760 stuff is the *dynamic* linker, and isn't present in a stage-1 compiler
1761
1762 \begin{code}
1763 -- | Information we can use to dynamically link modules into the compiler
1764 data Linkable = LM {
1765   linkableTime     :: ClockTime,        -- ^ Time at which this linkable was built
1766                                         -- (i.e. when the bytecodes were produced,
1767                                         --       or the mod date on the files)
1768   linkableModule   :: Module,           -- ^ The linkable module itself
1769   linkableUnlinked :: [Unlinked]
1770     -- ^ Those files and chunks of code we have yet to link.
1771     --
1772     -- INVARIANT: A valid linkable always has at least one 'Unlinked' item.
1773     -- If this list is empty, the Linkable represents a fake linkable, which
1774     -- is generated in HscNothing mode to avoid recompiling modules.
1775     --
1776     -- XXX: Do items get removed from this list when they get linked?
1777  }
1778
1779 isObjectLinkable :: Linkable -> Bool
1780 isObjectLinkable l = not (null unlinked) && all isObject unlinked
1781   where unlinked = linkableUnlinked l
1782         -- A linkable with no Unlinked's is treated as a BCO.  We can
1783         -- generate a linkable with no Unlinked's as a result of
1784         -- compiling a module in HscNothing mode, and this choice
1785         -- happens to work well with checkStability in module GHC.
1786
1787 instance Outputable Linkable where
1788    ppr (LM when_made mod unlinkeds)
1789       = (text "LinkableM" <+> parens (text (show when_made)) <+> ppr mod)
1790         $$ nest 3 (ppr unlinkeds)
1791
1792 -------------------------------------------
1793
1794 -- | Objects which have yet to be linked by the compiler
1795 data Unlinked
1796    = DotO FilePath      -- ^ An object file (.o)
1797    | DotA FilePath      -- ^ Static archive file (.a)
1798    | DotDLL FilePath    -- ^ Dynamically linked library file (.so, .dll, .dylib)
1799    | BCOs CompiledByteCode ModBreaks    -- ^ A byte-code object, lives only in memory
1800
1801 #ifndef GHCI
1802 data CompiledByteCode = CompiledByteCodeUndefined
1803 _unused :: CompiledByteCode
1804 _unused = CompiledByteCodeUndefined
1805 #endif
1806
1807 instance Outputable Unlinked where
1808    ppr (DotO path)   = text "DotO" <+> text path
1809    ppr (DotA path)   = text "DotA" <+> text path
1810    ppr (DotDLL path) = text "DotDLL" <+> text path
1811 #ifdef GHCI
1812    ppr (BCOs bcos _) = text "BCOs" <+> ppr bcos
1813 #else
1814    ppr (BCOs _ _)    = text "No byte code"
1815 #endif
1816
1817 -- | Is this an actual file on disk we can link in somehow?
1818 isObject :: Unlinked -> Bool
1819 isObject (DotO _)   = True
1820 isObject (DotA _)   = True
1821 isObject (DotDLL _) = True
1822 isObject _          = False
1823
1824 -- | Is this a bytecode linkable with no file on disk?
1825 isInterpretable :: Unlinked -> Bool
1826 isInterpretable = not . isObject
1827
1828 -- | Retrieve the filename of the linkable if possible. Panic if it is a byte-code object
1829 nameOfObject :: Unlinked -> FilePath
1830 nameOfObject (DotO fn)   = fn
1831 nameOfObject (DotA fn)   = fn
1832 nameOfObject (DotDLL fn) = fn
1833 nameOfObject other       = pprPanic "nameOfObject" (ppr other)
1834
1835 -- | Retrieve the compiled byte-code if possible. Panic if it is a file-based linkable
1836 byteCodeOfObject :: Unlinked -> CompiledByteCode
1837 byteCodeOfObject (BCOs bc _) = bc
1838 byteCodeOfObject other       = pprPanic "byteCodeOfObject" (ppr other)
1839 \end{code}
1840
1841 %************************************************************************
1842 %*                                                                      *
1843 \subsection{Breakpoint Support}
1844 %*                                                                      *
1845 %************************************************************************
1846
1847 \begin{code}
1848 -- | Breakpoint index
1849 type BreakIndex = Int
1850
1851 -- | All the information about the breakpoints for a given module
1852 data ModBreaks
1853    = ModBreaks
1854    { modBreaks_flags :: BreakArray
1855         -- ^ The array of flags, one per breakpoint,
1856         -- indicating which breakpoints are enabled.
1857    , modBreaks_locs :: !(Array BreakIndex SrcSpan)
1858         -- ^ An array giving the source span of each breakpoint.
1859    , modBreaks_vars :: !(Array BreakIndex [OccName])
1860         -- ^ An array giving the names of the free variables at each breakpoint.
1861    , modBreaks_decls :: !(Array BreakIndex [String])
1862         -- ^ An array giving the names of the declarations enclosing each breakpoint.
1863    }
1864
1865 emptyModBreaks :: ModBreaks
1866 emptyModBreaks = ModBreaks
1867    { modBreaks_flags = error "ModBreaks.modBreaks_array not initialised"
1868          -- Todo: can we avoid this?
1869    , modBreaks_locs  = array (0,-1) []
1870    , modBreaks_vars  = array (0,-1) []
1871    , modBreaks_decls = array (0,-1) []
1872    }
1873 \end{code}