compiler/main/TidyPgm.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Tidying up Core}
   5
   6 \begin{code}
   7 module TidyPgm( mkBootModDetailsDs, mkBootModDetailsTc,
   8                 tidyProgram, globaliseAndTidyId ) where
   9
  10 #include "HsVersions.h"
  11
  12 import TcRnTypes
  13 import FamInstEnv
  14 import DynFlags
  15 import CoreSyn
  16 import CoreUnfold
  17 import CoreFVs
  18 import CoreTidy
  19 import PprCore
  20 import CoreLint
  21 import CoreUtils
  22 import CoreArity        ( exprArity )
  23 import Class            ( classSelIds )
  24 import VarEnv
  25 import VarSet
  26 import Var
  27 import Id
  28 import IdInfo
  29 import InstEnv
  30 import NewDemand
  31 import BasicTypes
  32 import Name
  33 import NameSet
  34 import IfaceEnv
  35 import NameEnv
  36 import TcType
  37 import DataCon
  38 import TyCon
  39 import Module
  40 import HscTypes
  41 import Maybes
  42 import ErrUtils
  43 import UniqSupply
  44 import Outputable
  45 import FastBool hiding ( fastOr )
  46 import Util
  47
  48 import Data.List        ( sortBy )
  49 import Data.IORef       ( IORef, readIORef, writeIORef )
  50 \end{code}
  51
  52
  53 Constructing the TypeEnv, Instances, Rules from which the ModIface is
  54 constructed, and which goes on to subsequent modules in --make mode.
  55
  56 Most of the interface file is obtained simply by serialising the
  57 TypeEnv.  One important consequence is that if the *interface file*
  58 has pragma info if and only if the final TypeEnv does. This is not so
  59 important for *this* module, but it's essential for ghc --make:
  60 subsequent compilations must not see (e.g.) the arity if the interface
  61 file does not contain arity If they do, they'll exploit the arity;
  62 then the arity might change, but the iface file doesn't change =>
  63 recompilation does not happen => disaster.
  64
  65 For data types, the final TypeEnv will have a TyThing for the TyCon,
  66 plus one for each DataCon; the interface file will contain just one
  67 data type declaration, but it is de-serialised back into a collection
  68 of TyThings.
  69
  70 %************************************************************************
  71 %*                                                                      *
  72                 Plan A: simpleTidyPgm
  73 %*                                                                      *
  74 %************************************************************************
  75
  76
  77 Plan A: mkBootModDetails: omit pragmas, make interfaces small
  78 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  79 * Ignore the bindings
  80
  81 * Drop all WiredIn things from the TypeEnv
  82         (we never want them in interface files)
  83
  84 * Retain all TyCons and Classes in the TypeEnv, to avoid
  85         having to find which ones are mentioned in the
  86         types of exported Ids
  87
  88 * Trim off the constructors of non-exported TyCons, both
  89         from the TyCon and from the TypeEnv
  90
  91 * Drop non-exported Ids from the TypeEnv
  92
  93 * Tidy the types of the DFunIds of Instances,
  94   make them into GlobalIds, (they already have External Names)
  95   and add them to the TypeEnv
  96
  97 * Tidy the types of the (exported) Ids in the TypeEnv,
  98   make them into GlobalIds (they already have External Names)
  99
 100 * Drop rules altogether
 101
 102 * Tidy the bindings, to ensure that the Caf and Arity
 103   information is correct for each top-level binder; the
 104   code generator needs it. And to ensure that local names have
 105   distinct OccNames in case of object-file splitting
 106
 107 \begin{code}
 108 -- This is Plan A: make a small type env when typechecking only,
 109 -- or when compiling a hs-boot file, or simply when not using -O
 110 --
 111 -- We don't look at the bindings at all -- there aren't any
 112 -- for hs-boot files
 113
 114 mkBootModDetailsTc :: HscEnv -> TcGblEnv -> IO ModDetails
 115 mkBootModDetailsTc hsc_env
 116         TcGblEnv{ tcg_exports   = exports,
 117                   tcg_type_env  = type_env,
 118                   tcg_insts     = insts,
 119                   tcg_fam_insts = fam_insts
 120                 }
 121   = mkBootModDetails hsc_env exports type_env insts fam_insts
 122
 123 mkBootModDetailsDs :: HscEnv -> ModGuts -> IO ModDetails
 124 mkBootModDetailsDs hsc_env
 125         ModGuts{ mg_exports   = exports,
 126                  mg_types     = type_env,
 127                  mg_insts     = insts,
 128                  mg_fam_insts = fam_insts
 129                 }
 130   = mkBootModDetails hsc_env exports type_env insts fam_insts
 131
 132 mkBootModDetails :: HscEnv -> [AvailInfo] -> NameEnv TyThing
 133                  -> [Instance] -> [FamInstEnv.FamInst] -> IO ModDetails
 134 mkBootModDetails hsc_env exports type_env insts fam_insts
 135   = do  { let dflags = hsc_dflags hsc_env
 136         ; showPass dflags "Tidy [hoot] type env"
 137
 138         ; let { insts'     = tidyInstances globaliseAndTidyId insts
 139               ; dfun_ids   = map instanceDFunId insts'
 140               ; type_env1  = tidyBootTypeEnv (availsToNameSet exports) type_env
 141               ; type_env'  = extendTypeEnvWithIds type_env1 dfun_ids
 142               }
 143         ; return (ModDetails { md_types     = type_env'
 144                              , md_insts     = insts'
 145                              , md_fam_insts = fam_insts
 146                              , md_rules     = []
 147                              , md_anns      = []
 148                              , md_exports   = exports
 149                              , md_vect_info = noVectInfo
 150                              })
 151         }
 152   where
 153
 154 tidyBootTypeEnv :: NameSet -> TypeEnv -> TypeEnv
 155 tidyBootTypeEnv exports type_env
 156   = tidyTypeEnv True False exports type_env final_ids
 157   where
 158         -- Find the LocalIds in the type env that are exported
 159         -- Make them into GlobalIds, and tidy their types
 160         --
 161         -- It's very important to remove the non-exported ones
 162         -- because we don't tidy the OccNames, and if we don't remove
 163         -- the non-exported ones we'll get many things with the
 164         -- same name in the interface file, giving chaos.
 165     final_ids = [ globaliseAndTidyId id
 166                 | id <- typeEnvIds type_env
 167                 , isLocalId id
 168                 , keep_it id ]
 169
 170         -- default methods have their export flag set, but everything
 171         -- else doesn't (yet), because this is pre-desugaring, so we
 172         -- must test both.
 173     keep_it id = isExportedId id || idName id `elemNameSet` exports
 174
 175
 176
 177 globaliseAndTidyId :: Id -> Id
 178 -- Takes an LocalId with an External Name,
 179 -- makes it into a GlobalId
 180 --     * unchanged Name (might be Internal or External)
 181 --     * unchanged details
 182 --     * VanillaIdInfo (makes a conservative assumption about Caf-hood)
 183 globaliseAndTidyId id
 184   = Id.setIdType (globaliseId id) tidy_type
 185   where
 186     tidy_type = tidyTopType (idType id)
 187 \end{code}
 188
 189
 190 %************************************************************************
 191 %*                                                                      *
 192         Plan B: tidy bindings, make TypeEnv full of IdInfo
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 Plan B: include pragmas, make interfaces
 197 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 198 * Figure out which Ids are externally visible
 199
 200 * Tidy the bindings, externalising appropriate Ids
 201
 202 * Drop all Ids from the TypeEnv, and add all the External Ids from
 203   the bindings.  (This adds their IdInfo to the TypeEnv; and adds
 204   floated-out Ids that weren't even in the TypeEnv before.)
 205
 206 Step 1: Figure out external Ids
 207 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 208 Note [choosing external names]
 209
 210 See also the section "Interface stability" in the
 211 RecompilationAvoidance commentary:
 212   http://hackage.haskell.org/trac/ghc/wiki/Commentary/Compiler/RecompilationAvoidance
 213
 214 First we figure out which Ids are "external" Ids.  An
 215 "external" Id is one that is visible from outside the compilation
 216 unit.  These are
 217         a) the user exported ones
 218         b) ones mentioned in the unfoldings, workers,
 219            or rules of externally-visible ones
 220
 221 While figuring out which Ids are external, we pick a "tidy" OccName
 222 for each one.  That is, we make its OccName distinct from the other
 223 external OccNames in this module, so that in interface files and
 224 object code we can refer to it unambiguously by its OccName.  The
 225 OccName for each binder is prefixed by the name of the exported Id
 226 that references it; e.g. if "f" references "x" in its unfolding, then
 227 "x" is renamed to "f_x".  This helps distinguish the different "x"s
 228 from each other, and means that if "f" is later removed, things that
 229 depend on the other "x"s will not need to be recompiled.  Of course,
 230 if there are multiple "f_x"s, then we have to disambiguate somehow; we
 231 use "f_x0", "f_x1" etc.
 232
 233 As far as possible we should assign names in a deterministic fashion.
 234 Each time this module is compiled with the same options, we should end
 235 up with the same set of external names with the same types.  That is,
 236 the ABI hash in the interface should not change.  This turns out to be
 237 quite tricky, since the order of the bindings going into the tidy
 238 phase is already non-deterministic, as it is based on the ordering of
 239 Uniques, which are assigned unpredictably.
 240
 241 To name things in a stable way, we do a depth-first-search of the
 242 bindings, starting from the exports sorted by name.  This way, as long
 243 as the bindings themselves are deterministic (they sometimes aren't!),
 244 the order in which they are presented to the tidying phase does not
 245 affect the names we assign.
 246
 247 Step 2: Tidy the program
 248 ~~~~~~~~~~~~~~~~~~~~~~~~
 249 Next we traverse the bindings top to bottom.  For each *top-level*
 250 binder
 251
 252  1. Make it into a GlobalId; its IdDetails becomes VanillaGlobal,
 253     reflecting the fact that from now on we regard it as a global,
 254     not local, Id
 255
 256  2. Give it a system-wide Unique.
 257     [Even non-exported things need system-wide Uniques because the
 258     byte-code generator builds a single Name->BCO symbol table.]
 259
 260     We use the NameCache kept in the HscEnv as the
 261     source of such system-wide uniques.
 262
 263     For external Ids, use the original-name cache in the NameCache
 264     to ensure that the unique assigned is the same as the Id had
 265     in any previous compilation run.
 266
 267  3. Rename top-level Ids according to the names we chose in step 1.
 268     If it's an external Id, make it have a External Name, otherwise
 269     make it have an Internal Name.  This is used by the code generator
 270     to decide whether to make the label externally visible
 271
 272  4. Give it its UTTERLY FINAL IdInfo; in ptic,
 273         * its unfolding, if it should have one
 274
 275         * its arity, computed from the number of visible lambdas
 276
 277         * its CAF info, computed from what is free in its RHS
 278
 279
 280 Finally, substitute these new top-level binders consistently
 281 throughout, including in unfoldings.  We also tidy binders in
 282 RHSs, so that they print nicely in interfaces.
 283
 284 \begin{code}
 285 tidyProgram :: HscEnv -> ModGuts -> IO (CgGuts, ModDetails)
 286 tidyProgram hsc_env  (ModGuts { mg_module = mod, mg_exports = exports,
 287                                 mg_types = type_env,
 288                                 mg_insts = insts, mg_fam_insts = fam_insts,
 289                                 mg_binds = binds,
 290                                 mg_rules = imp_rules,
 291                                 mg_vect_info = vect_info,
 292                                 mg_dir_imps = dir_imps,
 293                                 mg_anns = anns,
 294                                 mg_deps = deps,
 295                                 mg_foreign = foreign_stubs,
 296                                 mg_hpc_info = hpc_info,
 297                                 mg_modBreaks = modBreaks })
 298
 299   = do  { let dflags = hsc_dflags hsc_env
 300         ; showPass dflags "Tidy Core"
 301
 302         ; let { omit_prags = dopt Opt_OmitInterfacePragmas dflags
 303               ; th         = dopt Opt_TemplateHaskell      dflags
 304               }
 305
 306         ; let { implicit_binds = getImplicitBinds type_env }
 307
 308         ; (unfold_env, tidy_occ_env)
 309               <- chooseExternalIds hsc_env mod omit_prags binds implicit_binds
 310
 311         ; let { ext_rules
 312                    | omit_prags = []
 313                    | otherwise  = findExternalRules binds imp_rules unfold_env
 314                 -- findExternalRules filters imp_rules to avoid binders that
 315                 -- aren't externally visible; but the externally-visible binders
 316                 -- are computed (by findExternalIds) assuming that all orphan
 317                 -- rules are exported (they get their Exported flag set in the desugarer)
 318                 -- So in fact we may export more than we need.
 319                 -- (It's a sort of mutual recursion.)
 320         }
 321
 322         ; let { (tidy_env, tidy_binds)
 323                  = tidyTopBinds hsc_env unfold_env tidy_occ_env binds }
 324
 325         ; let { export_set = availsToNameSet exports
 326               ; final_ids  = [ id | id <- bindersOfBinds tidy_binds,
 327                                     isExternalName (idName id)]
 328               ; tidy_type_env = tidyTypeEnv omit_prags th export_set
 329                                             type_env final_ids
 330               ; tidy_insts    = tidyInstances (lookup_dfun tidy_type_env) insts
 331                 -- A DFunId will have a binding in tidy_binds, and so
 332                 -- will now be in final_env, replete with IdInfo
 333                 -- Its name will be unchanged since it was born, but
 334                 -- we want Global, IdInfo-rich (or not) DFunId in the
 335                 -- tidy_insts
 336
 337               ; tidy_rules = tidyRules tidy_env ext_rules
 338                 -- You might worry that the tidy_env contains IdInfo-rich stuff
 339                 -- and indeed it does, but if omit_prags is on, ext_rules is
 340                 -- empty
 341
 342               -- See Note [Injecting implicit bindings]
 343               ; all_tidy_binds = implicit_binds ++ tidy_binds
 344
 345               ; alg_tycons = filter isAlgTyCon (typeEnvTyCons type_env)
 346               }
 347
 348         ; endPass dflags "Tidy Core" Opt_D_dump_simpl all_tidy_binds
 349         ; dumpIfSet_core dflags Opt_D_dump_simpl
 350                 "Tidy Core Rules"
 351                 (pprRules tidy_rules)
 352
 353         ; let dir_imp_mods = moduleEnvKeys dir_imps
 354
 355         ; return (CgGuts { cg_module   = mod,
 356                            cg_tycons   = alg_tycons,
 357                            cg_binds    = all_tidy_binds,
 358                            cg_dir_imps = dir_imp_mods,
 359                            cg_foreign  = foreign_stubs,
 360                            cg_dep_pkgs = dep_pkgs deps,
 361                            cg_hpc_info = hpc_info,
 362                            cg_modBreaks = modBreaks },
 363
 364                    ModDetails { md_types     = tidy_type_env,
 365                                 md_rules     = tidy_rules,
 366                                 md_insts     = tidy_insts,
 367                                 md_fam_insts = fam_insts,
 368                                 md_exports   = exports,
 369                                 md_anns      = anns,     -- are already tidy
 370                                 md_vect_info = vect_info --
 371                               })
 372         }
 373
 374 lookup_dfun :: TypeEnv -> Var -> Id
 375 lookup_dfun type_env dfun_id
 376   = case lookupTypeEnv type_env (idName dfun_id) of
 377         Just (AnId dfun_id') -> dfun_id'
 378         _other -> pprPanic "lookup_dfun" (ppr dfun_id)
 379
 380 --------------------------
 381 tidyTypeEnv :: Bool     -- Compiling without -O, so omit prags
 382             -> Bool     -- Template Haskell is on
 383             -> NameSet -> TypeEnv -> [Id] -> TypeEnv
 384
 385 -- The competed type environment is gotten from
 386 --      Dropping any wired-in things, and then
 387 --      a) keeping the types and classes
 388 --      b) removing all Ids,
 389 --      c) adding Ids with correct IdInfo, including unfoldings,
 390 --              gotten from the bindings
 391 -- From (c) we keep only those Ids with External names;
 392 --          the CoreTidy pass makes sure these are all and only
 393 --          the externally-accessible ones
 394 -- This truncates the type environment to include only the
 395 -- exported Ids and things needed from them, which saves space
 396
 397 tidyTypeEnv omit_prags th exports type_env final_ids
 398  = let  type_env1 = filterNameEnv keep_it type_env
 399         type_env2 = extendTypeEnvWithIds type_env1 final_ids
 400         type_env3 | omit_prags = mapNameEnv (trimThing th exports) type_env2
 401                   | otherwise  = type_env2
 402     in
 403     type_env3
 404   where
 405         -- We keep GlobalIds, because they won't appear
 406         -- in the bindings from which final_ids are derived!
 407         -- (The bindings bind LocalIds.)
 408     keep_it thing | isWiredInThing thing = False
 409     keep_it (AnId id) = isGlobalId id   -- Keep GlobalIds (e.g. class ops)
 410     keep_it _other    = True            -- Keep all TyCons, DataCons, and Classes
 411
 412 --------------------------
 413 isWiredInThing :: TyThing -> Bool
 414 isWiredInThing thing = isWiredInName (getName thing)
 415
 416 --------------------------
 417 trimThing :: Bool -> NameSet -> TyThing -> TyThing
 418 -- Trim off inessentials, for boot files and no -O
 419 trimThing th exports (ATyCon tc)
 420    | not th && not (mustExposeTyCon exports tc)
 421    = ATyCon (makeTyConAbstract tc)      -- Note [Trimming and Template Haskell]
 422
 423 trimThing _th _exports (AnId id)
 424    | not (isImplicitId id)
 425    = AnId (id `setIdInfo` vanillaIdInfo)
 426
 427 trimThing _th _exports other_thing
 428   = other_thing
 429
 430
 431 {- Note [Trimming and Template Haskell]
 432    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 433 Consider (Trac #2386) this
 434         module M(T, makeOne) where
 435           data T = Yay String
 436           makeOne = [| Yay "Yep" |]
 437 Notice that T is exported abstractly, but makeOne effectively exports it too!
 438 A module that splices in $(makeOne) will then look for a declartion of Yay,
 439 so it'd better be there.  Hence, brutally but simply, we switch off type
 440 constructor trimming if TH is enabled in this module. -}
 441
 442
 443 mustExposeTyCon :: NameSet      -- Exports
 444                 -> TyCon        -- The tycon
 445                 -> Bool         -- Can its rep be hidden?
 446 -- We are compiling without -O, and thus trying to write as little as
 447 -- possible into the interface file.  But we must expose the details of
 448 -- any data types whose constructors or fields are exported
 449 mustExposeTyCon exports tc
 450   | not (isAlgTyCon tc)         -- Synonyms
 451   = True
 452   | isEnumerationTyCon tc       -- For an enumeration, exposing the constructors
 453   = True                        -- won't lead to the need for further exposure
 454                                 -- (This includes data types with no constructors.)
 455   | isOpenTyCon tc              -- Open type family
 456   = True
 457
 458   | otherwise                   -- Newtype, datatype
 459   = any exported_con (tyConDataCons tc)
 460         -- Expose rep if any datacon or field is exported
 461
 462   || (isNewTyCon tc && isFFITy (snd (newTyConRhs tc)))
 463         -- Expose the rep for newtypes if the rep is an FFI type.
 464         -- For a very annoying reason.  'Foreign import' is meant to
 465         -- be able to look through newtypes transparently, but it
 466         -- can only do that if it can "see" the newtype representation
 467   where
 468     exported_con con = any (`elemNameSet` exports)
 469                            (dataConName con : dataConFieldLabels con)
 470
 471 tidyInstances :: (DFunId -> DFunId) -> [Instance] -> [Instance]
 472 tidyInstances tidy_dfun ispecs
 473   = map tidy ispecs
 474   where
 475     tidy ispec = setInstanceDFunId ispec $
 476                  tidy_dfun (instanceDFunId ispec)
 477 \end{code}
 478
 479
 480 %************************************************************************
 481 %*                                                                      *
 482         Implicit bindings
 483 %*                                                                      *
 484 %************************************************************************
 485
 486 Note [Injecting implicit bindings]
 487 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 488 We inject the implict bindings right at the end, in CoreTidy.
 489 Some of these bindings, notably record selectors, are not
 490 constructed in an optimised form.  E.g. record selector for
 491         data T = MkT { x :: {-# UNPACK #-} !Int }
 492 Then the unfolding looks like
 493         x = \t. case t of MkT x1 -> let x = I# x1 in x
 494 This generates bad code unless it's first simplified a bit.  That is
 495 why CoreUnfold.mkImplicitUnfolding uses simleExprOpt to do a bit of
 496 optimisation first.  (Only matters when the selector is used curried;
 497 eg map x ys.)  See Trac #2070.
 498
 499 At one time I tried injecting the implicit bindings *early*, at the
 500 beginning of SimplCore.  But that gave rise to real difficulty,
 501 becuase GlobalIds are supposed to have *fixed* IdInfo, but the
 502 simplifier and other core-to-core passes mess with IdInfo all the
 503 time.  The straw that broke the camels back was when a class selector
 504 got the wrong arity -- ie the simplifier gave it arity 2, whereas
 505 importing modules were expecting it to have arity 1 (Trac #2844).
 506 It's much safer just to inject them right at the end, after tidying.
 507
 508 Oh: two other reasons for injecting them late:
 509   - If implicit Ids are already in the bindings when we start TidyPgm,
 510     we'd have to be careful not to treat them as external Ids (in
 511     the sense of findExternalIds); else the Ids mentioned in *their*
 512     RHSs will be treated as external and you get an interface file
 513     saying      a18 = <blah>
 514     but nothing refererring to a18 (because the implicit Id is the
 515     one that does).
 516
 517   - More seriously, the tidied type-envt will include the implicit
 518     Id replete with a18 in its unfolding; but we won't take account
 519     of a18 when computing a fingerprint for the class; result chaos.
 520
 521
 522 \begin{code}
 523 getImplicitBinds :: TypeEnv -> [CoreBind]
 524 getImplicitBinds type_env
 525   = map get_defn (concatMap implicit_ids (typeEnvElts type_env))
 526   where
 527     implicit_ids (ATyCon tc)  = mapCatMaybes dataConWrapId_maybe (tyConDataCons tc)
 528     implicit_ids (AClass cls) = classSelIds cls
 529     implicit_ids _            = []
 530
 531     get_defn :: Id -> CoreBind
 532     get_defn id = NonRec id (unfoldingTemplate (idUnfolding id))
 533 \end{code}
 534
 535
 536 %************************************************************************
 537 %*                                                                      *
 538 \subsection{Step 1: finding externals}
 539 %*                                                                      *
 540 %************************************************************************
 541
 542 Sete Note [choosing external names].
 543
 544 \begin{code}
 545 type UnfoldEnv  = IdEnv (Name{-new name-}, Bool {-show unfolding-})
 546   -- maps each top-level Id to its new Name (the Id is tidied in step 2)
 547   -- The Unique is unchanged.  If the new Id is external, it will be
 548   -- visible in the interface file.
 549   --
 550   -- Bool => expose unfolding or not.
 551
 552 chooseExternalIds :: HscEnv
 553                   -> Module
 554                   -> Bool
 555                   -> [CoreBind]
 556                   -> [CoreBind]
 557                   -> IO (UnfoldEnv, TidyOccEnv)
 558         -- Step 1 from the notes above
 559
 560 chooseExternalIds hsc_env mod omit_prags binds implicit_binds
 561   = do
 562     (unfold_env1,occ_env1)
 563         <- search (zip sorted_exports sorted_exports) emptyVarEnv init_occ_env
 564     let internal_ids = filter (not . (`elemVarEnv` unfold_env1)) binders
 565     tidy_internal internal_ids unfold_env1 occ_env1
 566  where
 567   nc_var = hsc_NC hsc_env
 568
 569   -- the exports, sorted by OccName.  This is a deterministic list of
 570   -- Ids (i.e. it's the same list every time this module is compiled),
 571   -- in contrast to the bindings, which are ordered
 572   -- non-deterministically.
 573   --
 574   -- This list will serve as a starting point for finding a
 575   -- deterministic, tidy, renaming for all external Ids in this
 576   -- module.
 577   sorted_exports = sortBy (compare `on` getOccName) $
 578                      filter isExportedId binders
 579
 580   binders = bindersOfBinds binds
 581   implicit_binders = bindersOfBinds implicit_binds
 582
 583   bind_env :: IdEnv (Id,CoreExpr)
 584   bind_env = mkVarEnv (zip (map fst bs) bs) where bs = flattenBinds binds
 585
 586   avoids   = [getOccName name | bndr <- binders ++ implicit_binders,
 587                                 let name = idName bndr,
 588                                 isExternalName name ]
 589                 -- In computing our "avoids" list, we must include
 590                 --      all implicit Ids
 591                 --      all things with global names (assigned once and for
 592                 --                                      all by the renamer)
 593                 -- since their names are "taken".
 594                 -- The type environment is a convenient source of such things.
 595                 -- In particular, the set of binders doesn't include
 596                 -- implicit Ids at this stage.
 597
 598         -- We also make sure to avoid any exported binders.  Consider
 599         --      f{-u1-} = 1     -- Local decl
 600         --      ...
 601         --      f{-u2-} = 2     -- Exported decl
 602         --
 603         -- The second exported decl must 'get' the name 'f', so we
 604         -- have to put 'f' in the avoids list before we get to the first
 605         -- decl.  tidyTopId then does a no-op on exported binders.
 606   init_occ_env = initTidyOccEnv avoids
 607
 608
 609   search :: [(Id,Id)]    -- (external id, referrring id)
 610          -> UnfoldEnv    -- id -> (new Name, show_unfold)
 611          -> TidyOccEnv   -- occ env for choosing new Names
 612          -> IO (UnfoldEnv, TidyOccEnv)
 613
 614   search [] unfold_env occ_env = return (unfold_env, occ_env)
 615
 616   search ((idocc,referrer) : rest) unfold_env occ_env
 617     | idocc `elemVarEnv` unfold_env = search rest unfold_env occ_env
 618     | otherwise = do
 619       (occ_env', name') <- tidyTopName mod nc_var (Just referrer) occ_env idocc
 620       let
 621           (id, rhs) = expectJust (showSDoc (text "chooseExternalIds: " <>
 622                                             ppr idocc)) $
 623                                  lookupVarEnv bind_env idocc
 624           -- NB. idocc might be an *occurrence* of an Id, whereas we want
 625           -- the Id from the binding site, because only the latter is
 626           -- guaranteed to have the unfolding attached.  This is why we
 627           -- keep binding site Ids in the bind_env.
 628           (new_ids, show_unfold)
 629                 | omit_prags = ([], False)
 630                 | otherwise  = addExternal id rhs
 631           unfold_env' = extendVarEnv unfold_env id (name',show_unfold)
 632           referrer' | isExportedId id = id
 633                     | otherwise       = referrer
 634       --
 635       search (zip new_ids (repeat referrer') ++ rest) unfold_env' occ_env'
 636
 637   tidy_internal :: [Id] -> UnfoldEnv -> TidyOccEnv
 638                 -> IO (UnfoldEnv, TidyOccEnv)
 639   tidy_internal []       unfold_env occ_env = return (unfold_env,occ_env)
 640   tidy_internal (id:ids) unfold_env occ_env = do
 641       (occ_env', name') <- tidyTopName mod nc_var Nothing occ_env id
 642       let unfold_env' = extendVarEnv unfold_env id (name',False)
 643       tidy_internal ids unfold_env' occ_env'
 644
 645 addExternal :: Id -> CoreExpr -> ([Id],Bool)
 646 addExternal id rhs = (new_needed_ids, show_unfold)
 647   where
 648     new_needed_ids = unfold_ids ++
 649                      filter (\id -> isLocalId id &&
 650                                     not (id `elemVarSet` unfold_set))
 651                        (varSetElems worker_ids ++
 652                         varSetElems spec_ids) -- XXX non-det ordering
 653
 654     idinfo         = idInfo id
 655     dont_inline    = isNeverActive (inlinePragmaActivation (inlinePragInfo idinfo))
 656     loop_breaker   = isNonRuleLoopBreaker (occInfo idinfo)
 657     bottoming_fn   = isBottomingSig (newStrictnessInfo idinfo `orElse` topSig)
 658     spec_ids       = specInfoFreeVars (specInfo idinfo)
 659     worker_info    = workerInfo idinfo
 660
 661         -- Stuff to do with the Id's unfolding
 662         -- The simplifier has put an up-to-date unfolding
 663         -- in the IdInfo, but the RHS will do just as well
 664     unfolding    = unfoldingInfo idinfo
 665     rhs_is_small = not (neverUnfold unfolding)
 666
 667         -- We leave the unfolding there even if there is a worker
 668         -- In GHCI the unfolding is used by importers
 669         -- When writing an interface file, we omit the unfolding
 670         -- if there is a worker
 671     show_unfold = not bottoming_fn       &&     -- Not necessary
 672                   not dont_inline        &&
 673                   not loop_breaker       &&
 674                   rhs_is_small                  -- Small enough
 675
 676     (unfold_set, unfold_ids)
 677                | show_unfold = freeVarsInDepthFirstOrder rhs
 678                | otherwise   = (emptyVarSet, [])
 679
 680     worker_ids = case worker_info of
 681                    HasWorker work_id _ -> unitVarSet work_id
 682                    _otherwise          -> emptyVarSet
 683
 684
 685 -- We want a deterministic free-variable list.  exprFreeVars gives us
 686 -- a VarSet, which is in a non-deterministic order when converted to a
 687 -- list.  Hence, here we define a free-variable finder that returns
 688 -- the free variables in the order that they are encountered.
 689 --
 690 -- Note [choosing external names]
 691
 692 freeVarsInDepthFirstOrder :: CoreExpr -> (VarSet, [Id])
 693 freeVarsInDepthFirstOrder e =
 694   case dffvExpr e of
 695     DFFV m -> case m emptyVarSet [] of
 696                 (set,ids,_) -> (set,ids)
 697
 698 newtype DFFV a = DFFV (VarSet -> [Var] -> (VarSet,[Var],a))
 699
 700 instance Monad DFFV where
 701   return a = DFFV $ \set ids -> (set, ids, a)
 702   (DFFV m) >>= k = DFFV $ \set ids ->
 703     case m set ids of
 704        (set',ids',a) -> case k a of
 705                           DFFV f -> f set' ids'
 706
 707 insert :: Var -> DFFV ()
 708 insert v = DFFV $ \ set ids  -> case () of
 709  _ | v `elemVarSet` set -> (set,ids,())
 710    | otherwise          -> (extendVarSet set v, v:ids, ())
 711
 712 dffvExpr :: CoreExpr -> DFFV ()
 713 dffvExpr e = go emptyVarSet e
 714   where
 715     go scope e = case e of
 716       Var v | isLocalId v && not (v `elemVarSet` scope) -> insert v
 717       App e1 e2          -> do go scope e1; go scope e2
 718       Lam v e            -> go (extendVarSet scope v) e
 719       Note _ e           -> go scope e
 720       Cast e _           -> go scope e
 721       Let (NonRec x r) e -> do go scope r; go (extendVarSet scope x) e
 722       Let (Rec prs) e    -> do let scope' = extendVarSetList scope (map fst prs)
 723                                mapM_ (go scope') (map snd prs)
 724                                go scope' e
 725       Case e b _ as      -> do go scope e
 726                                mapM_ (go_alt (extendVarSet scope b)) as
 727       _other             -> return ()
 728
 729     go_alt scope (_,xs,r) = go (extendVarSetList scope xs) r
 730 \end{code}
 731
 732
 733 --------------------------------------------------------------------
 734 --              tidyTopName
 735 -- This is where we set names to local/global based on whether they really are
 736 -- externally visible (see comment at the top of this module).  If the name
 737 -- was previously local, we have to give it a unique occurrence name if
 738 -- we intend to externalise it.
 739
 740 \begin{code}
 741 tidyTopName :: Module -> IORef NameCache -> Maybe Id -> TidyOccEnv
 742             -> Id -> IO (TidyOccEnv, Name)
 743 tidyTopName mod nc_var maybe_ref occ_env id
 744   | global && internal = return (occ_env, localiseName name)
 745
 746   | global && external = return (occ_env, name)
 747         -- Global names are assumed to have been allocated by the renamer,
 748         -- so they already have the "right" unique
 749         -- And it's a system-wide unique too
 750
 751   -- Now we get to the real reason that all this is in the IO Monad:
 752   -- we have to update the name cache in a nice atomic fashion
 753
 754   | local  && internal = do { nc <- readIORef nc_var
 755                             ; let (nc', new_local_name) = mk_new_local nc
 756                             ; writeIORef nc_var nc'
 757                             ; return (occ_env', new_local_name) }
 758         -- Even local, internal names must get a unique occurrence, because
 759         -- if we do -split-objs we externalise the name later, in the code generator
 760         --
 761         -- Similarly, we must make sure it has a system-wide Unique, because
 762         -- the byte-code generator builds a system-wide Name->BCO symbol table
 763
 764   | local  && external = do { nc <- readIORef nc_var
 765                             ; let (nc', new_external_name) = mk_new_external nc
 766                             ; writeIORef nc_var nc'
 767                             ; return (occ_env', new_external_name) }
 768
 769   | otherwise = panic "tidyTopName"
 770   where
 771     name        = idName id
 772     external    = isJust maybe_ref
 773     global      = isExternalName name
 774     local       = not global
 775     internal    = not external
 776     loc         = nameSrcSpan name
 777
 778     old_occ     = nameOccName name
 779     new_occ
 780       | Just ref <- maybe_ref, ref /= id =
 781           mkOccName (occNameSpace old_occ) $
 782              let
 783                  ref_str = occNameString (getOccName ref)
 784                  occ_str = occNameString old_occ
 785              in
 786              case occ_str of
 787                '$':'w':_ -> occ_str
 788                   -- workers: the worker for a function already
 789                   -- includes the occname for its parent, so there's
 790                   -- no need to prepend the referrer.
 791                _other | isSystemName name -> ref_str
 792                       | otherwise         -> ref_str ++ '_' : occ_str
 793                   -- If this name was system-generated, then don't bother
 794                   -- to retain its OccName, just use the referrer.  These
 795                   -- system-generated names will become "f1", "f2", etc. for
 796                   -- a referrer "f".
 797       | otherwise = old_occ
 798
 799     (occ_env', occ') = tidyOccName occ_env new_occ
 800
 801     mk_new_local nc = (nc { nsUniqs = us2 }, mkInternalName uniq occ' loc)
 802                     where
 803                       (us1, us2) = splitUniqSupply (nsUniqs nc)
 804                       uniq       = uniqFromSupply us1
 805
 806     mk_new_external nc = allocateGlobalBinder nc mod occ' loc
 807         -- If we want to externalise a currently-local name, check
 808         -- whether we have already assigned a unique for it.
 809         -- If so, use it; if not, extend the table.
 810         -- All this is done by allcoateGlobalBinder.
 811         -- This is needed when *re*-compiling a module in GHCi; we must
 812         -- use the same name for externally-visible things as we did before.
 813 \end{code}
 814
 815 \begin{code}
 816 findExternalRules :: [CoreBind]
 817                   -> [CoreRule] -- Non-local rules (i.e. ones for imported fns)
 818                   -> UnfoldEnv  -- Ids that are exported, so we need their rules
 819                   -> [CoreRule]
 820   -- The complete rules are gotten by combining
 821   --    a) the non-local rules
 822   --    b) rules embedded in the top-level Ids
 823 findExternalRules binds non_local_rules unfold_env
 824   = filter (not . internal_rule) (non_local_rules ++ local_rules)
 825   where
 826     local_rules  = [ rule
 827                    | id <- bindersOfBinds binds,
 828                      external_id id,
 829                      rule <- idCoreRules id
 830                    ]
 831
 832     internal_rule rule
 833         =  any (not . external_id) (varSetElems (ruleLhsFreeIds rule))
 834                 -- Don't export a rule whose LHS mentions a locally-defined
 835                 --  Id that is completely internal (i.e. not visible to an
 836                 -- importing module)
 837
 838     external_id id
 839       | Just (name,_) <- lookupVarEnv unfold_env id = isExternalName name
 840       | otherwise = False
 841 \end{code}
 842
 843
 844
 845 %************************************************************************
 846 %*                                                                      *
 847 \subsection{Step 2: top-level tidying}
 848 %*                                                                      *
 849 %************************************************************************
 850
 851
 852 \begin{code}
 853 -- TopTidyEnv: when tidying we need to know
 854 --   * nc_var: The NameCache, containing a unique supply and any pre-ordained Names.
 855 --        These may have arisen because the
 856 --        renamer read in an interface file mentioning M.$wf, say,
 857 --        and assigned it unique r77.  If, on this compilation, we've
 858 --        invented an Id whose name is $wf (but with a different unique)
 859 --        we want to rename it to have unique r77, so that we can do easy
 860 --        comparisons with stuff from the interface file
 861 --
 862 --   * occ_env: The TidyOccEnv, which tells us which local occurrences
 863 --     are 'used'
 864 --
 865 --   * subst_env: A Var->Var mapping that substitutes the new Var for the old
 866
 867 tidyTopBinds :: HscEnv
 868              -> UnfoldEnv
 869              -> TidyOccEnv
 870              -> [CoreBind]
 871              -> (TidyEnv, [CoreBind])
 872
 873 tidyTopBinds hsc_env unfold_env init_occ_env binds
 874   = tidy init_env binds
 875   where
 876     init_env = (init_occ_env, emptyVarEnv)
 877
 878     this_pkg = thisPackage (hsc_dflags hsc_env)
 879
 880     tidy env []     = (env, [])
 881     tidy env (b:bs) = let (env1, b')  = tidyTopBind this_pkg unfold_env env b
 882                           (env2, bs') = tidy env1 bs
 883                       in
 884                           (env2, b':bs')
 885
 886 ------------------------
 887 tidyTopBind  :: PackageId
 888              -> UnfoldEnv
 889              -> TidyEnv
 890              -> CoreBind
 891              -> (TidyEnv, CoreBind)
 892
 893 tidyTopBind this_pkg unfold_env (occ_env,subst1) (NonRec bndr rhs)
 894   = (tidy_env2,  NonRec bndr' rhs')
 895   where
 896     Just (name',show_unfold) = lookupVarEnv unfold_env bndr
 897     caf_info      = hasCafRefs this_pkg subst1 (idArity bndr) rhs
 898     (bndr', rhs') = tidyTopPair show_unfold tidy_env2 caf_info name' (bndr, rhs)
 899     subst2        = extendVarEnv subst1 bndr bndr'
 900     tidy_env2     = (occ_env, subst2)
 901
 902 tidyTopBind this_pkg unfold_env (occ_env,subst1) (Rec prs)
 903   = (tidy_env2, Rec prs')
 904   where
 905     prs' = [ tidyTopPair show_unfold tidy_env2 caf_info name' (id,rhs)
 906            | (id,rhs) <- prs,
 907              let (name',show_unfold) =
 908                     expectJust "tidyTopBind" $ lookupVarEnv unfold_env id
 909            ]
 910
 911     subst2    = extendVarEnvList subst1 (bndrs `zip` map fst prs')
 912     tidy_env2 = (occ_env, subst2)
 913
 914     bndrs = map fst prs
 915
 916         -- the CafInfo for a recursive group says whether *any* rhs in
 917         -- the group may refer indirectly to a CAF (because then, they all do).
 918     caf_info
 919         | or [ mayHaveCafRefs (hasCafRefs this_pkg subst1 (idArity bndr) rhs)
 920              | (bndr,rhs) <- prs ] = MayHaveCafRefs
 921         | otherwise                = NoCafRefs
 922
 923 -----------------------------------------------------------
 924 tidyTopPair :: Bool  -- show unfolding
 925             -> TidyEnv  -- The TidyEnv is used to tidy the IdInfo
 926                         -- It is knot-tied: don't look at it!
 927             -> CafInfo
 928             -> Name             -- New name
 929             -> (Id, CoreExpr)   -- Binder and RHS before tidying
 930             -> (Id, CoreExpr)
 931         -- This function is the heart of Step 2
 932         -- The rec_tidy_env is the one to use for the IdInfo
 933         -- It's necessary because when we are dealing with a recursive
 934         -- group, a variable late in the group might be mentioned
 935         -- in the IdInfo of one early in the group
 936
 937 tidyTopPair show_unfold rhs_tidy_env caf_info name' (bndr, rhs)
 938   = (bndr', rhs')
 939   where
 940     bndr' = mkGlobalId details name' ty' idinfo'
 941     details = idDetails bndr    -- Preserve the IdDetails
 942     ty'     = tidyTopType (idType bndr)
 943     rhs'    = tidyExpr rhs_tidy_env rhs
 944     idinfo  = idInfo bndr
 945     idinfo' = tidyTopIdInfo (isExternalName name')
 946                             idinfo unfold_info worker_info
 947                             arity caf_info
 948
 949     unfold_info | show_unfold = mkTopUnfolding rhs'
 950                 | otherwise   = noUnfolding
 951     worker_info = tidyWorker rhs_tidy_env show_unfold (workerInfo idinfo)
 952
 953     -- Usually the Id will have an accurate arity on it, because
 954     -- the simplifier has just run, but not always.
 955     -- One case I found was when the last thing the simplifier
 956     -- did was to let-bind a non-atomic argument and then float
 957     -- it to the top level. So it seems more robust just to
 958     -- fix it here.
 959     arity = exprArity rhs
 960
 961
 962 -- tidyTopIdInfo creates the final IdInfo for top-level
 963 -- binders.  There are two delicate pieces:
 964 --
 965 --  * Arity.  After CoreTidy, this arity must not change any more.
 966 --      Indeed, CorePrep must eta expand where necessary to make
 967 --      the manifest arity equal to the claimed arity.
 968 --
 969 --  * CAF info.  This must also remain valid through to code generation.
 970 --      We add the info here so that it propagates to all
 971 --      occurrences of the binders in RHSs, and hence to occurrences in
 972 --      unfoldings, which are inside Ids imported by GHCi. Ditto RULES.
 973 --      CoreToStg makes use of this when constructing SRTs.
 974 tidyTopIdInfo :: Bool -> IdInfo -> Unfolding
 975               -> WorkerInfo -> ArityInfo -> CafInfo
 976               -> IdInfo
 977 tidyTopIdInfo is_external idinfo unfold_info worker_info arity caf_info
 978   | not is_external     -- For internal Ids (not externally visible)
 979   = vanillaIdInfo       -- we only need enough info for code generation
 980                         -- Arity and strictness info are enough;
 981                         --      c.f. CoreTidy.tidyLetBndr
 982         `setCafInfo`           caf_info
 983         `setArityInfo`         arity
 984         `setAllStrictnessInfo` newStrictnessInfo idinfo
 985
 986   | otherwise           -- Externally-visible Ids get the whole lot
 987   = vanillaIdInfo
 988         `setCafInfo`           caf_info
 989         `setArityInfo`         arity
 990         `setAllStrictnessInfo` newStrictnessInfo idinfo
 991         `setInlinePragInfo`    inlinePragInfo idinfo
 992         `setUnfoldingInfo`     unfold_info
 993         `setWorkerInfo`        worker_info
 994                 -- NB: we throw away the Rules
 995                 -- They have already been extracted by findExternalRules
 996
 997
 998
 999 ------------  Worker  --------------
1000 tidyWorker :: TidyEnv -> Bool -> WorkerInfo -> WorkerInfo
1001 tidyWorker _tidy_env _show_unfold NoWorker
1002   = NoWorker
1003 tidyWorker tidy_env show_unfold (HasWorker work_id wrap_arity)
1004   | show_unfold = HasWorker (tidyVarOcc tidy_env work_id) wrap_arity
1005   | otherwise   = NoWorker
1006     -- NB: do *not* expose the worker if show_unfold is off,
1007     --     because that means this thing is a loop breaker or
1008     --     marked NOINLINE or something like that
1009     -- This is important: if you expose the worker for a loop-breaker
1010     -- then you can make the simplifier go into an infinite loop, because
1011     -- in effect the unfolding is exposed.  See Trac #1709
1012     --
1013     -- You might think that if show_unfold is False, then the thing should
1014     -- not be w/w'd in the first place.  But a legitimate reason is this:
1015     --    the function returns bottom
1016     -- In this case, show_unfold will be false (we don't expose unfoldings
1017     -- for bottoming functions), but we might still have a worker/wrapper
1018     -- split (see Note [Worker-wrapper for bottoming functions] in WorkWrap.lhs
1019 \end{code}
1020
1021 %************************************************************************
1022 %*                                                                      *
1023 \subsection{Figuring out CafInfo for an expression}
1024 %*                                                                      *
1025 %************************************************************************
1026
1027 hasCafRefs decides whether a top-level closure can point into the dynamic heap.
1028 We mark such things as `MayHaveCafRefs' because this information is
1029 used to decide whether a particular closure needs to be referenced
1030 in an SRT or not.
1031
1032 There are two reasons for setting MayHaveCafRefs:
1033         a) The RHS is a CAF: a top-level updatable thunk.
1034         b) The RHS refers to something that MayHaveCafRefs
1035
1036 Possible improvement: In an effort to keep the number of CAFs (and
1037 hence the size of the SRTs) down, we could also look at the expression and
1038 decide whether it requires a small bounded amount of heap, so we can ignore
1039 it as a CAF.  In these cases however, we would need to use an additional
1040 CAF list to keep track of non-collectable CAFs.
1041
1042 \begin{code}
1043 hasCafRefs  :: PackageId -> VarEnv Var -> Arity -> CoreExpr -> CafInfo
1044 hasCafRefs this_pkg p arity expr
1045   | is_caf || mentions_cafs
1046                             = MayHaveCafRefs
1047   | otherwise               = NoCafRefs
1048  where
1049   mentions_cafs = isFastTrue (cafRefs p expr)
1050   is_caf = not (arity > 0 || rhsIsStatic this_pkg expr)
1051
1052   -- NB. we pass in the arity of the expression, which is expected
1053   -- to be calculated by exprArity.  This is because exprArity
1054   -- knows how much eta expansion is going to be done by
1055   -- CorePrep later on, and we don't want to duplicate that
1056   -- knowledge in rhsIsStatic below.
1057
1058 cafRefs :: VarEnv Id -> Expr a -> FastBool
1059 cafRefs p (Var id)
1060         -- imported Ids first:
1061   | not (isLocalId id) = fastBool (mayHaveCafRefs (idCafInfo id))
1062         -- now Ids local to this module:
1063   | otherwise =
1064      case lookupVarEnv p id of
1065         Just id' -> fastBool (mayHaveCafRefs (idCafInfo id'))
1066         Nothing  -> fastBool False
1067
1068 cafRefs _ (Lit _)              = fastBool False
1069 cafRefs p (App f a)            = fastOr (cafRefs p f) (cafRefs p) a
1070 cafRefs p (Lam _ e)            = cafRefs p e
1071 cafRefs p (Let b e)            = fastOr (cafRefss p (rhssOfBind b)) (cafRefs p) e
1072 cafRefs p (Case e _bndr _ alts) = fastOr (cafRefs p e) (cafRefss p) (rhssOfAlts alts)
1073 cafRefs p (Note _n e)          = cafRefs p e
1074 cafRefs p (Cast e _co)         = cafRefs p e
1075 cafRefs _ (Type _)             = fastBool False
1076
1077 cafRefss :: VarEnv Id -> [Expr a] -> FastBool
1078 cafRefss _ []     = fastBool False
1079 cafRefss p (e:es) = fastOr (cafRefs p e) (cafRefss p) es
1080
1081 fastOr :: FastBool -> (a -> FastBool) -> a -> FastBool
1082 -- hack for lazy-or over FastBool.
1083 fastOr a f x = fastBool (isFastTrue a || isFastTrue (f x))
1084 \end{code}