compiler/nativeGen/AsmCodeGen.lhs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow 1993-2004
   4 --
   5 -- This is the top-level module in the native code generator.
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 \begin{code}
  10 module AsmCodeGen ( nativeCodeGen ) where
  11
  12 #include "HsVersions.h"
  13 #include "nativeGen/NCG.h"
  14
  15
  16 #if   alpha_TARGET_ARCH
  17 import Alpha.CodeGen
  18 import Alpha.Regs
  19 import Alpha.RegInfo
  20 import Alpha.Instr
  21
  22 #elif i386_TARGET_ARCH || x86_64_TARGET_ARCH
  23 import X86.CodeGen
  24 import X86.Regs
  25 import X86.Instr
  26 import X86.Ppr
  27
  28 #elif sparc_TARGET_ARCH
  29 import SPARC.CodeGen
  30 import SPARC.CodeGen.Expand
  31 import SPARC.Regs
  32 import SPARC.Instr
  33 import SPARC.Ppr
  34 import SPARC.ShortcutJump
  35
  36 #elif powerpc_TARGET_ARCH
  37 import PPC.CodeGen
  38 import PPC.Cond
  39 import PPC.Regs
  40 import PPC.RegInfo
  41 import PPC.Instr
  42 import PPC.Ppr
  43
  44 #else
  45 #error "AsmCodeGen: unknown architecture"
  46
  47 #endif
  48
  49 import RegAlloc.Liveness
  50 import qualified RegAlloc.Linear.Main           as Linear
  51
  52 import qualified GraphColor                     as Color
  53 import qualified RegAlloc.Graph.Main            as Color
  54 import qualified RegAlloc.Graph.Stats           as Color
  55 import qualified RegAlloc.Graph.TrivColorable   as Color
  56
  57 import TargetReg
  58 import Platform
  59 import Instruction
  60 import PIC
  61 import Reg
  62 import NCGMonad
  63
  64 import BlockId
  65 import CgUtils          ( fixStgRegisters )
  66 import OldCmm
  67 import CmmOpt           ( cmmMiniInline, cmmMachOpFold )
  68 import OldPprCmm
  69 import CLabel
  70
  71 import UniqFM
  72 import Unique           ( Unique, getUnique )
  73 import UniqSupply
  74 import DynFlags
  75 import StaticFlags
  76 import Util
  77 import Config
  78
  79 import Digraph
  80 import qualified Pretty
  81 import BufWrite
  82 import Outputable
  83 import FastString
  84 import UniqSet
  85 import ErrUtils
  86 import Module
  87
  88 -- DEBUGGING ONLY
  89 --import OrdList
  90
  91 import Data.List
  92 import Data.Maybe
  93 import Control.Monad
  94 import System.IO
  95 import Distribution.System
  96
  97 {-
  98 The native-code generator has machine-independent and
  99 machine-dependent modules.
 100
 101 This module ("AsmCodeGen") is the top-level machine-independent
 102 module.  Before entering machine-dependent land, we do some
 103 machine-independent optimisations (defined below) on the
 104 'CmmStmts's.
 105
 106 We convert to the machine-specific 'Instr' datatype with
 107 'cmmCodeGen', assuming an infinite supply of registers.  We then use
 108 a machine-independent register allocator ('regAlloc') to rejoin
 109 reality.  Obviously, 'regAlloc' has machine-specific helper
 110 functions (see about "RegAllocInfo" below).
 111
 112 Finally, we order the basic blocks of the function so as to minimise
 113 the number of jumps between blocks, by utilising fallthrough wherever
 114 possible.
 115
 116 The machine-dependent bits break down as follows:
 117
 118   * ["MachRegs"]  Everything about the target platform's machine
 119     registers (and immediate operands, and addresses, which tend to
 120     intermingle/interact with registers).
 121
 122   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
 123     have a module of its own), plus a miscellany of other things
 124     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
 125
 126   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
 127     machine instructions.
 128
 129   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
 130     a 'Doc').
 131
 132   * ["RegAllocInfo"] In the register allocator, we manipulate
 133     'MRegsState's, which are 'BitSet's, one bit per machine register.
 134     When we want to say something about a specific machine register
 135     (e.g., ``it gets clobbered by this instruction''), we set/unset
 136     its bit.  Obviously, we do this 'BitSet' thing for efficiency
 137     reasons.
 138
 139     The 'RegAllocInfo' module collects together the machine-specific
 140     info needed to do register allocation.
 141
 142    * ["RegisterAlloc"] The (machine-independent) register allocator.
 143 -}
 144
 145 -- -----------------------------------------------------------------------------
 146 -- Top-level of the native codegen
 147
 148 --------------------
 149 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> [RawCmm] -> IO ()
 150 nativeCodeGen dflags h us cmms
 151  = do
 152         let split_cmms  = concat $ map add_split cmms
 153
 154         -- BufHandle is a performance hack.  We could hide it inside
 155         -- Pretty if it weren't for the fact that we do lots of little
 156         -- printDocs here (in order to do codegen in constant space).
 157         bufh <- newBufHandle h
 158         (imports, prof) <- cmmNativeGens dflags bufh us split_cmms [] [] 0
 159         bFlush bufh
 160
 161         let (native, colorStats, linearStats)
 162                 = unzip3 prof
 163
 164         -- dump native code
 165         dumpIfSet_dyn dflags
 166                 Opt_D_dump_asm "Asm code"
 167                 (vcat $ map (docToSDoc . pprNatCmmTop) $ concat native)
 168
 169         -- dump global NCG stats for graph coloring allocator
 170         (case concat $ catMaybes colorStats of
 171           []    -> return ()
 172           stats -> do
 173                 -- build the global register conflict graph
 174                 let graphGlobal
 175                         = foldl Color.union Color.initGraph
 176                         $ [ Color.raGraph stat
 177                                 | stat@Color.RegAllocStatsStart{} <- stats]
 178
 179                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
 180                         $ Color.pprStats stats graphGlobal
 181
 182                 dumpIfSet_dyn dflags
 183                         Opt_D_dump_asm_conflicts "Register conflict graph"
 184                         $ Color.dotGraph
 185                                 targetRegDotColor
 186                                 (Color.trivColorable
 187                                         targetVirtualRegSqueeze
 188                                         targetRealRegSqueeze)
 189                         $ graphGlobal)
 190
 191
 192         -- dump global NCG stats for linear allocator
 193         (case concat $ catMaybes linearStats of
 194                 []      -> return ()
 195                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
 196                                 $ Linear.pprStats (concat native) stats)
 197
 198         -- write out the imports
 199         Pretty.printDoc Pretty.LeftMode h
 200                 $ makeImportsDoc dflags (concat imports)
 201
 202         return  ()
 203
 204  where  add_split (Cmm tops)
 205                 | dopt Opt_SplitObjs dflags = split_marker : tops
 206                 | otherwise                 = tops
 207
 208         split_marker = CmmProc [] mkSplitMarkerLabel (ListGraph [])
 209
 210
 211 -- | Do native code generation on all these cmms.
 212 --
 213 cmmNativeGens :: DynFlags
 214               -> BufHandle
 215               -> UniqSupply
 216               -> [RawCmmTop]
 217               -> [[CLabel]]
 218               -> [ ([NatCmmTop Instr],
 219                    Maybe [Color.RegAllocStats Instr],
 220                    Maybe [Linear.RegAllocStats]) ]
 221               -> Int
 222               -> IO ( [[CLabel]],
 223                       [([NatCmmTop Instr],
 224                       Maybe [Color.RegAllocStats Instr],
 225                       Maybe [Linear.RegAllocStats])] )
 226
 227 cmmNativeGens _ _ _ [] impAcc profAcc _
 228         = return (reverse impAcc, reverse profAcc)
 229
 230 cmmNativeGens dflags h us (cmm : cmms) impAcc profAcc count
 231  = do
 232         (us', native, imports, colorStats, linearStats)
 233                 <- cmmNativeGen dflags us cmm count
 234
 235         Pretty.bufLeftRender h
 236                 $ {-# SCC "pprNativeCode" #-} Pretty.vcat $ map pprNatCmmTop native
 237
 238            -- carefully evaluate this strictly.  Binding it with 'let'
 239            -- and then using 'seq' doesn't work, because the let
 240            -- apparently gets inlined first.
 241         lsPprNative <- return $!
 242                 if  dopt Opt_D_dump_asm       dflags
 243                  || dopt Opt_D_dump_asm_stats dflags
 244                         then native
 245                         else []
 246
 247         count' <- return $! count + 1;
 248
 249         -- force evaulation all this stuff to avoid space leaks
 250         seqString (showSDoc $ vcat $ map ppr imports) `seq` return ()
 251
 252         cmmNativeGens dflags h us' cmms
 253                         (imports : impAcc)
 254                         ((lsPprNative, colorStats, linearStats) : profAcc)
 255                         count'
 256
 257  where  seqString []            = ()
 258         seqString (x:xs)        = x `seq` seqString xs `seq` ()
 259
 260
 261 -- | Complete native code generation phase for a single top-level chunk of Cmm.
 262 --      Dumping the output of each stage along the way.
 263 --      Global conflict graph and NGC stats
 264 cmmNativeGen
 265         :: DynFlags
 266         -> UniqSupply
 267         -> RawCmmTop                                    -- ^ the cmm to generate code for
 268         -> Int                                          -- ^ sequence number of this top thing
 269         -> IO   ( UniqSupply
 270                 , [NatCmmTop Instr]                     -- native code
 271                 , [CLabel]                              -- things imported by this cmm
 272                 , Maybe [Color.RegAllocStats Instr]     -- stats for the coloring register allocator
 273                 , Maybe [Linear.RegAllocStats])         -- stats for the linear register allocators
 274
 275 cmmNativeGen dflags us cmm count
 276  = do
 277
 278         -- rewrite assignments to global regs
 279         let fixed_cmm =
 280                 {-# SCC "fixStgRegisters" #-}
 281                 fixStgRegisters cmm
 282
 283         -- cmm to cmm optimisations
 284         let (opt_cmm, imports) =
 285                 {-# SCC "cmmToCmm" #-}
 286                 cmmToCmm dflags fixed_cmm
 287
 288         dumpIfSet_dyn dflags
 289                 Opt_D_dump_opt_cmm "Optimised Cmm"
 290                 (pprCmm $ Cmm [opt_cmm])
 291
 292         -- generate native code from cmm
 293         let ((native, lastMinuteImports), usGen) =
 294                 {-# SCC "genMachCode" #-}
 295                 initUs us $ genMachCode dflags opt_cmm
 296
 297         dumpIfSet_dyn dflags
 298                 Opt_D_dump_asm_native "Native code"
 299                 (vcat $ map (docToSDoc . pprNatCmmTop) native)
 300
 301         -- tag instructions with register liveness information
 302         let (withLiveness, usLive) =
 303                 {-# SCC "regLiveness" #-}
 304                 initUs usGen
 305                         $ mapUs regLiveness
 306                         $ map natCmmTopToLive native
 307
 308         dumpIfSet_dyn dflags
 309                 Opt_D_dump_asm_liveness "Liveness annotations added"
 310                 (vcat $ map ppr withLiveness)
 311
 312         -- allocate registers
 313         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
 314          if ( dopt Opt_RegsGraph dflags
 315            || dopt Opt_RegsIterative dflags)
 316           then do
 317                 -- the regs usable for allocation
 318                 let (alloc_regs :: UniqFM (UniqSet RealReg))
 319                         = foldr (\r -> plusUFM_C unionUniqSets
 320                                         $ unitUFM (targetClassOfRealReg r) (unitUniqSet r))
 321                                 emptyUFM
 322                         $ allocatableRegs
 323
 324                 -- do the graph coloring register allocation
 325                 let ((alloced, regAllocStats), usAlloc)
 326                         = {-# SCC "RegAlloc" #-}
 327                           initUs usLive
 328                           $ Color.regAlloc
 329                                 dflags
 330                                 alloc_regs
 331                                 (mkUniqSet [0..maxSpillSlots])
 332                                 withLiveness
 333
 334                 -- dump out what happened during register allocation
 335                 dumpIfSet_dyn dflags
 336                         Opt_D_dump_asm_regalloc "Registers allocated"
 337                         (vcat $ map (docToSDoc . pprNatCmmTop) alloced)
 338
 339                 dumpIfSet_dyn dflags
 340                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
 341                         (vcat   $ map (\(stage, stats)
 342                                         -> text "# --------------------------"
 343                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
 344                                         $$ ppr stats)
 345                                 $ zip [0..] regAllocStats)
 346
 347                 let mPprStats =
 348                         if dopt Opt_D_dump_asm_stats dflags
 349                          then Just regAllocStats else Nothing
 350
 351                 -- force evaluation of the Maybe to avoid space leak
 352                 mPprStats `seq` return ()
 353
 354                 return  ( alloced, usAlloc
 355                         , mPprStats
 356                         , Nothing)
 357
 358           else do
 359                 -- do linear register allocation
 360                 let ((alloced, regAllocStats), usAlloc)
 361                         = {-# SCC "RegAlloc" #-}
 362                           initUs usLive
 363                           $ liftM unzip
 364                           $ mapUs Linear.regAlloc withLiveness
 365
 366                 dumpIfSet_dyn dflags
 367                         Opt_D_dump_asm_regalloc "Registers allocated"
 368                         (vcat $ map (docToSDoc . pprNatCmmTop) alloced)
 369
 370                 let mPprStats =
 371                         if dopt Opt_D_dump_asm_stats dflags
 372                          then Just (catMaybes regAllocStats) else Nothing
 373
 374                 -- force evaluation of the Maybe to avoid space leak
 375                 mPprStats `seq` return ()
 376
 377                 return  ( alloced, usAlloc
 378                         , Nothing
 379                         , mPprStats)
 380
 381         ---- generate jump tables
 382         let tabled      =
 383                 {-# SCC "generateJumpTables" #-}
 384                 alloced ++ generateJumpTables alloced
 385
 386         ---- shortcut branches
 387         let shorted     =
 388                 {-# SCC "shortcutBranches" #-}
 389                 shortcutBranches dflags tabled
 390
 391         ---- sequence blocks
 392         let sequenced   =
 393                 {-# SCC "sequenceBlocks" #-}
 394                 map sequenceTop shorted
 395
 396         ---- x86fp_kludge
 397         let kludged =
 398 #if i386_TARGET_ARCH
 399                 {-# SCC "x86fp_kludge" #-}
 400                 map x86fp_kludge sequenced
 401 #else
 402                 sequenced
 403 #endif
 404
 405         ---- expansion of SPARC synthetic instrs
 406 #if sparc_TARGET_ARCH
 407         let expanded =
 408                 {-# SCC "sparc_expand" #-}
 409                 map expandTop kludged
 410
 411         dumpIfSet_dyn dflags
 412                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
 413                 (vcat $ map (docToSDoc . pprNatCmmTop) expanded)
 414 #else
 415         let expanded =
 416                 kludged
 417 #endif
 418
 419         return  ( usAlloc
 420                 , expanded
 421                 , lastMinuteImports ++ imports
 422                 , ppr_raStatsColor
 423                 , ppr_raStatsLinear)
 424
 425
 426 #if i386_TARGET_ARCH
 427 x86fp_kludge :: NatCmmTop Instr -> NatCmmTop Instr
 428 x86fp_kludge top@(CmmData _ _) = top
 429 x86fp_kludge (CmmProc info lbl (ListGraph code)) =
 430         CmmProc info lbl (ListGraph $ i386_insert_ffrees code)
 431 #endif
 432
 433
 434 -- | Build a doc for all the imports.
 435 --
 436 makeImportsDoc :: DynFlags -> [CLabel] -> Pretty.Doc
 437 makeImportsDoc dflags imports
 438  = dyld_stubs imports
 439
 440 #if HAVE_SUBSECTIONS_VIA_SYMBOLS
 441                 -- On recent versions of Darwin, the linker supports
 442                 -- dead-stripping of code and data on a per-symbol basis.
 443                 -- There's a hack to make this work in PprMach.pprNatCmmTop.
 444             Pretty.$$ Pretty.text ".subsections_via_symbols"
 445 #endif
 446 #if HAVE_GNU_NONEXEC_STACK
 447                 -- On recent GNU ELF systems one can mark an object file
 448                 -- as not requiring an executable stack. If all objects
 449                 -- linked into a program have this note then the program
 450                 -- will not use an executable stack, which is good for
 451                 -- security. GHC generated code does not need an executable
 452                 -- stack so add the note in:
 453             Pretty.$$ Pretty.text ".section .note.GNU-stack,\"\",@progbits"
 454 #endif
 455 #if !defined(darwin_TARGET_OS)
 456                 -- And just because every other compiler does, lets stick in
 457                 -- an identifier directive: .ident "GHC x.y.z"
 458             Pretty.$$ let compilerIdent = Pretty.text "GHC" Pretty.<+>
 459                                           Pretty.text cProjectVersion
 460                        in Pretty.text ".ident" Pretty.<+>
 461                           Pretty.doubleQuotes compilerIdent
 462 #endif
 463
 464  where
 465         -- Generate "symbol stubs" for all external symbols that might
 466         -- come from a dynamic library.
 467         dyld_stubs :: [CLabel] -> Pretty.Doc
 468 {-      dyld_stubs imps = Pretty.vcat $ map pprDyldSymbolStub $
 469                                     map head $ group $ sort imps-}
 470
 471         arch    = platformArch  $ targetPlatform dflags
 472         os      = platformOS    $ targetPlatform dflags
 473
 474         -- (Hack) sometimes two Labels pretty-print the same, but have
 475         -- different uniques; so we compare their text versions...
 476         dyld_stubs imps
 477                 | needImportedSymbols arch os
 478                 = Pretty.vcat $
 479                         (pprGotDeclaration arch os :) $
 480                         map ( pprImportedSymbol arch os . fst . head) $
 481                         groupBy (\(_,a) (_,b) -> a == b) $
 482                         sortBy (\(_,a) (_,b) -> compare a b) $
 483                         map doPpr $
 484                         imps
 485                 | otherwise
 486                 = Pretty.empty
 487
 488         doPpr lbl = (lbl, Pretty.render $ pprCLabel lbl astyle)
 489         astyle = mkCodeStyle AsmStyle
 490
 491
 492 -- -----------------------------------------------------------------------------
 493 -- Sequencing the basic blocks
 494
 495 -- Cmm BasicBlocks are self-contained entities: they always end in a
 496 -- jump, either non-local or to another basic block in the same proc.
 497 -- In this phase, we attempt to place the basic blocks in a sequence
 498 -- such that as many of the local jumps as possible turn into
 499 -- fallthroughs.
 500
 501 sequenceTop
 502         :: NatCmmTop Instr
 503         -> NatCmmTop Instr
 504
 505 sequenceTop top@(CmmData _ _) = top
 506 sequenceTop (CmmProc info lbl (ListGraph blocks)) =
 507   CmmProc info lbl (ListGraph $ makeFarBranches $ sequenceBlocks blocks)
 508
 509 -- The algorithm is very simple (and stupid): we make a graph out of
 510 -- the blocks where there is an edge from one block to another iff the
 511 -- first block ends by jumping to the second.  Then we topologically
 512 -- sort this graph.  Then traverse the list: for each block, we first
 513 -- output the block, then if it has an out edge, we move the
 514 -- destination of the out edge to the front of the list, and continue.
 515
 516 -- FYI, the classic layout for basic blocks uses postorder DFS; this
 517 -- algorithm is implemented in Hoopl.
 518
 519 sequenceBlocks
 520         :: Instruction instr
 521         => [NatBasicBlock instr]
 522         -> [NatBasicBlock instr]
 523
 524 sequenceBlocks [] = []
 525 sequenceBlocks (entry:blocks) =
 526   seqBlocks (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
 527   -- the first block is the entry point ==> it must remain at the start.
 528
 529
 530 sccBlocks
 531         :: Instruction instr
 532         => [NatBasicBlock instr]
 533         -> [SCC ( NatBasicBlock instr
 534                 , Unique
 535                 , [Unique])]
 536
 537 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
 538
 539 -- we're only interested in the last instruction of
 540 -- the block, and only if it has a single destination.
 541 getOutEdges
 542         :: Instruction instr
 543         => [instr] -> [Unique]
 544
 545 getOutEdges instrs
 546         = case jumpDestsOfInstr (last instrs) of
 547                 [one] -> [getUnique one]
 548                 _many -> []
 549
 550 mkNode :: (Instruction t)
 551        => GenBasicBlock t
 552        -> (GenBasicBlock t, Unique, [Unique])
 553 mkNode block@(BasicBlock id instrs) = (block, getUnique id, getOutEdges instrs)
 554
 555 seqBlocks :: (Eq t) => [(GenBasicBlock t1, t, [t])] -> [GenBasicBlock t1]
 556 seqBlocks [] = []
 557 seqBlocks ((block,_,[]) : rest)
 558   = block : seqBlocks rest
 559 seqBlocks ((block@(BasicBlock id instrs),_,[next]) : rest)
 560   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks rest'
 561   | otherwise       = block : seqBlocks rest'
 562   where
 563         (can_fallthrough, rest') = reorder next [] rest
 564           -- TODO: we should do a better job for cycles; try to maximise the
 565           -- fallthroughs within a loop.
 566 seqBlocks _ = panic "AsmCodegen:seqBlocks"
 567
 568 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
 569 reorder  _ accum [] = (False, reverse accum)
 570 reorder id accum (b@(block,id',out) : rest)
 571   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
 572   | otherwise  = reorder id (b:accum) rest
 573
 574
 575 -- -----------------------------------------------------------------------------
 576 -- Making far branches
 577
 578 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
 579 -- big, we have to work around this limitation.
 580
 581 makeFarBranches
 582         :: [NatBasicBlock Instr]
 583         -> [NatBasicBlock Instr]
 584
 585 #if powerpc_TARGET_ARCH
 586 makeFarBranches blocks
 587     | last blockAddresses < nearLimit = blocks
 588     | otherwise = zipWith handleBlock blockAddresses blocks
 589     where
 590         blockAddresses = scanl (+) 0 $ map blockLen blocks
 591         blockLen (BasicBlock _ instrs) = length instrs
 592
 593         handleBlock addr (BasicBlock id instrs)
 594                 = BasicBlock id (zipWith makeFar [addr..] instrs)
 595
 596         makeFar _ (BCC ALWAYS tgt) = BCC ALWAYS tgt
 597         makeFar addr (BCC cond tgt)
 598             | abs (addr - targetAddr) >= nearLimit
 599             = BCCFAR cond tgt
 600             | otherwise
 601             = BCC cond tgt
 602             where Just targetAddr = lookupUFM blockAddressMap tgt
 603         makeFar _ other            = other
 604
 605         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
 606                          -- distance, as we have a few pseudo-insns that are
 607                          -- pretty-printed as multiple instructions,
 608                          -- and it's just not worth the effort to calculate
 609                          -- things exactly
 610
 611         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
 612 #else
 613 makeFarBranches = id
 614 #endif
 615
 616 -- -----------------------------------------------------------------------------
 617 -- Generate jump tables
 618
 619 -- Analyzes all native code and generates data sections for all jump
 620 -- table instructions.
 621 generateJumpTables
 622         :: [NatCmmTop Instr] -> [NatCmmTop Instr]
 623 generateJumpTables xs = concatMap f xs
 624     where f (CmmProc _ _ (ListGraph xs)) = concatMap g xs
 625           f _ = []
 626           g (BasicBlock _ xs) = catMaybes (map generateJumpTableForInstr xs)
 627
 628 -- -----------------------------------------------------------------------------
 629 -- Shortcut branches
 630
 631 shortcutBranches
 632         :: DynFlags
 633         -> [NatCmmTop Instr]
 634         -> [NatCmmTop Instr]
 635
 636 shortcutBranches dflags tops
 637   | optLevel dflags < 1 = tops    -- only with -O or higher
 638   | otherwise           = map (apply_mapping mapping) tops'
 639   where
 640     (tops', mappings) = mapAndUnzip build_mapping tops
 641     mapping = foldr plusUFM emptyUFM mappings
 642
 643 build_mapping :: GenCmmTop d t (ListGraph Instr)
 644               -> (GenCmmTop d t (ListGraph Instr), UniqFM JumpDest)
 645 build_mapping top@(CmmData _ _) = (top, emptyUFM)
 646 build_mapping (CmmProc info lbl (ListGraph []))
 647   = (CmmProc info lbl (ListGraph []), emptyUFM)
 648 build_mapping (CmmProc info lbl (ListGraph (head:blocks)))
 649   = (CmmProc info lbl (ListGraph (head:others)), mapping)
 650         -- drop the shorted blocks, but don't ever drop the first one,
 651         -- because it is pointed to by a global label.
 652   where
 653     -- find all the blocks that just consist of a jump that can be
 654     -- shorted.
 655     -- Don't completely eliminate loops here -- that can leave a dangling jump!
 656     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
 657     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
 658         | Just (DestBlockId dest) <- canShortcut insn,
 659           (setMember dest s) || dest == id -- loop checks
 660         = (s, shortcut_blocks, b : others)
 661     split (s, shortcut_blocks, others) (BasicBlock id [insn])
 662         | Just dest <- canShortcut insn
 663         = (setInsert id s, (id,dest) : shortcut_blocks, others)
 664     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
 665
 666
 667     -- build a mapping from BlockId to JumpDest for shorting branches
 668     mapping = foldl add emptyUFM shortcut_blocks
 669     add ufm (id,dest) = addToUFM ufm id dest
 670
 671 apply_mapping :: UniqFM JumpDest
 672               -> GenCmmTop CmmStatic h (ListGraph Instr)
 673               -> GenCmmTop CmmStatic h (ListGraph Instr)
 674 apply_mapping ufm (CmmData sec statics)
 675   = CmmData sec (map (shortcutStatic (lookupUFM ufm)) statics)
 676   -- we need to get the jump tables, so apply the mapping to the entries
 677   -- of a CmmData too.
 678 apply_mapping ufm (CmmProc info lbl (ListGraph blocks))
 679   = CmmProc info lbl (ListGraph $ map short_bb blocks)
 680   where
 681     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
 682     short_insn i = shortcutJump (lookupUFM ufm) i
 683                  -- shortcutJump should apply the mapping repeatedly,
 684                  -- just in case we can short multiple branches.
 685
 686 -- -----------------------------------------------------------------------------
 687 -- Instruction selection
 688
 689 -- Native code instruction selection for a chunk of stix code.  For
 690 -- this part of the computation, we switch from the UniqSM monad to
 691 -- the NatM monad.  The latter carries not only a Unique, but also an
 692 -- Int denoting the current C stack pointer offset in the generated
 693 -- code; this is needed for creating correct spill offsets on
 694 -- architectures which don't offer, or for which it would be
 695 -- prohibitively expensive to employ, a frame pointer register.  Viz,
 696 -- x86.
 697
 698 -- The offset is measured in bytes, and indicates the difference
 699 -- between the current (simulated) C stack-ptr and the value it was at
 700 -- the beginning of the block.  For stacks which grow down, this value
 701 -- should be either zero or negative.
 702
 703 -- Switching between the two monads whilst carrying along the same
 704 -- Unique supply breaks abstraction.  Is that bad?
 705
 706 genMachCode
 707         :: DynFlags
 708         -> RawCmmTop
 709         -> UniqSM
 710                 ( [NatCmmTop Instr]
 711                 , [CLabel])
 712
 713 genMachCode dflags cmm_top
 714   = do  { initial_us <- getUs
 715         ; let initial_st           = mkNatM_State initial_us 0 dflags
 716               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen dflags cmm_top)
 717               final_delta          = natm_delta final_st
 718               final_imports        = natm_imports final_st
 719         ; if   final_delta == 0
 720           then return (new_tops, final_imports)
 721           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
 722     }
 723
 724 -- -----------------------------------------------------------------------------
 725 -- Generic Cmm optimiser
 726
 727 {-
 728 Here we do:
 729
 730   (a) Constant folding
 731   (b) Simple inlining: a temporary which is assigned to and then
 732       used, once, can be shorted.
 733   (c) Position independent code and dynamic linking
 734         (i)  introduce the appropriate indirections
 735              and position independent refs
 736         (ii) compile a list of imported symbols
 737
 738 Ideas for other things we could do (ToDo):
 739
 740   - shortcut jumps-to-jumps
 741   - eliminate dead code blocks
 742   - simple CSE: if an expr is assigned to a temp, then replace later occs of
 743     that expr with the temp, until the expr is no longer valid (can push through
 744     temp assignments, and certain assigns to mem...)
 745 -}
 746
 747 cmmToCmm :: DynFlags -> RawCmmTop -> (RawCmmTop, [CLabel])
 748 cmmToCmm _ top@(CmmData _ _) = (top, [])
 749 cmmToCmm dflags (CmmProc info lbl (ListGraph blocks)) = runCmmOpt dflags $ do
 750   blocks' <- mapM cmmBlockConFold (cmmMiniInline blocks)
 751   return $ CmmProc info lbl (ListGraph blocks')
 752
 753 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
 754
 755 instance Monad CmmOptM where
 756   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
 757   (CmmOptM f) >>= g =
 758     CmmOptM $ \(imports, dflags) ->
 759                 case f (imports, dflags) of
 760                   (# x, imports' #) ->
 761                     case g x of
 762                       CmmOptM g' -> g' (imports', dflags)
 763
 764 addImportCmmOpt :: CLabel -> CmmOptM ()
 765 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
 766
 767 getDynFlagsCmmOpt :: CmmOptM DynFlags
 768 getDynFlagsCmmOpt = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
 769
 770 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
 771 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
 772                         (# result, imports #) -> (result, imports)
 773
 774 cmmBlockConFold :: CmmBasicBlock -> CmmOptM CmmBasicBlock
 775 cmmBlockConFold (BasicBlock id stmts) = do
 776   stmts' <- mapM cmmStmtConFold stmts
 777   return $ BasicBlock id stmts'
 778
 779 cmmStmtConFold :: CmmStmt -> CmmOptM CmmStmt
 780 cmmStmtConFold stmt
 781    = case stmt of
 782         CmmAssign reg src
 783            -> do src' <- cmmExprConFold DataReference src
 784                  return $ case src' of
 785                    CmmReg reg' | reg == reg' -> CmmNop
 786                    new_src -> CmmAssign reg new_src
 787
 788         CmmStore addr src
 789            -> do addr' <- cmmExprConFold DataReference addr
 790                  src'  <- cmmExprConFold DataReference src
 791                  return $ CmmStore addr' src'
 792
 793         CmmJump addr regs
 794            -> do addr' <- cmmExprConFold JumpReference addr
 795                  return $ CmmJump addr' regs
 796
 797         CmmCall target regs args srt returns
 798            -> do target' <- case target of
 799                               CmmCallee e conv -> do
 800                                 e' <- cmmExprConFold CallReference e
 801                                 return $ CmmCallee e' conv
 802                               other -> return other
 803                  args' <- mapM (\(CmmHinted arg hint) -> do
 804                                   arg' <- cmmExprConFold DataReference arg
 805                                   return (CmmHinted arg' hint)) args
 806                  return $ CmmCall target' regs args' srt returns
 807
 808         CmmCondBranch test dest
 809            -> do test' <- cmmExprConFold DataReference test
 810                  return $ case test' of
 811                    CmmLit (CmmInt 0 _) ->
 812                      CmmComment (mkFastString ("deleted: " ++
 813                                         showSDoc (pprStmt stmt)))
 814
 815                    CmmLit (CmmInt _ _) -> CmmBranch dest
 816                    _other -> CmmCondBranch test' dest
 817
 818         CmmSwitch expr ids
 819            -> do expr' <- cmmExprConFold DataReference expr
 820                  return $ CmmSwitch expr' ids
 821
 822         other
 823            -> return other
 824
 825
 826 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
 827 cmmExprConFold referenceKind expr
 828    = case expr of
 829         CmmLoad addr rep
 830            -> do addr' <- cmmExprConFold DataReference addr
 831                  return $ CmmLoad addr' rep
 832
 833         CmmMachOp mop args
 834            -- For MachOps, we first optimize the children, and then we try
 835            -- our hand at some constant-folding.
 836            -> do args' <- mapM (cmmExprConFold DataReference) args
 837                  return $ cmmMachOpFold mop args'
 838
 839         CmmLit (CmmLabel lbl)
 840            -> do
 841                 dflags <- getDynFlagsCmmOpt
 842                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
 843         CmmLit (CmmLabelOff lbl off)
 844            -> do
 845                  dflags <- getDynFlagsCmmOpt
 846                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
 847                  return $ cmmMachOpFold (MO_Add wordWidth) [
 848                      dynRef,
 849                      (CmmLit $ CmmInt (fromIntegral off) wordWidth)
 850                    ]
 851
 852         -- On powerpc (non-PIC), it's easier to jump directly to a label than
 853         -- to use the register table, so we replace these registers
 854         -- with the corresponding labels:
 855         CmmReg (CmmGlobal EagerBlackholeInfo)
 856           | cTargetArch == PPC && not opt_PIC
 857           -> cmmExprConFold referenceKind $
 858              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
 859         CmmReg (CmmGlobal GCEnter1)
 860           | cTargetArch == PPC && not opt_PIC
 861           -> cmmExprConFold referenceKind $
 862              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1")))
 863         CmmReg (CmmGlobal GCFun)
 864           | cTargetArch == PPC && not opt_PIC
 865           -> cmmExprConFold referenceKind $
 866              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
 867
 868         other
 869            -> return other
 870
 871 \end{code}
 872