compiler/profiling/CostCentre.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[CostCentre]{The @CostCentre@ data type}
   5
   6 \begin{code}
   7 {-# OPTIONS -fno-warn-incomplete-patterns #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  12 -- for details
  13
  14 module CostCentre (
  15         CostCentre(..), CcName, IsDupdCC(..), IsCafCC(..),
  16                 -- All abstract except to friend: ParseIface.y
  17
  18         CostCentreStack,
  19         CollectedCCs,
  20         noCCS, subsumedCCS, currentCCS, overheadCCS, dontCareCCS,
  21         noCostCentre, noCCAttached,
  22         noCCSAttached, isCurrentCCS,  isSubsumedCCS, currentOrSubsumedCCS,
  23         isDerivedFromCurrentCCS, maybeSingletonCCS,
  24         decomposeCCS,
  25
  26         mkUserCC, mkAutoCC, mkAllCafsCC,
  27         mkSingletonCCS, dupifyCC, pushCCOnCCS,
  28         isCafCCS, isCafCC,
  29         isSccCountCostCentre,
  30         sccAbleCostCentre,
  31         ccFromThisModule,
  32
  33         pprCostCentreCore,
  34         costCentreUserName,
  35
  36         cmpCostCentre   -- used for removing dups in a list
  37     ) where
  38
  39 import Var              ( Id )
  40 import Name
  41 import Module           ( Module )
  42 import Unique
  43 import Outputable
  44 import FastTypes
  45 import FastString
  46 import Util             ( thenCmp )
  47 \end{code}
  48
  49 A Cost Centre Stack is something that can be attached to a closure.
  50 This is either:
  51
  52         - the current cost centre stack (CCCS)
  53         - a pre-defined cost centre stack (there are several
  54           pre-defined CCSs, see below).
  55
  56 \begin{code}
  57 data CostCentreStack
  58   = NoCCS
  59
  60   | CurrentCCS          -- Pinned on a let(rec)-bound
  61                         -- thunk/function/constructor, this says that the
  62                         -- cost centre to be attached to the object, when it
  63                         -- is allocated, is whatever is in the
  64                         -- current-cost-centre-stack register.
  65
  66   | SubsumedCCS         -- Cost centre stack for top-level subsumed functions
  67                         -- (CAFs get an AllCafsCC).
  68                         -- Its execution costs get subsumed into the caller.
  69                         -- This guy is *only* ever pinned on static closures,
  70                         -- and is *never* the cost centre for an SCC construct.
  71
  72   | OverheadCCS         -- We charge costs due to the profiling-system
  73                         -- doing its work to "overhead".
  74                         --
  75                         -- Objects whose CCS is "Overhead"
  76                         -- have their *allocation* charged to "overhead",
  77                         -- but have the current CCS put into the object
  78                         -- itself.
  79
  80                         -- For example, if we transform "f g" to "let
  81                         -- g' = g in f g'" (so that something about
  82                         -- profiling works better...), then we charge
  83                         -- the *allocation* of g' to OverheadCCS, but
  84                         -- we put the cost-centre of the call to f
  85                         -- (i.e., current CCS) into the g' object.  When
  86                         -- g' is entered, the CCS of the call
  87                         -- to f will be set.
  88
  89   | DontCareCCS         -- We need a CCS to stick in static closures
  90                         -- (for data), but we *don't* expect them to
  91                         -- accumulate any costs.  But we still need
  92                         -- the placeholder.  This CCS is it.
  93
  94   | PushCC CostCentre CostCentreStack
  95                 -- These are used during code generation as the CCSs
  96                 -- attached to closures.  A PushCC never appears as
  97                 -- the argument to an _scc_.
  98                 --
  99                 -- The tail (2nd argument) is either NoCCS, indicating
 100                 -- a staticly allocated CCS, or CurrentCCS indicating
 101                 -- a dynamically created CCS.  We only support
 102                 -- statically allocated *singleton* CCSs at the
 103                 -- moment, for the purposes of initialising the CCS
 104                 -- field of a CAF.
 105
 106   deriving (Eq, Ord)    -- needed for Ord on CLabel
 107 \end{code}
 108
 109 A Cost Centre is the argument of an _scc_ expression.
 110
 111 \begin{code}
 112 data CostCentre
 113   = NoCostCentre        -- Having this constructor avoids having
 114                         -- to use "Maybe CostCentre" all the time.
 115
 116   | NormalCC {
 117                 cc_name :: CcName,      -- Name of the cost centre itself
 118                 cc_mod  :: Module,      -- Name of module defining this CC.
 119                 cc_is_dupd :: IsDupdCC, -- see below
 120                 cc_is_caf  :: IsCafCC   -- see below
 121     }
 122
 123   | AllCafsCC {
 124                 cc_mod  :: Module       -- Name of module defining this CC.
 125     }
 126
 127 type CcName = FastString
 128
 129 data IsDupdCC
 130   = OriginalCC  -- This says how the CC is *used*.  Saying that
 131   | DupdCC              -- it is DupdCC doesn't make it a different
 132                         -- CC, just that it a sub-expression which has
 133                         -- been moved ("dupd") into a different scope.
 134                         --
 135                         -- The point about a dupd SCC is that we don't
 136                         -- count entries to it, because it's not the
 137                         -- "original" one.
 138                         --
 139                         -- In the papers, it's called "SCCsub",
 140                         --  i.e. SCCsub CC == SCC DupdCC,
 141                         -- but we are trying to avoid confusion between
 142                         -- "subd" and "subsumed".  So we call the former
 143                         -- "dupd".
 144
 145 data IsCafCC = CafCC | NotCafCC
 146
 147 -- synonym for triple which describes the cost centre info in the generated
 148 -- code for a module.
 149 type CollectedCCs
 150   = ( [CostCentre]       -- local cost-centres that need to be decl'd
 151     , [CostCentre]       -- "extern" cost-centres
 152     , [CostCentreStack]  -- pre-defined "singleton" cost centre stacks
 153     )
 154 \end{code}
 155
 156 WILL: Would there be any merit to recording ``I am now using a
 157 cost-centre from another module''?  I don't know if this would help a
 158 user; it might be interesting to us to know how much computation is
 159 being moved across module boundaries.
 160
 161 SIMON: Maybe later...
 162
 163 \begin{code}
 164 noCCS, subsumedCCS, currentCCS, overheadCCS, dontCareCCS :: CostCentreStack
 165
 166 noCCS                   = NoCCS
 167 subsumedCCS             = SubsumedCCS
 168 currentCCS              = CurrentCCS
 169 overheadCCS             = OverheadCCS
 170 dontCareCCS             = DontCareCCS
 171
 172 noCostCentre :: CostCentre
 173 noCostCentre            = NoCostCentre
 174 \end{code}
 175
 176 Predicates on Cost-Centre Stacks
 177
 178 \begin{code}
 179 noCCSAttached :: CostCentreStack -> Bool
 180 noCCSAttached NoCCS                     = True
 181 noCCSAttached _                         = False
 182
 183 noCCAttached :: CostCentre -> Bool
 184 noCCAttached NoCostCentre               = True
 185 noCCAttached _                          = False
 186
 187 isCurrentCCS :: CostCentreStack -> Bool
 188 isCurrentCCS CurrentCCS                 = True
 189 isCurrentCCS _                          = False
 190
 191 isSubsumedCCS :: CostCentreStack -> Bool
 192 isSubsumedCCS SubsumedCCS               = True
 193 isSubsumedCCS _                         = False
 194
 195 isCafCCS :: CostCentreStack -> Bool
 196 isCafCCS (PushCC cc NoCCS)              = isCafCC cc
 197 isCafCCS _                              = False
 198
 199 isDerivedFromCurrentCCS :: CostCentreStack -> Bool
 200 isDerivedFromCurrentCCS CurrentCCS      = True
 201 isDerivedFromCurrentCCS (PushCC _ ccs)  = isDerivedFromCurrentCCS ccs
 202 isDerivedFromCurrentCCS _               = False
 203
 204 currentOrSubsumedCCS :: CostCentreStack -> Bool
 205 currentOrSubsumedCCS SubsumedCCS        = True
 206 currentOrSubsumedCCS CurrentCCS         = True
 207 currentOrSubsumedCCS _                  = False
 208
 209 maybeSingletonCCS :: CostCentreStack -> Maybe CostCentre
 210 maybeSingletonCCS (PushCC cc NoCCS)     = Just cc
 211 maybeSingletonCCS _                     = Nothing
 212 \end{code}
 213
 214 Building cost centres
 215
 216 \begin{code}
 217 mkUserCC :: FastString -> Module -> CostCentre
 218 mkUserCC cc_name mod
 219   = NormalCC { cc_name = cc_name, cc_mod =  mod,
 220                cc_is_dupd = OriginalCC, cc_is_caf = NotCafCC {-might be changed-}
 221     }
 222
 223 mkAutoCC :: Id -> Module -> IsCafCC -> CostCentre
 224 mkAutoCC id mod is_caf
 225   = NormalCC { cc_name = str, cc_mod =  mod,
 226                cc_is_dupd = OriginalCC, cc_is_caf = is_caf
 227     }
 228   where
 229         name = getName id
 230         -- beware: only external names are guaranteed to have unique
 231         -- Occnames.  If the name is not external, we must append its
 232         -- Unique.
 233         -- See bug #249, tests prof001, prof002,  also #2411
 234         str | isExternalName name = occNameFS (getOccName id)
 235             | otherwise           = mkFastString $ showSDoc $
 236                                       ftext (occNameFS (getOccName id))
 237                                       <> char '_' <> pprUnique (getUnique name)
 238 mkAllCafsCC :: Module -> CostCentre
 239 mkAllCafsCC m = AllCafsCC  { cc_mod = m }
 240
 241
 242
 243 mkSingletonCCS :: CostCentre -> CostCentreStack
 244 mkSingletonCCS cc = pushCCOnCCS cc NoCCS
 245
 246 pushCCOnCCS :: CostCentre -> CostCentreStack -> CostCentreStack
 247 pushCCOnCCS = PushCC
 248
 249 dupifyCC :: CostCentre -> CostCentre
 250 dupifyCC cc = cc {cc_is_dupd = DupdCC}
 251
 252 isCafCC, isDupdCC :: CostCentre -> Bool
 253
 254 isCafCC (AllCafsCC {})                   = True
 255 isCafCC (NormalCC {cc_is_caf = CafCC}) = True
 256 isCafCC _                                = False
 257
 258 isDupdCC (NormalCC   {cc_is_dupd = DupdCC}) = True
 259 isDupdCC _                                   = False
 260
 261 isSccCountCostCentre :: CostCentre -> Bool
 262   -- Is this a cost-centre which records scc counts
 263
 264 #if DEBUG
 265 isSccCountCostCentre NoCostCentre  = panic "isSccCount:NoCostCentre"
 266 #endif
 267 isSccCountCostCentre cc | isCafCC cc  = False
 268                         | isDupdCC cc = False
 269                         | otherwise   = True
 270
 271 sccAbleCostCentre :: CostCentre -> Bool
 272   -- Is this a cost-centre which can be sccd ?
 273
 274 #if DEBUG
 275 sccAbleCostCentre NoCostCentre  = panic "sccAbleCC:NoCostCentre"
 276 #endif
 277 sccAbleCostCentre cc | isCafCC cc = False
 278                      | otherwise  = True
 279
 280 ccFromThisModule :: CostCentre -> Module -> Bool
 281 ccFromThisModule cc m = cc_mod cc == m
 282 \end{code}
 283
 284 \begin{code}
 285 instance Eq CostCentre where
 286         c1 == c2 = case c1 `cmpCostCentre` c2 of { EQ -> True; _ -> False }
 287
 288 instance Ord CostCentre where
 289         compare = cmpCostCentre
 290
 291 cmpCostCentre :: CostCentre -> CostCentre -> Ordering
 292
 293 cmpCostCentre (AllCafsCC  {cc_mod = m1}) (AllCafsCC  {cc_mod = m2}) = m1 `compare` m2
 294
 295 cmpCostCentre (NormalCC {cc_name = n1, cc_mod =  m1, cc_is_caf = c1})
 296               (NormalCC {cc_name = n2, cc_mod =  m2, cc_is_caf = c2})
 297     -- first key is module name, then we use "kinds" (which include
 298     -- names) and finally the caf flag
 299   = (m1 `compare` m2) `thenCmp` (n1 `compare` n2) `thenCmp` (c1 `cmp_caf` c2)
 300
 301 cmpCostCentre other_1 other_2
 302   = let
 303         !tag1 = tag_CC other_1
 304         !tag2 = tag_CC other_2
 305     in
 306     if tag1 <# tag2 then LT else GT
 307   where
 308     tag_CC (NormalCC   {}) = _ILIT(1)
 309     tag_CC (AllCafsCC  {}) = _ILIT(2)
 310
 311 -- TODO: swap order of IsCafCC, add deriving Ord
 312 cmp_caf :: IsCafCC -> IsCafCC -> Ordering
 313 cmp_caf NotCafCC CafCC     = LT
 314 cmp_caf NotCafCC NotCafCC  = EQ
 315 cmp_caf CafCC    CafCC     = EQ
 316 cmp_caf CafCC    NotCafCC  = GT
 317
 318 decomposeCCS :: CostCentreStack -> ([CostCentre],CostCentreStack)
 319 decomposeCCS (PushCC cc ccs) = (cc:more, ccs')
 320   where (more,ccs') = decomposeCCS ccs
 321 decomposeCCS ccs = ([],ccs)
 322 \end{code}
 323
 324 -----------------------------------------------------------------------------
 325 Printing Cost Centre Stacks.
 326
 327 The outputable instance for CostCentreStack prints the CCS as a C
 328 expression.
 329
 330 NOTE: Not all cost centres are suitable for using in a static
 331 initializer.  In particular, the PushCC forms where the tail is CCCS
 332 may only be used in inline C code because they expand to a
 333 non-constant C expression.
 334
 335 \begin{code}
 336 instance Outputable CostCentreStack where
 337   ppr NoCCS             = ptext (sLit "NO_CCS")
 338   ppr CurrentCCS        = ptext (sLit "CCCS")
 339   ppr OverheadCCS       = ptext (sLit "CCS_OVERHEAD")
 340   ppr DontCareCCS       = ptext (sLit "CCS_DONT_CARE")
 341   ppr SubsumedCCS       = ptext (sLit "CCS_SUBSUMED")
 342   ppr (PushCC cc NoCCS) = ppr cc <> ptext (sLit "_ccs")
 343   ppr (PushCC cc ccs)   = ptext (sLit "PushCostCentre") <>
 344                            parens (ppr ccs <> comma <>
 345                            parens(ptext (sLit "void *")) <> ppr cc)
 346 \end{code}
 347
 348 -----------------------------------------------------------------------------
 349 Printing Cost Centres.
 350
 351 There are several different ways in which we might want to print a
 352 cost centre:
 353
 354         - the name of the cost centre, for profiling output (a C string)
 355         - the label, i.e. C label for cost centre in .hc file.
 356         - the debugging name, for output in -ddump things
 357         - the interface name, for printing in _scc_ exprs in iface files.
 358
 359 The last 3 are derived from costCentreStr below.  The first is given
 360 by costCentreName.
 361
 362 \begin{code}
 363 instance Outputable CostCentre where
 364   ppr cc = getPprStyle $ \ sty ->
 365            if codeStyle sty
 366            then ppCostCentreLbl cc
 367            else text (costCentreUserName cc)
 368
 369 -- Printing in an interface file or in Core generally
 370 pprCostCentreCore :: CostCentre -> SDoc
 371 pprCostCentreCore (AllCafsCC {cc_mod = m})
 372   = text "__sccC" <+> braces (ppr m)
 373 pprCostCentreCore (NormalCC {cc_name = n, cc_mod = m,
 374                              cc_is_caf = caf, cc_is_dupd = dup})
 375   = text "__scc" <+> braces (hsep [
 376         ftext (zEncodeFS n),
 377         ppr m,
 378         pp_dup dup,
 379         pp_caf caf
 380     ])
 381
 382 pp_dup :: IsDupdCC -> SDoc
 383 pp_dup DupdCC = char '!'
 384 pp_dup _      = empty
 385
 386 pp_caf :: IsCafCC -> SDoc
 387 pp_caf CafCC = text "__C"
 388 pp_caf _     = empty
 389
 390 -- Printing as a C label
 391 ppCostCentreLbl :: CostCentre -> SDoc
 392 ppCostCentreLbl (NoCostCentre)            = text "NONE_cc"
 393 ppCostCentreLbl (AllCafsCC  {cc_mod = m}) = ppr m <> text "_CAFs_cc"
 394 ppCostCentreLbl (NormalCC {cc_name = n, cc_mod = m, cc_is_caf = is_caf})
 395   = ppr m <> char '_' <> ftext (zEncodeFS n) <>
 396         text (case is_caf of { CafCC -> "_CAF"; _ -> "" }) <> text "_cc"
 397
 398 -- This is the name to go in the user-displayed string,
 399 -- recorded in the cost centre declaration
 400 costCentreUserName :: CostCentre -> String
 401 costCentreUserName (NoCostCentre)  = "NO_CC"
 402 costCentreUserName (AllCafsCC {})  = "CAF"
 403 costCentreUserName (NormalCC {cc_name = name, cc_is_caf = is_caf})
 404   =  case is_caf of { CafCC -> "CAF:";   _ -> "" } ++ unpackFS name
 405 \end{code}