compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, rnHsTypeFVs,checkPrecMatch)
  26 import RnPat          (rnPatsAndThen_LocalRightwards, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker,
  28                        patSigErr)
  29
  30 import RnEnv
  31 import DynFlags ( DynFlag(..) )
  32 import Name
  33 import NameEnv
  34 import NameSet
  35 import PrelNames        ( isUnboundName )
  36 import RdrName          ( RdrName, rdrNameOcc )
  37 import SrcLoc
  38 import ListSetOps       ( findDupsEq )
  39 import BasicTypes       ( RecFlag(..) )
  40 import Digraph          ( SCC(..), stronglyConnComp )
  41 import Bag
  42 import Outputable
  43 import FastString
  44 import Maybes           ( orElse )
  45 import Util             ( filterOut )
  46 import Monad            ( foldM, unless )
  47 \end{code}
  48
  49 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  50 -- place and can be used when complaining.
  51
  52 The code tree received by the function @rnBinds@ contains definitions
  53 in where-clauses which are all apparently mutually recursive, but which may
  54 not really depend upon each other. For example, in the top level program
  55 \begin{verbatim}
  56 f x = y where a = x
  57               y = x
  58 \end{verbatim}
  59 the definitions of @a@ and @y@ do not depend on each other at all.
  60 Unfortunately, the typechecker cannot always check such definitions.
  61 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  62 definitions. In Proceedings of the International Symposium on Programming,
  63 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  64 However, the typechecker usually can check definitions in which only the
  65 strongly connected components have been collected into recursive bindings.
  66 This is precisely what the function @rnBinds@ does.
  67
  68 ToDo: deal with case where a single monobinds binds the same variable
  69 twice.
  70
  71 The vertag tag is a unique @Int@; the tags only need to be unique
  72 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  73 (heavy monad machinery not needed).
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 %* naming conventions                                                   *
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \subsection[name-conventions]{Name conventions}
  83
  84 The basic algorithm involves walking over the tree and returning a tuple
  85 containing the new tree plus its free variables. Some functions, such
  86 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  87 list comprehensions (@Quals@), return the variables bound in local
  88 environments. These are then used to calculate the free variables of the
  89 expression evaluated in these environments.
  90
  91 Conventions for variable names are as follows:
  92 \begin{itemize}
  93 \item
  94 new code is given a prime to distinguish it from the old.
  95
  96 \item
  97 a set of variables defined in @Exp@ is written @dvExp@
  98
  99 \item
 100 a set of variables free in @Exp@ is written @fvExp@
 101 \end{itemize}
 102
 103 %************************************************************************
 104 %*                                                                      *
 105 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 106 %*                                                                      *
 107 %************************************************************************
 108
 109 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 110
 111 Non-recursive expressions are reconstructed without any changes at top
 112 level, although their component expressions may have to be altered.
 113 However, non-recursive expressions are currently not expected as
 114 \Haskell{} programs, and this code should not be executed.
 115
 116 Monomorphic bindings contain information that is returned in a tuple
 117 (a @FlatMonoBinds@) containing:
 118
 119 \begin{enumerate}
 120 \item
 121 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 122
 123 \item
 124 the name of a function or the names in a pattern. These are a set
 125 referred to as @dvLhs@, the defined variables of the left hand side.
 126
 127 \item
 128 the free variables of the body. These are referred to as @fvBody@.
 129
 130 \item
 131 the definition's actual code. This is referred to as just @code@.
 132 \end{enumerate}
 133
 134 The function @nonRecDvFv@ returns two sets of variables. The first is
 135 the set of variables defined in the set of monomorphic bindings, while the
 136 second is the set of free variables in those bindings.
 137
 138 The set of variables defined in a non-recursive binding is just the
 139 union of all of them, as @union@ removes duplicates. However, the
 140 free variables in each successive set of cumulative bindings is the
 141 union of those in the previous set plus those of the newest binding after
 142 the defined variables of the previous set have been removed.
 143
 144 @rnMethodBinds@ deals only with the declarations in class and
 145 instance declarations.  It expects only to see @FunMonoBind@s, and
 146 it expects the global environment to contain bindings for the binders
 147 (which are all class operations).
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsubsection{ Top-level bindings}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 -- for top-level bindings, we need to make top-level names,
 157 -- so we have a different entry point than for local bindings
 158 rnTopBindsLHS :: MiniFixityEnv
 159               -> HsValBinds RdrName
 160               -> RnM (HsValBindsLR Name RdrName)
 161 rnTopBindsLHS fix_env binds =
 162     (uncurry $ rnValBindsLHSFromDoc (topRecNameMaker fix_env)) (bindersAndDoc binds) binds
 163
 164 rnTopBindsRHS :: [Name] -- the names bound by these binds
 165               -> HsValBindsLR Name RdrName
 166               -> RnM (HsValBinds Name, DefUses)
 167 rnTopBindsRHS bound_names binds =
 168     do { is_boot <- tcIsHsBoot
 169        ; if is_boot
 170          then rnTopBindsBoot binds
 171          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 172                                bound_names binds }
 173
 174
 175 -- wrapper if we don't need to do anything in between the left and right,
 176 -- or anything else in the scope of the left
 177 --
 178 -- never used when there are fixity declarations
 179 rnTopBinds :: HsValBinds RdrName
 180            -> RnM (HsValBinds Name, DefUses)
 181 rnTopBinds b =
 182   do nl <- rnTopBindsLHS emptyFsEnv b
 183      let bound_names = map unLoc (collectHsValBinders nl)
 184      bindLocalNames bound_names  $ rnTopBindsRHS bound_names nl
 185
 186
 187 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 188 -- A hs-boot file has no bindings.
 189 -- Return a single HsBindGroup with empty binds and renamed signatures
 190 rnTopBindsBoot (ValBindsIn mbinds sigs)
 191   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 192         ; sigs' <- renameSigs okHsBootSig sigs
 193         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 194 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 195 \end{code}
 196
 197
 198
 199 %*********************************************************
 200 %*                                                      *
 201                 HsLocalBinds
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 rnLocalBindsAndThen :: HsLocalBinds RdrName
 207                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 208                     -> RnM (result, FreeVars)
 209 -- This version (a) assumes that the binding vars are *not* already in scope
 210 --               (b) removes the binders from the free vars of the thing inside
 211 -- The parser doesn't produce ThenBinds
 212 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 213   = thing_inside EmptyLocalBinds
 214
 215 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 216   = rnValBindsAndThen val_binds $ \ val_binds' ->
 217       thing_inside (HsValBinds val_binds')
 218
 219 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 220     (binds',fv_binds) <- rnIPBinds binds
 221     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 222     return (thing, fvs_thing `plusFV` fv_binds)
 223
 224 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 225 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 226     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 227     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 228
 229 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 230 rnIPBind (IPBind n expr) = do
 231     name <- newIPNameRn  n
 232     (expr',fvExpr) <- rnLExpr expr
 233     return (IPBind name expr', fvExpr)
 234 \end{code}
 235
 236
 237 %************************************************************************
 238 %*                                                                      *
 239                 ValBinds
 240 %*                                                                      *
 241 %************************************************************************
 242
 243 \begin{code}
 244 -- wrapper for local binds
 245 -- creates the documentation info and calls the helper below
 246 rnValBindsLHS :: MiniFixityEnv
 247               -> HsValBinds RdrName
 248               -> RnM (HsValBindsLR Name RdrName)
 249 rnValBindsLHS fix_env binds =
 250     let (boundNames,doc) = bindersAndDoc binds
 251     in rnValBindsLHSFromDoc_Local boundNames doc fix_env binds
 252
 253 -- a helper used for local binds that does the duplicates check,
 254 -- just so we don't forget to do it somewhere
 255 rnValBindsLHSFromDoc_Local :: [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 256                            -> SDoc              -- doc string for dup names and shadowing
 257                            -> MiniFixityEnv
 258                            -> HsValBinds RdrName
 259                            -> RnM (HsValBindsLR Name RdrName)
 260
 261 rnValBindsLHSFromDoc_Local boundNames doc fix_env binds = do
 262      -- Do error checking: we need to check for dups here because we
 263      -- don't don't bind all of the variables from the ValBinds at once
 264      -- with bindLocatedLocals any more.
 265      checkDupAndShadowedRdrNames doc boundNames
 266
 267      -- (Note that we don't want to do this at the top level, since
 268      -- sorting out duplicates and shadowing there happens elsewhere.
 269      -- The behavior is even different. For example,
 270      --   import A(f)
 271      --   f = ...
 272      -- should not produce a shadowing warning (but it will produce
 273      -- an ambiguity warning if you use f), but
 274      --   import A(f)
 275      --   g = let f = ... in f
 276      -- should.
 277      rnValBindsLHSFromDoc (localRecNameMaker fix_env) boundNames doc binds
 278
 279 bindersAndDoc :: HsValBinds RdrName -> ([Located RdrName], SDoc)
 280 bindersAndDoc binds =
 281     let
 282         -- the unrenamed bndrs for error checking and reporting
 283         orig = collectHsValBinders binds
 284         doc = text "In the binding group for:" <+> pprWithCommas ppr (map unLoc orig)
 285     in
 286       (orig, doc)
 287
 288 -- renames the left-hand sides
 289 -- generic version used both at the top level and for local binds
 290 -- does some error checking, but not what gets done elsewhere at the top level
 291 rnValBindsLHSFromDoc :: NameMaker
 292                      -> [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 293                      -> SDoc              -- doc string for dup names and shadowing
 294                      -> HsValBinds RdrName
 295                      -> RnM (HsValBindsLR Name RdrName)
 296 rnValBindsLHSFromDoc topP _original_bndrs doc (ValBindsIn mbinds sigs) = do
 297      -- rename the LHSes
 298      mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 299      return $ ValBindsIn mbinds' sigs
 300 rnValBindsLHSFromDoc _ _ _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 301
 302 -- assumes the LHS vars are in scope
 303 -- general version used both from the top-level and for local things
 304 --
 305 -- does not bind the local fixity declarations
 306 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 307                      -- The trimming function trims the free vars we attach to a
 308                      -- binding so that it stays reasonably small
 309                  -> [Name]  -- names bound by the LHSes
 310                  -> HsValBindsLR Name RdrName
 311                  -> RnM (HsValBinds Name, DefUses)
 312
 313 rnValBindsRHSGen trim _bound_names (ValBindsIn mbinds sigs) = do
 314    -- rename the sigs
 315    env <- getGblEnv
 316    traceRn (ptext (sLit "Rename sigs") <+> ppr (tcg_rdr_env env))
 317    sigs' <- rename_sigs sigs
 318    -- rename the RHSes
 319    binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 320    let (anal_binds, anal_dus) = depAnalBinds binds_w_dus
 321        (valbind', valbind'_dus) = (ValBindsOut anal_binds sigs',
 322                                    usesOnly (hsSigsFVs sigs') `plusDU` anal_dus)
 323    -- We do the check-sigs after renaming the bindings,
 324    -- so that we have convenient access to the binders
 325    check_sigs (okBindSig (duDefs anal_dus)) sigs'
 326    return (valbind', valbind'_dus)
 327
 328 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 329
 330 -- Wrapper for local binds
 331 --
 332 -- The *client* of this function is responsible for checking for unused binders;
 333 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 334 --
 335 -- The client is also responsible for bringing the fixities into scope
 336 rnValBindsRHS :: [Name]  -- names bound by the LHSes
 337               -> HsValBindsLR Name RdrName
 338               -> RnM (HsValBinds Name, DefUses)
 339 rnValBindsRHS bound_names binds =
 340   rnValBindsRHSGen (\ fvs -> -- only keep the names the names from this group
 341                     intersectNameSet (mkNameSet bound_names) fvs) bound_names binds
 342
 343
 344 -- for local binds
 345 -- wrapper that does both the left- and right-hand sides
 346 --
 347 -- here there are no local fixity decls passed in;
 348 -- the local fixity decls come from the ValBinds sigs
 349 rnValBindsAndThen :: HsValBinds RdrName
 350                   -> (HsValBinds Name -> RnM (result, FreeVars))
 351                   -> RnM (result, FreeVars)
 352 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 353  = do   { let (original_bndrs, doc) = bindersAndDoc binds
 354
 355               -- (A) Create the local fixity environment
 356         ; new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 357
 358               -- (B) Rename the LHSes
 359         ; new_lhs <- rnValBindsLHSFromDoc_Local original_bndrs doc new_fixities binds
 360         ; let bound_names = map unLoc $ collectHsValBinders new_lhs
 361
 362               --     ...and bring them (and their fixities) into scope
 363         ; bindLocalNamesFV_WithFixities bound_names new_fixities $ do
 364
 365         {      -- (C) Do the RHS and thing inside
 366           (binds', dus) <- rnValBindsRHS bound_names new_lhs
 367         ; (result, result_fvs) <- thing_inside binds'
 368
 369                 -- Report unused bindings based on the (accurate)
 370                 -- findUses.  E.g.
 371                 --      let x = x in 3
 372                 -- should report 'x' unused
 373         ; let real_uses = findUses dus result_fvs
 374         ; warnUnusedLocalBinds bound_names real_uses
 375
 376         ; let
 377             -- The variables "used" in the val binds are:
 378             --   (1) the uses of the binds (duUses)
 379             --   (2) the FVs of the thing-inside
 380             all_uses = duUses dus `plusFV` result_fvs
 381                 -- Note [Unused binding hack]
 382                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 383                 -- Note that *in contrast* to the above reporting of
 384                 -- unused bindings, (1) above uses duUses to return *all*
 385                 -- the uses, even if the binding is unused.  Otherwise consider:
 386                 --      x = 3
 387                 --      y = let p = x in 'x'    -- NB: p not used
 388                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 389                 -- bindings in the wrong order, and the type checker will complain
 390                 -- that x isn't in scope
 391                 --
 392                 -- But note that this means we won't report 'x' as unused,
 393                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 394
 395         ; return (result, all_uses) }}
 396                 -- The bound names are pruned out of all_uses
 397                 -- by the bindLocalNamesFV call above
 398
 399 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 400
 401
 402 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 403 -- (We keep the location around for reporting duplicate fixity declarations.)
 404 --
 405 -- Checks for duplicates, but not that only locally defined things are fixed.
 406 -- Note: for local fixity declarations, duplicates would also be checked in
 407 --       check_sigs below.  But we also use this function at the top level.
 408
 409 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 410
 411 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 412  where
 413    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 414      { -- this fixity decl is a duplicate iff
 415        -- the ReaderName's OccName's FastString is already in the env
 416        -- (we only need to check the local fix_env because
 417        --  definitions of non-local will be caught elsewhere)
 418        let { fs = occNameFS (rdrNameOcc name)
 419            ; fix_item = L loc fixity };
 420
 421        case lookupFsEnv env fs of
 422          Nothing -> return $ extendFsEnv env fs fix_item
 423          Just (L loc' _) -> do
 424            { setSrcSpan loc $
 425              addLocErr (L name_loc name) (dupFixityDecl loc')
 426            ; return env}
 427      }
 428
 429 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 430 dupFixityDecl loc rdr_name
 431   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 432           ptext (sLit "also at ") <+> ppr loc]
 433
 434 ---------------------
 435
 436 -- renaming a single bind
 437
 438 rnBindLHS :: NameMaker
 439           -> SDoc
 440           -> LHsBind RdrName
 441           -- returns the renamed left-hand side,
 442           -- and the FreeVars *of the LHS*
 443           -- (i.e., any free variables of the pattern)
 444           -> RnM (LHsBindLR Name RdrName)
 445
 446 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 447                                          pat_rhs = grhss,
 448                                          pat_rhs_ty=pat_rhs_ty
 449                                        }))
 450   = setSrcSpan loc $ do
 451       -- we don't actually use the FV processing of rnPatsAndThen here
 452       (pat',pat'_fvs) <- rnBindPat name_maker pat
 453       return (L loc (PatBind { pat_lhs = pat',
 454                                pat_rhs = grhss,
 455                                -- we temporarily store the pat's FVs here;
 456                                -- gets updated to the FVs of the whole bind
 457                                -- when doing the RHS below
 458                                bind_fvs = pat'_fvs,
 459                                -- these will get ignored in the next pass,
 460                                -- when we rename the RHS
 461                                pat_rhs_ty = pat_rhs_ty }))
 462
 463 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 464                                          fun_infix = inf,
 465                                          fun_matches = matches,
 466                                          fun_co_fn = fun_co_fn,
 467                                          fun_tick = fun_tick
 468                                        }))
 469   = setSrcSpan loc $
 470     do { (newname, _fvs) <- applyNameMaker name_maker name $ \ newname ->
 471                             return (newname, emptyFVs)
 472        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 473                                   fun_infix = inf,
 474                                   fun_matches = matches,
 475                                   -- we temporatily store the LHS's FVs (empty in this case) here
 476                                   -- gets updated when doing the RHS below
 477                                   bind_fvs = emptyFVs,
 478                                   -- everything else will get ignored in the next pass
 479                                   fun_co_fn = fun_co_fn,
 480                                   fun_tick = fun_tick
 481                                   })) }
 482
 483 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 484
 485 -- assumes the left-hands-side vars are in scope
 486 rnBind :: (Name -> [Name])              -- Signature tyvar function
 487        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 488        -> LHsBindLR Name RdrName
 489        -> RnM (LHsBind Name, [Name], Uses)
 490 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 491                                 pat_rhs = grhss,
 492                                 -- pat fvs were stored here while
 493                                 -- processing the LHS
 494                                 bind_fvs=pat_fvs }))
 495   = setSrcSpan loc $
 496     do  {let bndrs = collectPatBinders pat
 497
 498         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 499                 -- No scoped type variables for pattern bindings
 500
 501         ; return (L loc (PatBind { pat_lhs = pat,
 502                                   pat_rhs = grhss',
 503                                      pat_rhs_ty = placeHolderType,
 504                                   bind_fvs = trim fvs }),
 505                   bndrs, pat_fvs `plusFV` fvs) }
 506
 507 rnBind sig_fn
 508        trim
 509        (L loc (FunBind { fun_id = name,
 510                          fun_infix = inf,
 511                          fun_matches = matches,
 512                          -- no pattern FVs
 513                          bind_fvs = _
 514                        }))
 515        -- invariant: no free vars here when it's a FunBind
 516   = setSrcSpan loc $
 517     do  { let plain_name = unLoc name
 518
 519         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 520                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 521                              rnMatchGroup (FunRhs plain_name inf) matches
 522
 523         ; checkPrecMatch inf plain_name matches'
 524
 525         ; return (L loc (FunBind { fun_id = name,
 526                                   fun_infix = inf,
 527                                   fun_matches = matches',
 528                                      bind_fvs = trim fvs,
 529                                   fun_co_fn = idHsWrapper,
 530                                   fun_tick = Nothing }),
 531                   [plain_name], fvs)
 532       }
 533
 534 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 535
 536 ---------------------
 537 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 538              -> ([(RecFlag, LHsBinds Name)], DefUses)
 539 -- Dependency analysis; this is important so that
 540 -- unused-binding reporting is accurate
 541 depAnalBinds binds_w_dus
 542   = (map get_binds sccs, map get_du sccs)
 543   where
 544     sccs = stronglyConnComp edges
 545
 546     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 547
 548     edges = [ (node, key, [key | n <- nameSetToList uses,
 549                                  Just key <- [lookupNameEnv key_map n] ])
 550             | (node@(_,_,uses), key) <- keyd_nodes ]
 551
 552     key_map :: NameEnv Int      -- Which binding it comes from
 553     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 554                                      , bndr <- bndrs ]
 555
 556     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 557     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 558
 559     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 560     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 561         where
 562           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 563           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 564
 565
 566 ---------------------
 567 -- Bind the top-level forall'd type variables in the sigs.
 568 -- E.g  f :: a -> a
 569 --      f = rhs
 570 --      The 'a' scopes over the rhs
 571 --
 572 -- NB: there'll usually be just one (for a function binding)
 573 --     but if there are many, one may shadow the rest; too bad!
 574 --      e.g  x :: [a] -> [a]
 575 --           y :: [(a,a)] -> a
 576 --           (x,y) = e
 577 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 578
 579 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 580 -- Return a lookup function that maps an Id Name to the names
 581 -- of the type variables that should scope over its body..
 582 mkSigTvFn sigs
 583   = \n -> lookupNameEnv env n `orElse` []
 584   where
 585     env :: NameEnv [Name]
 586     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 587                     | L _ (TypeSig (L _ name)
 588                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 589         -- Note the pattern-match on "Explicit"; we only bind
 590         -- type variables from signatures with an explicit top-level for-all
 591 \end{code}
 592
 593
 594 @rnMethodBinds@ is used for the method bindings of a class and an instance
 595 declaration.   Like @rnBinds@ but without dependency analysis.
 596
 597 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 598 That's crucial when dealing with an instance decl:
 599 \begin{verbatim}
 600         instance Foo (T a) where
 601            op x = ...
 602 \end{verbatim}
 603 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 604 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 605 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 606 in many ways the @op@ in an instance decl is just like an occurrence, not
 607 a binder.
 608
 609 \begin{code}
 610 rnMethodBinds :: Name                   -- Class name
 611               -> (Name -> [Name])       -- Signature tyvar function
 612               -> [Name]                 -- Names for generic type variables
 613               -> LHsBinds RdrName
 614               -> RnM (LHsBinds Name, FreeVars)
 615
 616 rnMethodBinds cls sig_fn gen_tyvars binds
 617   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 618   where do_one (binds,fvs) bind = do
 619            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 620            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 621
 622 rnMethodBind :: Name
 623               -> (Name -> [Name])
 624               -> [Name]
 625               -> LHsBindLR RdrName RdrName
 626               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 627 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = inf,
 628                                                      fun_matches = MatchGroup matches _ }))
 629   = setSrcSpan loc $ do
 630     sel_name <- lookupInstDeclBndr cls name
 631     let plain_name = unLoc sel_name
 632         -- We use the selector name as the binder
 633
 634     bindSigTyVarsFV (sig_fn plain_name) $ do
 635      (new_matches, fvs) <- mapFvRn (rn_match plain_name) matches
 636      let
 637          new_group = MatchGroup new_matches placeHolderType
 638
 639      checkPrecMatch inf plain_name new_group
 640      return (unitBag (L loc (FunBind {
 641                                 fun_id = sel_name, fun_infix = inf,
 642                                 fun_matches = new_group,
 643                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 644                                 fun_tick = Nothing })),
 645              fvs `addOneFV` plain_name)
 646         -- The 'fvs' field isn't used for method binds
 647   where
 648         -- Truly gruesome; bring into scope the correct members of the generic
 649         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 650     rn_match sel_name match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 651         = extendTyVarEnvFVRn gen_tvs    $
 652           rnMatch (FunRhs sel_name inf) match
 653         where
 654           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 655           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 656
 657     rn_match sel_name match = rnMatch (FunRhs sel_name inf) match
 658
 659
 660 -- Can't handle method pattern-bindings which bind multiple methods.
 661 rnMethodBind _ _ _ mbind@(L _ (PatBind _ _ _ _)) = do
 662     addLocErr mbind methodBindErr
 663     return (emptyBag, emptyFVs)
 664
 665 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 666 \end{code}
 667
 668
 669
 670 %************************************************************************
 671 %*                                                                      *
 672 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 673 %*                                                                      *
 674 %************************************************************************
 675
 676 @renameSigs@ checks for:
 677 \begin{enumerate}
 678 \item more than one sig for one thing;
 679 \item signatures given for things not bound here;
 680 \item with suitably flaggery, that all top-level things have type signatures.
 681 \end{enumerate}
 682 %
 683 At the moment we don't gather free-var info from the types in
 684 signatures.  We'd only need this if we wanted to report unused tyvars.
 685
 686 \begin{code}
 687 renameSigs :: (LSig Name -> Bool) -> [LSig RdrName] -> RnM [LSig Name]
 688 -- Renames the signatures and performs error checks
 689 renameSigs ok_sig sigs
 690   = do  { sigs' <- rename_sigs sigs
 691         ; check_sigs ok_sig sigs'
 692         ; return sigs' }
 693
 694 ----------------------
 695 rename_sigs :: [LSig RdrName] -> RnM [LSig Name]
 696 rename_sigs sigs = mapM (wrapLocM renameSig) sigs
 697
 698 ----------------------
 699 check_sigs :: (LSig Name -> Bool) -> [LSig Name] -> RnM ()
 700 -- Used for class and instance decls, as well as regular bindings
 701 check_sigs ok_sig sigs = do
 702         -- Check for (a) duplicate signatures
 703         --           (b) signatures for things not in this group = do
 704     traceRn (text "SIGS" <+> ppr sigs)
 705     mapM_ unknownSigErr (filter (not . ok_sig) sigs')
 706     mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs')
 707   where
 708         -- Don't complain about an unbound name again
 709     sigs' = filterOut bad_name sigs
 710     bad_name sig = case sigName sig of
 711                         Just n -> isUnboundName n
 712                         _      -> False
 713
 714 -- We use lookupLocatedSigOccRn in the signatures, which is a little bit unsatisfactory
 715 -- because this won't work for:
 716 --      instance Foo T where
 717 --        {-# INLINE op #-}
 718 --        Baz.op = ...
 719 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 720 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 721 -- Doesn't seem worth much trouble to sort this.
 722
 723 renameSig :: Sig RdrName -> RnM (Sig Name)
 724 -- FixitSig is renamed elsewhere.
 725 renameSig (TypeSig v ty) = do
 726     new_v <- lookupLocatedSigOccRn v
 727     new_ty <- rnHsSigType (quotes (ppr v)) ty
 728     return (TypeSig new_v new_ty)
 729
 730 renameSig (SpecInstSig ty) = do
 731     new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 732     return (SpecInstSig new_ty)
 733
 734 renameSig (SpecSig v ty inl) = do
 735     new_v <- lookupLocatedSigOccRn v
 736     new_ty <- rnHsSigType (quotes (ppr v)) ty
 737     return (SpecSig new_v new_ty inl)
 738
 739 renameSig (InlineSig v s) = do
 740     new_v <- lookupLocatedSigOccRn v
 741     return (InlineSig new_v s)
 742
 743 renameSig (FixSig (FixitySig v f)) = do
 744     new_v <- lookupLocatedSigOccRn v
 745     return (FixSig (FixitySig new_v f))
 746 \end{code}
 747
 748
 749 ************************************************************************
 750 *                                                                       *
 751 \subsection{Match}
 752 *                                                                       *
 753 ************************************************************************
 754
 755 \begin{code}
 756 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 757 rnMatchGroup ctxt (MatchGroup ms _) = do
 758     (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 759     return (MatchGroup new_ms placeHolderType, ms_fvs)
 760
 761 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 762 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 763
 764 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 765 rnMatch' ctxt (Match pats maybe_rhs_sig grhss)
 766   =
 767         -- Deal with the rhs type signature
 768     bindPatSigTyVarsFV rhs_sig_tys      $ do
 769     opt_PatternSignatures <- doptM Opt_PatternSignatures
 770     (maybe_rhs_sig', ty_fvs) <-
 771       case maybe_rhs_sig of
 772         Nothing -> return (Nothing, emptyFVs)
 773         Just ty | opt_PatternSignatures -> do (ty', ty_fvs) <- rnHsTypeFVs doc_sig ty
 774                                               return (Just ty', ty_fvs)
 775                 | otherwise             -> do addLocErr ty patSigErr
 776                                               return (Nothing, emptyFVs)
 777
 778        -- Now the main event
 779        -- note that there are no local ficity decls for matches
 780     rnPatsAndThen_LocalRightwards ctxt pats     $ \ pats' -> do
 781       (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 782
 783       return (Match pats' maybe_rhs_sig' grhss', grhss_fvs `plusFV` ty_fvs)
 784         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 785   where
 786      rhs_sig_tys =  case maybe_rhs_sig of
 787                         Nothing -> []
 788                         Just ty -> [ty]
 789      doc_sig = text "In a result type-signature"
 790 \end{code}
 791
 792
 793 %************************************************************************
 794 %*                                                                      *
 795 \subsubsection{Guarded right-hand sides (GRHSs)}
 796 %*                                                                      *
 797 %************************************************************************
 798
 799 \begin{code}
 800 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 801
 802 rnGRHSs ctxt (GRHSs grhss binds)
 803   = rnLocalBindsAndThen binds   $ \ binds' -> do
 804     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 805     return (GRHSs grhss' binds', fvGRHSs)
 806
 807 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 808 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 809
 810 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 811 rnGRHS' ctxt (GRHS guards rhs)
 812   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 813         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 814                                     rnLExpr rhs
 815
 816         ; unless (pattern_guards_allowed || is_standard_guard guards')
 817                  (addWarn (nonStdGuardErr guards'))
 818
 819         ; return (GRHS guards' rhs', fvs) }
 820   where
 821         -- Standard Haskell 1.4 guards are just a single boolean
 822         -- expression, rather than a list of qualifiers as in the
 823         -- Glasgow extension
 824     is_standard_guard []                     = True
 825     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 826     is_standard_guard _                      = False
 827 \end{code}
 828
 829 %************************************************************************
 830 %*                                                                      *
 831 \subsection{Error messages}
 832 %*                                                                      *
 833 %************************************************************************
 834
 835 \begin{code}
 836 dupSigDeclErr :: [LSig Name] -> RnM ()
 837 dupSigDeclErr sigs@(L loc sig : _)
 838   = addErrAt loc $
 839         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 840               nest 2 (vcat (map ppr_sig sigs))]
 841   where
 842     what_it_is = hsSigDoc sig
 843     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 844 dupSigDeclErr [] = panic "dupSigDeclErr"
 845
 846 unknownSigErr :: LSig Name -> RnM ()
 847 unknownSigErr (L loc sig)
 848   = do  { mod <- getModule
 849         ; addErrAt loc $
 850                 vcat [sep [ptext (sLit "Misplaced") <+> what_it_is <> colon, ppr sig],
 851                       extra_stuff mod sig] }
 852   where
 853     what_it_is = hsSigDoc sig
 854     extra_stuff mod  (TypeSig (L _ n) _)
 855         | nameIsLocalOrFrom mod n
 856         = ptext (sLit "The type signature must be given where")
 857                 <+> quotes (ppr n) <+> ptext (sLit "is declared")
 858         | otherwise
 859         = ptext (sLit "You cannot give a type signature for an imported value")
 860
 861     extra_stuff _ _ = empty
 862
 863 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 864 methodBindErr mbind
 865  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 866        2 (ppr mbind)
 867
 868 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 869 bindsInHsBootFile mbinds
 870   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 871        2 (ppr mbinds)
 872
 873 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 874 nonStdGuardErr guards
 875   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 876        4 (interpp'SP guards)
 877 \end{code}