compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPatsAndThen_LocalRightwards, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import PrelNames        ( mkUnboundName )
  32 import DynFlags ( DynFlag(..) )
  33 import Name
  34 import NameEnv
  35 import NameSet
  36 import RdrName          ( RdrName, rdrNameOcc )
  37 import SrcLoc
  38 import ListSetOps       ( findDupsEq )
  39 import BasicTypes       ( RecFlag(..) )
  40 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  41 import Bag
  42 import Outputable
  43 import FastString
  44 import Data.List        ( partition )
  45 import Maybes           ( orElse )
  46 import Monad            ( foldM, unless )
  47 \end{code}
  48
  49 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  50 -- place and can be used when complaining.
  51
  52 The code tree received by the function @rnBinds@ contains definitions
  53 in where-clauses which are all apparently mutually recursive, but which may
  54 not really depend upon each other. For example, in the top level program
  55 \begin{verbatim}
  56 f x = y where a = x
  57               y = x
  58 \end{verbatim}
  59 the definitions of @a@ and @y@ do not depend on each other at all.
  60 Unfortunately, the typechecker cannot always check such definitions.
  61 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  62 definitions. In Proceedings of the International Symposium on Programming,
  63 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  64 However, the typechecker usually can check definitions in which only the
  65 strongly connected components have been collected into recursive bindings.
  66 This is precisely what the function @rnBinds@ does.
  67
  68 ToDo: deal with case where a single monobinds binds the same variable
  69 twice.
  70
  71 The vertag tag is a unique @Int@; the tags only need to be unique
  72 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  73 (heavy monad machinery not needed).
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 %* naming conventions                                                   *
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \subsection[name-conventions]{Name conventions}
  83
  84 The basic algorithm involves walking over the tree and returning a tuple
  85 containing the new tree plus its free variables. Some functions, such
  86 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  87 list comprehensions (@Quals@), return the variables bound in local
  88 environments. These are then used to calculate the free variables of the
  89 expression evaluated in these environments.
  90
  91 Conventions for variable names are as follows:
  92 \begin{itemize}
  93 \item
  94 new code is given a prime to distinguish it from the old.
  95
  96 \item
  97 a set of variables defined in @Exp@ is written @dvExp@
  98
  99 \item
 100 a set of variables free in @Exp@ is written @fvExp@
 101 \end{itemize}
 102
 103 %************************************************************************
 104 %*                                                                      *
 105 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 106 %*                                                                      *
 107 %************************************************************************
 108
 109 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 110
 111 Non-recursive expressions are reconstructed without any changes at top
 112 level, although their component expressions may have to be altered.
 113 However, non-recursive expressions are currently not expected as
 114 \Haskell{} programs, and this code should not be executed.
 115
 116 Monomorphic bindings contain information that is returned in a tuple
 117 (a @FlatMonoBinds@) containing:
 118
 119 \begin{enumerate}
 120 \item
 121 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 122
 123 \item
 124 the name of a function or the names in a pattern. These are a set
 125 referred to as @dvLhs@, the defined variables of the left hand side.
 126
 127 \item
 128 the free variables of the body. These are referred to as @fvBody@.
 129
 130 \item
 131 the definition's actual code. This is referred to as just @code@.
 132 \end{enumerate}
 133
 134 The function @nonRecDvFv@ returns two sets of variables. The first is
 135 the set of variables defined in the set of monomorphic bindings, while the
 136 second is the set of free variables in those bindings.
 137
 138 The set of variables defined in a non-recursive binding is just the
 139 union of all of them, as @union@ removes duplicates. However, the
 140 free variables in each successive set of cumulative bindings is the
 141 union of those in the previous set plus those of the newest binding after
 142 the defined variables of the previous set have been removed.
 143
 144 @rnMethodBinds@ deals only with the declarations in class and
 145 instance declarations.  It expects only to see @FunMonoBind@s, and
 146 it expects the global environment to contain bindings for the binders
 147 (which are all class operations).
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsubsection{ Top-level bindings}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 -- for top-level bindings, we need to make top-level names,
 157 -- so we have a different entry point than for local bindings
 158 rnTopBindsLHS :: MiniFixityEnv
 159               -> HsValBinds RdrName
 160               -> RnM (HsValBindsLR Name RdrName)
 161 rnTopBindsLHS fix_env binds =
 162     (uncurry $ rnValBindsLHSFromDoc (topRecNameMaker fix_env)) (bindersAndDoc binds) binds
 163
 164 rnTopBindsRHS :: [Name] -- the names bound by these binds
 165               -> HsValBindsLR Name RdrName
 166               -> RnM (HsValBinds Name, DefUses)
 167 rnTopBindsRHS bound_names binds =
 168     do { is_boot <- tcIsHsBoot
 169        ; if is_boot
 170          then rnTopBindsBoot binds
 171          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 172                                bound_names binds }
 173
 174
 175 -- wrapper if we don't need to do anything in between the left and right,
 176 -- or anything else in the scope of the left
 177 --
 178 -- never used when there are fixity declarations
 179 rnTopBinds :: HsValBinds RdrName
 180            -> RnM (HsValBinds Name, DefUses)
 181 rnTopBinds b =
 182   do nl <- rnTopBindsLHS emptyFsEnv b
 183      let bound_names = map unLoc (collectHsValBinders nl)
 184      bindLocalNames bound_names  $ rnTopBindsRHS bound_names nl
 185
 186
 187 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 188 -- A hs-boot file has no bindings.
 189 -- Return a single HsBindGroup with empty binds and renamed signatures
 190 rnTopBindsBoot (ValBindsIn mbinds sigs)
 191   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 192         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 193         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 194 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 195 \end{code}
 196
 197
 198
 199 %*********************************************************
 200 %*                                                      *
 201                 HsLocalBinds
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 rnLocalBindsAndThen :: HsLocalBinds RdrName
 207                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 208                     -> RnM (result, FreeVars)
 209 -- This version (a) assumes that the binding vars are *not* already in scope
 210 --               (b) removes the binders from the free vars of the thing inside
 211 -- The parser doesn't produce ThenBinds
 212 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 213   = thing_inside EmptyLocalBinds
 214
 215 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 216   = rnValBindsAndThen val_binds $ \ val_binds' ->
 217       thing_inside (HsValBinds val_binds')
 218
 219 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 220     (binds',fv_binds) <- rnIPBinds binds
 221     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 222     return (thing, fvs_thing `plusFV` fv_binds)
 223
 224 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 225 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 226     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 227     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 228
 229 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 230 rnIPBind (IPBind n expr) = do
 231     name <- newIPNameRn  n
 232     (expr',fvExpr) <- rnLExpr expr
 233     return (IPBind name expr', fvExpr)
 234 \end{code}
 235
 236
 237 %************************************************************************
 238 %*                                                                      *
 239                 ValBinds
 240 %*                                                                      *
 241 %************************************************************************
 242
 243 \begin{code}
 244 -- wrapper for local binds
 245 -- creates the documentation info and calls the helper below
 246 rnValBindsLHS :: MiniFixityEnv
 247               -> HsValBinds RdrName
 248               -> RnM (HsValBindsLR Name RdrName)
 249 rnValBindsLHS fix_env binds =
 250     let (boundNames,doc) = bindersAndDoc binds
 251     in rnValBindsLHSFromDoc_Local boundNames doc fix_env binds
 252
 253 -- a helper used for local binds that does the duplicates check,
 254 -- just so we don't forget to do it somewhere
 255 rnValBindsLHSFromDoc_Local :: [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 256                            -> SDoc              -- doc string for dup names and shadowing
 257                            -> MiniFixityEnv
 258                            -> HsValBinds RdrName
 259                            -> RnM (HsValBindsLR Name RdrName)
 260
 261 rnValBindsLHSFromDoc_Local boundNames doc fix_env binds = do
 262      -- Do error checking: we need to check for dups here because we
 263      -- don't don't bind all of the variables from the ValBinds at once
 264      -- with bindLocatedLocals any more.
 265      checkDupAndShadowedRdrNames doc boundNames
 266
 267      -- (Note that we don't want to do this at the top level, since
 268      -- sorting out duplicates and shadowing there happens elsewhere.
 269      -- The behavior is even different. For example,
 270      --   import A(f)
 271      --   f = ...
 272      -- should not produce a shadowing warning (but it will produce
 273      -- an ambiguity warning if you use f), but
 274      --   import A(f)
 275      --   g = let f = ... in f
 276      -- should.
 277      rnValBindsLHSFromDoc (localRecNameMaker fix_env) boundNames doc binds
 278
 279 bindersAndDoc :: HsValBinds RdrName -> ([Located RdrName], SDoc)
 280 bindersAndDoc binds =
 281     let
 282         -- the unrenamed bndrs for error checking and reporting
 283         orig = collectHsValBinders binds
 284         doc = text "In the binding group for:" <+> pprWithCommas ppr (map unLoc orig)
 285     in
 286       (orig, doc)
 287
 288 -- renames the left-hand sides
 289 -- generic version used both at the top level and for local binds
 290 -- does some error checking, but not what gets done elsewhere at the top level
 291 rnValBindsLHSFromDoc :: NameMaker
 292                      -> [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 293                      -> SDoc              -- doc string for dup names and shadowing
 294                      -> HsValBinds RdrName
 295                      -> RnM (HsValBindsLR Name RdrName)
 296 rnValBindsLHSFromDoc topP _original_bndrs doc (ValBindsIn mbinds sigs) = do
 297      -- rename the LHSes
 298      mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 299      return $ ValBindsIn mbinds' sigs
 300 rnValBindsLHSFromDoc _ _ _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 301
 302 -- General version used both from the top-level and for local things
 303 -- Assumes the LHS vars are in scope
 304 --
 305 -- Does not bind the local fixity declarations
 306 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 307                      -- The trimming function trims the free vars we attach to a
 308                      -- binding so that it stays reasonably small
 309                  -> [Name]  -- names bound by the LHSes
 310                  -> HsValBindsLR Name RdrName
 311                  -> RnM (HsValBinds Name, DefUses)
 312
 313 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs) = do
 314    -- rename the sigs
 315    sigs' <- renameSigs (Just (mkNameSet bound_names)) okBindSig sigs
 316    -- rename the RHSes
 317    binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 318    case depAnalBinds binds_w_dus of
 319        (anal_binds, anal_dus) ->
 320            do let valbind' = ValBindsOut anal_binds sigs'
 321                   valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 322               return (valbind', valbind'_dus)
 323
 324 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 325
 326 -- Wrapper for local binds
 327 --
 328 -- The *client* of this function is responsible for checking for unused binders;
 329 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 330 --
 331 -- The client is also responsible for bringing the fixities into scope
 332 rnValBindsRHS :: [Name]  -- names bound by the LHSes
 333               -> HsValBindsLR Name RdrName
 334               -> RnM (HsValBinds Name, DefUses)
 335 rnValBindsRHS bound_names binds =
 336   rnValBindsRHSGen (\ fvs -> -- only keep the names the names from this group
 337                     intersectNameSet (mkNameSet bound_names) fvs) bound_names binds
 338
 339
 340 -- for local binds
 341 -- wrapper that does both the left- and right-hand sides
 342 --
 343 -- here there are no local fixity decls passed in;
 344 -- the local fixity decls come from the ValBinds sigs
 345 rnValBindsAndThen :: HsValBinds RdrName
 346                   -> (HsValBinds Name -> RnM (result, FreeVars))
 347                   -> RnM (result, FreeVars)
 348 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 349  = do   { let (original_bndrs, doc) = bindersAndDoc binds
 350
 351               -- (A) Create the local fixity environment
 352         ; new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 353
 354               -- (B) Rename the LHSes
 355         ; new_lhs <- rnValBindsLHSFromDoc_Local original_bndrs doc new_fixities binds
 356         ; let bound_names = map unLoc $ collectHsValBinders new_lhs
 357
 358               --     ...and bring them (and their fixities) into scope
 359         ; bindLocalNamesFV_WithFixities bound_names new_fixities $ do
 360
 361         {      -- (C) Do the RHS and thing inside
 362           (binds', dus) <- rnValBindsRHS bound_names new_lhs
 363         ; (result, result_fvs) <- thing_inside binds'
 364
 365                 -- Report unused bindings based on the (accurate)
 366                 -- findUses.  E.g.
 367                 --      let x = x in 3
 368                 -- should report 'x' unused
 369         ; let real_uses = findUses dus result_fvs
 370         ; warnUnusedLocalBinds bound_names real_uses
 371
 372         ; let
 373             -- The variables "used" in the val binds are:
 374             --   (1) the uses of the binds (duUses)
 375             --   (2) the FVs of the thing-inside
 376             all_uses = duUses dus `plusFV` result_fvs
 377                 -- Note [Unused binding hack]
 378                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 379                 -- Note that *in contrast* to the above reporting of
 380                 -- unused bindings, (1) above uses duUses to return *all*
 381                 -- the uses, even if the binding is unused.  Otherwise consider:
 382                 --      x = 3
 383                 --      y = let p = x in 'x'    -- NB: p not used
 384                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 385                 -- bindings in the wrong order, and the type checker will complain
 386                 -- that x isn't in scope
 387                 --
 388                 -- But note that this means we won't report 'x' as unused,
 389                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 390
 391         ; return (result, all_uses) }}
 392                 -- The bound names are pruned out of all_uses
 393                 -- by the bindLocalNamesFV call above
 394
 395 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 396
 397
 398 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 399 -- (We keep the location around for reporting duplicate fixity declarations.)
 400 --
 401 -- Checks for duplicates, but not that only locally defined things are fixed.
 402 -- Note: for local fixity declarations, duplicates would also be checked in
 403 --       check_sigs below.  But we also use this function at the top level.
 404
 405 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 406
 407 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 408  where
 409    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 410      { -- this fixity decl is a duplicate iff
 411        -- the ReaderName's OccName's FastString is already in the env
 412        -- (we only need to check the local fix_env because
 413        --  definitions of non-local will be caught elsewhere)
 414        let { fs = occNameFS (rdrNameOcc name)
 415            ; fix_item = L loc fixity };
 416
 417        case lookupFsEnv env fs of
 418          Nothing -> return $ extendFsEnv env fs fix_item
 419          Just (L loc' _) -> do
 420            { setSrcSpan loc $
 421              addLocErr (L name_loc name) (dupFixityDecl loc')
 422            ; return env}
 423      }
 424
 425 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 426 dupFixityDecl loc rdr_name
 427   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 428           ptext (sLit "also at ") <+> ppr loc]
 429
 430 ---------------------
 431
 432 -- renaming a single bind
 433
 434 rnBindLHS :: NameMaker
 435           -> SDoc
 436           -> LHsBind RdrName
 437           -- returns the renamed left-hand side,
 438           -- and the FreeVars *of the LHS*
 439           -- (i.e., any free variables of the pattern)
 440           -> RnM (LHsBindLR Name RdrName)
 441
 442 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 443                                          pat_rhs = grhss,
 444                                          pat_rhs_ty=pat_rhs_ty
 445                                        }))
 446   = setSrcSpan loc $ do
 447       -- we don't actually use the FV processing of rnPatsAndThen here
 448       (pat',pat'_fvs) <- rnBindPat name_maker pat
 449       return (L loc (PatBind { pat_lhs = pat',
 450                                pat_rhs = grhss,
 451                                -- we temporarily store the pat's FVs here;
 452                                -- gets updated to the FVs of the whole bind
 453                                -- when doing the RHS below
 454                                bind_fvs = pat'_fvs,
 455                                -- these will get ignored in the next pass,
 456                                -- when we rename the RHS
 457                                pat_rhs_ty = pat_rhs_ty }))
 458
 459 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 460                                          fun_infix = inf,
 461                                          fun_matches = matches,
 462                                          fun_co_fn = fun_co_fn,
 463                                          fun_tick = fun_tick
 464                                        }))
 465   = setSrcSpan loc $
 466     do { (newname, _fvs) <- applyNameMaker name_maker name $ \ newname ->
 467                             return (newname, emptyFVs)
 468        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 469                                   fun_infix = inf,
 470                                   fun_matches = matches,
 471                                   -- we temporatily store the LHS's FVs (empty in this case) here
 472                                   -- gets updated when doing the RHS below
 473                                   bind_fvs = emptyFVs,
 474                                   -- everything else will get ignored in the next pass
 475                                   fun_co_fn = fun_co_fn,
 476                                   fun_tick = fun_tick
 477                                   })) }
 478
 479 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 480
 481 -- assumes the left-hands-side vars are in scope
 482 rnBind :: (Name -> [Name])              -- Signature tyvar function
 483        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 484        -> LHsBindLR Name RdrName
 485        -> RnM (LHsBind Name, [Name], Uses)
 486 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 487                                 pat_rhs = grhss,
 488                                 -- pat fvs were stored here while
 489                                 -- processing the LHS
 490                                 bind_fvs=pat_fvs }))
 491   = setSrcSpan loc $
 492     do  {let bndrs = collectPatBinders pat
 493
 494         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 495                 -- No scoped type variables for pattern bindings
 496         ; let fvs' = trim fvs
 497
 498         ; fvs' `seq` -- See Note [Free-variable space leak]
 499       return (L loc (PatBind { pat_lhs = pat,
 500                                   pat_rhs = grhss',
 501                                      pat_rhs_ty = placeHolderType,
 502                                   bind_fvs = fvs' }),
 503                   bndrs, pat_fvs `plusFV` fvs) }
 504
 505 rnBind sig_fn
 506        trim
 507        (L loc (FunBind { fun_id = name,
 508                          fun_infix = inf,
 509                          fun_matches = matches,
 510                          -- no pattern FVs
 511                          bind_fvs = _
 512                        }))
 513        -- invariant: no free vars here when it's a FunBind
 514   = setSrcSpan loc $
 515     do  { let plain_name = unLoc name
 516
 517         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 518                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 519                              rnMatchGroup (FunRhs plain_name inf) matches
 520         ; let fvs' = trim fvs
 521
 522         ; checkPrecMatch inf plain_name matches'
 523
 524         ; fvs' `seq` -- See Note [Free-variable space leak]
 525       return (L loc (FunBind { fun_id = name,
 526                                   fun_infix = inf,
 527                                   fun_matches = matches',
 528                                      bind_fvs = fvs',
 529                                   fun_co_fn = idHsWrapper,
 530                                   fun_tick = Nothing }),
 531                   [plain_name], fvs)
 532       }
 533
 534 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 535
 536 {-
 537 Note [Free-variable space leak]
 538 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 539 We have
 540     fvs' = trim fvs
 541 and we seq fvs' before turning it as part of a record.
 542
 543 The reason is that trim is sometimes something like
 544     \xs -> intersectNameSet (mkNameSet bound_names) xs
 545 and we don't want to retain the list bound_names. This showed up in
 546 trac ticket #1136.
 547 -}
 548
 549 ---------------------
 550 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 551              -> ([(RecFlag, LHsBinds Name)], DefUses)
 552 -- Dependency analysis; this is important so that
 553 -- unused-binding reporting is accurate
 554 depAnalBinds binds_w_dus
 555   = (map get_binds sccs, map get_du sccs)
 556   where
 557     sccs = stronglyConnCompFromEdgedVertices edges
 558
 559     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 560
 561     edges = [ (node, key, [key | n <- nameSetToList uses,
 562                                  Just key <- [lookupNameEnv key_map n] ])
 563             | (node@(_,_,uses), key) <- keyd_nodes ]
 564
 565     key_map :: NameEnv Int      -- Which binding it comes from
 566     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 567                                      , bndr <- bndrs ]
 568
 569     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 570     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 571
 572     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 573     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 574         where
 575           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 576           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 577
 578
 579 ---------------------
 580 -- Bind the top-level forall'd type variables in the sigs.
 581 -- E.g  f :: a -> a
 582 --      f = rhs
 583 --      The 'a' scopes over the rhs
 584 --
 585 -- NB: there'll usually be just one (for a function binding)
 586 --     but if there are many, one may shadow the rest; too bad!
 587 --      e.g  x :: [a] -> [a]
 588 --           y :: [(a,a)] -> a
 589 --           (x,y) = e
 590 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 591
 592 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 593 -- Return a lookup function that maps an Id Name to the names
 594 -- of the type variables that should scope over its body..
 595 mkSigTvFn sigs
 596   = \n -> lookupNameEnv env n `orElse` []
 597   where
 598     env :: NameEnv [Name]
 599     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 600                     | L _ (TypeSig (L _ name)
 601                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 602         -- Note the pattern-match on "Explicit"; we only bind
 603         -- type variables from signatures with an explicit top-level for-all
 604 \end{code}
 605
 606
 607 @rnMethodBinds@ is used for the method bindings of a class and an instance
 608 declaration.   Like @rnBinds@ but without dependency analysis.
 609
 610 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 611 That's crucial when dealing with an instance decl:
 612 \begin{verbatim}
 613         instance Foo (T a) where
 614            op x = ...
 615 \end{verbatim}
 616 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 617 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 618 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 619 in many ways the @op@ in an instance decl is just like an occurrence, not
 620 a binder.
 621
 622 \begin{code}
 623 rnMethodBinds :: Name                   -- Class name
 624               -> (Name -> [Name])       -- Signature tyvar function
 625               -> [Name]                 -- Names for generic type variables
 626               -> LHsBinds RdrName
 627               -> RnM (LHsBinds Name, FreeVars)
 628
 629 rnMethodBinds cls sig_fn gen_tyvars binds
 630   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 631   where do_one (binds,fvs) bind = do
 632            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 633            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 634
 635 rnMethodBind :: Name
 636               -> (Name -> [Name])
 637               -> [Name]
 638               -> LHsBindLR RdrName RdrName
 639               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 640 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = inf,
 641                                                      fun_matches = MatchGroup matches _ }))
 642   = setSrcSpan loc $ do
 643     sel_name <- lookupInstDeclBndr cls name
 644     let plain_name = unLoc sel_name
 645         -- We use the selector name as the binder
 646
 647     bindSigTyVarsFV (sig_fn plain_name) $ do
 648      (new_matches, fvs) <- mapFvRn (rn_match plain_name) matches
 649      let
 650          new_group = MatchGroup new_matches placeHolderType
 651
 652      checkPrecMatch inf plain_name new_group
 653      return (unitBag (L loc (FunBind {
 654                                 fun_id = sel_name, fun_infix = inf,
 655                                 fun_matches = new_group,
 656                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 657                                 fun_tick = Nothing })),
 658              fvs `addOneFV` plain_name)
 659         -- The 'fvs' field isn't used for method binds
 660   where
 661         -- Truly gruesome; bring into scope the correct members of the generic
 662         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 663     rn_match sel_name match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 664         = extendTyVarEnvFVRn gen_tvs    $
 665           rnMatch (FunRhs sel_name inf) match
 666         where
 667           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 668           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 669
 670     rn_match sel_name match = rnMatch (FunRhs sel_name inf) match
 671
 672
 673 -- Can't handle method pattern-bindings which bind multiple methods.
 674 rnMethodBind _ _ _ mbind@(L _ (PatBind _ _ _ _)) = do
 675     addLocErr mbind methodBindErr
 676     return (emptyBag, emptyFVs)
 677
 678 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 679 \end{code}
 680
 681
 682
 683 %************************************************************************
 684 %*                                                                      *
 685 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 686 %*                                                                      *
 687 %************************************************************************
 688
 689 @renameSigs@ checks for:
 690 \begin{enumerate}
 691 \item more than one sig for one thing;
 692 \item signatures given for things not bound here;
 693 \end{enumerate}
 694 %
 695 At the moment we don't gather free-var info from the types in
 696 signatures.  We'd only need this if we wanted to report unused tyvars.
 697
 698 \begin{code}
 699 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 700            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 701            -> [LSig RdrName]
 702            -> RnM [LSig Name]
 703 -- Renames the signatures and performs error checks
 704 renameSigs mb_names ok_sig sigs
 705   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 706         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 707         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 708         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 709         ; return sigs' }
 710
 711 ----------------------
 712 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 713 -- because this won't work for:
 714 --      instance Foo T where
 715 --        {-# INLINE op #-}
 716 --        Baz.op = ...
 717 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 718 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 719 -- Doesn't seem worth much trouble to sort this.
 720
 721 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 722 -- FixitySig is renamed elsewhere.
 723 renameSig mb_names sig@(TypeSig v ty)
 724   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 725         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 726         ; return (TypeSig new_v new_ty) }
 727
 728 renameSig _ (SpecInstSig ty)
 729   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 730         ; return (SpecInstSig new_ty) }
 731
 732 renameSig mb_names sig@(SpecSig v ty inl)
 733   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 734         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 735         ; return (SpecSig new_v new_ty inl) }
 736
 737 renameSig mb_names sig@(InlineSig v s)
 738   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 739         ; return (InlineSig new_v s) }
 740
 741 renameSig mb_names sig@(FixSig (FixitySig v f))
 742   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 743         ; return (FixSig (FixitySig new_v f)) }
 744
 745 -- lookupSigOccRn is used for type signatures and pragmas
 746 -- Is this valid?
 747 --   module A
 748 --      import M( f )
 749 --      f :: Int -> Int
 750 --      f x = x
 751 -- It's clear that the 'f' in the signature must refer to A.f
 752 -- The Haskell98 report does not stipulate this, but it will!
 753 -- So we must treat the 'f' in the signature in the same way
 754 -- as the binding occurrence of 'f', using lookupBndrRn
 755 --
 756 -- However, consider this case:
 757 --      import M( f )
 758 --      f :: Int -> Int
 759 --      g x = x
 760 -- We don't want to say 'f' is out of scope; instead, we want to
 761 -- return the imported 'f', so that later on the reanamer will
 762 -- correctly report "misplaced type sig".
 763
 764 lookupSigLocOccRn :: Maybe NameSet -> Sig RdrName -> Located RdrName -> RnM (Located Name)
 765 lookupSigLocOccRn mb_names sig = wrapLocM (lookupSigOccRn mb_names sig)
 766
 767 lookupSigOccRn :: Maybe NameSet -> Sig RdrName -> RdrName -> RnM Name
 768 lookupSigOccRn mb_names sig v
 769   = do  { mb_n <- lookupBndrRn_maybe v
 770         ; case mb_n of {
 771             Just n  -> case mb_names of {
 772                         Nothing                      -> return n ;
 773                         Just ns | n `elemNameSet` ns -> return n
 774                                 | otherwise -> bale_out_with local_msg } ;
 775
 776             Nothing -> do
 777         { mb_n <- lookupGreRn_maybe v
 778         ; case mb_n of
 779             Just _  -> bale_out_with import_msg
 780             Nothing -> bale_out_with empty
 781         } }}
 782   where
 783     bale_out_with msg
 784         = do { addErr (sep [ ptext (sLit "The") <+> hsSigDoc sig
 785                                 <+> ptext (sLit "for") <+> quotes (ppr v)
 786                            , nest 2 $ ptext (sLit "lacks an accompanying binding")]
 787                        $$ nest 2 msg)
 788              ; return (mkUnboundName v) }
 789
 790     local_msg = parens $ ptext (sLit "The")  <+> hsSigDoc sig <+> ptext (sLit "must be given where")
 791                          <+> quotes (ppr v) <+> ptext (sLit "is declared")
 792
 793     import_msg = parens $ ptext (sLit "You cannot give a") <+> hsSigDoc sig
 794                           <+> ptext (sLit "an imported value")
 795 \end{code}
 796
 797
 798 %************************************************************************
 799 %*                                                                      *
 800 \subsection{Match}
 801 %*                                                                      *
 802 %************************************************************************
 803
 804 \begin{code}
 805 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 806 rnMatchGroup ctxt (MatchGroup ms _)
 807   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 808        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 809
 810 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 811 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 812
 813 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 814 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 815   = do  {       -- Result type signatures are no longer supported
 816           case maybe_rhs_sig of
 817                 Nothing -> return ()
 818                 Just ty -> addLocErr ty (resSigErr ctxt match)
 819
 820
 821                -- Now the main event
 822                -- note that there are no local ficity decls for matches
 823         ; rnPatsAndThen_LocalRightwards ctxt pats       $ \ pats' -> do
 824         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 825
 826         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 827         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 828   where
 829
 830 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 831 resSigErr ctxt match ty
 832    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 833           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 834           , pprMatchInCtxt ctxt match ]
 835 \end{code}
 836
 837
 838 %************************************************************************
 839 %*                                                                      *
 840 \subsubsection{Guarded right-hand sides (GRHSs)}
 841 %*                                                                      *
 842 %************************************************************************
 843
 844 \begin{code}
 845 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 846
 847 rnGRHSs ctxt (GRHSs grhss binds)
 848   = rnLocalBindsAndThen binds   $ \ binds' -> do
 849     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 850     return (GRHSs grhss' binds', fvGRHSs)
 851
 852 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 853 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 854
 855 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 856 rnGRHS' ctxt (GRHS guards rhs)
 857   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 858         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 859                                     rnLExpr rhs
 860
 861         ; unless (pattern_guards_allowed || is_standard_guard guards')
 862                  (addWarn (nonStdGuardErr guards'))
 863
 864         ; return (GRHS guards' rhs', fvs) }
 865   where
 866         -- Standard Haskell 1.4 guards are just a single boolean
 867         -- expression, rather than a list of qualifiers as in the
 868         -- Glasgow extension
 869     is_standard_guard []                     = True
 870     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 871     is_standard_guard _                      = False
 872 \end{code}
 873
 874 %************************************************************************
 875 %*                                                                      *
 876 \subsection{Error messages}
 877 %*                                                                      *
 878 %************************************************************************
 879
 880 \begin{code}
 881 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 882 dupSigDeclErr sigs@(L loc sig : _)
 883   = addErrAt loc $
 884         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 885               nest 2 (vcat (map ppr_sig sigs))]
 886   where
 887     what_it_is = hsSigDoc sig
 888     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 889 dupSigDeclErr [] = panic "dupSigDeclErr"
 890
 891 unknownSigErr :: LSig RdrName -> RnM ()
 892 unknownSigErr (L loc sig)
 893   = addErrAt loc $
 894     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 895
 896 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 897 methodBindErr mbind
 898  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 899        2 (ppr mbind)
 900
 901 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 902 bindsInHsBootFile mbinds
 903   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 904        2 (ppr mbinds)
 905
 906 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 907 nonStdGuardErr guards
 908   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 909        4 (interpp'SP guards)
 910 \end{code}