compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPats, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import DynFlags ( DynFlag(..) )
  32 import Name
  33 import NameEnv
  34 import NameSet
  35 import RdrName          ( RdrName, rdrNameOcc )
  36 import SrcLoc
  37 import ListSetOps       ( findDupsEq )
  38 import BasicTypes       ( RecFlag(..) )
  39 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  40 import Bag
  41 import Outputable
  42 import FastString
  43 import Data.List        ( partition )
  44 import Maybes           ( orElse )
  45 import Control.Monad
  46 \end{code}
  47
  48 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  49 -- place and can be used when complaining.
  50
  51 The code tree received by the function @rnBinds@ contains definitions
  52 in where-clauses which are all apparently mutually recursive, but which may
  53 not really depend upon each other. For example, in the top level program
  54 \begin{verbatim}
  55 f x = y where a = x
  56               y = x
  57 \end{verbatim}
  58 the definitions of @a@ and @y@ do not depend on each other at all.
  59 Unfortunately, the typechecker cannot always check such definitions.
  60 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  61 definitions. In Proceedings of the International Symposium on Programming,
  62 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  63 However, the typechecker usually can check definitions in which only the
  64 strongly connected components have been collected into recursive bindings.
  65 This is precisely what the function @rnBinds@ does.
  66
  67 ToDo: deal with case where a single monobinds binds the same variable
  68 twice.
  69
  70 The vertag tag is a unique @Int@; the tags only need to be unique
  71 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  72 (heavy monad machinery not needed).
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77 %* naming conventions                                                   *
  78 %*                                                                      *
  79 %************************************************************************
  80
  81 \subsection[name-conventions]{Name conventions}
  82
  83 The basic algorithm involves walking over the tree and returning a tuple
  84 containing the new tree plus its free variables. Some functions, such
  85 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  86 list comprehensions (@Quals@), return the variables bound in local
  87 environments. These are then used to calculate the free variables of the
  88 expression evaluated in these environments.
  89
  90 Conventions for variable names are as follows:
  91 \begin{itemize}
  92 \item
  93 new code is given a prime to distinguish it from the old.
  94
  95 \item
  96 a set of variables defined in @Exp@ is written @dvExp@
  97
  98 \item
  99 a set of variables free in @Exp@ is written @fvExp@
 100 \end{itemize}
 101
 102 %************************************************************************
 103 %*                                                                      *
 104 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 109
 110 Non-recursive expressions are reconstructed without any changes at top
 111 level, although their component expressions may have to be altered.
 112 However, non-recursive expressions are currently not expected as
 113 \Haskell{} programs, and this code should not be executed.
 114
 115 Monomorphic bindings contain information that is returned in a tuple
 116 (a @FlatMonoBinds@) containing:
 117
 118 \begin{enumerate}
 119 \item
 120 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 121
 122 \item
 123 the name of a function or the names in a pattern. These are a set
 124 referred to as @dvLhs@, the defined variables of the left hand side.
 125
 126 \item
 127 the free variables of the body. These are referred to as @fvBody@.
 128
 129 \item
 130 the definition's actual code. This is referred to as just @code@.
 131 \end{enumerate}
 132
 133 The function @nonRecDvFv@ returns two sets of variables. The first is
 134 the set of variables defined in the set of monomorphic bindings, while the
 135 second is the set of free variables in those bindings.
 136
 137 The set of variables defined in a non-recursive binding is just the
 138 union of all of them, as @union@ removes duplicates. However, the
 139 free variables in each successive set of cumulative bindings is the
 140 union of those in the previous set plus those of the newest binding after
 141 the defined variables of the previous set have been removed.
 142
 143 @rnMethodBinds@ deals only with the declarations in class and
 144 instance declarations.  It expects only to see @FunMonoBind@s, and
 145 it expects the global environment to contain bindings for the binders
 146 (which are all class operations).
 147
 148 %************************************************************************
 149 %*                                                                      *
 150 \subsubsection{ Top-level bindings}
 151 %*                                                                      *
 152 %************************************************************************
 153
 154 \begin{code}
 155 -- for top-level bindings, we need to make top-level names,
 156 -- so we have a different entry point than for local bindings
 157 rnTopBindsLHS :: MiniFixityEnv
 158               -> HsValBinds RdrName
 159               -> RnM (HsValBindsLR Name RdrName)
 160 rnTopBindsLHS fix_env binds
 161   = rnValBindsLHSFromDoc (topRecNameMaker fix_env) binds
 162
 163 rnTopBindsRHS :: NameSet        -- Names bound by these binds
 164               -> HsValBindsLR Name RdrName
 165               -> RnM (HsValBinds Name, DefUses)
 166 rnTopBindsRHS bound_names binds =
 167     do { is_boot <- tcIsHsBoot
 168        ; if is_boot
 169          then rnTopBindsBoot binds
 170          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 171                                bound_names binds }
 172
 173 -- Wrapper if we don't need to do anything in between the left and right,
 174 -- or anything else in the scope of the left
 175 --
 176 -- Never used when there are fixity declarations
 177 rnTopBinds :: HsValBinds RdrName
 178            -> RnM (HsValBinds Name, DefUses)
 179 rnTopBinds b =
 180   do nl <- rnTopBindsLHS emptyFsEnv b
 181      let bound_names = collectHsValBinders nl
 182      bindLocalNames bound_names $ rnTopBindsRHS (mkNameSet bound_names) nl
 183
 184
 185 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 186 -- A hs-boot file has no bindings.
 187 -- Return a single HsBindGroup with empty binds and renamed signatures
 188 rnTopBindsBoot (ValBindsIn mbinds sigs)
 189   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 190         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 191         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 192 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 193 \end{code}
 194
 195
 196
 197 %*********************************************************
 198 %*                                                      *
 199                 HsLocalBinds
 200 %*                                                      *
 201 %*********************************************************
 202
 203 \begin{code}
 204 rnLocalBindsAndThen :: HsLocalBinds RdrName
 205                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 206                     -> RnM (result, FreeVars)
 207 -- This version (a) assumes that the binding vars are *not* already in scope
 208 --               (b) removes the binders from the free vars of the thing inside
 209 -- The parser doesn't produce ThenBinds
 210 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 211   = thing_inside EmptyLocalBinds
 212
 213 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 214   = rnValBindsAndThen val_binds $ \ val_binds' ->
 215       thing_inside (HsValBinds val_binds')
 216
 217 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 218     (binds',fv_binds) <- rnIPBinds binds
 219     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 220     return (thing, fvs_thing `plusFV` fv_binds)
 221
 222 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 223 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 224     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 225     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 226
 227 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 228 rnIPBind (IPBind n expr) = do
 229     name <- newIPNameRn  n
 230     (expr',fvExpr) <- rnLExpr expr
 231     return (IPBind name expr', fvExpr)
 232 \end{code}
 233
 234
 235 %************************************************************************
 236 %*                                                                      *
 237                 ValBinds
 238 %*                                                                      *
 239 %************************************************************************
 240
 241 \begin{code}
 242 -- Renaming local binding gropus
 243 -- Does duplicate/shadow check
 244 rnValBindsLHS :: MiniFixityEnv
 245               -> HsValBinds RdrName
 246               -> RnM ([Name], HsValBindsLR Name RdrName)
 247 rnValBindsLHS fix_env binds
 248   = do { -- Do error checking: we need to check for dups here because we
 249          -- don't don't bind all of the variables from the ValBinds at once
 250          -- with bindLocatedLocals any more.
 251          --
 252          -- Note that we don't want to do this at the top level, since
 253          -- sorting out duplicates and shadowing there happens elsewhere.
 254          -- The behavior is even different. For example,
 255          --   import A(f)
 256          --   f = ...
 257          -- should not produce a shadowing warning (but it will produce
 258          -- an ambiguity warning if you use f), but
 259          --   import A(f)
 260          --   g = let f = ... in f
 261          -- should.
 262        ; binds' <- rnValBindsLHSFromDoc (localRecNameMaker fix_env) binds
 263        ; let bound_names = collectHsValBinders binds'
 264        ; envs <- getRdrEnvs
 265        ; checkDupAndShadowedNames envs bound_names
 266        ; return (bound_names, binds') }
 267
 268 -- renames the left-hand sides
 269 -- generic version used both at the top level and for local binds
 270 -- does some error checking, but not what gets done elsewhere at the top level
 271 rnValBindsLHSFromDoc :: NameMaker
 272                      -> HsValBinds RdrName
 273                      -> RnM (HsValBindsLR Name RdrName)
 274 rnValBindsLHSFromDoc topP (ValBindsIn mbinds sigs)
 275   = do { mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 276        ; return $ ValBindsIn mbinds' sigs }
 277   where
 278     bndrs = collectHsBindsBinders mbinds
 279     doc   = text "In the binding group for:" <+> pprWithCommas ppr bndrs
 280
 281 rnValBindsLHSFromDoc _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 282
 283 -- General version used both from the top-level and for local things
 284 -- Assumes the LHS vars are in scope
 285 --
 286 -- Does not bind the local fixity declarations
 287 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 288                      -- The trimming function trims the free vars we attach to a
 289                      -- binding so that it stays reasonably small
 290                  -> NameSet     -- Names bound by the LHSes
 291                  -> HsValBindsLR Name RdrName
 292                  -> RnM (HsValBinds Name, DefUses)
 293
 294 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs)
 295   = do {  -- rename the sigs
 296          sigs' <- renameSigs (Just bound_names) okBindSig sigs
 297           -- rename the RHSes
 298        ; binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 299        ; case depAnalBinds binds_w_dus of
 300             (anal_binds, anal_dus) -> do
 301        { let valbind' = ValBindsOut anal_binds sigs'
 302              valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 303        ; return (valbind', valbind'_dus) }}
 304
 305 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 306
 307 -- Wrapper for local binds
 308 --
 309 -- The *client* of this function is responsible for checking for unused binders;
 310 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 311 --
 312 -- The client is also responsible for bringing the fixities into scope
 313 rnValBindsRHS :: NameSet  -- names bound by the LHSes
 314               -> HsValBindsLR Name RdrName
 315               -> RnM (HsValBinds Name, DefUses)
 316 rnValBindsRHS bound_names binds
 317   = rnValBindsRHSGen trim bound_names binds
 318   where
 319     trim fvs = intersectNameSet bound_names fvs
 320         -- Only keep the names the names from this group
 321
 322 -- for local binds
 323 -- wrapper that does both the left- and right-hand sides
 324 --
 325 -- here there are no local fixity decls passed in;
 326 -- the local fixity decls come from the ValBinds sigs
 327 rnValBindsAndThen :: HsValBinds RdrName
 328                   -> (HsValBinds Name -> RnM (result, FreeVars))
 329                   -> RnM (result, FreeVars)
 330 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 331  = do   {     -- (A) Create the local fixity environment
 332           new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 333
 334               -- (B) Rename the LHSes
 335         ; (bound_names, new_lhs) <- rnValBindsLHS new_fixities binds
 336
 337               --     ...and bring them (and their fixities) into scope
 338         ; bindLocalNamesFV bound_names              $
 339           addLocalFixities new_fixities bound_names $ do
 340
 341         {      -- (C) Do the RHS and thing inside
 342           (binds', dus) <- rnValBindsRHS (mkNameSet bound_names) new_lhs
 343         ; (result, result_fvs) <- thing_inside binds'
 344
 345                 -- Report unused bindings based on the (accurate)
 346                 -- findUses.  E.g.
 347                 --      let x = x in 3
 348                 -- should report 'x' unused
 349         ; let real_uses = findUses dus result_fvs
 350         ; warnUnusedLocalBinds bound_names real_uses
 351
 352         ; let
 353             -- The variables "used" in the val binds are:
 354             --   (1) the uses of the binds (allUses)
 355             --   (2) the FVs of the thing-inside
 356             all_uses = allUses dus `plusFV` result_fvs
 357                 -- Note [Unused binding hack]
 358                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 359                 -- Note that *in contrast* to the above reporting of
 360                 -- unused bindings, (1) above uses duUses to return *all*
 361                 -- the uses, even if the binding is unused.  Otherwise consider:
 362                 --      x = 3
 363                 --      y = let p = x in 'x'    -- NB: p not used
 364                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 365                 -- bindings in the wrong order, and the type checker will complain
 366                 -- that x isn't in scope
 367                 --
 368                 -- But note that this means we won't report 'x' as unused,
 369                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 370
 371         ; return (result, all_uses) }}
 372                 -- The bound names are pruned out of all_uses
 373                 -- by the bindLocalNamesFV call above
 374
 375 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 376
 377
 378 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 379 -- (We keep the location around for reporting duplicate fixity declarations.)
 380 --
 381 -- Checks for duplicates, but not that only locally defined things are fixed.
 382 -- Note: for local fixity declarations, duplicates would also be checked in
 383 --       check_sigs below.  But we also use this function at the top level.
 384
 385 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 386
 387 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 388  where
 389    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 390      { -- this fixity decl is a duplicate iff
 391        -- the ReaderName's OccName's FastString is already in the env
 392        -- (we only need to check the local fix_env because
 393        --  definitions of non-local will be caught elsewhere)
 394        let { fs = occNameFS (rdrNameOcc name)
 395            ; fix_item = L loc fixity };
 396
 397        case lookupFsEnv env fs of
 398          Nothing -> return $ extendFsEnv env fs fix_item
 399          Just (L loc' _) -> do
 400            { setSrcSpan loc $
 401              addErrAt name_loc (dupFixityDecl loc' name)
 402            ; return env}
 403      }
 404
 405 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 406 dupFixityDecl loc rdr_name
 407   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 408           ptext (sLit "also at ") <+> ppr loc]
 409
 410 ---------------------
 411
 412 -- renaming a single bind
 413
 414 rnBindLHS :: NameMaker
 415           -> SDoc
 416           -> LHsBind RdrName
 417           -- returns the renamed left-hand side,
 418           -- and the FreeVars *of the LHS*
 419           -- (i.e., any free variables of the pattern)
 420           -> RnM (LHsBindLR Name RdrName)
 421
 422 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 423                                          pat_rhs = grhss,
 424                                          pat_rhs_ty=pat_rhs_ty
 425                                        }))
 426   = setSrcSpan loc $ do
 427       -- we don't actually use the FV processing of rnPatsAndThen here
 428       (pat',pat'_fvs) <- rnBindPat name_maker pat
 429       return (L loc (PatBind { pat_lhs = pat',
 430                                pat_rhs = grhss,
 431                                -- we temporarily store the pat's FVs here;
 432                                -- gets updated to the FVs of the whole bind
 433                                -- when doing the RHS below
 434                                bind_fvs = pat'_fvs,
 435                                -- these will get ignored in the next pass,
 436                                -- when we rename the RHS
 437                                pat_rhs_ty = pat_rhs_ty }))
 438
 439 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 440                                          fun_infix = inf,
 441                                          fun_matches = matches,
 442                                          fun_co_fn = fun_co_fn,
 443                                          fun_tick = fun_tick
 444                                        }))
 445   = setSrcSpan loc $
 446     do { newname <- applyNameMaker name_maker name
 447        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 448                                   fun_infix = inf,
 449                                   fun_matches = matches,
 450                                   -- we temporatily store the LHS's FVs (empty in this case) here
 451                                   -- gets updated when doing the RHS below
 452                                   bind_fvs = emptyFVs,
 453                                   -- everything else will get ignored in the next pass
 454                                   fun_co_fn = fun_co_fn,
 455                                   fun_tick = fun_tick
 456                                   })) }
 457
 458 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 459
 460 -- assumes the left-hands-side vars are in scope
 461 rnBind :: (Name -> [Name])              -- Signature tyvar function
 462        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 463        -> LHsBindLR Name RdrName
 464        -> RnM (LHsBind Name, [Name], Uses)
 465 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 466                                 pat_rhs = grhss,
 467                                 -- pat fvs were stored here while
 468                                 -- after processing the LHS
 469                                 bind_fvs = pat_fvs }))
 470   = setSrcSpan loc $
 471     do  {let bndrs = collectPatBinders pat
 472
 473         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 474                 -- No scoped type variables for pattern bindings
 475         ; let all_fvs = pat_fvs `plusFV` fvs
 476               fvs'    = trim all_fvs
 477
 478         ; fvs' `seq` -- See Note [Free-variable space leak]
 479           return (L loc (PatBind { pat_lhs    = pat,
 480                                    pat_rhs    = grhss',
 481                                    pat_rhs_ty = placeHolderType,
 482                                    bind_fvs   = fvs' }),
 483                   bndrs, all_fvs) }
 484
 485 rnBind sig_fn
 486        trim
 487        (L loc (FunBind { fun_id = name,
 488                          fun_infix = is_infix,
 489                          fun_matches = matches,
 490                          -- no pattern FVs
 491                          bind_fvs = _
 492                        }))
 493        -- invariant: no free vars here when it's a FunBind
 494   = setSrcSpan loc $
 495     do  { let plain_name = unLoc name
 496
 497         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 498                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 499                              rnMatchGroup (FunRhs plain_name is_infix) matches
 500         ; let fvs' = trim fvs
 501
 502         ; when is_infix $ checkPrecMatch plain_name matches'
 503
 504         ; fvs' `seq` -- See Note [Free-variable space leak]
 505
 506           return (L loc (FunBind { fun_id = name,
 507                                    fun_infix = is_infix,
 508                                    fun_matches = matches',
 509                                    bind_fvs = fvs',
 510                                    fun_co_fn = idHsWrapper,
 511                                    fun_tick = Nothing }),
 512                   [plain_name], fvs)
 513       }
 514
 515 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 516
 517 {-
 518 Note [Free-variable space leak]
 519 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 520 We have
 521     fvs' = trim fvs
 522 and we seq fvs' before turning it as part of a record.
 523
 524 The reason is that trim is sometimes something like
 525     \xs -> intersectNameSet (mkNameSet bound_names) xs
 526 and we don't want to retain the list bound_names. This showed up in
 527 trac ticket #1136.
 528 -}
 529
 530 ---------------------
 531 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 532              -> ([(RecFlag, LHsBinds Name)], DefUses)
 533 -- Dependency analysis; this is important so that
 534 -- unused-binding reporting is accurate
 535 depAnalBinds binds_w_dus
 536   = (map get_binds sccs, map get_du sccs)
 537   where
 538     sccs = stronglyConnCompFromEdgedVertices edges
 539
 540     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 541
 542     edges = [ (node, key, [key | n <- nameSetToList uses,
 543                                  Just key <- [lookupNameEnv key_map n] ])
 544             | (node@(_,_,uses), key) <- keyd_nodes ]
 545
 546     key_map :: NameEnv Int      -- Which binding it comes from
 547     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 548                                      , bndr <- bndrs ]
 549
 550     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 551     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 552
 553     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 554     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 555         where
 556           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 557           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 558
 559
 560 ---------------------
 561 -- Bind the top-level forall'd type variables in the sigs.
 562 -- E.g  f :: a -> a
 563 --      f = rhs
 564 --      The 'a' scopes over the rhs
 565 --
 566 -- NB: there'll usually be just one (for a function binding)
 567 --     but if there are many, one may shadow the rest; too bad!
 568 --      e.g  x :: [a] -> [a]
 569 --           y :: [(a,a)] -> a
 570 --           (x,y) = e
 571 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 572
 573 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 574 -- Return a lookup function that maps an Id Name to the names
 575 -- of the type variables that should scope over its body..
 576 mkSigTvFn sigs
 577   = \n -> lookupNameEnv env n `orElse` []
 578   where
 579     env :: NameEnv [Name]
 580     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 581                     | L _ (TypeSig (L _ name)
 582                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 583         -- Note the pattern-match on "Explicit"; we only bind
 584         -- type variables from signatures with an explicit top-level for-all
 585 \end{code}
 586
 587
 588 @rnMethodBinds@ is used for the method bindings of a class and an instance
 589 declaration.   Like @rnBinds@ but without dependency analysis.
 590
 591 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 592 That's crucial when dealing with an instance decl:
 593 \begin{verbatim}
 594         instance Foo (T a) where
 595            op x = ...
 596 \end{verbatim}
 597 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 598 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 599 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 600 in many ways the @op@ in an instance decl is just like an occurrence, not
 601 a binder.
 602
 603 \begin{code}
 604 rnMethodBinds :: Name                   -- Class name
 605               -> (Name -> [Name])       -- Signature tyvar function
 606               -> [Name]                 -- Names for generic type variables
 607               -> LHsBinds RdrName
 608               -> RnM (LHsBinds Name, FreeVars)
 609
 610 rnMethodBinds cls sig_fn gen_tyvars binds
 611   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 612   where do_one (binds,fvs) bind = do
 613            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 614            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 615
 616 rnMethodBind :: Name
 617               -> (Name -> [Name])
 618               -> [Name]
 619               -> LHsBindLR RdrName RdrName
 620               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 621 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = is_infix,
 622                                                      fun_matches = MatchGroup matches _ }))
 623   = setSrcSpan loc $ do
 624     sel_name <- wrapLocM (lookupInstDeclBndr cls) name
 625     let plain_name = unLoc sel_name
 626         -- We use the selector name as the binder
 627
 628     (new_matches, fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 629                           mapFvRn (rn_match (FunRhs plain_name is_infix)) matches
 630     let new_group = MatchGroup new_matches placeHolderType
 631
 632     when is_infix $ checkPrecMatch plain_name new_group
 633     return (unitBag (L loc (FunBind {
 634                                 fun_id = sel_name, fun_infix = is_infix,
 635                                 fun_matches = new_group,
 636                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 637                                 fun_tick = Nothing })),
 638              fvs `addOneFV` plain_name)
 639         -- The 'fvs' field isn't used for method binds
 640   where
 641         -- Truly gruesome; bring into scope the correct members of the generic
 642         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 643     rn_match info match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 644         = extendTyVarEnvFVRn gen_tvs    $
 645           rnMatch info match
 646         where
 647           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 648           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 649
 650     rn_match info match = rnMatch info match
 651
 652 -- Can't handle method pattern-bindings which bind multiple methods.
 653 rnMethodBind _ _ _ (L loc bind@(PatBind {})) = do
 654     addErrAt loc (methodBindErr bind)
 655     return (emptyBag, emptyFVs)
 656
 657 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 658 \end{code}
 659
 660
 661
 662 %************************************************************************
 663 %*                                                                      *
 664 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 665 %*                                                                      *
 666 %************************************************************************
 667
 668 @renameSigs@ checks for:
 669 \begin{enumerate}
 670 \item more than one sig for one thing;
 671 \item signatures given for things not bound here;
 672 \end{enumerate}
 673 %
 674 At the moment we don't gather free-var info from the types in
 675 signatures.  We'd only need this if we wanted to report unused tyvars.
 676
 677 \begin{code}
 678 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 679            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 680            -> [LSig RdrName]
 681            -> RnM [LSig Name]
 682 -- Renames the signatures and performs error checks
 683 renameSigs mb_names ok_sig sigs
 684   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 685         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 686         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 687         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 688         ; return sigs' }
 689
 690 ----------------------
 691 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 692 -- because this won't work for:
 693 --      instance Foo T where
 694 --        {-# INLINE op #-}
 695 --        Baz.op = ...
 696 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 697 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 698 -- Doesn't seem worth much trouble to sort this.
 699
 700 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 701 -- FixitySig is renamed elsewhere.
 702 renameSig _ (IdSig x)
 703   = return (IdSig x)      -- Actually this never occurs
 704 renameSig mb_names sig@(TypeSig v ty)
 705   = do  { new_v <- lookupSigOccRn mb_names sig v
 706         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 707         ; return (TypeSig new_v new_ty) }
 708
 709 renameSig _ (SpecInstSig ty)
 710   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 711         ; return (SpecInstSig new_ty) }
 712
 713 renameSig mb_names sig@(SpecSig v ty inl)
 714   = do  { new_v <- lookupSigOccRn mb_names sig v
 715         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 716         ; return (SpecSig new_v new_ty inl) }
 717
 718 renameSig mb_names sig@(InlineSig v s)
 719   = do  { new_v <- lookupSigOccRn mb_names sig v
 720         ; return (InlineSig new_v s) }
 721
 722 renameSig mb_names sig@(FixSig (FixitySig v f))
 723   = do  { new_v <- lookupSigOccRn mb_names sig v
 724         ; return (FixSig (FixitySig new_v f)) }
 725 \end{code}
 726
 727
 728 %************************************************************************
 729 %*                                                                      *
 730 \subsection{Match}
 731 %*                                                                      *
 732 %************************************************************************
 733
 734 \begin{code}
 735 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 736 rnMatchGroup ctxt (MatchGroup ms _)
 737   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 738        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 739
 740 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 741 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 742
 743 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 744 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 745   = do  {       -- Result type signatures are no longer supported
 746           case maybe_rhs_sig of
 747                 Nothing -> return ()
 748                 Just (L loc ty) -> addErrAt loc (resSigErr ctxt match ty)
 749
 750                -- Now the main event
 751                -- note that there are no local ficity decls for matches
 752         ; rnPats ctxt pats      $ \ pats' -> do
 753         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 754
 755         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 756         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 757
 758 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 759 resSigErr ctxt match ty
 760    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 761           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 762           , pprMatchInCtxt ctxt match ]
 763 \end{code}
 764
 765
 766 %************************************************************************
 767 %*                                                                      *
 768 \subsubsection{Guarded right-hand sides (GRHSs)}
 769 %*                                                                      *
 770 %************************************************************************
 771
 772 \begin{code}
 773 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 774
 775 rnGRHSs ctxt (GRHSs grhss binds)
 776   = rnLocalBindsAndThen binds   $ \ binds' -> do
 777     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 778     return (GRHSs grhss' binds', fvGRHSs)
 779
 780 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 781 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 782
 783 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 784 rnGRHS' ctxt (GRHS guards rhs)
 785   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 786         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 787                                     rnLExpr rhs
 788
 789         ; unless (pattern_guards_allowed || is_standard_guard guards')
 790                  (addWarn (nonStdGuardErr guards'))
 791
 792         ; return (GRHS guards' rhs', fvs) }
 793   where
 794         -- Standard Haskell 1.4 guards are just a single boolean
 795         -- expression, rather than a list of qualifiers as in the
 796         -- Glasgow extension
 797     is_standard_guard []                     = True
 798     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 799     is_standard_guard _                      = False
 800 \end{code}
 801
 802 %************************************************************************
 803 %*                                                                      *
 804 \subsection{Error messages}
 805 %*                                                                      *
 806 %************************************************************************
 807
 808 \begin{code}
 809 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 810 dupSigDeclErr sigs@(L loc sig : _)
 811   = addErrAt loc $
 812         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 813               nest 2 (vcat (map ppr_sig sigs))]
 814   where
 815     what_it_is = hsSigDoc sig
 816     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 817 dupSigDeclErr [] = panic "dupSigDeclErr"
 818
 819 unknownSigErr :: LSig RdrName -> RnM ()
 820 unknownSigErr (L loc sig)
 821   = addErrAt loc $
 822     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 823
 824 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 825 methodBindErr mbind
 826  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 827        2 (ppr mbind)
 828
 829 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 830 bindsInHsBootFile mbinds
 831   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 832        2 (ppr mbinds)
 833
 834 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 835 nonStdGuardErr guards
 836   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 837        4 (interpp'SP guards)
 838 \end{code}