compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPatsAndThen_LocalRightwards, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import PrelNames        ( mkUnboundName )
  32 import DynFlags ( DynFlag(..) )
  33 import Name
  34 import NameEnv
  35 import NameSet
  36 import RdrName          ( RdrName, rdrNameOcc )
  37 import SrcLoc
  38 import ListSetOps       ( findDupsEq )
  39 import BasicTypes       ( RecFlag(..) )
  40 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  41 import Bag
  42 import Outputable
  43 import FastString
  44 import Data.List        ( partition )
  45 import Maybes           ( orElse )
  46 import Monad            ( foldM, unless )
  47 \end{code}
  48
  49 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  50 -- place and can be used when complaining.
  51
  52 The code tree received by the function @rnBinds@ contains definitions
  53 in where-clauses which are all apparently mutually recursive, but which may
  54 not really depend upon each other. For example, in the top level program
  55 \begin{verbatim}
  56 f x = y where a = x
  57               y = x
  58 \end{verbatim}
  59 the definitions of @a@ and @y@ do not depend on each other at all.
  60 Unfortunately, the typechecker cannot always check such definitions.
  61 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  62 definitions. In Proceedings of the International Symposium on Programming,
  63 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  64 However, the typechecker usually can check definitions in which only the
  65 strongly connected components have been collected into recursive bindings.
  66 This is precisely what the function @rnBinds@ does.
  67
  68 ToDo: deal with case where a single monobinds binds the same variable
  69 twice.
  70
  71 The vertag tag is a unique @Int@; the tags only need to be unique
  72 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  73 (heavy monad machinery not needed).
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 %* naming conventions                                                   *
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \subsection[name-conventions]{Name conventions}
  83
  84 The basic algorithm involves walking over the tree and returning a tuple
  85 containing the new tree plus its free variables. Some functions, such
  86 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  87 list comprehensions (@Quals@), return the variables bound in local
  88 environments. These are then used to calculate the free variables of the
  89 expression evaluated in these environments.
  90
  91 Conventions for variable names are as follows:
  92 \begin{itemize}
  93 \item
  94 new code is given a prime to distinguish it from the old.
  95
  96 \item
  97 a set of variables defined in @Exp@ is written @dvExp@
  98
  99 \item
 100 a set of variables free in @Exp@ is written @fvExp@
 101 \end{itemize}
 102
 103 %************************************************************************
 104 %*                                                                      *
 105 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 106 %*                                                                      *
 107 %************************************************************************
 108
 109 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 110
 111 Non-recursive expressions are reconstructed without any changes at top
 112 level, although their component expressions may have to be altered.
 113 However, non-recursive expressions are currently not expected as
 114 \Haskell{} programs, and this code should not be executed.
 115
 116 Monomorphic bindings contain information that is returned in a tuple
 117 (a @FlatMonoBinds@) containing:
 118
 119 \begin{enumerate}
 120 \item
 121 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 122
 123 \item
 124 the name of a function or the names in a pattern. These are a set
 125 referred to as @dvLhs@, the defined variables of the left hand side.
 126
 127 \item
 128 the free variables of the body. These are referred to as @fvBody@.
 129
 130 \item
 131 the definition's actual code. This is referred to as just @code@.
 132 \end{enumerate}
 133
 134 The function @nonRecDvFv@ returns two sets of variables. The first is
 135 the set of variables defined in the set of monomorphic bindings, while the
 136 second is the set of free variables in those bindings.
 137
 138 The set of variables defined in a non-recursive binding is just the
 139 union of all of them, as @union@ removes duplicates. However, the
 140 free variables in each successive set of cumulative bindings is the
 141 union of those in the previous set plus those of the newest binding after
 142 the defined variables of the previous set have been removed.
 143
 144 @rnMethodBinds@ deals only with the declarations in class and
 145 instance declarations.  It expects only to see @FunMonoBind@s, and
 146 it expects the global environment to contain bindings for the binders
 147 (which are all class operations).
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsubsection{ Top-level bindings}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 -- for top-level bindings, we need to make top-level names,
 157 -- so we have a different entry point than for local bindings
 158 rnTopBindsLHS :: MiniFixityEnv
 159               -> HsValBinds RdrName
 160               -> RnM (HsValBindsLR Name RdrName)
 161 rnTopBindsLHS fix_env binds =
 162     (uncurry $ rnValBindsLHSFromDoc (topRecNameMaker fix_env)) (bindersAndDoc binds) binds
 163
 164 rnTopBindsRHS :: [Name] -- the names bound by these binds
 165               -> HsValBindsLR Name RdrName
 166               -> RnM (HsValBinds Name, DefUses)
 167 rnTopBindsRHS bound_names binds =
 168     do { is_boot <- tcIsHsBoot
 169        ; if is_boot
 170          then rnTopBindsBoot binds
 171          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 172                                bound_names binds }
 173
 174
 175 -- wrapper if we don't need to do anything in between the left and right,
 176 -- or anything else in the scope of the left
 177 --
 178 -- never used when there are fixity declarations
 179 rnTopBinds :: HsValBinds RdrName
 180            -> RnM (HsValBinds Name, DefUses)
 181 rnTopBinds b =
 182   do nl <- rnTopBindsLHS emptyFsEnv b
 183      let bound_names = map unLoc (collectHsValBinders nl)
 184      bindLocalNames bound_names  $ rnTopBindsRHS bound_names nl
 185
 186
 187 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 188 -- A hs-boot file has no bindings.
 189 -- Return a single HsBindGroup with empty binds and renamed signatures
 190 rnTopBindsBoot (ValBindsIn mbinds sigs)
 191   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 192         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 193         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 194 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 195 \end{code}
 196
 197
 198
 199 %*********************************************************
 200 %*                                                      *
 201                 HsLocalBinds
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 rnLocalBindsAndThen :: HsLocalBinds RdrName
 207                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 208                     -> RnM (result, FreeVars)
 209 -- This version (a) assumes that the binding vars are *not* already in scope
 210 --               (b) removes the binders from the free vars of the thing inside
 211 -- The parser doesn't produce ThenBinds
 212 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 213   = thing_inside EmptyLocalBinds
 214
 215 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 216   = rnValBindsAndThen val_binds $ \ val_binds' ->
 217       thing_inside (HsValBinds val_binds')
 218
 219 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 220     (binds',fv_binds) <- rnIPBinds binds
 221     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 222     return (thing, fvs_thing `plusFV` fv_binds)
 223
 224 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 225 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 226     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 227     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 228
 229 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 230 rnIPBind (IPBind n expr) = do
 231     name <- newIPNameRn  n
 232     (expr',fvExpr) <- rnLExpr expr
 233     return (IPBind name expr', fvExpr)
 234 \end{code}
 235
 236
 237 %************************************************************************
 238 %*                                                                      *
 239                 ValBinds
 240 %*                                                                      *
 241 %************************************************************************
 242
 243 \begin{code}
 244 -- wrapper for local binds
 245 -- creates the documentation info and calls the helper below
 246 rnValBindsLHS :: MiniFixityEnv
 247               -> HsValBinds RdrName
 248               -> RnM (HsValBindsLR Name RdrName)
 249 rnValBindsLHS fix_env binds =
 250     let (boundNames,doc) = bindersAndDoc binds
 251     in rnValBindsLHSFromDoc_Local boundNames doc fix_env binds
 252
 253 -- a helper used for local binds that does the duplicates check,
 254 -- just so we don't forget to do it somewhere
 255 rnValBindsLHSFromDoc_Local :: [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 256                            -> SDoc              -- doc string for dup names and shadowing
 257                            -> MiniFixityEnv
 258                            -> HsValBinds RdrName
 259                            -> RnM (HsValBindsLR Name RdrName)
 260
 261 rnValBindsLHSFromDoc_Local boundNames doc fix_env binds = do
 262      -- Do error checking: we need to check for dups here because we
 263      -- don't don't bind all of the variables from the ValBinds at once
 264      -- with bindLocatedLocals any more.
 265      checkDupAndShadowedRdrNames doc boundNames
 266
 267      -- (Note that we don't want to do this at the top level, since
 268      -- sorting out duplicates and shadowing there happens elsewhere.
 269      -- The behavior is even different. For example,
 270      --   import A(f)
 271      --   f = ...
 272      -- should not produce a shadowing warning (but it will produce
 273      -- an ambiguity warning if you use f), but
 274      --   import A(f)
 275      --   g = let f = ... in f
 276      -- should.
 277      rnValBindsLHSFromDoc (localRecNameMaker fix_env) boundNames doc binds
 278
 279 bindersAndDoc :: HsValBinds RdrName -> ([Located RdrName], SDoc)
 280 bindersAndDoc binds =
 281     let
 282         -- the unrenamed bndrs for error checking and reporting
 283         orig = collectHsValBinders binds
 284         doc = text "In the binding group for:" <+> pprWithCommas ppr (map unLoc orig)
 285     in
 286       (orig, doc)
 287
 288 -- renames the left-hand sides
 289 -- generic version used both at the top level and for local binds
 290 -- does some error checking, but not what gets done elsewhere at the top level
 291 rnValBindsLHSFromDoc :: NameMaker
 292                      -> [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 293                      -> SDoc              -- doc string for dup names and shadowing
 294                      -> HsValBinds RdrName
 295                      -> RnM (HsValBindsLR Name RdrName)
 296 rnValBindsLHSFromDoc topP _original_bndrs doc (ValBindsIn mbinds sigs) = do
 297      -- rename the LHSes
 298      mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 299      return $ ValBindsIn mbinds' sigs
 300 rnValBindsLHSFromDoc _ _ _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 301
 302 -- General version used both from the top-level and for local things
 303 -- Assumes the LHS vars are in scope
 304 --
 305 -- Does not bind the local fixity declarations
 306 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 307                      -- The trimming function trims the free vars we attach to a
 308                      -- binding so that it stays reasonably small
 309                  -> [Name]  -- names bound by the LHSes
 310                  -> HsValBindsLR Name RdrName
 311                  -> RnM (HsValBinds Name, DefUses)
 312
 313 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs) = do
 314    -- rename the sigs
 315    env <- getGblEnv
 316    sigs' <- renameSigs (Just (mkNameSet bound_names)) okBindSig sigs
 317    -- rename the RHSes
 318    binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 319    case depAnalBinds binds_w_dus of
 320        (anal_binds, anal_dus) ->
 321            do let valbind' = ValBindsOut anal_binds sigs'
 322                   valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 323               return (valbind', valbind'_dus)
 324
 325 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 326
 327 -- Wrapper for local binds
 328 --
 329 -- The *client* of this function is responsible for checking for unused binders;
 330 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 331 --
 332 -- The client is also responsible for bringing the fixities into scope
 333 rnValBindsRHS :: [Name]  -- names bound by the LHSes
 334               -> HsValBindsLR Name RdrName
 335               -> RnM (HsValBinds Name, DefUses)
 336 rnValBindsRHS bound_names binds =
 337   rnValBindsRHSGen (\ fvs -> -- only keep the names the names from this group
 338                     intersectNameSet (mkNameSet bound_names) fvs) bound_names binds
 339
 340
 341 -- for local binds
 342 -- wrapper that does both the left- and right-hand sides
 343 --
 344 -- here there are no local fixity decls passed in;
 345 -- the local fixity decls come from the ValBinds sigs
 346 rnValBindsAndThen :: HsValBinds RdrName
 347                   -> (HsValBinds Name -> RnM (result, FreeVars))
 348                   -> RnM (result, FreeVars)
 349 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 350  = do   { let (original_bndrs, doc) = bindersAndDoc binds
 351
 352               -- (A) Create the local fixity environment
 353         ; new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 354
 355               -- (B) Rename the LHSes
 356         ; new_lhs <- rnValBindsLHSFromDoc_Local original_bndrs doc new_fixities binds
 357         ; let bound_names = map unLoc $ collectHsValBinders new_lhs
 358
 359               --     ...and bring them (and their fixities) into scope
 360         ; bindLocalNamesFV_WithFixities bound_names new_fixities $ do
 361
 362         {      -- (C) Do the RHS and thing inside
 363           (binds', dus) <- rnValBindsRHS bound_names new_lhs
 364         ; (result, result_fvs) <- thing_inside binds'
 365
 366                 -- Report unused bindings based on the (accurate)
 367                 -- findUses.  E.g.
 368                 --      let x = x in 3
 369                 -- should report 'x' unused
 370         ; let real_uses = findUses dus result_fvs
 371         ; warnUnusedLocalBinds bound_names real_uses
 372
 373         ; let
 374             -- The variables "used" in the val binds are:
 375             --   (1) the uses of the binds (duUses)
 376             --   (2) the FVs of the thing-inside
 377             all_uses = duUses dus `plusFV` result_fvs
 378                 -- Note [Unused binding hack]
 379                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 380                 -- Note that *in contrast* to the above reporting of
 381                 -- unused bindings, (1) above uses duUses to return *all*
 382                 -- the uses, even if the binding is unused.  Otherwise consider:
 383                 --      x = 3
 384                 --      y = let p = x in 'x'    -- NB: p not used
 385                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 386                 -- bindings in the wrong order, and the type checker will complain
 387                 -- that x isn't in scope
 388                 --
 389                 -- But note that this means we won't report 'x' as unused,
 390                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 391
 392         ; return (result, all_uses) }}
 393                 -- The bound names are pruned out of all_uses
 394                 -- by the bindLocalNamesFV call above
 395
 396 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 397
 398
 399 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 400 -- (We keep the location around for reporting duplicate fixity declarations.)
 401 --
 402 -- Checks for duplicates, but not that only locally defined things are fixed.
 403 -- Note: for local fixity declarations, duplicates would also be checked in
 404 --       check_sigs below.  But we also use this function at the top level.
 405
 406 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 407
 408 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 409  where
 410    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 411      { -- this fixity decl is a duplicate iff
 412        -- the ReaderName's OccName's FastString is already in the env
 413        -- (we only need to check the local fix_env because
 414        --  definitions of non-local will be caught elsewhere)
 415        let { fs = occNameFS (rdrNameOcc name)
 416            ; fix_item = L loc fixity };
 417
 418        case lookupFsEnv env fs of
 419          Nothing -> return $ extendFsEnv env fs fix_item
 420          Just (L loc' _) -> do
 421            { setSrcSpan loc $
 422              addLocErr (L name_loc name) (dupFixityDecl loc')
 423            ; return env}
 424      }
 425
 426 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 427 dupFixityDecl loc rdr_name
 428   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 429           ptext (sLit "also at ") <+> ppr loc]
 430
 431 ---------------------
 432
 433 -- renaming a single bind
 434
 435 rnBindLHS :: NameMaker
 436           -> SDoc
 437           -> LHsBind RdrName
 438           -- returns the renamed left-hand side,
 439           -- and the FreeVars *of the LHS*
 440           -- (i.e., any free variables of the pattern)
 441           -> RnM (LHsBindLR Name RdrName)
 442
 443 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 444                                          pat_rhs = grhss,
 445                                          pat_rhs_ty=pat_rhs_ty
 446                                        }))
 447   = setSrcSpan loc $ do
 448       -- we don't actually use the FV processing of rnPatsAndThen here
 449       (pat',pat'_fvs) <- rnBindPat name_maker pat
 450       return (L loc (PatBind { pat_lhs = pat',
 451                                pat_rhs = grhss,
 452                                -- we temporarily store the pat's FVs here;
 453                                -- gets updated to the FVs of the whole bind
 454                                -- when doing the RHS below
 455                                bind_fvs = pat'_fvs,
 456                                -- these will get ignored in the next pass,
 457                                -- when we rename the RHS
 458                                pat_rhs_ty = pat_rhs_ty }))
 459
 460 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 461                                          fun_infix = inf,
 462                                          fun_matches = matches,
 463                                          fun_co_fn = fun_co_fn,
 464                                          fun_tick = fun_tick
 465                                        }))
 466   = setSrcSpan loc $
 467     do { (newname, _fvs) <- applyNameMaker name_maker name $ \ newname ->
 468                             return (newname, emptyFVs)
 469        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 470                                   fun_infix = inf,
 471                                   fun_matches = matches,
 472                                   -- we temporatily store the LHS's FVs (empty in this case) here
 473                                   -- gets updated when doing the RHS below
 474                                   bind_fvs = emptyFVs,
 475                                   -- everything else will get ignored in the next pass
 476                                   fun_co_fn = fun_co_fn,
 477                                   fun_tick = fun_tick
 478                                   })) }
 479
 480 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 481
 482 -- assumes the left-hands-side vars are in scope
 483 rnBind :: (Name -> [Name])              -- Signature tyvar function
 484        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 485        -> LHsBindLR Name RdrName
 486        -> RnM (LHsBind Name, [Name], Uses)
 487 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 488                                 pat_rhs = grhss,
 489                                 -- pat fvs were stored here while
 490                                 -- processing the LHS
 491                                 bind_fvs=pat_fvs }))
 492   = setSrcSpan loc $
 493     do  {let bndrs = collectPatBinders pat
 494
 495         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 496                 -- No scoped type variables for pattern bindings
 497         ; let fvs' = trim fvs
 498
 499         ; fvs' `seq` -- See Note [Free-variable space leak]
 500       return (L loc (PatBind { pat_lhs = pat,
 501                                   pat_rhs = grhss',
 502                                      pat_rhs_ty = placeHolderType,
 503                                   bind_fvs = fvs' }),
 504                   bndrs, pat_fvs `plusFV` fvs) }
 505
 506 rnBind sig_fn
 507        trim
 508        (L loc (FunBind { fun_id = name,
 509                          fun_infix = inf,
 510                          fun_matches = matches,
 511                          -- no pattern FVs
 512                          bind_fvs = _
 513                        }))
 514        -- invariant: no free vars here when it's a FunBind
 515   = setSrcSpan loc $
 516     do  { let plain_name = unLoc name
 517
 518         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 519                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 520                              rnMatchGroup (FunRhs plain_name inf) matches
 521         ; let fvs' = trim fvs
 522
 523         ; checkPrecMatch inf plain_name matches'
 524
 525         ; fvs' `seq` -- See Note [Free-variable space leak]
 526       return (L loc (FunBind { fun_id = name,
 527                                   fun_infix = inf,
 528                                   fun_matches = matches',
 529                                      bind_fvs = fvs',
 530                                   fun_co_fn = idHsWrapper,
 531                                   fun_tick = Nothing }),
 532                   [plain_name], fvs)
 533       }
 534
 535 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 536
 537 {-
 538 Note [Free-variable space leak]
 539 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 540 We have
 541     fvs' = trim fvs
 542 and we seq fvs' before turning it as part of a record.
 543
 544 The reason is that trim is sometimes something like
 545     \xs -> intersectNameSet (mkNameSet bound_names) xs
 546 and we don't want to retain the list bound_names. This showed up in
 547 trac ticket #1136.
 548 -}
 549
 550 ---------------------
 551 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 552              -> ([(RecFlag, LHsBinds Name)], DefUses)
 553 -- Dependency analysis; this is important so that
 554 -- unused-binding reporting is accurate
 555 depAnalBinds binds_w_dus
 556   = (map get_binds sccs, map get_du sccs)
 557   where
 558     sccs = stronglyConnCompFromEdgedVertices edges
 559
 560     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 561
 562     edges = [ (node, key, [key | n <- nameSetToList uses,
 563                                  Just key <- [lookupNameEnv key_map n] ])
 564             | (node@(_,_,uses), key) <- keyd_nodes ]
 565
 566     key_map :: NameEnv Int      -- Which binding it comes from
 567     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 568                                      , bndr <- bndrs ]
 569
 570     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 571     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 572
 573     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 574     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 575         where
 576           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 577           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 578
 579
 580 ---------------------
 581 -- Bind the top-level forall'd type variables in the sigs.
 582 -- E.g  f :: a -> a
 583 --      f = rhs
 584 --      The 'a' scopes over the rhs
 585 --
 586 -- NB: there'll usually be just one (for a function binding)
 587 --     but if there are many, one may shadow the rest; too bad!
 588 --      e.g  x :: [a] -> [a]
 589 --           y :: [(a,a)] -> a
 590 --           (x,y) = e
 591 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 592
 593 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 594 -- Return a lookup function that maps an Id Name to the names
 595 -- of the type variables that should scope over its body..
 596 mkSigTvFn sigs
 597   = \n -> lookupNameEnv env n `orElse` []
 598   where
 599     env :: NameEnv [Name]
 600     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 601                     | L _ (TypeSig (L _ name)
 602                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 603         -- Note the pattern-match on "Explicit"; we only bind
 604         -- type variables from signatures with an explicit top-level for-all
 605 \end{code}
 606
 607
 608 @rnMethodBinds@ is used for the method bindings of a class and an instance
 609 declaration.   Like @rnBinds@ but without dependency analysis.
 610
 611 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 612 That's crucial when dealing with an instance decl:
 613 \begin{verbatim}
 614         instance Foo (T a) where
 615            op x = ...
 616 \end{verbatim}
 617 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 618 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 619 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 620 in many ways the @op@ in an instance decl is just like an occurrence, not
 621 a binder.
 622
 623 \begin{code}
 624 rnMethodBinds :: Name                   -- Class name
 625               -> (Name -> [Name])       -- Signature tyvar function
 626               -> [Name]                 -- Names for generic type variables
 627               -> LHsBinds RdrName
 628               -> RnM (LHsBinds Name, FreeVars)
 629
 630 rnMethodBinds cls sig_fn gen_tyvars binds
 631   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 632   where do_one (binds,fvs) bind = do
 633            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 634            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 635
 636 rnMethodBind :: Name
 637               -> (Name -> [Name])
 638               -> [Name]
 639               -> LHsBindLR RdrName RdrName
 640               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 641 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = inf,
 642                                                      fun_matches = MatchGroup matches _ }))
 643   = setSrcSpan loc $ do
 644     sel_name <- lookupInstDeclBndr cls name
 645     let plain_name = unLoc sel_name
 646         -- We use the selector name as the binder
 647
 648     bindSigTyVarsFV (sig_fn plain_name) $ do
 649      (new_matches, fvs) <- mapFvRn (rn_match plain_name) matches
 650      let
 651          new_group = MatchGroup new_matches placeHolderType
 652
 653      checkPrecMatch inf plain_name new_group
 654      return (unitBag (L loc (FunBind {
 655                                 fun_id = sel_name, fun_infix = inf,
 656                                 fun_matches = new_group,
 657                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 658                                 fun_tick = Nothing })),
 659              fvs `addOneFV` plain_name)
 660         -- The 'fvs' field isn't used for method binds
 661   where
 662         -- Truly gruesome; bring into scope the correct members of the generic
 663         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 664     rn_match sel_name match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 665         = extendTyVarEnvFVRn gen_tvs    $
 666           rnMatch (FunRhs sel_name inf) match
 667         where
 668           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 669           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 670
 671     rn_match sel_name match = rnMatch (FunRhs sel_name inf) match
 672
 673
 674 -- Can't handle method pattern-bindings which bind multiple methods.
 675 rnMethodBind _ _ _ mbind@(L _ (PatBind _ _ _ _)) = do
 676     addLocErr mbind methodBindErr
 677     return (emptyBag, emptyFVs)
 678
 679 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 680 \end{code}
 681
 682
 683
 684 %************************************************************************
 685 %*                                                                      *
 686 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 687 %*                                                                      *
 688 %************************************************************************
 689
 690 @renameSigs@ checks for:
 691 \begin{enumerate}
 692 \item more than one sig for one thing;
 693 \item signatures given for things not bound here;
 694 \end{enumerate}
 695 %
 696 At the moment we don't gather free-var info from the types in
 697 signatures.  We'd only need this if we wanted to report unused tyvars.
 698
 699 \begin{code}
 700 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 701            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 702            -> [LSig RdrName]
 703            -> RnM [LSig Name]
 704 -- Renames the signatures and performs error checks
 705 renameSigs mb_names ok_sig sigs
 706   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 707         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 708         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 709         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 710         ; return sigs' }
 711
 712 ----------------------
 713 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 714 -- because this won't work for:
 715 --      instance Foo T where
 716 --        {-# INLINE op #-}
 717 --        Baz.op = ...
 718 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 719 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 720 -- Doesn't seem worth much trouble to sort this.
 721
 722 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 723 -- FixitySig is renamed elsewhere.
 724 renameSig mb_names sig@(TypeSig v ty)
 725   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 726         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 727         ; return (TypeSig new_v new_ty) }
 728
 729 renameSig _ (SpecInstSig ty)
 730   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 731         ; return (SpecInstSig new_ty) }
 732
 733 renameSig mb_names sig@(SpecSig v ty inl)
 734   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 735         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 736         ; return (SpecSig new_v new_ty inl) }
 737
 738 renameSig mb_names sig@(InlineSig v s)
 739   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 740         ; return (InlineSig new_v s) }
 741
 742 renameSig mb_names sig@(FixSig (FixitySig v f))
 743   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 744         ; return (FixSig (FixitySig new_v f)) }
 745
 746 -- lookupSigOccRn is used for type signatures and pragmas
 747 -- Is this valid?
 748 --   module A
 749 --      import M( f )
 750 --      f :: Int -> Int
 751 --      f x = x
 752 -- It's clear that the 'f' in the signature must refer to A.f
 753 -- The Haskell98 report does not stipulate this, but it will!
 754 -- So we must treat the 'f' in the signature in the same way
 755 -- as the binding occurrence of 'f', using lookupBndrRn
 756 --
 757 -- However, consider this case:
 758 --      import M( f )
 759 --      f :: Int -> Int
 760 --      g x = x
 761 -- We don't want to say 'f' is out of scope; instead, we want to
 762 -- return the imported 'f', so that later on the reanamer will
 763 -- correctly report "misplaced type sig".
 764
 765 lookupSigLocOccRn :: Maybe NameSet -> Sig RdrName -> Located RdrName -> RnM (Located Name)
 766 lookupSigLocOccRn mb_names sig = wrapLocM (lookupSigOccRn mb_names sig)
 767
 768 lookupSigOccRn :: Maybe NameSet -> Sig RdrName -> RdrName -> RnM Name
 769 lookupSigOccRn mb_names sig v
 770   = do  { mb_n <- lookupBndrRn_maybe v
 771         ; case mb_n of {
 772             Just n  -> case mb_names of {
 773                         Nothing                      -> return n ;
 774                         Just ns | n `elemNameSet` ns -> return n
 775                                 | otherwise -> bale_out_with local_msg } ;
 776
 777             Nothing -> do
 778         { mb_n <- lookupGreRn_maybe v
 779         ; case mb_n of
 780             Just _  -> bale_out_with import_msg
 781             Nothing -> bale_out_with empty
 782         } }}
 783   where
 784     bale_out_with msg
 785         = do { addErr (sep [ ptext (sLit "The") <+> hsSigDoc sig
 786                                 <+> ptext (sLit "for") <+> quotes (ppr v)
 787                            , nest 2 $ ptext (sLit "lacks an accompanying binding")]
 788                        $$ nest 2 msg)
 789              ; return (mkUnboundName v) }
 790
 791     local_msg = parens $ ptext (sLit "The")  <+> hsSigDoc sig <+> ptext (sLit "must be given where")
 792                          <+> quotes (ppr v) <+> ptext (sLit "is declared")
 793
 794     import_msg = parens $ ptext (sLit "You cannot give a") <+> hsSigDoc sig
 795                           <+> ptext (sLit "an imported value")
 796 \end{code}
 797
 798
 799 %************************************************************************
 800 %*                                                                      *
 801 \subsection{Match}
 802 %*                                                                      *
 803 %************************************************************************
 804
 805 \begin{code}
 806 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 807 rnMatchGroup ctxt (MatchGroup ms _)
 808   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 809        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 810
 811 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 812 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 813
 814 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 815 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 816   = do  {       -- Result type signatures are no longer supported
 817           case maybe_rhs_sig of
 818                 Nothing -> return ()
 819                 Just ty -> addLocErr ty (resSigErr ctxt match)
 820
 821
 822                -- Now the main event
 823                -- note that there are no local ficity decls for matches
 824         ; rnPatsAndThen_LocalRightwards ctxt pats       $ \ pats' -> do
 825         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 826
 827         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 828         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 829   where
 830
 831 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 832 resSigErr ctxt match ty
 833    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 834           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 835           , pprMatchInCtxt ctxt match ]
 836 \end{code}
 837
 838
 839 %************************************************************************
 840 %*                                                                      *
 841 \subsubsection{Guarded right-hand sides (GRHSs)}
 842 %*                                                                      *
 843 %************************************************************************
 844
 845 \begin{code}
 846 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 847
 848 rnGRHSs ctxt (GRHSs grhss binds)
 849   = rnLocalBindsAndThen binds   $ \ binds' -> do
 850     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 851     return (GRHSs grhss' binds', fvGRHSs)
 852
 853 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 854 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 855
 856 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 857 rnGRHS' ctxt (GRHS guards rhs)
 858   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 859         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 860                                     rnLExpr rhs
 861
 862         ; unless (pattern_guards_allowed || is_standard_guard guards')
 863                  (addWarn (nonStdGuardErr guards'))
 864
 865         ; return (GRHS guards' rhs', fvs) }
 866   where
 867         -- Standard Haskell 1.4 guards are just a single boolean
 868         -- expression, rather than a list of qualifiers as in the
 869         -- Glasgow extension
 870     is_standard_guard []                     = True
 871     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 872     is_standard_guard _                      = False
 873 \end{code}
 874
 875 %************************************************************************
 876 %*                                                                      *
 877 \subsection{Error messages}
 878 %*                                                                      *
 879 %************************************************************************
 880
 881 \begin{code}
 882 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 883 dupSigDeclErr sigs@(L loc sig : _)
 884   = addErrAt loc $
 885         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 886               nest 2 (vcat (map ppr_sig sigs))]
 887   where
 888     what_it_is = hsSigDoc sig
 889     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 890 dupSigDeclErr [] = panic "dupSigDeclErr"
 891
 892 unknownSigErr :: LSig RdrName -> RnM ()
 893 unknownSigErr (L loc sig)
 894   = addErrAt loc $
 895     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 896
 897 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 898 methodBindErr mbind
 899  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 900        2 (ppr mbind)
 901
 902 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 903 bindsInHsBootFile mbinds
 904   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 905        2 (ppr mbinds)
 906
 907 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 908 nonStdGuardErr guards
 909   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 910        4 (interpp'SP guards)
 911 \end{code}