compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPats, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import DynFlags ( DynFlag(..) )
  32 import Name
  33 import NameEnv
  34 import NameSet
  35 import RdrName          ( RdrName, rdrNameOcc )
  36 import SrcLoc
  37 import ListSetOps       ( findDupsEq )
  38 import BasicTypes       ( RecFlag(..) )
  39 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  40 import Bag
  41 import Outputable
  42 import FastString
  43 import Data.List        ( partition )
  44 import Maybes           ( orElse )
  45 import Control.Monad
  46 \end{code}
  47
  48 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  49 -- place and can be used when complaining.
  50
  51 The code tree received by the function @rnBinds@ contains definitions
  52 in where-clauses which are all apparently mutually recursive, but which may
  53 not really depend upon each other. For example, in the top level program
  54 \begin{verbatim}
  55 f x = y where a = x
  56               y = x
  57 \end{verbatim}
  58 the definitions of @a@ and @y@ do not depend on each other at all.
  59 Unfortunately, the typechecker cannot always check such definitions.
  60 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  61 definitions. In Proceedings of the International Symposium on Programming,
  62 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  63 However, the typechecker usually can check definitions in which only the
  64 strongly connected components have been collected into recursive bindings.
  65 This is precisely what the function @rnBinds@ does.
  66
  67 ToDo: deal with case where a single monobinds binds the same variable
  68 twice.
  69
  70 The vertag tag is a unique @Int@; the tags only need to be unique
  71 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  72 (heavy monad machinery not needed).
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77 %* naming conventions                                                   *
  78 %*                                                                      *
  79 %************************************************************************
  80
  81 \subsection[name-conventions]{Name conventions}
  82
  83 The basic algorithm involves walking over the tree and returning a tuple
  84 containing the new tree plus its free variables. Some functions, such
  85 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  86 list comprehensions (@Quals@), return the variables bound in local
  87 environments. These are then used to calculate the free variables of the
  88 expression evaluated in these environments.
  89
  90 Conventions for variable names are as follows:
  91 \begin{itemize}
  92 \item
  93 new code is given a prime to distinguish it from the old.
  94
  95 \item
  96 a set of variables defined in @Exp@ is written @dvExp@
  97
  98 \item
  99 a set of variables free in @Exp@ is written @fvExp@
 100 \end{itemize}
 101
 102 %************************************************************************
 103 %*                                                                      *
 104 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 109
 110 Non-recursive expressions are reconstructed without any changes at top
 111 level, although their component expressions may have to be altered.
 112 However, non-recursive expressions are currently not expected as
 113 \Haskell{} programs, and this code should not be executed.
 114
 115 Monomorphic bindings contain information that is returned in a tuple
 116 (a @FlatMonoBinds@) containing:
 117
 118 \begin{enumerate}
 119 \item
 120 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 121
 122 \item
 123 the name of a function or the names in a pattern. These are a set
 124 referred to as @dvLhs@, the defined variables of the left hand side.
 125
 126 \item
 127 the free variables of the body. These are referred to as @fvBody@.
 128
 129 \item
 130 the definition's actual code. This is referred to as just @code@.
 131 \end{enumerate}
 132
 133 The function @nonRecDvFv@ returns two sets of variables. The first is
 134 the set of variables defined in the set of monomorphic bindings, while the
 135 second is the set of free variables in those bindings.
 136
 137 The set of variables defined in a non-recursive binding is just the
 138 union of all of them, as @union@ removes duplicates. However, the
 139 free variables in each successive set of cumulative bindings is the
 140 union of those in the previous set plus those of the newest binding after
 141 the defined variables of the previous set have been removed.
 142
 143 @rnMethodBinds@ deals only with the declarations in class and
 144 instance declarations.  It expects only to see @FunMonoBind@s, and
 145 it expects the global environment to contain bindings for the binders
 146 (which are all class operations).
 147
 148 %************************************************************************
 149 %*                                                                      *
 150 \subsubsection{ Top-level bindings}
 151 %*                                                                      *
 152 %************************************************************************
 153
 154 \begin{code}
 155 -- for top-level bindings, we need to make top-level names,
 156 -- so we have a different entry point than for local bindings
 157 rnTopBindsLHS :: MiniFixityEnv
 158               -> HsValBinds RdrName
 159               -> RnM (HsValBindsLR Name RdrName)
 160 rnTopBindsLHS fix_env binds
 161   = do { let (boundNames,doc) = bindersAndDoc binds
 162        ; mod <- getModule
 163        ; rnValBindsLHSFromDoc (topRecNameMaker mod fix_env) boundNames doc binds }
 164
 165 rnTopBindsRHS :: NameSet        -- Names bound by these binds
 166               -> HsValBindsLR Name RdrName
 167               -> RnM (HsValBinds Name, DefUses)
 168 rnTopBindsRHS bound_names binds =
 169     do { is_boot <- tcIsHsBoot
 170        ; if is_boot
 171          then rnTopBindsBoot binds
 172          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 173                                bound_names binds }
 174
 175 -- Wrapper if we don't need to do anything in between the left and right,
 176 -- or anything else in the scope of the left
 177 --
 178 -- Never used when there are fixity declarations
 179 rnTopBinds :: HsValBinds RdrName
 180            -> RnM (HsValBinds Name, DefUses)
 181 rnTopBinds b =
 182   do nl <- rnTopBindsLHS emptyFsEnv b
 183      let bound_names = map unLoc (collectHsValBinders nl)
 184      bindLocalNames bound_names $ rnTopBindsRHS (mkNameSet bound_names) nl
 185
 186
 187 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 188 -- A hs-boot file has no bindings.
 189 -- Return a single HsBindGroup with empty binds and renamed signatures
 190 rnTopBindsBoot (ValBindsIn mbinds sigs)
 191   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 192         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 193         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 194 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 195 \end{code}
 196
 197
 198
 199 %*********************************************************
 200 %*                                                      *
 201                 HsLocalBinds
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 rnLocalBindsAndThen :: HsLocalBinds RdrName
 207                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 208                     -> RnM (result, FreeVars)
 209 -- This version (a) assumes that the binding vars are *not* already in scope
 210 --               (b) removes the binders from the free vars of the thing inside
 211 -- The parser doesn't produce ThenBinds
 212 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 213   = thing_inside EmptyLocalBinds
 214
 215 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 216   = rnValBindsAndThen val_binds $ \ val_binds' ->
 217       thing_inside (HsValBinds val_binds')
 218
 219 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 220     (binds',fv_binds) <- rnIPBinds binds
 221     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 222     return (thing, fvs_thing `plusFV` fv_binds)
 223
 224 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 225 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 226     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 227     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 228
 229 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 230 rnIPBind (IPBind n expr) = do
 231     name <- newIPNameRn  n
 232     (expr',fvExpr) <- rnLExpr expr
 233     return (IPBind name expr', fvExpr)
 234 \end{code}
 235
 236
 237 %************************************************************************
 238 %*                                                                      *
 239                 ValBinds
 240 %*                                                                      *
 241 %************************************************************************
 242
 243 \begin{code}
 244 -- wrapper for local binds
 245 -- creates the documentation info and calls the helper below
 246 rnValBindsLHS :: MiniFixityEnv
 247               -> HsValBinds RdrName
 248               -> RnM (HsValBindsLR Name RdrName)
 249 rnValBindsLHS fix_env binds =
 250     let (boundNames,doc) = bindersAndDoc binds
 251     in rnValBindsLHSFromDoc_Local boundNames doc fix_env binds
 252
 253 -- a helper used for local binds that does the duplicates check,
 254 -- just so we don't forget to do it somewhere
 255 rnValBindsLHSFromDoc_Local :: [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 256                            -> SDoc              -- doc string for dup names and shadowing
 257                            -> MiniFixityEnv
 258                            -> HsValBinds RdrName
 259                            -> RnM (HsValBindsLR Name RdrName)
 260
 261 rnValBindsLHSFromDoc_Local boundNames doc fix_env binds = do
 262      -- Do error checking: we need to check for dups here because we
 263      -- don't don't bind all of the variables from the ValBinds at once
 264      -- with bindLocatedLocals any more.
 265      checkDupAndShadowedRdrNames doc boundNames
 266
 267      -- (Note that we don't want to do this at the top level, since
 268      -- sorting out duplicates and shadowing there happens elsewhere.
 269      -- The behavior is even different. For example,
 270      --   import A(f)
 271      --   f = ...
 272      -- should not produce a shadowing warning (but it will produce
 273      -- an ambiguity warning if you use f), but
 274      --   import A(f)
 275      --   g = let f = ... in f
 276      -- should.
 277      rnValBindsLHSFromDoc (localRecNameMaker fix_env) boundNames doc binds
 278
 279 bindersAndDoc :: HsValBinds RdrName -> ([Located RdrName], SDoc)
 280 bindersAndDoc binds =
 281     let
 282         -- the unrenamed bndrs for error checking and reporting
 283         orig = collectHsValBinders binds
 284         doc = text "In the binding group for:" <+> pprWithCommas ppr (map unLoc orig)
 285     in
 286       (orig, doc)
 287
 288 -- renames the left-hand sides
 289 -- generic version used both at the top level and for local binds
 290 -- does some error checking, but not what gets done elsewhere at the top level
 291 rnValBindsLHSFromDoc :: NameMaker
 292                      -> [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 293                      -> SDoc              -- doc string for dup names and shadowing
 294                      -> HsValBinds RdrName
 295                      -> RnM (HsValBindsLR Name RdrName)
 296 rnValBindsLHSFromDoc topP _original_bndrs doc (ValBindsIn mbinds sigs) = do
 297      -- rename the LHSes
 298      mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 299      return $ ValBindsIn mbinds' sigs
 300 rnValBindsLHSFromDoc _ _ _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 301
 302 -- General version used both from the top-level and for local things
 303 -- Assumes the LHS vars are in scope
 304 --
 305 -- Does not bind the local fixity declarations
 306 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 307                      -- The trimming function trims the free vars we attach to a
 308                      -- binding so that it stays reasonably small
 309                  -> NameSet     -- Names bound by the LHSes
 310                  -> HsValBindsLR Name RdrName
 311                  -> RnM (HsValBinds Name, DefUses)
 312
 313 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs) = do
 314    -- rename the sigs
 315    sigs' <- renameSigs (Just bound_names) okBindSig sigs
 316    -- rename the RHSes
 317    binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 318    case depAnalBinds binds_w_dus of
 319        (anal_binds, anal_dus) ->
 320            do let valbind' = ValBindsOut anal_binds sigs'
 321                   valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 322               return (valbind', valbind'_dus)
 323
 324 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 325
 326 -- Wrapper for local binds
 327 --
 328 -- The *client* of this function is responsible for checking for unused binders;
 329 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 330 --
 331 -- The client is also responsible for bringing the fixities into scope
 332 rnValBindsRHS :: NameSet  -- names bound by the LHSes
 333               -> HsValBindsLR Name RdrName
 334               -> RnM (HsValBinds Name, DefUses)
 335 rnValBindsRHS bound_names binds =
 336   rnValBindsRHSGen (\ fvs -> -- only keep the names the names from this group
 337                     intersectNameSet bound_names fvs) bound_names binds
 338
 339
 340 -- for local binds
 341 -- wrapper that does both the left- and right-hand sides
 342 --
 343 -- here there are no local fixity decls passed in;
 344 -- the local fixity decls come from the ValBinds sigs
 345 rnValBindsAndThen :: HsValBinds RdrName
 346                   -> (HsValBinds Name -> RnM (result, FreeVars))
 347                   -> RnM (result, FreeVars)
 348 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 349  = do   { let (original_bndrs, doc) = bindersAndDoc binds
 350
 351               -- (A) Create the local fixity environment
 352         ; new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 353
 354               -- (B) Rename the LHSes
 355         ; new_lhs <- rnValBindsLHSFromDoc_Local original_bndrs doc new_fixities binds
 356         ; let bound_names = map unLoc $ collectHsValBinders new_lhs
 357
 358               --     ...and bring them (and their fixities) into scope
 359         ; bindLocalNamesFV_WithFixities bound_names new_fixities $ do
 360
 361         {      -- (C) Do the RHS and thing inside
 362           (binds', dus) <- rnValBindsRHS (mkNameSet bound_names) new_lhs
 363         ; (result, result_fvs) <- thing_inside binds'
 364
 365                 -- Report unused bindings based on the (accurate)
 366                 -- findUses.  E.g.
 367                 --      let x = x in 3
 368                 -- should report 'x' unused
 369         ; let real_uses = findUses dus result_fvs
 370         ; warnUnusedLocalBinds bound_names real_uses
 371
 372         ; let
 373             -- The variables "used" in the val binds are:
 374             --   (1) the uses of the binds (duUses)
 375             --   (2) the FVs of the thing-inside
 376             all_uses = duUses dus `plusFV` result_fvs
 377                 -- Note [Unused binding hack]
 378                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 379                 -- Note that *in contrast* to the above reporting of
 380                 -- unused bindings, (1) above uses duUses to return *all*
 381                 -- the uses, even if the binding is unused.  Otherwise consider:
 382                 --      x = 3
 383                 --      y = let p = x in 'x'    -- NB: p not used
 384                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 385                 -- bindings in the wrong order, and the type checker will complain
 386                 -- that x isn't in scope
 387                 --
 388                 -- But note that this means we won't report 'x' as unused,
 389                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 390
 391         ; return (result, all_uses) }}
 392                 -- The bound names are pruned out of all_uses
 393                 -- by the bindLocalNamesFV call above
 394
 395 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 396
 397
 398 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 399 -- (We keep the location around for reporting duplicate fixity declarations.)
 400 --
 401 -- Checks for duplicates, but not that only locally defined things are fixed.
 402 -- Note: for local fixity declarations, duplicates would also be checked in
 403 --       check_sigs below.  But we also use this function at the top level.
 404
 405 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 406
 407 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 408  where
 409    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 410      { -- this fixity decl is a duplicate iff
 411        -- the ReaderName's OccName's FastString is already in the env
 412        -- (we only need to check the local fix_env because
 413        --  definitions of non-local will be caught elsewhere)
 414        let { fs = occNameFS (rdrNameOcc name)
 415            ; fix_item = L loc fixity };
 416
 417        case lookupFsEnv env fs of
 418          Nothing -> return $ extendFsEnv env fs fix_item
 419          Just (L loc' _) -> do
 420            { setSrcSpan loc $
 421              addLocErr (L name_loc name) (dupFixityDecl loc')
 422            ; return env}
 423      }
 424
 425 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 426 dupFixityDecl loc rdr_name
 427   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 428           ptext (sLit "also at ") <+> ppr loc]
 429
 430 ---------------------
 431
 432 -- renaming a single bind
 433
 434 rnBindLHS :: NameMaker
 435           -> SDoc
 436           -> LHsBind RdrName
 437           -- returns the renamed left-hand side,
 438           -- and the FreeVars *of the LHS*
 439           -- (i.e., any free variables of the pattern)
 440           -> RnM (LHsBindLR Name RdrName)
 441
 442 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 443                                          pat_rhs = grhss,
 444                                          pat_rhs_ty=pat_rhs_ty
 445                                        }))
 446   = setSrcSpan loc $ do
 447       -- we don't actually use the FV processing of rnPatsAndThen here
 448       (pat',pat'_fvs) <- rnBindPat name_maker pat
 449       return (L loc (PatBind { pat_lhs = pat',
 450                                pat_rhs = grhss,
 451                                -- we temporarily store the pat's FVs here;
 452                                -- gets updated to the FVs of the whole bind
 453                                -- when doing the RHS below
 454                                bind_fvs = pat'_fvs,
 455                                -- these will get ignored in the next pass,
 456                                -- when we rename the RHS
 457                                pat_rhs_ty = pat_rhs_ty }))
 458
 459 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 460                                          fun_infix = inf,
 461                                          fun_matches = matches,
 462                                          fun_co_fn = fun_co_fn,
 463                                          fun_tick = fun_tick
 464                                        }))
 465   = setSrcSpan loc $
 466     do { newname <- applyNameMaker name_maker name
 467        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 468                                   fun_infix = inf,
 469                                   fun_matches = matches,
 470                                   -- we temporatily store the LHS's FVs (empty in this case) here
 471                                   -- gets updated when doing the RHS below
 472                                   bind_fvs = emptyFVs,
 473                                   -- everything else will get ignored in the next pass
 474                                   fun_co_fn = fun_co_fn,
 475                                   fun_tick = fun_tick
 476                                   })) }
 477
 478 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 479
 480 -- assumes the left-hands-side vars are in scope
 481 rnBind :: (Name -> [Name])              -- Signature tyvar function
 482        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 483        -> LHsBindLR Name RdrName
 484        -> RnM (LHsBind Name, [Name], Uses)
 485 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 486                                 pat_rhs = grhss,
 487                                 -- pat fvs were stored here while
 488                                 -- processing the LHS
 489                                 bind_fvs=pat_fvs }))
 490   = setSrcSpan loc $
 491     do  {let bndrs = collectPatBinders pat
 492
 493         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 494                 -- No scoped type variables for pattern bindings
 495         ; let fvs' = trim fvs
 496
 497         ; fvs' `seq` -- See Note [Free-variable space leak]
 498       return (L loc (PatBind { pat_lhs = pat,
 499                                   pat_rhs = grhss',
 500                                      pat_rhs_ty = placeHolderType,
 501                                   bind_fvs = fvs' }),
 502                   bndrs, pat_fvs `plusFV` fvs) }
 503
 504 rnBind sig_fn
 505        trim
 506        (L loc (FunBind { fun_id = name,
 507                          fun_infix = inf,
 508                          fun_matches = matches,
 509                          -- no pattern FVs
 510                          bind_fvs = _
 511                        }))
 512        -- invariant: no free vars here when it's a FunBind
 513   = setSrcSpan loc $
 514     do  { let plain_name = unLoc name
 515
 516         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 517                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 518                              rnMatchGroup (FunRhs plain_name inf) matches
 519         ; let fvs' = trim fvs
 520
 521         ; checkPrecMatch inf plain_name matches'
 522
 523         ; fvs' `seq` -- See Note [Free-variable space leak]
 524       return (L loc (FunBind { fun_id = name,
 525                                   fun_infix = inf,
 526                                   fun_matches = matches',
 527                                      bind_fvs = fvs',
 528                                   fun_co_fn = idHsWrapper,
 529                                   fun_tick = Nothing }),
 530                   [plain_name], fvs)
 531       }
 532
 533 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 534
 535 {-
 536 Note [Free-variable space leak]
 537 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 538 We have
 539     fvs' = trim fvs
 540 and we seq fvs' before turning it as part of a record.
 541
 542 The reason is that trim is sometimes something like
 543     \xs -> intersectNameSet (mkNameSet bound_names) xs
 544 and we don't want to retain the list bound_names. This showed up in
 545 trac ticket #1136.
 546 -}
 547
 548 ---------------------
 549 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 550              -> ([(RecFlag, LHsBinds Name)], DefUses)
 551 -- Dependency analysis; this is important so that
 552 -- unused-binding reporting is accurate
 553 depAnalBinds binds_w_dus
 554   = (map get_binds sccs, map get_du sccs)
 555   where
 556     sccs = stronglyConnCompFromEdgedVertices edges
 557
 558     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 559
 560     edges = [ (node, key, [key | n <- nameSetToList uses,
 561                                  Just key <- [lookupNameEnv key_map n] ])
 562             | (node@(_,_,uses), key) <- keyd_nodes ]
 563
 564     key_map :: NameEnv Int      -- Which binding it comes from
 565     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 566                                      , bndr <- bndrs ]
 567
 568     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 569     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 570
 571     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 572     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 573         where
 574           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 575           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 576
 577
 578 ---------------------
 579 -- Bind the top-level forall'd type variables in the sigs.
 580 -- E.g  f :: a -> a
 581 --      f = rhs
 582 --      The 'a' scopes over the rhs
 583 --
 584 -- NB: there'll usually be just one (for a function binding)
 585 --     but if there are many, one may shadow the rest; too bad!
 586 --      e.g  x :: [a] -> [a]
 587 --           y :: [(a,a)] -> a
 588 --           (x,y) = e
 589 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 590
 591 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 592 -- Return a lookup function that maps an Id Name to the names
 593 -- of the type variables that should scope over its body..
 594 mkSigTvFn sigs
 595   = \n -> lookupNameEnv env n `orElse` []
 596   where
 597     env :: NameEnv [Name]
 598     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 599                     | L _ (TypeSig (L _ name)
 600                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 601         -- Note the pattern-match on "Explicit"; we only bind
 602         -- type variables from signatures with an explicit top-level for-all
 603 \end{code}
 604
 605
 606 @rnMethodBinds@ is used for the method bindings of a class and an instance
 607 declaration.   Like @rnBinds@ but without dependency analysis.
 608
 609 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 610 That's crucial when dealing with an instance decl:
 611 \begin{verbatim}
 612         instance Foo (T a) where
 613            op x = ...
 614 \end{verbatim}
 615 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 616 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 617 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 618 in many ways the @op@ in an instance decl is just like an occurrence, not
 619 a binder.
 620
 621 \begin{code}
 622 rnMethodBinds :: Name                   -- Class name
 623               -> (Name -> [Name])       -- Signature tyvar function
 624               -> [Name]                 -- Names for generic type variables
 625               -> LHsBinds RdrName
 626               -> RnM (LHsBinds Name, FreeVars)
 627
 628 rnMethodBinds cls sig_fn gen_tyvars binds
 629   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 630   where do_one (binds,fvs) bind = do
 631            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 632            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 633
 634 rnMethodBind :: Name
 635               -> (Name -> [Name])
 636               -> [Name]
 637               -> LHsBindLR RdrName RdrName
 638               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 639 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = inf,
 640                                                      fun_matches = MatchGroup matches _ }))
 641   = setSrcSpan loc $ do
 642     sel_name <- wrapLocM (lookupInstDeclBndr cls) name
 643     let plain_name = unLoc sel_name
 644         -- We use the selector name as the binder
 645
 646     bindSigTyVarsFV (sig_fn plain_name) $ do
 647      (new_matches, fvs) <- mapFvRn (rn_match plain_name) matches
 648      let
 649          new_group = MatchGroup new_matches placeHolderType
 650
 651      checkPrecMatch inf plain_name new_group
 652      return (unitBag (L loc (FunBind {
 653                                 fun_id = sel_name, fun_infix = inf,
 654                                 fun_matches = new_group,
 655                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 656                                 fun_tick = Nothing })),
 657              fvs `addOneFV` plain_name)
 658         -- The 'fvs' field isn't used for method binds
 659   where
 660         -- Truly gruesome; bring into scope the correct members of the generic
 661         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 662     rn_match sel_name match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 663         = extendTyVarEnvFVRn gen_tvs    $
 664           rnMatch (FunRhs sel_name inf) match
 665         where
 666           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 667           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 668
 669     rn_match sel_name match = rnMatch (FunRhs sel_name inf) match
 670
 671
 672 -- Can't handle method pattern-bindings which bind multiple methods.
 673 rnMethodBind _ _ _ mbind@(L _ (PatBind _ _ _ _)) = do
 674     addLocErr mbind methodBindErr
 675     return (emptyBag, emptyFVs)
 676
 677 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 678 \end{code}
 679
 680
 681
 682 %************************************************************************
 683 %*                                                                      *
 684 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 685 %*                                                                      *
 686 %************************************************************************
 687
 688 @renameSigs@ checks for:
 689 \begin{enumerate}
 690 \item more than one sig for one thing;
 691 \item signatures given for things not bound here;
 692 \end{enumerate}
 693 %
 694 At the moment we don't gather free-var info from the types in
 695 signatures.  We'd only need this if we wanted to report unused tyvars.
 696
 697 \begin{code}
 698 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 699            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 700            -> [LSig RdrName]
 701            -> RnM [LSig Name]
 702 -- Renames the signatures and performs error checks
 703 renameSigs mb_names ok_sig sigs
 704   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 705         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 706         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 707         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 708         ; return sigs' }
 709
 710 ----------------------
 711 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 712 -- because this won't work for:
 713 --      instance Foo T where
 714 --        {-# INLINE op #-}
 715 --        Baz.op = ...
 716 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 717 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 718 -- Doesn't seem worth much trouble to sort this.
 719
 720 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 721 -- FixitySig is renamed elsewhere.
 722 renameSig _ (IdSig x)
 723   = return (IdSig x)      -- Actually this never occurs
 724 renameSig mb_names sig@(TypeSig v ty)
 725   = do  { new_v <- lookupSigOccRn mb_names sig v
 726         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 727         ; return (TypeSig new_v new_ty) }
 728
 729 renameSig _ (SpecInstSig ty)
 730   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 731         ; return (SpecInstSig new_ty) }
 732
 733 renameSig mb_names sig@(SpecSig v ty inl)
 734   = do  { new_v <- lookupSigOccRn mb_names sig v
 735         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 736         ; return (SpecSig new_v new_ty inl) }
 737
 738 renameSig mb_names sig@(InlineSig v s)
 739   = do  { new_v <- lookupSigOccRn mb_names sig v
 740         ; return (InlineSig new_v s) }
 741
 742 renameSig mb_names sig@(FixSig (FixitySig v f))
 743   = do  { new_v <- lookupSigOccRn mb_names sig v
 744         ; return (FixSig (FixitySig new_v f)) }
 745 \end{code}
 746
 747
 748 %************************************************************************
 749 %*                                                                      *
 750 \subsection{Match}
 751 %*                                                                      *
 752 %************************************************************************
 753
 754 \begin{code}
 755 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 756 rnMatchGroup ctxt (MatchGroup ms _)
 757   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 758        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 759
 760 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 761 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 762
 763 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 764 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 765   = do  {       -- Result type signatures are no longer supported
 766           case maybe_rhs_sig of
 767                 Nothing -> return ()
 768                 Just ty -> addLocErr ty (resSigErr ctxt match)
 769
 770
 771                -- Now the main event
 772                -- note that there are no local ficity decls for matches
 773         ; rnPats ctxt pats      $ \ pats' -> do
 774         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 775
 776         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 777         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 778   where
 779
 780 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 781 resSigErr ctxt match ty
 782    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 783           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 784           , pprMatchInCtxt ctxt match ]
 785 \end{code}
 786
 787
 788 %************************************************************************
 789 %*                                                                      *
 790 \subsubsection{Guarded right-hand sides (GRHSs)}
 791 %*                                                                      *
 792 %************************************************************************
 793
 794 \begin{code}
 795 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 796
 797 rnGRHSs ctxt (GRHSs grhss binds)
 798   = rnLocalBindsAndThen binds   $ \ binds' -> do
 799     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 800     return (GRHSs grhss' binds', fvGRHSs)
 801
 802 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 803 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 804
 805 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 806 rnGRHS' ctxt (GRHS guards rhs)
 807   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 808         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 809                                     rnLExpr rhs
 810
 811         ; unless (pattern_guards_allowed || is_standard_guard guards')
 812                  (addWarn (nonStdGuardErr guards'))
 813
 814         ; return (GRHS guards' rhs', fvs) }
 815   where
 816         -- Standard Haskell 1.4 guards are just a single boolean
 817         -- expression, rather than a list of qualifiers as in the
 818         -- Glasgow extension
 819     is_standard_guard []                     = True
 820     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 821     is_standard_guard _                      = False
 822 \end{code}
 823
 824 %************************************************************************
 825 %*                                                                      *
 826 \subsection{Error messages}
 827 %*                                                                      *
 828 %************************************************************************
 829
 830 \begin{code}
 831 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 832 dupSigDeclErr sigs@(L loc sig : _)
 833   = addErrAt loc $
 834         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 835               nest 2 (vcat (map ppr_sig sigs))]
 836   where
 837     what_it_is = hsSigDoc sig
 838     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 839 dupSigDeclErr [] = panic "dupSigDeclErr"
 840
 841 unknownSigErr :: LSig RdrName -> RnM ()
 842 unknownSigErr (L loc sig)
 843   = addErrAt loc $
 844     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 845
 846 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 847 methodBindErr mbind
 848  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 849        2 (ppr mbind)
 850
 851 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 852 bindsInHsBootFile mbinds
 853   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 854        2 (ppr mbinds)
 855
 856 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 857 nonStdGuardErr guards
 858   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 859        4 (interpp'SP guards)
 860 \end{code}