compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPats, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import DynFlags ( DynFlag(..) )
  32 import Name
  33 import NameEnv
  34 import NameSet
  35 import RdrName          ( RdrName, rdrNameOcc )
  36 import SrcLoc
  37 import ListSetOps       ( findDupsEq )
  38 import BasicTypes       ( RecFlag(..) )
  39 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  40 import Bag
  41 import Outputable
  42 import FastString
  43 import Data.List        ( partition )
  44 import Maybes           ( orElse )
  45 import Control.Monad
  46 \end{code}
  47
  48 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  49 -- place and can be used when complaining.
  50
  51 The code tree received by the function @rnBinds@ contains definitions
  52 in where-clauses which are all apparently mutually recursive, but which may
  53 not really depend upon each other. For example, in the top level program
  54 \begin{verbatim}
  55 f x = y where a = x
  56               y = x
  57 \end{verbatim}
  58 the definitions of @a@ and @y@ do not depend on each other at all.
  59 Unfortunately, the typechecker cannot always check such definitions.
  60 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  61 definitions. In Proceedings of the International Symposium on Programming,
  62 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  63 However, the typechecker usually can check definitions in which only the
  64 strongly connected components have been collected into recursive bindings.
  65 This is precisely what the function @rnBinds@ does.
  66
  67 ToDo: deal with case where a single monobinds binds the same variable
  68 twice.
  69
  70 The vertag tag is a unique @Int@; the tags only need to be unique
  71 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  72 (heavy monad machinery not needed).
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77 %* naming conventions                                                   *
  78 %*                                                                      *
  79 %************************************************************************
  80
  81 \subsection[name-conventions]{Name conventions}
  82
  83 The basic algorithm involves walking over the tree and returning a tuple
  84 containing the new tree plus its free variables. Some functions, such
  85 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  86 list comprehensions (@Quals@), return the variables bound in local
  87 environments. These are then used to calculate the free variables of the
  88 expression evaluated in these environments.
  89
  90 Conventions for variable names are as follows:
  91 \begin{itemize}
  92 \item
  93 new code is given a prime to distinguish it from the old.
  94
  95 \item
  96 a set of variables defined in @Exp@ is written @dvExp@
  97
  98 \item
  99 a set of variables free in @Exp@ is written @fvExp@
 100 \end{itemize}
 101
 102 %************************************************************************
 103 %*                                                                      *
 104 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 109
 110 Non-recursive expressions are reconstructed without any changes at top
 111 level, although their component expressions may have to be altered.
 112 However, non-recursive expressions are currently not expected as
 113 \Haskell{} programs, and this code should not be executed.
 114
 115 Monomorphic bindings contain information that is returned in a tuple
 116 (a @FlatMonoBinds@) containing:
 117
 118 \begin{enumerate}
 119 \item
 120 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 121
 122 \item
 123 the name of a function or the names in a pattern. These are a set
 124 referred to as @dvLhs@, the defined variables of the left hand side.
 125
 126 \item
 127 the free variables of the body. These are referred to as @fvBody@.
 128
 129 \item
 130 the definition's actual code. This is referred to as just @code@.
 131 \end{enumerate}
 132
 133 The function @nonRecDvFv@ returns two sets of variables. The first is
 134 the set of variables defined in the set of monomorphic bindings, while the
 135 second is the set of free variables in those bindings.
 136
 137 The set of variables defined in a non-recursive binding is just the
 138 union of all of them, as @union@ removes duplicates. However, the
 139 free variables in each successive set of cumulative bindings is the
 140 union of those in the previous set plus those of the newest binding after
 141 the defined variables of the previous set have been removed.
 142
 143 @rnMethodBinds@ deals only with the declarations in class and
 144 instance declarations.  It expects only to see @FunMonoBind@s, and
 145 it expects the global environment to contain bindings for the binders
 146 (which are all class operations).
 147
 148 %************************************************************************
 149 %*                                                                      *
 150 \subsubsection{ Top-level bindings}
 151 %*                                                                      *
 152 %************************************************************************
 153
 154 \begin{code}
 155 -- for top-level bindings, we need to make top-level names,
 156 -- so we have a different entry point than for local bindings
 157 rnTopBindsLHS :: MiniFixityEnv
 158               -> HsValBinds RdrName
 159               -> RnM (HsValBindsLR Name RdrName)
 160 rnTopBindsLHS fix_env binds
 161   = do { mod <- getModule
 162        ; rnValBindsLHSFromDoc (topRecNameMaker mod fix_env) binds }
 163
 164 rnTopBindsRHS :: NameSet        -- Names bound by these binds
 165               -> HsValBindsLR Name RdrName
 166               -> RnM (HsValBinds Name, DefUses)
 167 rnTopBindsRHS bound_names binds =
 168     do { is_boot <- tcIsHsBoot
 169        ; if is_boot
 170          then rnTopBindsBoot binds
 171          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 172                                bound_names binds }
 173
 174 -- Wrapper if we don't need to do anything in between the left and right,
 175 -- or anything else in the scope of the left
 176 --
 177 -- Never used when there are fixity declarations
 178 rnTopBinds :: HsValBinds RdrName
 179            -> RnM (HsValBinds Name, DefUses)
 180 rnTopBinds b =
 181   do nl <- rnTopBindsLHS emptyFsEnv b
 182      let bound_names = collectHsValBinders nl
 183      bindLocalNames bound_names $ rnTopBindsRHS (mkNameSet bound_names) nl
 184
 185
 186 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 187 -- A hs-boot file has no bindings.
 188 -- Return a single HsBindGroup with empty binds and renamed signatures
 189 rnTopBindsBoot (ValBindsIn mbinds sigs)
 190   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 191         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 192         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 193 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 194 \end{code}
 195
 196
 197
 198 %*********************************************************
 199 %*                                                      *
 200                 HsLocalBinds
 201 %*                                                      *
 202 %*********************************************************
 203
 204 \begin{code}
 205 rnLocalBindsAndThen :: HsLocalBinds RdrName
 206                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 207                     -> RnM (result, FreeVars)
 208 -- This version (a) assumes that the binding vars are *not* already in scope
 209 --               (b) removes the binders from the free vars of the thing inside
 210 -- The parser doesn't produce ThenBinds
 211 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 212   = thing_inside EmptyLocalBinds
 213
 214 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 215   = rnValBindsAndThen val_binds $ \ val_binds' ->
 216       thing_inside (HsValBinds val_binds')
 217
 218 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 219     (binds',fv_binds) <- rnIPBinds binds
 220     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 221     return (thing, fvs_thing `plusFV` fv_binds)
 222
 223 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 224 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 225     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 226     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 227
 228 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 229 rnIPBind (IPBind n expr) = do
 230     name <- newIPNameRn  n
 231     (expr',fvExpr) <- rnLExpr expr
 232     return (IPBind name expr', fvExpr)
 233 \end{code}
 234
 235
 236 %************************************************************************
 237 %*                                                                      *
 238                 ValBinds
 239 %*                                                                      *
 240 %************************************************************************
 241
 242 \begin{code}
 243 -- Renaming local binding gropus
 244 -- Does duplicate/shadow check
 245 rnValBindsLHS :: MiniFixityEnv
 246               -> HsValBinds RdrName
 247               -> RnM ([Name], HsValBindsLR Name RdrName)
 248 rnValBindsLHS fix_env binds
 249   = do { -- Do error checking: we need to check for dups here because we
 250          -- don't don't bind all of the variables from the ValBinds at once
 251          -- with bindLocatedLocals any more.
 252          --
 253          -- Note that we don't want to do this at the top level, since
 254          -- sorting out duplicates and shadowing there happens elsewhere.
 255          -- The behavior is even different. For example,
 256          --   import A(f)
 257          --   f = ...
 258          -- should not produce a shadowing warning (but it will produce
 259          -- an ambiguity warning if you use f), but
 260          --   import A(f)
 261          --   g = let f = ... in f
 262          -- should.
 263        ; binds' <- rnValBindsLHSFromDoc (localRecNameMaker fix_env) binds
 264        ; let bound_names = collectHsValBinders binds'
 265        ; envs <- getRdrEnvs
 266        ; checkDupAndShadowedNames envs bound_names
 267        ; return (bound_names, binds') }
 268
 269 -- renames the left-hand sides
 270 -- generic version used both at the top level and for local binds
 271 -- does some error checking, but not what gets done elsewhere at the top level
 272 rnValBindsLHSFromDoc :: NameMaker
 273                      -> HsValBinds RdrName
 274                      -> RnM (HsValBindsLR Name RdrName)
 275 rnValBindsLHSFromDoc topP (ValBindsIn mbinds sigs)
 276   = do { mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 277        ; return $ ValBindsIn mbinds' sigs }
 278   where
 279     bndrs = collectHsBindsBinders mbinds
 280     doc   = text "In the binding group for:" <+> pprWithCommas ppr bndrs
 281
 282 rnValBindsLHSFromDoc _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 283
 284 -- General version used both from the top-level and for local things
 285 -- Assumes the LHS vars are in scope
 286 --
 287 -- Does not bind the local fixity declarations
 288 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 289                      -- The trimming function trims the free vars we attach to a
 290                      -- binding so that it stays reasonably small
 291                  -> NameSet     -- Names bound by the LHSes
 292                  -> HsValBindsLR Name RdrName
 293                  -> RnM (HsValBinds Name, DefUses)
 294
 295 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs)
 296   = do {  -- rename the sigs
 297          sigs' <- renameSigs (Just bound_names) okBindSig sigs
 298           -- rename the RHSes
 299        ; binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 300        ; case depAnalBinds binds_w_dus of
 301             (anal_binds, anal_dus) -> do
 302        { let valbind' = ValBindsOut anal_binds sigs'
 303              valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 304        ; return (valbind', valbind'_dus) }}
 305
 306 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 307
 308 -- Wrapper for local binds
 309 --
 310 -- The *client* of this function is responsible for checking for unused binders;
 311 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 312 --
 313 -- The client is also responsible for bringing the fixities into scope
 314 rnValBindsRHS :: NameSet  -- names bound by the LHSes
 315               -> HsValBindsLR Name RdrName
 316               -> RnM (HsValBinds Name, DefUses)
 317 rnValBindsRHS bound_names binds
 318   = rnValBindsRHSGen trim bound_names binds
 319   where
 320     trim fvs = intersectNameSet bound_names fvs
 321         -- Only keep the names the names from this group
 322
 323 -- for local binds
 324 -- wrapper that does both the left- and right-hand sides
 325 --
 326 -- here there are no local fixity decls passed in;
 327 -- the local fixity decls come from the ValBinds sigs
 328 rnValBindsAndThen :: HsValBinds RdrName
 329                   -> (HsValBinds Name -> RnM (result, FreeVars))
 330                   -> RnM (result, FreeVars)
 331 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 332  = do   {     -- (A) Create the local fixity environment
 333           new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 334
 335               -- (B) Rename the LHSes
 336         ; (bound_names, new_lhs) <- rnValBindsLHS new_fixities binds
 337
 338               --     ...and bring them (and their fixities) into scope
 339         ; bindLocalNamesFV bound_names              $
 340           addLocalFixities new_fixities bound_names $ do
 341
 342         {      -- (C) Do the RHS and thing inside
 343           (binds', dus) <- rnValBindsRHS (mkNameSet bound_names) new_lhs
 344         ; (result, result_fvs) <- thing_inside binds'
 345
 346                 -- Report unused bindings based on the (accurate)
 347                 -- findUses.  E.g.
 348                 --      let x = x in 3
 349                 -- should report 'x' unused
 350         ; let real_uses = findUses dus result_fvs
 351         ; warnUnusedLocalBinds bound_names real_uses
 352
 353         ; let
 354             -- The variables "used" in the val binds are:
 355             --   (1) the uses of the binds (duUses)
 356             --   (2) the FVs of the thing-inside
 357             all_uses = duUses dus `plusFV` result_fvs
 358                 -- Note [Unused binding hack]
 359                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 360                 -- Note that *in contrast* to the above reporting of
 361                 -- unused bindings, (1) above uses duUses to return *all*
 362                 -- the uses, even if the binding is unused.  Otherwise consider:
 363                 --      x = 3
 364                 --      y = let p = x in 'x'    -- NB: p not used
 365                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 366                 -- bindings in the wrong order, and the type checker will complain
 367                 -- that x isn't in scope
 368                 --
 369                 -- But note that this means we won't report 'x' as unused,
 370                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 371
 372         ; return (result, all_uses) }}
 373                 -- The bound names are pruned out of all_uses
 374                 -- by the bindLocalNamesFV call above
 375
 376 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 377
 378
 379 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 380 -- (We keep the location around for reporting duplicate fixity declarations.)
 381 --
 382 -- Checks for duplicates, but not that only locally defined things are fixed.
 383 -- Note: for local fixity declarations, duplicates would also be checked in
 384 --       check_sigs below.  But we also use this function at the top level.
 385
 386 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 387
 388 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 389  where
 390    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 391      { -- this fixity decl is a duplicate iff
 392        -- the ReaderName's OccName's FastString is already in the env
 393        -- (we only need to check the local fix_env because
 394        --  definitions of non-local will be caught elsewhere)
 395        let { fs = occNameFS (rdrNameOcc name)
 396            ; fix_item = L loc fixity };
 397
 398        case lookupFsEnv env fs of
 399          Nothing -> return $ extendFsEnv env fs fix_item
 400          Just (L loc' _) -> do
 401            { setSrcSpan loc $
 402              addErrAt name_loc (dupFixityDecl loc' name)
 403            ; return env}
 404      }
 405
 406 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 407 dupFixityDecl loc rdr_name
 408   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 409           ptext (sLit "also at ") <+> ppr loc]
 410
 411 ---------------------
 412
 413 -- renaming a single bind
 414
 415 rnBindLHS :: NameMaker
 416           -> SDoc
 417           -> LHsBind RdrName
 418           -- returns the renamed left-hand side,
 419           -- and the FreeVars *of the LHS*
 420           -- (i.e., any free variables of the pattern)
 421           -> RnM (LHsBindLR Name RdrName)
 422
 423 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 424                                          pat_rhs = grhss,
 425                                          pat_rhs_ty=pat_rhs_ty
 426                                        }))
 427   = setSrcSpan loc $ do
 428       -- we don't actually use the FV processing of rnPatsAndThen here
 429       (pat',pat'_fvs) <- rnBindPat name_maker pat
 430       return (L loc (PatBind { pat_lhs = pat',
 431                                pat_rhs = grhss,
 432                                -- we temporarily store the pat's FVs here;
 433                                -- gets updated to the FVs of the whole bind
 434                                -- when doing the RHS below
 435                                bind_fvs = pat'_fvs,
 436                                -- these will get ignored in the next pass,
 437                                -- when we rename the RHS
 438                                pat_rhs_ty = pat_rhs_ty }))
 439
 440 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 441                                          fun_infix = inf,
 442                                          fun_matches = matches,
 443                                          fun_co_fn = fun_co_fn,
 444                                          fun_tick = fun_tick
 445                                        }))
 446   = setSrcSpan loc $
 447     do { newname <- applyNameMaker name_maker name
 448        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 449                                   fun_infix = inf,
 450                                   fun_matches = matches,
 451                                   -- we temporatily store the LHS's FVs (empty in this case) here
 452                                   -- gets updated when doing the RHS below
 453                                   bind_fvs = emptyFVs,
 454                                   -- everything else will get ignored in the next pass
 455                                   fun_co_fn = fun_co_fn,
 456                                   fun_tick = fun_tick
 457                                   })) }
 458
 459 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 460
 461 -- assumes the left-hands-side vars are in scope
 462 rnBind :: (Name -> [Name])              -- Signature tyvar function
 463        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 464        -> LHsBindLR Name RdrName
 465        -> RnM (LHsBind Name, [Name], Uses)
 466 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 467                                 pat_rhs = grhss,
 468                                 -- pat fvs were stored here while
 469                                 -- after processing the LHS
 470                                 bind_fvs = pat_fvs }))
 471   = setSrcSpan loc $
 472     do  {let bndrs = collectPatBinders pat
 473
 474         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 475                 -- No scoped type variables for pattern bindings
 476         ; let all_fvs = pat_fvs `plusFV` fvs
 477               fvs'    = trim all_fvs
 478
 479         ; fvs' `seq` -- See Note [Free-variable space leak]
 480           return (L loc (PatBind { pat_lhs    = pat,
 481                                    pat_rhs    = grhss',
 482                                    pat_rhs_ty = placeHolderType,
 483                                    bind_fvs   = fvs' }),
 484                   bndrs, all_fvs) }
 485
 486 rnBind sig_fn
 487        trim
 488        (L loc (FunBind { fun_id = name,
 489                          fun_infix = is_infix,
 490                          fun_matches = matches,
 491                          -- no pattern FVs
 492                          bind_fvs = _
 493                        }))
 494        -- invariant: no free vars here when it's a FunBind
 495   = setSrcSpan loc $
 496     do  { let plain_name = unLoc name
 497
 498         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 499                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 500                              rnMatchGroup (FunRhs plain_name is_infix) matches
 501         ; let fvs' = trim fvs
 502
 503         ; when is_infix $ checkPrecMatch plain_name matches'
 504
 505         ; fvs' `seq` -- See Note [Free-variable space leak]
 506
 507           return (L loc (FunBind { fun_id = name,
 508                                    fun_infix = is_infix,
 509                                    fun_matches = matches',
 510                                    bind_fvs = fvs',
 511                                    fun_co_fn = idHsWrapper,
 512                                    fun_tick = Nothing }),
 513                   [plain_name], fvs)
 514       }
 515
 516 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 517
 518 {-
 519 Note [Free-variable space leak]
 520 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 521 We have
 522     fvs' = trim fvs
 523 and we seq fvs' before turning it as part of a record.
 524
 525 The reason is that trim is sometimes something like
 526     \xs -> intersectNameSet (mkNameSet bound_names) xs
 527 and we don't want to retain the list bound_names. This showed up in
 528 trac ticket #1136.
 529 -}
 530
 531 ---------------------
 532 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 533              -> ([(RecFlag, LHsBinds Name)], DefUses)
 534 -- Dependency analysis; this is important so that
 535 -- unused-binding reporting is accurate
 536 depAnalBinds binds_w_dus
 537   = (map get_binds sccs, map get_du sccs)
 538   where
 539     sccs = stronglyConnCompFromEdgedVertices edges
 540
 541     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 542
 543     edges = [ (node, key, [key | n <- nameSetToList uses,
 544                                  Just key <- [lookupNameEnv key_map n] ])
 545             | (node@(_,_,uses), key) <- keyd_nodes ]
 546
 547     key_map :: NameEnv Int      -- Which binding it comes from
 548     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 549                                      , bndr <- bndrs ]
 550
 551     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 552     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 553
 554     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 555     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 556         where
 557           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 558           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 559
 560
 561 ---------------------
 562 -- Bind the top-level forall'd type variables in the sigs.
 563 -- E.g  f :: a -> a
 564 --      f = rhs
 565 --      The 'a' scopes over the rhs
 566 --
 567 -- NB: there'll usually be just one (for a function binding)
 568 --     but if there are many, one may shadow the rest; too bad!
 569 --      e.g  x :: [a] -> [a]
 570 --           y :: [(a,a)] -> a
 571 --           (x,y) = e
 572 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 573
 574 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 575 -- Return a lookup function that maps an Id Name to the names
 576 -- of the type variables that should scope over its body..
 577 mkSigTvFn sigs
 578   = \n -> lookupNameEnv env n `orElse` []
 579   where
 580     env :: NameEnv [Name]
 581     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 582                     | L _ (TypeSig (L _ name)
 583                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 584         -- Note the pattern-match on "Explicit"; we only bind
 585         -- type variables from signatures with an explicit top-level for-all
 586 \end{code}
 587
 588
 589 @rnMethodBinds@ is used for the method bindings of a class and an instance
 590 declaration.   Like @rnBinds@ but without dependency analysis.
 591
 592 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 593 That's crucial when dealing with an instance decl:
 594 \begin{verbatim}
 595         instance Foo (T a) where
 596            op x = ...
 597 \end{verbatim}
 598 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 599 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 600 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 601 in many ways the @op@ in an instance decl is just like an occurrence, not
 602 a binder.
 603
 604 \begin{code}
 605 rnMethodBinds :: Name                   -- Class name
 606               -> (Name -> [Name])       -- Signature tyvar function
 607               -> [Name]                 -- Names for generic type variables
 608               -> LHsBinds RdrName
 609               -> RnM (LHsBinds Name, FreeVars)
 610
 611 rnMethodBinds cls sig_fn gen_tyvars binds
 612   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 613   where do_one (binds,fvs) bind = do
 614            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 615            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 616
 617 rnMethodBind :: Name
 618               -> (Name -> [Name])
 619               -> [Name]
 620               -> LHsBindLR RdrName RdrName
 621               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 622 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = is_infix,
 623                                                      fun_matches = MatchGroup matches _ }))
 624   = setSrcSpan loc $ do
 625     sel_name <- wrapLocM (lookupInstDeclBndr cls) name
 626     let plain_name = unLoc sel_name
 627         -- We use the selector name as the binder
 628
 629     (new_matches, fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 630                           mapFvRn (rn_match (FunRhs plain_name is_infix)) matches
 631     let new_group = MatchGroup new_matches placeHolderType
 632
 633     when is_infix $ checkPrecMatch plain_name new_group
 634     return (unitBag (L loc (FunBind {
 635                                 fun_id = sel_name, fun_infix = is_infix,
 636                                 fun_matches = new_group,
 637                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 638                                 fun_tick = Nothing })),
 639              fvs `addOneFV` plain_name)
 640         -- The 'fvs' field isn't used for method binds
 641   where
 642         -- Truly gruesome; bring into scope the correct members of the generic
 643         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 644     rn_match info match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 645         = extendTyVarEnvFVRn gen_tvs    $
 646           rnMatch info match
 647         where
 648           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 649           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 650
 651     rn_match info match = rnMatch info match
 652
 653 -- Can't handle method pattern-bindings which bind multiple methods.
 654 rnMethodBind _ _ _ (L loc bind@(PatBind {})) = do
 655     addErrAt loc (methodBindErr bind)
 656     return (emptyBag, emptyFVs)
 657
 658 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 659 \end{code}
 660
 661
 662
 663 %************************************************************************
 664 %*                                                                      *
 665 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 666 %*                                                                      *
 667 %************************************************************************
 668
 669 @renameSigs@ checks for:
 670 \begin{enumerate}
 671 \item more than one sig for one thing;
 672 \item signatures given for things not bound here;
 673 \end{enumerate}
 674 %
 675 At the moment we don't gather free-var info from the types in
 676 signatures.  We'd only need this if we wanted to report unused tyvars.
 677
 678 \begin{code}
 679 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 680            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 681            -> [LSig RdrName]
 682            -> RnM [LSig Name]
 683 -- Renames the signatures and performs error checks
 684 renameSigs mb_names ok_sig sigs
 685   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 686         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 687         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 688         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 689         ; return sigs' }
 690
 691 ----------------------
 692 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 693 -- because this won't work for:
 694 --      instance Foo T where
 695 --        {-# INLINE op #-}
 696 --        Baz.op = ...
 697 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 698 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 699 -- Doesn't seem worth much trouble to sort this.
 700
 701 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 702 -- FixitySig is renamed elsewhere.
 703 renameSig _ (IdSig x)
 704   = return (IdSig x)      -- Actually this never occurs
 705 renameSig mb_names sig@(TypeSig v ty)
 706   = do  { new_v <- lookupSigOccRn mb_names sig v
 707         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 708         ; return (TypeSig new_v new_ty) }
 709
 710 renameSig _ (SpecInstSig ty)
 711   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 712         ; return (SpecInstSig new_ty) }
 713
 714 renameSig mb_names sig@(SpecSig v ty inl)
 715   = do  { new_v <- lookupSigOccRn mb_names sig v
 716         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 717         ; return (SpecSig new_v new_ty inl) }
 718
 719 renameSig mb_names sig@(InlineSig v s)
 720   = do  { new_v <- lookupSigOccRn mb_names sig v
 721         ; return (InlineSig new_v s) }
 722
 723 renameSig mb_names sig@(FixSig (FixitySig v f))
 724   = do  { new_v <- lookupSigOccRn mb_names sig v
 725         ; return (FixSig (FixitySig new_v f)) }
 726 \end{code}
 727
 728
 729 %************************************************************************
 730 %*                                                                      *
 731 \subsection{Match}
 732 %*                                                                      *
 733 %************************************************************************
 734
 735 \begin{code}
 736 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 737 rnMatchGroup ctxt (MatchGroup ms _)
 738   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 739        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 740
 741 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 742 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 743
 744 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 745 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 746   = do  {       -- Result type signatures are no longer supported
 747           case maybe_rhs_sig of
 748                 Nothing -> return ()
 749                 Just (L loc ty) -> addErrAt loc (resSigErr ctxt match ty)
 750
 751                -- Now the main event
 752                -- note that there are no local ficity decls for matches
 753         ; rnPats ctxt pats      $ \ pats' -> do
 754         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 755
 756         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 757         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 758
 759 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 760 resSigErr ctxt match ty
 761    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 762           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 763           , pprMatchInCtxt ctxt match ]
 764 \end{code}
 765
 766
 767 %************************************************************************
 768 %*                                                                      *
 769 \subsubsection{Guarded right-hand sides (GRHSs)}
 770 %*                                                                      *
 771 %************************************************************************
 772
 773 \begin{code}
 774 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 775
 776 rnGRHSs ctxt (GRHSs grhss binds)
 777   = rnLocalBindsAndThen binds   $ \ binds' -> do
 778     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 779     return (GRHSs grhss' binds', fvGRHSs)
 780
 781 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 782 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 783
 784 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 785 rnGRHS' ctxt (GRHS guards rhs)
 786   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 787         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 788                                     rnLExpr rhs
 789
 790         ; unless (pattern_guards_allowed || is_standard_guard guards')
 791                  (addWarn (nonStdGuardErr guards'))
 792
 793         ; return (GRHS guards' rhs', fvs) }
 794   where
 795         -- Standard Haskell 1.4 guards are just a single boolean
 796         -- expression, rather than a list of qualifiers as in the
 797         -- Glasgow extension
 798     is_standard_guard []                     = True
 799     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 800     is_standard_guard _                      = False
 801 \end{code}
 802
 803 %************************************************************************
 804 %*                                                                      *
 805 \subsection{Error messages}
 806 %*                                                                      *
 807 %************************************************************************
 808
 809 \begin{code}
 810 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 811 dupSigDeclErr sigs@(L loc sig : _)
 812   = addErrAt loc $
 813         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 814               nest 2 (vcat (map ppr_sig sigs))]
 815   where
 816     what_it_is = hsSigDoc sig
 817     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 818 dupSigDeclErr [] = panic "dupSigDeclErr"
 819
 820 unknownSigErr :: LSig RdrName -> RnM ()
 821 unknownSigErr (L loc sig)
 822   = addErrAt loc $
 823     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 824
 825 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 826 methodBindErr mbind
 827  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 828        2 (ppr mbind)
 829
 830 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 831 bindsInHsBootFile mbinds
 832   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 833        2 (ppr mbinds)
 834
 835 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 836 nonStdGuardErr guards
 837   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 838        4 (interpp'SP guards)
 839 \end{code}