compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPatsAndThen_LocalRightwards, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import PrelNames        ( mkUnboundName )
  32 import DynFlags ( DynFlag(..) )
  33 import Name
  34 import NameEnv
  35 import NameSet
  36 import RdrName          ( RdrName, rdrNameOcc )
  37 import SrcLoc
  38 import ListSetOps       ( findDupsEq )
  39 import BasicTypes       ( RecFlag(..) )
  40 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  41 import Bag
  42 import Outputable
  43 import FastString
  44 import Data.List        ( partition )
  45 import Maybes           ( orElse )
  46 import Monad            ( foldM, unless )
  47 \end{code}
  48
  49 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  50 -- place and can be used when complaining.
  51
  52 The code tree received by the function @rnBinds@ contains definitions
  53 in where-clauses which are all apparently mutually recursive, but which may
  54 not really depend upon each other. For example, in the top level program
  55 \begin{verbatim}
  56 f x = y where a = x
  57               y = x
  58 \end{verbatim}
  59 the definitions of @a@ and @y@ do not depend on each other at all.
  60 Unfortunately, the typechecker cannot always check such definitions.
  61 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  62 definitions. In Proceedings of the International Symposium on Programming,
  63 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  64 However, the typechecker usually can check definitions in which only the
  65 strongly connected components have been collected into recursive bindings.
  66 This is precisely what the function @rnBinds@ does.
  67
  68 ToDo: deal with case where a single monobinds binds the same variable
  69 twice.
  70
  71 The vertag tag is a unique @Int@; the tags only need to be unique
  72 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  73 (heavy monad machinery not needed).
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 %* naming conventions                                                   *
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \subsection[name-conventions]{Name conventions}
  83
  84 The basic algorithm involves walking over the tree and returning a tuple
  85 containing the new tree plus its free variables. Some functions, such
  86 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  87 list comprehensions (@Quals@), return the variables bound in local
  88 environments. These are then used to calculate the free variables of the
  89 expression evaluated in these environments.
  90
  91 Conventions for variable names are as follows:
  92 \begin{itemize}
  93 \item
  94 new code is given a prime to distinguish it from the old.
  95
  96 \item
  97 a set of variables defined in @Exp@ is written @dvExp@
  98
  99 \item
 100 a set of variables free in @Exp@ is written @fvExp@
 101 \end{itemize}
 102
 103 %************************************************************************
 104 %*                                                                      *
 105 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 106 %*                                                                      *
 107 %************************************************************************
 108
 109 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 110
 111 Non-recursive expressions are reconstructed without any changes at top
 112 level, although their component expressions may have to be altered.
 113 However, non-recursive expressions are currently not expected as
 114 \Haskell{} programs, and this code should not be executed.
 115
 116 Monomorphic bindings contain information that is returned in a tuple
 117 (a @FlatMonoBinds@) containing:
 118
 119 \begin{enumerate}
 120 \item
 121 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 122
 123 \item
 124 the name of a function or the names in a pattern. These are a set
 125 referred to as @dvLhs@, the defined variables of the left hand side.
 126
 127 \item
 128 the free variables of the body. These are referred to as @fvBody@.
 129
 130 \item
 131 the definition's actual code. This is referred to as just @code@.
 132 \end{enumerate}
 133
 134 The function @nonRecDvFv@ returns two sets of variables. The first is
 135 the set of variables defined in the set of monomorphic bindings, while the
 136 second is the set of free variables in those bindings.
 137
 138 The set of variables defined in a non-recursive binding is just the
 139 union of all of them, as @union@ removes duplicates. However, the
 140 free variables in each successive set of cumulative bindings is the
 141 union of those in the previous set plus those of the newest binding after
 142 the defined variables of the previous set have been removed.
 143
 144 @rnMethodBinds@ deals only with the declarations in class and
 145 instance declarations.  It expects only to see @FunMonoBind@s, and
 146 it expects the global environment to contain bindings for the binders
 147 (which are all class operations).
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsubsection{ Top-level bindings}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 -- for top-level bindings, we need to make top-level names,
 157 -- so we have a different entry point than for local bindings
 158 rnTopBindsLHS :: MiniFixityEnv
 159               -> HsValBinds RdrName
 160               -> RnM (HsValBindsLR Name RdrName)
 161 rnTopBindsLHS fix_env binds =
 162     (uncurry $ rnValBindsLHSFromDoc (topRecNameMaker fix_env)) (bindersAndDoc binds) binds
 163
 164 rnTopBindsRHS :: [Name] -- the names bound by these binds
 165               -> HsValBindsLR Name RdrName
 166               -> RnM (HsValBinds Name, DefUses)
 167 rnTopBindsRHS bound_names binds =
 168     do { is_boot <- tcIsHsBoot
 169        ; if is_boot
 170          then rnTopBindsBoot binds
 171          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 172                                bound_names binds }
 173
 174
 175 -- wrapper if we don't need to do anything in between the left and right,
 176 -- or anything else in the scope of the left
 177 --
 178 -- never used when there are fixity declarations
 179 rnTopBinds :: HsValBinds RdrName
 180            -> RnM (HsValBinds Name, DefUses)
 181 rnTopBinds b =
 182   do nl <- rnTopBindsLHS emptyFsEnv b
 183      let bound_names = map unLoc (collectHsValBinders nl)
 184      bindLocalNames bound_names  $ rnTopBindsRHS bound_names nl
 185
 186
 187 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 188 -- A hs-boot file has no bindings.
 189 -- Return a single HsBindGroup with empty binds and renamed signatures
 190 rnTopBindsBoot (ValBindsIn mbinds sigs)
 191   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 192         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 193         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 194 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 195 \end{code}
 196
 197
 198
 199 %*********************************************************
 200 %*                                                      *
 201                 HsLocalBinds
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 rnLocalBindsAndThen :: HsLocalBinds RdrName
 207                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 208                     -> RnM (result, FreeVars)
 209 -- This version (a) assumes that the binding vars are *not* already in scope
 210 --               (b) removes the binders from the free vars of the thing inside
 211 -- The parser doesn't produce ThenBinds
 212 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 213   = thing_inside EmptyLocalBinds
 214
 215 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 216   = rnValBindsAndThen val_binds $ \ val_binds' ->
 217       thing_inside (HsValBinds val_binds')
 218
 219 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 220     (binds',fv_binds) <- rnIPBinds binds
 221     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 222     return (thing, fvs_thing `plusFV` fv_binds)
 223
 224 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 225 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 226     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 227     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 228
 229 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 230 rnIPBind (IPBind n expr) = do
 231     name <- newIPNameRn  n
 232     (expr',fvExpr) <- rnLExpr expr
 233     return (IPBind name expr', fvExpr)
 234 \end{code}
 235
 236
 237 %************************************************************************
 238 %*                                                                      *
 239                 ValBinds
 240 %*                                                                      *
 241 %************************************************************************
 242
 243 \begin{code}
 244 -- wrapper for local binds
 245 -- creates the documentation info and calls the helper below
 246 rnValBindsLHS :: MiniFixityEnv
 247               -> HsValBinds RdrName
 248               -> RnM (HsValBindsLR Name RdrName)
 249 rnValBindsLHS fix_env binds =
 250     let (boundNames,doc) = bindersAndDoc binds
 251     in rnValBindsLHSFromDoc_Local boundNames doc fix_env binds
 252
 253 -- a helper used for local binds that does the duplicates check,
 254 -- just so we don't forget to do it somewhere
 255 rnValBindsLHSFromDoc_Local :: [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 256                            -> SDoc              -- doc string for dup names and shadowing
 257                            -> MiniFixityEnv
 258                            -> HsValBinds RdrName
 259                            -> RnM (HsValBindsLR Name RdrName)
 260
 261 rnValBindsLHSFromDoc_Local boundNames doc fix_env binds = do
 262      -- Do error checking: we need to check for dups here because we
 263      -- don't don't bind all of the variables from the ValBinds at once
 264      -- with bindLocatedLocals any more.
 265      checkDupAndShadowedRdrNames doc boundNames
 266
 267      -- (Note that we don't want to do this at the top level, since
 268      -- sorting out duplicates and shadowing there happens elsewhere.
 269      -- The behavior is even different. For example,
 270      --   import A(f)
 271      --   f = ...
 272      -- should not produce a shadowing warning (but it will produce
 273      -- an ambiguity warning if you use f), but
 274      --   import A(f)
 275      --   g = let f = ... in f
 276      -- should.
 277      rnValBindsLHSFromDoc (localRecNameMaker fix_env) boundNames doc binds
 278
 279 bindersAndDoc :: HsValBinds RdrName -> ([Located RdrName], SDoc)
 280 bindersAndDoc binds =
 281     let
 282         -- the unrenamed bndrs for error checking and reporting
 283         orig = collectHsValBinders binds
 284         doc = text "In the binding group for:" <+> pprWithCommas ppr (map unLoc orig)
 285     in
 286       (orig, doc)
 287
 288 -- renames the left-hand sides
 289 -- generic version used both at the top level and for local binds
 290 -- does some error checking, but not what gets done elsewhere at the top level
 291 rnValBindsLHSFromDoc :: NameMaker
 292                      -> [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 293                      -> SDoc              -- doc string for dup names and shadowing
 294                      -> HsValBinds RdrName
 295                      -> RnM (HsValBindsLR Name RdrName)
 296 rnValBindsLHSFromDoc topP _original_bndrs doc (ValBindsIn mbinds sigs) = do
 297      -- rename the LHSes
 298      mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 299      return $ ValBindsIn mbinds' sigs
 300 rnValBindsLHSFromDoc _ _ _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 301
 302 -- General version used both from the top-level and for local things
 303 -- Assumes the LHS vars are in scope
 304 --
 305 -- Does not bind the local fixity declarations
 306 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 307                      -- The trimming function trims the free vars we attach to a
 308                      -- binding so that it stays reasonably small
 309                  -> [Name]  -- names bound by the LHSes
 310                  -> HsValBindsLR Name RdrName
 311                  -> RnM (HsValBinds Name, DefUses)
 312
 313 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs) = do
 314    -- rename the sigs
 315    env <- getGblEnv
 316    traceRn (ptext (sLit "Rename sigs") <+> ppr (tcg_rdr_env env))
 317    sigs' <- renameSigs (Just (mkNameSet bound_names)) okBindSig sigs
 318    -- rename the RHSes
 319    binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 320    case depAnalBinds binds_w_dus of
 321        (anal_binds, anal_dus) ->
 322            do let valbind' = ValBindsOut anal_binds sigs'
 323                   valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 324               return (valbind', valbind'_dus)
 325
 326 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 327
 328 -- Wrapper for local binds
 329 --
 330 -- The *client* of this function is responsible for checking for unused binders;
 331 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 332 --
 333 -- The client is also responsible for bringing the fixities into scope
 334 rnValBindsRHS :: [Name]  -- names bound by the LHSes
 335               -> HsValBindsLR Name RdrName
 336               -> RnM (HsValBinds Name, DefUses)
 337 rnValBindsRHS bound_names binds =
 338   rnValBindsRHSGen (\ fvs -> -- only keep the names the names from this group
 339                     intersectNameSet (mkNameSet bound_names) fvs) bound_names binds
 340
 341
 342 -- for local binds
 343 -- wrapper that does both the left- and right-hand sides
 344 --
 345 -- here there are no local fixity decls passed in;
 346 -- the local fixity decls come from the ValBinds sigs
 347 rnValBindsAndThen :: HsValBinds RdrName
 348                   -> (HsValBinds Name -> RnM (result, FreeVars))
 349                   -> RnM (result, FreeVars)
 350 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 351  = do   { let (original_bndrs, doc) = bindersAndDoc binds
 352
 353               -- (A) Create the local fixity environment
 354         ; new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 355
 356               -- (B) Rename the LHSes
 357         ; new_lhs <- rnValBindsLHSFromDoc_Local original_bndrs doc new_fixities binds
 358         ; let bound_names = map unLoc $ collectHsValBinders new_lhs
 359
 360               --     ...and bring them (and their fixities) into scope
 361         ; bindLocalNamesFV_WithFixities bound_names new_fixities $ do
 362
 363         {      -- (C) Do the RHS and thing inside
 364           (binds', dus) <- rnValBindsRHS bound_names new_lhs
 365         ; (result, result_fvs) <- thing_inside binds'
 366
 367                 -- Report unused bindings based on the (accurate)
 368                 -- findUses.  E.g.
 369                 --      let x = x in 3
 370                 -- should report 'x' unused
 371         ; let real_uses = findUses dus result_fvs
 372         ; warnUnusedLocalBinds bound_names real_uses
 373
 374         ; let
 375             -- The variables "used" in the val binds are:
 376             --   (1) the uses of the binds (duUses)
 377             --   (2) the FVs of the thing-inside
 378             all_uses = duUses dus `plusFV` result_fvs
 379                 -- Note [Unused binding hack]
 380                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 381                 -- Note that *in contrast* to the above reporting of
 382                 -- unused bindings, (1) above uses duUses to return *all*
 383                 -- the uses, even if the binding is unused.  Otherwise consider:
 384                 --      x = 3
 385                 --      y = let p = x in 'x'    -- NB: p not used
 386                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 387                 -- bindings in the wrong order, and the type checker will complain
 388                 -- that x isn't in scope
 389                 --
 390                 -- But note that this means we won't report 'x' as unused,
 391                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 392
 393         ; return (result, all_uses) }}
 394                 -- The bound names are pruned out of all_uses
 395                 -- by the bindLocalNamesFV call above
 396
 397 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 398
 399
 400 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 401 -- (We keep the location around for reporting duplicate fixity declarations.)
 402 --
 403 -- Checks for duplicates, but not that only locally defined things are fixed.
 404 -- Note: for local fixity declarations, duplicates would also be checked in
 405 --       check_sigs below.  But we also use this function at the top level.
 406
 407 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 408
 409 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 410  where
 411    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 412      { -- this fixity decl is a duplicate iff
 413        -- the ReaderName's OccName's FastString is already in the env
 414        -- (we only need to check the local fix_env because
 415        --  definitions of non-local will be caught elsewhere)
 416        let { fs = occNameFS (rdrNameOcc name)
 417            ; fix_item = L loc fixity };
 418
 419        case lookupFsEnv env fs of
 420          Nothing -> return $ extendFsEnv env fs fix_item
 421          Just (L loc' _) -> do
 422            { setSrcSpan loc $
 423              addLocErr (L name_loc name) (dupFixityDecl loc')
 424            ; return env}
 425      }
 426
 427 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 428 dupFixityDecl loc rdr_name
 429   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 430           ptext (sLit "also at ") <+> ppr loc]
 431
 432 ---------------------
 433
 434 -- renaming a single bind
 435
 436 rnBindLHS :: NameMaker
 437           -> SDoc
 438           -> LHsBind RdrName
 439           -- returns the renamed left-hand side,
 440           -- and the FreeVars *of the LHS*
 441           -- (i.e., any free variables of the pattern)
 442           -> RnM (LHsBindLR Name RdrName)
 443
 444 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 445                                          pat_rhs = grhss,
 446                                          pat_rhs_ty=pat_rhs_ty
 447                                        }))
 448   = setSrcSpan loc $ do
 449       -- we don't actually use the FV processing of rnPatsAndThen here
 450       (pat',pat'_fvs) <- rnBindPat name_maker pat
 451       return (L loc (PatBind { pat_lhs = pat',
 452                                pat_rhs = grhss,
 453                                -- we temporarily store the pat's FVs here;
 454                                -- gets updated to the FVs of the whole bind
 455                                -- when doing the RHS below
 456                                bind_fvs = pat'_fvs,
 457                                -- these will get ignored in the next pass,
 458                                -- when we rename the RHS
 459                                pat_rhs_ty = pat_rhs_ty }))
 460
 461 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 462                                          fun_infix = inf,
 463                                          fun_matches = matches,
 464                                          fun_co_fn = fun_co_fn,
 465                                          fun_tick = fun_tick
 466                                        }))
 467   = setSrcSpan loc $
 468     do { (newname, _fvs) <- applyNameMaker name_maker name $ \ newname ->
 469                             return (newname, emptyFVs)
 470        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 471                                   fun_infix = inf,
 472                                   fun_matches = matches,
 473                                   -- we temporatily store the LHS's FVs (empty in this case) here
 474                                   -- gets updated when doing the RHS below
 475                                   bind_fvs = emptyFVs,
 476                                   -- everything else will get ignored in the next pass
 477                                   fun_co_fn = fun_co_fn,
 478                                   fun_tick = fun_tick
 479                                   })) }
 480
 481 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 482
 483 -- assumes the left-hands-side vars are in scope
 484 rnBind :: (Name -> [Name])              -- Signature tyvar function
 485        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 486        -> LHsBindLR Name RdrName
 487        -> RnM (LHsBind Name, [Name], Uses)
 488 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 489                                 pat_rhs = grhss,
 490                                 -- pat fvs were stored here while
 491                                 -- processing the LHS
 492                                 bind_fvs=pat_fvs }))
 493   = setSrcSpan loc $
 494     do  {let bndrs = collectPatBinders pat
 495
 496         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 497                 -- No scoped type variables for pattern bindings
 498         ; let fvs' = trim fvs
 499
 500         ; fvs' `seq` -- See Note [Free-variable space leak]
 501       return (L loc (PatBind { pat_lhs = pat,
 502                                   pat_rhs = grhss',
 503                                      pat_rhs_ty = placeHolderType,
 504                                   bind_fvs = fvs' }),
 505                   bndrs, pat_fvs `plusFV` fvs) }
 506
 507 rnBind sig_fn
 508        trim
 509        (L loc (FunBind { fun_id = name,
 510                          fun_infix = inf,
 511                          fun_matches = matches,
 512                          -- no pattern FVs
 513                          bind_fvs = _
 514                        }))
 515        -- invariant: no free vars here when it's a FunBind
 516   = setSrcSpan loc $
 517     do  { let plain_name = unLoc name
 518
 519         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 520                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 521                              rnMatchGroup (FunRhs plain_name inf) matches
 522         ; let fvs' = trim fvs
 523
 524         ; checkPrecMatch inf plain_name matches'
 525
 526         ; fvs' `seq` -- See Note [Free-variable space leak]
 527       return (L loc (FunBind { fun_id = name,
 528                                   fun_infix = inf,
 529                                   fun_matches = matches',
 530                                      bind_fvs = fvs',
 531                                   fun_co_fn = idHsWrapper,
 532                                   fun_tick = Nothing }),
 533                   [plain_name], fvs)
 534       }
 535
 536 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 537
 538 {-
 539 Note [Free-variable space leak]
 540 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 541 We have
 542     fvs' = trim fvs
 543 and we seq fvs' before turning it as part of a record.
 544
 545 The reason is that trim is sometimes something like
 546     \xs -> intersectNameSet (mkNameSet bound_names) xs
 547 and we don't want to retain the list bound_names. This showed up in
 548 trac ticket #1136.
 549 -}
 550
 551 ---------------------
 552 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 553              -> ([(RecFlag, LHsBinds Name)], DefUses)
 554 -- Dependency analysis; this is important so that
 555 -- unused-binding reporting is accurate
 556 depAnalBinds binds_w_dus
 557   = (map get_binds sccs, map get_du sccs)
 558   where
 559     sccs = stronglyConnCompFromEdgedVertices edges
 560
 561     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 562
 563     edges = [ (node, key, [key | n <- nameSetToList uses,
 564                                  Just key <- [lookupNameEnv key_map n] ])
 565             | (node@(_,_,uses), key) <- keyd_nodes ]
 566
 567     key_map :: NameEnv Int      -- Which binding it comes from
 568     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 569                                      , bndr <- bndrs ]
 570
 571     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 572     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 573
 574     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 575     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 576         where
 577           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 578           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 579
 580
 581 ---------------------
 582 -- Bind the top-level forall'd type variables in the sigs.
 583 -- E.g  f :: a -> a
 584 --      f = rhs
 585 --      The 'a' scopes over the rhs
 586 --
 587 -- NB: there'll usually be just one (for a function binding)
 588 --     but if there are many, one may shadow the rest; too bad!
 589 --      e.g  x :: [a] -> [a]
 590 --           y :: [(a,a)] -> a
 591 --           (x,y) = e
 592 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 593
 594 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 595 -- Return a lookup function that maps an Id Name to the names
 596 -- of the type variables that should scope over its body..
 597 mkSigTvFn sigs
 598   = \n -> lookupNameEnv env n `orElse` []
 599   where
 600     env :: NameEnv [Name]
 601     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 602                     | L _ (TypeSig (L _ name)
 603                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 604         -- Note the pattern-match on "Explicit"; we only bind
 605         -- type variables from signatures with an explicit top-level for-all
 606 \end{code}
 607
 608
 609 @rnMethodBinds@ is used for the method bindings of a class and an instance
 610 declaration.   Like @rnBinds@ but without dependency analysis.
 611
 612 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 613 That's crucial when dealing with an instance decl:
 614 \begin{verbatim}
 615         instance Foo (T a) where
 616            op x = ...
 617 \end{verbatim}
 618 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 619 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 620 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 621 in many ways the @op@ in an instance decl is just like an occurrence, not
 622 a binder.
 623
 624 \begin{code}
 625 rnMethodBinds :: Name                   -- Class name
 626               -> (Name -> [Name])       -- Signature tyvar function
 627               -> [Name]                 -- Names for generic type variables
 628               -> LHsBinds RdrName
 629               -> RnM (LHsBinds Name, FreeVars)
 630
 631 rnMethodBinds cls sig_fn gen_tyvars binds
 632   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 633   where do_one (binds,fvs) bind = do
 634            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 635            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 636
 637 rnMethodBind :: Name
 638               -> (Name -> [Name])
 639               -> [Name]
 640               -> LHsBindLR RdrName RdrName
 641               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 642 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = inf,
 643                                                      fun_matches = MatchGroup matches _ }))
 644   = setSrcSpan loc $ do
 645     sel_name <- lookupInstDeclBndr cls name
 646     let plain_name = unLoc sel_name
 647         -- We use the selector name as the binder
 648
 649     bindSigTyVarsFV (sig_fn plain_name) $ do
 650      (new_matches, fvs) <- mapFvRn (rn_match plain_name) matches
 651      let
 652          new_group = MatchGroup new_matches placeHolderType
 653
 654      checkPrecMatch inf plain_name new_group
 655      return (unitBag (L loc (FunBind {
 656                                 fun_id = sel_name, fun_infix = inf,
 657                                 fun_matches = new_group,
 658                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 659                                 fun_tick = Nothing })),
 660              fvs `addOneFV` plain_name)
 661         -- The 'fvs' field isn't used for method binds
 662   where
 663         -- Truly gruesome; bring into scope the correct members of the generic
 664         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 665     rn_match sel_name match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 666         = extendTyVarEnvFVRn gen_tvs    $
 667           rnMatch (FunRhs sel_name inf) match
 668         where
 669           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 670           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 671
 672     rn_match sel_name match = rnMatch (FunRhs sel_name inf) match
 673
 674
 675 -- Can't handle method pattern-bindings which bind multiple methods.
 676 rnMethodBind _ _ _ mbind@(L _ (PatBind _ _ _ _)) = do
 677     addLocErr mbind methodBindErr
 678     return (emptyBag, emptyFVs)
 679
 680 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 681 \end{code}
 682
 683
 684
 685 %************************************************************************
 686 %*                                                                      *
 687 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 688 %*                                                                      *
 689 %************************************************************************
 690
 691 @renameSigs@ checks for:
 692 \begin{enumerate}
 693 \item more than one sig for one thing;
 694 \item signatures given for things not bound here;
 695 \end{enumerate}
 696 %
 697 At the moment we don't gather free-var info from the types in
 698 signatures.  We'd only need this if we wanted to report unused tyvars.
 699
 700 \begin{code}
 701 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 702            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 703            -> [LSig RdrName]
 704            -> RnM [LSig Name]
 705 -- Renames the signatures and performs error checks
 706 renameSigs mb_names ok_sig sigs
 707   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 708         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 709         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 710         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 711         ; return sigs' }
 712
 713 ----------------------
 714 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 715 -- because this won't work for:
 716 --      instance Foo T where
 717 --        {-# INLINE op #-}
 718 --        Baz.op = ...
 719 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 720 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 721 -- Doesn't seem worth much trouble to sort this.
 722
 723 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 724 -- FixitySig is renamed elsewhere.
 725 renameSig mb_names sig@(TypeSig v ty)
 726   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 727         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 728         ; return (TypeSig new_v new_ty) }
 729
 730 renameSig _ (SpecInstSig ty)
 731   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 732         ; return (SpecInstSig new_ty) }
 733
 734 renameSig mb_names sig@(SpecSig v ty inl)
 735   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 736         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 737         ; return (SpecSig new_v new_ty inl) }
 738
 739 renameSig mb_names sig@(InlineSig v s)
 740   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 741         ; return (InlineSig new_v s) }
 742
 743 renameSig mb_names sig@(FixSig (FixitySig v f))
 744   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 745         ; return (FixSig (FixitySig new_v f)) }
 746
 747 -- lookupSigOccRn is used for type signatures and pragmas
 748 -- Is this valid?
 749 --   module A
 750 --      import M( f )
 751 --      f :: Int -> Int
 752 --      f x = x
 753 -- It's clear that the 'f' in the signature must refer to A.f
 754 -- The Haskell98 report does not stipulate this, but it will!
 755 -- So we must treat the 'f' in the signature in the same way
 756 -- as the binding occurrence of 'f', using lookupBndrRn
 757 --
 758 -- However, consider this case:
 759 --      import M( f )
 760 --      f :: Int -> Int
 761 --      g x = x
 762 -- We don't want to say 'f' is out of scope; instead, we want to
 763 -- return the imported 'f', so that later on the reanamer will
 764 -- correctly report "misplaced type sig".
 765
 766 lookupSigLocOccRn :: Maybe NameSet -> Sig RdrName -> Located RdrName -> RnM (Located Name)
 767 lookupSigLocOccRn mb_names sig = wrapLocM (lookupSigOccRn mb_names sig)
 768
 769 lookupSigOccRn :: Maybe NameSet -> Sig RdrName -> RdrName -> RnM Name
 770 lookupSigOccRn mb_names sig v
 771   = do  { mb_n <- lookupBndrRn_maybe v
 772         ; case mb_n of {
 773             Just n  -> case mb_names of {
 774                         Nothing                      -> return n ;
 775                         Just ns | n `elemNameSet` ns -> return n
 776                                 | otherwise -> bale_out_with local_msg } ;
 777
 778             Nothing -> do
 779         { mb_n <- lookupGreRn_maybe v
 780         ; case mb_n of
 781             Just _  -> bale_out_with import_msg
 782             Nothing -> bale_out_with empty
 783         } }}
 784   where
 785     bale_out_with msg
 786         = do { addErr (sep [ ptext (sLit "The") <+> hsSigDoc sig
 787                                 <+> ptext (sLit "for") <+> quotes (ppr v)
 788                            , nest 2 $ ptext (sLit "lacks an accompanying binding")]
 789                        $$ nest 2 msg)
 790              ; return (mkUnboundName v) }
 791
 792     local_msg = parens $ ptext (sLit "The")  <+> hsSigDoc sig <+> ptext (sLit "must be given where")
 793                          <+> quotes (ppr v) <+> ptext (sLit "is declared")
 794
 795     import_msg = parens $ ptext (sLit "You cannot give a") <+> hsSigDoc sig
 796                           <+> ptext (sLit "an imported value")
 797 \end{code}
 798
 799
 800 %************************************************************************
 801 %*                                                                      *
 802 \subsection{Match}
 803 %*                                                                      *
 804 %************************************************************************
 805
 806 \begin{code}
 807 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 808 rnMatchGroup ctxt (MatchGroup ms _)
 809   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 810        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 811
 812 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 813 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 814
 815 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 816 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 817   = do  {       -- Result type signatures are no longer supported
 818           case maybe_rhs_sig of
 819                 Nothing -> return ()
 820                 Just ty -> addLocErr ty (resSigErr ctxt match)
 821
 822
 823                -- Now the main event
 824                -- note that there are no local ficity decls for matches
 825         ; rnPatsAndThen_LocalRightwards ctxt pats       $ \ pats' -> do
 826         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 827
 828         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 829         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 830   where
 831
 832 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 833 resSigErr ctxt match ty
 834    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 835           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 836           , pprMatchInCtxt ctxt match ]
 837 \end{code}
 838
 839
 840 %************************************************************************
 841 %*                                                                      *
 842 \subsubsection{Guarded right-hand sides (GRHSs)}
 843 %*                                                                      *
 844 %************************************************************************
 845
 846 \begin{code}
 847 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 848
 849 rnGRHSs ctxt (GRHSs grhss binds)
 850   = rnLocalBindsAndThen binds   $ \ binds' -> do
 851     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 852     return (GRHSs grhss' binds', fvGRHSs)
 853
 854 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 855 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 856
 857 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 858 rnGRHS' ctxt (GRHS guards rhs)
 859   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 860         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 861                                     rnLExpr rhs
 862
 863         ; unless (pattern_guards_allowed || is_standard_guard guards')
 864                  (addWarn (nonStdGuardErr guards'))
 865
 866         ; return (GRHS guards' rhs', fvs) }
 867   where
 868         -- Standard Haskell 1.4 guards are just a single boolean
 869         -- expression, rather than a list of qualifiers as in the
 870         -- Glasgow extension
 871     is_standard_guard []                     = True
 872     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 873     is_standard_guard _                      = False
 874 \end{code}
 875
 876 %************************************************************************
 877 %*                                                                      *
 878 \subsection{Error messages}
 879 %*                                                                      *
 880 %************************************************************************
 881
 882 \begin{code}
 883 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 884 dupSigDeclErr sigs@(L loc sig : _)
 885   = addErrAt loc $
 886         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 887               nest 2 (vcat (map ppr_sig sigs))]
 888   where
 889     what_it_is = hsSigDoc sig
 890     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 891 dupSigDeclErr [] = panic "dupSigDeclErr"
 892
 893 unknownSigErr :: LSig RdrName -> RnM ()
 894 unknownSigErr (L loc sig)
 895   = addErrAt loc $
 896     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 897
 898 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 899 methodBindErr mbind
 900  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 901        2 (ppr mbind)
 902
 903 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 904 bindsInHsBootFile mbinds
 905   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 906        2 (ppr mbinds)
 907
 908 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 909 nonStdGuardErr guards
 910   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 911        4 (interpp'SP guards)
 912 \end{code}