compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPatsAndThen_LocalRightwards, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import PrelNames        ( mkUnboundName )
  32 import DynFlags ( DynFlag(..) )
  33 import Name
  34 import NameEnv
  35 import NameSet
  36 import RdrName          ( RdrName, rdrNameOcc )
  37 import SrcLoc
  38 import ListSetOps       ( findDupsEq )
  39 import BasicTypes       ( RecFlag(..) )
  40 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  41 import Bag
  42 import Outputable
  43 import FastString
  44 import Data.List        ( partition )
  45 import Maybes           ( orElse )
  46 import Monad            ( foldM, unless )
  47 \end{code}
  48
  49 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  50 -- place and can be used when complaining.
  51
  52 The code tree received by the function @rnBinds@ contains definitions
  53 in where-clauses which are all apparently mutually recursive, but which may
  54 not really depend upon each other. For example, in the top level program
  55 \begin{verbatim}
  56 f x = y where a = x
  57               y = x
  58 \end{verbatim}
  59 the definitions of @a@ and @y@ do not depend on each other at all.
  60 Unfortunately, the typechecker cannot always check such definitions.
  61 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  62 definitions. In Proceedings of the International Symposium on Programming,
  63 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  64 However, the typechecker usually can check definitions in which only the
  65 strongly connected components have been collected into recursive bindings.
  66 This is precisely what the function @rnBinds@ does.
  67
  68 ToDo: deal with case where a single monobinds binds the same variable
  69 twice.
  70
  71 The vertag tag is a unique @Int@; the tags only need to be unique
  72 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  73 (heavy monad machinery not needed).
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 %* naming conventions                                                   *
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \subsection[name-conventions]{Name conventions}
  83
  84 The basic algorithm involves walking over the tree and returning a tuple
  85 containing the new tree plus its free variables. Some functions, such
  86 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  87 list comprehensions (@Quals@), return the variables bound in local
  88 environments. These are then used to calculate the free variables of the
  89 expression evaluated in these environments.
  90
  91 Conventions for variable names are as follows:
  92 \begin{itemize}
  93 \item
  94 new code is given a prime to distinguish it from the old.
  95
  96 \item
  97 a set of variables defined in @Exp@ is written @dvExp@
  98
  99 \item
 100 a set of variables free in @Exp@ is written @fvExp@
 101 \end{itemize}
 102
 103 %************************************************************************
 104 %*                                                                      *
 105 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 106 %*                                                                      *
 107 %************************************************************************
 108
 109 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 110
 111 Non-recursive expressions are reconstructed without any changes at top
 112 level, although their component expressions may have to be altered.
 113 However, non-recursive expressions are currently not expected as
 114 \Haskell{} programs, and this code should not be executed.
 115
 116 Monomorphic bindings contain information that is returned in a tuple
 117 (a @FlatMonoBinds@) containing:
 118
 119 \begin{enumerate}
 120 \item
 121 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 122
 123 \item
 124 the name of a function or the names in a pattern. These are a set
 125 referred to as @dvLhs@, the defined variables of the left hand side.
 126
 127 \item
 128 the free variables of the body. These are referred to as @fvBody@.
 129
 130 \item
 131 the definition's actual code. This is referred to as just @code@.
 132 \end{enumerate}
 133
 134 The function @nonRecDvFv@ returns two sets of variables. The first is
 135 the set of variables defined in the set of monomorphic bindings, while the
 136 second is the set of free variables in those bindings.
 137
 138 The set of variables defined in a non-recursive binding is just the
 139 union of all of them, as @union@ removes duplicates. However, the
 140 free variables in each successive set of cumulative bindings is the
 141 union of those in the previous set plus those of the newest binding after
 142 the defined variables of the previous set have been removed.
 143
 144 @rnMethodBinds@ deals only with the declarations in class and
 145 instance declarations.  It expects only to see @FunMonoBind@s, and
 146 it expects the global environment to contain bindings for the binders
 147 (which are all class operations).
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsubsection{ Top-level bindings}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 -- for top-level bindings, we need to make top-level names,
 157 -- so we have a different entry point than for local bindings
 158 rnTopBindsLHS :: MiniFixityEnv
 159               -> HsValBinds RdrName
 160               -> RnM (HsValBindsLR Name RdrName)
 161 rnTopBindsLHS fix_env binds =
 162     (uncurry $ rnValBindsLHSFromDoc (topRecNameMaker fix_env)) (bindersAndDoc binds) binds
 163
 164 rnTopBindsRHS :: [Name] -- the names bound by these binds
 165               -> HsValBindsLR Name RdrName
 166               -> RnM (HsValBinds Name, DefUses)
 167 rnTopBindsRHS bound_names binds =
 168     do { is_boot <- tcIsHsBoot
 169        ; if is_boot
 170          then rnTopBindsBoot binds
 171          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 172                                bound_names binds }
 173
 174
 175 -- wrapper if we don't need to do anything in between the left and right,
 176 -- or anything else in the scope of the left
 177 --
 178 -- never used when there are fixity declarations
 179 rnTopBinds :: HsValBinds RdrName
 180            -> RnM (HsValBinds Name, DefUses)
 181 rnTopBinds b =
 182   do nl <- rnTopBindsLHS emptyFsEnv b
 183      let bound_names = map unLoc (collectHsValBinders nl)
 184      bindLocalNames bound_names  $ rnTopBindsRHS bound_names nl
 185
 186
 187 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 188 -- A hs-boot file has no bindings.
 189 -- Return a single HsBindGroup with empty binds and renamed signatures
 190 rnTopBindsBoot (ValBindsIn mbinds sigs)
 191   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 192         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 193         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 194 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 195 \end{code}
 196
 197
 198
 199 %*********************************************************
 200 %*                                                      *
 201                 HsLocalBinds
 202 %*                                                      *
 203 %*********************************************************
 204
 205 \begin{code}
 206 rnLocalBindsAndThen :: HsLocalBinds RdrName
 207                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 208                     -> RnM (result, FreeVars)
 209 -- This version (a) assumes that the binding vars are *not* already in scope
 210 --               (b) removes the binders from the free vars of the thing inside
 211 -- The parser doesn't produce ThenBinds
 212 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 213   = thing_inside EmptyLocalBinds
 214
 215 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 216   = rnValBindsAndThen val_binds $ \ val_binds' ->
 217       thing_inside (HsValBinds val_binds')
 218
 219 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 220     (binds',fv_binds) <- rnIPBinds binds
 221     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 222     return (thing, fvs_thing `plusFV` fv_binds)
 223
 224 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 225 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 226     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 227     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 228
 229 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 230 rnIPBind (IPBind n expr) = do
 231     name <- newIPNameRn  n
 232     (expr',fvExpr) <- rnLExpr expr
 233     return (IPBind name expr', fvExpr)
 234 \end{code}
 235
 236
 237 %************************************************************************
 238 %*                                                                      *
 239                 ValBinds
 240 %*                                                                      *
 241 %************************************************************************
 242
 243 \begin{code}
 244 -- wrapper for local binds
 245 -- creates the documentation info and calls the helper below
 246 rnValBindsLHS :: MiniFixityEnv
 247               -> HsValBinds RdrName
 248               -> RnM (HsValBindsLR Name RdrName)
 249 rnValBindsLHS fix_env binds =
 250     let (boundNames,doc) = bindersAndDoc binds
 251     in rnValBindsLHSFromDoc_Local boundNames doc fix_env binds
 252
 253 -- a helper used for local binds that does the duplicates check,
 254 -- just so we don't forget to do it somewhere
 255 rnValBindsLHSFromDoc_Local :: [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 256                            -> SDoc              -- doc string for dup names and shadowing
 257                            -> MiniFixityEnv
 258                            -> HsValBinds RdrName
 259                            -> RnM (HsValBindsLR Name RdrName)
 260
 261 rnValBindsLHSFromDoc_Local boundNames doc fix_env binds = do
 262      -- Do error checking: we need to check for dups here because we
 263      -- don't don't bind all of the variables from the ValBinds at once
 264      -- with bindLocatedLocals any more.
 265      checkDupAndShadowedRdrNames doc boundNames
 266
 267      -- (Note that we don't want to do this at the top level, since
 268      -- sorting out duplicates and shadowing there happens elsewhere.
 269      -- The behavior is even different. For example,
 270      --   import A(f)
 271      --   f = ...
 272      -- should not produce a shadowing warning (but it will produce
 273      -- an ambiguity warning if you use f), but
 274      --   import A(f)
 275      --   g = let f = ... in f
 276      -- should.
 277      rnValBindsLHSFromDoc (localRecNameMaker fix_env) boundNames doc binds
 278
 279 bindersAndDoc :: HsValBinds RdrName -> ([Located RdrName], SDoc)
 280 bindersAndDoc binds =
 281     let
 282         -- the unrenamed bndrs for error checking and reporting
 283         orig = collectHsValBinders binds
 284         doc = text "In the binding group for:" <+> pprWithCommas ppr (map unLoc orig)
 285     in
 286       (orig, doc)
 287
 288 -- renames the left-hand sides
 289 -- generic version used both at the top level and for local binds
 290 -- does some error checking, but not what gets done elsewhere at the top level
 291 rnValBindsLHSFromDoc :: NameMaker
 292                      -> [Located RdrName] -- RdrNames of the LHS (so we don't have to gather them twice)
 293                      -> SDoc              -- doc string for dup names and shadowing
 294                      -> HsValBinds RdrName
 295                      -> RnM (HsValBindsLR Name RdrName)
 296 rnValBindsLHSFromDoc topP _original_bndrs doc (ValBindsIn mbinds sigs) = do
 297      -- rename the LHSes
 298      mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 299      return $ ValBindsIn mbinds' sigs
 300 rnValBindsLHSFromDoc _ _ _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 301
 302 -- General version used both from the top-level and for local things
 303 -- Assumes the LHS vars are in scope
 304 --
 305 -- Does not bind the local fixity declarations
 306 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 307                      -- The trimming function trims the free vars we attach to a
 308                      -- binding so that it stays reasonably small
 309                  -> [Name]  -- names bound by the LHSes
 310                  -> HsValBindsLR Name RdrName
 311                  -> RnM (HsValBinds Name, DefUses)
 312
 313 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs) = do
 314    -- rename the sigs
 315    env <- getGblEnv
 316    traceRn (ptext (sLit "Rename sigs") <+> ppr (tcg_rdr_env env))
 317    sigs' <- renameSigs (Just (mkNameSet bound_names)) okBindSig sigs
 318    -- rename the RHSes
 319    binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 320    case depAnalBinds binds_w_dus of
 321        (anal_binds, anal_dus) ->
 322            do let valbind' = ValBindsOut anal_binds sigs'
 323                   valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 324               return (valbind', valbind'_dus)
 325
 326 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 327
 328 -- Wrapper for local binds
 329 --
 330 -- The *client* of this function is responsible for checking for unused binders;
 331 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 332 --
 333 -- The client is also responsible for bringing the fixities into scope
 334 rnValBindsRHS :: [Name]  -- names bound by the LHSes
 335               -> HsValBindsLR Name RdrName
 336               -> RnM (HsValBinds Name, DefUses)
 337 rnValBindsRHS bound_names binds =
 338   rnValBindsRHSGen (\ fvs -> -- only keep the names the names from this group
 339                     intersectNameSet (mkNameSet bound_names) fvs) bound_names binds
 340
 341
 342 -- for local binds
 343 -- wrapper that does both the left- and right-hand sides
 344 --
 345 -- here there are no local fixity decls passed in;
 346 -- the local fixity decls come from the ValBinds sigs
 347 rnValBindsAndThen :: HsValBinds RdrName
 348                   -> (HsValBinds Name -> RnM (result, FreeVars))
 349                   -> RnM (result, FreeVars)
 350 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 351  = do   { let (original_bndrs, doc) = bindersAndDoc binds
 352
 353               -- (A) Create the local fixity environment
 354         ; new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 355
 356               -- (B) Rename the LHSes
 357         ; new_lhs <- rnValBindsLHSFromDoc_Local original_bndrs doc new_fixities binds
 358         ; let bound_names = map unLoc $ collectHsValBinders new_lhs
 359
 360               --     ...and bring them (and their fixities) into scope
 361         ; bindLocalNamesFV_WithFixities bound_names new_fixities $ do
 362
 363         {      -- (C) Do the RHS and thing inside
 364           (binds', dus) <- rnValBindsRHS bound_names new_lhs
 365         ; (result, result_fvs) <- thing_inside binds'
 366
 367                 -- Report unused bindings based on the (accurate)
 368                 -- findUses.  E.g.
 369                 --      let x = x in 3
 370                 -- should report 'x' unused
 371         ; let real_uses = findUses dus result_fvs
 372         ; warnUnusedLocalBinds bound_names real_uses
 373
 374         ; let
 375             -- The variables "used" in the val binds are:
 376             --   (1) the uses of the binds (duUses)
 377             --   (2) the FVs of the thing-inside
 378             all_uses = duUses dus `plusFV` result_fvs
 379                 -- Note [Unused binding hack]
 380                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 381                 -- Note that *in contrast* to the above reporting of
 382                 -- unused bindings, (1) above uses duUses to return *all*
 383                 -- the uses, even if the binding is unused.  Otherwise consider:
 384                 --      x = 3
 385                 --      y = let p = x in 'x'    -- NB: p not used
 386                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 387                 -- bindings in the wrong order, and the type checker will complain
 388                 -- that x isn't in scope
 389                 --
 390                 -- But note that this means we won't report 'x' as unused,
 391                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 392
 393         ; return (result, all_uses) }}
 394                 -- The bound names are pruned out of all_uses
 395                 -- by the bindLocalNamesFV call above
 396
 397 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 398
 399
 400 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 401 -- (We keep the location around for reporting duplicate fixity declarations.)
 402 --
 403 -- Checks for duplicates, but not that only locally defined things are fixed.
 404 -- Note: for local fixity declarations, duplicates would also be checked in
 405 --       check_sigs below.  But we also use this function at the top level.
 406
 407 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 408
 409 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 410  where
 411    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 412      { -- this fixity decl is a duplicate iff
 413        -- the ReaderName's OccName's FastString is already in the env
 414        -- (we only need to check the local fix_env because
 415        --  definitions of non-local will be caught elsewhere)
 416        let { fs = occNameFS (rdrNameOcc name)
 417            ; fix_item = L loc fixity };
 418
 419        case lookupFsEnv env fs of
 420          Nothing -> return $ extendFsEnv env fs fix_item
 421          Just (L loc' _) -> do
 422            { setSrcSpan loc $
 423              addLocErr (L name_loc name) (dupFixityDecl loc')
 424            ; return env}
 425      }
 426
 427 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 428 dupFixityDecl loc rdr_name
 429   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 430           ptext (sLit "also at ") <+> ppr loc]
 431
 432 ---------------------
 433
 434 -- renaming a single bind
 435
 436 rnBindLHS :: NameMaker
 437           -> SDoc
 438           -> LHsBind RdrName
 439           -- returns the renamed left-hand side,
 440           -- and the FreeVars *of the LHS*
 441           -- (i.e., any free variables of the pattern)
 442           -> RnM (LHsBindLR Name RdrName)
 443
 444 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 445                                          pat_rhs = grhss,
 446                                          pat_rhs_ty=pat_rhs_ty
 447                                        }))
 448   = setSrcSpan loc $ do
 449       -- we don't actually use the FV processing of rnPatsAndThen here
 450       (pat',pat'_fvs) <- rnBindPat name_maker pat
 451       return (L loc (PatBind { pat_lhs = pat',
 452                                pat_rhs = grhss,
 453                                -- we temporarily store the pat's FVs here;
 454                                -- gets updated to the FVs of the whole bind
 455                                -- when doing the RHS below
 456                                bind_fvs = pat'_fvs,
 457                                -- these will get ignored in the next pass,
 458                                -- when we rename the RHS
 459                                pat_rhs_ty = pat_rhs_ty }))
 460
 461 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 462                                          fun_infix = inf,
 463                                          fun_matches = matches,
 464                                          fun_co_fn = fun_co_fn,
 465                                          fun_tick = fun_tick
 466                                        }))
 467   = setSrcSpan loc $
 468     do { (newname, _fvs) <- applyNameMaker name_maker name $ \ newname ->
 469                             return (newname, emptyFVs)
 470        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 471                                   fun_infix = inf,
 472                                   fun_matches = matches,
 473                                   -- we temporatily store the LHS's FVs (empty in this case) here
 474                                   -- gets updated when doing the RHS below
 475                                   bind_fvs = emptyFVs,
 476                                   -- everything else will get ignored in the next pass
 477                                   fun_co_fn = fun_co_fn,
 478                                   fun_tick = fun_tick
 479                                   })) }
 480
 481 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 482
 483 -- assumes the left-hands-side vars are in scope
 484 rnBind :: (Name -> [Name])              -- Signature tyvar function
 485        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 486        -> LHsBindLR Name RdrName
 487        -> RnM (LHsBind Name, [Name], Uses)
 488 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 489                                 pat_rhs = grhss,
 490                                 -- pat fvs were stored here while
 491                                 -- processing the LHS
 492                                 bind_fvs=pat_fvs }))
 493   = setSrcSpan loc $
 494     do  {let bndrs = collectPatBinders pat
 495
 496         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 497                 -- No scoped type variables for pattern bindings
 498
 499         ; return (L loc (PatBind { pat_lhs = pat,
 500                                   pat_rhs = grhss',
 501                                      pat_rhs_ty = placeHolderType,
 502                                   bind_fvs = trim fvs }),
 503                   bndrs, pat_fvs `plusFV` fvs) }
 504
 505 rnBind sig_fn
 506        trim
 507        (L loc (FunBind { fun_id = name,
 508                          fun_infix = inf,
 509                          fun_matches = matches,
 510                          -- no pattern FVs
 511                          bind_fvs = _
 512                        }))
 513        -- invariant: no free vars here when it's a FunBind
 514   = setSrcSpan loc $
 515     do  { let plain_name = unLoc name
 516
 517         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 518                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 519                              rnMatchGroup (FunRhs plain_name inf) matches
 520
 521         ; checkPrecMatch inf plain_name matches'
 522
 523         ; return (L loc (FunBind { fun_id = name,
 524                                   fun_infix = inf,
 525                                   fun_matches = matches',
 526                                      bind_fvs = trim fvs,
 527                                   fun_co_fn = idHsWrapper,
 528                                   fun_tick = Nothing }),
 529                   [plain_name], fvs)
 530       }
 531
 532 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 533
 534 ---------------------
 535 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 536              -> ([(RecFlag, LHsBinds Name)], DefUses)
 537 -- Dependency analysis; this is important so that
 538 -- unused-binding reporting is accurate
 539 depAnalBinds binds_w_dus
 540   = (map get_binds sccs, map get_du sccs)
 541   where
 542     sccs = stronglyConnCompFromEdgedVertices edges
 543
 544     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 545
 546     edges = [ (node, key, [key | n <- nameSetToList uses,
 547                                  Just key <- [lookupNameEnv key_map n] ])
 548             | (node@(_,_,uses), key) <- keyd_nodes ]
 549
 550     key_map :: NameEnv Int      -- Which binding it comes from
 551     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 552                                      , bndr <- bndrs ]
 553
 554     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 555     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 556
 557     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 558     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 559         where
 560           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 561           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 562
 563
 564 ---------------------
 565 -- Bind the top-level forall'd type variables in the sigs.
 566 -- E.g  f :: a -> a
 567 --      f = rhs
 568 --      The 'a' scopes over the rhs
 569 --
 570 -- NB: there'll usually be just one (for a function binding)
 571 --     but if there are many, one may shadow the rest; too bad!
 572 --      e.g  x :: [a] -> [a]
 573 --           y :: [(a,a)] -> a
 574 --           (x,y) = e
 575 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 576
 577 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 578 -- Return a lookup function that maps an Id Name to the names
 579 -- of the type variables that should scope over its body..
 580 mkSigTvFn sigs
 581   = \n -> lookupNameEnv env n `orElse` []
 582   where
 583     env :: NameEnv [Name]
 584     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 585                     | L _ (TypeSig (L _ name)
 586                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 587         -- Note the pattern-match on "Explicit"; we only bind
 588         -- type variables from signatures with an explicit top-level for-all
 589 \end{code}
 590
 591
 592 @rnMethodBinds@ is used for the method bindings of a class and an instance
 593 declaration.   Like @rnBinds@ but without dependency analysis.
 594
 595 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 596 That's crucial when dealing with an instance decl:
 597 \begin{verbatim}
 598         instance Foo (T a) where
 599            op x = ...
 600 \end{verbatim}
 601 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 602 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 603 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 604 in many ways the @op@ in an instance decl is just like an occurrence, not
 605 a binder.
 606
 607 \begin{code}
 608 rnMethodBinds :: Name                   -- Class name
 609               -> (Name -> [Name])       -- Signature tyvar function
 610               -> [Name]                 -- Names for generic type variables
 611               -> LHsBinds RdrName
 612               -> RnM (LHsBinds Name, FreeVars)
 613
 614 rnMethodBinds cls sig_fn gen_tyvars binds
 615   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 616   where do_one (binds,fvs) bind = do
 617            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 618            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 619
 620 rnMethodBind :: Name
 621               -> (Name -> [Name])
 622               -> [Name]
 623               -> LHsBindLR RdrName RdrName
 624               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 625 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = inf,
 626                                                      fun_matches = MatchGroup matches _ }))
 627   = setSrcSpan loc $ do
 628     sel_name <- lookupInstDeclBndr cls name
 629     let plain_name = unLoc sel_name
 630         -- We use the selector name as the binder
 631
 632     bindSigTyVarsFV (sig_fn plain_name) $ do
 633      (new_matches, fvs) <- mapFvRn (rn_match plain_name) matches
 634      let
 635          new_group = MatchGroup new_matches placeHolderType
 636
 637      checkPrecMatch inf plain_name new_group
 638      return (unitBag (L loc (FunBind {
 639                                 fun_id = sel_name, fun_infix = inf,
 640                                 fun_matches = new_group,
 641                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 642                                 fun_tick = Nothing })),
 643              fvs `addOneFV` plain_name)
 644         -- The 'fvs' field isn't used for method binds
 645   where
 646         -- Truly gruesome; bring into scope the correct members of the generic
 647         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 648     rn_match sel_name match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 649         = extendTyVarEnvFVRn gen_tvs    $
 650           rnMatch (FunRhs sel_name inf) match
 651         where
 652           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 653           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 654
 655     rn_match sel_name match = rnMatch (FunRhs sel_name inf) match
 656
 657
 658 -- Can't handle method pattern-bindings which bind multiple methods.
 659 rnMethodBind _ _ _ mbind@(L _ (PatBind _ _ _ _)) = do
 660     addLocErr mbind methodBindErr
 661     return (emptyBag, emptyFVs)
 662
 663 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 664 \end{code}
 665
 666
 667
 668 %************************************************************************
 669 %*                                                                      *
 670 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 671 %*                                                                      *
 672 %************************************************************************
 673
 674 @renameSigs@ checks for:
 675 \begin{enumerate}
 676 \item more than one sig for one thing;
 677 \item signatures given for things not bound here;
 678 \end{enumerate}
 679 %
 680 At the moment we don't gather free-var info from the types in
 681 signatures.  We'd only need this if we wanted to report unused tyvars.
 682
 683 \begin{code}
 684 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 685            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 686            -> [LSig RdrName]
 687            -> RnM [LSig Name]
 688 -- Renames the signatures and performs error checks
 689 renameSigs mb_names ok_sig sigs
 690   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 691         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 692         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 693         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 694         ; return sigs' }
 695
 696 ----------------------
 697 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 698 -- because this won't work for:
 699 --      instance Foo T where
 700 --        {-# INLINE op #-}
 701 --        Baz.op = ...
 702 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 703 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 704 -- Doesn't seem worth much trouble to sort this.
 705
 706 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 707 -- FixitySig is renamed elsewhere.
 708 renameSig mb_names sig@(TypeSig v ty)
 709   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 710         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 711         ; return (TypeSig new_v new_ty) }
 712
 713 renameSig _ (SpecInstSig ty)
 714   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 715         ; return (SpecInstSig new_ty) }
 716
 717 renameSig mb_names sig@(SpecSig v ty inl)
 718   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 719         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 720         ; return (SpecSig new_v new_ty inl) }
 721
 722 renameSig mb_names sig@(InlineSig v s)
 723   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 724         ; return (InlineSig new_v s) }
 725
 726 renameSig mb_names sig@(FixSig (FixitySig v f))
 727   = do  { new_v <- lookupSigLocOccRn mb_names sig v
 728         ; return (FixSig (FixitySig new_v f)) }
 729
 730 -- lookupSigOccRn is used for type signatures and pragmas
 731 -- Is this valid?
 732 --   module A
 733 --      import M( f )
 734 --      f :: Int -> Int
 735 --      f x = x
 736 -- It's clear that the 'f' in the signature must refer to A.f
 737 -- The Haskell98 report does not stipulate this, but it will!
 738 -- So we must treat the 'f' in the signature in the same way
 739 -- as the binding occurrence of 'f', using lookupBndrRn
 740 --
 741 -- However, consider this case:
 742 --      import M( f )
 743 --      f :: Int -> Int
 744 --      g x = x
 745 -- We don't want to say 'f' is out of scope; instead, we want to
 746 -- return the imported 'f', so that later on the reanamer will
 747 -- correctly report "misplaced type sig".
 748
 749 lookupSigLocOccRn :: Maybe NameSet -> Sig RdrName -> Located RdrName -> RnM (Located Name)
 750 lookupSigLocOccRn mb_names sig = wrapLocM (lookupSigOccRn mb_names sig)
 751
 752 lookupSigOccRn :: Maybe NameSet -> Sig RdrName -> RdrName -> RnM Name
 753 lookupSigOccRn mb_names sig v
 754   = do  { mb_n <- lookupBndrRn_maybe v
 755         ; case mb_n of {
 756             Just n  -> case mb_names of {
 757                         Nothing                      -> return n ;
 758                         Just ns | n `elemNameSet` ns -> return n
 759                                 | otherwise -> bale_out_with local_msg } ;
 760
 761             Nothing -> do
 762         { mb_n <- lookupGreRn_maybe v
 763         ; case mb_n of
 764             Just _  -> bale_out_with import_msg
 765             Nothing -> bale_out_with empty
 766         } }}
 767   where
 768     bale_out_with msg
 769         = do { addErr (sep [ ptext (sLit "The") <+> hsSigDoc sig
 770                                 <+> ptext (sLit "for") <+> quotes (ppr v)
 771                            , nest 2 $ ptext (sLit "lacks an accompanying binding")]
 772                        $$ nest 2 msg)
 773              ; return (mkUnboundName v) }
 774
 775     local_msg = parens $ ptext (sLit "The")  <+> hsSigDoc sig <+> ptext (sLit "must be given where")
 776                          <+> quotes (ppr v) <+> ptext (sLit "is declared")
 777
 778     import_msg = parens $ ptext (sLit "You cannot give a") <+> hsSigDoc sig
 779                           <+> ptext (sLit "an imported value")
 780 \end{code}
 781
 782
 783 %************************************************************************
 784 %*                                                                      *
 785 \subsection{Match}
 786 %*                                                                      *
 787 %************************************************************************
 788
 789 \begin{code}
 790 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 791 rnMatchGroup ctxt (MatchGroup ms _)
 792   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 793        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 794
 795 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 796 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 797
 798 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 799 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 800   = do  {       -- Result type signatures are no longer supported
 801           case maybe_rhs_sig of
 802                 Nothing -> return ()
 803                 Just ty -> addLocErr ty (resSigErr ctxt match)
 804
 805
 806                -- Now the main event
 807                -- note that there are no local ficity decls for matches
 808         ; rnPatsAndThen_LocalRightwards ctxt pats       $ \ pats' -> do
 809         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 810
 811         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 812         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 813   where
 814
 815 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 816 resSigErr ctxt match ty
 817    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 818           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 819           , pprMatchInCtxt ctxt match ]
 820 \end{code}
 821
 822
 823 %************************************************************************
 824 %*                                                                      *
 825 \subsubsection{Guarded right-hand sides (GRHSs)}
 826 %*                                                                      *
 827 %************************************************************************
 828
 829 \begin{code}
 830 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 831
 832 rnGRHSs ctxt (GRHSs grhss binds)
 833   = rnLocalBindsAndThen binds   $ \ binds' -> do
 834     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 835     return (GRHSs grhss' binds', fvGRHSs)
 836
 837 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 838 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 839
 840 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 841 rnGRHS' ctxt (GRHS guards rhs)
 842   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 843         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 844                                     rnLExpr rhs
 845
 846         ; unless (pattern_guards_allowed || is_standard_guard guards')
 847                  (addWarn (nonStdGuardErr guards'))
 848
 849         ; return (GRHS guards' rhs', fvs) }
 850   where
 851         -- Standard Haskell 1.4 guards are just a single boolean
 852         -- expression, rather than a list of qualifiers as in the
 853         -- Glasgow extension
 854     is_standard_guard []                     = True
 855     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 856     is_standard_guard _                      = False
 857 \end{code}
 858
 859 %************************************************************************
 860 %*                                                                      *
 861 \subsection{Error messages}
 862 %*                                                                      *
 863 %************************************************************************
 864
 865 \begin{code}
 866 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 867 dupSigDeclErr sigs@(L loc sig : _)
 868   = addErrAt loc $
 869         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 870               nest 2 (vcat (map ppr_sig sigs))]
 871   where
 872     what_it_is = hsSigDoc sig
 873     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 874 dupSigDeclErr [] = panic "dupSigDeclErr"
 875
 876 unknownSigErr :: LSig RdrName -> RnM ()
 877 unknownSigErr (L loc sig)
 878   = addErrAt loc $
 879     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 880
 881 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 882 methodBindErr mbind
 883  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 884        2 (ppr mbind)
 885
 886 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 887 bindsInHsBootFile mbinds
 888   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 889        2 (ppr mbinds)
 890
 891 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 892 nonStdGuardErr guards
 893   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 894        4 (interpp'SP guards)
 895 \end{code}