compiler/rename/RnHsSyn.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[RnHsSyn]{Specialisations of the @HsSyn@ syntax for the renamer}
   5
   6 \begin{code}
   7 module RnHsSyn(
   8         -- Names
   9         charTyCon_name, listTyCon_name, parrTyCon_name, tupleTyCon_name,
  10         extractHsTyVars, extractHsTyNames, extractHsTyNames_s,
  11         extractFunDepNames, extractHsCtxtTyNames, extractHsPredTyNames,
  12
  13         -- Free variables
  14         hsSigsFVs, hsSigFVs, conDeclFVs, bangTyFVs,
  15
  16         maybeGenericMatch
  17   ) where
  18
  19 #include "HsVersions.h"
  20
  21 import HsSyn
  22 import Class            ( FunDep )
  23 import TysWiredIn       ( tupleTyCon, listTyCon, parrTyCon, charTyCon )
  24 import Name             ( Name, getName, isTyVarName )
  25 import NameSet
  26 import BasicTypes       ( Boxity )
  27 import SrcLoc           ( Located(..), unLoc )
  28 \end{code}
  29
  30 %************************************************************************
  31 %*                                                                      *
  32 \subsection{Free variables}
  33 %*                                                                      *
  34 %************************************************************************
  35
  36 These free-variable finders returns tycons and classes too.
  37
  38 \begin{code}
  39 charTyCon_name, listTyCon_name, parrTyCon_name :: Name
  40 charTyCon_name    = getName charTyCon
  41 listTyCon_name    = getName listTyCon
  42 parrTyCon_name    = getName parrTyCon
  43
  44 tupleTyCon_name :: Boxity -> Int -> Name
  45 tupleTyCon_name boxity n = getName (tupleTyCon boxity n)
  46
  47 extractHsTyVars :: LHsType Name -> NameSet
  48 extractHsTyVars x = filterNameSet isTyVarName (extractHsTyNames x)
  49
  50 extractFunDepNames :: FunDep Name -> NameSet
  51 extractFunDepNames (ns1, ns2) = mkNameSet ns1 `unionNameSets` mkNameSet ns2
  52
  53 extractHsTyNames   :: LHsType Name -> NameSet
  54 extractHsTyNames ty
  55   = getl ty
  56   where
  57     getl (L _ ty) = get ty
  58
  59     get (HsAppTy ty1 ty2)      = getl ty1 `unionNameSets` getl ty2
  60     get (HsListTy ty)          = unitNameSet listTyCon_name `unionNameSets` getl ty
  61     get (HsPArrTy ty)          = unitNameSet parrTyCon_name `unionNameSets` getl ty
  62     get (HsTupleTy _ tys)      = extractHsTyNames_s tys
  63     get (HsFunTy ty1 ty2)      = getl ty1 `unionNameSets` getl ty2
  64     get (HsPredTy p)           = extractHsPredTyNames p
  65     get (HsOpTy ty1 op ty2)    = getl ty1 `unionNameSets` getl ty2 `unionNameSets` unitNameSet (unLoc op)
  66     get (HsParTy ty)           = getl ty
  67     get (HsBangTy _ ty)        = getl ty
  68     get (HsNumTy _)            = emptyNameSet
  69     get (HsTyVar tv)           = unitNameSet tv
  70     get (HsSpliceTy _)         = emptyNameSet   -- Type splices mention no type variables
  71     get (HsKindSig ty _)       = getl ty
  72     get (HsForAllTy _ tvs
  73                     ctxt ty)   = (extractHsCtxtTyNames ctxt
  74                                          `unionNameSets` getl ty)
  75                                             `minusNameSet`
  76                                   mkNameSet (hsLTyVarNames tvs)
  77     get (HsDocTy ty _)         = getl ty
  78
  79 extractHsTyNames_s  :: [LHsType Name] -> NameSet
  80 extractHsTyNames_s tys = foldr (unionNameSets . extractHsTyNames) emptyNameSet tys
  81
  82 extractHsCtxtTyNames :: LHsContext Name -> NameSet
  83 extractHsCtxtTyNames (L _ ctxt)
  84   = foldr (unionNameSets . extractHsPredTyNames . unLoc) emptyNameSet ctxt
  85
  86 -- You don't import or export implicit parameters,
  87 -- so don't mention the IP names
  88 extractHsPredTyNames :: HsPred Name -> NameSet
  89 extractHsPredTyNames (HsClassP cls tys)
  90   = unitNameSet cls `unionNameSets` extractHsTyNames_s tys
  91 extractHsPredTyNames (HsEqualP ty1 ty2)
  92   = extractHsTyNames ty1 `unionNameSets` extractHsTyNames ty2
  93 extractHsPredTyNames (HsIParam _ ty)
  94   = extractHsTyNames ty
  95 \end{code}
  96
  97
  98 %************************************************************************
  99 %*                                                                      *
 100 \subsection{Free variables of declarations}
 101 %*                                                                      *
 102 %************************************************************************
 103
 104 Return the Names that must be in scope if we are to use this declaration.
 105 In all cases this is set up for interface-file declarations:
 106         - for class decls we ignore the bindings
 107         - for instance decls likewise, plus the pragmas
 108         - for rule decls, we ignore HsRules
 109         - for data decls, we ignore derivings
 110
 111         *** See "THE NAMING STORY" in HsDecls ****
 112
 113 \begin{code}
 114 ----------------
 115 hsSigsFVs :: [LSig Name] -> FreeVars
 116 hsSigsFVs sigs = plusFVs (map (hsSigFVs.unLoc) sigs)
 117
 118 hsSigFVs :: Sig Name -> FreeVars
 119 hsSigFVs (TypeSig _ ty)   = extractHsTyNames ty
 120 hsSigFVs (SpecInstSig ty) = extractHsTyNames ty
 121 hsSigFVs (SpecSig _ ty _) = extractHsTyNames ty
 122 hsSigFVs _                = emptyFVs
 123
 124 ----------------
 125 conDeclFVs :: LConDecl Name -> FreeVars
 126 conDeclFVs (L _ (ConDecl { con_qvars = tyvars, con_cxt = context,
 127                            con_details = details, con_res = res_ty}))
 128   = delFVs (map hsLTyVarName tyvars) $
 129     extractHsCtxtTyNames context  `plusFV`
 130     conDetailsFVs details         `plusFV`
 131     conResTyFVs res_ty
 132
 133 conResTyFVs :: ResType Name -> FreeVars
 134 conResTyFVs ResTyH98       = emptyFVs
 135 conResTyFVs (ResTyGADT ty) = extractHsTyNames ty
 136
 137 conDetailsFVs :: HsConDeclDetails Name -> FreeVars
 138 conDetailsFVs details = plusFVs (map bangTyFVs (hsConDeclArgTys details))
 139
 140 bangTyFVs :: LHsType Name -> FreeVars
 141 bangTyFVs bty = extractHsTyNames (getBangType bty)
 142 \end{code}
 143
 144
 145 %************************************************************************
 146 %*                                                                      *
 147 \subsection{A few functions on generic defintions
 148 %*                                                                      *
 149 %************************************************************************
 150
 151 These functions on generics are defined over Matches Name, which is
 152 why they are here and not in HsMatches.
 153
 154 \begin{code}
 155 maybeGenericMatch :: LMatch Name -> Maybe (HsType Name, LMatch Name)
 156   -- Tells whether a Match is for a generic definition
 157   -- and extract the type from a generic match and put it at the front
 158
 159 maybeGenericMatch (L loc (Match (L _ (TypePat (L _ ty)) : pats) sig_ty grhss))
 160   = Just (ty, L loc (Match pats sig_ty grhss))
 161
 162 maybeGenericMatch _ = Nothing
 163 \end{code}