compiler/rename/RnTypes.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnSource]{Main pass of renamer}
   5
   6 \begin{code}
   7 module RnTypes (
   8         -- Type related stuff
   9         rnHsType, rnLHsType, rnLHsTypes, rnContext,
  10         rnHsSigType, rnHsTypeFVs,
  11
  12         -- Patterns and literals
  13         rnLPat, rnPat, rnPatsAndThen,   -- Here because it's not part
  14         rnLit, rnOverLit,               -- of any mutual recursion
  15
  16         -- Precence related stuff
  17         mkOpAppRn, mkNegAppRn, mkOpFormRn,
  18         checkPrecMatch, checkSectionPrec,
  19
  20         -- Error messages
  21         dupFieldErr, patSigErr, checkTupSize
  22   ) where
  23
  24 import DynFlags         ( DynFlag(Opt_WarnUnusedMatches, Opt_GlasgowExts, Opt_ScopedTypeVariables ) )
  25
  26 import HsSyn
  27 import RdrHsSyn         ( extractHsRhoRdrTyVars )
  28 import RnHsSyn          ( extractHsTyNames, parrTyCon_name, tupleTyCon_name,
  29                           listTyCon_name
  30                         )
  31 import RnHsDoc          ( rnLHsDoc )
  32 import RnEnv            ( lookupOccRn, lookupBndrRn, lookupSyntaxName,
  33                           lookupLocatedOccRn, lookupLocatedBndrRn,
  34                           lookupLocatedGlobalOccRn, bindTyVarsRn,
  35                           lookupFixityRn, lookupTyFixityRn,
  36                           mapFvRn, warnUnusedMatches,
  37                           newIPNameRn, bindPatSigTyVarsFV, bindLocatedLocalsFV )
  38 import TcRnMonad
  39 import RdrName          ( RdrName, elemLocalRdrEnv )
  40 import PrelNames        ( eqClassName, integralClassName, geName, eqName,
  41                           negateName, minusName, lengthPName, indexPName,
  42                           plusIntegerName, fromIntegerName, timesIntegerName,
  43                           ratioDataConName, fromRationalName )
  44 import TypeRep          ( funTyCon )
  45 import Constants        ( mAX_TUPLE_SIZE )
  46 import Name             ( Name )
  47 import SrcLoc           ( SrcSpan, Located(..), unLoc, noLoc, combineLocs )
  48 import NameSet
  49
  50 import Literal          ( inIntRange, inCharRange )
  51 import BasicTypes       ( compareFixity, funTyFixity, negateFixity,
  52                           Fixity(..), FixityDirection(..) )
  53 import ListSetOps       ( removeDups )
  54 import Outputable
  55
  56 #include "HsVersions.h"
  57 \end{code}
  58
  59 These type renamers are in a separate module, rather than in (say) RnSource,
  60 to break several loop.
  61
  62 %*********************************************************
  63 %*                                                      *
  64 \subsection{Renaming types}
  65 %*                                                      *
  66 %*********************************************************
  67
  68 \begin{code}
  69 rnHsTypeFVs :: SDoc -> LHsType RdrName -> RnM (LHsType Name, FreeVars)
  70 rnHsTypeFVs doc_str ty
  71   = rnLHsType doc_str ty        `thenM` \ ty' ->
  72     returnM (ty', extractHsTyNames ty')
  73
  74 rnHsSigType :: SDoc -> LHsType RdrName -> RnM (LHsType Name)
  75         -- rnHsSigType is used for source-language type signatures,
  76         -- which use *implicit* universal quantification.
  77 rnHsSigType doc_str ty
  78   = rnLHsType (text "In the type signature for" <+> doc_str) ty
  79 \end{code}
  80
  81 rnHsType is here because we call it from loadInstDecl, and I didn't
  82 want a gratuitous knot.
  83
  84 \begin{code}
  85 rnLHsType  :: SDoc -> LHsType RdrName -> RnM (LHsType Name)
  86 rnLHsType doc = wrapLocM (rnHsType doc)
  87
  88 rnHsType :: SDoc -> HsType RdrName -> RnM (HsType Name)
  89
  90 rnHsType doc (HsForAllTy Implicit _ ctxt ty)
  91         -- Implicit quantifiction in source code (no kinds on tyvars)
  92         -- Given the signature  C => T  we universally quantify
  93         -- over FV(T) \ {in-scope-tyvars}
  94   = getLocalRdrEnv              `thenM` \ name_env ->
  95     let
  96         mentioned = extractHsRhoRdrTyVars ctxt ty
  97
  98         -- Don't quantify over type variables that are in scope;
  99         -- when GlasgowExts is off, there usually won't be any, except for
 100         -- class signatures:
 101         --      class C a where { op :: a -> a }
 102         forall_tyvars = filter (not . (`elemLocalRdrEnv` name_env) . unLoc) mentioned
 103         tyvar_bndrs   = userHsTyVarBndrs forall_tyvars
 104     in
 105     rnForAll doc Implicit tyvar_bndrs ctxt ty
 106
 107 rnHsType doc (HsForAllTy Explicit forall_tyvars ctxt tau)
 108         -- Explicit quantification.
 109         -- Check that the forall'd tyvars are actually
 110         -- mentioned in the type, and produce a warning if not
 111   = let
 112         mentioned          = map unLoc (extractHsRhoRdrTyVars ctxt tau)
 113         forall_tyvar_names = hsLTyVarLocNames forall_tyvars
 114
 115         -- Explicitly quantified but not mentioned in ctxt or tau
 116         warn_guys = filter ((`notElem` mentioned) . unLoc) forall_tyvar_names
 117     in
 118     mappM_ (forAllWarn doc tau) warn_guys       `thenM_`
 119     rnForAll doc Explicit forall_tyvars ctxt tau
 120
 121 rnHsType doc (HsTyVar tyvar)
 122   = lookupOccRn tyvar           `thenM` \ tyvar' ->
 123     returnM (HsTyVar tyvar')
 124
 125 rnHsType doc ty@(HsOpTy ty1 (L loc op) ty2)
 126   = setSrcSpan loc $
 127     do  { ty_ops_ok <- doptM Opt_ScopedTypeVariables    -- Badly named option
 128         ; checkErr ty_ops_ok (opTyErr op ty)
 129         ; op' <- lookupOccRn op
 130         ; let l_op' = L loc op'
 131         ; fix <- lookupTyFixityRn l_op'
 132         ; ty1' <- rnLHsType doc ty1
 133         ; ty2' <- rnLHsType doc ty2
 134         ; mkHsOpTyRn (\t1 t2 -> HsOpTy t1 l_op' t2) (ppr op') fix ty1' ty2' }
 135
 136 rnHsType doc (HsParTy ty)
 137   = rnLHsType doc ty            `thenM` \ ty' ->
 138     returnM (HsParTy ty')
 139
 140 rnHsType doc (HsBangTy b ty)
 141   = rnLHsType doc ty            `thenM` \ ty' ->
 142     returnM (HsBangTy b ty')
 143
 144 rnHsType doc (HsNumTy i)
 145   | i == 1    = returnM (HsNumTy i)
 146   | otherwise = addErr err_msg  `thenM_`  returnM (HsNumTy i)
 147   where
 148     err_msg = ptext SLIT("Only unit numeric type pattern is valid")
 149
 150
 151 rnHsType doc (HsFunTy ty1 ty2)
 152   = rnLHsType doc ty1   `thenM` \ ty1' ->
 153         -- Might find a for-all as the arg of a function type
 154     rnLHsType doc ty2   `thenM` \ ty2' ->
 155         -- Or as the result.  This happens when reading Prelude.hi
 156         -- when we find return :: forall m. Monad m -> forall a. a -> m a
 157
 158         -- Check for fixity rearrangements
 159     mkHsOpTyRn HsFunTy (ppr funTyCon) funTyFixity ty1' ty2'
 160
 161 rnHsType doc (HsListTy ty)
 162   = rnLHsType doc ty                            `thenM` \ ty' ->
 163     returnM (HsListTy ty')
 164
 165 rnHsType doc (HsKindSig ty k)
 166   = rnLHsType doc ty                            `thenM` \ ty' ->
 167     returnM (HsKindSig ty' k)
 168
 169 rnHsType doc (HsPArrTy ty)
 170   = rnLHsType doc ty                            `thenM` \ ty' ->
 171     returnM (HsPArrTy ty')
 172
 173 -- Unboxed tuples are allowed to have poly-typed arguments.  These
 174 -- sometimes crop up as a result of CPR worker-wrappering dictionaries.
 175 rnHsType doc (HsTupleTy tup_con tys)
 176   = mappM (rnLHsType doc) tys           `thenM` \ tys' ->
 177     returnM (HsTupleTy tup_con tys')
 178
 179 rnHsType doc (HsAppTy ty1 ty2)
 180   = rnLHsType doc ty1           `thenM` \ ty1' ->
 181     rnLHsType doc ty2           `thenM` \ ty2' ->
 182     returnM (HsAppTy ty1' ty2')
 183
 184 rnHsType doc (HsPredTy pred)
 185   = rnPred doc pred     `thenM` \ pred' ->
 186     returnM (HsPredTy pred')
 187
 188 rnHsType doc (HsSpliceTy _)
 189   = do  { addErr (ptext SLIT("Type splices are not yet implemented"))
 190         ; failM }
 191
 192 rnHsType doc (HsDocTy ty haddock_doc)
 193   = rnLHsType doc ty            `thenM` \ ty' ->
 194     rnLHsDoc haddock_doc        `thenM` \ haddock_doc' ->
 195     returnM (HsDocTy ty' haddock_doc')
 196
 197 rnLHsTypes doc tys = mappM (rnLHsType doc) tys
 198 \end{code}
 199
 200
 201 \begin{code}
 202 rnForAll :: SDoc -> HsExplicitForAll -> [LHsTyVarBndr RdrName]
 203          -> LHsContext RdrName -> LHsType RdrName -> RnM (HsType Name)
 204
 205 rnForAll doc exp [] (L _ []) (L _ ty) = rnHsType doc ty
 206         -- One reason for this case is that a type like Int#
 207         -- starts off as (HsForAllTy Nothing [] Int), in case
 208         -- there is some quantification.  Now that we have quantified
 209         -- and discovered there are no type variables, it's nicer to turn
 210         -- it into plain Int.  If it were Int# instead of Int, we'd actually
 211         -- get an error, because the body of a genuine for-all is
 212         -- of kind *.
 213
 214 rnForAll doc exp forall_tyvars ctxt ty
 215   = bindTyVarsRn doc forall_tyvars      $ \ new_tyvars ->
 216     rnContext doc ctxt                  `thenM` \ new_ctxt ->
 217     rnLHsType doc ty                    `thenM` \ new_ty ->
 218     returnM (HsForAllTy exp new_tyvars new_ctxt new_ty)
 219         -- Retain the same implicit/explicit flag as before
 220         -- so that we can later print it correctly
 221 \end{code}
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226         Fixities and precedence parsing
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 @mkOpAppRn@ deals with operator fixities.  The argument expressions
 231 are assumed to be already correctly arranged.  It needs the fixities
 232 recorded in the OpApp nodes, because fixity info applies to the things
 233 the programmer actually wrote, so you can't find it out from the Name.
 234
 235 Furthermore, the second argument is guaranteed not to be another
 236 operator application.  Why? Because the parser parses all
 237 operator appications left-associatively, EXCEPT negation, which
 238 we need to handle specially.
 239 Infix types are read in a *right-associative* way, so that
 240         a `op` b `op` c
 241 is always read in as
 242         a `op` (b `op` c)
 243
 244 mkHsOpTyRn rearranges where necessary.  The two arguments
 245 have already been renamed and rearranged.  It's made rather tiresome
 246 by the presence of ->, which is a separate syntactic construct.
 247
 248 \begin{code}
 249 ---------------
 250 -- Building (ty1 `op1` (ty21 `op2` ty22))
 251 mkHsOpTyRn :: (LHsType Name -> LHsType Name -> HsType Name)
 252            -> SDoc -> Fixity -> LHsType Name -> LHsType Name
 253            -> RnM (HsType Name)
 254
 255 mkHsOpTyRn mk1 pp_op1 fix1 ty1 (L loc2 (HsOpTy ty21 op2 ty22))
 256   = do  { fix2 <- lookupTyFixityRn op2
 257         ; mk_hs_op_ty mk1 pp_op1 fix1 ty1
 258                       (\t1 t2 -> HsOpTy t1 op2 t2)
 259                       (ppr op2) fix2 ty21 ty22 loc2 }
 260
 261 mkHsOpTyRn mk1 pp_op1 fix1 ty1 ty2@(L loc2 (HsFunTy ty21 ty22))
 262   = mk_hs_op_ty mk1 pp_op1 fix1 ty1
 263                 HsFunTy (ppr funTyCon) funTyFixity ty21 ty22 loc2
 264
 265 mkHsOpTyRn mk1 pp_op1 fix1 ty1 ty2              -- Default case, no rearrangment
 266   = return (mk1 ty1 ty2)
 267
 268 ---------------
 269 mk_hs_op_ty :: (LHsType Name -> LHsType Name -> HsType Name)
 270             -> SDoc -> Fixity -> LHsType Name
 271             -> (LHsType Name -> LHsType Name -> HsType Name)
 272             -> SDoc -> Fixity -> LHsType Name -> LHsType Name -> SrcSpan
 273             -> RnM (HsType Name)
 274 mk_hs_op_ty mk1 pp_op1 fix1 ty1
 275             mk2 pp_op2 fix2 ty21 ty22 loc2
 276   | nofix_error     = do { addErr (precParseErr (quotes pp_op1,fix1)
 277                                                 (quotes pp_op2,fix2))
 278                          ; return (mk1 ty1 (L loc2 (mk2 ty21 ty22))) }
 279   | associate_right = return (mk1 ty1 (L loc2 (mk2 ty21 ty22)))
 280   | otherwise       = do { -- Rearrange to ((ty1 `op1` ty21) `op2` ty22)
 281                            new_ty <- mkHsOpTyRn mk1 pp_op1 fix1 ty1 ty21
 282                          ; return (mk2 (noLoc new_ty) ty22) }
 283   where
 284     (nofix_error, associate_right) = compareFixity fix1 fix2
 285
 286
 287 ---------------------------
 288 mkOpAppRn :: LHsExpr Name                       -- Left operand; already rearranged
 289           -> LHsExpr Name -> Fixity             -- Operator and fixity
 290           -> LHsExpr Name                       -- Right operand (not an OpApp, but might
 291                                                 -- be a NegApp)
 292           -> RnM (HsExpr Name)
 293
 294 -- (e11 `op1` e12) `op2` e2
 295 mkOpAppRn e1@(L _ (OpApp e11 op1 fix1 e12)) op2 fix2 e2
 296   | nofix_error
 297   = addErr (precParseErr (ppr_op op1,fix1) (ppr_op op2,fix2))   `thenM_`
 298     returnM (OpApp e1 op2 fix2 e2)
 299
 300   | associate_right
 301   = mkOpAppRn e12 op2 fix2 e2           `thenM` \ new_e ->
 302     returnM (OpApp e11 op1 fix1 (L loc' new_e))
 303   where
 304     loc'= combineLocs e12 e2
 305     (nofix_error, associate_right) = compareFixity fix1 fix2
 306
 307 ---------------------------
 308 --      (- neg_arg) `op` e2
 309 mkOpAppRn e1@(L _ (NegApp neg_arg neg_name)) op2 fix2 e2
 310   | nofix_error
 311   = addErr (precParseErr (pp_prefix_minus,negateFixity) (ppr_op op2,fix2))      `thenM_`
 312     returnM (OpApp e1 op2 fix2 e2)
 313
 314   | associate_right
 315   = mkOpAppRn neg_arg op2 fix2 e2       `thenM` \ new_e ->
 316     returnM (NegApp (L loc' new_e) neg_name)
 317   where
 318     loc' = combineLocs neg_arg e2
 319     (nofix_error, associate_right) = compareFixity negateFixity fix2
 320
 321 ---------------------------
 322 --      e1 `op` - neg_arg
 323 mkOpAppRn e1 op1 fix1 e2@(L _ (NegApp neg_arg _))       -- NegApp can occur on the right
 324   | not associate_right                         -- We *want* right association
 325   = addErr (precParseErr (ppr_op op1, fix1) (pp_prefix_minus, negateFixity))    `thenM_`
 326     returnM (OpApp e1 op1 fix1 e2)
 327   where
 328     (_, associate_right) = compareFixity fix1 negateFixity
 329
 330 ---------------------------
 331 --      Default case
 332 mkOpAppRn e1 op fix e2                  -- Default case, no rearrangment
 333   = ASSERT2( right_op_ok fix (unLoc e2),
 334              ppr e1 $$ text "---" $$ ppr op $$ text "---" $$ ppr fix $$ text "---" $$ ppr e2
 335     )
 336     returnM (OpApp e1 op fix e2)
 337
 338 -- Parser left-associates everything, but
 339 -- derived instances may have correctly-associated things to
 340 -- in the right operarand.  So we just check that the right operand is OK
 341 right_op_ok fix1 (OpApp _ _ fix2 _)
 342   = not error_please && associate_right
 343   where
 344     (error_please, associate_right) = compareFixity fix1 fix2
 345 right_op_ok fix1 other
 346   = True
 347
 348 -- Parser initially makes negation bind more tightly than any other operator
 349 -- And "deriving" code should respect this (use HsPar if not)
 350 mkNegAppRn :: LHsExpr id -> SyntaxExpr id -> RnM (HsExpr id)
 351 mkNegAppRn neg_arg neg_name
 352   = ASSERT( not_op_app (unLoc neg_arg) )
 353     returnM (NegApp neg_arg neg_name)
 354
 355 not_op_app (OpApp _ _ _ _) = False
 356 not_op_app other           = True
 357
 358 ---------------------------
 359 mkOpFormRn :: LHsCmdTop Name            -- Left operand; already rearranged
 360           -> LHsExpr Name -> Fixity     -- Operator and fixity
 361           -> LHsCmdTop Name             -- Right operand (not an infix)
 362           -> RnM (HsCmd Name)
 363
 364 -- (e11 `op1` e12) `op2` e2
 365 mkOpFormRn a1@(L loc (HsCmdTop (L _ (HsArrForm op1 (Just fix1) [a11,a12])) _ _ _))
 366         op2 fix2 a2
 367   | nofix_error
 368   = addErr (precParseErr (ppr_op op1,fix1) (ppr_op op2,fix2))   `thenM_`
 369     returnM (HsArrForm op2 (Just fix2) [a1, a2])
 370
 371   | associate_right
 372   = mkOpFormRn a12 op2 fix2 a2          `thenM` \ new_c ->
 373     returnM (HsArrForm op1 (Just fix1)
 374         [a11, L loc (HsCmdTop (L loc new_c) [] placeHolderType [])])
 375         -- TODO: locs are wrong
 376   where
 377     (nofix_error, associate_right) = compareFixity fix1 fix2
 378
 379 --      Default case
 380 mkOpFormRn arg1 op fix arg2                     -- Default case, no rearrangment
 381   = returnM (HsArrForm op (Just fix) [arg1, arg2])
 382
 383
 384 --------------------------------------
 385 mkConOpPatRn :: Located Name -> Fixity -> LPat Name -> LPat Name
 386              -> RnM (Pat Name)
 387
 388 mkConOpPatRn op2 fix2 p1@(L loc (ConPatIn op1 (InfixCon p11 p12))) p2
 389   = lookupFixityRn (unLoc op1)  `thenM` \ fix1 ->
 390     let
 391         (nofix_error, associate_right) = compareFixity fix1 fix2
 392     in
 393     if nofix_error then
 394         addErr (precParseErr (ppr_op op1,fix1) (ppr_op op2,fix2))       `thenM_`
 395         returnM (ConPatIn op2 (InfixCon p1 p2))
 396     else
 397     if associate_right then
 398         mkConOpPatRn op2 fix2 p12 p2            `thenM` \ new_p ->
 399         returnM (ConPatIn op1 (InfixCon p11 (L loc new_p)))  -- XXX loc right?
 400     else
 401     returnM (ConPatIn op2 (InfixCon p1 p2))
 402
 403 mkConOpPatRn op fix p1 p2                       -- Default case, no rearrangment
 404   = ASSERT( not_op_pat (unLoc p2) )
 405     returnM (ConPatIn op (InfixCon p1 p2))
 406
 407 not_op_pat (ConPatIn _ (InfixCon _ _)) = False
 408 not_op_pat other                       = True
 409
 410 --------------------------------------
 411 checkPrecMatch :: Bool -> Name -> MatchGroup Name -> RnM ()
 412         -- True indicates an infix lhs
 413         -- See comments with rnExpr (OpApp ...) about "deriving"
 414
 415 checkPrecMatch False fn match
 416   = returnM ()
 417 checkPrecMatch True op (MatchGroup ms _)
 418   = mapM_ check ms
 419   where
 420     check (L _ (Match (p1:p2:_) _ _))
 421       = checkPrec op (unLoc p1) False   `thenM_`
 422         checkPrec op (unLoc p2) True
 423
 424     check _ = return ()
 425         -- This can happen.  Consider
 426         --      a `op` True = ...
 427         --      op          = ...
 428         -- The infix flag comes from the first binding of the group
 429         -- but the second eqn has no args (an error, but not discovered
 430         -- until the type checker).  So we don't want to crash on the
 431         -- second eqn.
 432
 433 checkPrec op (ConPatIn op1 (InfixCon _ _)) right
 434   = lookupFixityRn op           `thenM` \  op_fix@(Fixity op_prec  op_dir) ->
 435     lookupFixityRn (unLoc op1)  `thenM` \ op1_fix@(Fixity op1_prec op1_dir) ->
 436     let
 437         inf_ok = op1_prec > op_prec ||
 438                  (op1_prec == op_prec &&
 439                   (op1_dir == InfixR && op_dir == InfixR && right ||
 440                    op1_dir == InfixL && op_dir == InfixL && not right))
 441
 442         info  = (ppr_op op,  op_fix)
 443         info1 = (ppr_op op1, op1_fix)
 444         (infol, infor) = if right then (info, info1) else (info1, info)
 445     in
 446     checkErr inf_ok (precParseErr infol infor)
 447
 448 checkPrec op pat right
 449   = returnM ()
 450
 451 -- Check precedence of (arg op) or (op arg) respectively
 452 -- If arg is itself an operator application, then either
 453 --   (a) its precedence must be higher than that of op
 454 --   (b) its precedency & associativity must be the same as that of op
 455 checkSectionPrec :: FixityDirection -> HsExpr RdrName
 456         -> LHsExpr Name -> LHsExpr Name -> RnM ()
 457 checkSectionPrec direction section op arg
 458   = case unLoc arg of
 459         OpApp _ op fix _ -> go_for_it (ppr_op op)     fix
 460         NegApp _ _       -> go_for_it pp_prefix_minus negateFixity
 461         other            -> returnM ()
 462   where
 463     L _ (HsVar op_name) = op
 464     go_for_it pp_arg_op arg_fix@(Fixity arg_prec assoc)
 465         = lookupFixityRn op_name        `thenM` \ op_fix@(Fixity op_prec _) ->
 466           checkErr (op_prec < arg_prec
 467                      || op_prec == arg_prec && direction == assoc)
 468                   (sectionPrecErr (ppr_op op_name, op_fix)
 469                   (pp_arg_op, arg_fix) section)
 470 \end{code}
 471
 472 Precedence-related error messages
 473
 474 \begin{code}
 475 precParseErr op1 op2
 476   = hang (ptext SLIT("precedence parsing error"))
 477       4 (hsep [ptext SLIT("cannot mix"), ppr_opfix op1, ptext SLIT("and"),
 478                ppr_opfix op2,
 479                ptext SLIT("in the same infix expression")])
 480
 481 sectionPrecErr op arg_op section
 482  = vcat [ptext SLIT("The operator") <+> ppr_opfix op <+> ptext SLIT("of a section"),
 483          nest 4 (ptext SLIT("must have lower precedence than the operand") <+> ppr_opfix arg_op),
 484          nest 4 (ptext SLIT("in the section:") <+> quotes (ppr section))]
 485
 486 pp_prefix_minus = ptext SLIT("prefix `-'")
 487 ppr_op op = quotes (ppr op)     -- Here, op can be a Name or a (Var n), where n is a Name
 488 ppr_opfix (pp_op, fixity) = pp_op <+> brackets (ppr fixity)
 489 \end{code}
 490
 491 %*********************************************************
 492 %*                                                      *
 493 \subsection{Contexts and predicates}
 494 %*                                                      *
 495 %*********************************************************
 496
 497 \begin{code}
 498 rnContext :: SDoc -> LHsContext RdrName -> RnM (LHsContext Name)
 499 rnContext doc = wrapLocM (rnContext' doc)
 500
 501 rnContext' :: SDoc -> HsContext RdrName -> RnM (HsContext Name)
 502 rnContext' doc ctxt = mappM (rnLPred doc) ctxt
 503
 504 rnLPred :: SDoc -> LHsPred RdrName -> RnM (LHsPred Name)
 505 rnLPred doc  = wrapLocM (rnPred doc)
 506
 507 rnPred doc (HsClassP clas tys)
 508   = lookupOccRn clas            `thenM` \ clas_name ->
 509     rnLHsTypes doc tys          `thenM` \ tys' ->
 510     returnM (HsClassP clas_name tys')
 511
 512 rnPred doc (HsIParam n ty)
 513   = newIPNameRn n               `thenM` \ name ->
 514     rnLHsType doc ty            `thenM` \ ty' ->
 515     returnM (HsIParam name ty')
 516 \end{code}
 517
 518
 519 *********************************************************
 520 *                                                       *
 521 \subsection{Patterns}
 522 *                                                       *
 523 *********************************************************
 524
 525 \begin{code}
 526 rnPatsAndThen :: HsMatchContext Name
 527               -> [LPat RdrName]
 528               -> ([LPat Name] -> RnM (a, FreeVars))
 529               -> RnM (a, FreeVars)
 530 -- Bring into scope all the binders and type variables
 531 -- bound by the patterns; then rename the patterns; then
 532 -- do the thing inside.
 533 --
 534 -- Note that we do a single bindLocalsRn for all the
 535 -- matches together, so that we spot the repeated variable in
 536 --      f x x = 1
 537
 538 rnPatsAndThen ctxt pats thing_inside
 539   = bindPatSigTyVarsFV pat_sig_tys      $
 540     bindLocatedLocalsFV doc_pat bndrs   $ \ new_bndrs ->
 541     rnLPats pats                        `thenM` \ (pats', pat_fvs) ->
 542     thing_inside pats'                  `thenM` \ (res, res_fvs) ->
 543     let
 544         unused_binders = filter (not . (`elemNameSet` res_fvs)) new_bndrs
 545     in
 546     warnUnusedMatches unused_binders   `thenM_`
 547     returnM (res, res_fvs `plusFV` pat_fvs)
 548   where
 549     pat_sig_tys = collectSigTysFromPats pats
 550     bndrs       = collectLocatedPatsBinders pats
 551     doc_pat     = ptext SLIT("In") <+> pprMatchContext ctxt
 552
 553 rnLPats :: [LPat RdrName] -> RnM ([LPat Name], FreeVars)
 554 rnLPats ps = mapFvRn rnLPat ps
 555
 556 rnLPat :: LPat RdrName -> RnM (LPat Name, FreeVars)
 557 rnLPat = wrapLocFstM rnPat
 558
 559 -- -----------------------------------------------------------------------------
 560 -- rnPat
 561
 562 rnPat :: Pat RdrName -> RnM (Pat Name, FreeVars)
 563
 564 rnPat (WildPat _) = returnM (WildPat placeHolderType, emptyFVs)
 565
 566 rnPat (VarPat name)
 567   = lookupBndrRn  name                  `thenM` \ vname ->
 568     returnM (VarPat vname, emptyFVs)
 569
 570 rnPat (SigPatIn pat ty)
 571   = doptM Opt_GlasgowExts `thenM` \ glaExts ->
 572
 573     if glaExts
 574     then rnLPat pat             `thenM` \ (pat', fvs1) ->
 575          rnHsTypeFVs doc ty     `thenM` \ (ty',  fvs2) ->
 576          returnM (SigPatIn pat' ty', fvs1 `plusFV` fvs2)
 577
 578     else addErr (patSigErr ty)  `thenM_`
 579          rnPat (unLoc pat) -- XXX shouldn't throw away the loc
 580   where
 581     doc = text "In a pattern type-signature"
 582
 583 rnPat (LitPat lit)
 584   = rnLit lit   `thenM_`
 585     returnM (LitPat lit, emptyFVs)
 586
 587 rnPat (NPat lit mb_neg eq _)
 588   = rnOverLit lit                       `thenM` \ (lit', fvs1) ->
 589     (case mb_neg of
 590         Nothing -> returnM (Nothing, emptyFVs)
 591         Just _  -> lookupSyntaxName negateName  `thenM` \ (neg, fvs) ->
 592                    returnM (Just neg, fvs)
 593     )                                   `thenM` \ (mb_neg', fvs2) ->
 594     lookupSyntaxName eqName             `thenM` \ (eq', fvs3) ->
 595     returnM (NPat lit' mb_neg' eq' placeHolderType,
 596               fvs1 `plusFV` fvs2 `plusFV` fvs3 `addOneFV` eqClassName)
 597         -- Needed to find equality on pattern
 598
 599 rnPat (NPlusKPat name lit _ _)
 600   = rnOverLit lit                       `thenM` \ (lit', fvs1) ->
 601     lookupLocatedBndrRn name            `thenM` \ name' ->
 602     lookupSyntaxName minusName          `thenM` \ (minus, fvs2) ->
 603     lookupSyntaxName geName             `thenM` \ (ge, fvs3) ->
 604     returnM (NPlusKPat name' lit' ge minus,
 605              fvs1 `plusFV` fvs2 `plusFV` fvs3 `addOneFV` integralClassName)
 606         -- The Report says that n+k patterns must be in Integral
 607
 608 rnPat (LazyPat pat)
 609   = rnLPat pat          `thenM` \ (pat', fvs) ->
 610     returnM (LazyPat pat', fvs)
 611
 612 rnPat (BangPat pat)
 613   = rnLPat pat          `thenM` \ (pat', fvs) ->
 614     returnM (BangPat pat', fvs)
 615
 616 rnPat (AsPat name pat)
 617   = rnLPat pat                  `thenM` \ (pat', fvs) ->
 618     lookupLocatedBndrRn name    `thenM` \ vname ->
 619     returnM (AsPat vname pat', fvs)
 620
 621 rnPat (ConPatIn con stuff) = rnConPat con stuff
 622
 623
 624 rnPat (ParPat pat)
 625   = rnLPat pat          `thenM` \ (pat', fvs) ->
 626     returnM (ParPat pat', fvs)
 627
 628 rnPat (ListPat pats _)
 629   = rnLPats pats                        `thenM` \ (patslist, fvs) ->
 630     returnM (ListPat patslist placeHolderType, fvs `addOneFV` listTyCon_name)
 631
 632 rnPat (PArrPat pats _)
 633   = rnLPats pats                        `thenM` \ (patslist, fvs) ->
 634     returnM (PArrPat patslist placeHolderType,
 635               fvs `plusFV` implicit_fvs `addOneFV` parrTyCon_name)
 636   where
 637     implicit_fvs = mkFVs [lengthPName, indexPName]
 638
 639 rnPat (TuplePat pats boxed _)
 640   = checkTupSize tup_size       `thenM_`
 641     rnLPats pats                        `thenM` \ (patslist, fvs) ->
 642     returnM (TuplePat patslist boxed placeHolderType,
 643              fvs `addOneFV` tycon_name)
 644   where
 645     tup_size   = length pats
 646     tycon_name = tupleTyCon_name boxed tup_size
 647
 648 rnPat (TypePat name) =
 649     rnHsTypeFVs (text "In a type pattern") name `thenM` \ (name', fvs) ->
 650     returnM (TypePat name', fvs)
 651
 652 -- -----------------------------------------------------------------------------
 653 -- rnConPat
 654
 655 rnConPat con (PrefixCon pats)
 656   = lookupLocatedOccRn con      `thenM` \ con' ->
 657     rnLPats pats                `thenM` \ (pats', fvs) ->
 658     returnM (ConPatIn con' (PrefixCon pats'), fvs `addOneFV` unLoc con')
 659
 660 rnConPat con (RecCon rpats)
 661   = lookupLocatedOccRn con      `thenM` \ con' ->
 662     rnRpats rpats               `thenM` \ (rpats', fvs) ->
 663     returnM (ConPatIn con' (RecCon rpats'), fvs `addOneFV` unLoc con')
 664
 665 rnConPat con (InfixCon pat1 pat2)
 666   = lookupLocatedOccRn con                      `thenM` \ con' ->
 667     rnLPat pat1                                 `thenM` \ (pat1', fvs1) ->
 668     rnLPat pat2                                 `thenM` \ (pat2', fvs2) ->
 669     lookupFixityRn (unLoc con')                 `thenM` \ fixity ->
 670     mkConOpPatRn con' fixity pat1' pat2'        `thenM` \ pat' ->
 671     returnM (pat', fvs1 `plusFV` fvs2 `addOneFV` unLoc con')
 672
 673 -- -----------------------------------------------------------------------------
 674 -- rnRpats
 675
 676 -- Haddock comments for record fields are renamed to Nothing here
 677 rnRpats :: [HsRecField RdrName (LPat RdrName)]
 678         -> RnM ([HsRecField Name (LPat Name)], FreeVars)
 679 rnRpats rpats
 680   = mappM_ field_dup_err dup_fields     `thenM_`
 681     mapFvRn rn_rpat rpats               `thenM` \ (rpats', fvs) ->
 682     returnM (rpats', fvs)
 683   where
 684     (_, dup_fields) = removeDups compare [ unLoc f | HsRecField f _ _ <- rpats ]
 685
 686     field_dup_err dups = addErr (dupFieldErr "pattern" dups)
 687
 688     rn_rpat (HsRecField field pat _)
 689       = lookupLocatedGlobalOccRn field  `thenM` \ fieldname ->
 690         rnLPat pat                      `thenM` \ (pat', fvs) ->
 691         returnM ((mkRecField fieldname pat'), fvs `addOneFV` unLoc fieldname)
 692
 693 \end{code}
 694
 695
 696 %************************************************************************
 697 %*                                                                      *
 698 \subsubsection{Literals}
 699 %*                                                                      *
 700 %************************************************************************
 701
 702 When literals occur we have to make sure
 703 that the types and classes they involve
 704 are made available.
 705
 706 \begin{code}
 707 rnLit :: HsLit -> RnM ()
 708 rnLit (HsChar c) = checkErr (inCharRange c) (bogusCharError c)
 709 rnLit other      = returnM ()
 710
 711 rnOverLit (HsIntegral i _)
 712   = lookupSyntaxName fromIntegerName    `thenM` \ (from_integer_name, fvs) ->
 713     if inIntRange i then
 714         returnM (HsIntegral i from_integer_name, fvs)
 715     else let
 716         extra_fvs = mkFVs [plusIntegerName, timesIntegerName]
 717         -- Big integer literals are built, using + and *,
 718         -- out of small integers (DsUtils.mkIntegerLit)
 719         -- [NB: plusInteger, timesInteger aren't rebindable...
 720         --      they are used to construct the argument to fromInteger,
 721         --      which is the rebindable one.]
 722     in
 723     returnM (HsIntegral i from_integer_name, fvs `plusFV` extra_fvs)
 724
 725 rnOverLit (HsFractional i _)
 726   = lookupSyntaxName fromRationalName           `thenM` \ (from_rat_name, fvs) ->
 727     let
 728         extra_fvs = mkFVs [ratioDataConName, plusIntegerName, timesIntegerName]
 729         -- We have to make sure that the Ratio type is imported with
 730         -- its constructor, because literals of type Ratio t are
 731         -- built with that constructor.
 732         -- The Rational type is needed too, but that will come in
 733         -- as part of the type for fromRational.
 734         -- The plus/times integer operations may be needed to construct the numerator
 735         -- and denominator (see DsUtils.mkIntegerLit)
 736     in
 737     returnM (HsFractional i from_rat_name, fvs `plusFV` extra_fvs)
 738 \end{code}
 739
 740
 741
 742 %*********************************************************
 743 %*                                                      *
 744 \subsection{Errors}
 745 %*                                                      *
 746 %*********************************************************
 747
 748 \begin{code}
 749 checkTupSize :: Int -> RnM ()
 750 checkTupSize tup_size
 751   | tup_size <= mAX_TUPLE_SIZE
 752   = returnM ()
 753   | otherwise
 754   = addErr (sep [ptext SLIT("A") <+> int tup_size <> ptext SLIT("-tuple is too large for GHC"),
 755                  nest 2 (parens (ptext SLIT("max size is") <+> int mAX_TUPLE_SIZE)),
 756                  nest 2 (ptext SLIT("Workaround: use nested tuples or define a data type"))])
 757
 758 forAllWarn doc ty (L loc tyvar)
 759   = ifOptM Opt_WarnUnusedMatches        $
 760     addWarnAt loc (sep [ptext SLIT("The universally quantified type variable") <+> quotes (ppr tyvar),
 761                         nest 4 (ptext SLIT("does not appear in the type") <+> quotes (ppr ty))]
 762                    $$
 763                    doc)
 764
 765 opTyErr op ty
 766   = hang (ptext SLIT("Illegal operator") <+> quotes (ppr op) <+> ptext SLIT("in type") <+> quotes (ppr ty))
 767          2 (parens (ptext SLIT("Use -fscoped-type-variables to allow operators in types")))
 768
 769 bogusCharError c
 770   = ptext SLIT("character literal out of range: '\\") <> char c  <> char '\''
 771
 772 patSigErr ty
 773   =  (ptext SLIT("Illegal signature in pattern:") <+> ppr ty)
 774         $$ nest 4 (ptext SLIT("Use -fglasgow-exts to permit it"))
 775
 776 dupFieldErr str dup
 777   = hsep [ptext SLIT("duplicate field name"),
 778           quotes (ppr dup),
 779           ptext SLIT("in record"), text str]
 780 \end{code}