compiler/simplCore/FloatOut.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[FloatOut]{Float bindings outwards (towards the top level)}
   5
   6 ``Long-distance'' floating of bindings towards the top level.
   7
   8 \begin{code}
   9 {-# OPTIONS -w #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 module FloatOut ( floatOutwards ) where
  17
  18 #include "HsVersions.h"
  19
  20 import CoreSyn
  21 import CoreUtils
  22
  23 import DynFlags ( DynFlags, DynFlag(..), FloatOutSwitches(..) )
  24 import ErrUtils         ( dumpIfSet_dyn )
  25 import CostCentre       ( dupifyCC, CostCentre )
  26 import Id               ( Id, idType )
  27 import Type             ( isUnLiftedType )
  28 import CoreLint         ( showPass, endPass )
  29 import SetLevels        ( Level(..), LevelledExpr, LevelledBind,
  30                           setLevels, ltMajLvl, ltLvl, isTopLvl )
  31 import UniqSupply       ( UniqSupply )
  32 import List             ( partition )
  33 import Outputable
  34 import FastString
  35 \end{code}
  36
  37         -----------------
  38         Overall game plan
  39         -----------------
  40
  41 The Big Main Idea is:
  42
  43         To float out sub-expressions that can thereby get outside
  44         a non-one-shot value lambda, and hence may be shared.
  45
  46
  47 To achieve this we may need to do two thing:
  48
  49    a) Let-bind the sub-expression:
  50
  51         f (g x)  ==>  let lvl = f (g x) in lvl
  52
  53       Now we can float the binding for 'lvl'.
  54
  55    b) More than that, we may need to abstract wrt a type variable
  56
  57         \x -> ... /\a -> let v = ...a... in ....
  58
  59       Here the binding for v mentions 'a' but not 'x'.  So we
  60       abstract wrt 'a', to give this binding for 'v':
  61
  62             vp = /\a -> ...a...
  63             v  = vp a
  64
  65       Now the binding for vp can float out unimpeded.
  66       I can't remember why this case seemed important enough to
  67       deal with, but I certainly found cases where important floats
  68       didn't happen if we did not abstract wrt tyvars.
  69
  70 With this in mind we can also achieve another goal: lambda lifting.
  71 We can make an arbitrary (function) binding float to top level by
  72 abstracting wrt *all* local variables, not just type variables, leaving
  73 a binding that can be floated right to top level.  Whether or not this
  74 happens is controlled by a flag.
  75
  76
  77 Random comments
  78 ~~~~~~~~~~~~~~~
  79
  80 At the moment we never float a binding out to between two adjacent
  81 lambdas.  For example:
  82
  83 @
  84         \x y -> let t = x+x in ...
  85 ===>
  86         \x -> let t = x+x in \y -> ...
  87 @
  88 Reason: this is less efficient in the case where the original lambda
  89 is never partially applied.
  90
  91 But there's a case I've seen where this might not be true.  Consider:
  92 @
  93 elEm2 x ys
  94   = elem' x ys
  95   where
  96     elem' _ []  = False
  97     elem' x (y:ys)      = x==y || elem' x ys
  98 @
  99 It turns out that this generates a subexpression of the form
 100 @
 101         \deq x ys -> let eq = eqFromEqDict deq in ...
 102 @
 103 vwhich might usefully be separated to
 104 @
 105         \deq -> let eq = eqFromEqDict deq in \xy -> ...
 106 @
 107 Well, maybe.  We don't do this at the moment.
 108
 109 \begin{code}
 110 type FloatBind     = (Level, CoreBind)  -- INVARIANT: a FloatBind is always lifted
 111 type FloatBinds    = [FloatBind]
 112 \end{code}
 113
 114 %************************************************************************
 115 %*                                                                      *
 116 \subsection[floatOutwards]{@floatOutwards@: let-floating interface function}
 117 %*                                                                      *
 118 %************************************************************************
 119
 120 \begin{code}
 121 floatOutwards :: FloatOutSwitches
 122               -> DynFlags
 123               -> UniqSupply
 124               -> [CoreBind] -> IO [CoreBind]
 125
 126 floatOutwards float_sws dflags us pgm
 127   = do {
 128         showPass dflags float_msg ;
 129
 130         let { annotated_w_levels = setLevels float_sws pgm us ;
 131               (fss, binds_s')    = unzip (map floatTopBind annotated_w_levels)
 132             } ;
 133
 134         dumpIfSet_dyn dflags Opt_D_verbose_core2core "Levels added:"
 135                   (vcat (map ppr annotated_w_levels));
 136
 137         let { (tlets, ntlets, lams) = get_stats (sum_stats fss) };
 138
 139         dumpIfSet_dyn dflags Opt_D_dump_simpl_stats "FloatOut stats:"
 140                 (hcat [ int tlets,  ptext SLIT(" Lets floated to top level; "),
 141                         int ntlets, ptext SLIT(" Lets floated elsewhere; from "),
 142                         int lams,   ptext SLIT(" Lambda groups")]);
 143
 144         endPass dflags float_msg  Opt_D_verbose_core2core (concat binds_s')
 145                         {- no specific flag for dumping float-out -}
 146     }
 147   where
 148     float_msg = showSDoc (text "Float out" <+> parens (sws float_sws))
 149     sws (FloatOutSw lam const) = pp_not lam   <+> text "lambdas" <> comma <+>
 150                                  pp_not const <+> text "constants"
 151     pp_not True  = empty
 152     pp_not False = text "not"
 153
 154 floatTopBind bind
 155   = case (floatBind bind) of { (fs, floats) ->
 156     (fs, floatsToBinds floats)
 157     }
 158 \end{code}
 159
 160 %************************************************************************
 161 %*                                                                      *
 162 \subsection[FloatOut-Bind]{Floating in a binding (the business end)}
 163 %*                                                                      *
 164 %************************************************************************
 165
 166
 167 \begin{code}
 168 floatBind :: LevelledBind -> (FloatStats, FloatBinds)
 169
 170 floatBind (NonRec (TB name level) rhs)
 171   = case (floatRhs level rhs) of { (fs, rhs_floats, rhs') ->
 172     (fs, rhs_floats ++ [(level, NonRec name rhs')]) }
 173
 174 floatBind bind@(Rec pairs)
 175   = case (unzip3 (map do_pair pairs)) of { (fss, rhss_floats, new_pairs) ->
 176     let rhs_floats = concat rhss_floats in
 177
 178     if not (isTopLvl bind_dest_lvl) then
 179         -- Find which bindings float out at least one lambda beyond this one
 180         -- These ones can't mention the binders, because they couldn't
 181         -- be escaping a major level if so.
 182         -- The ones that are not going further can join the letrec;
 183         -- they may not be mutually recursive but the occurrence analyser will
 184         -- find that out.
 185         case (partitionByMajorLevel bind_dest_lvl rhs_floats) of { (floats', heres) ->
 186         (sum_stats fss, floats' ++ [(bind_dest_lvl, Rec (floatsToBindPairs heres ++ new_pairs))]) }
 187     else
 188         -- In a recursive binding, *destined for* the top level
 189         -- (only), the rhs floats may contain references to the
 190         -- bound things.  For example
 191         --      f = ...(let v = ...f... in b) ...
 192         --  might get floated to
 193         --      v = ...f...
 194         --      f = ... b ...
 195         -- and hence we must (pessimistically) make all the floats recursive
 196         -- with the top binding.  Later dependency analysis will unravel it.
 197         --
 198         -- This can only happen for bindings destined for the top level,
 199         -- because only then will partitionByMajorLevel allow through a binding
 200         -- that only differs in its minor level
 201         (sum_stats fss, [(bind_dest_lvl, Rec (new_pairs ++ floatsToBindPairs rhs_floats))])
 202     }
 203   where
 204     bind_dest_lvl = getBindLevel bind
 205
 206     do_pair (TB name level, rhs)
 207       = case (floatRhs level rhs) of { (fs, rhs_floats, rhs') ->
 208         (fs, rhs_floats, (name, rhs'))
 209         }
 210 \end{code}
 211
 212 %************************************************************************
 213
 214 \subsection[FloatOut-Expr]{Floating in expressions}
 215 %*                                                                      *
 216 %************************************************************************
 217
 218 \begin{code}
 219 floatExpr, floatRhs, floatCaseAlt
 220          :: Level
 221          -> LevelledExpr
 222          -> (FloatStats, FloatBinds, CoreExpr)
 223
 224 floatCaseAlt lvl arg    -- Used rec rhss, and case-alternative rhss
 225   = case (floatExpr lvl arg) of { (fsa, floats, arg') ->
 226     case (partitionByMajorLevel lvl floats) of { (floats', heres) ->
 227         -- Dump bindings that aren't going to escape from a lambda;
 228         -- in particular, we must dump the ones that are bound by
 229         -- the rec or case alternative
 230     (fsa, floats', install heres arg') }}
 231
 232 floatRhs lvl arg        -- Used for nested non-rec rhss, and fn args
 233                         -- See Note [Floating out of RHS]
 234   = case (floatExpr lvl arg) of { (fsa, floats, arg') ->
 235     if exprIsCheap arg' then
 236         (fsa, floats, arg')
 237     else
 238     case (partitionByMajorLevel lvl floats) of { (floats', heres) ->
 239     (fsa, floats', install heres arg') }}
 240
 241 -- Note [Floating out of RHSs]
 242 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 243 -- Dump bindings that aren't going to escape from a lambda
 244 -- This isn't a scoping issue (the binder isn't in scope in the RHS
 245 --      of a non-rec binding)
 246 -- Rather, it is to avoid floating the x binding out of
 247 --      f (let x = e in b)
 248 -- unnecessarily.  But we first test for values or trival rhss,
 249 -- because (in particular) we don't want to insert new bindings between
 250 -- the "=" and the "\".  E.g.
 251 --      f = \x -> let <bind> in <body>
 252 -- We do not want
 253 --      f = let <bind> in \x -> <body>
 254 -- (a) The simplifier will immediately float it further out, so we may
 255 --      as well do so right now; in general, keeping rhss as manifest
 256 --      values is good
 257 -- (b) If a float-in pass follows immediately, it might add yet more
 258 --      bindings just after the '='.  And some of them might (correctly)
 259 --      be strict even though the 'let f' is lazy, because f, being a value,
 260 --      gets its demand-info zapped by the simplifier.
 261 --
 262 -- We use exprIsCheap because that is also what's used by the simplifier
 263 -- to decide whether to float a let out of a let
 264
 265 floatExpr _ (Var v)   = (zeroStats, [], Var v)
 266 floatExpr _ (Type ty) = (zeroStats, [], Type ty)
 267 floatExpr _ (Lit lit) = (zeroStats, [], Lit lit)
 268
 269 floatExpr lvl (App e a)
 270   = case (floatExpr      lvl e) of { (fse, floats_e, e') ->
 271     case (floatRhs lvl a)       of { (fsa, floats_a, a') ->
 272     (fse `add_stats` fsa, floats_e ++ floats_a, App e' a') }}
 273
 274 floatExpr lvl lam@(Lam _ _)
 275   = let
 276         (bndrs_w_lvls, body) = collectBinders lam
 277         bndrs                = [b | TB b _ <- bndrs_w_lvls]
 278         lvls                 = [l | TB b l <- bndrs_w_lvls]
 279
 280         -- For the all-tyvar case we are prepared to pull
 281         -- the lets out, to implement the float-out-of-big-lambda
 282         -- transform; but otherwise we only float bindings that are
 283         -- going to escape a value lambda.
 284         -- In particular, for one-shot lambdas we don't float things
 285         -- out; we get no saving by so doing.
 286         partition_fn | all isTyVar bndrs = partitionByLevel
 287                      | otherwise         = partitionByMajorLevel
 288     in
 289     case (floatExpr (last lvls) body) of { (fs, floats, body') ->
 290
 291         -- Dump any bindings which absolutely cannot go any further
 292     case (partition_fn (head lvls) floats)      of { (floats', heres) ->
 293
 294     (add_to_stats fs floats', floats', mkLams bndrs (install heres body'))
 295     }}
 296
 297 floatExpr lvl (Note note@(SCC cc) expr)
 298   = case (floatExpr lvl expr)    of { (fs, floating_defns, expr') ->
 299     let
 300         -- Annotate bindings floated outwards past an scc expression
 301         -- with the cc.  We mark that cc as "duplicated", though.
 302
 303         annotated_defns = annotate (dupifyCC cc) floating_defns
 304     in
 305     (fs, annotated_defns, Note note expr') }
 306   where
 307     annotate :: CostCentre -> FloatBinds -> FloatBinds
 308
 309     annotate dupd_cc defn_groups
 310       = [ (level, ann_bind floater) | (level, floater) <- defn_groups ]
 311       where
 312         ann_bind (NonRec binder rhs)
 313           = NonRec binder (mkSCC dupd_cc rhs)
 314
 315         ann_bind (Rec pairs)
 316           = Rec [(binder, mkSCC dupd_cc rhs) | (binder, rhs) <- pairs]
 317
 318 floatExpr lvl (Note InlineMe expr)      -- Other than SCCs
 319   = case floatExpr InlineCtxt expr of { (fs, floating_defns, expr') ->
 320         -- There can be some floating_defns, arising from
 321         -- ordinary lets that were there all the time.  It seems
 322         -- more efficient to test once here than to avoid putting
 323         -- them into floating_defns (which would mean testing for
 324         -- inlineCtxt  at every let)
 325     (fs, [], Note InlineMe (install floating_defns expr')) }
 326         -- See Note [FloatOut inside INLINE] in SetLevels
 327         -- I'm guessing that floating_dens should be empty
 328
 329 floatExpr lvl (Note note expr)  -- Other than SCCs
 330   = case (floatExpr lvl expr)    of { (fs, floating_defns, expr') ->
 331     (fs, floating_defns, Note note expr') }
 332
 333 floatExpr lvl (Cast expr co)
 334   = case (floatExpr lvl expr)   of { (fs, floating_defns, expr') ->
 335     (fs, floating_defns, Cast expr' co) }
 336
 337 floatExpr lvl (Let (NonRec (TB bndr bndr_lvl) rhs) body)
 338   | isUnLiftedType (idType bndr)        -- Treat unlifted lets just like a case
 339                                 -- I.e. floatExpr for rhs, floatCaseAlt for body
 340   = case floatExpr lvl rhs          of { (fs, rhs_floats, rhs') ->
 341     case floatCaseAlt bndr_lvl body of { (fs, body_floats, body') ->
 342     (fs, rhs_floats ++ body_floats, Let (NonRec bndr rhs') body') }}
 343
 344 floatExpr lvl (Let bind body)
 345   = case (floatBind bind)     of { (fsb, bind_floats) ->
 346     case (floatExpr lvl body) of { (fse, body_floats, body') ->
 347     (add_stats fsb fse,
 348      bind_floats ++ body_floats,
 349      body')  }}
 350
 351 floatExpr lvl (Case scrut (TB case_bndr case_lvl) ty alts)
 352   = case floatExpr lvl scrut    of { (fse, fde, scrut') ->
 353     case floatList float_alt alts       of { (fsa, fda, alts')  ->
 354     (add_stats fse fsa, fda ++ fde, Case scrut' case_bndr ty alts')
 355     }}
 356   where
 357         -- Use floatCaseAlt for the alternatives, so that we
 358         -- don't gratuitiously float bindings out of the RHSs
 359     float_alt (con, bs, rhs)
 360         = case (floatCaseAlt case_lvl rhs)      of { (fs, rhs_floats, rhs') ->
 361           (fs, rhs_floats, (con, [b | TB b _ <- bs], rhs')) }
 362
 363
 364 floatList :: (a -> (FloatStats, FloatBinds, b)) -> [a] -> (FloatStats, FloatBinds, [b])
 365 floatList f [] = (zeroStats, [], [])
 366 floatList f (a:as) = case f a            of { (fs_a,  binds_a,  b)  ->
 367                      case floatList f as of { (fs_as, binds_as, bs) ->
 368                      (fs_a `add_stats` fs_as, binds_a ++ binds_as, b:bs) }}
 369 \end{code}
 370
 371 %************************************************************************
 372 %*                                                                      *
 373 \subsection{Utility bits for floating stats}
 374 %*                                                                      *
 375 %************************************************************************
 376
 377 I didn't implement this with unboxed numbers.  I don't want to be too
 378 strict in this stuff, as it is rarely turned on.  (WDP 95/09)
 379
 380 \begin{code}
 381 data FloatStats
 382   = FlS Int  -- Number of top-floats * lambda groups they've been past
 383         Int  -- Number of non-top-floats * lambda groups they've been past
 384         Int  -- Number of lambda (groups) seen
 385
 386 get_stats (FlS a b c) = (a, b, c)
 387
 388 zeroStats = FlS 0 0 0
 389
 390 sum_stats xs = foldr add_stats zeroStats xs
 391
 392 add_stats (FlS a1 b1 c1) (FlS a2 b2 c2)
 393   = FlS (a1 + a2) (b1 + b2) (c1 + c2)
 394
 395 add_to_stats (FlS a b c) floats
 396   = FlS (a + length top_floats) (b + length other_floats) (c + 1)
 397   where
 398     (top_floats, other_floats) = partition to_very_top floats
 399
 400     to_very_top (my_lvl, _) = isTopLvl my_lvl
 401 \end{code}
 402
 403
 404 %************************************************************************
 405 %*                                                                      *
 406 \subsection{Utility bits for floating}
 407 %*                                                                      *
 408 %************************************************************************
 409
 410 \begin{code}
 411 getBindLevel (NonRec (TB _ lvl) _)      = lvl
 412 getBindLevel (Rec (((TB _ lvl), _) : _)) = lvl
 413 \end{code}
 414
 415 \begin{code}
 416 partitionByMajorLevel, partitionByLevel
 417         :: Level                -- Partitioning level
 418
 419         -> FloatBinds           -- Defns to be divided into 2 piles...
 420
 421         -> (FloatBinds, -- Defns  with level strictly < partition level,
 422             FloatBinds) -- The rest
 423
 424
 425 partitionByMajorLevel ctxt_lvl defns
 426   = partition float_further defns
 427   where
 428         -- Float it if we escape a value lambda, or if we get to the top level
 429     float_further (my_lvl, bind) = my_lvl `ltMajLvl` ctxt_lvl || isTopLvl my_lvl
 430         -- The isTopLvl part says that if we can get to the top level, say "yes" anyway
 431         -- This means that
 432         --      x = f e
 433         -- transforms to
 434         --    lvl = e
 435         --    x = f lvl
 436         -- which is as it should be
 437
 438 partitionByLevel ctxt_lvl defns
 439   = partition float_further defns
 440   where
 441     float_further (my_lvl, _) = my_lvl `ltLvl` ctxt_lvl
 442 \end{code}
 443
 444 \begin{code}
 445 floatsToBinds :: FloatBinds -> [CoreBind]
 446 floatsToBinds floats = map snd floats
 447
 448 floatsToBindPairs :: FloatBinds -> [(Id,CoreExpr)]
 449
 450 floatsToBindPairs floats = concat (map mk_pairs floats)
 451   where
 452    mk_pairs (_, Rec pairs)         = pairs
 453    mk_pairs (_, NonRec binder rhs) = [(binder,rhs)]
 454
 455 install :: FloatBinds -> CoreExpr -> CoreExpr
 456
 457 install defn_groups expr
 458   = foldr install_group expr defn_groups
 459   where
 460     install_group (_, defns) body = Let defns body
 461 \end{code}