compiler/simplCore/SimplCore.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SimplCore]{Driver for simplifying @Core@ programs}
   5
   6 \begin{code}
   7 {-# OPTIONS -w #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  12 -- for details
  13
  14 module SimplCore ( core2core, simplifyExpr ) where
  15
  16 #include "HsVersions.h"
  17
  18 import DynFlags         ( DynFlags, DynFlag(..), dopt )
  19 import CoreSyn
  20 import CoreSubst
  21 import HscTypes
  22 import CSE              ( cseProgram )
  23 import Rules            ( RuleBase, emptyRuleBase, mkRuleBase, unionRuleBase,
  24                           extendRuleBaseList, pprRuleBase, pprRulesForUser,
  25                           ruleCheckProgram, rulesOfBinds,
  26                           addSpecInfo, addIdSpecialisations )
  27 import PprCore          ( pprCoreBindings, pprCoreExpr, pprRules )
  28 import OccurAnal        ( occurAnalysePgm, occurAnalyseExpr )
  29 import IdInfo
  30 import CoreUtils        ( coreBindsSize )
  31 import Simplify         ( simplTopBinds, simplExpr )
  32 import SimplUtils       ( simplEnvForGHCi, simplEnvForRules )
  33 import SimplEnv
  34 import SimplMonad
  35 import CoreMonad
  36 import qualified ErrUtils as Err
  37 import CoreLint
  38 import FloatIn          ( floatInwards )
  39 import FloatOut         ( floatOutwards )
  40 import FamInstEnv
  41 import Id
  42 import DataCon
  43 import TyCon            ( tyConDataCons )
  44 import Class            ( classSelIds )
  45 import BasicTypes       ( CompilerPhase, isActive, isDefaultInlinePragma )
  46 import VarSet
  47 import VarEnv
  48 import NameEnv          ( lookupNameEnv )
  49 import LiberateCase     ( liberateCase )
  50 import SAT              ( doStaticArgs )
  51 import Specialise       ( specProgram)
  52 import SpecConstr       ( specConstrProgram)
  53 import DmdAnal          ( dmdAnalPgm )
  54 import WorkWrap         ( wwTopBinds )
  55 import Vectorise        ( vectorise )
  56 import FastString
  57 import Util
  58
  59 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, splitUniqSupply )
  60 import Outputable
  61 import Control.Monad
  62 import Data.List
  63 import System.IO
  64 import Maybes
  65 \end{code}
  66
  67 %************************************************************************
  68 %*                                                                      *
  69 \subsection{The driver for the simplifier}
  70 %*                                                                      *
  71 %************************************************************************
  72
  73 \begin{code}
  74 core2core :: HscEnv
  75           -> ModGuts
  76           -> IO ModGuts
  77
  78 core2core hsc_env guts = do
  79     let dflags = hsc_dflags hsc_env
  80
  81     us <- mkSplitUniqSupply 's'
  82     let (cp_us, ru_us) = splitUniqSupply us
  83
  84     -- COMPUTE THE RULE BASE TO USE
  85     -- See Note [Overall plumbing for rules] in Rules.lhs
  86     (hpt_rule_base, guts1) <- prepareRules hsc_env guts ru_us
  87
  88     -- Get the module out of the current HscEnv so we can retrieve it from the monad.
  89     -- This is very convienent for the users of the monad (e.g. plugins do not have to
  90     -- consume the ModGuts to find the module) but somewhat ugly because mg_module may
  91     -- _theoretically_ be changed during the Core pipeline (it's part of ModGuts), which
  92     -- would mean our cached value would go out of date.
  93     let mod = mg_module guts
  94     (guts2, stats) <- runCoreM hsc_env hpt_rule_base cp_us mod $ do
  95         -- FIND BUILT-IN PASSES
  96         let builtin_core_todos = getCoreToDo dflags
  97
  98         -- DO THE BUSINESS
  99         doCorePasses builtin_core_todos guts1
 100
 101     Err.dumpIfSet_dyn dflags Opt_D_dump_simpl_stats
 102         "Grand total simplifier statistics"
 103         (pprSimplCount stats)
 104
 105     return guts2
 106
 107
 108 type CorePass = CoreToDo
 109
 110 simplifyExpr :: DynFlags -- includes spec of what core-to-core passes to do
 111              -> CoreExpr
 112              -> IO CoreExpr
 113 -- simplifyExpr is called by the driver to simplify an
 114 -- expression typed in at the interactive prompt
 115 --
 116 -- Also used by Template Haskell
 117 simplifyExpr dflags expr
 118   = do  {
 119         ; Err.showPass dflags "Simplify"
 120
 121         ; us <-  mkSplitUniqSupply 's'
 122
 123         ; let (expr', _counts) = initSmpl dflags emptyRuleBase emptyFamInstEnvs us $
 124                                  simplExprGently simplEnvForGHCi expr
 125
 126         ; Err.dumpIfSet_dyn dflags Opt_D_dump_simpl "Simplified expression"
 127                         (pprCoreExpr expr')
 128
 129         ; return expr'
 130         }
 131
 132 doCorePasses :: [CorePass] -> ModGuts -> CoreM ModGuts
 133 doCorePasses passes guts
 134   = foldM do_pass guts passes
 135   where
 136     do_pass guts CoreDoNothing = return guts
 137     do_pass guts (CoreDoPasses ps) = doCorePasses ps guts
 138     do_pass guts pass
 139        = do { dflags <- getDynFlags
 140             ; liftIO $ showPass dflags pass
 141             ; guts' <- doCorePass pass guts
 142             ; liftIO $ endPass dflags pass (mg_binds guts') (mg_rules guts')
 143             ; return guts' }
 144
 145 doCorePass :: CorePass -> ModGuts -> CoreM ModGuts
 146 doCorePass pass@(CoreDoSimplify {})  = {-# SCC "Simplify" #-}
 147                                        simplifyPgm pass
 148
 149 doCorePass CoreCSE                   = {-# SCC "CommonSubExpr" #-}
 150                                        doPass cseProgram
 151
 152 doCorePass CoreLiberateCase          = {-# SCC "LiberateCase" #-}
 153                                        doPassD liberateCase
 154
 155 doCorePass CoreDoFloatInwards        = {-# SCC "FloatInwards" #-}
 156                                        doPass floatInwards
 157
 158 doCorePass (CoreDoFloatOutwards f)   = {-# SCC "FloatOutwards" #-}
 159                                        doPassDUM (floatOutwards f)
 160
 161 doCorePass CoreDoStaticArgs          = {-# SCC "StaticArgs" #-}
 162                                        doPassU doStaticArgs
 163
 164 doCorePass CoreDoStrictness          = {-# SCC "Stranal" #-}
 165                                        doPassDM dmdAnalPgm
 166
 167 doCorePass CoreDoWorkerWrapper       = {-# SCC "WorkWrap" #-}
 168                                        doPassU wwTopBinds
 169
 170 doCorePass CoreDoSpecialising        = {-# SCC "Specialise" #-}
 171                                        doPassU specProgram
 172
 173 doCorePass CoreDoSpecConstr          = {-# SCC "SpecConstr" #-}
 174                                        specConstrProgram
 175
 176 doCorePass (CoreDoVectorisation be)  = {-# SCC "Vectorise" #-}
 177                                        vectorise be
 178
 179 doCorePass CoreDoGlomBinds              = doPassDM  glomBinds
 180 doCorePass CoreDoPrintCore              = observe   printCore
 181 doCorePass (CoreDoRuleCheck phase pat)  = ruleCheck phase pat
 182 doCorePass CoreDoNothing                = return
 183 doCorePass (CoreDoPasses passes)        = doCorePasses passes
 184 \end{code}
 185
 186 %************************************************************************
 187 %*                                                                      *
 188 \subsection{Core pass combinators}
 189 %*                                                                      *
 190 %************************************************************************
 191
 192 \begin{code}
 193 printCore _ binds = Err.dumpIfSet True "Print Core" (pprCoreBindings binds)
 194
 195 ruleCheck :: CompilerPhase -> String -> ModGuts -> CoreM ModGuts
 196 ruleCheck current_phase pat guts = do
 197     rb <- getRuleBase
 198     dflags <- getDynFlags
 199     liftIO $ Err.showPass dflags "RuleCheck"
 200     liftIO $ printDump (ruleCheckProgram current_phase pat rb (mg_binds guts))
 201     return guts
 202
 203
 204 doPassDMS :: (DynFlags -> [CoreBind] -> IO (SimplCount, [CoreBind])) -> ModGuts -> CoreM ModGuts
 205 doPassDMS do_pass = doPassM $ \binds -> do
 206     dflags <- getDynFlags
 207     liftIOWithCount $ do_pass dflags binds
 208
 209 doPassDUM :: (DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]) -> ModGuts -> CoreM ModGuts
 210 doPassDUM do_pass = doPassM $ \binds -> do
 211     dflags <- getDynFlags
 212     us     <- getUniqueSupplyM
 213     liftIO $ do_pass dflags us binds
 214
 215 doPassDM :: (DynFlags -> [CoreBind] -> IO [CoreBind]) -> ModGuts -> CoreM ModGuts
 216 doPassDM do_pass = doPassDUM (\dflags -> const (do_pass dflags))
 217
 218 doPassD :: (DynFlags -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 219 doPassD do_pass = doPassDM (\dflags -> return . do_pass dflags)
 220
 221 doPassDU :: (DynFlags -> UniqSupply -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 222 doPassDU do_pass = doPassDUM (\dflags us -> return . do_pass dflags us)
 223
 224 doPassU :: (UniqSupply -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 225 doPassU do_pass = doPassDU (const do_pass)
 226
 227 -- Most passes return no stats and don't change rules: these combinators
 228 -- let us lift them to the full blown ModGuts+CoreM world
 229 doPassM :: Monad m => ([CoreBind] -> m [CoreBind]) -> ModGuts -> m ModGuts
 230 doPassM bind_f guts = do
 231     binds' <- bind_f (mg_binds guts)
 232     return (guts { mg_binds = binds' })
 233
 234 doPassMG :: Monad m => (ModGuts -> m [CoreBind]) -> ModGuts -> m ModGuts
 235 doPassMG bind_f guts = do
 236     binds' <- bind_f guts
 237     return (guts { mg_binds = binds' })
 238
 239 doPass :: ([CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 240 doPass bind_f guts = return $ guts { mg_binds = bind_f (mg_binds guts) }
 241
 242 -- Observer passes just peek; don't modify the bindings at all
 243 observe :: (DynFlags -> [CoreBind] -> IO a) -> ModGuts -> CoreM ModGuts
 244 observe do_pass = doPassM $ \binds -> do
 245     dflags <- getDynFlags
 246     liftIO $ do_pass dflags binds
 247     return binds
 248 \end{code}
 249
 250
 251 %************************************************************************
 252 %*                                                                      *
 253         Dealing with rules
 254 %*                                                                      *
 255 %************************************************************************
 256
 257 -- prepareLocalRuleBase takes the CoreBinds and rules defined in this module.
 258 -- It attaches those rules that are for local Ids to their binders, and
 259 -- returns the remainder attached to Ids in an IdSet.
 260
 261 \begin{code}
 262 prepareRules :: HscEnv
 263              -> ModGuts
 264              -> UniqSupply
 265              -> IO (RuleBase,           -- Rule base for imported things, incl
 266                                         -- (a) rules defined in this module (orphans)
 267                                         -- (b) rules from other modules in home package
 268                                         -- but not things from other packages
 269
 270                     ModGuts)            -- Modified fields are
 271                                         --      (a) Bindings have rules attached,
 272                                         --              and INLINE rules simplified
 273                                         --      (b) Rules are now just orphan rules
 274
 275 prepareRules hsc_env@(HscEnv { hsc_dflags = dflags, hsc_HPT = hpt })
 276              guts@(ModGuts { mg_binds = binds, mg_deps = deps
 277                            , mg_rules = local_rules, mg_rdr_env = rdr_env })
 278              us
 279   = do  { us <- mkSplitUniqSupply 'w'
 280
 281         ; let   -- Simplify the local rules; boringly, we need to make an in-scope set
 282                 -- from the local binders, to avoid warnings from Simplify.simplVar
 283               local_ids        = mkInScopeSet (mkVarSet (bindersOfBinds binds))
 284               env              = setInScopeSet simplEnvForRules local_ids
 285               (simpl_rules, _) = initSmpl dflags emptyRuleBase emptyFamInstEnvs us $
 286                                  mapM (simplRule env) local_rules
 287
 288         ; let (rules_for_locals, rules_for_imps) = partition isLocalRule simpl_rules
 289
 290               home_pkg_rules = hptRules hsc_env (dep_mods deps)
 291               hpt_rule_base  = mkRuleBase home_pkg_rules
 292               binds_w_rules  = updateBinders rules_for_locals binds
 293
 294
 295         ; Err.dumpIfSet_dyn dflags Opt_D_dump_rules "Transformation rules"
 296                 (withPprStyle (mkUserStyle (mkPrintUnqualified dflags rdr_env) AllTheWay) $
 297                  vcat [text "Local rules for local Ids", pprRules simpl_rules,
 298                        blankLine,
 299                        text "Local rules for imported Ids", pprRuleBase hpt_rule_base])
 300
 301         ; return (hpt_rule_base, guts { mg_binds = binds_w_rules,
 302                                         mg_rules = rules_for_imps })
 303     }
 304
 305 -- Note [Attach rules to local ids]
 306 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 307 -- Find the rules for locally-defined Ids; then we can attach them
 308 -- to the binders in the top-level bindings
 309 --
 310 -- Reason
 311 --      - It makes the rules easier to look up
 312 --      - It means that transformation rules and specialisations for
 313 --        locally defined Ids are handled uniformly
 314 --      - It keeps alive things that are referred to only from a rule
 315 --        (the occurrence analyser knows about rules attached to Ids)
 316 --      - It makes sure that, when we apply a rule, the free vars
 317 --        of the RHS are more likely to be in scope
 318 --      - The imported rules are carried in the in-scope set
 319 --        which is extended on each iteration by the new wave of
 320 --        local binders; any rules which aren't on the binding will
 321 --        thereby get dropped
 322
 323 updateBinders :: [CoreRule] -> [CoreBind] -> [CoreBind]
 324 updateBinders rules_for_locals binds
 325   = map update_bind binds
 326   where
 327     local_rules = extendRuleBaseList emptyRuleBase rules_for_locals
 328
 329     update_bind (NonRec b r) = NonRec (add_rules b) r
 330     update_bind (Rec prs)    = Rec (mapFst add_rules prs)
 331
 332         -- See Note [Attach rules to local ids]
 333         -- NB: the binder might have some existing rules,
 334         -- arising from specialisation pragmas
 335     add_rules bndr
 336         | Just rules <- lookupNameEnv local_rules (idName bndr)
 337         = bndr `addIdSpecialisations` rules
 338         | otherwise
 339         = bndr
 340 \end{code}
 341
 342 Note [Simplifying the left-hand side of a RULE]
 343 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 344 We must do some gentle simplification on the lhs (template) of each
 345 rule.  The case that forced me to add this was the fold/build rule,
 346 which without simplification looked like:
 347         fold k z (build (/\a. g a))  ==>  ...
 348 This doesn't match unless you do eta reduction on the build argument.
 349 Similarly for a LHS like
 350         augment g (build h)
 351 we do not want to get
 352         augment (\a. g a) (build h)
 353 otherwise we don't match when given an argument like
 354         augment (\a. h a a) (build h)
 355
 356 The simplifier does indeed do eta reduction (it's in
 357 Simplify.completeLam) but only if -O is on.
 358
 359 \begin{code}
 360 simplRule :: SimplEnv -> CoreRule -> SimplM CoreRule
 361 simplRule env rule@(BuiltinRule {})
 362   = return rule
 363 simplRule env rule@(Rule { ru_bndrs = bndrs, ru_args = args, ru_rhs = rhs })
 364   = do (env, bndrs') <- simplBinders env bndrs
 365        args' <- mapM (simplExprGently env) args
 366        rhs' <- simplExprGently env rhs
 367        return (rule { ru_bndrs = bndrs', ru_args = args'
 368                     , ru_rhs = occurAnalyseExpr rhs' })
 369 \end{code}
 370
 371 \begin{code}
 372 simplExprGently :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 373 -- Simplifies an expression
 374 --      does occurrence analysis, then simplification
 375 --      and repeats (twice currently) because one pass
 376 --      alone leaves tons of crud.
 377 -- Used (a) for user expressions typed in at the interactive prompt
 378 --      (b) the LHS and RHS of a RULE
 379 --      (c) Template Haskell splices
 380 --
 381 -- The name 'Gently' suggests that the SimplifierMode is SimplGently,
 382 -- and in fact that is so.... but the 'Gently' in simplExprGently doesn't
 383 -- enforce that; it just simplifies the expression twice
 384
 385 -- It's important that simplExprGently does eta reduction; see
 386 -- Note [Simplifying the left-hand side of a RULE] above.  The
 387 -- simplifier does indeed do eta reduction (it's in Simplify.completeLam)
 388 -- but only if -O is on.
 389
 390 simplExprGently env expr = do
 391     expr1 <- simplExpr env (occurAnalyseExpr expr)
 392     simplExpr env (occurAnalyseExpr expr1)
 393 \end{code}
 394
 395
 396 %************************************************************************
 397 %*                                                                      *
 398 \subsection{Glomming}
 399 %*                                                                      *
 400 %************************************************************************
 401
 402 \begin{code}
 403 glomBinds :: DynFlags -> [CoreBind] -> IO [CoreBind]
 404 -- Glom all binds together in one Rec, in case any
 405 -- transformations have introduced any new dependencies
 406 --
 407 -- NB: the global invariant is this:
 408 --      *** the top level bindings are never cloned, and are always unique ***
 409 --
 410 -- We sort them into dependency order, but applying transformation rules may
 411 -- make something at the top refer to something at the bottom:
 412 --      f = \x -> p (q x)
 413 --      h = \y -> 3
 414 --
 415 --      RULE:  p (q x) = h x
 416 --
 417 -- Applying this rule makes f refer to h,
 418 -- although it doesn't appear to in the source program.
 419 -- This pass lets us control where it happens.
 420 --
 421 -- NOTICE that this cannot happen for rules whose head is a locally-defined
 422 -- function.  It only happens for rules whose head is an imported function
 423 -- (p in the example above).  So, for example, the rule had been
 424 --      RULE: f (p x) = h x
 425 -- then the rule for f would be attached to f itself (in its IdInfo)
 426 -- by prepareLocalRuleBase and h would be regarded by the occurrency
 427 -- analyser as free in f.
 428
 429 glomBinds dflags binds
 430   = do { Err.showPass dflags "GlomBinds" ;
 431          let { recd_binds = [Rec (flattenBinds binds)] } ;
 432          return recd_binds }
 433         -- Not much point in printing the result...
 434         -- just consumes output bandwidth
 435 \end{code}
 436
 437
 438 %************************************************************************
 439 %*                                                                      *
 440 \subsection{The driver for the simplifier}
 441 %*                                                                      *
 442 %************************************************************************
 443
 444 \begin{code}
 445 simplifyPgm :: CoreToDo -> ModGuts -> CoreM ModGuts
 446 simplifyPgm pass guts
 447   = do { hsc_env <- getHscEnv
 448        ; us <- getUniqueSupplyM
 449        ; rb <- getRuleBase
 450        ; liftIOWithCount $
 451          simplifyPgmIO pass hsc_env us rb guts }
 452
 453 simplifyPgmIO :: CoreToDo
 454               -> HscEnv
 455               -> UniqSupply
 456               -> RuleBase
 457               -> ModGuts
 458               -> IO (SimplCount, ModGuts)  -- New bindings
 459
 460 simplifyPgmIO pass@(CoreDoSimplify mode max_iterations switches)
 461               hsc_env us hpt_rule_base
 462               guts@(ModGuts { mg_binds = binds, mg_rules = rules
 463                             , mg_fam_inst_env = fam_inst_env })
 464   = do { (termination_msg, it_count, counts_out, guts')
 465            <- do_iteration us 1 [] binds rules
 466
 467         ; Err.dumpIfSet (dump_phase && dopt Opt_D_dump_simpl_stats dflags)
 468                   "Simplifier statistics for following pass"
 469                   (vcat [text termination_msg <+> text "after" <+> ppr it_count <+> text "iterations",
 470                          blankLine,
 471                          pprSimplCount counts_out])
 472
 473         ; return (counts_out, guts')
 474     }
 475   where
 476     dflags       = hsc_dflags hsc_env
 477     dump_phase   = dumpSimplPhase dflags mode
 478     sw_chkr      = isAmongSimpl switches
 479     do_iteration :: UniqSupply
 480                  -> Int          -- Counts iterations
 481                  -> [SimplCount] -- Counts from earlier iterations, reversed
 482                  -> [CoreBind]   -- Bindings in
 483                  -> [CoreRule]   -- and orphan rules
 484                  -> IO (String, Int, SimplCount, ModGuts)
 485
 486     do_iteration us iteration_no counts_so_far binds rules
 487         -- iteration_no is the number of the iteration we are
 488         -- about to begin, with '1' for the first
 489       | iteration_no > max_iterations   -- Stop if we've run out of iterations
 490       = WARN( debugIsOn && (max_iterations > 2)
 491             , ptext (sLit "Simplifier baling out after") <+> int max_iterations
 492               <+> ptext (sLit "iterations")
 493               <+> brackets (pprWithCommas (int . simplCountN) (reverse counts_so_far))
 494               <+> ptext (sLit "Size =") <+> int (coreBindsSize binds) )
 495
 496                 -- Subtract 1 from iteration_no to get the
 497                 -- number of iterations we actually completed
 498         return ("Simplifier baled out", iteration_no - 1, total_counts,
 499                  guts { mg_binds = binds, mg_rules = rules })
 500
 501       -- Try and force thunks off the binds; significantly reduces
 502       -- space usage, especially with -O.  JRS, 000620.
 503       | let sz = coreBindsSize binds in sz == sz
 504       = do {
 505                 -- Occurrence analysis
 506            let { tagged_binds = {-# SCC "OccAnal" #-} occurAnalysePgm binds rules } ;
 507            Err.dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
 508                      (pprCoreBindings tagged_binds);
 509
 510                 -- Get any new rules, and extend the rule base
 511                 -- See Note [Overall plumbing for rules] in Rules.lhs
 512                 -- We need to do this regularly, because simplification can
 513                 -- poke on IdInfo thunks, which in turn brings in new rules
 514                 -- behind the scenes.  Otherwise there's a danger we'll simply
 515                 -- miss the rules for Ids hidden inside imported inlinings
 516            eps <- hscEPS hsc_env ;
 517            let  { rule_base1 = unionRuleBase hpt_rule_base (eps_rule_base eps)
 518                 ; rule_base2 = extendRuleBaseList rule_base1 rules
 519                 ; simpl_env  = mkSimplEnv sw_chkr mode
 520                 ; simpl_binds = {-# SCC "SimplTopBinds" #-}
 521                                 simplTopBinds simpl_env tagged_binds
 522                 ; fam_envs = (eps_fam_inst_env eps, fam_inst_env) } ;
 523
 524                 -- Simplify the program
 525                 -- We do this with a *case* not a *let* because lazy pattern
 526                 -- matching bit us with bad space leak!
 527                 -- With a let, we ended up with
 528                 --   let
 529                 --      t = initSmpl ...
 530                 --      counts1 = snd t
 531                 --   in
 532                 --      case t of {(_,counts1) -> if counts1=0 then ... }
 533                 -- So the conditional didn't force counts1, because the
 534                 -- selection got duplicated.  Sigh!
 535            case initSmpl dflags rule_base2 fam_envs us1 simpl_binds of {
 536                 (env1, counts1) -> do {
 537
 538            let  { binds1 = getFloats env1
 539                 ; rules1 = substRulesForImportedIds (mkCoreSubst (text "imp-rules") env1) rules
 540                 } ;
 541
 542                 -- Stop if nothing happened; don't dump output
 543            if isZeroSimplCount counts1 then
 544                 return ("Simplifier reached fixed point", iteration_no, total_counts,
 545                         guts { mg_binds = binds1, mg_rules = rules1 })
 546            else do {
 547                 -- Short out indirections
 548                 -- We do this *after* at least one run of the simplifier
 549                 -- because indirection-shorting uses the export flag on *occurrences*
 550                 -- and that isn't guaranteed to be ok until after the first run propagates
 551                 -- stuff from the binding site to its occurrences
 552                 --
 553                 -- ToDo: alas, this means that indirection-shorting does not happen at all
 554                 --       if the simplifier does nothing (not common, I know, but unsavoury)
 555            let { binds2 = {-# SCC "ZapInd" #-} shortOutIndirections binds1 } ;
 556
 557                 -- Dump the result of this iteration
 558            end_iteration dflags pass iteration_no counts1 binds2 rules1 ;
 559
 560                 -- Loop
 561            do_iteration us2 (iteration_no + 1) (counts1:counts_so_far) binds2 rules1
 562         }  } } }
 563       where
 564         (us1, us2) = splitUniqSupply us
 565
 566         -- Remember the counts_so_far are reversed
 567         total_counts = foldr (\c acc -> acc `plusSimplCount` c)
 568                              (zeroSimplCount dflags) counts_so_far
 569
 570 -------------------
 571 end_iteration :: DynFlags -> CoreToDo -> Int
 572              -> SimplCount -> [CoreBind] -> [CoreRule] -> IO ()
 573 -- Same as endIteration but with simplifier counts
 574 end_iteration dflags pass iteration_no counts binds rules
 575   = do { dumpIfSet (dopt Opt_D_dump_simpl_iterations dflags)
 576                    pass (ptext (sLit "Simplifier counts"))
 577                    (pprSimplCount counts)
 578
 579        ; endIteration dflags pass iteration_no binds rules }
 580 \end{code}
 581
 582
 583 %************************************************************************
 584 %*                                                                      *
 585                 Shorting out indirections
 586 %*                                                                      *
 587 %************************************************************************
 588
 589 If we have this:
 590
 591         x_local = <expression>
 592         ...bindings...
 593         x_exported = x_local
 594
 595 where x_exported is exported, and x_local is not, then we replace it with this:
 596
 597         x_exported = <expression>
 598         x_local = x_exported
 599         ...bindings...
 600
 601 Without this we never get rid of the x_exported = x_local thing.  This
 602 save a gratuitous jump (from \tr{x_exported} to \tr{x_local}), and
 603 makes strictness information propagate better.  This used to happen in
 604 the final phase, but it's tidier to do it here.
 605
 606 Note [Transferring IdInfo]
 607 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 608 We want to propagage any useful IdInfo on x_local to x_exported.
 609
 610 STRICTNESS: if we have done strictness analysis, we want the strictness info on
 611 x_local to transfer to x_exported.  Hence the copyIdInfo call.
 612
 613 RULES: we want to *add* any RULES for x_local to x_exported.
 614
 615
 616 Note [Messing up the exported Id's RULES]
 617 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 618 We must be careful about discarding (obviously) or even merging the
 619 RULES on the exported Id. The example that went bad on me at one stage
 620 was this one:
 621
 622     iterate :: (a -> a) -> a -> [a]
 623         [Exported]
 624     iterate = iterateList
 625
 626     iterateFB c f x = x `c` iterateFB c f (f x)
 627     iterateList f x =  x : iterateList f (f x)
 628         [Not exported]
 629
 630     {-# RULES
 631     "iterate"   forall f x.     iterate f x = build (\c _n -> iterateFB c f x)
 632     "iterateFB"                 iterateFB (:) = iterateList
 633      #-}
 634
 635 This got shorted out to:
 636
 637     iterateList :: (a -> a) -> a -> [a]
 638     iterateList = iterate
 639
 640     iterateFB c f x = x `c` iterateFB c f (f x)
 641     iterate f x =  x : iterate f (f x)
 642
 643     {-# RULES
 644     "iterate"   forall f x.     iterate f x = build (\c _n -> iterateFB c f x)
 645     "iterateFB"                 iterateFB (:) = iterate
 646      #-}
 647
 648 And now we get an infinite loop in the rule system
 649         iterate f x -> build (\cn -> iterateFB c f x)
 650                     -> iterateFB (:) f x
 651                     -> iterate f x
 652
 653 Old "solution":
 654         use rule switching-off pragmas to get rid
 655         of iterateList in the first place
 656
 657 But in principle the user *might* want rules that only apply to the Id
 658 he says.  And inline pragmas are similar
 659    {-# NOINLINE f #-}
 660    f = local
 661    local = <stuff>
 662 Then we do not want to get rid of the NOINLINE.
 663
 664 Hence hasShortableIdinfo.
 665
 666
 667 Note [Rules and indirection-zapping]
 668 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 669 Problem: what if x_exported has a RULE that mentions something in ...bindings...?
 670 Then the things mentioned can be out of scope!  Solution
 671  a) Make sure that in this pass the usage-info from x_exported is
 672         available for ...bindings...
 673  b) If there are any such RULES, rec-ify the entire top-level.
 674     It'll get sorted out next time round
 675
 676 Other remarks
 677 ~~~~~~~~~~~~~
 678 If more than one exported thing is equal to a local thing (i.e., the
 679 local thing really is shared), then we do one only:
 680 \begin{verbatim}
 681         x_local = ....
 682         x_exported1 = x_local
 683         x_exported2 = x_local
 684 ==>
 685         x_exported1 = ....
 686
 687         x_exported2 = x_exported1
 688 \end{verbatim}
 689
 690 We rely on prior eta reduction to simplify things like
 691 \begin{verbatim}
 692         x_exported = /\ tyvars -> x_local tyvars
 693 ==>
 694         x_exported = x_local
 695 \end{verbatim}
 696 Hence,there's a possibility of leaving unchanged something like this:
 697 \begin{verbatim}
 698         x_local = ....
 699         x_exported1 = x_local Int
 700 \end{verbatim}
 701 By the time we've thrown away the types in STG land this
 702 could be eliminated.  But I don't think it's very common
 703 and it's dangerous to do this fiddling in STG land
 704 because we might elminate a binding that's mentioned in the
 705 unfolding for something.
 706
 707 \begin{code}
 708 type IndEnv = IdEnv Id          -- Maps local_id -> exported_id
 709
 710 shortOutIndirections :: [CoreBind] -> [CoreBind]
 711 shortOutIndirections binds
 712   | isEmptyVarEnv ind_env = binds
 713   | no_need_to_flatten    = binds'                      -- See Note [Rules and indirect-zapping]
 714   | otherwise             = [Rec (flattenBinds binds')] -- for this no_need_to_flatten stuff
 715   where
 716     ind_env            = makeIndEnv binds
 717     exp_ids            = varSetElems ind_env    -- These exported Ids are the subjects
 718     exp_id_set         = mkVarSet exp_ids       -- of the indirection-elimination
 719     no_need_to_flatten = all (null . specInfoRules . idSpecialisation) exp_ids
 720     binds'             = concatMap zap binds
 721
 722     zap (NonRec bndr rhs) = [NonRec b r | (b,r) <- zapPair (bndr,rhs)]
 723     zap (Rec pairs)       = [Rec (concatMap zapPair pairs)]
 724
 725     zapPair (bndr, rhs)
 726         | bndr `elemVarSet` exp_id_set             = []
 727         | Just exp_id <- lookupVarEnv ind_env bndr = [(transferIdInfo exp_id bndr, rhs),
 728                                                       (bndr, Var exp_id)]
 729         | otherwise                                = [(bndr,rhs)]
 730
 731 makeIndEnv :: [CoreBind] -> IndEnv
 732 makeIndEnv binds
 733   = foldr add_bind emptyVarEnv binds
 734   where
 735     add_bind :: CoreBind -> IndEnv -> IndEnv
 736     add_bind (NonRec exported_id rhs) env = add_pair (exported_id, rhs) env
 737     add_bind (Rec pairs)              env = foldr add_pair env pairs
 738
 739     add_pair :: (Id,CoreExpr) -> IndEnv -> IndEnv
 740     add_pair (exported_id, Var local_id) env
 741         | shortMeOut env exported_id local_id = extendVarEnv env local_id exported_id
 742     add_pair (exported_id, rhs) env
 743         = env
 744
 745 -----------------
 746 shortMeOut ind_env exported_id local_id
 747 -- The if-then-else stuff is just so I can get a pprTrace to see
 748 -- how often I don't get shorting out becuase of IdInfo stuff
 749   = if isExportedId exported_id &&              -- Only if this is exported
 750
 751        isLocalId local_id &&                    -- Only if this one is defined in this
 752                                                 --      module, so that we *can* change its
 753                                                 --      binding to be the exported thing!
 754
 755        not (isExportedId local_id) &&           -- Only if this one is not itself exported,
 756                                                 --      since the transformation will nuke it
 757
 758        not (local_id `elemVarEnv` ind_env)      -- Only if not already substituted for
 759     then
 760         if hasShortableIdInfo exported_id
 761         then True       -- See Note [Messing up the exported Id's IdInfo]
 762         else WARN( True, ptext (sLit "Not shorting out:") <+> ppr exported_id )
 763              False
 764     else
 765         False
 766
 767 -----------------
 768 hasShortableIdInfo :: Id -> Bool
 769 -- True if there is no user-attached IdInfo on exported_id,
 770 -- so we can safely discard it
 771 -- See Note [Messing up the exported Id's IdInfo]
 772 hasShortableIdInfo id
 773   =  isEmptySpecInfo (specInfo info)
 774   && isDefaultInlinePragma (inlinePragInfo info)
 775   where
 776      info = idInfo id
 777
 778 -----------------
 779 transferIdInfo :: Id -> Id -> Id
 780 -- See Note [Transferring IdInfo]
 781 -- If we have
 782 --      lcl_id = e; exp_id = lcl_id
 783 -- and lcl_id has useful IdInfo, we don't want to discard it by going
 784 --      gbl_id = e; lcl_id = gbl_id
 785 -- Instead, transfer IdInfo from lcl_id to exp_id
 786 -- Overwriting, rather than merging, seems to work ok.
 787 transferIdInfo exported_id local_id
 788   = modifyIdInfo transfer exported_id
 789   where
 790     local_info = idInfo local_id
 791     transfer exp_info = exp_info `setStrictnessInfo` strictnessInfo local_info
 792                                  `setUnfoldingInfo`     unfoldingInfo local_info
 793                                  `setInlinePragInfo`    inlinePragInfo local_info
 794                                  `setSpecInfo`          addSpecInfo (specInfo exp_info) new_info
 795     new_info = setSpecInfoHead (idName exported_id)
 796                                (specInfo local_info)
 797         -- Remember to set the function-name field of the
 798         -- rules as we transfer them from one function to another
 799 \end{code}