compiler/simplCore/SimplCore.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SimplCore]{Driver for simplifying @Core@ programs}
   5
   6 \begin{code}
   7 module SimplCore ( core2core, simplifyExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags         ( DynFlags, DynFlag(..), dopt )
  12 import CoreSyn
  13 import CoreSubst
  14 import HscTypes
  15 import CSE              ( cseProgram )
  16 import Rules            ( RuleBase, emptyRuleBase, mkRuleBase, unionRuleBase,
  17                           extendRuleBaseList, ruleCheckProgram, addSpecInfo, )
  18 import PprCore          ( pprCoreBindings, pprCoreExpr )
  19 import OccurAnal        ( occurAnalysePgm, occurAnalyseExpr )
  20 import IdInfo
  21 import CoreUtils        ( coreBindsSize )
  22 import Simplify         ( simplTopBinds, simplExpr )
  23 import SimplUtils       ( simplEnvForGHCi )
  24 import SimplEnv
  25 import SimplMonad
  26 import CoreMonad
  27 import qualified ErrUtils as Err
  28 import FloatIn          ( floatInwards )
  29 import FloatOut         ( floatOutwards )
  30 import FamInstEnv
  31 import Id
  32 import BasicTypes       ( CompilerPhase, isDefaultInlinePragma )
  33 import VarSet
  34 import VarEnv
  35 import LiberateCase     ( liberateCase )
  36 import SAT              ( doStaticArgs )
  37 import Specialise       ( specProgram)
  38 import SpecConstr       ( specConstrProgram)
  39 import DmdAnal          ( dmdAnalPgm )
  40 import WorkWrap         ( wwTopBinds )
  41 import Vectorise        ( vectorise )
  42 import FastString
  43 import Util
  44
  45 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, splitUniqSupply )
  46 import Outputable
  47 import Control.Monad
  48 \end{code}
  49
  50 %************************************************************************
  51 %*                                                                      *
  52 \subsection{The driver for the simplifier}
  53 %*                                                                      *
  54 %************************************************************************
  55
  56 \begin{code}
  57 core2core :: HscEnv -> ModGuts -> IO ModGuts
  58 core2core hsc_env guts
  59   = do { us <- mkSplitUniqSupply 's'
  60        ; (guts2, stats) <- runCoreM hsc_env hpt_rule_base us mod $
  61                            doCorePasses (getCoreToDo dflags) guts
  62
  63        ; Err.dumpIfSet_dyn dflags Opt_D_dump_simpl_stats
  64              "Grand total simplifier statistics"
  65              (pprSimplCount stats)
  66
  67        ; return guts2 }
  68   where
  69     dflags         = hsc_dflags hsc_env
  70     home_pkg_rules = hptRules hsc_env (dep_mods (mg_deps guts))
  71     hpt_rule_base  = mkRuleBase home_pkg_rules
  72     mod            = mg_module guts
  73     -- mod: get the module out of the current HscEnv so we can retrieve it from the monad.
  74     -- This is very convienent for the users of the monad (e.g. plugins do not have to
  75     -- consume the ModGuts to find the module) but somewhat ugly because mg_module may
  76     -- _theoretically_ be changed during the Core pipeline (it's part of ModGuts), which
  77     -- would mean our cached value would go out of date.
  78
  79
  80 type CorePass = CoreToDo
  81
  82 doCorePasses :: [CorePass] -> ModGuts -> CoreM ModGuts
  83 doCorePasses passes guts
  84   = foldM do_pass guts passes
  85   where
  86     do_pass guts CoreDoNothing = return guts
  87     do_pass guts (CoreDoPasses ps) = doCorePasses ps guts
  88     do_pass guts pass
  89        = do { dflags <- getDynFlags
  90             ; liftIO $ showPass dflags pass
  91             ; guts' <- doCorePass pass guts
  92             ; liftIO $ endPass dflags pass (mg_binds guts') (mg_rules guts')
  93             ; return guts' }
  94
  95 doCorePass :: CorePass -> ModGuts -> CoreM ModGuts
  96 doCorePass pass@(CoreDoSimplify {})  = {-# SCC "Simplify" #-}
  97                                        simplifyPgm pass
  98
  99 doCorePass CoreCSE                   = {-# SCC "CommonSubExpr" #-}
 100                                        doPass cseProgram
 101
 102 doCorePass CoreLiberateCase          = {-# SCC "LiberateCase" #-}
 103                                        doPassD liberateCase
 104
 105 doCorePass CoreDoFloatInwards        = {-# SCC "FloatInwards" #-}
 106                                        doPass floatInwards
 107
 108 doCorePass (CoreDoFloatOutwards f)   = {-# SCC "FloatOutwards" #-}
 109                                        doPassDUM (floatOutwards f)
 110
 111 doCorePass CoreDoStaticArgs          = {-# SCC "StaticArgs" #-}
 112                                        doPassU doStaticArgs
 113
 114 doCorePass CoreDoStrictness          = {-# SCC "Stranal" #-}
 115                                        doPassDM dmdAnalPgm
 116
 117 doCorePass CoreDoWorkerWrapper       = {-# SCC "WorkWrap" #-}
 118                                        doPassU wwTopBinds
 119
 120 doCorePass CoreDoSpecialising        = {-# SCC "Specialise" #-}
 121                                        specProgram
 122
 123 doCorePass CoreDoSpecConstr          = {-# SCC "SpecConstr" #-}
 124                                        specConstrProgram
 125
 126 doCorePass (CoreDoVectorisation be)  = {-# SCC "Vectorise" #-}
 127                                        vectorise be
 128
 129 doCorePass CoreDoGlomBinds              = doPassDM  glomBinds
 130 doCorePass CoreDoPrintCore              = observe   printCore
 131 doCorePass (CoreDoRuleCheck phase pat)  = ruleCheck phase pat
 132 doCorePass CoreDoNothing                = return
 133 doCorePass (CoreDoPasses passes)        = doCorePasses passes
 134 doCorePass pass = pprPanic "doCorePass" (ppr pass)
 135 \end{code}
 136
 137 %************************************************************************
 138 %*                                                                      *
 139 \subsection{Core pass combinators}
 140 %*                                                                      *
 141 %************************************************************************
 142
 143 \begin{code}
 144 printCore :: a -> [CoreBind] -> IO ()
 145 printCore _ binds = Err.dumpIfSet True "Print Core" (pprCoreBindings binds)
 146
 147 ruleCheck :: CompilerPhase -> String -> ModGuts -> CoreM ModGuts
 148 ruleCheck current_phase pat guts = do
 149     rb <- getRuleBase
 150     dflags <- getDynFlags
 151     liftIO $ Err.showPass dflags "RuleCheck"
 152     liftIO $ printDump (ruleCheckProgram current_phase pat rb (mg_binds guts))
 153     return guts
 154
 155
 156 doPassDUM :: (DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]) -> ModGuts -> CoreM ModGuts
 157 doPassDUM do_pass = doPassM $ \binds -> do
 158     dflags <- getDynFlags
 159     us     <- getUniqueSupplyM
 160     liftIO $ do_pass dflags us binds
 161
 162 doPassDM :: (DynFlags -> [CoreBind] -> IO [CoreBind]) -> ModGuts -> CoreM ModGuts
 163 doPassDM do_pass = doPassDUM (\dflags -> const (do_pass dflags))
 164
 165 doPassD :: (DynFlags -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 166 doPassD do_pass = doPassDM (\dflags -> return . do_pass dflags)
 167
 168 doPassDU :: (DynFlags -> UniqSupply -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 169 doPassDU do_pass = doPassDUM (\dflags us -> return . do_pass dflags us)
 170
 171 doPassU :: (UniqSupply -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 172 doPassU do_pass = doPassDU (const do_pass)
 173
 174 -- Most passes return no stats and don't change rules: these combinators
 175 -- let us lift them to the full blown ModGuts+CoreM world
 176 doPassM :: Monad m => ([CoreBind] -> m [CoreBind]) -> ModGuts -> m ModGuts
 177 doPassM bind_f guts = do
 178     binds' <- bind_f (mg_binds guts)
 179     return (guts { mg_binds = binds' })
 180
 181 doPass :: ([CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 182 doPass bind_f guts = return $ guts { mg_binds = bind_f (mg_binds guts) }
 183
 184 -- Observer passes just peek; don't modify the bindings at all
 185 observe :: (DynFlags -> [CoreBind] -> IO a) -> ModGuts -> CoreM ModGuts
 186 observe do_pass = doPassM $ \binds -> do
 187     dflags <- getDynFlags
 188     _ <- liftIO $ do_pass dflags binds
 189     return binds
 190 \end{code}
 191
 192
 193 %************************************************************************
 194 %*                                                                      *
 195         Gentle simplification
 196 %*                                                                      *
 197 %************************************************************************
 198
 199 \begin{code}
 200 simplifyExpr :: DynFlags -- includes spec of what core-to-core passes to do
 201              -> CoreExpr
 202              -> IO CoreExpr
 203 -- simplifyExpr is called by the driver to simplify an
 204 -- expression typed in at the interactive prompt
 205 --
 206 -- Also used by Template Haskell
 207 simplifyExpr dflags expr
 208   = do  {
 209         ; Err.showPass dflags "Simplify"
 210
 211         ; us <-  mkSplitUniqSupply 's'
 212
 213         ; let (expr', _counts) = initSmpl dflags emptyRuleBase emptyFamInstEnvs us $
 214                                  simplExprGently simplEnvForGHCi expr
 215
 216         ; Err.dumpIfSet_dyn dflags Opt_D_dump_simpl "Simplified expression"
 217                         (pprCoreExpr expr')
 218
 219         ; return expr'
 220         }
 221
 222 simplExprGently :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 223 -- Simplifies an expression
 224 --      does occurrence analysis, then simplification
 225 --      and repeats (twice currently) because one pass
 226 --      alone leaves tons of crud.
 227 -- Used (a) for user expressions typed in at the interactive prompt
 228 --      (b) the LHS and RHS of a RULE
 229 --      (c) Template Haskell splices
 230 --
 231 -- The name 'Gently' suggests that the SimplifierMode is SimplGently,
 232 -- and in fact that is so.... but the 'Gently' in simplExprGently doesn't
 233 -- enforce that; it just simplifies the expression twice
 234
 235 -- It's important that simplExprGently does eta reduction; see
 236 -- Note [Simplifying the left-hand side of a RULE] above.  The
 237 -- simplifier does indeed do eta reduction (it's in Simplify.completeLam)
 238 -- but only if -O is on.
 239
 240 simplExprGently env expr = do
 241     expr1 <- simplExpr env (occurAnalyseExpr expr)
 242     simplExpr env (occurAnalyseExpr expr1)
 243 \end{code}
 244
 245
 246 %************************************************************************
 247 %*                                                                      *
 248 \subsection{Glomming}
 249 %*                                                                      *
 250 %************************************************************************
 251
 252 \begin{code}
 253 glomBinds :: DynFlags -> [CoreBind] -> IO [CoreBind]
 254 -- Glom all binds together in one Rec, in case any
 255 -- transformations have introduced any new dependencies
 256 --
 257 -- NB: the global invariant is this:
 258 --      *** the top level bindings are never cloned, and are always unique ***
 259 --
 260 -- We sort them into dependency order, but applying transformation rules may
 261 -- make something at the top refer to something at the bottom:
 262 --      f = \x -> p (q x)
 263 --      h = \y -> 3
 264 --
 265 --      RULE:  p (q x) = h x
 266 --
 267 -- Applying this rule makes f refer to h,
 268 -- although it doesn't appear to in the source program.
 269 -- This pass lets us control where it happens.
 270 --
 271 -- NOTICE that this cannot happen for rules whose head is a locally-defined
 272 -- function.  It only happens for rules whose head is an imported function
 273 -- (p in the example above).  So, for example, the rule had been
 274 --      RULE: f (p x) = h x
 275 -- then the rule for f would be attached to f itself (in its IdInfo)
 276 -- by prepareLocalRuleBase and h would be regarded by the occurrency
 277 -- analyser as free in f.
 278
 279 glomBinds dflags binds
 280   = do { Err.showPass dflags "GlomBinds" ;
 281          let { recd_binds = [Rec (flattenBinds binds)] } ;
 282          return recd_binds }
 283         -- Not much point in printing the result...
 284         -- just consumes output bandwidth
 285 \end{code}
 286
 287
 288 %************************************************************************
 289 %*                                                                      *
 290 \subsection{The driver for the simplifier}
 291 %*                                                                      *
 292 %************************************************************************
 293
 294 \begin{code}
 295 simplifyPgm :: CoreToDo -> ModGuts -> CoreM ModGuts
 296 simplifyPgm pass guts
 297   = do { hsc_env <- getHscEnv
 298        ; us <- getUniqueSupplyM
 299        ; rb <- getRuleBase
 300        ; liftIOWithCount $
 301          simplifyPgmIO pass hsc_env us rb guts }
 302
 303 simplifyPgmIO :: CoreToDo
 304               -> HscEnv
 305               -> UniqSupply
 306               -> RuleBase
 307               -> ModGuts
 308               -> IO (SimplCount, ModGuts)  -- New bindings
 309
 310 simplifyPgmIO pass@(CoreDoSimplify mode max_iterations switches)
 311               hsc_env us hpt_rule_base
 312               guts@(ModGuts { mg_binds = binds, mg_rules = rules
 313                             , mg_fam_inst_env = fam_inst_env })
 314   = do { (termination_msg, it_count, counts_out, guts')
 315            <- do_iteration us 1 [] binds rules
 316
 317         ; Err.dumpIfSet (dump_phase && dopt Opt_D_dump_simpl_stats dflags)
 318                   "Simplifier statistics for following pass"
 319                   (vcat [text termination_msg <+> text "after" <+> ppr it_count <+> text "iterations",
 320                          blankLine,
 321                          pprSimplCount counts_out])
 322
 323         ; return (counts_out, guts')
 324     }
 325   where
 326     dflags       = hsc_dflags hsc_env
 327     dump_phase   = dumpSimplPhase dflags mode
 328     sw_chkr      = isAmongSimpl switches
 329     do_iteration :: UniqSupply
 330                  -> Int          -- Counts iterations
 331                  -> [SimplCount] -- Counts from earlier iterations, reversed
 332                  -> [CoreBind]   -- Bindings in
 333                  -> [CoreRule]   -- and orphan rules
 334                  -> IO (String, Int, SimplCount, ModGuts)
 335
 336     do_iteration us iteration_no counts_so_far binds rules
 337         -- iteration_no is the number of the iteration we are
 338         -- about to begin, with '1' for the first
 339       | iteration_no > max_iterations   -- Stop if we've run out of iterations
 340       = WARN( debugIsOn && (max_iterations > 2)
 341             , ptext (sLit "Simplifier baling out after") <+> int max_iterations
 342               <+> ptext (sLit "iterations")
 343               <+> (brackets $ hsep $ punctuate comma $
 344                    map (int . simplCountN) (reverse counts_so_far))
 345               <+> ptext (sLit "Size =") <+> int (coreBindsSize binds) )
 346
 347                 -- Subtract 1 from iteration_no to get the
 348                 -- number of iterations we actually completed
 349         return ( "Simplifier baled out", iteration_no - 1
 350                , totalise counts_so_far
 351                , guts { mg_binds = binds, mg_rules = rules } )
 352
 353       -- Try and force thunks off the binds; significantly reduces
 354       -- space usage, especially with -O.  JRS, 000620.
 355       | let sz = coreBindsSize binds in sz == sz
 356       = do {
 357                 -- Occurrence analysis
 358            let { tagged_binds = {-# SCC "OccAnal" #-} occurAnalysePgm binds rules } ;
 359            Err.dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
 360                      (pprCoreBindings tagged_binds);
 361
 362                 -- Get any new rules, and extend the rule base
 363                 -- See Note [Overall plumbing for rules] in Rules.lhs
 364                 -- We need to do this regularly, because simplification can
 365                 -- poke on IdInfo thunks, which in turn brings in new rules
 366                 -- behind the scenes.  Otherwise there's a danger we'll simply
 367                 -- miss the rules for Ids hidden inside imported inlinings
 368            eps <- hscEPS hsc_env ;
 369            let  { rule_base1 = unionRuleBase hpt_rule_base (eps_rule_base eps)
 370                 ; rule_base2 = extendRuleBaseList rule_base1 rules
 371                 ; simpl_env  = mkSimplEnv sw_chkr mode
 372                 ; simpl_binds = {-# SCC "SimplTopBinds" #-}
 373                                 simplTopBinds simpl_env tagged_binds
 374                 ; fam_envs = (eps_fam_inst_env eps, fam_inst_env) } ;
 375
 376                 -- Simplify the program
 377                 -- We do this with a *case* not a *let* because lazy pattern
 378                 -- matching bit us with bad space leak!
 379                 -- With a let, we ended up with
 380                 --   let
 381                 --      t = initSmpl ...
 382                 --      counts1 = snd t
 383                 --   in
 384                 --      case t of {(_,counts1) -> if counts1=0 then ... }
 385                 -- So the conditional didn't force counts1, because the
 386                 -- selection got duplicated.  Sigh!
 387            case initSmpl dflags rule_base2 fam_envs us1 simpl_binds of {
 388                 (env1, counts1) -> do {
 389
 390            let  { binds1 = getFloats env1
 391                 ; rules1 = substRulesForImportedIds (mkCoreSubst (text "imp-rules") env1) rules
 392                 } ;
 393
 394                 -- Stop if nothing happened; don't dump output
 395            if isZeroSimplCount counts1 then
 396                 return ( "Simplifier reached fixed point", iteration_no
 397                        , totalise (counts1 : counts_so_far)  -- Include "free" ticks
 398                        , guts { mg_binds = binds1, mg_rules = rules1 } )
 399            else do {
 400                 -- Short out indirections
 401                 -- We do this *after* at least one run of the simplifier
 402                 -- because indirection-shorting uses the export flag on *occurrences*
 403                 -- and that isn't guaranteed to be ok until after the first run propagates
 404                 -- stuff from the binding site to its occurrences
 405                 --
 406                 -- ToDo: alas, this means that indirection-shorting does not happen at all
 407                 --       if the simplifier does nothing (not common, I know, but unsavoury)
 408            let { binds2 = {-# SCC "ZapInd" #-} shortOutIndirections binds1 } ;
 409
 410                 -- Dump the result of this iteration
 411            end_iteration dflags pass iteration_no counts1 binds2 rules1 ;
 412
 413                 -- Loop
 414            do_iteration us2 (iteration_no + 1) (counts1:counts_so_far) binds2 rules1
 415            } } } }
 416       | otherwise = panic "do_iteration"
 417       where
 418         (us1, us2) = splitUniqSupply us
 419
 420         -- Remember the counts_so_far are reversed
 421         totalise :: [SimplCount] -> SimplCount
 422         totalise = foldr (\c acc -> acc `plusSimplCount` c)
 423                          (zeroSimplCount dflags)
 424
 425 simplifyPgmIO _ _ _ _ _ = panic "simplifyPgmIO"
 426
 427 -------------------
 428 end_iteration :: DynFlags -> CoreToDo -> Int
 429              -> SimplCount -> [CoreBind] -> [CoreRule] -> IO ()
 430 -- Same as endIteration but with simplifier counts
 431 end_iteration dflags pass iteration_no counts binds rules
 432   = do { dumpIfSet (dopt Opt_D_dump_simpl_iterations dflags)
 433                    pass (ptext (sLit "Simplifier counts"))
 434                    (pprSimplCount counts)
 435
 436        ; endIteration dflags pass iteration_no binds rules }
 437 \end{code}
 438
 439
 440 %************************************************************************
 441 %*                                                                      *
 442                 Shorting out indirections
 443 %*                                                                      *
 444 %************************************************************************
 445
 446 If we have this:
 447
 448         x_local = <expression>
 449         ...bindings...
 450         x_exported = x_local
 451
 452 where x_exported is exported, and x_local is not, then we replace it with this:
 453
 454         x_exported = <expression>
 455         x_local = x_exported
 456         ...bindings...
 457
 458 Without this we never get rid of the x_exported = x_local thing.  This
 459 save a gratuitous jump (from \tr{x_exported} to \tr{x_local}), and
 460 makes strictness information propagate better.  This used to happen in
 461 the final phase, but it's tidier to do it here.
 462
 463 Note [Transferring IdInfo]
 464 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 465 We want to propagage any useful IdInfo on x_local to x_exported.
 466
 467 STRICTNESS: if we have done strictness analysis, we want the strictness info on
 468 x_local to transfer to x_exported.  Hence the copyIdInfo call.
 469
 470 RULES: we want to *add* any RULES for x_local to x_exported.
 471
 472
 473 Note [Messing up the exported Id's RULES]
 474 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 475 We must be careful about discarding (obviously) or even merging the
 476 RULES on the exported Id. The example that went bad on me at one stage
 477 was this one:
 478
 479     iterate :: (a -> a) -> a -> [a]
 480         [Exported]
 481     iterate = iterateList
 482
 483     iterateFB c f x = x `c` iterateFB c f (f x)
 484     iterateList f x =  x : iterateList f (f x)
 485         [Not exported]
 486
 487     {-# RULES
 488     "iterate"   forall f x.     iterate f x = build (\c _n -> iterateFB c f x)
 489     "iterateFB"                 iterateFB (:) = iterateList
 490      #-}
 491
 492 This got shorted out to:
 493
 494     iterateList :: (a -> a) -> a -> [a]
 495     iterateList = iterate
 496
 497     iterateFB c f x = x `c` iterateFB c f (f x)
 498     iterate f x =  x : iterate f (f x)
 499
 500     {-# RULES
 501     "iterate"   forall f x.     iterate f x = build (\c _n -> iterateFB c f x)
 502     "iterateFB"                 iterateFB (:) = iterate
 503      #-}
 504
 505 And now we get an infinite loop in the rule system
 506         iterate f x -> build (\cn -> iterateFB c f x)
 507                     -> iterateFB (:) f x
 508                     -> iterate f x
 509
 510 Old "solution":
 511         use rule switching-off pragmas to get rid
 512         of iterateList in the first place
 513
 514 But in principle the user *might* want rules that only apply to the Id
 515 he says.  And inline pragmas are similar
 516    {-# NOINLINE f #-}
 517    f = local
 518    local = <stuff>
 519 Then we do not want to get rid of the NOINLINE.
 520
 521 Hence hasShortableIdinfo.
 522
 523
 524 Note [Rules and indirection-zapping]
 525 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 526 Problem: what if x_exported has a RULE that mentions something in ...bindings...?
 527 Then the things mentioned can be out of scope!  Solution
 528  a) Make sure that in this pass the usage-info from x_exported is
 529         available for ...bindings...
 530  b) If there are any such RULES, rec-ify the entire top-level.
 531     It'll get sorted out next time round
 532
 533 Other remarks
 534 ~~~~~~~~~~~~~
 535 If more than one exported thing is equal to a local thing (i.e., the
 536 local thing really is shared), then we do one only:
 537 \begin{verbatim}
 538         x_local = ....
 539         x_exported1 = x_local
 540         x_exported2 = x_local
 541 ==>
 542         x_exported1 = ....
 543
 544         x_exported2 = x_exported1
 545 \end{verbatim}
 546
 547 We rely on prior eta reduction to simplify things like
 548 \begin{verbatim}
 549         x_exported = /\ tyvars -> x_local tyvars
 550 ==>
 551         x_exported = x_local
 552 \end{verbatim}
 553 Hence,there's a possibility of leaving unchanged something like this:
 554 \begin{verbatim}
 555         x_local = ....
 556         x_exported1 = x_local Int
 557 \end{verbatim}
 558 By the time we've thrown away the types in STG land this
 559 could be eliminated.  But I don't think it's very common
 560 and it's dangerous to do this fiddling in STG land
 561 because we might elminate a binding that's mentioned in the
 562 unfolding for something.
 563
 564 \begin{code}
 565 type IndEnv = IdEnv Id          -- Maps local_id -> exported_id
 566
 567 shortOutIndirections :: [CoreBind] -> [CoreBind]
 568 shortOutIndirections binds
 569   | isEmptyVarEnv ind_env = binds
 570   | no_need_to_flatten    = binds'                      -- See Note [Rules and indirect-zapping]
 571   | otherwise             = [Rec (flattenBinds binds')] -- for this no_need_to_flatten stuff
 572   where
 573     ind_env            = makeIndEnv binds
 574     exp_ids            = varSetElems ind_env    -- These exported Ids are the subjects
 575     exp_id_set         = mkVarSet exp_ids       -- of the indirection-elimination
 576     no_need_to_flatten = all (null . specInfoRules . idSpecialisation) exp_ids
 577     binds'             = concatMap zap binds
 578
 579     zap (NonRec bndr rhs) = [NonRec b r | (b,r) <- zapPair (bndr,rhs)]
 580     zap (Rec pairs)       = [Rec (concatMap zapPair pairs)]
 581
 582     zapPair (bndr, rhs)
 583         | bndr `elemVarSet` exp_id_set             = []
 584         | Just exp_id <- lookupVarEnv ind_env bndr = [(transferIdInfo exp_id bndr, rhs),
 585                                                       (bndr, Var exp_id)]
 586         | otherwise                                = [(bndr,rhs)]
 587
 588 makeIndEnv :: [CoreBind] -> IndEnv
 589 makeIndEnv binds
 590   = foldr add_bind emptyVarEnv binds
 591   where
 592     add_bind :: CoreBind -> IndEnv -> IndEnv
 593     add_bind (NonRec exported_id rhs) env = add_pair (exported_id, rhs) env
 594     add_bind (Rec pairs)              env = foldr add_pair env pairs
 595
 596     add_pair :: (Id,CoreExpr) -> IndEnv -> IndEnv
 597     add_pair (exported_id, Var local_id) env
 598         | shortMeOut env exported_id local_id = extendVarEnv env local_id exported_id
 599     add_pair _ env = env
 600
 601 -----------------
 602 shortMeOut :: IndEnv -> Id -> Id -> Bool
 603 shortMeOut ind_env exported_id local_id
 604 -- The if-then-else stuff is just so I can get a pprTrace to see
 605 -- how often I don't get shorting out becuase of IdInfo stuff
 606   = if isExportedId exported_id &&              -- Only if this is exported
 607
 608        isLocalId local_id &&                    -- Only if this one is defined in this
 609                                                 --      module, so that we *can* change its
 610                                                 --      binding to be the exported thing!
 611
 612        not (isExportedId local_id) &&           -- Only if this one is not itself exported,
 613                                                 --      since the transformation will nuke it
 614
 615        not (local_id `elemVarEnv` ind_env)      -- Only if not already substituted for
 616     then
 617         if hasShortableIdInfo exported_id
 618         then True       -- See Note [Messing up the exported Id's IdInfo]
 619         else WARN( True, ptext (sLit "Not shorting out:") <+> ppr exported_id )
 620              False
 621     else
 622         False
 623
 624 -----------------
 625 hasShortableIdInfo :: Id -> Bool
 626 -- True if there is no user-attached IdInfo on exported_id,
 627 -- so we can safely discard it
 628 -- See Note [Messing up the exported Id's IdInfo]
 629 hasShortableIdInfo id
 630   =  isEmptySpecInfo (specInfo info)
 631   && isDefaultInlinePragma (inlinePragInfo info)
 632   where
 633      info = idInfo id
 634
 635 -----------------
 636 transferIdInfo :: Id -> Id -> Id
 637 -- See Note [Transferring IdInfo]
 638 -- If we have
 639 --      lcl_id = e; exp_id = lcl_id
 640 -- and lcl_id has useful IdInfo, we don't want to discard it by going
 641 --      gbl_id = e; lcl_id = gbl_id
 642 -- Instead, transfer IdInfo from lcl_id to exp_id
 643 -- Overwriting, rather than merging, seems to work ok.
 644 transferIdInfo exported_id local_id
 645   = modifyIdInfo transfer exported_id
 646   where
 647     local_info = idInfo local_id
 648     transfer exp_info = exp_info `setStrictnessInfo` strictnessInfo local_info
 649                                  `setUnfoldingInfo`     unfoldingInfo local_info
 650                                  `setInlinePragInfo`    inlinePragInfo local_info
 651                                  `setSpecInfo`          addSpecInfo (specInfo exp_info) new_info
 652     new_info = setSpecInfoHead (idName exported_id)
 653                                (specInfo local_info)
 654         -- Remember to set the function-name field of the
 655         -- rules as we transfer them from one function to another
 656 \end{code}