compiler/simplCore/SimplEnv.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplMonad]{The simplifier Monad}
   5
   6 \begin{code}
   7 module SimplEnv (
   8         InId, InBind, InExpr, InAlt, InArg, InType, InBndr,
   9         OutId, OutTyVar, OutBind, OutExpr, OutAlt, OutArg, OutType, OutBndr,
  10         InCoercion, OutCoercion,
  11
  12         -- The simplifier mode
  13         setMode, getMode,
  14
  15         -- Switch checker
  16         SwitchChecker, SwitchResult(..), getSwitchChecker, getSimplIntSwitch,
  17         isAmongSimpl, intSwitchSet, switchIsOn,
  18
  19         setEnclosingCC, getEnclosingCC,
  20
  21         -- Environments
  22         SimplEnv(..), pprSimplEnv,      -- Temp not abstract
  23         mkSimplEnv, extendIdSubst, SimplEnv.extendTvSubst,
  24         zapSubstEnv, setSubstEnv,
  25         getInScope, setInScope, setInScopeSet, modifyInScope, addNewInScopeIds,
  26         getSimplRules, inGentleMode,
  27
  28         SimplSR(..), mkContEx, substId, lookupRecBndr,
  29
  30         simplNonRecBndr, simplRecBndrs, simplLamBndr, simplLamBndrs,
  31         simplBinder, simplBinders, addBndrRules,
  32         substExpr, substTy, mkCoreSubst,
  33
  34         -- Floats
  35         Floats, emptyFloats, isEmptyFloats, addNonRec, addFloats, extendFloats,
  36         wrapFloats, floatBinds, setFloats, zapFloats, addRecFloats,
  37         doFloatFromRhs, getFloats
  38     ) where
  39
  40 #include "HsVersions.h"
  41
  42 import SimplMonad
  43 import IdInfo
  44 import CoreSyn
  45 import CoreUtils
  46 import CostCentre
  47 import Var
  48 import VarEnv
  49 import VarSet
  50 import OrdList
  51 import Id
  52 import qualified CoreSubst      ( Subst, mkSubst, substExpr, substSpec, substUnfolding )
  53 import qualified Type           ( substTy, substTyVarBndr )
  54 import Type hiding              ( substTy, substTyVarBndr )
  55 import Coercion
  56 import BasicTypes
  57 import DynFlags
  58 import MonadUtils
  59 import Outputable
  60 import FastString
  61
  62 import Data.List
  63 \end{code}
  64
  65 %************************************************************************
  66 %*                                                                      *
  67 \subsection[Simplify-types]{Type declarations}
  68 %*                                                                      *
  69 %************************************************************************
  70
  71 \begin{code}
  72 type InBndr     = CoreBndr
  73 type InId       = Id                    -- Not yet cloned
  74 type InType     = Type                  -- Ditto
  75 type InBind     = CoreBind
  76 type InExpr     = CoreExpr
  77 type InAlt      = CoreAlt
  78 type InArg      = CoreArg
  79 type InCoercion = Coercion
  80
  81 type OutBndr     = CoreBndr
  82 type OutId       = Id                   -- Cloned
  83 type OutTyVar    = TyVar                -- Cloned
  84 type OutType     = Type                 -- Cloned
  85 type OutCoercion = Coercion
  86 type OutBind     = CoreBind
  87 type OutExpr     = CoreExpr
  88 type OutAlt      = CoreAlt
  89 type OutArg      = CoreArg
  90 \end{code}
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsubsection{The @SimplEnv@ type}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98
  99 \begin{code}
 100 data SimplEnv
 101   = SimplEnv {
 102         seMode      :: SimplifierMode,
 103         seChkr      :: SwitchChecker,
 104         seCC        :: CostCentreStack, -- The enclosing CCS (when profiling)
 105
 106         -- The current set of in-scope variables
 107         -- They are all OutVars, and all bound in this module
 108         seInScope   :: InScopeSet,      -- OutVars only
 109                 -- Includes all variables bound by seFloats
 110         seFloats    :: Floats,
 111                 -- See Note [Simplifier floats]
 112
 113         -- The current substitution
 114         seTvSubst   :: TvSubstEnv,      -- InTyVar |--> OutType
 115         seIdSubst   :: SimplIdSubst     -- InId    |--> OutExpr
 116
 117     }
 118
 119 pprSimplEnv :: SimplEnv -> SDoc
 120 -- Used for debugging; selective
 121 pprSimplEnv env
 122   = vcat [ptext (sLit "TvSubst:") <+> ppr (seTvSubst env),
 123           ptext (sLit "IdSubst:") <+> ppr (seIdSubst env) ]
 124
 125 type SimplIdSubst = IdEnv SimplSR       -- IdId |--> OutExpr
 126         -- See Note [Extending the Subst] in CoreSubst
 127
 128 data SimplSR
 129   = DoneEx OutExpr              -- Completed term
 130   | DoneId OutId                -- Completed term variable
 131   | ContEx TvSubstEnv           -- A suspended substitution
 132            SimplIdSubst
 133            InExpr
 134
 135 instance Outputable SimplSR where
 136   ppr (DoneEx e) = ptext (sLit "DoneEx") <+> ppr e
 137   ppr (DoneId v) = ptext (sLit "DoneId") <+> ppr v
 138   ppr (ContEx _tv _id e) = vcat [ptext (sLit "ContEx") <+> ppr e {-,
 139                                 ppr (filter_env tv), ppr (filter_env id) -}]
 140         -- where
 141         -- fvs = exprFreeVars e
 142         -- filter_env env = filterVarEnv_Directly keep env
 143         -- keep uniq _ = uniq `elemUFM_Directly` fvs
 144 \end{code}
 145
 146
 147 seInScope:
 148         The in-scope part of Subst includes *all* in-scope TyVars and Ids
 149         The elements of the set may have better IdInfo than the
 150         occurrences of in-scope Ids, and (more important) they will
 151         have a correctly-substituted type.  So we use a lookup in this
 152         set to replace occurrences
 153
 154         The Ids in the InScopeSet are replete with their Rules,
 155         and as we gather info about the unfolding of an Id, we replace
 156         it in the in-scope set.
 157
 158         The in-scope set is actually a mapping OutVar -> OutVar, and
 159         in case expressions we sometimes bind
 160
 161 seIdSubst:
 162         The substitution is *apply-once* only, because InIds and OutIds can overlap.
 163         For example, we generally omit mappings
 164                 a77 -> a77
 165         from the substitution, when we decide not to clone a77, but it's quite
 166         legitimate to put the mapping in the substitution anyway.
 167
 168         Furthermore, consider
 169                 let x = case k of I# x77 -> ... in
 170                 let y = case k of I# x77 -> ... in ...
 171         and suppose the body is strict in both x and y.  Then the simplifier
 172         will pull the first (case k) to the top; so the second (case k) will
 173         cancel out, mapping x77 to, well, x77!  But one is an in-Id and the
 174         other is an out-Id.
 175
 176         Of course, the substitution *must* applied! Things in its domain
 177         simply aren't necessarily bound in the result.
 178
 179 * substId adds a binding (DoneId new_id) to the substitution if
 180         the Id's unique has changed
 181
 182
 183   Note, though that the substitution isn't necessarily extended
 184   if the type changes.  Why not?  Because of the next point:
 185
 186 * We *always, always* finish by looking up in the in-scope set
 187   any variable that doesn't get a DoneEx or DoneVar hit in the substitution.
 188   Reason: so that we never finish up with a "old" Id in the result.
 189   An old Id might point to an old unfolding and so on... which gives a space leak.
 190
 191   [The DoneEx and DoneVar hits map to "new" stuff.]
 192
 193 * It follows that substExpr must not do a no-op if the substitution is empty.
 194   substType is free to do so, however.
 195
 196 * When we come to a let-binding (say) we generate new IdInfo, including an
 197   unfolding, attach it to the binder, and add this newly adorned binder to
 198   the in-scope set.  So all subsequent occurrences of the binder will get mapped
 199   to the full-adorned binder, which is also the one put in the binding site.
 200
 201 * The in-scope "set" usually maps x->x; we use it simply for its domain.
 202   But sometimes we have two in-scope Ids that are synomyms, and should
 203   map to the same target:  x->x, y->x.  Notably:
 204         case y of x { ... }
 205   That's why the "set" is actually a VarEnv Var
 206
 207
 208 \begin{code}
 209 mkSimplEnv :: SimplifierMode -> SwitchChecker -> SimplEnv
 210 mkSimplEnv mode switches
 211   = SimplEnv { seChkr = switches, seCC = subsumedCCS,
 212                seMode = mode, seInScope = emptyInScopeSet,
 213                seFloats = emptyFloats,
 214                seTvSubst = emptyVarEnv, seIdSubst = emptyVarEnv }
 215         -- The top level "enclosing CC" is "SUBSUMED".
 216
 217 ---------------------
 218 getSwitchChecker :: SimplEnv -> SwitchChecker
 219 getSwitchChecker env = seChkr env
 220
 221 ---------------------
 222 getMode :: SimplEnv -> SimplifierMode
 223 getMode env = seMode env
 224
 225 setMode :: SimplifierMode -> SimplEnv -> SimplEnv
 226 setMode mode env = env { seMode = mode }
 227
 228 inGentleMode :: SimplEnv -> Bool
 229 inGentleMode env = case seMode env of
 230                         SimplGently -> True
 231                         _other      -> False
 232
 233 ---------------------
 234 getEnclosingCC :: SimplEnv -> CostCentreStack
 235 getEnclosingCC env = seCC env
 236
 237 setEnclosingCC :: SimplEnv -> CostCentreStack -> SimplEnv
 238 setEnclosingCC env cc = env {seCC = cc}
 239
 240 ---------------------
 241 extendIdSubst :: SimplEnv -> Id -> SimplSR -> SimplEnv
 242 extendIdSubst env@(SimplEnv {seIdSubst = subst}) var res
 243   = env {seIdSubst = extendVarEnv subst var res}
 244
 245 extendTvSubst :: SimplEnv -> TyVar -> Type -> SimplEnv
 246 extendTvSubst env@(SimplEnv {seTvSubst = subst}) var res
 247   = env {seTvSubst = extendVarEnv subst var res}
 248
 249 ---------------------
 250 getInScope :: SimplEnv -> InScopeSet
 251 getInScope env = seInScope env
 252
 253 setInScopeSet :: SimplEnv -> InScopeSet -> SimplEnv
 254 setInScopeSet env in_scope = env {seInScope = in_scope}
 255
 256 setInScope :: SimplEnv -> SimplEnv -> SimplEnv
 257 -- Set the in-scope set, and *zap* the floats
 258 setInScope env env_with_scope
 259   = env { seInScope = seInScope env_with_scope,
 260           seFloats = emptyFloats }
 261
 262 setFloats :: SimplEnv -> SimplEnv -> SimplEnv
 263 -- Set the in-scope set *and* the floats
 264 setFloats env env_with_floats
 265   = env { seInScope = seInScope env_with_floats,
 266           seFloats  = seFloats  env_with_floats }
 267
 268 addNewInScopeIds :: SimplEnv -> [CoreBndr] -> SimplEnv
 269         -- The new Ids are guaranteed to be freshly allocated
 270 addNewInScopeIds env@(SimplEnv { seInScope = in_scope, seIdSubst = id_subst }) vs
 271   = env { seInScope = in_scope `extendInScopeSetList` vs,
 272           seIdSubst = id_subst `delVarEnvList` vs }
 273         -- Why delete?  Consider
 274         --      let x = a*b in (x, \x -> x+3)
 275         -- We add [x |-> a*b] to the substitution, but we must
 276         -- _delete_ it from the substitution when going inside
 277         -- the (\x -> ...)!
 278
 279 modifyInScope :: SimplEnv -> CoreBndr -> SimplEnv
 280 -- The variable should already be in scope, but
 281 -- replace the existing version with this new one
 282 -- which has more information
 283 modifyInScope env@(SimplEnv {seInScope = in_scope}) v
 284   = env {seInScope = extendInScopeSet in_scope v}
 285
 286 ---------------------
 287 zapSubstEnv :: SimplEnv -> SimplEnv
 288 zapSubstEnv env = env {seTvSubst = emptyVarEnv, seIdSubst = emptyVarEnv}
 289
 290 setSubstEnv :: SimplEnv -> TvSubstEnv -> SimplIdSubst -> SimplEnv
 291 setSubstEnv env tvs ids = env { seTvSubst = tvs, seIdSubst = ids }
 292
 293 mkContEx :: SimplEnv -> InExpr -> SimplSR
 294 mkContEx (SimplEnv { seTvSubst = tvs, seIdSubst = ids }) e = ContEx tvs ids e
 295 \end{code}
 296
 297
 298
 299 %************************************************************************
 300 %*                                                                      *
 301 \subsection{Floats}
 302 %*                                                                      *
 303 %************************************************************************
 304
 305 Note [Simplifier floats]
 306 ~~~~~~~~~~~~~~~~~~~~~~~~~
 307 The Floats is a bunch of bindings, classified by a FloatFlag.
 308
 309   NonRec x (y:ys)       FltLifted
 310   Rec [(x,rhs)]         FltLifted
 311
 312   NonRec x# (y +# 3)    FltOkSpec       -- Unboxed, but ok-for-spec'n
 313
 314   NonRec x# (a /# b)    FltCareful
 315   NonRec x* (f y)       FltCareful      -- Strict binding; might fail or diverge
 316   NonRec x# (f y)       FltCareful      -- Unboxed binding: might fail or diverge
 317                                         --        (where f :: Int -> Int#)
 318
 319 \begin{code}
 320 data Floats = Floats (OrdList OutBind) FloatFlag
 321         -- See Note [Simplifier floats]
 322
 323 data FloatFlag
 324   = FltLifted   -- All bindings are lifted and lazy
 325                 --  Hence ok to float to top level, or recursive
 326
 327   | FltOkSpec   -- All bindings are FltLifted *or*
 328                 --      strict (perhaps because unlifted,
 329                 --      perhaps because of a strict binder),
 330                 --        *and* ok-for-speculation
 331                 --  Hence ok to float out of the RHS
 332                 --  of a lazy non-recursive let binding
 333                 --  (but not to top level, or into a rec group)
 334
 335   | FltCareful  -- At least one binding is strict (or unlifted)
 336                 --      and not guaranteed cheap
 337                 --      Do not float these bindings out of a lazy let
 338
 339 instance Outputable Floats where
 340   ppr (Floats binds ff) = ppr ff $$ ppr (fromOL binds)
 341
 342 instance Outputable FloatFlag where
 343   ppr FltLifted = ptext (sLit "FltLifted")
 344   ppr FltOkSpec = ptext (sLit "FltOkSpec")
 345   ppr FltCareful = ptext (sLit "FltCareful")
 346
 347 andFF :: FloatFlag -> FloatFlag -> FloatFlag
 348 andFF FltCareful _          = FltCareful
 349 andFF FltOkSpec  FltCareful = FltCareful
 350 andFF FltOkSpec  _          = FltOkSpec
 351 andFF FltLifted  flt        = flt
 352
 353 classifyFF :: CoreBind -> FloatFlag
 354 classifyFF (Rec _) = FltLifted
 355 classifyFF (NonRec bndr rhs)
 356   | not (isStrictId bndr)    = FltLifted
 357   | exprOkForSpeculation rhs = FltOkSpec
 358   | otherwise                = FltCareful
 359
 360 doFloatFromRhs :: TopLevelFlag -> RecFlag -> Bool -> OutExpr -> SimplEnv -> Bool
 361 doFloatFromRhs lvl rec str rhs (SimplEnv {seFloats = Floats fs ff})
 362   =  not (isNilOL fs) && want_to_float && can_float
 363   where
 364      want_to_float = isTopLevel lvl || exprIsExpandable rhs
 365      can_float = case ff of
 366                    FltLifted  -> True
 367                    FltOkSpec  -> isNotTopLevel lvl && isNonRec rec
 368                    FltCareful -> isNotTopLevel lvl && isNonRec rec && str
 369 \end{code}
 370
 371
 372 \begin{code}
 373 emptyFloats :: Floats
 374 emptyFloats = Floats nilOL FltLifted
 375
 376 unitFloat :: OutBind -> Floats
 377 -- A single-binding float
 378 unitFloat bind = Floats (unitOL bind) (classifyFF bind)
 379
 380 addNonRec :: SimplEnv -> OutId -> OutExpr -> SimplEnv
 381 -- Add a non-recursive binding and extend the in-scope set
 382 -- The latter is important; the binder may already be in the
 383 -- in-scope set (although it might also have been created with newId)
 384 -- but it may now have more IdInfo
 385 addNonRec env id rhs
 386   = env { seFloats = seFloats env `addFlts` unitFloat (NonRec id rhs),
 387           seInScope = extendInScopeSet (seInScope env) id }
 388
 389 extendFloats :: SimplEnv -> OutBind -> SimplEnv
 390 -- Add these bindings to the floats, and extend the in-scope env too
 391 extendFloats env bind
 392   = env { seFloats  = seFloats env `addFlts` unitFloat bind,
 393           seInScope = extendInScopeSetList (seInScope env) bndrs }
 394   where
 395     bndrs = bindersOf bind
 396
 397 addFloats :: SimplEnv -> SimplEnv -> SimplEnv
 398 -- Add the floats for env2 to env1;
 399 -- *plus* the in-scope set for env2, which is bigger
 400 -- than that for env1
 401 addFloats env1 env2
 402   = env1 {seFloats = seFloats env1 `addFlts` seFloats env2,
 403           seInScope = seInScope env2 }
 404
 405 addFlts :: Floats -> Floats -> Floats
 406 addFlts (Floats bs1 l1) (Floats bs2 l2)
 407   = Floats (bs1 `appOL` bs2) (l1 `andFF` l2)
 408
 409 zapFloats :: SimplEnv -> SimplEnv
 410 zapFloats env = env { seFloats = emptyFloats }
 411
 412 addRecFloats :: SimplEnv -> SimplEnv -> SimplEnv
 413 -- Flattens the floats from env2 into a single Rec group,
 414 -- prepends the floats from env1, and puts the result back in env2
 415 -- This is all very specific to the way recursive bindings are
 416 -- handled; see Simplify.simplRecBind
 417 addRecFloats env1 env2@(SimplEnv {seFloats = Floats bs ff})
 418   = ASSERT2( case ff of { FltLifted -> True; _ -> False }, ppr (fromOL bs) )
 419     env2 {seFloats = seFloats env1 `addFlts` unitFloat (Rec (flattenBinds (fromOL bs)))}
 420
 421 wrapFloats :: SimplEnv -> OutExpr -> OutExpr
 422 wrapFloats env expr = wrapFlts (seFloats env) expr
 423
 424 wrapFlts :: Floats -> OutExpr -> OutExpr
 425 -- Wrap the floats around the expression, using case-binding where necessary
 426 wrapFlts (Floats bs _) body = foldrOL wrap body bs
 427   where
 428     wrap (Rec prs)    body = Let (Rec prs) body
 429     wrap (NonRec b r) body = bindNonRec b r body
 430
 431 getFloats :: SimplEnv -> [CoreBind]
 432 getFloats (SimplEnv {seFloats = Floats bs _}) = fromOL bs
 433
 434 isEmptyFloats :: SimplEnv -> Bool
 435 isEmptyFloats env = isEmptyFlts (seFloats env)
 436
 437 isEmptyFlts :: Floats -> Bool
 438 isEmptyFlts (Floats bs _) = isNilOL bs
 439
 440 floatBinds :: Floats -> [OutBind]
 441 floatBinds (Floats bs _) = fromOL bs
 442 \end{code}
 443
 444
 445 %************************************************************************
 446 %*                                                                      *
 447                 Substitution of Vars
 448 %*                                                                      *
 449 %************************************************************************
 450
 451 Note [Global Ids in the substitution]
 452 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 453 We look up even a global (eg imported) Id in the substitution. Consider
 454    case X.g_34 of b { (a,b) ->  ... case X.g_34 of { (p,q) -> ...} ... }
 455 The binder-swap in the occurence analyser will add a binding
 456 for a LocalId version of g (with the same unique though):
 457    case X.g_34 of b { (a,b) ->  let g_34 = b in
 458                                 ... case X.g_34 of { (p,q) -> ...} ... }
 459 So we want to look up the inner X.g_34 in the substitution, where we'll
 460 find that it has been substituted by b.  (Or conceivably cloned.)
 461
 462 \begin{code}
 463 substId :: SimplEnv -> InId -> SimplSR
 464 -- Returns DoneEx only on a non-Var expression
 465 substId (SimplEnv { seInScope = in_scope, seIdSubst = ids }) v
 466   = case lookupVarEnv ids v of          -- Note [Global Ids in the substitution]
 467         Nothing               -> DoneId (refine in_scope v)
 468         Just (DoneId v)       -> DoneId (refine in_scope v)
 469         Just (DoneEx (Var v)) -> DoneId (refine in_scope v)
 470         Just res              -> res    -- DoneEx non-var, or ContEx
 471   where
 472
 473         -- Get the most up-to-date thing from the in-scope set
 474         -- Even though it isn't in the substitution, it may be in
 475         -- the in-scope set with better IdInfo
 476 refine :: InScopeSet -> Var -> Var
 477 refine in_scope v
 478   | isLocalId v = case lookupInScope in_scope v of
 479                          Just v' -> v'
 480                          Nothing -> WARN( True, ppr v ) v       -- This is an error!
 481   | otherwise = v
 482
 483 lookupRecBndr :: SimplEnv -> InId -> OutId
 484 -- Look up an Id which has been put into the envt by simplRecBndrs,
 485 -- but where we have not yet done its RHS
 486 lookupRecBndr (SimplEnv { seInScope = in_scope, seIdSubst = ids }) v
 487   = case lookupVarEnv ids v of
 488         Just (DoneId v) -> v
 489         Just _ -> pprPanic "lookupRecBndr" (ppr v)
 490         Nothing -> refine in_scope v
 491 \end{code}
 492
 493
 494 %************************************************************************
 495 %*                                                                      *
 496 \section{Substituting an Id binder}
 497 %*                                                                      *
 498 %************************************************************************
 499
 500
 501 These functions are in the monad only so that they can be made strict via seq.
 502
 503 \begin{code}
 504 simplBinders, simplLamBndrs
 505         :: SimplEnv -> [InBndr] -> SimplM (SimplEnv, [OutBndr])
 506 simplBinders  env bndrs = mapAccumLM simplBinder  env bndrs
 507 simplLamBndrs env bndrs = mapAccumLM simplLamBndr env bndrs
 508
 509 -------------
 510 simplBinder :: SimplEnv -> InBndr -> SimplM (SimplEnv, OutBndr)
 511 -- Used for lambda and case-bound variables
 512 -- Clone Id if necessary, substitute type
 513 -- Return with IdInfo already substituted, but (fragile) occurrence info zapped
 514 -- The substitution is extended only if the variable is cloned, because
 515 -- we *don't* need to use it to track occurrence info.
 516 simplBinder env bndr
 517   | isTyVar bndr  = do  { let (env', tv) = substTyVarBndr env bndr
 518                         ; seqTyVar tv `seq` return (env', tv) }
 519   | otherwise     = do  { let (env', id) = substIdBndr env bndr
 520                         ; seqId id `seq` return (env', id) }
 521
 522 -------------
 523 simplLamBndr :: SimplEnv -> Var -> SimplM (SimplEnv, Var)
 524 -- Used for lambda binders.  These sometimes have unfoldings added by
 525 -- the worker/wrapper pass that must be preserved, because they can't
 526 -- be reconstructed from context.  For example:
 527 --      f x = case x of (a,b) -> fw a b x
 528 --      fw a b x{=(a,b)} = ...
 529 -- The "{=(a,b)}" is an unfolding we can't reconstruct otherwise.
 530 simplLamBndr env bndr
 531   | isId bndr && hasSomeUnfolding old_unf = seqId id2 `seq` return (env2, id2)  -- Special case
 532   | otherwise                             = simplBinder env bndr                -- Normal case
 533   where
 534     old_unf = idUnfolding bndr
 535     (env1, id1) = substIdBndr env bndr
 536     id2  = id1 `setIdUnfolding` substUnfolding env old_unf
 537     env2 = modifyInScope env1 id2
 538
 539 ---------------
 540 simplNonRecBndr :: SimplEnv -> InBndr -> SimplM (SimplEnv, OutBndr)
 541 -- A non-recursive let binder
 542 simplNonRecBndr env id
 543   = do  { let (env1, id1) = substIdBndr env id
 544         ; seqId id1 `seq` return (env1, id1) }
 545
 546 ---------------
 547 simplRecBndrs :: SimplEnv -> [InBndr] -> SimplM SimplEnv
 548 -- Recursive let binders
 549 simplRecBndrs env@(SimplEnv {}) ids
 550   = do  { let (env1, ids1) = mapAccumL substIdBndr env ids
 551         ; seqIds ids1 `seq` return env1 }
 552
 553 ---------------
 554 substIdBndr :: SimplEnv
 555             -> InBndr   -- Env and binder to transform
 556             -> (SimplEnv, OutBndr)
 557 -- Clone Id if necessary, substitute its type
 558 -- Return an Id with its
 559 --      * Type substituted
 560 --      * UnfoldingInfo, Rules, WorkerInfo zapped
 561 --      * Fragile OccInfo (only) zapped: Note [Robust OccInfo]
 562 --      * Robust info, retained especially arity and demand info,
 563 --         so that they are available to occurrences that occur in an
 564 --         earlier binding of a letrec
 565 --
 566 -- For the robust info, see Note [Arity robustness]
 567 --
 568 -- Augment the substitution  if the unique changed
 569 -- Extend the in-scope set with the new Id
 570 --
 571 -- Similar to CoreSubst.substIdBndr, except that
 572 --      the type of id_subst differs
 573 --      all fragile info is zapped
 574
 575 substIdBndr env@(SimplEnv { seInScope = in_scope, seIdSubst = id_subst })
 576                old_id
 577   = (env { seInScope = in_scope `extendInScopeSet` new_id,
 578            seIdSubst = new_subst }, new_id)
 579   where
 580     id1    = uniqAway in_scope old_id
 581     id2    = substIdType env id1
 582     new_id = zapFragileIdInfo id2       -- Zaps rules, worker-info, unfolding
 583                                         -- and fragile OccInfo
 584
 585         -- Extend the substitution if the unique has changed,
 586         -- or there's some useful occurrence information
 587         -- See the notes with substTyVarBndr for the delSubstEnv
 588     new_subst | new_id /= old_id
 589               = extendVarEnv id_subst old_id (DoneId new_id)
 590               | otherwise
 591               = delVarEnv id_subst old_id
 592 \end{code}
 593
 594 \begin{code}
 595 ------------------------------------
 596 seqTyVar :: TyVar -> ()
 597 seqTyVar b = b `seq` ()
 598
 599 seqId :: Id -> ()
 600 seqId id = seqType (idType id)  `seq`
 601            idInfo id            `seq`
 602            ()
 603
 604 seqIds :: [Id] -> ()
 605 seqIds []       = ()
 606 seqIds (id:ids) = seqId id `seq` seqIds ids
 607 \end{code}
 608
 609
 610 Note [Arity robustness]
 611 ~~~~~~~~~~~~~~~~~~~~~~~
 612 We *do* transfer the arity from from the in_id of a let binding to the
 613 out_id.  This is important, so that the arity of an Id is visible in
 614 its own RHS.  For example:
 615         f = \x. ....g (\y. f y)....
 616 We can eta-reduce the arg to g, becuase f is a value.  But that
 617 needs to be visible.
 618
 619 This interacts with the 'state hack' too:
 620         f :: Bool -> IO Int
 621         f = \x. case x of
 622                   True  -> f y
 623                   False -> \s -> ...
 624 Can we eta-expand f?  Only if we see that f has arity 1, and then we
 625 take advantage of the 'state hack' on the result of
 626 (f y) :: State# -> (State#, Int) to expand the arity one more.
 627
 628 There is a disadvantage though.  Making the arity visible in the RHS
 629 allows us to eta-reduce
 630         f = \x -> f x
 631 to
 632         f = f
 633 which technically is not sound.   This is very much a corner case, so
 634 I'm not worried about it.  Another idea is to ensure that f's arity
 635 never decreases; its arity started as 1, and we should never eta-reduce
 636 below that.
 637
 638
 639 Note [Robust OccInfo]
 640 ~~~~~~~~~~~~~~~~~~~~~
 641 It's important that we *do* retain the loop-breaker OccInfo, because
 642 that's what stops the Id getting inlined infinitely, in the body of
 643 the letrec.
 644
 645
 646 Note [Rules in a letrec]
 647 ~~~~~~~~~~~~~~~~~~~~~~~~
 648 After creating fresh binders for the binders of a letrec, we
 649 substitute the RULES and add them back onto the binders; this is done
 650 *before* processing any of the RHSs.  This is important.  Manuel found
 651 cases where he really, really wanted a RULE for a recursive function
 652 to apply in that function's own right-hand side.
 653
 654 See Note [Loop breaking and RULES] in OccAnal.
 655
 656
 657 \begin{code}
 658 addBndrRules :: SimplEnv -> InBndr -> OutBndr -> (SimplEnv, OutBndr)
 659 -- Rules are added back in to to the bin
 660 addBndrRules env in_id out_id
 661   | isEmptySpecInfo old_rules = (env, out_id)
 662   | otherwise = (modifyInScope env final_id, final_id)
 663   where
 664     subst     = mkCoreSubst env
 665     old_rules = idSpecialisation in_id
 666     new_rules = CoreSubst.substSpec subst out_id old_rules
 667     final_id  = out_id `setIdSpecialisation` new_rules
 668 \end{code}
 669
 670
 671 %************************************************************************
 672 %*                                                                      *
 673                 Impedence matching to type substitution
 674 %*                                                                      *
 675 %************************************************************************
 676
 677 \begin{code}
 678 substTy :: SimplEnv -> Type -> Type
 679 substTy (SimplEnv { seInScope = in_scope, seTvSubst = tv_env }) ty
 680   = Type.substTy (TvSubst in_scope tv_env) ty
 681
 682 substTyVarBndr :: SimplEnv -> TyVar -> (SimplEnv, TyVar)
 683 substTyVarBndr env@(SimplEnv { seInScope = in_scope, seTvSubst = tv_env }) tv
 684   = case Type.substTyVarBndr (TvSubst in_scope tv_env) tv of
 685         (TvSubst in_scope' tv_env', tv')
 686            -> (env { seInScope = in_scope', seTvSubst = tv_env'}, tv')
 687
 688 -- When substituting in rules etc we can get CoreSubst to do the work
 689 -- But CoreSubst uses a simpler form of IdSubstEnv, so we must impedence-match
 690 -- here.  I think the this will not usually result in a lot of work;
 691 -- the substitutions are typically small, and laziness will avoid work in many cases.
 692
 693 mkCoreSubst  :: SimplEnv -> CoreSubst.Subst
 694 mkCoreSubst (SimplEnv { seInScope = in_scope, seTvSubst = tv_env, seIdSubst = id_env })
 695   = mk_subst tv_env id_env
 696   where
 697     mk_subst tv_env id_env = CoreSubst.mkSubst in_scope tv_env (mapVarEnv fiddle id_env)
 698
 699     fiddle (DoneEx e)       = e
 700     fiddle (DoneId v)       = Var v
 701     fiddle (ContEx tv id e) = CoreSubst.substExpr (mk_subst tv id) e
 702
 703 ------------------
 704 substIdType :: SimplEnv -> Id -> Id
 705 substIdType (SimplEnv { seInScope = in_scope,  seTvSubst = tv_env}) id
 706   | isEmptyVarEnv tv_env || isEmptyVarSet (tyVarsOfType old_ty) = id
 707   | otherwise   = Id.setIdType id (Type.substTy (TvSubst in_scope tv_env) old_ty)
 708                 -- The tyVarsOfType is cheaper than it looks
 709                 -- because we cache the free tyvars of the type
 710                 -- in a Note in the id's type itself
 711   where
 712     old_ty = idType id
 713
 714 ------------------
 715 substExpr :: SimplEnv -> CoreExpr -> CoreExpr
 716 substExpr env expr = CoreSubst.substExpr (mkCoreSubst env) expr
 717   -- Do *not* short-cut in the case of an empty substitution
 718   -- See CoreSubst: Note [Extending the Subst]
 719
 720 substUnfolding :: SimplEnv -> Unfolding -> Unfolding
 721 substUnfolding env unf = CoreSubst.substUnfolding (mkCoreSubst env) unf
 722 \end{code}
 723