compiler/simplCore/SimplEnv.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplMonad]{The simplifier Monad}
   5
   6 \begin{code}
   7 {-# OPTIONS -w #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  12 -- for details
  13
  14 module SimplEnv (
  15         InId, InBind, InExpr, InAlt, InArg, InType, InBndr,
  16         OutId, OutTyVar, OutBind, OutExpr, OutAlt, OutArg, OutType, OutBndr,
  17         InCoercion, OutCoercion,
  18
  19         -- The simplifier mode
  20         setMode, getMode,
  21
  22         -- Switch checker
  23         SwitchChecker, SwitchResult(..), getSwitchChecker, getSimplIntSwitch,
  24         isAmongSimpl, intSwitchSet, switchIsOn,
  25
  26         setEnclosingCC, getEnclosingCC,
  27
  28         -- Environments
  29         SimplEnv(..), pprSimplEnv,      -- Temp not abstract
  30         mkSimplEnv, extendIdSubst, SimplEnv.extendTvSubst,
  31         zapSubstEnv, setSubstEnv,
  32         getInScope, setInScope, setInScopeSet, modifyInScope, addNewInScopeIds,
  33         getRules,
  34
  35         SimplSR(..), mkContEx, substId, lookupRecBndr,
  36
  37         simplNonRecBndr, simplRecBndrs, simplLamBndr, simplLamBndrs,
  38         simplBinder, simplBinders, addBndrRules,
  39         substExpr, substWorker, substTy,
  40
  41         -- Floats
  42         Floats, emptyFloats, isEmptyFloats, addNonRec, addFloats, extendFloats,
  43         wrapFloats, floatBinds, setFloats, zapFloats, addRecFloats,
  44         doFloatFromRhs, getFloats
  45     ) where
  46
  47 #include "HsVersions.h"
  48
  49 import SimplMonad
  50 import IdInfo
  51 import CoreSyn
  52 import Rules
  53 import CoreUtils
  54 import CostCentre
  55 import Var
  56 import VarEnv
  57 import VarSet
  58 import OrdList
  59 import Id
  60 import qualified CoreSubst      ( Subst, mkSubst, substExpr, substSpec, substWorker )
  61 import qualified Type           ( substTy, substTyVarBndr )
  62 import Type hiding              ( substTy, substTyVarBndr )
  63 import Coercion
  64 import BasicTypes
  65 import DynFlags
  66 import Util
  67 import Outputable
  68
  69 import Data.List
  70 \end{code}
  71
  72 %************************************************************************
  73 %*                                                                      *
  74 \subsection[Simplify-types]{Type declarations}
  75 %*                                                                      *
  76 %************************************************************************
  77
  78 \begin{code}
  79 type InBndr     = CoreBndr
  80 type InId       = Id                    -- Not yet cloned
  81 type InType     = Type                  -- Ditto
  82 type InBind     = CoreBind
  83 type InExpr     = CoreExpr
  84 type InAlt      = CoreAlt
  85 type InArg      = CoreArg
  86 type InCoercion = Coercion
  87
  88 type OutBndr     = CoreBndr
  89 type OutId       = Id                   -- Cloned
  90 type OutTyVar    = TyVar                -- Cloned
  91 type OutType     = Type                 -- Cloned
  92 type OutCoercion = Coercion
  93 type OutBind     = CoreBind
  94 type OutExpr     = CoreExpr
  95 type OutAlt      = CoreAlt
  96 type OutArg      = CoreArg
  97 \end{code}
  98
  99 %************************************************************************
 100 %*                                                                      *
 101 \subsubsection{The @SimplEnv@ type}
 102 %*                                                                      *
 103 %************************************************************************
 104
 105
 106 \begin{code}
 107 data SimplEnv
 108   = SimplEnv {
 109         seMode      :: SimplifierMode,
 110         seChkr      :: SwitchChecker,
 111         seCC        :: CostCentreStack, -- The enclosing CCS (when profiling)
 112
 113         -- The current set of in-scope variables
 114         -- They are all OutVars, and all bound in this module
 115         seInScope   :: InScopeSet,      -- OutVars only
 116                 -- Includes all variables bound by seFloats
 117         seFloats    :: Floats,
 118                 -- See Note [Simplifier floats]
 119
 120         -- The current substitution
 121         seTvSubst   :: TvSubstEnv,      -- InTyVar |--> OutType
 122         seIdSubst   :: SimplIdSubst     -- InId    |--> OutExpr
 123
 124     }
 125
 126 pprSimplEnv :: SimplEnv -> SDoc
 127 -- Used for debugging; selective
 128 pprSimplEnv env
 129   = vcat [ptext SLIT("TvSubst:") <+> ppr (seTvSubst env),
 130           ptext SLIT("IdSubst:") <+> ppr (seIdSubst env) ]
 131
 132 type SimplIdSubst = IdEnv SimplSR       -- IdId |--> OutExpr
 133         -- See Note [Extending the Subst] in CoreSubst
 134
 135 data SimplSR
 136   = DoneEx OutExpr              -- Completed term
 137   | DoneId OutId                -- Completed term variable
 138   | ContEx TvSubstEnv           -- A suspended substitution
 139            SimplIdSubst
 140            InExpr
 141
 142 instance Outputable SimplSR where
 143   ppr (DoneEx e) = ptext SLIT("DoneEx") <+> ppr e
 144   ppr (DoneId v) = ptext SLIT("DoneId") <+> ppr v
 145   ppr (ContEx tv id e) = vcat [ptext SLIT("ContEx") <+> ppr e {-,
 146                                 ppr (filter_env tv), ppr (filter_env id) -}]
 147         -- where
 148         -- fvs = exprFreeVars e
 149         -- filter_env env = filterVarEnv_Directly keep env
 150         -- keep uniq _ = uniq `elemUFM_Directly` fvs
 151 \end{code}
 152
 153
 154 seInScope:
 155         The in-scope part of Subst includes *all* in-scope TyVars and Ids
 156         The elements of the set may have better IdInfo than the
 157         occurrences of in-scope Ids, and (more important) they will
 158         have a correctly-substituted type.  So we use a lookup in this
 159         set to replace occurrences
 160
 161         The Ids in the InScopeSet are replete with their Rules,
 162         and as we gather info about the unfolding of an Id, we replace
 163         it in the in-scope set.
 164
 165         The in-scope set is actually a mapping OutVar -> OutVar, and
 166         in case expressions we sometimes bind
 167
 168 seIdSubst:
 169         The substitution is *apply-once* only, because InIds and OutIds can overlap.
 170         For example, we generally omit mappings
 171                 a77 -> a77
 172         from the substitution, when we decide not to clone a77, but it's quite
 173         legitimate to put the mapping in the substitution anyway.
 174
 175         Furthermore, consider
 176                 let x = case k of I# x77 -> ... in
 177                 let y = case k of I# x77 -> ... in ...
 178         and suppose the body is strict in both x and y.  Then the simplifier
 179         will pull the first (case k) to the top; so the second (case k) will
 180         cancel out, mapping x77 to, well, x77!  But one is an in-Id and the
 181         other is an out-Id.
 182
 183         Of course, the substitution *must* applied! Things in its domain
 184         simply aren't necessarily bound in the result.
 185
 186 * substId adds a binding (DoneId new_id) to the substitution if
 187         the Id's unique has changed
 188
 189
 190   Note, though that the substitution isn't necessarily extended
 191   if the type changes.  Why not?  Because of the next point:
 192
 193 * We *always, always* finish by looking up in the in-scope set
 194   any variable that doesn't get a DoneEx or DoneVar hit in the substitution.
 195   Reason: so that we never finish up with a "old" Id in the result.
 196   An old Id might point to an old unfolding and so on... which gives a space leak.
 197
 198   [The DoneEx and DoneVar hits map to "new" stuff.]
 199
 200 * It follows that substExpr must not do a no-op if the substitution is empty.
 201   substType is free to do so, however.
 202
 203 * When we come to a let-binding (say) we generate new IdInfo, including an
 204   unfolding, attach it to the binder, and add this newly adorned binder to
 205   the in-scope set.  So all subsequent occurrences of the binder will get mapped
 206   to the full-adorned binder, which is also the one put in the binding site.
 207
 208 * The in-scope "set" usually maps x->x; we use it simply for its domain.
 209   But sometimes we have two in-scope Ids that are synomyms, and should
 210   map to the same target:  x->x, y->x.  Notably:
 211         case y of x { ... }
 212   That's why the "set" is actually a VarEnv Var
 213
 214
 215 \begin{code}
 216 mkSimplEnv :: SimplifierMode -> SwitchChecker -> SimplEnv
 217 mkSimplEnv mode switches
 218   = SimplEnv { seChkr = switches, seCC = subsumedCCS,
 219                seMode = mode, seInScope = emptyInScopeSet,
 220                seFloats = emptyFloats,
 221                seTvSubst = emptyVarEnv, seIdSubst = emptyVarEnv }
 222         -- The top level "enclosing CC" is "SUBSUMED".
 223
 224 ---------------------
 225 getSwitchChecker :: SimplEnv -> SwitchChecker
 226 getSwitchChecker env = seChkr env
 227
 228 ---------------------
 229 getMode :: SimplEnv -> SimplifierMode
 230 getMode env = seMode env
 231
 232 setMode :: SimplifierMode -> SimplEnv -> SimplEnv
 233 setMode mode env = env { seMode = mode }
 234
 235 ---------------------
 236 getEnclosingCC :: SimplEnv -> CostCentreStack
 237 getEnclosingCC env = seCC env
 238
 239 setEnclosingCC :: SimplEnv -> CostCentreStack -> SimplEnv
 240 setEnclosingCC env cc = env {seCC = cc}
 241
 242 ---------------------
 243 extendIdSubst :: SimplEnv -> Id -> SimplSR -> SimplEnv
 244 extendIdSubst env@(SimplEnv {seIdSubst = subst}) var res
 245   = env {seIdSubst = extendVarEnv subst var res}
 246
 247 extendTvSubst :: SimplEnv -> TyVar -> Type -> SimplEnv
 248 extendTvSubst env@(SimplEnv {seTvSubst = subst}) var res
 249   = env {seTvSubst = extendVarEnv subst var res}
 250
 251 ---------------------
 252 getInScope :: SimplEnv -> InScopeSet
 253 getInScope env = seInScope env
 254
 255 setInScopeSet :: SimplEnv -> InScopeSet -> SimplEnv
 256 setInScopeSet env in_scope = env {seInScope = in_scope}
 257
 258 setInScope :: SimplEnv -> SimplEnv -> SimplEnv
 259 -- Set the in-scope set, and *zap* the floats
 260 setInScope env env_with_scope
 261   = env { seInScope = seInScope env_with_scope,
 262           seFloats = emptyFloats }
 263
 264 setFloats :: SimplEnv -> SimplEnv -> SimplEnv
 265 -- Set the in-scope set *and* the floats
 266 setFloats env env_with_floats
 267   = env { seInScope = seInScope env_with_floats,
 268           seFloats  = seFloats  env_with_floats }
 269
 270 addNewInScopeIds :: SimplEnv -> [CoreBndr] -> SimplEnv
 271         -- The new Ids are guaranteed to be freshly allocated
 272 addNewInScopeIds env@(SimplEnv { seInScope = in_scope, seIdSubst = id_subst }) vs
 273   = env { seInScope = in_scope `extendInScopeSetList` vs,
 274           seIdSubst = id_subst `delVarEnvList` vs }
 275         -- Why delete?  Consider
 276         --      let x = a*b in (x, \x -> x+3)
 277         -- We add [x |-> a*b] to the substitution, but we must
 278         -- *delete* it from the substitution when going inside
 279         -- the (\x -> ...)!
 280
 281 modifyInScope :: SimplEnv -> CoreBndr -> CoreBndr -> SimplEnv
 282 modifyInScope env@(SimplEnv {seInScope = in_scope}) v v'
 283   = env {seInScope = modifyInScopeSet in_scope v v'}
 284
 285 ---------------------
 286 zapSubstEnv :: SimplEnv -> SimplEnv
 287 zapSubstEnv env = env {seTvSubst = emptyVarEnv, seIdSubst = emptyVarEnv}
 288
 289 setSubstEnv :: SimplEnv -> TvSubstEnv -> SimplIdSubst -> SimplEnv
 290 setSubstEnv env tvs ids = env { seTvSubst = tvs, seIdSubst = ids }
 291
 292 mkContEx :: SimplEnv -> InExpr -> SimplSR
 293 mkContEx (SimplEnv { seTvSubst = tvs, seIdSubst = ids }) e = ContEx tvs ids e
 294
 295 isEmptySimplSubst :: SimplEnv -> Bool
 296 isEmptySimplSubst (SimplEnv { seTvSubst = tvs, seIdSubst = ids })
 297   = isEmptyVarEnv tvs && isEmptyVarEnv ids
 298 \end{code}
 299
 300
 301
 302 %************************************************************************
 303 %*                                                                      *
 304 \subsection{Floats}
 305 %*                                                                      *
 306 %************************************************************************
 307
 308 Note [Simplifier floats]
 309 ~~~~~~~~~~~~~~~~~~~~~~~~~
 310 The Floats is a bunch of bindings, classified by a FloatFlag.
 311
 312   NonRec x (y:ys)       FltLifted
 313   Rec [(x,rhs)]         FltLifted
 314
 315   NonRec x# (y +# 3)    FltOkSpec       -- Unboxed, but ok-for-spec'n
 316
 317   NonRec x# (a /# b)    FltCareful
 318   NonRec x* (f y)       FltCareful      -- Strict binding; might fail or diverge
 319   NonRec x# (f y)       FltCareful      -- Unboxed binding: might fail or diverge
 320                                         --        (where f :: Int -> Int#)
 321
 322 \begin{code}
 323 data Floats = Floats (OrdList OutBind) FloatFlag
 324         -- See Note [Simplifier floats]
 325
 326 data FloatFlag
 327   = FltLifted   -- All bindings are lifted and lazy
 328                 --  Hence ok to float to top level, or recursive
 329
 330   | FltOkSpec   -- All bindings are FltLifted *or*
 331                 --      strict (perhaps because unlifted,
 332                 --      perhaps because of a strict binder),
 333                 --        *and* ok-for-speculation
 334                 --  Hence ok to float out of the RHS
 335                 --  of a lazy non-recursive let binding
 336                 --  (but not to top level, or into a rec group)
 337
 338   | FltCareful  -- At least one binding is strict (or unlifted)
 339                 --      and not guaranteed cheap
 340                 --      Do not float these bindings out of a lazy let
 341
 342 instance Outputable Floats where
 343   ppr (Floats binds ff) = ppr ff $$ ppr (fromOL binds)
 344
 345 instance Outputable FloatFlag where
 346   ppr FltLifted = ptext SLIT("FltLifted")
 347   ppr FltOkSpec = ptext SLIT("FltOkSpec")
 348   ppr FltCareful = ptext SLIT("FltCareful")
 349
 350 andFF :: FloatFlag -> FloatFlag -> FloatFlag
 351 andFF FltCareful _          = FltCareful
 352 andFF FltOkSpec  FltCareful = FltCareful
 353 andFF FltOkSpec  flt        = FltOkSpec
 354 andFF FltLifted  flt        = flt
 355
 356 classifyFF :: CoreBind -> FloatFlag
 357 classifyFF (Rec _) = FltLifted
 358 classifyFF (NonRec bndr rhs)
 359   | not (isStrictId bndr)    = FltLifted
 360   | exprOkForSpeculation rhs = FltOkSpec
 361   | otherwise                = FltCareful
 362
 363 doFloatFromRhs :: TopLevelFlag -> RecFlag -> Bool -> OutExpr -> SimplEnv -> Bool
 364 doFloatFromRhs lvl rec str rhs (SimplEnv {seFloats = Floats fs ff})
 365   =  not (isNilOL fs) && want_to_float && can_float
 366   where
 367      want_to_float = isTopLevel lvl || exprIsCheap rhs
 368      can_float = case ff of
 369                    FltLifted  -> True
 370                    FltOkSpec  -> isNotTopLevel lvl && isNonRec rec
 371                    FltCareful -> isNotTopLevel lvl && isNonRec rec && str
 372 \end{code}
 373
 374
 375 \begin{code}
 376 emptyFloats :: Floats
 377 emptyFloats = Floats nilOL FltLifted
 378
 379 unitFloat :: OutBind -> Floats
 380 -- A single-binding float
 381 unitFloat bind = Floats (unitOL bind) (classifyFF bind)
 382
 383 addNonRec :: SimplEnv -> OutId -> OutExpr -> SimplEnv
 384 -- Add a non-recursive binding and extend the in-scope set
 385 -- The latter is important; the binder may already be in the
 386 -- in-scope set (although it might also have been created with newId)
 387 -- but it may now have more IdInfo
 388 addNonRec env id rhs
 389   = env { seFloats = seFloats env `addFlts` unitFloat (NonRec id rhs),
 390           seInScope = extendInScopeSet (seInScope env) id }
 391
 392 extendFloats :: SimplEnv -> [OutBind] -> SimplEnv
 393 -- Add these bindings to the floats, and extend the in-scope env too
 394 extendFloats env binds
 395   = env { seFloats  = seFloats env `addFlts` new_floats,
 396           seInScope = extendInScopeSetList (seInScope env) bndrs }
 397   where
 398     bndrs = bindersOfBinds binds
 399     new_floats = Floats (toOL binds)
 400                         (foldr (andFF . classifyFF) FltLifted binds)
 401
 402 addFloats :: SimplEnv -> SimplEnv -> SimplEnv
 403 -- Add the floats for env2 to env1;
 404 -- *plus* the in-scope set for env2, which is bigger
 405 -- than that for env1
 406 addFloats env1 env2
 407   = env1 {seFloats = seFloats env1 `addFlts` seFloats env2,
 408           seInScope = seInScope env2 }
 409
 410 addFlts :: Floats -> Floats -> Floats
 411 addFlts (Floats bs1 l1) (Floats bs2 l2)
 412   = Floats (bs1 `appOL` bs2) (l1 `andFF` l2)
 413
 414 zapFloats :: SimplEnv -> SimplEnv
 415 zapFloats env = env { seFloats = emptyFloats }
 416
 417 addRecFloats :: SimplEnv -> SimplEnv -> SimplEnv
 418 -- Flattens the floats from env2 into a single Rec group,
 419 -- prepends the floats from env1, and puts the result back in env2
 420 -- This is all very specific to the way recursive bindings are
 421 -- handled; see Simplify.simplRecBind
 422 addRecFloats env1 env2@(SimplEnv {seFloats = Floats bs ff})
 423   = ASSERT2( case ff of { FltLifted -> True; other -> False }, ppr (fromOL bs) )
 424     env2 {seFloats = seFloats env1 `addFlts` unitFloat (Rec (flattenBinds (fromOL bs)))}
 425
 426 wrapFloats :: SimplEnv -> OutExpr -> OutExpr
 427 wrapFloats env expr = wrapFlts (seFloats env) expr
 428
 429 wrapFlts :: Floats -> OutExpr -> OutExpr
 430 -- Wrap the floats around the expression, using case-binding where necessary
 431 wrapFlts (Floats bs _) body = foldrOL wrap body bs
 432   where
 433     wrap (Rec prs)    body = Let (Rec prs) body
 434     wrap (NonRec b r) body = bindNonRec b r body
 435
 436 getFloats :: SimplEnv -> [CoreBind]
 437 getFloats (SimplEnv {seFloats = Floats bs _}) = fromOL bs
 438
 439 isEmptyFloats :: SimplEnv -> Bool
 440 isEmptyFloats env = isEmptyFlts (seFloats env)
 441
 442 isEmptyFlts :: Floats -> Bool
 443 isEmptyFlts (Floats bs _) = isNilOL bs
 444
 445 floatBinds :: Floats -> [OutBind]
 446 floatBinds (Floats bs _) = fromOL bs
 447 \end{code}
 448
 449
 450 %************************************************************************
 451 %*                                                                      *
 452                 Substitution of Vars
 453 %*                                                                      *
 454 %************************************************************************
 455
 456
 457 \begin{code}
 458 substId :: SimplEnv -> Id -> SimplSR
 459 substId (SimplEnv { seInScope = in_scope, seIdSubst = ids }) v
 460   | not (isLocalId v)
 461   = DoneId v
 462   | otherwise   -- A local Id
 463   = case lookupVarEnv ids v of
 464         Just (DoneId v) -> DoneId (refine in_scope v)
 465         Just res        -> res
 466         Nothing         -> DoneId (refine in_scope v)
 467   where
 468
 469         -- Get the most up-to-date thing from the in-scope set
 470         -- Even though it isn't in the substitution, it may be in
 471         -- the in-scope set with better IdInfo
 472 refine in_scope v = case lookupInScope in_scope v of
 473                          Just v' -> v'
 474                          Nothing -> WARN( True, ppr v ) v       -- This is an error!
 475
 476 lookupRecBndr :: SimplEnv -> Id -> Id
 477 -- Look up an Id which has been put into the envt by simplRecBndrs,
 478 -- but where we have not yet done its RHS
 479 lookupRecBndr (SimplEnv { seInScope = in_scope, seIdSubst = ids }) v
 480   = case lookupVarEnv ids v of
 481         Just (DoneId v) -> v
 482         Just res        -> pprPanic "lookupRecBndr" (ppr v)
 483         Nothing         -> refine in_scope v
 484 \end{code}
 485
 486
 487 %************************************************************************
 488 %*                                                                      *
 489 \section{Substituting an Id binder}
 490 %*                                                                      *
 491 %************************************************************************
 492
 493
 494 These functions are in the monad only so that they can be made strict via seq.
 495
 496 \begin{code}
 497 simplBinders, simplLamBndrs
 498         :: SimplEnv -> [InBndr] -> SimplM (SimplEnv, [OutBndr])
 499 simplBinders  env bndrs = mapAccumLSmpl simplBinder  env bndrs
 500 simplLamBndrs env bndrs = mapAccumLSmpl simplLamBndr env bndrs
 501
 502 -------------
 503 simplBinder :: SimplEnv -> InBndr -> SimplM (SimplEnv, OutBndr)
 504 -- Used for lambda and case-bound variables
 505 -- Clone Id if necessary, substitute type
 506 -- Return with IdInfo already substituted, but (fragile) occurrence info zapped
 507 -- The substitution is extended only if the variable is cloned, because
 508 -- we *don't* need to use it to track occurrence info.
 509 simplBinder env bndr
 510   | isTyVar bndr  = do  { let (env', tv) = substTyVarBndr env bndr
 511                         ; seqTyVar tv `seq` return (env', tv) }
 512   | otherwise     = do  { let (env', id) = substIdBndr env bndr
 513                         ; seqId id `seq` return (env', id) }
 514
 515 -------------
 516 simplLamBndr :: SimplEnv -> Var -> SimplM (SimplEnv, Var)
 517 -- Used for lambda binders.  These sometimes have unfoldings added by
 518 -- the worker/wrapper pass that must be preserved, becuase they can't
 519 -- be reconstructed from context.  For example:
 520 --      f x = case x of (a,b) -> fw a b x
 521 --      fw a b x{=(a,b)} = ...
 522 -- The "{=(a,b)}" is an unfolding we can't reconstruct otherwise.
 523 simplLamBndr env bndr
 524   | not (isId bndr && hasSomeUnfolding old_unf) = simplBinder env bndr  -- Normal case
 525   | otherwise                                   = seqId id2 `seq` return (env', id2)
 526   where
 527     old_unf = idUnfolding bndr
 528     (env', id1) = substIdBndr env bndr
 529     id2 = id1 `setIdUnfolding` substUnfolding env old_unf
 530
 531 ---------------
 532 simplNonRecBndr :: SimplEnv -> InBndr -> SimplM (SimplEnv, OutBndr)
 533 -- A non-recursive let binder
 534 simplNonRecBndr env id
 535   = do  { let (env1, id1) = substIdBndr env id
 536         ; seqId id1 `seq` return (env1, id1) }
 537
 538 ---------------
 539 simplRecBndrs :: SimplEnv -> [InBndr] -> SimplM SimplEnv
 540 -- Recursive let binders
 541 simplRecBndrs env@(SimplEnv { seInScope = in_scope, seIdSubst = id_subst }) ids
 542   = do  { let (env1, ids1) = mapAccumL substIdBndr env ids
 543         ; seqIds ids1 `seq` return env1 }
 544
 545 ---------------
 546 substIdBndr :: SimplEnv
 547             -> InBndr   -- Env and binder to transform
 548             -> (SimplEnv, OutBndr)
 549 -- Clone Id if necessary, substitute its type
 550 -- Return an Id with its
 551 --      * Type substituted
 552 --      * UnfoldingInfo, Rules, WorkerInfo zapped
 553 --      * Fragile OccInfo (only) zapped: Note [Robust OccInfo]
 554 --      * Robust info, retained especially arity and demand info,
 555 --         so that they are available to occurrences that occur in an
 556 --         earlier binding of a letrec
 557 --
 558 -- For the robust info, see Note [Arity robustness]
 559 --
 560 -- Augment the substitution  if the unique changed
 561 -- Extend the in-scope set with the new Id
 562 --
 563 -- Similar to CoreSubst.substIdBndr, except that
 564 --      the type of id_subst differs
 565 --      all fragile info is zapped
 566
 567 substIdBndr env@(SimplEnv { seInScope = in_scope, seIdSubst = id_subst })
 568                old_id
 569   = (env { seInScope = in_scope `extendInScopeSet` new_id,
 570            seIdSubst = new_subst }, new_id)
 571   where
 572     id1    = uniqAway in_scope old_id
 573     id2    = substIdType env id1
 574     new_id = zapFragileIdInfo id2       -- Zaps rules, worker-info, unfolding
 575                                         -- and fragile OccInfo
 576
 577         -- Extend the substitution if the unique has changed,
 578         -- or there's some useful occurrence information
 579         -- See the notes with substTyVarBndr for the delSubstEnv
 580     new_subst | new_id /= old_id
 581               = extendVarEnv id_subst old_id (DoneId new_id)
 582               | otherwise
 583               = delVarEnv id_subst old_id
 584 \end{code}
 585
 586 \begin{code}
 587 ------------------------------------
 588 seqTyVar :: TyVar -> ()
 589 seqTyVar b = b `seq` ()
 590
 591 seqId :: Id -> ()
 592 seqId id = seqType (idType id)  `seq`
 593            idInfo id            `seq`
 594            ()
 595
 596 seqIds :: [Id] -> ()
 597 seqIds []       = ()
 598 seqIds (id:ids) = seqId id `seq` seqIds ids
 599 \end{code}
 600
 601
 602 Note [Arity robustness]
 603 ~~~~~~~~~~~~~~~~~~~~~~~
 604 We *do* transfer the arity from from the in_id of a let binding to the
 605 out_id.  This is important, so that the arity of an Id is visible in
 606 its own RHS.  For example:
 607         f = \x. ....g (\y. f y)....
 608 We can eta-reduce the arg to g, becuase f is a value.  But that
 609 needs to be visible.
 610
 611 This interacts with the 'state hack' too:
 612         f :: Bool -> IO Int
 613         f = \x. case x of
 614                   True  -> f y
 615                   False -> \s -> ...
 616 Can we eta-expand f?  Only if we see that f has arity 1, and then we
 617 take advantage of the 'state hack' on the result of
 618 (f y) :: State# -> (State#, Int) to expand the arity one more.
 619
 620 There is a disadvantage though.  Making the arity visible in the RHA
 621 allows us to eta-reduce
 622         f = \x -> f x
 623 to
 624         f = f
 625 which technically is not sound.   This is very much a corner case, so
 626 I'm not worried about it.  Another idea is to ensure that f's arity
 627 never decreases; its arity started as 1, and we should never eta-reduce
 628 below that.
 629
 630
 631 Note [Robust OccInfo]
 632 ~~~~~~~~~~~~~~~~~~~~~
 633 It's important that we *do* retain the loop-breaker OccInfo, because
 634 that's what stops the Id getting inlined infinitely, in the body of
 635 the letrec.
 636
 637
 638 Note [Rules in a letrec]
 639 ~~~~~~~~~~~~~~~~~~~~~~~~
 640 After creating fresh binders for the binders of a letrec, we
 641 substitute the RULES and add them back onto the binders; this is done
 642 *before* processing any of the RHSs.  This is important.  Manuel found
 643 cases where he really, really wanted a RULE for a recursive function
 644 to apply in that function's own right-hand side.
 645
 646 See Note [Loop breaking and RULES] in OccAnal.
 647
 648
 649 \begin{code}
 650 addBndrRules :: SimplEnv -> InBndr -> OutBndr -> (SimplEnv, OutBndr)
 651 -- Rules are added back in to to hte bin
 652 addBndrRules env in_id out_id
 653   | isEmptySpecInfo old_rules = (env, out_id)
 654   | otherwise = (modifyInScope env out_id final_id, final_id)
 655   where
 656     subst     = mkCoreSubst env
 657     old_rules = idSpecialisation in_id
 658     new_rules = CoreSubst.substSpec subst old_rules
 659     final_id  = out_id `setIdSpecialisation` new_rules
 660
 661 ------------------
 662 substIdType :: SimplEnv -> Id -> Id
 663 substIdType env@(SimplEnv { seInScope = in_scope,  seTvSubst = tv_env}) id
 664   | isEmptyVarEnv tv_env || isEmptyVarSet (tyVarsOfType old_ty) = id
 665   | otherwise   = Id.setIdType id (Type.substTy (TvSubst in_scope tv_env) old_ty)
 666                 -- The tyVarsOfType is cheaper than it looks
 667                 -- because we cache the free tyvars of the type
 668                 -- in a Note in the id's type itself
 669   where
 670     old_ty = idType id
 671
 672 ------------------
 673 substUnfolding :: SimplEnv -> Unfolding -> Unfolding
 674 substUnfolding env NoUnfolding                 = NoUnfolding
 675 substUnfolding env (OtherCon cons)             = OtherCon cons
 676 substUnfolding env (CompulsoryUnfolding rhs)   = CompulsoryUnfolding (substExpr env rhs)
 677 substUnfolding env (CoreUnfolding rhs t v w g) = CoreUnfolding (substExpr env rhs) t v w g
 678
 679 ------------------
 680 substWorker :: SimplEnv -> WorkerInfo -> WorkerInfo
 681 substWorker env NoWorker = NoWorker
 682 substWorker env wkr_info = CoreSubst.substWorker (mkCoreSubst env) wkr_info
 683 \end{code}
 684
 685
 686 %************************************************************************
 687 %*                                                                      *
 688                 Impedence matching to type substitution
 689 %*                                                                      *
 690 %************************************************************************
 691
 692 \begin{code}
 693 substTy :: SimplEnv -> Type -> Type
 694 substTy (SimplEnv { seInScope = in_scope, seTvSubst = tv_env }) ty
 695   = Type.substTy (TvSubst in_scope tv_env) ty
 696
 697 substTyVarBndr :: SimplEnv -> TyVar -> (SimplEnv, TyVar)
 698 substTyVarBndr env@(SimplEnv { seInScope = in_scope, seTvSubst = tv_env }) tv
 699   = case Type.substTyVarBndr (TvSubst in_scope tv_env) tv of
 700         (TvSubst in_scope' tv_env', tv')
 701            -> (env { seInScope = in_scope', seTvSubst = tv_env'}, tv')
 702
 703 -- When substituting in rules etc we can get CoreSubst to do the work
 704 -- But CoreSubst uses a simpler form of IdSubstEnv, so we must impedence-match
 705 -- here.  I think the this will not usually result in a lot of work;
 706 -- the substitutions are typically small, and laziness will avoid work in many cases.
 707
 708 mkCoreSubst  :: SimplEnv -> CoreSubst.Subst
 709 mkCoreSubst (SimplEnv { seInScope = in_scope, seTvSubst = tv_env, seIdSubst = id_env })
 710   = mk_subst tv_env id_env
 711   where
 712     mk_subst tv_env id_env = CoreSubst.mkSubst in_scope tv_env (mapVarEnv fiddle id_env)
 713
 714     fiddle (DoneEx e)       = e
 715     fiddle (DoneId v)       = Var v
 716     fiddle (ContEx tv id e) = CoreSubst.substExpr (mk_subst tv id) e
 717
 718 substExpr :: SimplEnv -> CoreExpr -> CoreExpr
 719 substExpr env expr
 720   | isEmptySimplSubst env = expr
 721   | otherwise             = CoreSubst.substExpr (mkCoreSubst env) expr
 722 \end{code}
 723