compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         mkLam, mkCase,
   9
  10         -- Inlining,
  11         preInlineUnconditionally, postInlineUnconditionally, activeInline, activeRule,
  12         inlineMode,
  13
  14         -- The continuation type
  15         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  16         contIsDupable, contResultType,
  17         countValArgs, countArgs, pushContArgs,
  18         mkBoringStop, mkRhsStop, contIsRhs, contIsRhsOrArg,
  19         getContArgs, interestingCallContext, interestingArg, isStrictType
  20
  21     ) where
  22
  23 #include "HsVersions.h"
  24
  25 import SimplEnv
  26 import DynFlags         ( SimplifierSwitch(..), SimplifierMode(..),
  27                           DynFlag(..), dopt )
  28 import StaticFlags      ( opt_UF_UpdateInPlace, opt_SimplNoPreInlining,
  29                           opt_RulesOff )
  30 import CoreSyn
  31 import CoreFVs          ( exprFreeVars )
  32 import CoreUtils        ( cheapEqExpr, exprType, exprIsTrivial, exprIsCheap,
  33                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce2,
  34                           findDefault, exprOkForSpeculation, exprIsHNF, mergeAlts
  35                         )
  36 import Literal          ( mkStringLit )
  37 import CoreUnfold       ( smallEnoughToInline )
  38 import MkId             ( eRROR_ID )
  39 import Id               ( idType, isDataConWorkId, idOccInfo, isDictId,
  40                           isDeadBinder, idNewDemandInfo, isExportedId,
  41                           idUnfolding, idNewStrictness, idInlinePragma,
  42                         )
  43 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
  44 import SimplMonad
  45 import Type             ( Type, splitFunTys, dropForAlls, isStrictType,
  46                           splitTyConApp_maybe, tyConAppArgs
  47                         )
  48 import TyCon            ( tyConDataCons_maybe )
  49 import DataCon          ( dataConRepArity )
  50 import VarSet
  51 import BasicTypes       ( TopLevelFlag(..), isNotTopLevel, OccInfo(..), isLoopBreaker, isOneOcc,
  52                           Activation, isAlwaysActive, isActive )
  53 import Util             ( lengthExceeds )
  54 import Outputable
  55 \end{code}
  56
  57
  58 %************************************************************************
  59 %*                                                                      *
  60 \subsection{The continuation data type}
  61 %*                                                                      *
  62 %************************************************************************
  63
  64 \begin{code}
  65 data SimplCont          -- Strict contexts
  66   = Stop     OutType            -- Type of the result
  67              LetRhsFlag
  68              Bool               -- True <=> This is the RHS of a thunk whose type suggests
  69                                 --          that update-in-place would be possible
  70                                 --          (This makes the inliner a little keener.)
  71
  72   | CoerceIt OutType                    -- The To-type, simplified
  73              SimplCont
  74
  75   | InlinePlease                        -- This continuation makes a function very
  76              SimplCont                  -- keen to inline itelf
  77
  78   | ApplyTo  DupFlag
  79              InExpr SimplEnv            -- The argument, as yet unsimplified,
  80              SimplCont                  -- and its environment
  81
  82   | Select   DupFlag
  83              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
  84              SimplCont
  85
  86   | ArgOf    LetRhsFlag         -- An arbitrary strict context: the argument
  87                                 --      of a strict function, or a primitive-arg fn
  88                                 --      or a PrimOp
  89                                 -- No DupFlag because we never duplicate it
  90              OutType            -- arg_ty: type of the argument itself
  91              OutType            -- cont_ty: the type of the expression being sought by the context
  92                                 --      f (error "foo") ==> coerce t (error "foo")
  93                                 -- when f is strict
  94                                 -- We need to know the type t, to which to coerce.
  95
  96              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
  97                                 -- The result expression in the OutExprStuff has type cont_ty
  98
  99 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
 100                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
 101
 102 instance Outputable LetRhsFlag where
 103   ppr AnArg = ptext SLIT("arg")
 104   ppr AnRhs = ptext SLIT("rhs")
 105
 106 instance Outputable SimplCont where
 107   ppr (Stop ty is_rhs _)             = ptext SLIT("Stop") <> brackets (ppr is_rhs) <+> ppr ty
 108   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
 109   ppr (ArgOf _ _ _ _)                = ptext SLIT("ArgOf...")
 110   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 111                                        (nest 4 (ppr alts)) $$ ppr cont
 112   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
 113   ppr (InlinePlease cont)            = ptext SLIT("InlinePlease") $$ ppr cont
 114
 115 data DupFlag = OkToDup | NoDup
 116
 117 instance Outputable DupFlag where
 118   ppr OkToDup = ptext SLIT("ok")
 119   ppr NoDup   = ptext SLIT("nodup")
 120
 121
 122 -------------------
 123 mkBoringStop, mkRhsStop :: OutType -> SimplCont
 124 mkBoringStop ty = Stop ty AnArg (canUpdateInPlace ty)
 125 mkRhsStop    ty = Stop ty AnRhs (canUpdateInPlace ty)
 126
 127 contIsRhs :: SimplCont -> Bool
 128 contIsRhs (Stop _ AnRhs _)    = True
 129 contIsRhs (ArgOf AnRhs _ _ _) = True
 130 contIsRhs other               = False
 131
 132 contIsRhsOrArg (Stop _ _ _)    = True
 133 contIsRhsOrArg (ArgOf _ _ _ _) = True
 134 contIsRhsOrArg other           = False
 135
 136 -------------------
 137 contIsDupable :: SimplCont -> Bool
 138 contIsDupable (Stop _ _ _)               = True
 139 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 140 contIsDupable (Select   OkToDup _ _ _ _) = True
 141 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 142 contIsDupable (InlinePlease cont)        = contIsDupable cont
 143 contIsDupable other                      = False
 144
 145 -------------------
 146 discardableCont :: SimplCont -> Bool
 147 discardableCont (Stop _ _ _)        = False
 148 discardableCont (CoerceIt _ cont)   = discardableCont cont
 149 discardableCont (InlinePlease cont) = discardableCont cont
 150 discardableCont other               = True
 151
 152 discardCont :: SimplCont        -- A continuation, expecting
 153             -> SimplCont        -- Replace the continuation with a suitable coerce
 154 discardCont cont = case cont of
 155                      Stop to_ty is_rhs _ -> cont
 156                      other               -> CoerceIt to_ty (mkBoringStop to_ty)
 157                  where
 158                    to_ty = contResultType cont
 159
 160 -------------------
 161 contResultType :: SimplCont -> OutType
 162 contResultType (Stop to_ty _ _)      = to_ty
 163 contResultType (ArgOf _ _ to_ty _)   = to_ty
 164 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 165 contResultType (CoerceIt _ cont)     = contResultType cont
 166 contResultType (InlinePlease cont)   = contResultType cont
 167 contResultType (Select _ _ _ _ cont) = contResultType cont
 168
 169 -------------------
 170 countValArgs :: SimplCont -> Int
 171 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 172 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 173 countValArgs other                         = 0
 174
 175 countArgs :: SimplCont -> Int
 176 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 177 countArgs other                   = 0
 178
 179 -------------------
 180 pushContArgs :: SimplEnv -> [OutArg] -> SimplCont -> SimplCont
 181 -- Pushes args with the specified environment
 182 pushContArgs env []           cont = cont
 183 pushContArgs env (arg : args) cont = ApplyTo NoDup arg env (pushContArgs env args cont)
 184 \end{code}
 185
 186
 187 \begin{code}
 188 getContArgs :: SwitchChecker
 189             -> OutId -> SimplCont
 190             -> ([(InExpr, SimplEnv, Bool)],     -- Arguments; the Bool is true for strict args
 191                 SimplCont,                      -- Remaining continuation
 192                 Bool)                           -- Whether we came across an InlineCall
 193 -- getContArgs id k = (args, k', inl)
 194 --      args are the leading ApplyTo items in k
 195 --      (i.e. outermost comes first)
 196 --      augmented with demand info from the functionn
 197 getContArgs chkr fun orig_cont
 198   = let
 199                 -- Ignore strictness info if the no-case-of-case
 200                 -- flag is on.  Strictness changes evaluation order
 201                 -- and that can change full laziness
 202         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 203                 | otherwise                    = computed_stricts
 204     in
 205     go [] stricts False orig_cont
 206   where
 207     ----------------------------
 208
 209         -- Type argument
 210     go acc ss inl (ApplyTo _ arg@(Type _) se cont)
 211         = go ((arg,se,False) : acc) ss inl cont
 212                 -- NB: don't bother to instantiate the function type
 213
 214         -- Value argument
 215     go acc (s:ss) inl (ApplyTo _ arg se cont)
 216         = go ((arg,se,s) : acc) ss inl cont
 217
 218         -- An Inline continuation
 219     go acc ss inl (InlinePlease cont)
 220         = go acc ss True cont
 221
 222         -- We're run out of arguments, or else we've run out of demands
 223         -- The latter only happens if the result is guaranteed bottom
 224         -- This is the case for
 225         --      * case (error "hello") of { ... }
 226         --      * (error "Hello") arg
 227         --      * f (error "Hello") where f is strict
 228         --      etc
 229         -- Then, especially in the first of these cases, we'd like to discard
 230         -- the continuation, leaving just the bottoming expression.  But the
 231         -- type might not be right, so we may have to add a coerce.
 232     go acc ss inl cont
 233         | null ss && discardableCont cont = (reverse acc, discardCont cont, inl)
 234         | otherwise                       = (reverse acc, cont,             inl)
 235
 236     ----------------------------
 237     vanilla_stricts, computed_stricts :: [Bool]
 238     vanilla_stricts  = repeat False
 239     computed_stricts = zipWith (||) fun_stricts arg_stricts
 240
 241     ----------------------------
 242     (val_arg_tys, _) = splitFunTys (dropForAlls (idType fun))
 243     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 244         -- These argument types are used as a cheap and cheerful way to find
 245         -- unboxed arguments, which must be strict.  But it's an InType
 246         -- and so there might be a type variable where we expect a function
 247         -- type (the substitution hasn't happened yet).  And we don't bother
 248         -- doing the type applications for a polymorphic function.
 249         -- Hence the splitFunTys*IgnoringForAlls*
 250
 251     ----------------------------
 252         -- If fun_stricts is finite, it means the function returns bottom
 253         -- after that number of value args have been consumed
 254         -- Otherwise it's infinite, extended with False
 255     fun_stricts
 256       = case splitStrictSig (idNewStrictness fun) of
 257           (demands, result_info)
 258                 | not (demands `lengthExceeds` countValArgs orig_cont)
 259                 ->      -- Enough args, use the strictness given.
 260                         -- For bottoming functions we used to pretend that the arg
 261                         -- is lazy, so that we don't treat the arg as an
 262                         -- interesting context.  This avoids substituting
 263                         -- top-level bindings for (say) strings into
 264                         -- calls to error.  But now we are more careful about
 265                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 266                    if isBotRes result_info then
 267                         map isStrictDmd demands         -- Finite => result is bottom
 268                    else
 269                         map isStrictDmd demands ++ vanilla_stricts
 270
 271           other -> vanilla_stricts      -- Not enough args, or no strictness
 272
 273 -------------------
 274 interestingArg :: OutExpr -> Bool
 275         -- An argument is interesting if it has *some* structure
 276         -- We are here trying to avoid unfolding a function that
 277         -- is applied only to variables that have no unfolding
 278         -- (i.e. they are probably lambda bound): f x y z
 279         -- There is little point in inlining f here.
 280 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 281                                         -- Was: isValueUnfolding (idUnfolding v')
 282                                         -- But that seems over-pessimistic
 283                                  || isDataConWorkId v
 284                                         -- This accounts for an argument like
 285                                         -- () or [], which is definitely interesting
 286 interestingArg (Type _)          = False
 287 interestingArg (App fn (Type _)) = interestingArg fn
 288 interestingArg (Note _ a)        = interestingArg a
 289 interestingArg other             = True
 290         -- Consider     let x = 3 in f x
 291         -- The substitution will contain (x -> ContEx 3), and we want to
 292         -- to say that x is an interesting argument.
 293         -- But consider also (\x. f x y) y
 294         -- The substitution will contain (x -> ContEx y), and we want to say
 295         -- that x is not interesting (assuming y has no unfolding)
 296 \end{code}
 297
 298 Comment about interestingCallContext
 299 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 300 We want to avoid inlining an expression where there can't possibly be
 301 any gain, such as in an argument position.  Hence, if the continuation
 302 is interesting (eg. a case scrutinee, application etc.) then we
 303 inline, otherwise we don't.
 304
 305 Previously some_benefit used to return True only if the variable was
 306 applied to some value arguments.  This didn't work:
 307
 308         let x = _coerce_ (T Int) Int (I# 3) in
 309         case _coerce_ Int (T Int) x of
 310                 I# y -> ....
 311
 312 we want to inline x, but can't see that it's a constructor in a case
 313 scrutinee position, and some_benefit is False.
 314
 315 Another example:
 316
 317 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 318
 319 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 320
 321 we'd really like to inline dMonadST here, but we *don't* want to
 322 inline if the case expression is just
 323
 324         case x of y { DEFAULT -> ... }
 325
 326 since we can just eliminate this case instead (x is in WHNF).  Similar
 327 applies when x is bound to a lambda expression.  Hence
 328 contIsInteresting looks for case expressions with just a single
 329 default case.
 330
 331 \begin{code}
 332 interestingCallContext :: Bool          -- False <=> no args at all
 333                        -> Bool          -- False <=> no value args
 334                        -> SimplCont -> Bool
 335         -- The "lone-variable" case is important.  I spent ages
 336         -- messing about with unsatisfactory varaints, but this is nice.
 337         -- The idea is that if a variable appear all alone
 338         --      as an arg of lazy fn, or rhs    Stop
 339         --      as scrutinee of a case          Select
 340         --      as arg of a strict fn           ArgOf
 341         -- then we should not inline it (unless there is some other reason,
 342         -- e.g. is is the sole occurrence).  We achieve this by making
 343         -- interestingCallContext return False for a lone variable.
 344         --
 345         -- Why?  At least in the case-scrutinee situation, turning
 346         --      let x = (a,b) in case x of y -> ...
 347         -- into
 348         --      let x = (a,b) in case (a,b) of y -> ...
 349         -- and thence to
 350         --      let x = (a,b) in let y = (a,b) in ...
 351         -- is bad if the binding for x will remain.
 352         --
 353         -- Another example: I discovered that strings
 354         -- were getting inlined straight back into applications of 'error'
 355         -- because the latter is strict.
 356         --      s = "foo"
 357         --      f = \x -> ...(error s)...
 358
 359         -- Fundamentally such contexts should not ecourage inlining because
 360         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 361         -- so there's no gain.
 362         --
 363         -- However, even a type application or coercion isn't a lone variable.
 364         -- Consider
 365         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 366         -- We had better inline that sucker!  The case won't see through it.
 367         --
 368         -- For now, I'm treating treating a variable applied to types
 369         -- in a *lazy* context "lone". The motivating example was
 370         --      f = /\a. \x. BIG
 371         --      g = /\a. \y.  h (f a)
 372         -- There's no advantage in inlining f here, and perhaps
 373         -- a significant disadvantage.  Hence some_val_args in the Stop case
 374
 375 interestingCallContext some_args some_val_args cont
 376   = interesting cont
 377   where
 378     interesting (InlinePlease _)         = True
 379     interesting (Select _ _ _ _ _)       = some_args
 380     interesting (ApplyTo _ _ _ _)        = True -- Can happen if we have (coerce t (f x)) y
 381                                                 -- Perhaps True is a bit over-keen, but I've
 382                                                 -- seen (coerce f) x, where f has an INLINE prag,
 383                                                 -- So we have to give some motivaiton for inlining it
 384     interesting (ArgOf _ _ _ _)          = some_val_args
 385     interesting (Stop ty _ upd_in_place) = some_val_args && upd_in_place
 386     interesting (CoerceIt _ cont)        = interesting cont
 387         -- If this call is the arg of a strict function, the context
 388         -- is a bit interesting.  If we inline here, we may get useful
 389         -- evaluation information to avoid repeated evals: e.g.
 390         --      x + (y * z)
 391         -- Here the contIsInteresting makes the '*' keener to inline,
 392         -- which in turn exposes a constructor which makes the '+' inline.
 393         -- Assuming that +,* aren't small enough to inline regardless.
 394         --
 395         -- It's also very important to inline in a strict context for things
 396         -- like
 397         --              foldr k z (f x)
 398         -- Here, the context of (f x) is strict, and if f's unfolding is
 399         -- a build it's *great* to inline it here.  So we must ensure that
 400         -- the context for (f x) is not totally uninteresting.
 401
 402
 403 -------------------
 404 canUpdateInPlace :: Type -> Bool
 405 -- Consider   let x = <wurble> in ...
 406 -- If <wurble> returns an explicit constructor, we might be able
 407 -- to do update in place.  So we treat even a thunk RHS context
 408 -- as interesting if update in place is possible.  We approximate
 409 -- this by seeing if the type has a single constructor with a
 410 -- small arity.  But arity zero isn't good -- we share the single copy
 411 -- for that case, so no point in sharing.
 412
 413 canUpdateInPlace ty
 414   | not opt_UF_UpdateInPlace = False
 415   | otherwise
 416   = case splitTyConApp_maybe ty of
 417         Nothing         -> False
 418         Just (tycon, _) -> case tyConDataCons_maybe tycon of
 419                                 Just [dc]  -> arity == 1 || arity == 2
 420                                            where
 421                                               arity = dataConRepArity dc
 422                                 other -> False
 423 \end{code}
 424
 425
 426
 427 %************************************************************************
 428 %*                                                                      *
 429 \subsection{Decisions about inlining}
 430 %*                                                                      *
 431 %************************************************************************
 432
 433 Inlining is controlled partly by the SimplifierMode switch.  This has two
 434 settings:
 435
 436         SimplGently     (a) Simplifying before specialiser/full laziness
 437                         (b) Simplifiying inside INLINE pragma
 438                         (c) Simplifying the LHS of a rule
 439                         (d) Simplifying a GHCi expression or Template
 440                                 Haskell splice
 441
 442         SimplPhase n    Used at all other times
 443
 444 The key thing about SimplGently is that it does no call-site inlining.
 445 Before full laziness we must be careful not to inline wrappers,
 446 because doing so inhibits floating
 447     e.g. ...(case f x of ...)...
 448     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 449     ==> ...(case x of I# x# -> case fw x# of ...)...
 450 and now the redex (f x) isn't floatable any more.
 451
 452 The no-inling thing is also important for Template Haskell.  You might be
 453 compiling in one-shot mode with -O2; but when TH compiles a splice before
 454 running it, we don't want to use -O2.  Indeed, we don't want to inline
 455 anything, because the byte-code interpreter might get confused about
 456 unboxed tuples and suchlike.
 457
 458 INLINE pragmas
 459 ~~~~~~~~~~~~~~
 460 SimplGently is also used as the mode to simplify inside an InlineMe note.
 461
 462 \begin{code}
 463 inlineMode :: SimplifierMode
 464 inlineMode = SimplGently
 465 \end{code}
 466
 467 It really is important to switch off inlinings inside such
 468 expressions.  Consider the following example
 469
 470         let f = \pq -> BIG
 471         in
 472         let g = \y -> f y y
 473             {-# INLINE g #-}
 474         in ...g...g...g...g...g...
 475
 476 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 477 and thence copied multiple times when g is inlined.
 478
 479
 480 This function may be inlinined in other modules, so we
 481 don't want to remove (by inlining) calls to functions that have
 482 specialisations, or that may have transformation rules in an importing
 483 scope.
 484
 485 E.g.    {-# INLINE f #-}
 486                 f x = ...g...
 487
 488 and suppose that g is strict *and* has specialisations.  If we inline
 489 g's wrapper, we deny f the chance of getting the specialised version
 490 of g when f is inlined at some call site (perhaps in some other
 491 module).
 492
 493 It's also important not to inline a worker back into a wrapper.
 494 A wrapper looks like
 495         wraper = inline_me (\x -> ...worker... )
 496 Normally, the inline_me prevents the worker getting inlined into
 497 the wrapper (initially, the worker's only call site!).  But,
 498 if the wrapper is sure to be called, the strictness analyser will
 499 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 500 continuation.  That's why the keep_inline predicate returns True for
 501 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 502 inline-me note under these circumstances.
 503
 504 Note that the result is that we do very little simplification
 505 inside an InlineMe.
 506
 507         all xs = foldr (&&) True xs
 508         any p = all . map p  {-# INLINE any #-}
 509
 510 Problem: any won't get deforested, and so if it's exported and the
 511 importer doesn't use the inlining, (eg passes it as an arg) then we
 512 won't get deforestation at all.  We havn't solved this problem yet!
 513
 514
 515 preInlineUnconditionally
 516 ~~~~~~~~~~~~~~~~~~~~~~~~
 517 @preInlineUnconditionally@ examines a bndr to see if it is used just
 518 once in a completely safe way, so that it is safe to discard the
 519 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 520 big the RHS might be.  If this is the case we don't simplify the RHS
 521 first, but just inline it un-simplified.
 522
 523 This is much better than first simplifying a perhaps-huge RHS and then
 524 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 525 better.  Consider
 526
 527         x1 = e1
 528         x2 = e2[x1]
 529         x3 = e3[x2]
 530         ...etc...
 531         xN = eN[xN-1]
 532
 533 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 534 This can happen with cascades of functions too:
 535
 536         f1 = \x1.e1
 537         f2 = \xs.e2[f1]
 538         f3 = \xs.e3[f3]
 539         ...etc...
 540
 541 THE MAIN INVARIANT is this:
 542
 543         ----  preInlineUnconditionally invariant -----
 544    IF preInlineUnconditionally chooses to inline x = <rhs>
 545    THEN doing the inlining should not change the occurrence
 546         info for the free vars of <rhs>
 547         ----------------------------------------------
 548
 549 For example, it's tempting to look at trivial binding like
 550         x = y
 551 and inline it unconditionally.  But suppose x is used many times,
 552 but this is the unique occurrence of y.  Then inlining x would change
 553 y's occurrence info, which breaks the invariant.  It matters: y
 554 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
 555
 556
 557 Evne RHSs labelled InlineMe aren't caught here, because there might be
 558 no benefit from inlining at the call site.
 559
 560 [Sept 01] Don't unconditionally inline a top-level thing, because that
 561 can simply make a static thing into something built dynamically.  E.g.
 562         x = (a,b)
 563         main = \s -> h x
 564
 565 [Remember that we treat \s as a one-shot lambda.]  No point in
 566 inlining x unless there is something interesting about the call site.
 567
 568 But watch out: if you aren't careful, some useful foldr/build fusion
 569 can be lost (most notably in spectral/hartel/parstof) because the
 570 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 571 deal, in fact, but losing the fusion can be.  But the right thing here
 572 seems to be to do a callSiteInline based on the fact that there is
 573 something interesting about the call site (it's strict).  Hmm.  That
 574 seems a bit fragile.
 575
 576 Conclusion: inline top level things gaily until Phase 0 (the last
 577 phase), at which point don't.
 578
 579 \begin{code}
 580 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
 581 preInlineUnconditionally env top_lvl bndr rhs
 582   | not active             = False
 583   | opt_SimplNoPreInlining = False
 584   | otherwise = case idOccInfo bndr of
 585                   IAmDead                    -> True    -- Happens in ((\x.1) v)
 586                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
 587                   other                      -> False
 588   where
 589     phase = getMode env
 590     active = case phase of
 591                    SimplGently  -> isAlwaysActive prag
 592                    SimplPhase n -> isActive n prag
 593     prag = idInlinePragma bndr
 594
 595     try_once in_lam int_cxt     -- There's one textual occurrence
 596         | not in_lam = isNotTopLevel top_lvl || early_phase
 597         | otherwise  = int_cxt && canInlineInLam rhs
 598
 599 -- Be very careful before inlining inside a lambda, becuase (a) we must not
 600 -- invalidate occurrence information, and (b) we want to avoid pushing a
 601 -- single allocation (here) into multiple allocations (inside lambda).
 602 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
 603 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
 604 --      where
 605 --              is_cheap = exprIsCheap rhs
 606 --              ok = is_cheap && int_cxt
 607
 608         --      int_cxt         The context isn't totally boring
 609         -- E.g. let f = \ab.BIG in \y. map f xs
 610         --      Don't want to substitute for f, because then we allocate
 611         --      its closure every time the \y is called
 612         -- But: let f = \ab.BIG in \y. map (f y) xs
 613         --      Now we do want to substitute for f, even though it's not
 614         --      saturated, because we're going to allocate a closure for
 615         --      (f y) every time round the loop anyhow.
 616
 617         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
 618         -- so substituting rhs inside a lambda doesn't change the occ info.
 619         -- Sadly, not quite the same as exprIsHNF.
 620     canInlineInLam (Lit l)              = True
 621     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
 622     canInlineInLam (Note _ e)           = canInlineInLam e
 623     canInlineInLam _                    = False
 624
 625     early_phase = case phase of
 626                         SimplPhase 0 -> False
 627                         other        -> True
 628 -- If we don't have this early_phase test, consider
 629 --      x = length [1,2,3]
 630 -- The full laziness pass carefully floats all the cons cells to
 631 -- top level, and preInlineUnconditionally floats them all back in.
 632 -- Result is (a) static allocation replaced by dynamic allocation
 633 --           (b) many simplifier iterations because this tickles
 634 --               a related problem; only one inlining per pass
 635 --
 636 -- On the other hand, I have seen cases where top-level fusion is
 637 -- lost if we don't inline top level thing (e.g. string constants)
 638 -- Hence the test for phase zero (which is the phase for all the final
 639 -- simplifications).  Until phase zero we take no special notice of
 640 -- top level things, but then we become more leery about inlining
 641 -- them.
 642
 643 \end{code}
 644
 645 postInlineUnconditionally
 646 ~~~~~~~~~~~~~~~~~~~~~~~~~
 647 @postInlineUnconditionally@ decides whether to unconditionally inline
 648 a thing based on the form of its RHS; in particular if it has a
 649 trivial RHS.  If so, we can inline and discard the binding altogether.
 650
 651 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 652 only have *forward* references Hence, it's safe to discard the binding
 653
 654 NOTE: This isn't our last opportunity to inline.  We're at the binding
 655 site right now, and we'll get another opportunity when we get to the
 656 ocurrence(s)
 657
 658 Note that we do this unconditional inlining only for trival RHSs.
 659 Don't inline even WHNFs inside lambdas; doing so may simply increase
 660 allocation when the function is called. This isn't the last chance; see
 661 NOTE above.
 662
 663 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 664 Because we don't even want to inline them into the RHS of constructor
 665 arguments. See NOTE above
 666
 667 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 668 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 669 with both a and b marked NOINLINE.  But that seems incompatible with
 670 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 671 story for now.
 672
 673 \begin{code}
 674 postInlineUnconditionally :: SimplEnv -> TopLevelFlag -> OutId -> OccInfo -> OutExpr -> Unfolding -> Bool
 675 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
 676   | not active             = False
 677   | isLoopBreaker occ_info = False
 678   | isExportedId bndr      = False
 679   | exprIsTrivial rhs      = True
 680   | otherwise
 681   = case occ_info of
 682       OneOcc in_lam one_br int_cxt
 683         ->     (one_br || smallEnoughToInline unfolding)        -- Small enough to dup
 684                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
 685                         --
 686                         -- NB: Do we want to inline arbitrarily big things becuase
 687                         -- one_br is True? that can lead to inline cascades.  But
 688                         -- preInlineUnconditionlly has dealt with all the common cases
 689                         -- so perhaps it's worth the risk. Here's an example
 690                         --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
 691                         --      in \y. ....f....
 692                         -- We can't preInlineUnconditionally because that woud invalidate
 693                         -- the occ info for b.  Yet f is used just once, and duplicating
 694                         -- the case work is fine (exprIsCheap).
 695
 696            &&  ((isNotTopLevel top_lvl && not in_lam) ||
 697                         -- But outside a lambda, we want to be reasonably aggressive
 698                         -- about inlining into multiple branches of case
 699                         -- e.g. let x = <non-value>
 700                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... }
 701                         -- Inlining can be a big win if C3 is the hot-spot, even if
 702                         -- the uses in C1, C2 are not 'interesting'
 703                         -- An example that gets worse if you add int_cxt here is 'clausify'
 704
 705                 (isCheapUnfolding unfolding && int_cxt))
 706                         -- isCheap => acceptable work duplication; in_lam may be true
 707                         -- int_cxt to prevent us inlining inside a lambda without some
 708                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
 709
 710       other -> False
 711         -- The point here is that for *non-values* that occur
 712         -- outside a lambda, the call-site inliner won't have
 713         -- a chance (becuase it doesn't know that the thing
 714         -- only occurs once).   The pre-inliner won't have gotten
 715         -- it either, if the thing occurs in more than one branch
 716         -- So the main target is things like
 717         --      let x = f y in
 718         --      case v of
 719         --         True  -> case x of ...
 720         --         False -> case x of ...
 721         -- I'm not sure how important this is in practice
 722   where
 723     active = case getMode env of
 724                    SimplGently  -> isAlwaysActive prag
 725                    SimplPhase n -> isActive n prag
 726     prag = idInlinePragma bndr
 727
 728 activeInline :: SimplEnv -> OutId -> OccInfo -> Bool
 729 activeInline env id occ
 730   = case getMode env of
 731       SimplGently -> isOneOcc occ && isAlwaysActive prag
 732         -- No inlining at all when doing gentle stuff,
 733         -- except for local things that occur once
 734         -- The reason is that too little clean-up happens if you
 735         -- don't inline use-once things.   Also a bit of inlining is *good* for
 736         -- full laziness; it can expose constant sub-expressions.
 737         -- Example in spectral/mandel/Mandel.hs, where the mandelset
 738         -- function gets a useful let-float if you inline windowToViewport
 739
 740         -- NB: we used to have a second exception, for data con wrappers.
 741         -- On the grounds that we use gentle mode for rule LHSs, and
 742         -- they match better when data con wrappers are inlined.
 743         -- But that only really applies to the trivial wrappers (like (:)),
 744         -- and they are now constructed as Compulsory unfoldings (in MkId)
 745         -- so they'll happen anyway.
 746
 747       SimplPhase n -> isActive n prag
 748   where
 749     prag = idInlinePragma id
 750
 751 activeRule :: SimplEnv -> Maybe (Activation -> Bool)
 752 -- Nothing => No rules at all
 753 activeRule env
 754   | opt_RulesOff = Nothing
 755   | otherwise
 756   = case getMode env of
 757         SimplGently  -> Just isAlwaysActive
 758                         -- Used to be Nothing (no rules in gentle mode)
 759                         -- Main motivation for changing is that I wanted
 760                         --      lift String ===> ...
 761                         -- to work in Template Haskell when simplifying
 762                         -- splices, so we get simpler code for literal strings
 763         SimplPhase n -> Just (isActive n)
 764 \end{code}
 765
 766
 767 %************************************************************************
 768 %*                                                                      *
 769 \subsection{Rebuilding a lambda}
 770 %*                                                                      *
 771 %************************************************************************
 772
 773 \begin{code}
 774 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
 775 \end{code}
 776
 777 Try three things
 778         a) eta reduction, if that gives a trivial expression
 779         b) eta expansion [only if there are some value lambdas]
 780         c) floating lets out through big lambdas
 781                 [only if all tyvar lambdas, and only if this lambda
 782                  is the RHS of a let]
 783
 784 \begin{code}
 785 mkLam env bndrs body cont
 786  = getDOptsSmpl  `thenSmpl` \dflags ->
 787    mkLam' dflags env bndrs body cont
 788  where
 789  mkLam' dflags env bndrs body cont
 790    | dopt Opt_DoEtaReduction dflags,
 791      Just etad_lam <- tryEtaReduce bndrs body
 792    = tick (EtaReduction (head bndrs))   `thenSmpl_`
 793      returnSmpl (emptyFloats env, etad_lam)
 794
 795    | dopt Opt_DoLambdaEtaExpansion dflags,
 796      any isRuntimeVar bndrs
 797    = tryEtaExpansion body               `thenSmpl` \ body' ->
 798      returnSmpl (emptyFloats env, mkLams bndrs body')
 799
 800 {-      Sept 01: I'm experimenting with getting the
 801         full laziness pass to float out past big lambdsa
 802  | all isTyVar bndrs,   -- Only for big lambdas
 803    contIsRhs cont       -- Only try the rhs type-lambda floating
 804                         -- if this is indeed a right-hand side; otherwise
 805                         -- we end up floating the thing out, only for float-in
 806                         -- to float it right back in again!
 807  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 808    returnSmpl (floats, mkLams bndrs body')
 809 -}
 810
 811    | otherwise
 812    = returnSmpl (emptyFloats env, mkLams bndrs body)
 813 \end{code}
 814
 815
 816 %************************************************************************
 817 %*                                                                      *
 818 \subsection{Eta expansion and reduction}
 819 %*                                                                      *
 820 %************************************************************************
 821
 822 We try for eta reduction here, but *only* if we get all the
 823 way to an exprIsTrivial expression.
 824 We don't want to remove extra lambdas unless we are going
 825 to avoid allocating this thing altogether
 826
 827 \begin{code}
 828 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
 829 tryEtaReduce bndrs body
 830         -- We don't use CoreUtils.etaReduce, because we can be more
 831         -- efficient here:
 832         --  (a) we already have the binders
 833         --  (b) we can do the triviality test before computing the free vars
 834   = go (reverse bndrs) body
 835   where
 836     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 837     go []       fun           | ok_fun fun   = Just fun         -- Success!
 838     go _        _                            = Nothing          -- Failure!
 839
 840     ok_fun fun =  exprIsTrivial fun
 841                && not (any (`elemVarSet` (exprFreeVars fun)) bndrs)
 842                && (exprIsHNF fun || all ok_lam bndrs)
 843     ok_lam v = isTyVar v || isDictId v
 844         -- The exprIsHNF is because eta reduction is not
 845         -- valid in general:  \x. bot  /=  bot
 846         -- So we need to be sure that the "fun" is a value.
 847         --
 848         -- However, we always want to reduce (/\a -> f a) to f
 849         -- This came up in a RULE: foldr (build (/\a -> g a))
 850         --      did not match      foldr (build (/\b -> ...something complex...))
 851         -- The type checker can insert these eta-expanded versions,
 852         -- with both type and dictionary lambdas; hence the slightly
 853         -- ad-hoc isDictTy
 854
 855     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 856 \end{code}
 857
 858
 859         Try eta expansion for RHSs
 860
 861 We go for:
 862    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 863                                  (n >= 0)
 864
 865 where (in both cases)
 866
 867         * The xi can include type variables
 868
 869         * The yi are all value variables
 870
 871         * N is a NORMAL FORM (i.e. no redexes anywhere)
 872           wanting a suitable number of extra args.
 873
 874 We may have to sandwich some coerces between the lambdas
 875 to make the types work.   exprEtaExpandArity looks through coerces
 876 when computing arity; and etaExpand adds the coerces as necessary when
 877 actually computing the expansion.
 878
 879 \begin{code}
 880 tryEtaExpansion :: OutExpr -> SimplM OutExpr
 881 -- There is at least one runtime binder in the binders
 882 tryEtaExpansion body
 883   = getUniquesSmpl                      `thenSmpl` \ us ->
 884     returnSmpl (etaExpand fun_arity us body (exprType body))
 885   where
 886     fun_arity = exprEtaExpandArity body
 887 \end{code}
 888
 889
 890 %************************************************************************
 891 %*                                                                      *
 892 \subsection{Floating lets out of big lambdas}
 893 %*                                                                      *
 894 %************************************************************************
 895
 896 tryRhsTyLam tries this transformation, when the big lambda appears as
 897 the RHS of a let(rec) binding:
 898
 899         /\abc -> let(rec) x = e in b
 900    ==>
 901         let(rec) x' = /\abc -> let x = x' a b c in e
 902         in
 903         /\abc -> let x = x' a b c in b
 904
 905 This is good because it can turn things like:
 906
 907         let f = /\a -> letrec g = ... g ... in g
 908 into
 909         letrec g' = /\a -> ... g' a ...
 910         in
 911         let f = /\ a -> g' a
 912
 913 which is better.  In effect, it means that big lambdas don't impede
 914 let-floating.
 915
 916 This optimisation is CRUCIAL in eliminating the junk introduced by
 917 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 918
 919 So far as the implementation is concerned:
 920
 921         Invariant: go F e = /\tvs -> F e
 922
 923         Equalities:
 924                 go F (Let x=e in b)
 925                 = Let x' = /\tvs -> F e
 926                   in
 927                   go G b
 928                 where
 929                     G = F . Let x = x' tvs
 930
 931                 go F (Letrec xi=ei in b)
 932                 = Letrec {xi' = /\tvs -> G ei}
 933                   in
 934                   go G b
 935                 where
 936                   G = F . Let {xi = xi' tvs}
 937
 938 [May 1999]  If we do this transformation *regardless* then we can
 939 end up with some pretty silly stuff.  For example,
 940
 941         let
 942             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
 943         in ..
 944 becomes
 945         let y1 = /\s -> r1
 946             y2 = /\s -> r2
 947             st = /\s -> ...[y1 s/x1, y2 s/x2]
 948         in ..
 949
 950 Unless the "..." is a WHNF there is really no point in doing this.
 951 Indeed it can make things worse.  Suppose x1 is used strictly,
 952 and is of the form
 953
 954         x1* = case f y of { (a,b) -> e }
 955
 956 If we abstract this wrt the tyvar we then can't do the case inline
 957 as we would normally do.
 958
 959
 960 \begin{code}
 961 {-      Trying to do this in full laziness
 962
 963 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
 964 -- Call ensures that all the binders are type variables
 965
 966 tryRhsTyLam env tyvars body             -- Only does something if there's a let
 967   |  not (all isTyVar tyvars)
 968   || not (worth_it body)                -- inside a type lambda,
 969   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
 970
 971   | otherwise
 972   = go env (\x -> x) body
 973
 974   where
 975     worth_it e@(Let _ _) = whnf_in_middle e
 976     worth_it e           = False
 977
 978     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
 979     whnf_in_middle (Let _ e) = whnf_in_middle e
 980     whnf_in_middle e         = exprIsCheap e
 981
 982     main_tyvar_set = mkVarSet tyvars
 983
 984     go env fn (Let bind@(NonRec var rhs) body)
 985       | exprIsTrivial rhs
 986       = go env (fn . Let bind) body
 987
 988     go env fn (Let (NonRec var rhs) body)
 989       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
 990         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env ->
 991         go env (fn . Let (mk_silly_bind var rhs')) body
 992
 993       where
 994
 995         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
 996                 -- Abstract only over the type variables free in the rhs
 997                 -- wrt which the new binding is abstracted.  But the naive
 998                 -- approach of abstract wrt the tyvars free in the Id's type
 999                 -- fails. Consider:
1000                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1001                 --                    x :: a     = fst t
1002                 --                in ...
1003                 -- Here, b isn't free in x's type, but we must nevertheless
1004                 -- abstract wrt b as well, because t's type mentions b.
1005                 -- Since t is floated too, we'd end up with the bogus:
1006                 --      poly_t = /\ a b -> (e1, e2)
1007                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1008                 -- So for now we adopt the even more naive approach of
1009                 -- abstracting wrt *all* the tyvars.  We'll see if that
1010                 -- gives rise to problems.   SLPJ June 98
1011
1012     go env fn (Let (Rec prs) body)
1013        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
1014          let
1015             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
1016             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
1017          in
1018          addAuxiliaryBind env (Rec pairs)               $ \ env ->
1019          go env gn body
1020        where
1021          (vars,rhss) = unzip prs
1022          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
1023                 -- See notes with tyvars_here above
1024
1025     go env fn body = returnSmpl (emptyFloats env, fn body)
1026
1027     mk_poly tyvars_here var
1028       = getUniqueSmpl           `thenSmpl` \ uniq ->
1029         let
1030             poly_name = setNameUnique (idName var) uniq         -- Keep same name
1031             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
1032             poly_id   = mkLocalId poly_name poly_ty
1033
1034                 -- In the olden days, it was crucial to copy the occInfo of the original var,
1035                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1036                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1037                 -- at already simplified code, so it doesn't matter
1038                 --
1039                 -- It's even right to retain single-occurrence or dead-var info:
1040                 -- Suppose we started with  /\a -> let x = E in B
1041                 -- where x occurs once in B. Then we transform to:
1042                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1043                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1044                 -- the occurrences of x' will be just the occurrences originally
1045                 -- pinned on x.
1046         in
1047         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
1048
1049     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
1050                 -- Suppose we start with:
1051                 --
1052                 --      x = /\ a -> let g = G in E
1053                 --
1054                 -- Then we'll float to get
1055                 --
1056                 --      x = let poly_g = /\ a -> G
1057                 --          in /\ a -> let g = poly_g a in E
1058                 --
1059                 -- But now the occurrence analyser will see just one occurrence
1060                 -- of poly_g, not inside a lambda, so the simplifier will
1061                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1062                 -- (I used to think that the "don't inline lone occurrences" stuff
1063                 --  would stop this happening, but since it's the *only* occurrence,
1064                 --  PreInlineUnconditionally kicks in first!)
1065                 --
1066                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1067                 --           to appear many times.  (NB: mkInlineMe eliminates
1068                 --           such notes on trivial RHSs, so do it manually.)
1069 -}
1070 \end{code}
1071
1072 %************************************************************************
1073 %*                                                                      *
1074 \subsection{Case absorption and identity-case elimination}
1075 %*                                                                      *
1076 %************************************************************************
1077
1078 mkCase puts a case expression back together, trying various transformations first.
1079
1080 \begin{code}
1081 mkCase :: OutExpr -> OutId -> OutType
1082        -> [OutAlt]              -- Increasing order
1083        -> SimplM OutExpr
1084
1085 mkCase scrut case_bndr ty alts
1086   = getDOptsSmpl                        `thenSmpl` \dflags ->
1087     mkAlts dflags scrut case_bndr alts  `thenSmpl` \ better_alts ->
1088     mkCase1 scrut case_bndr ty better_alts
1089 \end{code}
1090
1091
1092 mkAlts tries these things:
1093
1094 1.  If several alternatives are identical, merge them into
1095     a single DEFAULT alternative.  I've occasionally seen this
1096     making a big difference:
1097
1098         case e of               =====>     case e of
1099           C _ -> f x                         D v -> ....v....
1100           D v -> ....v....                   DEFAULT -> f x
1101           DEFAULT -> f x
1102
1103    The point is that we merge common RHSs, at least for the DEFAULT case.
1104    [One could do something more elaborate but I've never seen it needed.]
1105    To avoid an expensive test, we just merge branches equal to the *first*
1106    alternative; this picks up the common cases
1107         a) all branches equal
1108         b) some branches equal to the DEFAULT (which occurs first)
1109
1110 2.  Case merging:
1111        case e of b {             ==>   case e of b {
1112          p1 -> rhs1                      p1 -> rhs1
1113          ...                             ...
1114          pm -> rhsm                      pm -> rhsm
1115          _  -> case b of b' {            pn -> let b'=b in rhsn
1116                      pn -> rhsn          ...
1117                      ...                 po -> let b'=b in rhso
1118                      po -> rhso          _  -> let b'=b in rhsd
1119                      _  -> rhsd
1120        }
1121
1122     which merges two cases in one case when -- the default alternative of
1123     the outer case scrutises the same variable as the outer case This
1124     transformation is called Case Merging.  It avoids that the same
1125     variable is scrutinised multiple times.
1126
1127
1128 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1129
1130         x | p `is` 1 -> e1
1131           | p `is` 2 -> e2
1132         ...etc...
1133
1134 where @is@ was something like
1135
1136         p `is` n = p /= (-1) && p == n
1137
1138 This gave rise to a horrible sequence of cases
1139
1140         case p of
1141           (-1) -> $j p
1142           1    -> e1
1143           DEFAULT -> $j p
1144
1145 and similarly in cascade for all the join points!
1146
1147
1148
1149 \begin{code}
1150 --------------------------------------------------
1151 --      1. Merge identical branches
1152 --------------------------------------------------
1153 mkAlts dflags scrut case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1154   | all isDeadBinder bndrs1,                    -- Remember the default
1155     length filtered_alts < length con_alts      -- alternative comes first
1156   = tick (AltMerge case_bndr)                   `thenSmpl_`
1157     returnSmpl better_alts
1158   where
1159     filtered_alts        = filter keep con_alts
1160     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1161     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
1162
1163
1164 --------------------------------------------------
1165 --      2.  Merge nested cases
1166 --------------------------------------------------
1167
1168 mkAlts dflags scrut outer_bndr outer_alts
1169   | dopt Opt_CaseMerge dflags,
1170     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
1171     Just (Case (Var scrut_var) inner_bndr _ inner_alts) <- maybe_outer_deflt,
1172     scruting_same_var scrut_var
1173   = let
1174         munged_inner_alts = [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts]
1175         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1176
1177         new_alts = mergeAlts outer_alts_without_deflt munged_inner_alts
1178                 -- The merge keeps the inner DEFAULT at the front, if there is one
1179                 -- and eliminates any inner_alts that are shadowed by the outer_alts
1180     in
1181     tick (CaseMerge outer_bndr)                         `thenSmpl_`
1182     returnSmpl new_alts
1183         -- Warning: don't call mkAlts recursively!
1184         -- Firstly, there's no point, because inner alts have already had
1185         -- mkCase applied to them, so they won't have a case in their default
1186         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1187         -- in munge_rhs may put a case into the DEFAULT branch!
1188   where
1189         -- We are scrutinising the same variable if it's
1190         -- the outer case-binder, or if the outer case scrutinises a variable
1191         -- (and it's the same).  Testing both allows us not to replace the
1192         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
1193     scruting_same_var = case scrut of
1194                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
1195                           other           -> \ v -> v == outer_bndr
1196
1197 ------------------------------------------------
1198 --      Catch-all
1199 ------------------------------------------------
1200
1201 mkAlts dflags scrut case_bndr other_alts = returnSmpl other_alts
1202 \end{code}
1203
1204
1205
1206 =================================================================================
1207
1208 mkCase1 tries these things
1209
1210 1.  Eliminate the case altogether if possible
1211
1212 2.  Case-identity:
1213
1214         case e of               ===> e
1215                 True  -> True;
1216                 False -> False
1217
1218     and similar friends.
1219
1220
1221 Start with a simple situation:
1222
1223         case x# of      ===>   e[x#/y#]
1224           y# -> e
1225
1226 (when x#, y# are of primitive type, of course).  We can't (in general)
1227 do this for algebraic cases, because we might turn bottom into
1228 non-bottom!
1229
1230 Actually, we generalise this idea to look for a case where we're
1231 scrutinising a variable, and we know that only the default case can
1232 match.  For example:
1233 \begin{verbatim}
1234         case x of
1235           0#    -> ...
1236           other -> ...(case x of
1237                          0#    -> ...
1238                          other -> ...) ...
1239 \end{code}
1240 Here the inner case can be eliminated.  This really only shows up in
1241 eliminating error-checking code.
1242
1243 We also make sure that we deal with this very common case:
1244
1245         case e of
1246           x -> ...x...
1247
1248 Here we are using the case as a strict let; if x is used only once
1249 then we want to inline it.  We have to be careful that this doesn't
1250 make the program terminate when it would have diverged before, so we
1251 check that
1252         - x is used strictly, or
1253         - e is already evaluated (it may so if e is a variable)
1254
1255 Lastly, we generalise the transformation to handle this:
1256
1257         case e of       ===> r
1258            True  -> r
1259            False -> r
1260
1261 We only do this for very cheaply compared r's (constructors, literals
1262 and variables).  If pedantic bottoms is on, we only do it when the
1263 scrutinee is a PrimOp which can't fail.
1264
1265 We do it *here*, looking at un-simplified alternatives, because we
1266 have to check that r doesn't mention the variables bound by the
1267 pattern in each alternative, so the binder-info is rather useful.
1268
1269 So the case-elimination algorithm is:
1270
1271         1. Eliminate alternatives which can't match
1272
1273         2. Check whether all the remaining alternatives
1274                 (a) do not mention in their rhs any of the variables bound in their pattern
1275            and  (b) have equal rhss
1276
1277         3. Check we can safely ditch the case:
1278                    * PedanticBottoms is off,
1279                 or * the scrutinee is an already-evaluated variable
1280                 or * the scrutinee is a primop which is ok for speculation
1281                         -- ie we want to preserve divide-by-zero errors, and
1282                         -- calls to error itself!
1283
1284                 or * [Prim cases] the scrutinee is a primitive variable
1285
1286                 or * [Alg cases] the scrutinee is a variable and
1287                      either * the rhs is the same variable
1288                         (eg case x of C a b -> x  ===>   x)
1289                      or     * there is only one alternative, the default alternative,
1290                                 and the binder is used strictly in its scope.
1291                                 [NB this is helped by the "use default binder where
1292                                  possible" transformation; see below.]
1293
1294
1295 If so, then we can replace the case with one of the rhss.
1296
1297 Further notes about case elimination
1298 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1299 Consider:       test :: Integer -> IO ()
1300                 test = print
1301
1302 Turns out that this compiles to:
1303     Print.test
1304       = \ eta :: Integer
1305           eta1 :: State# RealWorld ->
1306           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1307           case hPutStr stdout
1308                  (PrelNum.jtos eta ($w[] @ Char))
1309                  eta1
1310           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1311
1312 Notice the strange '<' which has no effect at all. This is a funny one.
1313 It started like this:
1314
1315 f x y = if x < 0 then jtos x
1316           else if y==0 then "" else jtos x
1317
1318 At a particular call site we have (f v 1).  So we inline to get
1319
1320         if v < 0 then jtos x
1321         else if 1==0 then "" else jtos x
1322
1323 Now simplify the 1==0 conditional:
1324
1325         if v<0 then jtos v else jtos v
1326
1327 Now common-up the two branches of the case:
1328
1329         case (v<0) of DEFAULT -> jtos v
1330
1331 Why don't we drop the case?  Because it's strict in v.  It's technically
1332 wrong to drop even unnecessary evaluations, and in practice they
1333 may be a result of 'seq' so we *definitely* don't want to drop those.
1334 I don't really know how to improve this situation.
1335
1336
1337 \begin{code}
1338 --------------------------------------------------
1339 --      0. Check for empty alternatives
1340 --------------------------------------------------
1341
1342 -- This isn't strictly an error.  It's possible that the simplifer might "see"
1343 -- that an inner case has no accessible alternatives before it "sees" that the
1344 -- entire branch of an outer case is inaccessible.  So we simply
1345 -- put an error case here insteadd
1346 mkCase1 scrut case_bndr ty []
1347   = pprTrace "mkCase1: null alts" (ppr case_bndr <+> ppr scrut) $
1348     return (mkApps (Var eRROR_ID)
1349                    [Type ty, Lit (mkStringLit "Impossible alternative")])
1350
1351 --------------------------------------------------
1352 --      1. Eliminate the case altogether if poss
1353 --------------------------------------------------
1354
1355 mkCase1 scrut case_bndr ty [(con,bndrs,rhs)]
1356   -- See if we can get rid of the case altogether
1357   -- See the extensive notes on case-elimination above
1358   -- mkCase made sure that if all the alternatives are equal,
1359   -- then there is now only one (DEFAULT) rhs
1360  |  all isDeadBinder bndrs,
1361
1362         -- Check that the scrutinee can be let-bound instead of case-bound
1363     exprOkForSpeculation scrut
1364                 -- OK not to evaluate it
1365                 -- This includes things like (==# a# b#)::Bool
1366                 -- so that we simplify
1367                 --      case ==# a# b# of { True -> x; False -> x }
1368                 -- to just
1369                 --      x
1370                 -- This particular example shows up in default methods for
1371                 -- comparision operations (e.g. in (>=) for Int.Int32)
1372         || exprIsHNF scrut                      -- It's already evaluated
1373         || var_demanded_later scrut             -- It'll be demanded later
1374
1375 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1376 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1377 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1378 --      its argument:  case x of { y -> dataToTag# y }
1379 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1380 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1381 --      other problems
1382 --      Also we don't want to discard 'seq's
1383   = tick (CaseElim case_bndr)                   `thenSmpl_`
1384     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1385
1386   where
1387         -- The case binder is going to be evaluated later,
1388         -- and the scrutinee is a simple variable
1389     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1390     var_demanded_later other   = False
1391
1392
1393 --------------------------------------------------
1394 --      2. Identity case
1395 --------------------------------------------------
1396
1397 mkCase1 scrut case_bndr ty alts -- Identity case
1398   | all identity_alt alts
1399   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1400     returnSmpl (re_note scrut)
1401   where
1402     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
1403
1404     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
1405     identity_rhs (LitAlt lit)  _    = Lit lit
1406     identity_rhs DEFAULT       _    = Var case_bndr
1407
1408     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1409
1410         -- We've seen this:
1411         --      case coerce T e of x { _ -> coerce T' x }
1412         -- And we definitely want to eliminate this case!
1413         -- So we throw away notes from the RHS, and reconstruct
1414         -- (at least an approximation) at the other end
1415     de_note (Note _ e) = de_note e
1416     de_note e          = e
1417
1418         -- re_note wraps a coerce if it might be necessary
1419     re_note scrut = case head alts of
1420                         (_,_,rhs1@(Note _ _)) -> mkCoerce2 (exprType rhs1) (idType case_bndr) scrut
1421                         other                 -> scrut
1422
1423
1424 --------------------------------------------------
1425 --      Catch-all
1426 --------------------------------------------------
1427 mkCase1 scrut bndr ty alts = returnSmpl (Case scrut bndr ty alts)
1428 \end{code}
1429
1430
1431 When adding auxiliary bindings for the case binder, it's worth checking if
1432 its dead, because it often is, and occasionally these mkCase transformations
1433 cascade rather nicely.
1434
1435 \begin{code}
1436 bindCaseBndr bndr rhs body
1437   | isDeadBinder bndr = body
1438   | otherwise         = bindNonRec bndr rhs body
1439 \end{code}