compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         -- Rebuilding
   9         mkLam, mkCase, prepareAlts, bindCaseBndr,
  10
  11         -- Inlining,
  12         preInlineUnconditionally, postInlineUnconditionally,
  13         activeInline, activeRule,
  14         simplEnvForGHCi, simplEnvForRules, simplGentlyForInlineRules,
  15
  16         -- The continuation type
  17         SimplCont(..), DupFlag(..), ArgInfo(..),
  18         contIsDupable, contResultType, contIsTrivial, contArgs, dropArgs,
  19         countValArgs, countArgs,
  20         mkBoringStop, mkRhsStop, mkLazyArgStop, contIsRhsOrArg,
  21         interestingCallContext,
  22
  23         interestingArg, mkArgInfo,
  24
  25         abstractFloats
  26     ) where
  27
  28 #include "HsVersions.h"
  29
  30 import SimplEnv
  31 import DynFlags
  32 import StaticFlags
  33 import CoreSyn
  34 import qualified CoreSubst
  35 import PprCore
  36 import CoreFVs
  37 import CoreUtils
  38 import CoreArity        ( etaExpand, exprEtaExpandArity )
  39 import CoreUnfold
  40 import Name
  41 import Id
  42 import Var      ( isCoVar )
  43 import NewDemand
  44 import SimplMonad
  45 import Type     hiding( substTy )
  46 import Coercion ( coercionKind )
  47 import TyCon
  48 import Unify    ( dataConCannotMatch )
  49 import VarSet
  50 import BasicTypes
  51 import Util
  52 import MonadUtils
  53 import Outputable
  54 import FastString
  55
  56 import Data.List
  57 \end{code}
  58
  59
  60 %************************************************************************
  61 %*                                                                      *
  62                 The SimplCont type
  63 %*                                                                      *
  64 %************************************************************************
  65
  66 A SimplCont allows the simplifier to traverse the expression in a
  67 zipper-like fashion.  The SimplCont represents the rest of the expression,
  68 "above" the point of interest.
  69
  70 You can also think of a SimplCont as an "evaluation context", using
  71 that term in the way it is used for operational semantics. This is the
  72 way I usually think of it, For example you'll often see a syntax for
  73 evaluation context looking like
  74         C ::= []  |  C e   |  case C of alts  |  C `cast` co
  75 That's the kind of thing we are doing here, and I use that syntax in
  76 the comments.
  77
  78
  79 Key points:
  80   * A SimplCont describes a *strict* context (just like
  81     evaluation contexts do).  E.g. Just [] is not a SimplCont
  82
  83   * A SimplCont describes a context that *does not* bind
  84     any variables.  E.g. \x. [] is not a SimplCont
  85
  86 \begin{code}
  87 data SimplCont
  88   = Stop                -- An empty context, or hole, []
  89         CallCtxt        -- True <=> There is something interesting about
  90                         --          the context, and hence the inliner
  91                         --          should be a bit keener (see interestingCallContext)
  92                         -- Specifically:
  93                         --     This is an argument of a function that has RULES
  94                         --     Inlining the call might allow the rule to fire
  95
  96   | CoerceIt            -- C `cast` co
  97         OutCoercion             -- The coercion simplified
  98         SimplCont
  99
 100   | ApplyTo             -- C arg
 101         DupFlag
 102         InExpr SimplEnv         -- The argument and its static env
 103         SimplCont
 104
 105   | Select              -- case C of alts
 106         DupFlag
 107         InId [InAlt] SimplEnv   -- The case binder, alts, and subst-env
 108         SimplCont
 109
 110   -- The two strict forms have no DupFlag, because we never duplicate them
 111   | StrictBind          -- (\x* \xs. e) C
 112         InId [InBndr]           -- let x* = [] in e
 113         InExpr SimplEnv         --      is a special case
 114         SimplCont
 115
 116   | StrictArg           -- e C
 117         OutExpr                 -- e; *always* of form (Var v `App1` e1 .. `App` en)
 118         CallCtxt                -- Whether *this* argument position is interesting
 119         ArgInfo                 -- Whether the function at the head of e has rules, etc
 120         SimplCont               --     plus strictness flags for *further* args
 121
 122 data ArgInfo
 123   = ArgInfo {
 124         ai_rules :: Bool,       -- Function has rules (recursively)
 125                                 --      => be keener to inline in all args
 126         ai_strs :: [Bool],      -- Strictness of arguments
 127                                 --   Usually infinite, but if it is finite it guarantees
 128                                 --   that the function diverges after being given
 129                                 --   that number of args
 130         ai_discs :: [Int]       -- Discounts for arguments; non-zero => be keener to inline
 131                                 --   Always infinite
 132     }
 133
 134 instance Outputable SimplCont where
 135   ppr (Stop interesting)             = ptext (sLit "Stop") <> brackets (ppr interesting)
 136   ppr (ApplyTo dup arg _ cont)       = ((ptext (sLit "ApplyTo") <+> ppr dup <+> pprParendExpr arg)
 137                                           {-  $$ nest 2 (pprSimplEnv se) -}) $$ ppr cont
 138   ppr (StrictBind b _ _ _ cont)      = (ptext (sLit "StrictBind") <+> ppr b) $$ ppr cont
 139   ppr (StrictArg f _ _ cont)         = (ptext (sLit "StrictArg") <+> ppr f) $$ ppr cont
 140   ppr (Select dup bndr alts _ cont)  = (ptext (sLit "Select") <+> ppr dup <+> ppr bndr) $$
 141                                        (nest 4 (ppr alts)) $$ ppr cont
 142   ppr (CoerceIt co cont)             = (ptext (sLit "CoerceIt") <+> ppr co) $$ ppr cont
 143
 144 data DupFlag = OkToDup | NoDup
 145
 146 instance Outputable DupFlag where
 147   ppr OkToDup = ptext (sLit "ok")
 148   ppr NoDup   = ptext (sLit "nodup")
 149
 150
 151
 152 -------------------
 153 mkBoringStop :: SimplCont
 154 mkBoringStop = Stop BoringCtxt
 155
 156 mkRhsStop :: SimplCont  -- See Note [RHS of lets] in CoreUnfold
 157 mkRhsStop = Stop (ArgCtxt False)
 158
 159 mkLazyArgStop :: CallCtxt -> SimplCont
 160 mkLazyArgStop cci = Stop cci
 161
 162 -------------------
 163 contIsRhsOrArg :: SimplCont -> Bool
 164 contIsRhsOrArg (Stop {})       = True
 165 contIsRhsOrArg (StrictBind {}) = True
 166 contIsRhsOrArg (StrictArg {})  = True
 167 contIsRhsOrArg _               = False
 168
 169 -------------------
 170 contIsDupable :: SimplCont -> Bool
 171 contIsDupable (Stop {})                  = True
 172 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 173 contIsDupable (Select   OkToDup _ _ _ _) = True
 174 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 175 contIsDupable _                          = False
 176
 177 -------------------
 178 contIsTrivial :: SimplCont -> Bool
 179 contIsTrivial (Stop {})                   = True
 180 contIsTrivial (ApplyTo _ (Type _) _ cont) = contIsTrivial cont
 181 contIsTrivial (CoerceIt _ cont)           = contIsTrivial cont
 182 contIsTrivial _                           = False
 183
 184 -------------------
 185 contResultType :: SimplEnv -> OutType -> SimplCont -> OutType
 186 contResultType env ty cont
 187   = go cont ty
 188   where
 189     subst_ty se ty = substTy (se `setInScope` env) ty
 190
 191     go (Stop {})                      ty = ty
 192     go (CoerceIt co cont)             _  = go cont (snd (coercionKind co))
 193     go (StrictBind _ bs body se cont) _  = go cont (subst_ty se (exprType (mkLams bs body)))
 194     go (StrictArg fn _ _ cont)        _  = go cont (funResultTy (exprType fn))
 195     go (Select _ _ alts se cont)      _  = go cont (subst_ty se (coreAltsType alts))
 196     go (ApplyTo _ arg se cont)        ty = go cont (apply_to_arg ty arg se)
 197
 198     apply_to_arg ty (Type ty_arg) se = applyTy ty (subst_ty se ty_arg)
 199     apply_to_arg ty _             _  = funResultTy ty
 200
 201 -------------------
 202 countValArgs :: SimplCont -> Int
 203 countValArgs (ApplyTo _ (Type _) _ cont) = countValArgs cont
 204 countValArgs (ApplyTo _ _        _ cont) = 1 + countValArgs cont
 205 countValArgs _                           = 0
 206
 207 countArgs :: SimplCont -> Int
 208 countArgs (ApplyTo _ _ _ cont) = 1 + countArgs cont
 209 countArgs _                    = 0
 210
 211 contArgs :: SimplCont -> ([OutExpr], SimplCont)
 212 -- Uses substitution to turn each arg into an OutExpr
 213 contArgs cont = go [] cont
 214   where
 215     go args (ApplyTo _ arg se cont) = go (substExpr se arg : args) cont
 216     go args cont                    = (reverse args, cont)
 217
 218 dropArgs :: Int -> SimplCont -> SimplCont
 219 dropArgs 0 cont = cont
 220 dropArgs n (ApplyTo _ _ _ cont) = dropArgs (n-1) cont
 221 dropArgs n other                = pprPanic "dropArgs" (ppr n <+> ppr other)
 222 \end{code}
 223
 224
 225 Note [Interesting call context]
 226 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 227 We want to avoid inlining an expression where there can't possibly be
 228 any gain, such as in an argument position.  Hence, if the continuation
 229 is interesting (eg. a case scrutinee, application etc.) then we
 230 inline, otherwise we don't.
 231
 232 Previously some_benefit used to return True only if the variable was
 233 applied to some value arguments.  This didn't work:
 234
 235         let x = _coerce_ (T Int) Int (I# 3) in
 236         case _coerce_ Int (T Int) x of
 237                 I# y -> ....
 238
 239 we want to inline x, but can't see that it's a constructor in a case
 240 scrutinee position, and some_benefit is False.
 241
 242 Another example:
 243
 244 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 245
 246 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 247
 248 we'd really like to inline dMonadST here, but we *don't* want to
 249 inline if the case expression is just
 250
 251         case x of y { DEFAULT -> ... }
 252
 253 since we can just eliminate this case instead (x is in WHNF).  Similar
 254 applies when x is bound to a lambda expression.  Hence
 255 contIsInteresting looks for case expressions with just a single
 256 default case.
 257
 258
 259 \begin{code}
 260 interestingCallContext :: SimplCont -> CallCtxt
 261 -- See Note [Interesting call context]
 262 interestingCallContext cont
 263   = interesting cont
 264   where
 265     interesting (Select _ bndr _ _ _)
 266         | isDeadBinder bndr = CaseCtxt
 267         | otherwise         = ArgCtxt False     -- If the binder is used, this
 268                                                 -- is like a strict let
 269                                                 -- See Note [RHS of lets] in CoreUnfold
 270
 271     interesting (ApplyTo _ arg _ cont)
 272         | isTypeArg arg = interesting cont
 273         | otherwise     = ValAppCtxt    -- Can happen if we have (f Int |> co) y
 274                                         -- If f has an INLINE prag we need to give it some
 275                                         -- motivation to inline. See Note [Cast then apply]
 276                                         -- in CoreUnfold
 277
 278     interesting (StrictArg _ cci _ _)   = cci
 279     interesting (StrictBind {})         = BoringCtxt
 280     interesting (Stop cci)              = cci
 281     interesting (CoerceIt _ cont)       = interesting cont
 282         -- If this call is the arg of a strict function, the context
 283         -- is a bit interesting.  If we inline here, we may get useful
 284         -- evaluation information to avoid repeated evals: e.g.
 285         --      x + (y * z)
 286         -- Here the contIsInteresting makes the '*' keener to inline,
 287         -- which in turn exposes a constructor which makes the '+' inline.
 288         -- Assuming that +,* aren't small enough to inline regardless.
 289         --
 290         -- It's also very important to inline in a strict context for things
 291         -- like
 292         --              foldr k z (f x)
 293         -- Here, the context of (f x) is strict, and if f's unfolding is
 294         -- a build it's *great* to inline it here.  So we must ensure that
 295         -- the context for (f x) is not totally uninteresting.
 296
 297
 298 -------------------
 299 mkArgInfo :: Id
 300           -> [CoreRule] -- Rules for function
 301           -> Int        -- Number of value args
 302           -> SimplCont  -- Context of the call
 303           -> ArgInfo
 304
 305 mkArgInfo fun rules n_val_args call_cont
 306   | n_val_args < idArity fun            -- Note [Unsaturated functions]
 307   = ArgInfo { ai_rules = False
 308             , ai_strs = vanilla_stricts
 309             , ai_discs = vanilla_discounts }
 310   | otherwise
 311   = ArgInfo { ai_rules = interestingArgContext rules call_cont
 312             , ai_strs  = add_type_str (idType fun) arg_stricts
 313             , ai_discs = arg_discounts }
 314   where
 315     vanilla_discounts, arg_discounts :: [Int]
 316     vanilla_discounts = repeat 0
 317     arg_discounts = case idUnfolding fun of
 318                         CoreUnfolding {uf_guidance = UnfoldIfGoodArgs {ug_args = discounts}}
 319                               -> discounts ++ vanilla_discounts
 320                         _     -> vanilla_discounts
 321
 322     vanilla_stricts, arg_stricts :: [Bool]
 323     vanilla_stricts  = repeat False
 324
 325     arg_stricts
 326       = case splitStrictSig (idNewStrictness fun) of
 327           (demands, result_info)
 328                 | not (demands `lengthExceeds` n_val_args)
 329                 ->      -- Enough args, use the strictness given.
 330                         -- For bottoming functions we used to pretend that the arg
 331                         -- is lazy, so that we don't treat the arg as an
 332                         -- interesting context.  This avoids substituting
 333                         -- top-level bindings for (say) strings into
 334                         -- calls to error.  But now we are more careful about
 335                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 336                    if isBotRes result_info then
 337                         map isStrictDmd demands         -- Finite => result is bottom
 338                    else
 339                         map isStrictDmd demands ++ vanilla_stricts
 340                | otherwise
 341                -> WARN( True, text "More demands than arity" <+> ppr fun <+> ppr (idArity fun)
 342                                 <+> ppr n_val_args <+> ppr demands )
 343                    vanilla_stricts      -- Not enough args, or no strictness
 344
 345     add_type_str :: Type -> [Bool] -> [Bool]
 346     -- If the function arg types are strict, record that in the 'strictness bits'
 347     -- No need to instantiate because unboxed types (which dominate the strict
 348     -- types) can't instantiate type variables.
 349     -- add_type_str is done repeatedly (for each call); might be better
 350     -- once-for-all in the function
 351     -- But beware primops/datacons with no strictness
 352     add_type_str _ [] = []
 353     add_type_str fun_ty strs            -- Look through foralls
 354         | Just (_, fun_ty') <- splitForAllTy_maybe fun_ty       -- Includes coercions
 355         = add_type_str fun_ty' strs
 356     add_type_str fun_ty (str:strs)      -- Add strict-type info
 357         | Just (arg_ty, fun_ty') <- splitFunTy_maybe fun_ty
 358         = (str || isStrictType arg_ty) : add_type_str fun_ty' strs
 359     add_type_str _ strs
 360         = strs
 361
 362 {- Note [Unsaturated functions]
 363   ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 364 Consider (test eyeball/inline4)
 365         x = a:as
 366         y = f x
 367 where f has arity 2.  Then we do not want to inline 'x', because
 368 it'll just be floated out again.  Even if f has lots of discounts
 369 on its first argument -- it must be saturated for these to kick in
 370 -}
 371
 372 interestingArgContext :: [CoreRule] -> SimplCont -> Bool
 373 -- If the argument has form (f x y), where x,y are boring,
 374 -- and f is marked INLINE, then we don't want to inline f.
 375 -- But if the context of the argument is
 376 --      g (f x y)
 377 -- where g has rules, then we *do* want to inline f, in case it
 378 -- exposes a rule that might fire.  Similarly, if the context is
 379 --      h (g (f x x))
 380 -- where h has rules, then we do want to inline f; hence the
 381 -- call_cont argument to interestingArgContext
 382 --
 383 -- The ai-rules flag makes this happen; if it's
 384 -- set, the inliner gets just enough keener to inline f
 385 -- regardless of how boring f's arguments are, if it's marked INLINE
 386 --
 387 -- The alternative would be to *always* inline an INLINE function,
 388 -- regardless of how boring its context is; but that seems overkill
 389 -- For example, it'd mean that wrapper functions were always inlined
 390 interestingArgContext rules call_cont
 391   = notNull rules || enclosing_fn_has_rules
 392   where
 393     enclosing_fn_has_rules = go call_cont
 394
 395     go (Select {})           = False
 396     go (ApplyTo {})          = False
 397     go (StrictArg _ cci _ _) = interesting cci
 398     go (StrictBind {})       = False    -- ??
 399     go (CoerceIt _ c)        = go c
 400     go (Stop cci)            = interesting cci
 401
 402     interesting (ArgCtxt rules) = rules
 403     interesting _               = False
 404 \end{code}
 405
 406
 407
 408 %************************************************************************
 409 %*                                                                      *
 410 \subsection{Decisions about inlining}
 411 %*                                                                      *
 412 %************************************************************************
 413
 414 \begin{code}
 415 simplEnvForGHCi :: SimplEnv
 416 simplEnvForGHCi = mkSimplEnv allOffSwitchChecker $
 417                   SimplGently { sm_rules = False, sm_inline = False }
 418    -- Do not do any inlining, in case we expose some unboxed
 419    -- tuple stuff that confuses the bytecode interpreter
 420
 421 simplEnvForRules :: SimplEnv
 422 simplEnvForRules = mkSimplEnv allOffSwitchChecker $
 423                    SimplGently { sm_rules = True, sm_inline = False }
 424
 425 simplGentlyForInlineRules :: SimplifierMode
 426 simplGentlyForInlineRules = SimplGently { sm_rules = True, sm_inline = True }
 427         -- Simplify as much as possible, subject to the usual "gentle" rules
 428 \end{code}
 429
 430 Inlining is controlled partly by the SimplifierMode switch.  This has two
 431 settings
 432
 433         SimplGently     (a) Simplifying before specialiser/full laziness
 434                         (b) Simplifiying inside InlineRules
 435                         (c) Simplifying the LHS of a rule
 436                         (d) Simplifying a GHCi expression or Template
 437                                 Haskell splice
 438
 439         SimplPhase n _   Used at all other times
 440
 441 Note [Gentle mode]
 442 ~~~~~~~~~~~~~~~~~~
 443 Gentle mode has a separate boolean flag to control
 444         a) inlining (sm_inline flag)
 445         b) rules    (sm_rules  flag)
 446 A key invariant about Gentle mode is that it is treated as the EARLIEST
 447 phase.  Something is inlined if the sm_inline flag is on AND the thing
 448 is inlinable in the earliest phase.  This is important. Example
 449
 450   {-# INLINE [~1] g #-}
 451   g = ...
 452
 453   {-# INLINE f #-}
 454   f x = g (g x)
 455
 456 If we were to inline g into f's inlining, then an importing module would
 457 never be able to do
 458         f e --> g (g e) ---> RULE fires
 459 because the InlineRule for f has had g inlined into it.
 460
 461 On the other hand, it is bad not to do ANY inlining into an
 462 InlineRule, because then recursive knots in instance declarations
 463 don't get unravelled.
 464
 465 However, *sometimes* SimplGently must do no call-site inlining at all.
 466 Before full laziness we must be careful not to inline wrappers,
 467 because doing so inhibits floating
 468     e.g. ...(case f x of ...)...
 469     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 470     ==> ...(case x of I# x# -> case fw x# of ...)...
 471 and now the redex (f x) isn't floatable any more.
 472
 473 The no-inlining thing is also important for Template Haskell.  You might be
 474 compiling in one-shot mode with -O2; but when TH compiles a splice before
 475 running it, we don't want to use -O2.  Indeed, we don't want to inline
 476 anything, because the byte-code interpreter might get confused about
 477 unboxed tuples and suchlike.
 478
 479 Note [Simplifying gently inside InlineRules]
 480 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 481 We don't do much simplification inside InlineRules (which come from
 482 INLINE pragmas).  It really is important to switch off inlinings
 483 inside such expressions.  Consider the following example
 484
 485         let f = \pq -> BIG
 486         in
 487         let g = \y -> f y y
 488             {-# INLINE g #-}
 489         in ...g...g...g...g...g...
 490
 491 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 492 and thence copied multiple times when g is inlined.
 493
 494 This function may be inlinined in other modules, so we don't want to
 495 remove (by inlining) calls to functions that have specialisations, or
 496 that may have transformation rules in an importing scope.
 497
 498 E.g.    {-# INLINE f #-}
 499         f x = ...g...
 500
 501 and suppose that g is strict *and* has specialisations.  If we inline
 502 g's wrapper, we deny f the chance of getting the specialised version
 503 of g when f is inlined at some call site (perhaps in some other
 504 module).
 505
 506 It's also important not to inline a worker back into a wrapper.
 507 A wrapper looks like
 508         wraper = inline_me (\x -> ...worker... )
 509 Normally, the inline_me prevents the worker getting inlined into
 510 the wrapper (initially, the worker's only call site!).  But,
 511 if the wrapper is sure to be called, the strictness analyser will
 512 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 513 continuation.  That's why the keep_inline predicate returns True for
 514 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 515 inline-me note under these circumstances.
 516
 517 Although we do very little simplification inside an InlineRule,
 518 the RHS is simplified as normal.  For example:
 519
 520         all xs = foldr (&&) True xs
 521         any p = all . map p  {-# INLINE any #-}
 522
 523 The RHS of 'any' will get optimised and deforested; but the InlineRule
 524 will still mention the original RHS.
 525
 526
 527 preInlineUnconditionally
 528 ~~~~~~~~~~~~~~~~~~~~~~~~
 529 @preInlineUnconditionally@ examines a bndr to see if it is used just
 530 once in a completely safe way, so that it is safe to discard the
 531 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 532 big the RHS might be.  If this is the case we don't simplify the RHS
 533 first, but just inline it un-simplified.
 534
 535 This is much better than first simplifying a perhaps-huge RHS and then
 536 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 537 better.  Consider
 538
 539         x1 = e1
 540         x2 = e2[x1]
 541         x3 = e3[x2]
 542         ...etc...
 543         xN = eN[xN-1]
 544
 545 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 546 This can happen with cascades of functions too:
 547
 548         f1 = \x1.e1
 549         f2 = \xs.e2[f1]
 550         f3 = \xs.e3[f3]
 551         ...etc...
 552
 553 THE MAIN INVARIANT is this:
 554
 555         ----  preInlineUnconditionally invariant -----
 556    IF preInlineUnconditionally chooses to inline x = <rhs>
 557    THEN doing the inlining should not change the occurrence
 558         info for the free vars of <rhs>
 559         ----------------------------------------------
 560
 561 For example, it's tempting to look at trivial binding like
 562         x = y
 563 and inline it unconditionally.  But suppose x is used many times,
 564 but this is the unique occurrence of y.  Then inlining x would change
 565 y's occurrence info, which breaks the invariant.  It matters: y
 566 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
 567
 568
 569 Even RHSs labelled InlineMe aren't caught here, because there might be
 570 no benefit from inlining at the call site.
 571
 572 [Sept 01] Don't unconditionally inline a top-level thing, because that
 573 can simply make a static thing into something built dynamically.  E.g.
 574         x = (a,b)
 575         main = \s -> h x
 576
 577 [Remember that we treat \s as a one-shot lambda.]  No point in
 578 inlining x unless there is something interesting about the call site.
 579
 580 But watch out: if you aren't careful, some useful foldr/build fusion
 581 can be lost (most notably in spectral/hartel/parstof) because the
 582 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 583 deal, in fact, but losing the fusion can be.  But the right thing here
 584 seems to be to do a callSiteInline based on the fact that there is
 585 something interesting about the call site (it's strict).  Hmm.  That
 586 seems a bit fragile.
 587
 588 Conclusion: inline top level things gaily until Phase 0 (the last
 589 phase), at which point don't.
 590
 591 Note [pre/postInlineUnconditionally in gentle mode]
 592 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 593 Even in gentle mode we want to do preInlineUnconditionally.  The
 594 reason is that too little clean-up happens if you don't inline
 595 use-once things.  Also a bit of inlining is *good* for full laziness;
 596 it can expose constant sub-expressions.  Example in
 597 spectral/mandel/Mandel.hs, where the mandelset function gets a useful
 598 let-float if you inline windowToViewport
 599
 600 However, as usual for Gentle mode, do not inline things that are
 601 inactive in the intial stages.  See Note [Gentle mode].
 602
 603 \begin{code}
 604 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
 605 preInlineUnconditionally env top_lvl bndr rhs
 606   | not active             = False
 607   | opt_SimplNoPreInlining = False
 608   | otherwise = case idOccInfo bndr of
 609                   IAmDead                    -> True    -- Happens in ((\x.1) v)
 610                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
 611                   _                          -> False
 612   where
 613     phase = getMode env
 614     active = case phase of
 615                    SimplGently {} -> isEarlyActive act
 616                         -- See Note [pre/postInlineUnconditionally in gentle mode]
 617                    SimplPhase n _ -> isActive n act
 618     act = idInlineActivation bndr
 619
 620     try_once in_lam int_cxt     -- There's one textual occurrence
 621         | not in_lam = isNotTopLevel top_lvl || early_phase
 622         | otherwise  = int_cxt && canInlineInLam rhs
 623
 624 -- Be very careful before inlining inside a lambda, becuase (a) we must not
 625 -- invalidate occurrence information, and (b) we want to avoid pushing a
 626 -- single allocation (here) into multiple allocations (inside lambda).
 627 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
 628 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
 629 --      where
 630 --              is_cheap = exprIsCheap rhs
 631 --              ok = is_cheap && int_cxt
 632
 633         --      int_cxt         The context isn't totally boring
 634         -- E.g. let f = \ab.BIG in \y. map f xs
 635         --      Don't want to substitute for f, because then we allocate
 636         --      its closure every time the \y is called
 637         -- But: let f = \ab.BIG in \y. map (f y) xs
 638         --      Now we do want to substitute for f, even though it's not
 639         --      saturated, because we're going to allocate a closure for
 640         --      (f y) every time round the loop anyhow.
 641
 642         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
 643         -- so substituting rhs inside a lambda doesn't change the occ info.
 644         -- Sadly, not quite the same as exprIsHNF.
 645     canInlineInLam (Lit _)              = True
 646     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
 647     canInlineInLam (Note _ e)           = canInlineInLam e
 648     canInlineInLam _                    = False
 649
 650     early_phase = case phase of
 651                         SimplPhase 0 _ -> False
 652                         _              -> True
 653 -- If we don't have this early_phase test, consider
 654 --      x = length [1,2,3]
 655 -- The full laziness pass carefully floats all the cons cells to
 656 -- top level, and preInlineUnconditionally floats them all back in.
 657 -- Result is (a) static allocation replaced by dynamic allocation
 658 --           (b) many simplifier iterations because this tickles
 659 --               a related problem; only one inlining per pass
 660 --
 661 -- On the other hand, I have seen cases where top-level fusion is
 662 -- lost if we don't inline top level thing (e.g. string constants)
 663 -- Hence the test for phase zero (which is the phase for all the final
 664 -- simplifications).  Until phase zero we take no special notice of
 665 -- top level things, but then we become more leery about inlining
 666 -- them.
 667
 668 \end{code}
 669
 670 postInlineUnconditionally
 671 ~~~~~~~~~~~~~~~~~~~~~~~~~
 672 @postInlineUnconditionally@ decides whether to unconditionally inline
 673 a thing based on the form of its RHS; in particular if it has a
 674 trivial RHS.  If so, we can inline and discard the binding altogether.
 675
 676 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 677 only have *forward* references Hence, it's safe to discard the binding
 678
 679 NOTE: This isn't our last opportunity to inline.  We're at the binding
 680 site right now, and we'll get another opportunity when we get to the
 681 ocurrence(s)
 682
 683 Note that we do this unconditional inlining only for trival RHSs.
 684 Don't inline even WHNFs inside lambdas; doing so may simply increase
 685 allocation when the function is called. This isn't the last chance; see
 686 NOTE above.
 687
 688 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 689 Because we don't even want to inline them into the RHS of constructor
 690 arguments. See NOTE above
 691
 692 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 693 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 694 with both a and b marked NOINLINE.  But that seems incompatible with
 695 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 696 story for now.
 697
 698 \begin{code}
 699 postInlineUnconditionally
 700     :: SimplEnv -> TopLevelFlag
 701     -> OutId            -- The binder (an InId would be fine too)
 702     -> OccInfo          -- From the InId
 703     -> OutExpr
 704     -> Unfolding
 705     -> Bool
 706 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
 707   | not active             = False
 708   | isLoopBreaker occ_info = False      -- If it's a loop-breaker of any kind, don't inline
 709                                         -- because it might be referred to "earlier"
 710   | isExportedId bndr      = False
 711   | isInlineRule unfolding = False      -- Note [InlineRule and postInlineUnconditionally]
 712   | exprIsTrivial rhs      = True
 713   | otherwise
 714   = case occ_info of
 715         -- The point of examining occ_info here is that for *non-values*
 716         -- that occur outside a lambda, the call-site inliner won't have
 717         -- a chance (becuase it doesn't know that the thing
 718         -- only occurs once).   The pre-inliner won't have gotten
 719         -- it either, if the thing occurs in more than one branch
 720         -- So the main target is things like
 721         --      let x = f y in
 722         --      case v of
 723         --         True  -> case x of ...
 724         --         False -> case x of ...
 725         -- I'm not sure how important this is in practice
 726       OneOcc in_lam _one_br int_cxt     -- OneOcc => no code-duplication issue
 727         ->     smallEnoughToInline unfolding    -- Small enough to dup
 728                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
 729                         --
 730                         -- NB: Do NOT inline arbitrarily big things, even if one_br is True
 731                         -- Reason: doing so risks exponential behaviour.  We simplify a big
 732                         --         expression, inline it, and simplify it again.  But if the
 733                         --         very same thing happens in the big expression, we get
 734                         --         exponential cost!
 735                         -- PRINCIPLE: when we've already simplified an expression once,
 736                         -- make sure that we only inline it if it's reasonably small.
 737
 738            &&  ((isNotTopLevel top_lvl && not in_lam) ||
 739                         -- But outside a lambda, we want to be reasonably aggressive
 740                         -- about inlining into multiple branches of case
 741                         -- e.g. let x = <non-value>
 742                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... }
 743                         -- Inlining can be a big win if C3 is the hot-spot, even if
 744                         -- the uses in C1, C2 are not 'interesting'
 745                         -- An example that gets worse if you add int_cxt here is 'clausify'
 746
 747                 (isCheapUnfolding unfolding && int_cxt))
 748                         -- isCheap => acceptable work duplication; in_lam may be true
 749                         -- int_cxt to prevent us inlining inside a lambda without some
 750                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
 751
 752       IAmDead -> True   -- This happens; for example, the case_bndr during case of
 753                         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 754                         -- Here x isn't mentioned in the RHS, so we don't want to
 755                         -- create the (dead) let-binding  let x = (a,b) in ...
 756
 757       _ -> False
 758
 759 -- Here's an example that we don't handle well:
 760 --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
 761 --      in \y. ....case f of {...} ....
 762 -- Here f is used just once, and duplicating the case work is fine (exprIsCheap).
 763 -- But
 764 --  - We can't preInlineUnconditionally because that woud invalidate
 765 --    the occ info for b.
 766 --  - We can't postInlineUnconditionally because the RHS is big, and
 767 --    that risks exponential behaviour
 768 --  - We can't call-site inline, because the rhs is big
 769 -- Alas!
 770
 771   where
 772     active = case getMode env of
 773                    SimplGently {} -> isEarlyActive act
 774                         -- See Note [pre/postInlineUnconditionally in gentle mode]
 775                    SimplPhase n _ -> isActive n act
 776     act = idInlineActivation bndr
 777
 778 activeInline :: SimplEnv -> OutId -> Bool
 779 activeInline env id
 780   = case getMode env of
 781       SimplGently { sm_inline = inlining_on }
 782          -> inlining_on && isEarlyActive act
 783         -- See Note [Gentle mode]
 784
 785         -- NB: we used to have a second exception, for data con wrappers.
 786         -- On the grounds that we use gentle mode for rule LHSs, and
 787         -- they match better when data con wrappers are inlined.
 788         -- But that only really applies to the trivial wrappers (like (:)),
 789         -- and they are now constructed as Compulsory unfoldings (in MkId)
 790         -- so they'll happen anyway.
 791
 792       SimplPhase n _ -> isActive n act
 793   where
 794     act = idInlineActivation id
 795
 796 activeRule :: DynFlags -> SimplEnv -> Maybe (Activation -> Bool)
 797 -- Nothing => No rules at all
 798 activeRule dflags env
 799   | not (dopt Opt_EnableRewriteRules dflags)
 800   = Nothing     -- Rewriting is off
 801   | otherwise
 802   = case getMode env of
 803       SimplGently { sm_rules = rules_on }
 804         | rules_on  -> Just isEarlyActive
 805         | otherwise -> Nothing
 806                         -- Used to be Nothing (no rules in gentle mode)
 807                         -- Main motivation for changing is that I wanted
 808                         --      lift String ===> ...
 809                         -- to work in Template Haskell when simplifying
 810                         -- splices, so we get simpler code for literal strings
 811       SimplPhase n _ -> Just (isActive n)
 812 \end{code}
 813
 814 Note [InlineRule and postInlineUnconditionally]
 815 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 816 Do not do postInlineUnconditionally if the Id has an InlineRule, otherwise
 817 we lose the unfolding.  Example
 818
 819      -- f has InlineRule with rhs (e |> co)
 820      --   where 'e' is big
 821      f = e |> co
 822
 823 Then there's a danger we'll optimise to
 824
 825      f' = e
 826      f = f' |> co
 827
 828 and now postInlineUnconditionally, losing the InlineRule on f.  Now f'
 829 won't inline because 'e' is too big.
 830
 831
 832 %************************************************************************
 833 %*                                                                      *
 834         Rebuilding a lambda
 835 %*                                                                      *
 836 %************************************************************************
 837
 838 \begin{code}
 839 mkLam :: SimplEnv -> [OutBndr] -> OutExpr -> SimplM OutExpr
 840 -- mkLam tries three things
 841 --      a) eta reduction, if that gives a trivial expression
 842 --      b) eta expansion [only if there are some value lambdas]
 843
 844 mkLam _b [] body
 845   = return body
 846 mkLam env bndrs body
 847   = do  { dflags <- getDOptsSmpl
 848         ; mkLam' dflags bndrs body }
 849   where
 850     mkLam' :: DynFlags -> [OutBndr] -> OutExpr -> SimplM OutExpr
 851     mkLam' dflags bndrs (Cast body co)
 852       | not (any bad bndrs)
 853         -- Note [Casts and lambdas]
 854       = do { lam <- mkLam' dflags bndrs body
 855            ; return (mkCoerce (mkPiTypes bndrs co) lam) }
 856       where
 857         co_vars  = tyVarsOfType co
 858         bad bndr = isCoVar bndr && bndr `elemVarSet` co_vars
 859
 860     mkLam' dflags bndrs body
 861       | dopt Opt_DoEtaReduction dflags,
 862         Just etad_lam <- tryEtaReduce bndrs body
 863       = do { tick (EtaReduction (head bndrs))
 864            ; return etad_lam }
 865
 866       | dopt Opt_DoLambdaEtaExpansion dflags,
 867         not (inGentleMode env),       -- In gentle mode don't eta-expansion
 868         any isRuntimeVar bndrs        -- because it can clutter up the code
 869                                       -- with casts etc that may not be removed
 870       = do { let body' = tryEtaExpansion dflags body
 871            ; return (mkLams bndrs body') }
 872
 873       | otherwise
 874       = return (mkLams bndrs body)
 875 \end{code}
 876
 877 Note [Casts and lambdas]
 878 ~~~~~~~~~~~~~~~~~~~~~~~~
 879 Consider
 880         (\x. (\y. e) `cast` g1) `cast` g2
 881 There is a danger here that the two lambdas look separated, and the
 882 full laziness pass might float an expression to between the two.
 883
 884 So this equation in mkLam' floats the g1 out, thus:
 885         (\x. e `cast` g1)  -->  (\x.e) `cast` (tx -> g1)
 886 where x:tx.
 887
 888 In general, this floats casts outside lambdas, where (I hope) they
 889 might meet and cancel with some other cast:
 890         \x. e `cast` co   ===>   (\x. e) `cast` (tx -> co)
 891         /\a. e `cast` co  ===>   (/\a. e) `cast` (/\a. co)
 892         /\g. e `cast` co  ===>   (/\g. e) `cast` (/\g. co)
 893                           (if not (g `in` co))
 894
 895 Notice that it works regardless of 'e'.  Originally it worked only
 896 if 'e' was itself a lambda, but in some cases that resulted in
 897 fruitless iteration in the simplifier.  A good example was when
 898 compiling Text.ParserCombinators.ReadPrec, where we had a definition
 899 like    (\x. Get `cast` g)
 900 where Get is a constructor with nonzero arity.  Then mkLam eta-expanded
 901 the Get, and the next iteration eta-reduced it, and then eta-expanded
 902 it again.
 903
 904 Note also the side condition for the case of coercion binders.
 905 It does not make sense to transform
 906         /\g. e `cast` g  ==>  (/\g.e) `cast` (/\g.g)
 907 because the latter is not well-kinded.
 908
 909 --      c) floating lets out through big lambdas
 910 --              [only if all tyvar lambdas, and only if this lambda
 911 --               is the RHS of a let]
 912
 913 {-      Sept 01: I'm experimenting with getting the
 914         full laziness pass to float out past big lambdsa
 915  | all isTyVar bndrs,   -- Only for big lambdas
 916    contIsRhs cont       -- Only try the rhs type-lambda floating
 917                         -- if this is indeed a right-hand side; otherwise
 918                         -- we end up floating the thing out, only for float-in
 919                         -- to float it right back in again!
 920  = do (floats, body') <- tryRhsTyLam env bndrs body
 921       return (floats, mkLams bndrs body')
 922 -}
 923
 924
 925 %************************************************************************
 926 %*                                                                      *
 927                 Eta reduction
 928 %*                                                                      *
 929 %************************************************************************
 930
 931 Note [Eta reduction conditions]
 932 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 933 We try for eta reduction here, but *only* if we get all the way to an
 934 trivial expression.  We don't want to remove extra lambdas unless we
 935 are going to avoid allocating this thing altogether.
 936
 937 There are some particularly delicate points here:
 938
 939 * Eta reduction is not valid in general:
 940         \x. bot  /=  bot
 941   This matters, partly for old-fashioned correctness reasons but,
 942   worse, getting it wrong can yield a seg fault. Consider
 943         f = \x.f x
 944         h y = case (case y of { True -> f `seq` True; False -> False }) of
 945                 True -> ...; False -> ...
 946
 947   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
 948   says f=bottom, and replaces the (f `seq` True) with just
 949   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
 950   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
 951   the definition again, so that it does not termninate after all.
 952   Result: seg-fault because the boolean case actually gets a function value.
 953   See Trac #1947.
 954
 955   So it's important to to the right thing.
 956
 957 * Note [Arity care]: we need to be careful if we just look at f's
 958   arity. Currently (Dec07), f's arity is visible in its own RHS (see
 959   Note [Arity robustness] in SimplEnv) so we must *not* trust the
 960   arity when checking that 'f' is a value.  Otherwise we will
 961   eta-reduce
 962       f = \x. f x
 963   to
 964       f = f
 965   Which might change a terminiating program (think (f `seq` e)) to a
 966   non-terminating one.  So we check for being a loop breaker first.
 967
 968   However for GlobalIds we can look at the arity; and for primops we
 969   must, since they have no unfolding.
 970
 971 * Regardless of whether 'f' is a value, we always want to
 972   reduce (/\a -> f a) to f
 973   This came up in a RULE: foldr (build (/\a -> g a))
 974   did not match           foldr (build (/\b -> ...something complex...))
 975   The type checker can insert these eta-expanded versions,
 976   with both type and dictionary lambdas; hence the slightly
 977   ad-hoc isDictId
 978
 979 * Never *reduce* arity. For example
 980       f = \xy. g x y
 981   Then if h has arity 1 we don't want to eta-reduce because then
 982   f's arity would decrease, and that is bad
 983
 984 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
 985 Alas.
 986
 987 \begin{code}
 988 tryEtaReduce :: [OutBndr] -> OutExpr -> Maybe OutExpr
 989 tryEtaReduce bndrs body
 990   = go (reverse bndrs) body
 991   where
 992     incoming_arity = count isId bndrs
 993
 994     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 995     go []       fun           | ok_fun fun   = Just fun         -- Success!
 996     go _        _                            = Nothing          -- Failure!
 997
 998         -- Note [Eta reduction conditions]
 999     ok_fun (App fun (Type ty))
1000         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1001         =  ok_fun fun
1002     ok_fun (Var fun_id)
1003         =  not (fun_id `elem` bndrs)
1004         && (ok_fun_id fun_id || all ok_lam bndrs)
1005     ok_fun _fun = False
1006
1007     ok_fun_id fun = fun_arity fun >= incoming_arity
1008
1009     fun_arity fun             -- See Note [Arity care]
1010        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1011        | otherwise = idArity fun
1012
1013     ok_lam v = isTyVar v || isDictId v
1014
1015     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
1016 \end{code}
1017
1018
1019 %************************************************************************
1020 %*                                                                      *
1021                 Eta expansion
1022 %*                                                                      *
1023 %************************************************************************
1024
1025
1026 We go for:
1027    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
1028                                  (n >= 0)
1029
1030 where (in both cases)
1031
1032         * The xi can include type variables
1033
1034         * The yi are all value variables
1035
1036         * N is a NORMAL FORM (i.e. no redexes anywhere)
1037           wanting a suitable number of extra args.
1038
1039 The biggest reason for doing this is for cases like
1040
1041         f = \x -> case x of
1042                     True  -> \y -> e1
1043                     False -> \y -> e2
1044
1045 Here we want to get the lambdas together.  A good exmaple is the nofib
1046 program fibheaps, which gets 25% more allocation if you don't do this
1047 eta-expansion.
1048
1049 We may have to sandwich some coerces between the lambdas
1050 to make the types work.   exprEtaExpandArity looks through coerces
1051 when computing arity; and etaExpand adds the coerces as necessary when
1052 actually computing the expansion.
1053
1054 \begin{code}
1055 tryEtaExpansion :: DynFlags -> OutExpr -> OutExpr
1056 -- There is at least one runtime binder in the binders
1057 tryEtaExpansion dflags body
1058   = etaExpand fun_arity body
1059   where
1060     fun_arity = exprEtaExpandArity dflags body
1061 \end{code}
1062
1063
1064 %************************************************************************
1065 %*                                                                      *
1066 \subsection{Floating lets out of big lambdas}
1067 %*                                                                      *
1068 %************************************************************************
1069
1070 Note [Floating and type abstraction]
1071 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1072 Consider this:
1073         x = /\a. C e1 e2
1074 We'd like to float this to
1075         y1 = /\a. e1
1076         y2 = /\a. e2
1077         x  = /\a. C (y1 a) (y2 a)
1078 for the usual reasons: we want to inline x rather vigorously.
1079
1080 You may think that this kind of thing is rare.  But in some programs it is
1081 common.  For example, if you do closure conversion you might get:
1082
1083         data a :-> b = forall e. (e -> a -> b) :$ e
1084
1085         f_cc :: forall a. a :-> a
1086         f_cc = /\a. (\e. id a) :$ ()
1087
1088 Now we really want to inline that f_cc thing so that the
1089 construction of the closure goes away.
1090
1091 So I have elaborated simplLazyBind to understand right-hand sides that look
1092 like
1093         /\ a1..an. body
1094
1095 and treat them specially. The real work is done in SimplUtils.abstractFloats,
1096 but there is quite a bit of plumbing in simplLazyBind as well.
1097
1098 The same transformation is good when there are lets in the body:
1099
1100         /\abc -> let(rec) x = e in b
1101    ==>
1102         let(rec) x' = /\abc -> let x = x' a b c in e
1103         in
1104         /\abc -> let x = x' a b c in b
1105
1106 This is good because it can turn things like:
1107
1108         let f = /\a -> letrec g = ... g ... in g
1109 into
1110         letrec g' = /\a -> ... g' a ...
1111         in
1112         let f = /\ a -> g' a
1113
1114 which is better.  In effect, it means that big lambdas don't impede
1115 let-floating.
1116
1117 This optimisation is CRUCIAL in eliminating the junk introduced by
1118 desugaring mutually recursive definitions.  Don't eliminate it lightly!
1119
1120 [May 1999]  If we do this transformation *regardless* then we can
1121 end up with some pretty silly stuff.  For example,
1122
1123         let
1124             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
1125         in ..
1126 becomes
1127         let y1 = /\s -> r1
1128             y2 = /\s -> r2
1129             st = /\s -> ...[y1 s/x1, y2 s/x2]
1130         in ..
1131
1132 Unless the "..." is a WHNF there is really no point in doing this.
1133 Indeed it can make things worse.  Suppose x1 is used strictly,
1134 and is of the form
1135
1136         x1* = case f y of { (a,b) -> e }
1137
1138 If we abstract this wrt the tyvar we then can't do the case inline
1139 as we would normally do.
1140
1141 That's why the whole transformation is part of the same process that
1142 floats let-bindings and constructor arguments out of RHSs.  In particular,
1143 it is guarded by the doFloatFromRhs call in simplLazyBind.
1144
1145
1146 \begin{code}
1147 abstractFloats :: [OutTyVar] -> SimplEnv -> OutExpr -> SimplM ([OutBind], OutExpr)
1148 abstractFloats main_tvs body_env body
1149   = ASSERT( notNull body_floats )
1150     do  { (subst, float_binds) <- mapAccumLM abstract empty_subst body_floats
1151         ; return (float_binds, CoreSubst.substExpr subst body) }
1152   where
1153     main_tv_set = mkVarSet main_tvs
1154     body_floats = getFloats body_env
1155     empty_subst = CoreSubst.mkEmptySubst (seInScope body_env)
1156
1157     abstract :: CoreSubst.Subst -> OutBind -> SimplM (CoreSubst.Subst, OutBind)
1158     abstract subst (NonRec id rhs)
1159       = do { (poly_id, poly_app) <- mk_poly tvs_here id
1160            ; let poly_rhs = mkLams tvs_here rhs'
1161                  subst'   = CoreSubst.extendIdSubst subst id poly_app
1162            ; return (subst', (NonRec poly_id poly_rhs)) }
1163       where
1164         rhs' = CoreSubst.substExpr subst rhs
1165         tvs_here | any isCoVar main_tvs = main_tvs      -- Note [Abstract over coercions]
1166                  | otherwise
1167                  = varSetElems (main_tv_set `intersectVarSet` exprSomeFreeVars isTyVar rhs')
1168
1169                 -- Abstract only over the type variables free in the rhs
1170                 -- wrt which the new binding is abstracted.  But the naive
1171                 -- approach of abstract wrt the tyvars free in the Id's type
1172                 -- fails. Consider:
1173                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1174                 --                    x :: a     = fst t
1175                 --                in ...
1176                 -- Here, b isn't free in x's type, but we must nevertheless
1177                 -- abstract wrt b as well, because t's type mentions b.
1178                 -- Since t is floated too, we'd end up with the bogus:
1179                 --      poly_t = /\ a b -> (e1, e2)
1180                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1181                 -- So for now we adopt the even more naive approach of
1182                 -- abstracting wrt *all* the tyvars.  We'll see if that
1183                 -- gives rise to problems.   SLPJ June 98
1184
1185     abstract subst (Rec prs)
1186        = do { (poly_ids, poly_apps) <- mapAndUnzipM (mk_poly tvs_here) ids
1187             ; let subst' = CoreSubst.extendSubstList subst (ids `zip` poly_apps)
1188                   poly_rhss = [mkLams tvs_here (CoreSubst.substExpr subst' rhs) | rhs <- rhss]
1189             ; return (subst', Rec (poly_ids `zip` poly_rhss)) }
1190        where
1191          (ids,rhss) = unzip prs
1192                 -- For a recursive group, it's a bit of a pain to work out the minimal
1193                 -- set of tyvars over which to abstract:
1194                 --      /\ a b c.  let x = ...a... in
1195                 --                 letrec { p = ...x...q...
1196                 --                          q = .....p...b... } in
1197                 --                 ...
1198                 -- Since 'x' is abstracted over 'a', the {p,q} group must be abstracted
1199                 -- over 'a' (because x is replaced by (poly_x a)) as well as 'b'.
1200                 -- Since it's a pain, we just use the whole set, which is always safe
1201                 --
1202                 -- If you ever want to be more selective, remember this bizarre case too:
1203                 --      x::a = x
1204                 -- Here, we must abstract 'x' over 'a'.
1205          tvs_here = main_tvs
1206
1207     mk_poly tvs_here var
1208       = do { uniq <- getUniqueM
1209            ; let  poly_name = setNameUnique (idName var) uniq           -- Keep same name
1210                   poly_ty   = mkForAllTys tvs_here (idType var) -- But new type of course
1211                   poly_id   = transferPolyIdInfo var tvs_here $ -- Note [transferPolyIdInfo] in Id.lhs
1212                               mkLocalId poly_name poly_ty
1213            ; return (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tvs_here)) }
1214                 -- In the olden days, it was crucial to copy the occInfo of the original var,
1215                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1216                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1217                 -- at already simplified code, so it doesn't matter
1218                 --
1219                 -- It's even right to retain single-occurrence or dead-var info:
1220                 -- Suppose we started with  /\a -> let x = E in B
1221                 -- where x occurs once in B. Then we transform to:
1222                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1223                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1224                 -- the occurrences of x' will be just the occurrences originally
1225                 -- pinned on x.
1226 \end{code}
1227
1228 Note [Abstract over coercions]
1229 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1230 If a coercion variable (g :: a ~ Int) is free in the RHS, then so is the
1231 type variable a.  Rather than sort this mess out, we simply bale out and abstract
1232 wrt all the type variables if any of them are coercion variables.
1233
1234
1235 Historical note: if you use let-bindings instead of a substitution, beware of this:
1236
1237                 -- Suppose we start with:
1238                 --
1239                 --      x = /\ a -> let g = G in E
1240                 --
1241                 -- Then we'll float to get
1242                 --
1243                 --      x = let poly_g = /\ a -> G
1244                 --          in /\ a -> let g = poly_g a in E
1245                 --
1246                 -- But now the occurrence analyser will see just one occurrence
1247                 -- of poly_g, not inside a lambda, so the simplifier will
1248                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1249                 -- (I used to think that the "don't inline lone occurrences" stuff
1250                 --  would stop this happening, but since it's the *only* occurrence,
1251                 --  PreInlineUnconditionally kicks in first!)
1252                 --
1253                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1254                 --           to appear many times.  (NB: mkInlineMe eliminates
1255                 --           such notes on trivial RHSs, so do it manually.)
1256
1257 %************************************************************************
1258 %*                                                                      *
1259                 prepareAlts
1260 %*                                                                      *
1261 %************************************************************************
1262
1263 prepareAlts tries these things:
1264
1265 1.  If several alternatives are identical, merge them into
1266     a single DEFAULT alternative.  I've occasionally seen this
1267     making a big difference:
1268
1269         case e of               =====>     case e of
1270           C _ -> f x                         D v -> ....v....
1271           D v -> ....v....                   DEFAULT -> f x
1272           DEFAULT -> f x
1273
1274    The point is that we merge common RHSs, at least for the DEFAULT case.
1275    [One could do something more elaborate but I've never seen it needed.]
1276    To avoid an expensive test, we just merge branches equal to the *first*
1277    alternative; this picks up the common cases
1278         a) all branches equal
1279         b) some branches equal to the DEFAULT (which occurs first)
1280
1281 2.  Case merging:
1282        case e of b {             ==>   case e of b {
1283          p1 -> rhs1                      p1 -> rhs1
1284          ...                             ...
1285          pm -> rhsm                      pm -> rhsm
1286          _  -> case b of b' {            pn -> let b'=b in rhsn
1287                      pn -> rhsn          ...
1288                      ...                 po -> let b'=b in rhso
1289                      po -> rhso          _  -> let b'=b in rhsd
1290                      _  -> rhsd
1291        }
1292
1293     which merges two cases in one case when -- the default alternative of
1294     the outer case scrutises the same variable as the outer case This
1295     transformation is called Case Merging.  It avoids that the same
1296     variable is scrutinised multiple times.
1297
1298
1299 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1300
1301         x | p `is` 1 -> e1
1302           | p `is` 2 -> e2
1303         ...etc...
1304
1305 where @is@ was something like
1306
1307         p `is` n = p /= (-1) && p == n
1308
1309 This gave rise to a horrible sequence of cases
1310
1311         case p of
1312           (-1) -> $j p
1313           1    -> e1
1314           DEFAULT -> $j p
1315
1316 and similarly in cascade for all the join points!
1317
1318 Note [Dead binders]
1319 ~~~~~~~~~~~~~~~~~~~~
1320 We do this *here*, looking at un-simplified alternatives, because we
1321 have to check that r doesn't mention the variables bound by the
1322 pattern in each alternative, so the binder-info is rather useful.
1323
1324 \begin{code}
1325 prepareAlts :: SimplEnv -> OutExpr -> OutId -> [InAlt] -> SimplM ([AltCon], [InAlt])
1326 prepareAlts env scrut case_bndr' alts
1327   = do  { dflags <- getDOptsSmpl
1328         ; alts <- combineIdenticalAlts case_bndr' alts
1329
1330         ; let (alts_wo_default, maybe_deflt) = findDefault alts
1331               alt_cons = [con | (con,_,_) <- alts_wo_default]
1332               imposs_deflt_cons = nub (imposs_cons ++ alt_cons)
1333                 -- "imposs_deflt_cons" are handled
1334                 --   EITHER by the context,
1335                 --   OR by a non-DEFAULT branch in this case expression.
1336
1337         ; default_alts <- prepareDefault dflags env case_bndr' mb_tc_app
1338                                          imposs_deflt_cons maybe_deflt
1339
1340         ; let trimmed_alts = filterOut impossible_alt alts_wo_default
1341               merged_alts = mergeAlts trimmed_alts default_alts
1342                 -- We need the mergeAlts in case the new default_alt
1343                 -- has turned into a constructor alternative.
1344                 -- The merge keeps the inner DEFAULT at the front, if there is one
1345                 -- and interleaves the alternatives in the right order
1346
1347         ; return (imposs_deflt_cons, merged_alts) }
1348   where
1349     mb_tc_app = splitTyConApp_maybe (idType case_bndr')
1350     Just (_, inst_tys) = mb_tc_app
1351
1352     imposs_cons = case scrut of
1353                     Var v -> otherCons (idUnfolding v)
1354                     _     -> []
1355
1356     impossible_alt :: CoreAlt -> Bool
1357     impossible_alt (con, _, _) | con `elem` imposs_cons = True
1358     impossible_alt (DataAlt con, _, _) = dataConCannotMatch inst_tys con
1359     impossible_alt _                   = False
1360
1361
1362 --------------------------------------------------
1363 --      1. Merge identical branches
1364 --------------------------------------------------
1365 combineIdenticalAlts :: OutId -> [InAlt] -> SimplM [InAlt]
1366
1367 combineIdenticalAlts case_bndr ((_con1,bndrs1,rhs1) : con_alts)
1368   | all isDeadBinder bndrs1,                    -- Remember the default
1369     length filtered_alts < length con_alts      -- alternative comes first
1370         -- Also Note [Dead binders]
1371   = do  { tick (AltMerge case_bndr)
1372         ; return ((DEFAULT, [], rhs1) : filtered_alts) }
1373   where
1374     filtered_alts        = filter keep con_alts
1375     keep (_con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1376
1377 combineIdenticalAlts _ alts = return alts
1378
1379 -------------------------------------------------------------------------
1380 --                      Prepare the default alternative
1381 -------------------------------------------------------------------------
1382 prepareDefault :: DynFlags
1383                -> SimplEnv
1384                -> OutId         -- Case binder; need just for its type. Note that as an
1385                                 --   OutId, it has maximum information; this is important.
1386                                 --   Test simpl013 is an example
1387                -> Maybe (TyCon, [Type]) -- Type of scrutinee, decomposed
1388                -> [AltCon]      -- These cons can't happen when matching the default
1389                -> Maybe InExpr  -- Rhs
1390                -> SimplM [InAlt]        -- Still unsimplified
1391                                         -- We use a list because it's what mergeAlts expects,
1392                                         -- And becuase case-merging can cause many to show up
1393
1394 ------- Merge nested cases ----------
1395 prepareDefault dflags env outer_bndr _bndr_ty imposs_cons (Just deflt_rhs)
1396   | dopt Opt_CaseMerge dflags
1397   , Case (Var inner_scrut_var) inner_bndr _ inner_alts <- deflt_rhs
1398   , DoneId inner_scrut_var' <- substId env inner_scrut_var
1399         -- Remember, inner_scrut_var is an InId, but outer_bndr is an OutId
1400   , inner_scrut_var' == outer_bndr
1401         -- NB: the substId means that if the outer scrutinee was a
1402         --     variable, and inner scrutinee is the same variable,
1403         --     then inner_scrut_var' will be outer_bndr
1404         --     via the magic of simplCaseBinder
1405   = do  { tick (CaseMerge outer_bndr)
1406
1407         ; let munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1408         ; return [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts,
1409                                                not (con `elem` imposs_cons) ]
1410                 -- NB: filter out any imposs_cons.  Example:
1411                 --      case x of
1412                 --        A -> e1
1413                 --        DEFAULT -> case x of
1414                 --                      A -> e2
1415                 --                      B -> e3
1416                 -- When we merge, we must ensure that e1 takes
1417                 -- precedence over e2 as the value for A!
1418         }
1419         -- Warning: don't call prepareAlts recursively!
1420         -- Firstly, there's no point, because inner alts have already had
1421         -- mkCase applied to them, so they won't have a case in their default
1422         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1423         -- in munge_rhs may put a case into the DEFAULT branch!
1424
1425
1426 --------- Fill in known constructor -----------
1427 prepareDefault _ _ case_bndr (Just (tycon, inst_tys)) imposs_cons (Just deflt_rhs)
1428   |     -- This branch handles the case where we are
1429         -- scrutinisng an algebraic data type
1430     isAlgTyCon tycon            -- It's a data type, tuple, or unboxed tuples.
1431   , not (isNewTyCon tycon)      -- We can have a newtype, if we are just doing an eval:
1432                                 --      case x of { DEFAULT -> e }
1433                                 -- and we don't want to fill in a default for them!
1434   , Just all_cons <- tyConDataCons_maybe tycon
1435   , not (null all_cons)         -- This is a tricky corner case.  If the data type has no constructors,
1436                                 -- which GHC allows, then the case expression will have at most a default
1437                                 -- alternative.  We don't want to eliminate that alternative, because the
1438                                 -- invariant is that there's always one alternative.  It's more convenient
1439                                 -- to leave
1440                                 --      case x of { DEFAULT -> e }
1441                                 -- as it is, rather than transform it to
1442                                 --      error "case cant match"
1443                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1444                                 -- not worth wasting code on.
1445   , let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1446         impossible con  = con `elem` imposs_data_cons || dataConCannotMatch inst_tys con
1447   = case filterOut impossible all_cons of
1448         []    -> return []      -- Eliminate the default alternative
1449                                 -- altogether if it can't match
1450
1451         [con] ->        -- It matches exactly one constructor, so fill it in
1452                  do { tick (FillInCaseDefault case_bndr)
1453                     ; us <- getUniquesM
1454                     ; let (ex_tvs, co_tvs, arg_ids) =
1455                               dataConRepInstPat us con inst_tys
1456                     ; return [(DataAlt con, ex_tvs ++ co_tvs ++ arg_ids, deflt_rhs)] }
1457
1458         _ -> return [(DEFAULT, [], deflt_rhs)]
1459
1460   | debugIsOn, isAlgTyCon tycon, not (isOpenTyCon tycon), null (tyConDataCons tycon)
1461         -- This can legitimately happen for type families, so don't report that
1462   = pprTrace "prepareDefault" (ppr case_bndr <+> ppr tycon)
1463         $ return [(DEFAULT, [], deflt_rhs)]
1464
1465 --------- Catch-all cases -----------
1466 prepareDefault _dflags _env _case_bndr _bndr_ty _imposs_cons (Just deflt_rhs)
1467   = return [(DEFAULT, [], deflt_rhs)]
1468
1469 prepareDefault _dflags _env _case_bndr _bndr_ty _imposs_cons Nothing
1470   = return []   -- No default branch
1471 \end{code}
1472
1473
1474
1475 =================================================================================
1476
1477 mkCase tries these things
1478
1479 1.  Eliminate the case altogether if possible
1480
1481 2.  Case-identity:
1482
1483         case e of               ===> e
1484                 True  -> True;
1485                 False -> False
1486
1487     and similar friends.
1488
1489
1490 \begin{code}
1491 mkCase :: OutExpr -> OutId -> [OutAlt]  -- Increasing order
1492        -> SimplM OutExpr
1493
1494 --------------------------------------------------
1495 --      2. Identity case
1496 --------------------------------------------------
1497
1498 mkCase scrut case_bndr alts     -- Identity case
1499   | all identity_alt alts
1500   = do tick (CaseIdentity case_bndr)
1501        return (re_cast scrut)
1502   where
1503     identity_alt (con, args, rhs) = check_eq con args (de_cast rhs)
1504
1505     check_eq DEFAULT       _    (Var v)   = v == case_bndr
1506     check_eq (LitAlt lit') _    (Lit lit) = lit == lit'
1507     check_eq (DataAlt con) args rhs       = rhs `cheapEqExpr` mkConApp con (arg_tys ++ varsToCoreExprs args)
1508                                          || rhs `cheapEqExpr` Var case_bndr
1509     check_eq _ _ _ = False
1510
1511     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1512
1513         -- We've seen this:
1514         --      case e of x { _ -> x `cast` c }
1515         -- And we definitely want to eliminate this case, to give
1516         --      e `cast` c
1517         -- So we throw away the cast from the RHS, and reconstruct
1518         -- it at the other end.  All the RHS casts must be the same
1519         -- if (all identity_alt alts) holds.
1520         --
1521         -- Don't worry about nested casts, because the simplifier combines them
1522     de_cast (Cast e _) = e
1523     de_cast e          = e
1524
1525     re_cast scrut = case head alts of
1526                         (_,_,Cast _ co) -> Cast scrut co
1527                         _               -> scrut
1528
1529
1530
1531 --------------------------------------------------
1532 --      Catch-all
1533 --------------------------------------------------
1534 mkCase scrut bndr alts = return (Case scrut bndr (coreAltsType alts) alts)
1535 \end{code}
1536
1537
1538 When adding auxiliary bindings for the case binder, it's worth checking if
1539 its dead, because it often is, and occasionally these mkCase transformations
1540 cascade rather nicely.
1541
1542 \begin{code}
1543 bindCaseBndr :: Id -> CoreExpr -> CoreExpr -> CoreExpr
1544 bindCaseBndr bndr rhs body
1545   | isDeadBinder bndr = body
1546   | otherwise         = bindNonRec bndr rhs body
1547 \end{code}