compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 {-# OPTIONS -w #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  12 -- for details
  13
  14 module SimplUtils (
  15         -- Rebuilding
  16         mkLam, mkCase, prepareAlts, bindCaseBndr,
  17
  18         -- Inlining,
  19         preInlineUnconditionally, postInlineUnconditionally,
  20         activeInline, activeRule, inlineMode,
  21
  22         -- The continuation type
  23         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  24         contIsDupable, contResultType, contIsTrivial, contArgs, dropArgs,
  25         countValArgs, countArgs, splitInlineCont,
  26         mkBoringStop, mkLazyArgStop, mkRhsStop, contIsRhsOrArg,
  27         interestingCallContext, interestingArgContext,
  28
  29         interestingArg, mkArgInfo,
  30
  31         abstractFloats
  32     ) where
  33
  34 #include "HsVersions.h"
  35
  36 import SimplEnv
  37 import DynFlags
  38 import StaticFlags
  39 import CoreSyn
  40 import qualified CoreSubst
  41 import PprCore
  42 import CoreFVs
  43 import CoreUtils
  44 import Literal
  45 import CoreUnfold
  46 import MkId
  47 import Name
  48 import Id
  49 import Var      ( isCoVar )
  50 import NewDemand
  51 import SimplMonad
  52 import Type     hiding( substTy )
  53 import TyCon
  54 import DataCon
  55 import Unify    ( dataConCannotMatch )
  56 import VarSet
  57 import BasicTypes
  58 import Util
  59 import Outputable
  60 import List( nub )
  61 \end{code}
  62
  63
  64 %************************************************************************
  65 %*                                                                      *
  66                 The SimplCont type
  67 %*                                                                      *
  68 %************************************************************************
  69
  70 A SimplCont allows the simplifier to traverse the expression in a
  71 zipper-like fashion.  The SimplCont represents the rest of the expression,
  72 "above" the point of interest.
  73
  74 You can also think of a SimplCont as an "evaluation context", using
  75 that term in the way it is used for operational semantics. This is the
  76 way I usually think of it, For example you'll often see a syntax for
  77 evaluation context looking like
  78         C ::= []  |  C e   |  case C of alts  |  C `cast` co
  79 That's the kind of thing we are doing here, and I use that syntax in
  80 the comments.
  81
  82
  83 Key points:
  84   * A SimplCont describes a *strict* context (just like
  85     evaluation contexts do).  E.g. Just [] is not a SimplCont
  86
  87   * A SimplCont describes a context that *does not* bind
  88     any variables.  E.g. \x. [] is not a SimplCont
  89
  90 \begin{code}
  91 data SimplCont
  92   = Stop                -- An empty context, or hole, []
  93         OutType         -- Type of the result
  94         LetRhsFlag
  95         Bool            -- True <=> There is something interesting about
  96                         --          the context, and hence the inliner
  97                         --          should be a bit keener (see interestingCallContext)
  98                         -- Two cases:
  99                         -- (a) This is the RHS of a thunk whose type suggests
 100                         --     that update-in-place would be possible
 101                         -- (b) This is an argument of a function that has RULES
 102                         --     Inlining the call might allow the rule to fire
 103
 104   | CoerceIt            -- C `cast` co
 105         OutCoercion             -- The coercion simplified
 106         SimplCont
 107
 108   | ApplyTo             -- C arg
 109         DupFlag
 110         InExpr SimplEnv         -- The argument and its static env
 111         SimplCont
 112
 113   | Select              -- case C of alts
 114         DupFlag
 115         InId [InAlt] SimplEnv   -- The case binder, alts, and subst-env
 116         SimplCont
 117
 118   -- The two strict forms have no DupFlag, because we never duplicate them
 119   | StrictBind          -- (\x* \xs. e) C
 120         InId [InBndr]           -- let x* = [] in e
 121         InExpr SimplEnv         --      is a special case
 122         SimplCont
 123
 124   | StrictArg           -- e C
 125         OutExpr OutType         -- e and its type
 126         (Bool,[Bool])           -- Whether the function at the head of e has rules,
 127         SimplCont               --     plus strictness flags for further args
 128
 129 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
 130                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
 131
 132 instance Outputable LetRhsFlag where
 133   ppr AnArg = ptext SLIT("arg")
 134   ppr AnRhs = ptext SLIT("rhs")
 135
 136 instance Outputable SimplCont where
 137   ppr (Stop ty is_rhs _)             = ptext SLIT("Stop") <> brackets (ppr is_rhs) <+> ppr ty
 138   ppr (ApplyTo dup arg se cont)      = ((ptext SLIT("ApplyTo") <+> ppr dup <+> pprParendExpr arg)
 139                                           {-  $$ nest 2 (pprSimplEnv se) -}) $$ ppr cont
 140   ppr (StrictBind b _ _ _ cont)      = (ptext SLIT("StrictBind") <+> ppr b) $$ ppr cont
 141   ppr (StrictArg f _ _ cont)         = (ptext SLIT("StrictArg") <+> ppr f) $$ ppr cont
 142   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 143                                        (nest 4 (ppr alts)) $$ ppr cont
 144   ppr (CoerceIt co cont)             = (ptext SLIT("CoerceIt") <+> ppr co) $$ ppr cont
 145
 146 data DupFlag = OkToDup | NoDup
 147
 148 instance Outputable DupFlag where
 149   ppr OkToDup = ptext SLIT("ok")
 150   ppr NoDup   = ptext SLIT("nodup")
 151
 152
 153
 154 -------------------
 155 mkBoringStop :: OutType -> SimplCont
 156 mkBoringStop ty = Stop ty AnArg False
 157
 158 mkLazyArgStop :: OutType -> Bool -> SimplCont
 159 mkLazyArgStop ty has_rules = Stop ty AnArg (canUpdateInPlace ty || has_rules)
 160
 161 mkRhsStop :: OutType -> SimplCont
 162 mkRhsStop ty = Stop ty AnRhs (canUpdateInPlace ty)
 163
 164 -------------------
 165 contIsRhsOrArg (Stop {})         = True
 166 contIsRhsOrArg (StrictBind {})   = True
 167 contIsRhsOrArg (StrictArg {})    = True
 168 contIsRhsOrArg other             = False
 169
 170 -------------------
 171 contIsDupable :: SimplCont -> Bool
 172 contIsDupable (Stop {})                  = True
 173 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 174 contIsDupable (Select   OkToDup _ _ _ _) = True
 175 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 176 contIsDupable other                      = False
 177
 178 -------------------
 179 contIsTrivial :: SimplCont -> Bool
 180 contIsTrivial (Stop {})                   = True
 181 contIsTrivial (ApplyTo _ (Type _) _ cont) = contIsTrivial cont
 182 contIsTrivial (CoerceIt _ cont)           = contIsTrivial cont
 183 contIsTrivial other                       = False
 184
 185 -------------------
 186 contResultType :: SimplCont -> OutType
 187 contResultType (Stop to_ty _ _)          = to_ty
 188 contResultType (StrictArg _ _ _ cont)    = contResultType cont
 189 contResultType (StrictBind _ _ _ _ cont) = contResultType cont
 190 contResultType (ApplyTo _ _ _ cont)      = contResultType cont
 191 contResultType (CoerceIt _ cont)         = contResultType cont
 192 contResultType (Select _ _ _ _ cont)     = contResultType cont
 193
 194 -------------------
 195 countValArgs :: SimplCont -> Int
 196 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 197 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 198 countValArgs other                         = 0
 199
 200 countArgs :: SimplCont -> Int
 201 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 202 countArgs other                   = 0
 203
 204 contArgs :: SimplCont -> ([OutExpr], SimplCont)
 205 -- Uses substitution to turn each arg into an OutExpr
 206 contArgs cont = go [] cont
 207   where
 208     go args (ApplyTo _ arg se cont) = go (substExpr se arg : args) cont
 209     go args cont                    = (reverse args, cont)
 210
 211 dropArgs :: Int -> SimplCont -> SimplCont
 212 dropArgs 0 cont = cont
 213 dropArgs n (ApplyTo _ _ _ cont) = dropArgs (n-1) cont
 214 dropArgs n other                = pprPanic "dropArgs" (ppr n <+> ppr other)
 215
 216 --------------------
 217 splitInlineCont :: SimplCont -> Maybe (SimplCont, SimplCont)
 218 -- Returns Nothing if the continuation should dissolve an InlineMe Note
 219 -- Return Just (c1,c2) otherwise,
 220 --      where c1 is the continuation to put inside the InlineMe
 221 --      and   c2 outside
 222
 223 -- Example: (__inline_me__ (/\a. e)) ty
 224 --      Here we want to do the beta-redex without dissolving the InlineMe
 225 -- See test simpl017 (and Trac #1627) for a good example of why this is important
 226
 227 splitInlineCont (ApplyTo dup (Type ty) se c)
 228   | Just (c1, c2) <- splitInlineCont c          = Just (ApplyTo dup (Type ty) se c1, c2)
 229 splitInlineCont cont@(Stop ty _ _)              = Just (mkBoringStop ty, cont)
 230 splitInlineCont cont@(StrictBind bndr _ _ se _) = Just (mkBoringStop (substTy se (idType bndr)), cont)
 231 splitInlineCont cont@(StrictArg _ fun_ty _ _)   = Just (mkBoringStop (funArgTy fun_ty), cont)
 232 splitInlineCont other                           = Nothing
 233         -- NB: the calculation of the type for mkBoringStop is an annoying
 234         --     duplication of the same calucation in mkDupableCont
 235 \end{code}
 236
 237
 238 \begin{code}
 239 interestingArg :: OutExpr -> Bool
 240         -- An argument is interesting if it has *some* structure
 241         -- We are here trying to avoid unfolding a function that
 242         -- is applied only to variables that have no unfolding
 243         -- (i.e. they are probably lambda bound): f x y z
 244         -- There is little point in inlining f here.
 245 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 246                                         -- Was: isValueUnfolding (idUnfolding v')
 247                                         -- But that seems over-pessimistic
 248                                  || isDataConWorkId v
 249                                         -- This accounts for an argument like
 250                                         -- () or [], which is definitely interesting
 251 interestingArg (Type _)          = False
 252 interestingArg (App fn (Type _)) = interestingArg fn
 253 interestingArg (Note _ a)        = interestingArg a
 254
 255 -- Idea (from Sam B); I'm not sure if it's a good idea, so commented out for now
 256 -- interestingArg expr | isUnLiftedType (exprType expr)
 257 --        -- Unlifted args are only ever interesting if we know what they are
 258 --  =                  case expr of
 259 --                        Lit lit -> True
 260 --                        _       -> False
 261
 262 interestingArg other             = True
 263         -- Consider     let x = 3 in f x
 264         -- The substitution will contain (x -> ContEx 3), and we want to
 265         -- to say that x is an interesting argument.
 266         -- But consider also (\x. f x y) y
 267         -- The substitution will contain (x -> ContEx y), and we want to say
 268         -- that x is not interesting (assuming y has no unfolding)
 269 \end{code}
 270
 271
 272 Comment about interestingCallContext
 273 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 274 We want to avoid inlining an expression where there can't possibly be
 275 any gain, such as in an argument position.  Hence, if the continuation
 276 is interesting (eg. a case scrutinee, application etc.) then we
 277 inline, otherwise we don't.
 278
 279 Previously some_benefit used to return True only if the variable was
 280 applied to some value arguments.  This didn't work:
 281
 282         let x = _coerce_ (T Int) Int (I# 3) in
 283         case _coerce_ Int (T Int) x of
 284                 I# y -> ....
 285
 286 we want to inline x, but can't see that it's a constructor in a case
 287 scrutinee position, and some_benefit is False.
 288
 289 Another example:
 290
 291 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 292
 293 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 294
 295 we'd really like to inline dMonadST here, but we *don't* want to
 296 inline if the case expression is just
 297
 298         case x of y { DEFAULT -> ... }
 299
 300 since we can just eliminate this case instead (x is in WHNF).  Similar
 301 applies when x is bound to a lambda expression.  Hence
 302 contIsInteresting looks for case expressions with just a single
 303 default case.
 304
 305
 306 \begin{code}
 307 interestingCallContext :: SimplCont -> CallContInfo
 308 interestingCallContext cont
 309   = interesting cont
 310   where
 311     interesting (Select _ bndr _ _ _)
 312         | isDeadBinder bndr       = CaseCont
 313         | otherwise               = InterestingCont
 314
 315     interesting (ApplyTo {})      = InterestingCont
 316                                                 -- Can happen if we have (coerce t (f x)) y
 317                                                 -- Perhaps True is a bit over-keen, but I've
 318                                                 -- seen (coerce f) x, where f has an INLINE prag,
 319                                                 -- So we have to give some motivation for inlining it
 320     interesting (StrictArg {})    = InterestingCont
 321     interesting (StrictBind {})   = InterestingCont
 322     interesting (Stop ty _ yes)   = if yes then InterestingCont else BoringCont
 323     interesting (CoerceIt _ cont) = interesting cont
 324         -- If this call is the arg of a strict function, the context
 325         -- is a bit interesting.  If we inline here, we may get useful
 326         -- evaluation information to avoid repeated evals: e.g.
 327         --      x + (y * z)
 328         -- Here the contIsInteresting makes the '*' keener to inline,
 329         -- which in turn exposes a constructor which makes the '+' inline.
 330         -- Assuming that +,* aren't small enough to inline regardless.
 331         --
 332         -- It's also very important to inline in a strict context for things
 333         -- like
 334         --              foldr k z (f x)
 335         -- Here, the context of (f x) is strict, and if f's unfolding is
 336         -- a build it's *great* to inline it here.  So we must ensure that
 337         -- the context for (f x) is not totally uninteresting.
 338
 339
 340 -------------------
 341 mkArgInfo :: Id
 342           -> Int        -- Number of value args
 343           -> SimplCont  -- Context of the cal
 344           -> (Bool, [Bool])     -- Arg info
 345 -- The arg info consists of
 346 --  * A Bool indicating if the function has rules (recursively)
 347 --  * A [Bool] indicating strictness for each arg
 348 -- The [Bool] is usually infinite, but if it is finite it
 349 -- guarantees that the function diverges after being given
 350 -- that number of args
 351
 352 mkArgInfo fun n_val_args call_cont
 353   = (interestingArgContext fun call_cont, fun_stricts)
 354   where
 355     vanilla_stricts, fun_stricts :: [Bool]
 356     vanilla_stricts  = repeat False
 357
 358     fun_stricts
 359       = case splitStrictSig (idNewStrictness fun) of
 360           (demands, result_info)
 361                 | not (demands `lengthExceeds` n_val_args)
 362                 ->      -- Enough args, use the strictness given.
 363                         -- For bottoming functions we used to pretend that the arg
 364                         -- is lazy, so that we don't treat the arg as an
 365                         -- interesting context.  This avoids substituting
 366                         -- top-level bindings for (say) strings into
 367                         -- calls to error.  But now we are more careful about
 368                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 369                    if isBotRes result_info then
 370                         map isStrictDmd demands         -- Finite => result is bottom
 371                    else
 372                         map isStrictDmd demands ++ vanilla_stricts
 373
 374           other -> vanilla_stricts      -- Not enough args, or no strictness
 375
 376 interestingArgContext :: Id -> SimplCont -> Bool
 377 -- If the argument has form (f x y), where x,y are boring,
 378 -- and f is marked INLINE, then we don't want to inline f.
 379 -- But if the context of the argument is
 380 --      g (f x y)
 381 -- where g has rules, then we *do* want to inline f, in case it
 382 -- exposes a rule that might fire.  Similarly, if the context is
 383 --      h (g (f x x))
 384 -- where h has rules, then we do want to inline f; hence the
 385 -- call_cont argument to interestingArgContext
 386 --
 387 -- The interesting_arg_ctxt flag makes this happen; if it's
 388 -- set, the inliner gets just enough keener to inline f
 389 -- regardless of how boring f's arguments are, if it's marked INLINE
 390 --
 391 -- The alternative would be to *always* inline an INLINE function,
 392 -- regardless of how boring its context is; but that seems overkill
 393 -- For example, it'd mean that wrapper functions were always inlined
 394 interestingArgContext fn call_cont
 395   = idHasRules fn || go call_cont
 396   where
 397     go (Select {})            = False
 398     go (ApplyTo {})           = False
 399     go (StrictArg {})         = True
 400     go (StrictBind {})        = False   -- ??
 401     go (CoerceIt _ c)         = go c
 402     go (Stop _ _ interesting) = interesting
 403
 404 -------------------
 405 canUpdateInPlace :: Type -> Bool
 406 -- Consider   let x = <wurble> in ...
 407 -- If <wurble> returns an explicit constructor, we might be able
 408 -- to do update in place.  So we treat even a thunk RHS context
 409 -- as interesting if update in place is possible.  We approximate
 410 -- this by seeing if the type has a single constructor with a
 411 -- small arity.  But arity zero isn't good -- we share the single copy
 412 -- for that case, so no point in sharing.
 413
 414 canUpdateInPlace ty
 415   | not opt_UF_UpdateInPlace = False
 416   | otherwise
 417   = case splitTyConApp_maybe ty of
 418         Nothing         -> False
 419         Just (tycon, _) -> case tyConDataCons_maybe tycon of
 420                                 Just [dc]  -> arity == 1 || arity == 2
 421                                            where
 422                                               arity = dataConRepArity dc
 423                                 other -> False
 424 \end{code}
 425
 426
 427
 428 %************************************************************************
 429 %*                                                                      *
 430 \subsection{Decisions about inlining}
 431 %*                                                                      *
 432 %************************************************************************
 433
 434 Inlining is controlled partly by the SimplifierMode switch.  This has two
 435 settings:
 436
 437         SimplGently     (a) Simplifying before specialiser/full laziness
 438                         (b) Simplifiying inside INLINE pragma
 439                         (c) Simplifying the LHS of a rule
 440                         (d) Simplifying a GHCi expression or Template
 441                                 Haskell splice
 442
 443         SimplPhase n    Used at all other times
 444
 445 The key thing about SimplGently is that it does no call-site inlining.
 446 Before full laziness we must be careful not to inline wrappers,
 447 because doing so inhibits floating
 448     e.g. ...(case f x of ...)...
 449     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 450     ==> ...(case x of I# x# -> case fw x# of ...)...
 451 and now the redex (f x) isn't floatable any more.
 452
 453 The no-inlining thing is also important for Template Haskell.  You might be
 454 compiling in one-shot mode with -O2; but when TH compiles a splice before
 455 running it, we don't want to use -O2.  Indeed, we don't want to inline
 456 anything, because the byte-code interpreter might get confused about
 457 unboxed tuples and suchlike.
 458
 459 INLINE pragmas
 460 ~~~~~~~~~~~~~~
 461 SimplGently is also used as the mode to simplify inside an InlineMe note.
 462
 463 \begin{code}
 464 inlineMode :: SimplifierMode
 465 inlineMode = SimplGently
 466 \end{code}
 467
 468 It really is important to switch off inlinings inside such
 469 expressions.  Consider the following example
 470
 471         let f = \pq -> BIG
 472         in
 473         let g = \y -> f y y
 474             {-# INLINE g #-}
 475         in ...g...g...g...g...g...
 476
 477 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 478 and thence copied multiple times when g is inlined.
 479
 480
 481 This function may be inlinined in other modules, so we
 482 don't want to remove (by inlining) calls to functions that have
 483 specialisations, or that may have transformation rules in an importing
 484 scope.
 485
 486 E.g.    {-# INLINE f #-}
 487                 f x = ...g...
 488
 489 and suppose that g is strict *and* has specialisations.  If we inline
 490 g's wrapper, we deny f the chance of getting the specialised version
 491 of g when f is inlined at some call site (perhaps in some other
 492 module).
 493
 494 It's also important not to inline a worker back into a wrapper.
 495 A wrapper looks like
 496         wraper = inline_me (\x -> ...worker... )
 497 Normally, the inline_me prevents the worker getting inlined into
 498 the wrapper (initially, the worker's only call site!).  But,
 499 if the wrapper is sure to be called, the strictness analyser will
 500 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 501 continuation.  That's why the keep_inline predicate returns True for
 502 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 503 inline-me note under these circumstances.
 504
 505 Note that the result is that we do very little simplification
 506 inside an InlineMe.
 507
 508         all xs = foldr (&&) True xs
 509         any p = all . map p  {-# INLINE any #-}
 510
 511 Problem: any won't get deforested, and so if it's exported and the
 512 importer doesn't use the inlining, (eg passes it as an arg) then we
 513 won't get deforestation at all.  We havn't solved this problem yet!
 514
 515
 516 preInlineUnconditionally
 517 ~~~~~~~~~~~~~~~~~~~~~~~~
 518 @preInlineUnconditionally@ examines a bndr to see if it is used just
 519 once in a completely safe way, so that it is safe to discard the
 520 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 521 big the RHS might be.  If this is the case we don't simplify the RHS
 522 first, but just inline it un-simplified.
 523
 524 This is much better than first simplifying a perhaps-huge RHS and then
 525 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 526 better.  Consider
 527
 528         x1 = e1
 529         x2 = e2[x1]
 530         x3 = e3[x2]
 531         ...etc...
 532         xN = eN[xN-1]
 533
 534 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 535 This can happen with cascades of functions too:
 536
 537         f1 = \x1.e1
 538         f2 = \xs.e2[f1]
 539         f3 = \xs.e3[f3]
 540         ...etc...
 541
 542 THE MAIN INVARIANT is this:
 543
 544         ----  preInlineUnconditionally invariant -----
 545    IF preInlineUnconditionally chooses to inline x = <rhs>
 546    THEN doing the inlining should not change the occurrence
 547         info for the free vars of <rhs>
 548         ----------------------------------------------
 549
 550 For example, it's tempting to look at trivial binding like
 551         x = y
 552 and inline it unconditionally.  But suppose x is used many times,
 553 but this is the unique occurrence of y.  Then inlining x would change
 554 y's occurrence info, which breaks the invariant.  It matters: y
 555 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
 556
 557
 558 Even RHSs labelled InlineMe aren't caught here, because there might be
 559 no benefit from inlining at the call site.
 560
 561 [Sept 01] Don't unconditionally inline a top-level thing, because that
 562 can simply make a static thing into something built dynamically.  E.g.
 563         x = (a,b)
 564         main = \s -> h x
 565
 566 [Remember that we treat \s as a one-shot lambda.]  No point in
 567 inlining x unless there is something interesting about the call site.
 568
 569 But watch out: if you aren't careful, some useful foldr/build fusion
 570 can be lost (most notably in spectral/hartel/parstof) because the
 571 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 572 deal, in fact, but losing the fusion can be.  But the right thing here
 573 seems to be to do a callSiteInline based on the fact that there is
 574 something interesting about the call site (it's strict).  Hmm.  That
 575 seems a bit fragile.
 576
 577 Conclusion: inline top level things gaily until Phase 0 (the last
 578 phase), at which point don't.
 579
 580 \begin{code}
 581 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
 582 preInlineUnconditionally env top_lvl bndr rhs
 583   | not active             = False
 584   | opt_SimplNoPreInlining = False
 585   | otherwise = case idOccInfo bndr of
 586                   IAmDead                    -> True    -- Happens in ((\x.1) v)
 587                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
 588                   other                      -> False
 589   where
 590     phase = getMode env
 591     active = case phase of
 592                    SimplGently  -> isAlwaysActive prag
 593                    SimplPhase n -> isActive n prag
 594     prag = idInlinePragma bndr
 595
 596     try_once in_lam int_cxt     -- There's one textual occurrence
 597         | not in_lam = isNotTopLevel top_lvl || early_phase
 598         | otherwise  = int_cxt && canInlineInLam rhs
 599
 600 -- Be very careful before inlining inside a lambda, becuase (a) we must not
 601 -- invalidate occurrence information, and (b) we want to avoid pushing a
 602 -- single allocation (here) into multiple allocations (inside lambda).
 603 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
 604 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
 605 --      where
 606 --              is_cheap = exprIsCheap rhs
 607 --              ok = is_cheap && int_cxt
 608
 609         --      int_cxt         The context isn't totally boring
 610         -- E.g. let f = \ab.BIG in \y. map f xs
 611         --      Don't want to substitute for f, because then we allocate
 612         --      its closure every time the \y is called
 613         -- But: let f = \ab.BIG in \y. map (f y) xs
 614         --      Now we do want to substitute for f, even though it's not
 615         --      saturated, because we're going to allocate a closure for
 616         --      (f y) every time round the loop anyhow.
 617
 618         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
 619         -- so substituting rhs inside a lambda doesn't change the occ info.
 620         -- Sadly, not quite the same as exprIsHNF.
 621     canInlineInLam (Lit l)              = True
 622     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
 623     canInlineInLam (Note _ e)           = canInlineInLam e
 624     canInlineInLam _                    = False
 625
 626     early_phase = case phase of
 627                         SimplPhase 0 -> False
 628                         other        -> True
 629 -- If we don't have this early_phase test, consider
 630 --      x = length [1,2,3]
 631 -- The full laziness pass carefully floats all the cons cells to
 632 -- top level, and preInlineUnconditionally floats them all back in.
 633 -- Result is (a) static allocation replaced by dynamic allocation
 634 --           (b) many simplifier iterations because this tickles
 635 --               a related problem; only one inlining per pass
 636 --
 637 -- On the other hand, I have seen cases where top-level fusion is
 638 -- lost if we don't inline top level thing (e.g. string constants)
 639 -- Hence the test for phase zero (which is the phase for all the final
 640 -- simplifications).  Until phase zero we take no special notice of
 641 -- top level things, but then we become more leery about inlining
 642 -- them.
 643
 644 \end{code}
 645
 646 postInlineUnconditionally
 647 ~~~~~~~~~~~~~~~~~~~~~~~~~
 648 @postInlineUnconditionally@ decides whether to unconditionally inline
 649 a thing based on the form of its RHS; in particular if it has a
 650 trivial RHS.  If so, we can inline and discard the binding altogether.
 651
 652 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 653 only have *forward* references Hence, it's safe to discard the binding
 654
 655 NOTE: This isn't our last opportunity to inline.  We're at the binding
 656 site right now, and we'll get another opportunity when we get to the
 657 ocurrence(s)
 658
 659 Note that we do this unconditional inlining only for trival RHSs.
 660 Don't inline even WHNFs inside lambdas; doing so may simply increase
 661 allocation when the function is called. This isn't the last chance; see
 662 NOTE above.
 663
 664 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 665 Because we don't even want to inline them into the RHS of constructor
 666 arguments. See NOTE above
 667
 668 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 669 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 670 with both a and b marked NOINLINE.  But that seems incompatible with
 671 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 672 story for now.
 673
 674 \begin{code}
 675 postInlineUnconditionally
 676     :: SimplEnv -> TopLevelFlag
 677     -> InId             -- The binder (an OutId would be fine too)
 678     -> OccInfo          -- From the InId
 679     -> OutExpr
 680     -> Unfolding
 681     -> Bool
 682 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
 683   | not active             = False
 684   | isLoopBreaker occ_info = False      -- If it's a loop-breaker of any kind, dont' inline
 685                                         -- because it might be referred to "earlier"
 686   | isExportedId bndr      = False
 687   | exprIsTrivial rhs      = True
 688   | otherwise
 689   = case occ_info of
 690         -- The point of examining occ_info here is that for *non-values*
 691         -- that occur outside a lambda, the call-site inliner won't have
 692         -- a chance (becuase it doesn't know that the thing
 693         -- only occurs once).   The pre-inliner won't have gotten
 694         -- it either, if the thing occurs in more than one branch
 695         -- So the main target is things like
 696         --      let x = f y in
 697         --      case v of
 698         --         True  -> case x of ...
 699         --         False -> case x of ...
 700         -- I'm not sure how important this is in practice
 701       OneOcc in_lam one_br int_cxt      -- OneOcc => no code-duplication issue
 702         ->     smallEnoughToInline unfolding    -- Small enough to dup
 703                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
 704                         --
 705                         -- NB: Do NOT inline arbitrarily big things, even if one_br is True
 706                         -- Reason: doing so risks exponential behaviour.  We simplify a big
 707                         --         expression, inline it, and simplify it again.  But if the
 708                         --         very same thing happens in the big expression, we get
 709                         --         exponential cost!
 710                         -- PRINCIPLE: when we've already simplified an expression once,
 711                         -- make sure that we only inline it if it's reasonably small.
 712
 713            &&  ((isNotTopLevel top_lvl && not in_lam) ||
 714                         -- But outside a lambda, we want to be reasonably aggressive
 715                         -- about inlining into multiple branches of case
 716                         -- e.g. let x = <non-value>
 717                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... }
 718                         -- Inlining can be a big win if C3 is the hot-spot, even if
 719                         -- the uses in C1, C2 are not 'interesting'
 720                         -- An example that gets worse if you add int_cxt here is 'clausify'
 721
 722                 (isCheapUnfolding unfolding && int_cxt))
 723                         -- isCheap => acceptable work duplication; in_lam may be true
 724                         -- int_cxt to prevent us inlining inside a lambda without some
 725                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
 726
 727       IAmDead -> True   -- This happens; for example, the case_bndr during case of
 728                         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 729                         -- Here x isn't mentioned in the RHS, so we don't want to
 730                         -- create the (dead) let-binding  let x = (a,b) in ...
 731
 732       other -> False
 733
 734 -- Here's an example that we don't handle well:
 735 --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
 736 --      in \y. ....case f of {...} ....
 737 -- Here f is used just once, and duplicating the case work is fine (exprIsCheap).
 738 -- But
 739 -- * We can't preInlineUnconditionally because that woud invalidate
 740 --   the occ info for b.
 741 -- * We can't postInlineUnconditionally because the RHS is big, and
 742 --   that risks exponential behaviour
 743 -- * We can't call-site inline, because the rhs is big
 744 -- Alas!
 745
 746   where
 747     active = case getMode env of
 748                    SimplGently  -> isAlwaysActive prag
 749                    SimplPhase n -> isActive n prag
 750     prag = idInlinePragma bndr
 751
 752 activeInline :: SimplEnv -> OutId -> Bool
 753 activeInline env id
 754   = case getMode env of
 755       SimplGently -> False
 756         -- No inlining at all when doing gentle stuff,
 757         -- except for local things that occur once
 758         -- The reason is that too little clean-up happens if you
 759         -- don't inline use-once things.   Also a bit of inlining is *good* for
 760         -- full laziness; it can expose constant sub-expressions.
 761         -- Example in spectral/mandel/Mandel.hs, where the mandelset
 762         -- function gets a useful let-float if you inline windowToViewport
 763
 764         -- NB: we used to have a second exception, for data con wrappers.
 765         -- On the grounds that we use gentle mode for rule LHSs, and
 766         -- they match better when data con wrappers are inlined.
 767         -- But that only really applies to the trivial wrappers (like (:)),
 768         -- and they are now constructed as Compulsory unfoldings (in MkId)
 769         -- so they'll happen anyway.
 770
 771       SimplPhase n -> isActive n prag
 772   where
 773     prag = idInlinePragma id
 774
 775 activeRule :: DynFlags -> SimplEnv -> Maybe (Activation -> Bool)
 776 -- Nothing => No rules at all
 777 activeRule dflags env
 778   | not (dopt Opt_RewriteRules dflags)
 779   = Nothing     -- Rewriting is off
 780   | otherwise
 781   = case getMode env of
 782         SimplGently  -> Just isAlwaysActive
 783                         -- Used to be Nothing (no rules in gentle mode)
 784                         -- Main motivation for changing is that I wanted
 785                         --      lift String ===> ...
 786                         -- to work in Template Haskell when simplifying
 787                         -- splices, so we get simpler code for literal strings
 788         SimplPhase n -> Just (isActive n)
 789 \end{code}
 790
 791
 792 %************************************************************************
 793 %*                                                                      *
 794         Rebuilding a lambda
 795 %*                                                                      *
 796 %************************************************************************
 797
 798 \begin{code}
 799 mkLam :: [OutBndr] -> OutExpr -> SimplM OutExpr
 800 -- mkLam tries three things
 801 --      a) eta reduction, if that gives a trivial expression
 802 --      b) eta expansion [only if there are some value lambdas]
 803
 804 mkLam [] body
 805   = return body
 806 mkLam bndrs body
 807   = do  { dflags <- getDOptsSmpl
 808         ; mkLam' dflags bndrs body }
 809   where
 810     mkLam' :: DynFlags -> [OutBndr] -> OutExpr -> SimplM OutExpr
 811     mkLam' dflags bndrs (Cast body co)
 812       | not (any bad bndrs)
 813         -- Note [Casts and lambdas]
 814       = do { lam <- mkLam' dflags bndrs body
 815            ; return (mkCoerce (mkPiTypes bndrs co) lam) }
 816       where
 817         co_vars  = tyVarsOfType co
 818         bad bndr = isCoVar bndr && bndr `elemVarSet` co_vars
 819
 820     mkLam' dflags bndrs body
 821       | dopt Opt_DoEtaReduction dflags,
 822         Just etad_lam <- tryEtaReduce bndrs body
 823       = do { tick (EtaReduction (head bndrs))
 824            ; return etad_lam }
 825
 826       | dopt Opt_DoLambdaEtaExpansion dflags,
 827         any isRuntimeVar bndrs
 828       = do { body' <- tryEtaExpansion dflags body
 829            ; return (mkLams bndrs body') }
 830
 831       | otherwise
 832       = returnSmpl (mkLams bndrs body)
 833 \end{code}
 834
 835 Note [Casts and lambdas]
 836 ~~~~~~~~~~~~~~~~~~~~~~~~
 837 Consider
 838         (\x. (\y. e) `cast` g1) `cast` g2
 839 There is a danger here that the two lambdas look separated, and the
 840 full laziness pass might float an expression to between the two.
 841
 842 So this equation in mkLam' floats the g1 out, thus:
 843         (\x. e `cast` g1)  -->  (\x.e) `cast` (tx -> g1)
 844 where x:tx.
 845
 846 In general, this floats casts outside lambdas, where (I hope) they
 847 might meet and cancel with some other cast:
 848         \x. e `cast` co   ===>   (\x. e) `cast` (tx -> co)
 849         /\a. e `cast` co  ===>   (/\a. e) `cast` (/\a. co)
 850         /\g. e `cast` co  ===>   (/\g. e) `cast` (/\g. co)
 851                           (if not (g `in` co))
 852
 853 Notice that it works regardless of 'e'.  Originally it worked only
 854 if 'e' was itself a lambda, but in some cases that resulted in
 855 fruitless iteration in the simplifier.  A good example was when
 856 compiling Text.ParserCombinators.ReadPrec, where we had a definition
 857 like    (\x. Get `cast` g)
 858 where Get is a constructor with nonzero arity.  Then mkLam eta-expanded
 859 the Get, and the next iteration eta-reduced it, and then eta-expanded
 860 it again.
 861
 862 Note also the side condition for the case of coercion binders.
 863 It does not make sense to transform
 864         /\g. e `cast` g  ==>  (/\g.e) `cast` (/\g.g)
 865 because the latter is not well-kinded.
 866
 867 --      c) floating lets out through big lambdas
 868 --              [only if all tyvar lambdas, and only if this lambda
 869 --               is the RHS of a let]
 870
 871 {-      Sept 01: I'm experimenting with getting the
 872         full laziness pass to float out past big lambdsa
 873  | all isTyVar bndrs,   -- Only for big lambdas
 874    contIsRhs cont       -- Only try the rhs type-lambda floating
 875                         -- if this is indeed a right-hand side; otherwise
 876                         -- we end up floating the thing out, only for float-in
 877                         -- to float it right back in again!
 878  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 879    returnSmpl (floats, mkLams bndrs body')
 880 -}
 881
 882
 883 %************************************************************************
 884 %*                                                                      *
 885                 Eta reduction
 886 %*                                                                      *
 887 %************************************************************************
 888
 889 Note [Eta reduction conditions]
 890 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 891 We try for eta reduction here, but *only* if we get all the way to an
 892 trivial expression.  We don't want to remove extra lambdas unless we
 893 are going to avoid allocating this thing altogether.
 894
 895 There are some particularly delicate points here:
 896
 897 * Eta reduction is not valid in general:
 898         \x. bot  /=  bot
 899   This matters, partly for old-fashioned correctness reasons but,
 900   worse, getting it wrong can yield a seg fault. Consider
 901         f = \x.f x
 902         h y = case (case y of { True -> f `seq` True; False -> False }) of
 903                 True -> ...; False -> ...
 904
 905   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
 906   says f=bottom, and replaces the (f `seq` True) with just
 907   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
 908   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
 909   the definition again, so that it does not termninate after all.
 910   Result: seg-fault because the boolean case actually gets a function value.
 911   See Trac #1947.
 912
 913   So it's important to to the right thing.
 914
 915 * We need to be careful if we just look at f's arity. Currently (Dec07),
 916   f's arity is visible in its own RHS (see Note [Arity robustness] in
 917   SimplEnv) so we must *not* trust the arity when checking that 'f' is
 918   a value.  Instead, look at the unfolding.
 919
 920   However for GlobalIds we can look at the arity; and for primops we
 921   must, since they have no unfolding.
 922
 923 * Regardless of whether 'f' is a vlaue, we always want to
 924   reduce (/\a -> f a) to f
 925   This came up in a RULE: foldr (build (/\a -> g a))
 926   did not match            foldr (build (/\b -> ...something complex...))
 927   The type checker can insert these eta-expanded versions,
 928   with both type and dictionary lambdas; hence the slightly
 929   ad-hoc isDictId
 930
 931 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
 932 Alas.
 933
 934 \begin{code}
 935 tryEtaReduce :: [OutBndr] -> OutExpr -> Maybe OutExpr
 936 tryEtaReduce bndrs body
 937   = go (reverse bndrs) body
 938   where
 939     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 940     go []       fun           | ok_fun fun   = Just fun         -- Success!
 941     go _        _                            = Nothing          -- Failure!
 942
 943         -- Note [Eta reduction conditions]
 944     ok_fun (App fun (Type ty))
 945         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
 946         =  ok_fun fun
 947     ok_fun (Var fun_id)
 948         =  not (fun_id `elem` bndrs)
 949         && (ok_fun_id fun_id || all ok_lam bndrs)
 950     ok_fun _fun = False
 951
 952     ok_fun_id fun
 953         | isLocalId fun       = isEvaldUnfolding (idUnfolding fun)
 954         | isDataConWorkId fun = True
 955         | isGlobalId fun      = idArity fun > 0
 956
 957     ok_lam v = isTyVar v || isDictId v
 958
 959     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 960 \end{code}
 961
 962
 963 %************************************************************************
 964 %*                                                                      *
 965                 Eta expansion
 966 %*                                                                      *
 967 %************************************************************************
 968
 969
 970 We go for:
 971    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 972                                  (n >= 0)
 973
 974 where (in both cases)
 975
 976         * The xi can include type variables
 977
 978         * The yi are all value variables
 979
 980         * N is a NORMAL FORM (i.e. no redexes anywhere)
 981           wanting a suitable number of extra args.
 982
 983 The biggest reason for doing this is for cases like
 984
 985         f = \x -> case x of
 986                     True  -> \y -> e1
 987                     False -> \y -> e2
 988
 989 Here we want to get the lambdas together.  A good exmaple is the nofib
 990 program fibheaps, which gets 25% more allocation if you don't do this
 991 eta-expansion.
 992
 993 We may have to sandwich some coerces between the lambdas
 994 to make the types work.   exprEtaExpandArity looks through coerces
 995 when computing arity; and etaExpand adds the coerces as necessary when
 996 actually computing the expansion.
 997
 998 \begin{code}
 999 tryEtaExpansion :: DynFlags -> OutExpr -> SimplM OutExpr
1000 -- There is at least one runtime binder in the binders
1001 tryEtaExpansion dflags body
1002   = getUniquesSmpl                      `thenSmpl` \ us ->
1003     returnSmpl (etaExpand fun_arity us body (exprType body))
1004   where
1005     fun_arity = exprEtaExpandArity dflags body
1006 \end{code}
1007
1008
1009 %************************************************************************
1010 %*                                                                      *
1011 \subsection{Floating lets out of big lambdas}
1012 %*                                                                      *
1013 %************************************************************************
1014
1015 Note [Floating and type abstraction]
1016 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1017 Consider this:
1018         x = /\a. C e1 e2
1019 We'd like to float this to
1020         y1 = /\a. e1
1021         y2 = /\a. e2
1022         x = /\a. C (y1 a) (y2 a)
1023 for the usual reasons: we want to inline x rather vigorously.
1024
1025 You may think that this kind of thing is rare.  But in some programs it is
1026 common.  For example, if you do closure conversion you might get:
1027
1028         data a :-> b = forall e. (e -> a -> b) :$ e
1029
1030         f_cc :: forall a. a :-> a
1031         f_cc = /\a. (\e. id a) :$ ()
1032
1033 Now we really want to inline that f_cc thing so that the
1034 construction of the closure goes away.
1035
1036 So I have elaborated simplLazyBind to understand right-hand sides that look
1037 like
1038         /\ a1..an. body
1039
1040 and treat them specially. The real work is done in SimplUtils.abstractFloats,
1041 but there is quite a bit of plumbing in simplLazyBind as well.
1042
1043 The same transformation is good when there are lets in the body:
1044
1045         /\abc -> let(rec) x = e in b
1046    ==>
1047         let(rec) x' = /\abc -> let x = x' a b c in e
1048         in
1049         /\abc -> let x = x' a b c in b
1050
1051 This is good because it can turn things like:
1052
1053         let f = /\a -> letrec g = ... g ... in g
1054 into
1055         letrec g' = /\a -> ... g' a ...
1056         in
1057         let f = /\ a -> g' a
1058
1059 which is better.  In effect, it means that big lambdas don't impede
1060 let-floating.
1061
1062 This optimisation is CRUCIAL in eliminating the junk introduced by
1063 desugaring mutually recursive definitions.  Don't eliminate it lightly!
1064
1065 [May 1999]  If we do this transformation *regardless* then we can
1066 end up with some pretty silly stuff.  For example,
1067
1068         let
1069             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
1070         in ..
1071 becomes
1072         let y1 = /\s -> r1
1073             y2 = /\s -> r2
1074             st = /\s -> ...[y1 s/x1, y2 s/x2]
1075         in ..
1076
1077 Unless the "..." is a WHNF there is really no point in doing this.
1078 Indeed it can make things worse.  Suppose x1 is used strictly,
1079 and is of the form
1080
1081         x1* = case f y of { (a,b) -> e }
1082
1083 If we abstract this wrt the tyvar we then can't do the case inline
1084 as we would normally do.
1085
1086 That's why the whole transformation is part of the same process that
1087 floats let-bindings and constructor arguments out of RHSs.  In particular,
1088 it is guarded by the doFloatFromRhs call in simplLazyBind.
1089
1090
1091 \begin{code}
1092 abstractFloats :: [OutTyVar] -> SimplEnv -> OutExpr -> SimplM ([OutBind], OutExpr)
1093 abstractFloats main_tvs body_env body
1094   = ASSERT( notNull body_floats )
1095     do  { (subst, float_binds) <- mapAccumLSmpl abstract empty_subst body_floats
1096         ; return (float_binds, CoreSubst.substExpr subst body) }
1097   where
1098     main_tv_set = mkVarSet main_tvs
1099     body_floats = getFloats body_env
1100     empty_subst = CoreSubst.mkEmptySubst (seInScope body_env)
1101
1102     abstract :: CoreSubst.Subst -> OutBind -> SimplM (CoreSubst.Subst, OutBind)
1103     abstract subst (NonRec id rhs)
1104       = do { (poly_id, poly_app) <- mk_poly tvs_here id
1105            ; let poly_rhs = mkLams tvs_here rhs'
1106                  subst'   = CoreSubst.extendIdSubst subst id poly_app
1107            ; return (subst', (NonRec poly_id poly_rhs)) }
1108       where
1109         rhs' = CoreSubst.substExpr subst rhs
1110         tvs_here | any isCoVar main_tvs = main_tvs      -- Note [Abstract over coercions]
1111                  | otherwise
1112                  = varSetElems (main_tv_set `intersectVarSet` exprSomeFreeVars isTyVar rhs')
1113
1114                 -- Abstract only over the type variables free in the rhs
1115                 -- wrt which the new binding is abstracted.  But the naive
1116                 -- approach of abstract wrt the tyvars free in the Id's type
1117                 -- fails. Consider:
1118                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1119                 --                    x :: a     = fst t
1120                 --                in ...
1121                 -- Here, b isn't free in x's type, but we must nevertheless
1122                 -- abstract wrt b as well, because t's type mentions b.
1123                 -- Since t is floated too, we'd end up with the bogus:
1124                 --      poly_t = /\ a b -> (e1, e2)
1125                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1126                 -- So for now we adopt the even more naive approach of
1127                 -- abstracting wrt *all* the tyvars.  We'll see if that
1128                 -- gives rise to problems.   SLPJ June 98
1129
1130     abstract subst (Rec prs)
1131        = do { (poly_ids, poly_apps) <- mapAndUnzipSmpl (mk_poly tvs_here) ids
1132             ; let subst' = CoreSubst.extendSubstList subst (ids `zip` poly_apps)
1133                   poly_rhss = [mkLams tvs_here (CoreSubst.substExpr subst' rhs) | rhs <- rhss]
1134             ; return (subst', Rec (poly_ids `zip` poly_rhss)) }
1135        where
1136          (ids,rhss) = unzip prs
1137                 -- For a recursive group, it's a bit of a pain to work out the minimal
1138                 -- set of tyvars over which to abstract:
1139                 --      /\ a b c.  let x = ...a... in
1140                 --                 letrec { p = ...x...q...
1141                 --                          q = .....p...b... } in
1142                 --                 ...
1143                 -- Since 'x' is abstracted over 'a', the {p,q} group must be abstracted
1144                 -- over 'a' (because x is replaced by (poly_x a)) as well as 'b'.
1145                 -- Since it's a pain, we just use the whole set, which is always safe
1146                 --
1147                 -- If you ever want to be more selective, remember this bizarre case too:
1148                 --      x::a = x
1149                 -- Here, we must abstract 'x' over 'a'.
1150          tvs_here = main_tvs
1151
1152     mk_poly tvs_here var
1153       = do { uniq <- getUniqueSmpl
1154            ; let  poly_name = setNameUnique (idName var) uniq           -- Keep same name
1155                   poly_ty   = mkForAllTys tvs_here (idType var) -- But new type of course
1156                   poly_id   = mkLocalId poly_name poly_ty
1157            ; return (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tvs_here)) }
1158                 -- In the olden days, it was crucial to copy the occInfo of the original var,
1159                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1160                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1161                 -- at already simplified code, so it doesn't matter
1162                 --
1163                 -- It's even right to retain single-occurrence or dead-var info:
1164                 -- Suppose we started with  /\a -> let x = E in B
1165                 -- where x occurs once in B. Then we transform to:
1166                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1167                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1168                 -- the occurrences of x' will be just the occurrences originally
1169                 -- pinned on x.
1170 \end{code}
1171
1172 Note [Abstract over coercions]
1173 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1174 If a coercion variable (g :: a ~ Int) is free in the RHS, then so is the
1175 type variable a.  Rather than sort this mess out, we simply bale out and abstract
1176 wrt all the type variables if any of them are coercion variables.
1177
1178
1179 Historical note: if you use let-bindings instead of a substitution, beware of this:
1180
1181                 -- Suppose we start with:
1182                 --
1183                 --      x = /\ a -> let g = G in E
1184                 --
1185                 -- Then we'll float to get
1186                 --
1187                 --      x = let poly_g = /\ a -> G
1188                 --          in /\ a -> let g = poly_g a in E
1189                 --
1190                 -- But now the occurrence analyser will see just one occurrence
1191                 -- of poly_g, not inside a lambda, so the simplifier will
1192                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1193                 -- (I used to think that the "don't inline lone occurrences" stuff
1194                 --  would stop this happening, but since it's the *only* occurrence,
1195                 --  PreInlineUnconditionally kicks in first!)
1196                 --
1197                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1198                 --           to appear many times.  (NB: mkInlineMe eliminates
1199                 --           such notes on trivial RHSs, so do it manually.)
1200
1201 %************************************************************************
1202 %*                                                                      *
1203                 prepareAlts
1204 %*                                                                      *
1205 %************************************************************************
1206
1207 prepareAlts tries these things:
1208
1209 1.  If several alternatives are identical, merge them into
1210     a single DEFAULT alternative.  I've occasionally seen this
1211     making a big difference:
1212
1213         case e of               =====>     case e of
1214           C _ -> f x                         D v -> ....v....
1215           D v -> ....v....                   DEFAULT -> f x
1216           DEFAULT -> f x
1217
1218    The point is that we merge common RHSs, at least for the DEFAULT case.
1219    [One could do something more elaborate but I've never seen it needed.]
1220    To avoid an expensive test, we just merge branches equal to the *first*
1221    alternative; this picks up the common cases
1222         a) all branches equal
1223         b) some branches equal to the DEFAULT (which occurs first)
1224
1225 2.  Case merging:
1226        case e of b {             ==>   case e of b {
1227          p1 -> rhs1                      p1 -> rhs1
1228          ...                             ...
1229          pm -> rhsm                      pm -> rhsm
1230          _  -> case b of b' {            pn -> let b'=b in rhsn
1231                      pn -> rhsn          ...
1232                      ...                 po -> let b'=b in rhso
1233                      po -> rhso          _  -> let b'=b in rhsd
1234                      _  -> rhsd
1235        }
1236
1237     which merges two cases in one case when -- the default alternative of
1238     the outer case scrutises the same variable as the outer case This
1239     transformation is called Case Merging.  It avoids that the same
1240     variable is scrutinised multiple times.
1241
1242
1243 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1244
1245         x | p `is` 1 -> e1
1246           | p `is` 2 -> e2
1247         ...etc...
1248
1249 where @is@ was something like
1250
1251         p `is` n = p /= (-1) && p == n
1252
1253 This gave rise to a horrible sequence of cases
1254
1255         case p of
1256           (-1) -> $j p
1257           1    -> e1
1258           DEFAULT -> $j p
1259
1260 and similarly in cascade for all the join points!
1261
1262 Note [Dead binders]
1263 ~~~~~~~~~~~~~~~~~~~~
1264 We do this *here*, looking at un-simplified alternatives, because we
1265 have to check that r doesn't mention the variables bound by the
1266 pattern in each alternative, so the binder-info is rather useful.
1267
1268 \begin{code}
1269 prepareAlts :: SimplEnv -> OutExpr -> OutId -> [InAlt] -> SimplM ([AltCon], [InAlt])
1270 prepareAlts env scrut case_bndr' alts
1271   = do  { dflags <- getDOptsSmpl
1272         ; alts <- combineIdenticalAlts case_bndr' alts
1273
1274         ; let (alts_wo_default, maybe_deflt) = findDefault alts
1275               alt_cons = [con | (con,_,_) <- alts_wo_default]
1276               imposs_deflt_cons = nub (imposs_cons ++ alt_cons)
1277                 -- "imposs_deflt_cons" are handled
1278                 --   EITHER by the context,
1279                 --   OR by a non-DEFAULT branch in this case expression.
1280
1281         ; default_alts <- prepareDefault dflags env case_bndr' mb_tc_app
1282                                          imposs_deflt_cons maybe_deflt
1283
1284         ; let trimmed_alts = filterOut impossible_alt alts_wo_default
1285               merged_alts = mergeAlts trimmed_alts default_alts
1286                 -- We need the mergeAlts in case the new default_alt
1287                 -- has turned into a constructor alternative.
1288                 -- The merge keeps the inner DEFAULT at the front, if there is one
1289                 -- and interleaves the alternatives in the right order
1290
1291         ; return (imposs_deflt_cons, merged_alts) }
1292   where
1293     mb_tc_app = splitTyConApp_maybe (idType case_bndr')
1294     Just (_, inst_tys) = mb_tc_app
1295
1296     imposs_cons = case scrut of
1297                     Var v -> otherCons (idUnfolding v)
1298                     other -> []
1299
1300     impossible_alt :: CoreAlt -> Bool
1301     impossible_alt (con, _, _) | con `elem` imposs_cons = True
1302     impossible_alt (DataAlt con, _, _) = dataConCannotMatch inst_tys con
1303     impossible_alt alt                 = False
1304
1305
1306 --------------------------------------------------
1307 --      1. Merge identical branches
1308 --------------------------------------------------
1309 combineIdenticalAlts :: OutId -> [InAlt] -> SimplM [InAlt]
1310
1311 combineIdenticalAlts case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1312   | all isDeadBinder bndrs1,                    -- Remember the default
1313     length filtered_alts < length con_alts      -- alternative comes first
1314         -- Also Note [Dead binders]
1315   = do  { tick (AltMerge case_bndr)
1316         ; return ((DEFAULT, [], rhs1) : filtered_alts) }
1317   where
1318     filtered_alts        = filter keep con_alts
1319     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1320
1321 combineIdenticalAlts case_bndr alts = return alts
1322
1323 -------------------------------------------------------------------------
1324 --                      Prepare the default alternative
1325 -------------------------------------------------------------------------
1326 prepareDefault :: DynFlags
1327                -> SimplEnv
1328                -> OutId         -- Case binder; need just for its type. Note that as an
1329                                 --   OutId, it has maximum information; this is important.
1330                                 --   Test simpl013 is an example
1331                -> Maybe (TyCon, [Type]) -- Type of scrutinee, decomposed
1332                -> [AltCon]      -- These cons can't happen when matching the default
1333                -> Maybe InExpr  -- Rhs
1334                -> SimplM [InAlt]        -- Still unsimplified
1335                                         -- We use a list because it's what mergeAlts expects,
1336                                         -- And becuase case-merging can cause many to show up
1337
1338 ------- Merge nested cases ----------
1339 prepareDefault dflags env outer_bndr bndr_ty imposs_cons (Just deflt_rhs)
1340   | dopt Opt_CaseMerge dflags
1341   , Case (Var inner_scrut_var) inner_bndr _ inner_alts <- deflt_rhs
1342   , DoneId inner_scrut_var' <- substId env inner_scrut_var
1343         -- Remember, inner_scrut_var is an InId, but outer_bndr is an OutId
1344   , inner_scrut_var' == outer_bndr
1345         -- NB: the substId means that if the outer scrutinee was a
1346         --     variable, and inner scrutinee is the same variable,
1347         --     then inner_scrut_var' will be outer_bndr
1348         --     via the magic of simplCaseBinder
1349   = do  { tick (CaseMerge outer_bndr)
1350
1351         ; let munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1352         ; return [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts,
1353                                                not (con `elem` imposs_cons) ]
1354                 -- NB: filter out any imposs_cons.  Example:
1355                 --      case x of
1356                 --        A -> e1
1357                 --        DEFAULT -> case x of
1358                 --                      A -> e2
1359                 --                      B -> e3
1360                 -- When we merge, we must ensure that e1 takes
1361                 -- precedence over e2 as the value for A!
1362         }
1363         -- Warning: don't call prepareAlts recursively!
1364         -- Firstly, there's no point, because inner alts have already had
1365         -- mkCase applied to them, so they won't have a case in their default
1366         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1367         -- in munge_rhs may put a case into the DEFAULT branch!
1368
1369
1370 --------- Fill in known constructor -----------
1371 prepareDefault dflags env case_bndr (Just (tycon, inst_tys)) imposs_cons (Just deflt_rhs)
1372   |     -- This branch handles the case where we are
1373         -- scrutinisng an algebraic data type
1374     isAlgTyCon tycon            -- It's a data type, tuple, or unboxed tuples.
1375   , not (isNewTyCon tycon)      -- We can have a newtype, if we are just doing an eval:
1376                                 --      case x of { DEFAULT -> e }
1377                                 -- and we don't want to fill in a default for them!
1378   , Just all_cons <- tyConDataCons_maybe tycon
1379   , not (null all_cons)         -- This is a tricky corner case.  If the data type has no constructors,
1380                                 -- which GHC allows, then the case expression will have at most a default
1381                                 -- alternative.  We don't want to eliminate that alternative, because the
1382                                 -- invariant is that there's always one alternative.  It's more convenient
1383                                 -- to leave
1384                                 --      case x of { DEFAULT -> e }
1385                                 -- as it is, rather than transform it to
1386                                 --      error "case cant match"
1387                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1388                                 -- not worth wasting code on.
1389   , let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1390         impossible con  = con `elem` imposs_data_cons || dataConCannotMatch inst_tys con
1391   = case filterOut impossible all_cons of
1392         []    -> return []      -- Eliminate the default alternative
1393                                 -- altogether if it can't match
1394
1395         [con] ->        -- It matches exactly one constructor, so fill it in
1396                  do { tick (FillInCaseDefault case_bndr)
1397                     ; us <- getUniquesSmpl
1398                     ; let (ex_tvs, co_tvs, arg_ids) =
1399                               dataConRepInstPat us con inst_tys
1400                     ; return [(DataAlt con, ex_tvs ++ co_tvs ++ arg_ids, deflt_rhs)] }
1401
1402         two_or_more -> return [(DEFAULT, [], deflt_rhs)]
1403
1404 --------- Catch-all cases -----------
1405 prepareDefault dflags env case_bndr bndr_ty imposs_cons (Just deflt_rhs)
1406   = return [(DEFAULT, [], deflt_rhs)]
1407
1408 prepareDefault dflags env case_bndr bndr_ty imposs_cons Nothing
1409   = return []   -- No default branch
1410 \end{code}
1411
1412
1413
1414 =================================================================================
1415
1416 mkCase tries these things
1417
1418 1.  Eliminate the case altogether if possible
1419
1420 2.  Case-identity:
1421
1422         case e of               ===> e
1423                 True  -> True;
1424                 False -> False
1425
1426     and similar friends.
1427
1428
1429 \begin{code}
1430 mkCase :: OutExpr -> OutId -> OutType
1431        -> [OutAlt]              -- Increasing order
1432        -> SimplM OutExpr
1433
1434 --------------------------------------------------
1435 --      1. Check for empty alternatives
1436 --------------------------------------------------
1437
1438 -- This isn't strictly an error.  It's possible that the simplifer might "see"
1439 -- that an inner case has no accessible alternatives before it "sees" that the
1440 -- entire branch of an outer case is inaccessible.  So we simply
1441 -- put an error case here insteadd
1442 mkCase scrut case_bndr ty []
1443   = pprTrace "mkCase: null alts" (ppr case_bndr <+> ppr scrut) $
1444     return (mkApps (Var rUNTIME_ERROR_ID)
1445                    [Type ty, Lit (mkStringLit "Impossible alternative")])
1446
1447
1448 --------------------------------------------------
1449 --      2. Identity case
1450 --------------------------------------------------
1451
1452 mkCase scrut case_bndr ty alts  -- Identity case
1453   | all identity_alt alts
1454   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1455     returnSmpl (re_cast scrut)
1456   where
1457     identity_alt (con, args, rhs) = check_eq con args (de_cast rhs)
1458
1459     check_eq DEFAULT       _    (Var v)   = v == case_bndr
1460     check_eq (LitAlt lit') _    (Lit lit) = lit == lit'
1461     check_eq (DataAlt con) args rhs       = rhs `cheapEqExpr` mkConApp con (arg_tys ++ varsToCoreExprs args)
1462                                          || rhs `cheapEqExpr` Var case_bndr
1463     check_eq con args rhs = False
1464
1465     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1466
1467         -- We've seen this:
1468         --      case e of x { _ -> x `cast` c }
1469         -- And we definitely want to eliminate this case, to give
1470         --      e `cast` c
1471         -- So we throw away the cast from the RHS, and reconstruct
1472         -- it at the other end.  All the RHS casts must be the same
1473         -- if (all identity_alt alts) holds.
1474         --
1475         -- Don't worry about nested casts, because the simplifier combines them
1476     de_cast (Cast e _) = e
1477     de_cast e          = e
1478
1479     re_cast scrut = case head alts of
1480                         (_,_,Cast _ co) -> Cast scrut co
1481                         other           -> scrut
1482
1483
1484
1485 --------------------------------------------------
1486 --      Catch-all
1487 --------------------------------------------------
1488 mkCase scrut bndr ty alts = returnSmpl (Case scrut bndr ty alts)
1489 \end{code}
1490
1491
1492 When adding auxiliary bindings for the case binder, it's worth checking if
1493 its dead, because it often is, and occasionally these mkCase transformations
1494 cascade rather nicely.
1495
1496 \begin{code}
1497 bindCaseBndr bndr rhs body
1498   | isDeadBinder bndr = body
1499   | otherwise         = bindNonRec bndr rhs body
1500 \end{code}