compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         -- Rebuilding
   9         mkLam, mkCase, prepareAlts,
  10
  11         -- Inlining,
  12         preInlineUnconditionally, postInlineUnconditionally,
  13         activeUnfolding, activeUnfInRule, activeRule,
  14         simplEnvForGHCi, simplEnvForRules, updModeForInlineRules,
  15
  16         -- The continuation type
  17         SimplCont(..), DupFlag(..), ArgInfo(..),
  18         contIsDupable, contResultType, contIsTrivial, contArgs, dropArgs,
  19         pushArgs, countValArgs, countArgs, addArgTo,
  20         mkBoringStop, mkRhsStop, mkLazyArgStop, contIsRhsOrArg,
  21         interestingCallContext,
  22
  23         interestingArg, mkArgInfo,
  24
  25         abstractFloats
  26     ) where
  27
  28 #include "HsVersions.h"
  29
  30 import SimplEnv
  31 import CoreMonad        ( SimplifierMode(..), Tick(..) )
  32 import DynFlags
  33 import StaticFlags
  34 import CoreSyn
  35 import qualified CoreSubst
  36 import PprCore
  37 import CoreFVs
  38 import CoreUtils
  39 import CoreArity        ( etaExpand, exprEtaExpandArity )
  40 import CoreUnfold
  41 import Name
  42 import Id
  43 import Var      ( isCoVar )
  44 import Demand
  45 import SimplMonad
  46 import Type     hiding( substTy )
  47 import Coercion ( coercionKind )
  48 import TyCon
  49 import Unify    ( dataConCannotMatch )
  50 import VarSet
  51 import BasicTypes
  52 import Util
  53 import MonadUtils
  54 import Outputable
  55 import FastString
  56
  57 import Data.List
  58 \end{code}
  59
  60
  61 %************************************************************************
  62 %*                                                                      *
  63                 The SimplCont type
  64 %*                                                                      *
  65 %************************************************************************
  66
  67 A SimplCont allows the simplifier to traverse the expression in a
  68 zipper-like fashion.  The SimplCont represents the rest of the expression,
  69 "above" the point of interest.
  70
  71 You can also think of a SimplCont as an "evaluation context", using
  72 that term in the way it is used for operational semantics. This is the
  73 way I usually think of it, For example you'll often see a syntax for
  74 evaluation context looking like
  75         C ::= []  |  C e   |  case C of alts  |  C `cast` co
  76 That's the kind of thing we are doing here, and I use that syntax in
  77 the comments.
  78
  79
  80 Key points:
  81   * A SimplCont describes a *strict* context (just like
  82     evaluation contexts do).  E.g. Just [] is not a SimplCont
  83
  84   * A SimplCont describes a context that *does not* bind
  85     any variables.  E.g. \x. [] is not a SimplCont
  86
  87 \begin{code}
  88 data SimplCont
  89   = Stop                -- An empty context, or hole, []
  90         CallCtxt        -- True <=> There is something interesting about
  91                         --          the context, and hence the inliner
  92                         --          should be a bit keener (see interestingCallContext)
  93                         -- Specifically:
  94                         --     This is an argument of a function that has RULES
  95                         --     Inlining the call might allow the rule to fire
  96
  97   | CoerceIt            -- C `cast` co
  98         OutCoercion             -- The coercion simplified
  99         SimplCont
 100
 101   | ApplyTo             -- C arg
 102         DupFlag
 103         InExpr StaticEnv                -- The argument and its static env
 104         SimplCont
 105
 106   | Select              -- case C of alts
 107         DupFlag
 108         InId [InAlt] StaticEnv  -- The case binder, alts, and subst-env
 109         SimplCont
 110
 111   -- The two strict forms have no DupFlag, because we never duplicate them
 112   | StrictBind          -- (\x* \xs. e) C
 113         InId [InBndr]           -- let x* = [] in e
 114         InExpr StaticEnv        --      is a special case
 115         SimplCont
 116
 117   | StrictArg           -- f e1 ..en C
 118         ArgInfo         -- Specifies f, e1..en, Whether f has rules, etc
 119                         --     plus strictness flags for *further* args
 120         CallCtxt        -- Whether *this* argument position is interesting
 121         SimplCont
 122
 123 data ArgInfo
 124   = ArgInfo {
 125         ai_fun   :: Id,         -- The function
 126         ai_args  :: [OutExpr],  -- ...applied to these args (which are in *reverse* order)
 127         ai_rules :: [CoreRule], -- Rules for this function
 128
 129         ai_encl :: Bool,        -- Flag saying whether this function
 130                                 -- or an enclosing one has rules (recursively)
 131                                 --      True => be keener to inline in all args
 132
 133         ai_strs :: [Bool],      -- Strictness of remaining arguments
 134                                 --   Usually infinite, but if it is finite it guarantees
 135                                 --   that the function diverges after being given
 136                                 --   that number of args
 137         ai_discs :: [Int]       -- Discounts for remaining arguments; non-zero => be keener to inline
 138                                 --   Always infinite
 139     }
 140
 141 addArgTo :: ArgInfo -> OutExpr -> ArgInfo
 142 addArgTo ai arg = ai { ai_args = arg : ai_args ai }
 143
 144 instance Outputable SimplCont where
 145   ppr (Stop interesting)             = ptext (sLit "Stop") <> brackets (ppr interesting)
 146   ppr (ApplyTo dup arg _ cont)       = ((ptext (sLit "ApplyTo") <+> ppr dup <+> pprParendExpr arg)
 147                                           {-  $$ nest 2 (pprSimplEnv se) -}) $$ ppr cont
 148   ppr (StrictBind b _ _ _ cont)      = (ptext (sLit "StrictBind") <+> ppr b) $$ ppr cont
 149   ppr (StrictArg ai _ cont)          = (ptext (sLit "StrictArg") <+> ppr (ai_fun ai)) $$ ppr cont
 150   ppr (Select dup bndr alts se cont) = (ptext (sLit "Select") <+> ppr dup <+> ppr bndr) $$
 151                                        (nest 2 $ vcat [ppr (seTvSubst se), ppr alts]) $$ ppr cont
 152   ppr (CoerceIt co cont)             = (ptext (sLit "CoerceIt") <+> ppr co) $$ ppr cont
 153
 154 data DupFlag = OkToDup | NoDup
 155
 156 instance Outputable DupFlag where
 157   ppr OkToDup = ptext (sLit "ok")
 158   ppr NoDup   = ptext (sLit "nodup")
 159
 160
 161
 162 -------------------
 163 mkBoringStop :: SimplCont
 164 mkBoringStop = Stop BoringCtxt
 165
 166 mkRhsStop :: SimplCont  -- See Note [RHS of lets] in CoreUnfold
 167 mkRhsStop = Stop (ArgCtxt False)
 168
 169 mkLazyArgStop :: CallCtxt -> SimplCont
 170 mkLazyArgStop cci = Stop cci
 171
 172 -------------------
 173 contIsRhsOrArg :: SimplCont -> Bool
 174 contIsRhsOrArg (Stop {})       = True
 175 contIsRhsOrArg (StrictBind {}) = True
 176 contIsRhsOrArg (StrictArg {})  = True
 177 contIsRhsOrArg _               = False
 178
 179 -------------------
 180 contIsDupable :: SimplCont -> Bool
 181 contIsDupable (Stop {})                  = True
 182 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 183 contIsDupable (Select   OkToDup _ _ _ _) = True
 184 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 185 contIsDupable _                          = False
 186
 187 -------------------
 188 contIsTrivial :: SimplCont -> Bool
 189 contIsTrivial (Stop {})                   = True
 190 contIsTrivial (ApplyTo _ (Type _) _ cont) = contIsTrivial cont
 191 contIsTrivial (CoerceIt _ cont)           = contIsTrivial cont
 192 contIsTrivial _                           = False
 193
 194 -------------------
 195 contResultType :: SimplEnv -> OutType -> SimplCont -> OutType
 196 contResultType env ty cont
 197   = go cont ty
 198   where
 199     subst_ty se ty = substTy (se `setInScope` env) ty
 200
 201     go (Stop {})                      ty = ty
 202     go (CoerceIt co cont)             _  = go cont (snd (coercionKind co))
 203     go (StrictBind _ bs body se cont) _  = go cont (subst_ty se (exprType (mkLams bs body)))
 204     go (StrictArg ai _ cont)          _  = go cont (funResultTy (argInfoResultTy ai))
 205     go (Select _ _ alts se cont)      _  = go cont (subst_ty se (coreAltsType alts))
 206     go (ApplyTo _ arg se cont)        ty = go cont (apply_to_arg ty arg se)
 207
 208     apply_to_arg ty (Type ty_arg) se = applyTy ty (subst_ty se ty_arg)
 209     apply_to_arg ty _             _  = funResultTy ty
 210
 211 argInfoResultTy :: ArgInfo -> OutType
 212 argInfoResultTy (ArgInfo { ai_fun = fun, ai_args = args })
 213   = foldr (\arg fn_ty -> applyTypeToArg fn_ty arg) (idType fun) args
 214
 215 -------------------
 216 countValArgs :: SimplCont -> Int
 217 countValArgs (ApplyTo _ (Type _) _ cont) = countValArgs cont
 218 countValArgs (ApplyTo _ _        _ cont) = 1 + countValArgs cont
 219 countValArgs _                           = 0
 220
 221 countArgs :: SimplCont -> Int
 222 countArgs (ApplyTo _ _ _ cont) = 1 + countArgs cont
 223 countArgs _                    = 0
 224
 225 contArgs :: SimplCont -> (Bool, [ArgSummary], SimplCont)
 226 -- Uses substitution to turn each arg into an OutExpr
 227 contArgs cont@(ApplyTo {})
 228   = case go [] cont of { (args, cont') -> (False, args, cont') }
 229   where
 230     go args (ApplyTo _ arg se cont)
 231       | isTypeArg arg = go args                           cont
 232       | otherwise     = go (is_interesting arg se : args) cont
 233     go args cont      = (reverse args, cont)
 234
 235     is_interesting arg se = interestingArg (substExpr (text "contArgs") se arg)
 236                    -- Do *not* use short-cutting substitution here
 237                    -- because we want to get as much IdInfo as possible
 238
 239 contArgs cont = (True, [], cont)
 240
 241 pushArgs :: SimplEnv -> [CoreExpr] -> SimplCont -> SimplCont
 242 pushArgs _env []         cont = cont
 243 pushArgs env  (arg:args) cont = ApplyTo NoDup arg env (pushArgs env args cont)
 244
 245 dropArgs :: Int -> SimplCont -> SimplCont
 246 dropArgs 0 cont = cont
 247 dropArgs n (ApplyTo _ _ _ cont) = dropArgs (n-1) cont
 248 dropArgs n other                = pprPanic "dropArgs" (ppr n <+> ppr other)
 249 \end{code}
 250
 251
 252 Note [Interesting call context]
 253 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 254 We want to avoid inlining an expression where there can't possibly be
 255 any gain, such as in an argument position.  Hence, if the continuation
 256 is interesting (eg. a case scrutinee, application etc.) then we
 257 inline, otherwise we don't.
 258
 259 Previously some_benefit used to return True only if the variable was
 260 applied to some value arguments.  This didn't work:
 261
 262         let x = _coerce_ (T Int) Int (I# 3) in
 263         case _coerce_ Int (T Int) x of
 264                 I# y -> ....
 265
 266 we want to inline x, but can't see that it's a constructor in a case
 267 scrutinee position, and some_benefit is False.
 268
 269 Another example:
 270
 271 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 272
 273 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 274
 275 we'd really like to inline dMonadST here, but we *don't* want to
 276 inline if the case expression is just
 277
 278         case x of y { DEFAULT -> ... }
 279
 280 since we can just eliminate this case instead (x is in WHNF).  Similar
 281 applies when x is bound to a lambda expression.  Hence
 282 contIsInteresting looks for case expressions with just a single
 283 default case.
 284
 285
 286 \begin{code}
 287 interestingCallContext :: SimplCont -> CallCtxt
 288 -- See Note [Interesting call context]
 289 interestingCallContext cont
 290   = interesting cont
 291   where
 292     interesting (Select _ bndr _ _ _)
 293         | isDeadBinder bndr = CaseCtxt
 294         | otherwise         = ArgCtxt False     -- If the binder is used, this
 295                                                 -- is like a strict let
 296                                                 -- See Note [RHS of lets] in CoreUnfold
 297
 298     interesting (ApplyTo _ arg _ cont)
 299         | isTypeArg arg = interesting cont
 300         | otherwise     = ValAppCtxt    -- Can happen if we have (f Int |> co) y
 301                                         -- If f has an INLINE prag we need to give it some
 302                                         -- motivation to inline. See Note [Cast then apply]
 303                                         -- in CoreUnfold
 304
 305     interesting (StrictArg _ cci _) = cci
 306     interesting (StrictBind {})     = BoringCtxt
 307     interesting (Stop cci)          = cci
 308     interesting (CoerceIt _ cont)   = interesting cont
 309         -- If this call is the arg of a strict function, the context
 310         -- is a bit interesting.  If we inline here, we may get useful
 311         -- evaluation information to avoid repeated evals: e.g.
 312         --      x + (y * z)
 313         -- Here the contIsInteresting makes the '*' keener to inline,
 314         -- which in turn exposes a constructor which makes the '+' inline.
 315         -- Assuming that +,* aren't small enough to inline regardless.
 316         --
 317         -- It's also very important to inline in a strict context for things
 318         -- like
 319         --              foldr k z (f x)
 320         -- Here, the context of (f x) is strict, and if f's unfolding is
 321         -- a build it's *great* to inline it here.  So we must ensure that
 322         -- the context for (f x) is not totally uninteresting.
 323
 324
 325 -------------------
 326 mkArgInfo :: Id
 327           -> [CoreRule] -- Rules for function
 328           -> Int        -- Number of value args
 329           -> SimplCont  -- Context of the call
 330           -> ArgInfo
 331
 332 mkArgInfo fun rules n_val_args call_cont
 333   | n_val_args < idArity fun            -- Note [Unsaturated functions]
 334   = ArgInfo { ai_fun = fun, ai_args = [], ai_rules = rules
 335             , ai_encl = False
 336             , ai_strs = vanilla_stricts
 337             , ai_discs = vanilla_discounts }
 338   | otherwise
 339   = ArgInfo { ai_fun = fun, ai_args = [], ai_rules = rules
 340             , ai_encl = interestingArgContext rules call_cont
 341             , ai_strs  = add_type_str (idType fun) arg_stricts
 342             , ai_discs = arg_discounts }
 343   where
 344     vanilla_discounts, arg_discounts :: [Int]
 345     vanilla_discounts = repeat 0
 346     arg_discounts = case idUnfolding fun of
 347                         CoreUnfolding {uf_guidance = UnfIfGoodArgs {ug_args = discounts}}
 348                               -> discounts ++ vanilla_discounts
 349                         _     -> vanilla_discounts
 350
 351     vanilla_stricts, arg_stricts :: [Bool]
 352     vanilla_stricts  = repeat False
 353
 354     arg_stricts
 355       = case splitStrictSig (idStrictness fun) of
 356           (demands, result_info)
 357                 | not (demands `lengthExceeds` n_val_args)
 358                 ->      -- Enough args, use the strictness given.
 359                         -- For bottoming functions we used to pretend that the arg
 360                         -- is lazy, so that we don't treat the arg as an
 361                         -- interesting context.  This avoids substituting
 362                         -- top-level bindings for (say) strings into
 363                         -- calls to error.  But now we are more careful about
 364                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 365                    if isBotRes result_info then
 366                         map isStrictDmd demands         -- Finite => result is bottom
 367                    else
 368                         map isStrictDmd demands ++ vanilla_stricts
 369                | otherwise
 370                -> WARN( True, text "More demands than arity" <+> ppr fun <+> ppr (idArity fun)
 371                                 <+> ppr n_val_args <+> ppr demands )
 372                    vanilla_stricts      -- Not enough args, or no strictness
 373
 374     add_type_str :: Type -> [Bool] -> [Bool]
 375     -- If the function arg types are strict, record that in the 'strictness bits'
 376     -- No need to instantiate because unboxed types (which dominate the strict
 377     -- types) can't instantiate type variables.
 378     -- add_type_str is done repeatedly (for each call); might be better
 379     -- once-for-all in the function
 380     -- But beware primops/datacons with no strictness
 381     add_type_str _ [] = []
 382     add_type_str fun_ty strs            -- Look through foralls
 383         | Just (_, fun_ty') <- splitForAllTy_maybe fun_ty       -- Includes coercions
 384         = add_type_str fun_ty' strs
 385     add_type_str fun_ty (str:strs)      -- Add strict-type info
 386         | Just (arg_ty, fun_ty') <- splitFunTy_maybe fun_ty
 387         = (str || isStrictType arg_ty) : add_type_str fun_ty' strs
 388     add_type_str _ strs
 389         = strs
 390
 391 {- Note [Unsaturated functions]
 392   ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 393 Consider (test eyeball/inline4)
 394         x = a:as
 395         y = f x
 396 where f has arity 2.  Then we do not want to inline 'x', because
 397 it'll just be floated out again.  Even if f has lots of discounts
 398 on its first argument -- it must be saturated for these to kick in
 399 -}
 400
 401 interestingArgContext :: [CoreRule] -> SimplCont -> Bool
 402 -- If the argument has form (f x y), where x,y are boring,
 403 -- and f is marked INLINE, then we don't want to inline f.
 404 -- But if the context of the argument is
 405 --      g (f x y)
 406 -- where g has rules, then we *do* want to inline f, in case it
 407 -- exposes a rule that might fire.  Similarly, if the context is
 408 --      h (g (f x x))
 409 -- where h has rules, then we do want to inline f; hence the
 410 -- call_cont argument to interestingArgContext
 411 --
 412 -- The ai-rules flag makes this happen; if it's
 413 -- set, the inliner gets just enough keener to inline f
 414 -- regardless of how boring f's arguments are, if it's marked INLINE
 415 --
 416 -- The alternative would be to *always* inline an INLINE function,
 417 -- regardless of how boring its context is; but that seems overkill
 418 -- For example, it'd mean that wrapper functions were always inlined
 419 interestingArgContext rules call_cont
 420   = notNull rules || enclosing_fn_has_rules
 421   where
 422     enclosing_fn_has_rules = go call_cont
 423
 424     go (Select {})         = False
 425     go (ApplyTo {})        = False
 426     go (StrictArg _ cci _) = interesting cci
 427     go (StrictBind {})     = False      -- ??
 428     go (CoerceIt _ c)      = go c
 429     go (Stop cci)          = interesting cci
 430
 431     interesting (ArgCtxt rules) = rules
 432     interesting _               = False
 433 \end{code}
 434
 435
 436
 437 %************************************************************************
 438 %*                                                                      *
 439 \subsection{Decisions about inlining}
 440 %*                                                                      *
 441 %************************************************************************
 442
 443 Inlining is controlled partly by the SimplifierMode switch.  This has two
 444 settings
 445
 446         SimplGently     (a) Simplifying before specialiser/full laziness
 447                         (b) Simplifiying inside InlineRules
 448                         (c) Simplifying the LHS of a rule
 449                         (d) Simplifying a GHCi expression or Template
 450                                 Haskell splice
 451
 452         SimplPhase n _   Used at all other times
 453
 454 Note [Gentle mode]
 455 ~~~~~~~~~~~~~~~~~~
 456 Gentle mode has a separate boolean flag to control
 457         a) inlining (sm_inline flag)
 458         b) rules    (sm_rules  flag)
 459 A key invariant about Gentle mode is that it is treated as the EARLIEST
 460 phase.  Something is inlined if the sm_inline flag is on AND the thing
 461 is inlinable in the earliest phase.  This is important. Example
 462
 463   {-# INLINE [~1] g #-}
 464   g = ...
 465
 466   {-# INLINE f #-}
 467   f x = g (g x)
 468
 469 If we were to inline g into f's inlining, then an importing module would
 470 never be able to do
 471         f e --> g (g e) ---> RULE fires
 472 because the InlineRule for f has had g inlined into it.
 473
 474 On the other hand, it is bad not to do ANY inlining into an
 475 InlineRule, because then recursive knots in instance declarations
 476 don't get unravelled.
 477
 478 However, *sometimes* SimplGently must do no call-site inlining at all.
 479 Before full laziness we must be careful not to inline wrappers,
 480 because doing so inhibits floating
 481     e.g. ...(case f x of ...)...
 482     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 483     ==> ...(case x of I# x# -> case fw x# of ...)...
 484 and now the redex (f x) isn't floatable any more.
 485
 486 The no-inlining thing is also important for Template Haskell.  You might be
 487 compiling in one-shot mode with -O2; but when TH compiles a splice before
 488 running it, we don't want to use -O2.  Indeed, we don't want to inline
 489 anything, because the byte-code interpreter might get confused about
 490 unboxed tuples and suchlike.
 491
 492 Note [RULEs enabled in SimplGently]
 493 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 494 RULES are enabled when doing "gentle" simplification.  Two reasons:
 495
 496   * We really want the class-op cancellation to happen:
 497         op (df d1 d2) --> $cop3 d1 d2
 498     because this breaks the mutual recursion between 'op' and 'df'
 499
 500   * I wanted the RULE
 501         lift String ===> ...
 502     to work in Template Haskell when simplifying
 503     splices, so we get simpler code for literal strings
 504
 505 Note [Simplifying inside InlineRules]
 506 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 507 We must take care with simplification inside InlineRules (which come from
 508 INLINE pragmas).
 509
 510 First, consider the following example
 511         let f = \pq -> BIG
 512         in
 513         let g = \y -> f y y
 514             {-# INLINE g #-}
 515         in ...g...g...g...g...g...
 516 Now, if that's the ONLY occurrence of f, it might be inlined inside g,
 517 and thence copied multiple times when g is inlined. HENCE we treat
 518 any occurrence in an InlineRule as a multiple occurrence, not a single
 519 one; see OccurAnal.addRuleUsage.
 520
 521 Second, we do want *do* to some modest rules/inlining stuff in InlineRules,
 522 partly to eliminate senseless crap, and partly to break the recursive knots
 523 generated by instance declarations.  To keep things simple, we always set
 524 the phase to 'gentle' when processing InlineRules.  OK, so suppose we have
 525         {-# INLINE <act> f #-}
 526         f = <rhs>
 527 meaning "inline f in phases p where activation <act>(p) holds".
 528 Then what inlinings/rules can we apply to the copy of <rhs> captured in
 529 f's InlineRule?  Our model is that literally <rhs> is substituted for
 530 f when it is inlined.  So our conservative plan (implemented by
 531 updModeForInlineRules) is this:
 532
 533   -------------------------------------------------------------
 534   When simplifying the RHS of an InlineRule,
 535   If the InlineRule becomes active in phase p, then
 536     if the current phase is *earlier than* p,
 537        make no inlinings or rules active when simplifying the RHS
 538     otherwise
 539        set the phase to p when simplifying the RHS
 540   -------------------------------------------------------------
 541
 542 That ensures that
 543
 544   a) Rules/inlinings that *cease* being active before p will
 545      not apply to the InlineRule rhs, consistent with it being
 546      inlined in its *original* form in phase p.
 547
 548   b) Rules/inlinings that only become active *after* p will
 549      not apply to the InlineRule rhs, again to be consistent with
 550      inlining the *original* rhs in phase p.
 551
 552 For example,
 553         {-# INLINE f #-}
 554         f x = ...g...
 555
 556         {-# NOINLINE [1] g #-}
 557         g y = ...
 558
 559         {-# RULE h g = ... #-}
 560 Here we must not inline g into f's RHS, even when we get to phase 0,
 561 because when f is later inlined into some other module we want the
 562 rule for h to fire.
 563
 564 Similarly, consider
 565         {-# INLINE f #-}
 566         f x = ...g...
 567
 568         g y = ...
 569 and suppose that there are auto-generated specialisations and a strictness
 570 wrapper for g.  The specialisations get activation AlwaysActive, and the
 571 strictness wrapper get activation (ActiveAfter 0).  So the strictness
 572 wrepper fails the test and won't be inlined into f's InlineRule. That
 573 means f can inline, expose the specialised call to g, so the specialisation
 574 rules can fire.
 575
 576 A note about wrappers
 577 ~~~~~~~~~~~~~~~~~~~~~
 578 It's also important not to inline a worker back into a wrapper.
 579 A wrapper looks like
 580         wraper = inline_me (\x -> ...worker... )
 581 Normally, the inline_me prevents the worker getting inlined into
 582 the wrapper (initially, the worker's only call site!).  But,
 583 if the wrapper is sure to be called, the strictness analyser will
 584 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 585 continuation.
 586
 587 \begin{code}
 588 simplEnvForGHCi :: SimplEnv
 589 simplEnvForGHCi = mkSimplEnv allOffSwitchChecker $
 590                   SimplGently { sm_rules = False, sm_inline = False }
 591    -- Do not do any inlining, in case we expose some unboxed
 592    -- tuple stuff that confuses the bytecode interpreter
 593
 594 simplEnvForRules :: SimplEnv
 595 simplEnvForRules = mkSimplEnv allOffSwitchChecker $
 596                    SimplGently { sm_rules = True, sm_inline = False }
 597
 598 updModeForInlineRules :: Activation -> SimplifierMode -> SimplifierMode
 599 -- See Note [Simplifying inside InlineRules]
 600 --    Treat Gentle as phase "infinity"
 601 --    If current_phase `earlier than` inline_rule_start_phase
 602 --      then no_op
 603 --    else
 604 --    if current_phase `same phase` inline_rule_start_phase
 605 --      then current_phase   (keep gentle flags)
 606 --      else inline_rule_start_phase
 607 updModeForInlineRules inline_rule_act current_mode
 608   = case inline_rule_act of
 609       NeverActive     -> no_op
 610       AlwaysActive    -> mk_gentle current_mode
 611       ActiveBefore {} -> mk_gentle current_mode
 612       ActiveAfter n   -> mk_phase n current_mode
 613   where
 614     no_op = SimplGently { sm_rules = False, sm_inline = False }
 615
 616     mk_gentle (SimplGently {}) = current_mode
 617     mk_gentle _                = SimplGently { sm_rules = True, sm_inline = True }
 618
 619     mk_phase n (SimplPhase _ ss) = SimplPhase n ss
 620     mk_phase n (SimplGently {})  = SimplPhase n ["gentle-rules"]
 621 \end{code}
 622
 623
 624 preInlineUnconditionally
 625 ~~~~~~~~~~~~~~~~~~~~~~~~
 626 @preInlineUnconditionally@ examines a bndr to see if it is used just
 627 once in a completely safe way, so that it is safe to discard the
 628 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 629 big the RHS might be.  If this is the case we don't simplify the RHS
 630 first, but just inline it un-simplified.
 631
 632 This is much better than first simplifying a perhaps-huge RHS and then
 633 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 634 better.  Consider
 635
 636         x1 = e1
 637         x2 = e2[x1]
 638         x3 = e3[x2]
 639         ...etc...
 640         xN = eN[xN-1]
 641
 642 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 643 This can happen with cascades of functions too:
 644
 645         f1 = \x1.e1
 646         f2 = \xs.e2[f1]
 647         f3 = \xs.e3[f3]
 648         ...etc...
 649
 650 THE MAIN INVARIANT is this:
 651
 652         ----  preInlineUnconditionally invariant -----
 653    IF preInlineUnconditionally chooses to inline x = <rhs>
 654    THEN doing the inlining should not change the occurrence
 655         info for the free vars of <rhs>
 656         ----------------------------------------------
 657
 658 For example, it's tempting to look at trivial binding like
 659         x = y
 660 and inline it unconditionally.  But suppose x is used many times,
 661 but this is the unique occurrence of y.  Then inlining x would change
 662 y's occurrence info, which breaks the invariant.  It matters: y
 663 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
 664
 665
 666 Even RHSs labelled InlineMe aren't caught here, because there might be
 667 no benefit from inlining at the call site.
 668
 669 [Sept 01] Don't unconditionally inline a top-level thing, because that
 670 can simply make a static thing into something built dynamically.  E.g.
 671         x = (a,b)
 672         main = \s -> h x
 673
 674 [Remember that we treat \s as a one-shot lambda.]  No point in
 675 inlining x unless there is something interesting about the call site.
 676
 677 But watch out: if you aren't careful, some useful foldr/build fusion
 678 can be lost (most notably in spectral/hartel/parstof) because the
 679 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 680 deal, in fact, but losing the fusion can be.  But the right thing here
 681 seems to be to do a callSiteInline based on the fact that there is
 682 something interesting about the call site (it's strict).  Hmm.  That
 683 seems a bit fragile.
 684
 685 Conclusion: inline top level things gaily until Phase 0 (the last
 686 phase), at which point don't.
 687
 688 Note [pre/postInlineUnconditionally in gentle mode]
 689 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 690 Even in gentle mode we want to do preInlineUnconditionally.  The
 691 reason is that too little clean-up happens if you don't inline
 692 use-once things.  Also a bit of inlining is *good* for full laziness;
 693 it can expose constant sub-expressions.  Example in
 694 spectral/mandel/Mandel.hs, where the mandelset function gets a useful
 695 let-float if you inline windowToViewport
 696
 697 However, as usual for Gentle mode, do not inline things that are
 698 inactive in the intial stages.  See Note [Gentle mode].
 699
 700 Note [InlineRule and preInlineUnconditionally]
 701 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 702 Surprisingly, do not pre-inline-unconditionally Ids with INLINE pragmas!
 703 Example
 704
 705    {-# INLINE f #-}
 706    f :: Eq a => a -> a
 707    f x = ...
 708
 709    fInt :: Int -> Int
 710    fInt = f Int dEqInt
 711
 712    ...fInt...fInt...fInt...
 713
 714 Here f occurs just once, in the RHS of f1. But if we inline it there
 715 we'll lose the opportunity to inline at each of fInt's call sites.
 716 The INLINE pragma will only inline when the application is saturated
 717 for exactly this reason; and we don't want PreInlineUnconditionally
 718 to second-guess it.  A live example is Trac #3736.
 719     c.f. Note [InlineRule and postInlineUnconditionally]
 720
 721 Note [Top-level botomming Ids]
 722 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 723 Don't inline top-level Ids that are bottoming, even if they are used just
 724 once, because FloatOut has gone to some trouble to extract them out.
 725 Inlining them won't make the program run faster!
 726
 727 \begin{code}
 728 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
 729 preInlineUnconditionally env top_lvl bndr rhs
 730   | not active                               = False
 731   | isStableUnfolding (idUnfolding bndr)     = False    -- Note [InlineRule and preInlineUnconditionally]
 732   | isTopLevel top_lvl && isBottomingId bndr = False    -- Note [Top-level bottoming Ids]
 733   | opt_SimplNoPreInlining                   = False
 734   | otherwise = case idOccInfo bndr of
 735                   IAmDead                    -> True    -- Happens in ((\x.1) v)
 736                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
 737                   _                          -> False
 738   where
 739     phase = getMode env
 740     active = case phase of
 741                    SimplGently {} -> isEarlyActive act
 742                         -- See Note [pre/postInlineUnconditionally in gentle mode]
 743                    SimplPhase n _ -> isActive n act
 744     act = idInlineActivation bndr
 745     try_once in_lam int_cxt     -- There's one textual occurrence
 746         | not in_lam = isNotTopLevel top_lvl || early_phase
 747         | otherwise  = int_cxt && canInlineInLam rhs
 748
 749 -- Be very careful before inlining inside a lambda, because (a) we must not
 750 -- invalidate occurrence information, and (b) we want to avoid pushing a
 751 -- single allocation (here) into multiple allocations (inside lambda).
 752 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
 753 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
 754 --      where
 755 --              is_cheap = exprIsCheap rhs
 756 --              ok = is_cheap && int_cxt
 757
 758         --      int_cxt         The context isn't totally boring
 759         -- E.g. let f = \ab.BIG in \y. map f xs
 760         --      Don't want to substitute for f, because then we allocate
 761         --      its closure every time the \y is called
 762         -- But: let f = \ab.BIG in \y. map (f y) xs
 763         --      Now we do want to substitute for f, even though it's not
 764         --      saturated, because we're going to allocate a closure for
 765         --      (f y) every time round the loop anyhow.
 766
 767         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
 768         -- so substituting rhs inside a lambda doesn't change the occ info.
 769         -- Sadly, not quite the same as exprIsHNF.
 770     canInlineInLam (Lit _)              = True
 771     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
 772     canInlineInLam (Note _ e)           = canInlineInLam e
 773     canInlineInLam _                    = False
 774
 775     early_phase = case phase of
 776                         SimplPhase 0 _ -> False
 777                         _              -> True
 778 -- If we don't have this early_phase test, consider
 779 --      x = length [1,2,3]
 780 -- The full laziness pass carefully floats all the cons cells to
 781 -- top level, and preInlineUnconditionally floats them all back in.
 782 -- Result is (a) static allocation replaced by dynamic allocation
 783 --           (b) many simplifier iterations because this tickles
 784 --               a related problem; only one inlining per pass
 785 --
 786 -- On the other hand, I have seen cases where top-level fusion is
 787 -- lost if we don't inline top level thing (e.g. string constants)
 788 -- Hence the test for phase zero (which is the phase for all the final
 789 -- simplifications).  Until phase zero we take no special notice of
 790 -- top level things, but then we become more leery about inlining
 791 -- them.
 792
 793 \end{code}
 794
 795 postInlineUnconditionally
 796 ~~~~~~~~~~~~~~~~~~~~~~~~~
 797 @postInlineUnconditionally@ decides whether to unconditionally inline
 798 a thing based on the form of its RHS; in particular if it has a
 799 trivial RHS.  If so, we can inline and discard the binding altogether.
 800
 801 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 802 only have *forward* references Hence, it's safe to discard the binding
 803
 804 NOTE: This isn't our last opportunity to inline.  We're at the binding
 805 site right now, and we'll get another opportunity when we get to the
 806 ocurrence(s)
 807
 808 Note that we do this unconditional inlining only for trival RHSs.
 809 Don't inline even WHNFs inside lambdas; doing so may simply increase
 810 allocation when the function is called. This isn't the last chance; see
 811 NOTE above.
 812
 813 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 814 Because we don't even want to inline them into the RHS of constructor
 815 arguments. See NOTE above
 816
 817 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 818 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 819 with both a and b marked NOINLINE.  But that seems incompatible with
 820 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 821 story for now.
 822
 823 \begin{code}
 824 postInlineUnconditionally
 825     :: SimplEnv -> TopLevelFlag
 826     -> OutId            -- The binder (an InId would be fine too)
 827     -> OccInfo          -- From the InId
 828     -> OutExpr
 829     -> Unfolding
 830     -> Bool
 831 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
 832   | not active                  = False
 833   | isLoopBreaker occ_info      = False -- If it's a loop-breaker of any kind, don't inline
 834                                         -- because it might be referred to "earlier"
 835   | isExportedId bndr           = False
 836   | isStableUnfolding unfolding = False -- Note [InlineRule and postInlineUnconditionally]
 837   | exprIsTrivial rhs           = True
 838   | isTopLevel top_lvl          = False -- Note [Top level and postInlineUnconditionally]
 839   | otherwise
 840   = case occ_info of
 841         -- The point of examining occ_info here is that for *non-values*
 842         -- that occur outside a lambda, the call-site inliner won't have
 843         -- a chance (becuase it doesn't know that the thing
 844         -- only occurs once).   The pre-inliner won't have gotten
 845         -- it either, if the thing occurs in more than one branch
 846         -- So the main target is things like
 847         --      let x = f y in
 848         --      case v of
 849         --         True  -> case x of ...
 850         --         False -> case x of ...
 851         -- This is very important in practice; e.g. wheel-seive1 doubles
 852         -- in allocation if you miss this out
 853       OneOcc in_lam _one_br int_cxt     -- OneOcc => no code-duplication issue
 854         ->     smallEnoughToInline unfolding    -- Small enough to dup
 855                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
 856                         --
 857                         -- NB: Do NOT inline arbitrarily big things, even if one_br is True
 858                         -- Reason: doing so risks exponential behaviour.  We simplify a big
 859                         --         expression, inline it, and simplify it again.  But if the
 860                         --         very same thing happens in the big expression, we get
 861                         --         exponential cost!
 862                         -- PRINCIPLE: when we've already simplified an expression once,
 863                         -- make sure that we only inline it if it's reasonably small.
 864
 865            && (not in_lam ||
 866                         -- Outside a lambda, we want to be reasonably aggressive
 867                         -- about inlining into multiple branches of case
 868                         -- e.g. let x = <non-value>
 869                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... }
 870                         -- Inlining can be a big win if C3 is the hot-spot, even if
 871                         -- the uses in C1, C2 are not 'interesting'
 872                         -- An example that gets worse if you add int_cxt here is 'clausify'
 873
 874                 (isCheapUnfolding unfolding && int_cxt))
 875                         -- isCheap => acceptable work duplication; in_lam may be true
 876                         -- int_cxt to prevent us inlining inside a lambda without some
 877                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
 878
 879       IAmDead -> True   -- This happens; for example, the case_bndr during case of
 880                         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 881                         -- Here x isn't mentioned in the RHS, so we don't want to
 882                         -- create the (dead) let-binding  let x = (a,b) in ...
 883
 884       _ -> False
 885
 886 -- Here's an example that we don't handle well:
 887 --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
 888 --      in \y. ....case f of {...} ....
 889 -- Here f is used just once, and duplicating the case work is fine (exprIsCheap).
 890 -- But
 891 --  - We can't preInlineUnconditionally because that woud invalidate
 892 --    the occ info for b.
 893 --  - We can't postInlineUnconditionally because the RHS is big, and
 894 --    that risks exponential behaviour
 895 --  - We can't call-site inline, because the rhs is big
 896 -- Alas!
 897
 898   where
 899     active = case getMode env of
 900                    SimplGently {} -> isEarlyActive act
 901                         -- See Note [pre/postInlineUnconditionally in gentle mode]
 902                    SimplPhase n _ -> isActive n act
 903     act = idInlineActivation bndr
 904
 905 activeUnfolding :: SimplEnv -> IdUnfoldingFun
 906 activeUnfolding env
 907   = case getMode env of
 908       SimplGently { sm_inline = False } -> active_unfolding_minimal
 909       SimplGently { sm_inline = True  } -> active_unfolding_gentle
 910       SimplPhase n _                    -> active_unfolding n
 911
 912 activeUnfInRule :: SimplEnv -> IdUnfoldingFun
 913 -- When matching in RULE, we want to "look through" an unfolding
 914 -- if *rules* are on, even if *inlinings* are not.  A notable example
 915 -- is DFuns, which really we want to match in rules like (op dfun)
 916 -- in gentle mode.
 917 activeUnfInRule env
 918   = case getMode env of
 919       SimplGently { sm_rules = False } -> active_unfolding_minimal
 920       SimplGently { sm_rules = True  } -> active_unfolding_gentle
 921       SimplPhase n _                   -> active_unfolding n
 922
 923 active_unfolding_minimal :: IdUnfoldingFun
 924 -- Compuslory unfoldings only
 925 -- Ignore SimplGently, because we want to inline regardless;
 926 -- the Id has no top-level binding at all
 927 --
 928 -- NB: we used to have a second exception, for data con wrappers.
 929 -- On the grounds that we use gentle mode for rule LHSs, and
 930 -- they match better when data con wrappers are inlined.
 931 -- But that only really applies to the trivial wrappers (like (:)),
 932 -- and they are now constructed as Compulsory unfoldings (in MkId)
 933 -- so they'll happen anyway.
 934 active_unfolding_minimal id
 935   | isCompulsoryUnfolding unf = unf
 936   | otherwise                 = NoUnfolding
 937   where
 938     unf = realIdUnfolding id    -- Never a loop breaker
 939
 940 active_unfolding_gentle :: IdUnfoldingFun
 941 -- Anything that is early-active
 942 -- See Note [Gentle mode]
 943 active_unfolding_gentle id
 944   | isEarlyActive (idInlineActivation id) = idUnfolding id
 945   | otherwise                             = NoUnfolding
 946       -- idUnfolding checks for loop-breakers
 947       -- Things with an INLINE pragma may have
 948       -- an unfolding *and* be a loop breaker
 949       -- (maybe the knot is not yet untied)
 950
 951 active_unfolding :: CompilerPhase -> IdUnfoldingFun
 952 active_unfolding n id
 953   | isActive n (idInlineActivation id) = idUnfolding id
 954   | otherwise                          = NoUnfolding
 955
 956 activeRule :: DynFlags -> SimplEnv -> Maybe (Activation -> Bool)
 957 -- Nothing => No rules at all
 958 activeRule dflags env
 959   | not (dopt Opt_EnableRewriteRules dflags)
 960   = Nothing     -- Rewriting is off
 961   | otherwise
 962   = case getMode env of
 963       SimplGently { sm_rules = rules_on }
 964         | rules_on  -> Just isEarlyActive       -- Note [RULEs enabled in SimplGently]
 965         | otherwise -> Nothing
 966       SimplPhase n _ -> Just (isActive n)
 967 \end{code}
 968
 969 Note [Top level and postInlineUnconditionally]
 970 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 971 We don't do postInlineUnconditionally for top-level things (exept ones that
 972 are trivial):
 973   * There is no point, because the main goal is to get rid of local
 974     bindings used in multiple case branches.
 975   * Doing so will inline top-level error expressions that have been
 976     carefully floated out by FloatOut.  More generally, it might
 977     replace static allocation with dynamic.
 978
 979 Note [InlineRule and postInlineUnconditionally]
 980 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 981 Do not do postInlineUnconditionally if the Id has an InlineRule, otherwise
 982 we lose the unfolding.  Example
 983
 984      -- f has InlineRule with rhs (e |> co)
 985      --   where 'e' is big
 986      f = e |> co
 987
 988 Then there's a danger we'll optimise to
 989
 990      f' = e
 991      f = f' |> co
 992
 993 and now postInlineUnconditionally, losing the InlineRule on f.  Now f'
 994 won't inline because 'e' is too big.
 995
 996     c.f. Note [InlineRule and preInlineUnconditionally]
 997
 998
 999 %************************************************************************
1000 %*                                                                      *
1001         Rebuilding a lambda
1002 %*                                                                      *
1003 %************************************************************************
1004
1005 \begin{code}
1006 mkLam :: SimplEnv -> [OutBndr] -> OutExpr -> SimplM OutExpr
1007 -- mkLam tries three things
1008 --      a) eta reduction, if that gives a trivial expression
1009 --      b) eta expansion [only if there are some value lambdas]
1010
1011 mkLam _b [] body
1012   = return body
1013 mkLam _env bndrs body
1014   = do  { dflags <- getDOptsSmpl
1015         ; mkLam' dflags bndrs body }
1016   where
1017     mkLam' :: DynFlags -> [OutBndr] -> OutExpr -> SimplM OutExpr
1018     mkLam' dflags bndrs (Cast body co)
1019       | not (any bad bndrs)
1020         -- Note [Casts and lambdas]
1021       = do { lam <- mkLam' dflags bndrs body
1022            ; return (mkCoerce (mkPiTypes bndrs co) lam) }
1023       where
1024         co_vars  = tyVarsOfType co
1025         bad bndr = isCoVar bndr && bndr `elemVarSet` co_vars
1026
1027     mkLam' dflags bndrs body
1028       | dopt Opt_DoEtaReduction dflags,
1029         Just etad_lam <- tryEtaReduce bndrs body
1030       = do { tick (EtaReduction (head bndrs))
1031            ; return etad_lam }
1032
1033       | dopt Opt_DoLambdaEtaExpansion dflags,
1034         not (all isTyVar bndrs) -- Don't eta expand type abstractions
1035       = do { let body' = tryEtaExpansion dflags body
1036            ; return (mkLams bndrs body') }
1037
1038       | otherwise
1039       = return (mkLams bndrs body)
1040 \end{code}
1041
1042 Note [Casts and lambdas]
1043 ~~~~~~~~~~~~~~~~~~~~~~~~
1044 Consider
1045         (\x. (\y. e) `cast` g1) `cast` g2
1046 There is a danger here that the two lambdas look separated, and the
1047 full laziness pass might float an expression to between the two.
1048
1049 So this equation in mkLam' floats the g1 out, thus:
1050         (\x. e `cast` g1)  -->  (\x.e) `cast` (tx -> g1)
1051 where x:tx.
1052
1053 In general, this floats casts outside lambdas, where (I hope) they
1054 might meet and cancel with some other cast:
1055         \x. e `cast` co   ===>   (\x. e) `cast` (tx -> co)
1056         /\a. e `cast` co  ===>   (/\a. e) `cast` (/\a. co)
1057         /\g. e `cast` co  ===>   (/\g. e) `cast` (/\g. co)
1058                           (if not (g `in` co))
1059
1060 Notice that it works regardless of 'e'.  Originally it worked only
1061 if 'e' was itself a lambda, but in some cases that resulted in
1062 fruitless iteration in the simplifier.  A good example was when
1063 compiling Text.ParserCombinators.ReadPrec, where we had a definition
1064 like    (\x. Get `cast` g)
1065 where Get is a constructor with nonzero arity.  Then mkLam eta-expanded
1066 the Get, and the next iteration eta-reduced it, and then eta-expanded
1067 it again.
1068
1069 Note also the side condition for the case of coercion binders.
1070 It does not make sense to transform
1071         /\g. e `cast` g  ==>  (/\g.e) `cast` (/\g.g)
1072 because the latter is not well-kinded.
1073
1074 --      c) floating lets out through big lambdas
1075 --              [only if all tyvar lambdas, and only if this lambda
1076 --               is the RHS of a let]
1077
1078 {-      Sept 01: I'm experimenting with getting the
1079         full laziness pass to float out past big lambdsa
1080  | all isTyVar bndrs,   -- Only for big lambdas
1081    contIsRhs cont       -- Only try the rhs type-lambda floating
1082                         -- if this is indeed a right-hand side; otherwise
1083                         -- we end up floating the thing out, only for float-in
1084                         -- to float it right back in again!
1085  = do (floats, body') <- tryRhsTyLam env bndrs body
1086       return (floats, mkLams bndrs body')
1087 -}
1088
1089
1090 %************************************************************************
1091 %*                                                                      *
1092                 Eta reduction
1093 %*                                                                      *
1094 %************************************************************************
1095
1096 Note [Eta reduction conditions]
1097 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1098 We try for eta reduction here, but *only* if we get all the way to an
1099 trivial expression.  We don't want to remove extra lambdas unless we
1100 are going to avoid allocating this thing altogether.
1101
1102 There are some particularly delicate points here:
1103
1104 * Eta reduction is not valid in general:
1105         \x. bot  /=  bot
1106   This matters, partly for old-fashioned correctness reasons but,
1107   worse, getting it wrong can yield a seg fault. Consider
1108         f = \x.f x
1109         h y = case (case y of { True -> f `seq` True; False -> False }) of
1110                 True -> ...; False -> ...
1111
1112   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
1113   says f=bottom, and replaces the (f `seq` True) with just
1114   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
1115   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
1116   the definition again, so that it does not termninate after all.
1117   Result: seg-fault because the boolean case actually gets a function value.
1118   See Trac #1947.
1119
1120   So it's important to to the right thing.
1121
1122 * Note [Arity care]: we need to be careful if we just look at f's
1123   arity. Currently (Dec07), f's arity is visible in its own RHS (see
1124   Note [Arity robustness] in SimplEnv) so we must *not* trust the
1125   arity when checking that 'f' is a value.  Otherwise we will
1126   eta-reduce
1127       f = \x. f x
1128   to
1129       f = f
1130   Which might change a terminiating program (think (f `seq` e)) to a
1131   non-terminating one.  So we check for being a loop breaker first.
1132
1133   However for GlobalIds we can look at the arity; and for primops we
1134   must, since they have no unfolding.
1135
1136 * Regardless of whether 'f' is a value, we always want to
1137   reduce (/\a -> f a) to f
1138   This came up in a RULE: foldr (build (/\a -> g a))
1139   did not match           foldr (build (/\b -> ...something complex...))
1140   The type checker can insert these eta-expanded versions,
1141   with both type and dictionary lambdas; hence the slightly
1142   ad-hoc isDictId
1143
1144 * Never *reduce* arity. For example
1145       f = \xy. g x y
1146   Then if h has arity 1 we don't want to eta-reduce because then
1147   f's arity would decrease, and that is bad
1148
1149 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
1150 Alas.
1151
1152 \begin{code}
1153 tryEtaReduce :: [OutBndr] -> OutExpr -> Maybe OutExpr
1154 tryEtaReduce bndrs body
1155   = go (reverse bndrs) body
1156   where
1157     incoming_arity = count isId bndrs
1158
1159     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
1160     go []       fun           | ok_fun fun   = Just fun         -- Success!
1161     go _        _                            = Nothing          -- Failure!
1162
1163         -- Note [Eta reduction conditions]
1164     ok_fun (App fun (Type ty))
1165         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1166         =  ok_fun fun
1167     ok_fun (Var fun_id)
1168         =  not (fun_id `elem` bndrs)
1169         && (ok_fun_id fun_id || all ok_lam bndrs)
1170     ok_fun _fun = False
1171
1172     ok_fun_id fun = fun_arity fun >= incoming_arity
1173
1174     fun_arity fun             -- See Note [Arity care]
1175        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1176        | otherwise = idArity fun
1177
1178     ok_lam v = isTyVar v || isDictId v
1179
1180     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
1181 \end{code}
1182
1183
1184 %************************************************************************
1185 %*                                                                      *
1186                 Eta expansion
1187 %*                                                                      *
1188 %************************************************************************
1189
1190
1191 We go for:
1192    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
1193                                  (n >= 0)
1194
1195 where (in both cases)
1196
1197         * The xi can include type variables
1198
1199         * The yi are all value variables
1200
1201         * N is a NORMAL FORM (i.e. no redexes anywhere)
1202           wanting a suitable number of extra args.
1203
1204 The biggest reason for doing this is for cases like
1205
1206         f = \x -> case x of
1207                     True  -> \y -> e1
1208                     False -> \y -> e2
1209
1210 Here we want to get the lambdas together.  A good exmaple is the nofib
1211 program fibheaps, which gets 25% more allocation if you don't do this
1212 eta-expansion.
1213
1214 We may have to sandwich some coerces between the lambdas
1215 to make the types work.   exprEtaExpandArity looks through coerces
1216 when computing arity; and etaExpand adds the coerces as necessary when
1217 actually computing the expansion.
1218
1219 \begin{code}
1220 tryEtaExpansion :: DynFlags -> OutExpr -> OutExpr
1221 -- There is at least one runtime binder in the binders
1222 tryEtaExpansion dflags body
1223   = etaExpand fun_arity body
1224   where
1225     fun_arity = exprEtaExpandArity dflags body
1226 \end{code}
1227
1228
1229 %************************************************************************
1230 %*                                                                      *
1231 \subsection{Floating lets out of big lambdas}
1232 %*                                                                      *
1233 %************************************************************************
1234
1235 Note [Floating and type abstraction]
1236 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1237 Consider this:
1238         x = /\a. C e1 e2
1239 We'd like to float this to
1240         y1 = /\a. e1
1241         y2 = /\a. e2
1242         x  = /\a. C (y1 a) (y2 a)
1243 for the usual reasons: we want to inline x rather vigorously.
1244
1245 You may think that this kind of thing is rare.  But in some programs it is
1246 common.  For example, if you do closure conversion you might get:
1247
1248         data a :-> b = forall e. (e -> a -> b) :$ e
1249
1250         f_cc :: forall a. a :-> a
1251         f_cc = /\a. (\e. id a) :$ ()
1252
1253 Now we really want to inline that f_cc thing so that the
1254 construction of the closure goes away.
1255
1256 So I have elaborated simplLazyBind to understand right-hand sides that look
1257 like
1258         /\ a1..an. body
1259
1260 and treat them specially. The real work is done in SimplUtils.abstractFloats,
1261 but there is quite a bit of plumbing in simplLazyBind as well.
1262
1263 The same transformation is good when there are lets in the body:
1264
1265         /\abc -> let(rec) x = e in b
1266    ==>
1267         let(rec) x' = /\abc -> let x = x' a b c in e
1268         in
1269         /\abc -> let x = x' a b c in b
1270
1271 This is good because it can turn things like:
1272
1273         let f = /\a -> letrec g = ... g ... in g
1274 into
1275         letrec g' = /\a -> ... g' a ...
1276         in
1277         let f = /\ a -> g' a
1278
1279 which is better.  In effect, it means that big lambdas don't impede
1280 let-floating.
1281
1282 This optimisation is CRUCIAL in eliminating the junk introduced by
1283 desugaring mutually recursive definitions.  Don't eliminate it lightly!
1284
1285 [May 1999]  If we do this transformation *regardless* then we can
1286 end up with some pretty silly stuff.  For example,
1287
1288         let
1289             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
1290         in ..
1291 becomes
1292         let y1 = /\s -> r1
1293             y2 = /\s -> r2
1294             st = /\s -> ...[y1 s/x1, y2 s/x2]
1295         in ..
1296
1297 Unless the "..." is a WHNF there is really no point in doing this.
1298 Indeed it can make things worse.  Suppose x1 is used strictly,
1299 and is of the form
1300
1301         x1* = case f y of { (a,b) -> e }
1302
1303 If we abstract this wrt the tyvar we then can't do the case inline
1304 as we would normally do.
1305
1306 That's why the whole transformation is part of the same process that
1307 floats let-bindings and constructor arguments out of RHSs.  In particular,
1308 it is guarded by the doFloatFromRhs call in simplLazyBind.
1309
1310
1311 \begin{code}
1312 abstractFloats :: [OutTyVar] -> SimplEnv -> OutExpr -> SimplM ([OutBind], OutExpr)
1313 abstractFloats main_tvs body_env body
1314   = ASSERT( notNull body_floats )
1315     do  { (subst, float_binds) <- mapAccumLM abstract empty_subst body_floats
1316         ; return (float_binds, CoreSubst.substExpr (text "abstract_floats1") subst body) }
1317   where
1318     main_tv_set = mkVarSet main_tvs
1319     body_floats = getFloats body_env
1320     empty_subst = CoreSubst.mkEmptySubst (seInScope body_env)
1321
1322     abstract :: CoreSubst.Subst -> OutBind -> SimplM (CoreSubst.Subst, OutBind)
1323     abstract subst (NonRec id rhs)
1324       = do { (poly_id, poly_app) <- mk_poly tvs_here id
1325            ; let poly_rhs = mkLams tvs_here rhs'
1326                  subst'   = CoreSubst.extendIdSubst subst id poly_app
1327            ; return (subst', (NonRec poly_id poly_rhs)) }
1328       where
1329         rhs' = CoreSubst.substExpr (text "abstract_floats2") subst rhs
1330         tvs_here | any isCoVar main_tvs = main_tvs      -- Note [Abstract over coercions]
1331                  | otherwise
1332                  = varSetElems (main_tv_set `intersectVarSet` exprSomeFreeVars isTyVar rhs')
1333
1334                 -- Abstract only over the type variables free in the rhs
1335                 -- wrt which the new binding is abstracted.  But the naive
1336                 -- approach of abstract wrt the tyvars free in the Id's type
1337                 -- fails. Consider:
1338                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1339                 --                    x :: a     = fst t
1340                 --                in ...
1341                 -- Here, b isn't free in x's type, but we must nevertheless
1342                 -- abstract wrt b as well, because t's type mentions b.
1343                 -- Since t is floated too, we'd end up with the bogus:
1344                 --      poly_t = /\ a b -> (e1, e2)
1345                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1346                 -- So for now we adopt the even more naive approach of
1347                 -- abstracting wrt *all* the tyvars.  We'll see if that
1348                 -- gives rise to problems.   SLPJ June 98
1349
1350     abstract subst (Rec prs)
1351        = do { (poly_ids, poly_apps) <- mapAndUnzipM (mk_poly tvs_here) ids
1352             ; let subst' = CoreSubst.extendSubstList subst (ids `zip` poly_apps)
1353                   poly_rhss = [mkLams tvs_here (CoreSubst.substExpr (text "abstract_floats3") subst' rhs)
1354                               | rhs <- rhss]
1355             ; return (subst', Rec (poly_ids `zip` poly_rhss)) }
1356        where
1357          (ids,rhss) = unzip prs
1358                 -- For a recursive group, it's a bit of a pain to work out the minimal
1359                 -- set of tyvars over which to abstract:
1360                 --      /\ a b c.  let x = ...a... in
1361                 --                 letrec { p = ...x...q...
1362                 --                          q = .....p...b... } in
1363                 --                 ...
1364                 -- Since 'x' is abstracted over 'a', the {p,q} group must be abstracted
1365                 -- over 'a' (because x is replaced by (poly_x a)) as well as 'b'.
1366                 -- Since it's a pain, we just use the whole set, which is always safe
1367                 --
1368                 -- If you ever want to be more selective, remember this bizarre case too:
1369                 --      x::a = x
1370                 -- Here, we must abstract 'x' over 'a'.
1371          tvs_here = main_tvs
1372
1373     mk_poly tvs_here var
1374       = do { uniq <- getUniqueM
1375            ; let  poly_name = setNameUnique (idName var) uniq           -- Keep same name
1376                   poly_ty   = mkForAllTys tvs_here (idType var) -- But new type of course
1377                   poly_id   = transferPolyIdInfo var tvs_here $ -- Note [transferPolyIdInfo] in Id.lhs
1378                               mkLocalId poly_name poly_ty
1379            ; return (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tvs_here)) }
1380                 -- In the olden days, it was crucial to copy the occInfo of the original var,
1381                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1382                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1383                 -- at already simplified code, so it doesn't matter
1384                 --
1385                 -- It's even right to retain single-occurrence or dead-var info:
1386                 -- Suppose we started with  /\a -> let x = E in B
1387                 -- where x occurs once in B. Then we transform to:
1388                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1389                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1390                 -- the occurrences of x' will be just the occurrences originally
1391                 -- pinned on x.
1392 \end{code}
1393
1394 Note [Abstract over coercions]
1395 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1396 If a coercion variable (g :: a ~ Int) is free in the RHS, then so is the
1397 type variable a.  Rather than sort this mess out, we simply bale out and abstract
1398 wrt all the type variables if any of them are coercion variables.
1399
1400
1401 Historical note: if you use let-bindings instead of a substitution, beware of this:
1402
1403                 -- Suppose we start with:
1404                 --
1405                 --      x = /\ a -> let g = G in E
1406                 --
1407                 -- Then we'll float to get
1408                 --
1409                 --      x = let poly_g = /\ a -> G
1410                 --          in /\ a -> let g = poly_g a in E
1411                 --
1412                 -- But now the occurrence analyser will see just one occurrence
1413                 -- of poly_g, not inside a lambda, so the simplifier will
1414                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1415                 -- (I used to think that the "don't inline lone occurrences" stuff
1416                 --  would stop this happening, but since it's the *only* occurrence,
1417                 --  PreInlineUnconditionally kicks in first!)
1418                 --
1419                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1420                 --           to appear many times.  (NB: mkInlineMe eliminates
1421                 --           such notes on trivial RHSs, so do it manually.)
1422
1423 %************************************************************************
1424 %*                                                                      *
1425                 prepareAlts
1426 %*                                                                      *
1427 %************************************************************************
1428
1429 prepareAlts tries these things:
1430
1431 1.  Eliminate alternatives that cannot match, including the
1432     DEFAULT alternative.
1433
1434 2.  If the DEFAULT alternative can match only one possible constructor,
1435     then make that constructor explicit.
1436     e.g.
1437         case e of x { DEFAULT -> rhs }
1438      ===>
1439         case e of x { (a,b) -> rhs }
1440     where the type is a single constructor type.  This gives better code
1441     when rhs also scrutinises x or e.
1442
1443 3. Returns a list of the constructors that cannot holds in the
1444    DEFAULT alternative (if there is one)
1445
1446 Here "cannot match" includes knowledge from GADTs
1447
1448 It's a good idea do do this stuff before simplifying the alternatives, to
1449 avoid simplifying alternatives we know can't happen, and to come up with
1450 the list of constructors that are handled, to put into the IdInfo of the
1451 case binder, for use when simplifying the alternatives.
1452
1453 Eliminating the default alternative in (1) isn't so obvious, but it can
1454 happen:
1455
1456 data Colour = Red | Green | Blue
1457
1458 f x = case x of
1459         Red -> ..
1460         Green -> ..
1461         DEFAULT -> h x
1462
1463 h y = case y of
1464         Blue -> ..
1465         DEFAULT -> [ case y of ... ]
1466
1467 If we inline h into f, the default case of the inlined h can't happen.
1468 If we don't notice this, we may end up filtering out *all* the cases
1469 of the inner case y, which give us nowhere to go!
1470
1471 \begin{code}
1472 prepareAlts :: OutExpr -> OutId -> [InAlt] -> SimplM ([AltCon], [InAlt])
1473 prepareAlts scrut case_bndr' alts
1474   = do  { let (alts_wo_default, maybe_deflt) = findDefault alts
1475               alt_cons = [con | (con,_,_) <- alts_wo_default]
1476               imposs_deflt_cons = nub (imposs_cons ++ alt_cons)
1477                 -- "imposs_deflt_cons" are handled
1478                 --   EITHER by the context,
1479                 --   OR by a non-DEFAULT branch in this case expression.
1480
1481         ; default_alts <- prepareDefault case_bndr' mb_tc_app
1482                                          imposs_deflt_cons maybe_deflt
1483
1484         ; let trimmed_alts = filterOut impossible_alt alts_wo_default
1485               merged_alts  = mergeAlts trimmed_alts default_alts
1486                 -- We need the mergeAlts in case the new default_alt
1487                 -- has turned into a constructor alternative.
1488                 -- The merge keeps the inner DEFAULT at the front, if there is one
1489                 -- and interleaves the alternatives in the right order
1490
1491         ; return (imposs_deflt_cons, merged_alts) }
1492   where
1493     mb_tc_app = splitTyConApp_maybe (idType case_bndr')
1494     Just (_, inst_tys) = mb_tc_app
1495
1496     imposs_cons = case scrut of
1497                     Var v -> otherCons (idUnfolding v)
1498                     _     -> []
1499
1500     impossible_alt :: CoreAlt -> Bool
1501     impossible_alt (con, _, _) | con `elem` imposs_cons = True
1502     impossible_alt (DataAlt con, _, _) = dataConCannotMatch inst_tys con
1503     impossible_alt _                   = False
1504
1505
1506 prepareDefault :: OutId         -- Case binder; need just for its type. Note that as an
1507                                 --   OutId, it has maximum information; this is important.
1508                                 --   Test simpl013 is an example
1509                -> Maybe (TyCon, [Type]) -- Type of scrutinee, decomposed
1510                -> [AltCon]      -- These cons can't happen when matching the default
1511                -> Maybe InExpr  -- Rhs
1512                -> SimplM [InAlt]        -- Still unsimplified
1513                                         -- We use a list because it's what mergeAlts expects,
1514
1515 --------- Fill in known constructor -----------
1516 prepareDefault case_bndr (Just (tycon, inst_tys)) imposs_cons (Just deflt_rhs)
1517   |     -- This branch handles the case where we are
1518         -- scrutinisng an algebraic data type
1519     isAlgTyCon tycon            -- It's a data type, tuple, or unboxed tuples.
1520   , not (isNewTyCon tycon)      -- We can have a newtype, if we are just doing an eval:
1521                                 --      case x of { DEFAULT -> e }
1522                                 -- and we don't want to fill in a default for them!
1523   , Just all_cons <- tyConDataCons_maybe tycon
1524   , not (null all_cons)         -- This is a tricky corner case.  If the data type has no constructors,
1525                                 -- which GHC allows, then the case expression will have at most a default
1526                                 -- alternative.  We don't want to eliminate that alternative, because the
1527                                 -- invariant is that there's always one alternative.  It's more convenient
1528                                 -- to leave
1529                                 --      case x of { DEFAULT -> e }
1530                                 -- as it is, rather than transform it to
1531                                 --      error "case cant match"
1532                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1533                                 -- not worth wasting code on.
1534   , let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1535         impossible con   = con `elem` imposs_data_cons || dataConCannotMatch inst_tys con
1536   = case filterOut impossible all_cons of
1537         []    -> return []      -- Eliminate the default alternative
1538                                 -- altogether if it can't match
1539
1540         [con] ->        -- It matches exactly one constructor, so fill it in
1541                  do { tick (FillInCaseDefault case_bndr)
1542                     ; us <- getUniquesM
1543                     ; let (ex_tvs, co_tvs, arg_ids) =
1544                               dataConRepInstPat us con inst_tys
1545                     ; return [(DataAlt con, ex_tvs ++ co_tvs ++ arg_ids, deflt_rhs)] }
1546
1547         _ -> return [(DEFAULT, [], deflt_rhs)]
1548
1549   | debugIsOn, isAlgTyCon tycon, not (isOpenTyCon tycon), null (tyConDataCons tycon)
1550         -- Check for no data constructors
1551         -- This can legitimately happen for type families, so don't report that
1552   = pprTrace "prepareDefault" (ppr case_bndr <+> ppr tycon)
1553         $ return [(DEFAULT, [], deflt_rhs)]
1554
1555 --------- Catch-all cases -----------
1556 prepareDefault _case_bndr _bndr_ty _imposs_cons (Just deflt_rhs)
1557   = return [(DEFAULT, [], deflt_rhs)]
1558
1559 prepareDefault _case_bndr _bndr_ty _imposs_cons Nothing
1560   = return []   -- No default branch
1561 \end{code}
1562
1563
1564
1565 %************************************************************************
1566 %*                                                                      *
1567                 mkCase
1568 %*                                                                      *
1569 %************************************************************************
1570
1571 mkCase tries these things
1572
1573 1.  Merge Nested Cases
1574
1575        case e of b {             ==>   case e of b {
1576          p1 -> rhs1                      p1 -> rhs1
1577          ...                             ...
1578          pm -> rhsm                      pm -> rhsm
1579          _  -> case b of b' {            pn -> let b'=b in rhsn
1580                      pn -> rhsn          ...
1581                      ...                 po -> let b'=b in rhso
1582                      po -> rhso          _  -> let b'=b in rhsd
1583                      _  -> rhsd
1584        }
1585
1586     which merges two cases in one case when -- the default alternative of
1587     the outer case scrutises the same variable as the outer case. This
1588     transformation is called Case Merging.  It avoids that the same
1589     variable is scrutinised multiple times.
1590
1591 2.  Eliminate Identity Case
1592
1593         case e of               ===> e
1594                 True  -> True;
1595                 False -> False
1596
1597     and similar friends.
1598
1599 3.  Merge identical alternatives.
1600     If several alternatives are identical, merge them into
1601     a single DEFAULT alternative.  I've occasionally seen this
1602     making a big difference:
1603
1604         case e of               =====>     case e of
1605           C _ -> f x                         D v -> ....v....
1606           D v -> ....v....                   DEFAULT -> f x
1607           DEFAULT -> f x
1608
1609    The point is that we merge common RHSs, at least for the DEFAULT case.
1610    [One could do something more elaborate but I've never seen it needed.]
1611    To avoid an expensive test, we just merge branches equal to the *first*
1612    alternative; this picks up the common cases
1613         a) all branches equal
1614         b) some branches equal to the DEFAULT (which occurs first)
1615
1616 The case where Merge Identical Alternatives transformation showed up
1617 was like this (base/Foreign/C/Err/Error.lhs):
1618
1619         x | p `is` 1 -> e1
1620           | p `is` 2 -> e2
1621         ...etc...
1622
1623 where @is@ was something like
1624
1625         p `is` n = p /= (-1) && p == n
1626
1627 This gave rise to a horrible sequence of cases
1628
1629         case p of
1630           (-1) -> $j p
1631           1    -> e1
1632           DEFAULT -> $j p
1633
1634 and similarly in cascade for all the join points!
1635
1636
1637 \begin{code}
1638 mkCase, mkCase1, mkCase2
1639    :: DynFlags
1640    -> OutExpr -> OutId
1641    -> [OutAlt]          -- Alternatives in standard (increasing) order
1642    -> SimplM OutExpr
1643
1644 --------------------------------------------------
1645 --      1. Merge Nested Cases
1646 --------------------------------------------------
1647
1648 mkCase dflags scrut outer_bndr ((DEFAULT, _, deflt_rhs) : outer_alts)
1649   | dopt Opt_CaseMerge dflags
1650   , Case (Var inner_scrut_var) inner_bndr _ inner_alts <- deflt_rhs
1651   , inner_scrut_var == outer_bndr
1652   = do  { tick (CaseMerge outer_bndr)
1653
1654         ; let wrap_alt (con, args, rhs) = ASSERT( outer_bndr `notElem` args )
1655                                           (con, args, wrap_rhs rhs)
1656                 -- Simplifier's no-shadowing invariant should ensure
1657                 -- that outer_bndr is not shadowed by the inner patterns
1658               wrap_rhs rhs = Let (NonRec inner_bndr (Var outer_bndr)) rhs
1659                 -- The let is OK even for unboxed binders,
1660
1661               wrapped_alts | isDeadBinder inner_bndr = inner_alts
1662                            | otherwise               = map wrap_alt inner_alts
1663
1664               merged_alts = mergeAlts outer_alts wrapped_alts
1665                 -- NB: mergeAlts gives priority to the left
1666                 --      case x of
1667                 --        A -> e1
1668                 --        DEFAULT -> case x of
1669                 --                      A -> e2
1670                 --                      B -> e3
1671                 -- When we merge, we must ensure that e1 takes
1672                 -- precedence over e2 as the value for A!
1673
1674         ; mkCase1 dflags scrut outer_bndr merged_alts
1675         }
1676         -- Warning: don't call mkCase recursively!
1677         -- Firstly, there's no point, because inner alts have already had
1678         -- mkCase applied to them, so they won't have a case in their default
1679         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1680         -- in munge_rhs may put a case into the DEFAULT branch!
1681
1682 mkCase dflags scrut bndr alts = mkCase1 dflags scrut bndr alts
1683
1684 --------------------------------------------------
1685 --      2. Eliminate Identity Case
1686 --------------------------------------------------
1687
1688 mkCase1 _dflags scrut case_bndr alts    -- Identity case
1689   | all identity_alt alts
1690   = do { tick (CaseIdentity case_bndr)
1691        ; return (re_cast scrut) }
1692   where
1693     identity_alt (con, args, rhs) = check_eq con args (de_cast rhs)
1694
1695     check_eq DEFAULT       _    (Var v)   = v == case_bndr
1696     check_eq (LitAlt lit') _    (Lit lit) = lit == lit'
1697     check_eq (DataAlt con) args rhs       = rhs `cheapEqExpr` mkConApp con (arg_tys ++ varsToCoreExprs args)
1698                                          || rhs `cheapEqExpr` Var case_bndr
1699     check_eq _ _ _ = False
1700
1701     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1702
1703         -- We've seen this:
1704         --      case e of x { _ -> x `cast` c }
1705         -- And we definitely want to eliminate this case, to give
1706         --      e `cast` c
1707         -- So we throw away the cast from the RHS, and reconstruct
1708         -- it at the other end.  All the RHS casts must be the same
1709         -- if (all identity_alt alts) holds.
1710         --
1711         -- Don't worry about nested casts, because the simplifier combines them
1712     de_cast (Cast e _) = e
1713     de_cast e          = e
1714
1715     re_cast scrut = case head alts of
1716                         (_,_,Cast _ co) -> Cast scrut co
1717                         _               -> scrut
1718
1719 --------------------------------------------------
1720 --      3. Merge Identical Alternatives
1721 --------------------------------------------------
1722 mkCase1 dflags scrut case_bndr ((_con1,bndrs1,rhs1) : con_alts)
1723   | all isDeadBinder bndrs1                     -- Remember the default
1724   , length filtered_alts < length con_alts      -- alternative comes first
1725         -- Also Note [Dead binders]
1726   = do  { tick (AltMerge case_bndr)
1727         ; mkCase2 dflags scrut case_bndr alts' }
1728   where
1729     alts' = (DEFAULT, [], rhs1) : filtered_alts
1730     filtered_alts         = filter keep con_alts
1731     keep (_con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1732
1733 mkCase1 dflags scrut bndr alts = mkCase2 dflags scrut bndr alts
1734
1735 --------------------------------------------------
1736 --      Catch-all
1737 --------------------------------------------------
1738 mkCase2 _dflags scrut bndr alts
1739   = return (Case scrut bndr (coreAltsType alts) alts)
1740 \end{code}
1741
1742 Note [Dead binders]
1743 ~~~~~~~~~~~~~~~~~~~~
1744 Note that dead-ness is maintained by the simplifier, so that it is
1745 accurate after simplification as well as before.
1746
1747
1748 Note [Cascading case merge]
1749 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1750 Case merging should cascade in one sweep, because it
1751 happens bottom-up
1752
1753       case e of a {
1754         DEFAULT -> case a of b
1755                       DEFAULT -> case b of c {
1756                                      DEFAULT -> e
1757                                      A -> ea
1758                       B -> eb
1759         C -> ec
1760 ==>
1761       case e of a {
1762         DEFAULT -> case a of b
1763                       DEFAULT -> let c = b in e
1764                       A -> let c = b in ea
1765                       B -> eb
1766         C -> ec
1767 ==>
1768       case e of a {
1769         DEFAULT -> let b = a in let c = b in e
1770         A -> let b = a in let c = b in ea
1771         B -> let b = a in eb
1772         C -> ec
1773
1774
1775 However here's a tricky case that we still don't catch, and I don't
1776 see how to catch it in one pass:
1777
1778   case x of c1 { I# a1 ->
1779   case a1 of c2 ->
1780     0 -> ...
1781     DEFAULT -> case x of c3 { I# a2 ->
1782                case a2 of ...
1783
1784 After occurrence analysis (and its binder-swap) we get this
1785
1786   case x of c1 { I# a1 ->
1787   let x = c1 in         -- Binder-swap addition
1788   case a1 of c2 ->
1789     0 -> ...
1790     DEFAULT -> case x of c3 { I# a2 ->
1791                case a2 of ...
1792
1793 When we simplify the inner case x, we'll see that
1794 x=c1=I# a1.  So we'll bind a2 to a1, and get
1795
1796   case x of c1 { I# a1 ->
1797   case a1 of c2 ->
1798     0 -> ...
1799     DEFAULT -> case a1 of ...
1800
1801 This is corect, but we can't do a case merge in this sweep
1802 because c2 /= a1.  Reason: the binding c1=I# a1 went inwards
1803 without getting changed to c1=I# c2.
1804
1805 I don't think this is worth fixing, even if I knew how. It'll
1806 all come out in the next pass anyway.
1807
1808