compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         mkLam, mkCase,
   9
  10         -- Inlining,
  11         preInlineUnconditionally, postInlineUnconditionally, activeInline, activeRule,
  12         inlineMode,
  13
  14         -- The continuation type
  15         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  16         contIsDupable, contResultType,
  17         countValArgs, countArgs, pushContArgs,
  18         mkBoringStop, mkLazyArgStop, mkRhsStop, contIsRhs, contIsRhsOrArg,
  19         getContArgs, interestingCallContext, interestingArgContext,
  20         interestingArg, isStrictType
  21
  22     ) where
  23
  24 #include "HsVersions.h"
  25
  26 import SimplEnv
  27 import DynFlags         ( SimplifierSwitch(..), SimplifierMode(..),
  28                           DynFlags, DynFlag(..), dopt )
  29 import StaticFlags      ( opt_UF_UpdateInPlace, opt_SimplNoPreInlining,
  30                           opt_RulesOff )
  31 import CoreSyn
  32 import CoreFVs          ( exprFreeVars )
  33 import CoreUtils        ( cheapEqExpr, exprType, exprIsTrivial,
  34                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce,
  35                           findDefault, exprOkForSpeculation, exprIsHNF, mergeAlts,
  36                           applyTypeToArgs
  37                         )
  38 import Literal          ( mkStringLit )
  39 import CoreUnfold       ( smallEnoughToInline )
  40 import MkId             ( eRROR_ID, wrapNewTypeBody )
  41 import Id               ( Id, idType, isDataConWorkId, idOccInfo, isDictId,
  42                           isDeadBinder, idNewDemandInfo, isExportedId, mkSysLocal,
  43                           idUnfolding, idNewStrictness, idInlinePragma, idHasRules
  44                         )
  45 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
  46 import SimplMonad
  47 import Var              ( tyVarKind, mkTyVar )
  48 import Name             ( mkSysTvName )
  49 import Type             ( Type, splitFunTys, dropForAlls, isStrictType,
  50                           splitTyConApp_maybe, tyConAppArgs, mkTyVarTys )
  51 import Coercion         ( isEqPredTy
  52                         )
  53 import Coercion         ( Coercion, mkUnsafeCoercion, coercionKind )
  54 import TyCon            ( tyConDataCons_maybe, isClosedNewTyCon )
  55 import DataCon          ( DataCon, dataConRepArity, dataConInstArgTys, dataConTyCon )
  56 import VarSet
  57 import BasicTypes       ( TopLevelFlag(..), isNotTopLevel, OccInfo(..), isLoopBreaker, isOneOcc,
  58                           Activation, isAlwaysActive, isActive )
  59 import Util             ( lengthExceeds )
  60 import Outputable
  61 \end{code}
  62
  63
  64 %************************************************************************
  65 %*                                                                      *
  66 \subsection{The continuation data type}
  67 %*                                                                      *
  68 %************************************************************************
  69
  70 \begin{code}
  71 data SimplCont          -- Strict contexts
  72   = Stop     OutType    -- Type of the result
  73              LetRhsFlag
  74              Bool       -- True <=> There is something interesting about
  75                         --          the context, and hence the inliner
  76                         --          should be a bit keener (see interestingCallContext)
  77                         -- Two cases:
  78                         -- (a) This is the RHS of a thunk whose type suggests
  79                         --     that update-in-place would be possible
  80                         -- (b) This is an argument of a function that has RULES
  81                         --     Inlining the call might allow the rule to fire
  82
  83   | CoerceIt OutCoercion                -- The coercion simplified
  84              SimplCont
  85
  86   | ApplyTo  DupFlag
  87              CoreExpr           -- The argument
  88              (Maybe SimplEnv)   -- (Just se) => the arg is un-simplified and this is its subst-env
  89                                 -- Nothing   => the arg is already simplified; don't repeatedly simplify it!
  90              SimplCont          -- and its environment
  91
  92   | Select   DupFlag
  93              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
  94              SimplCont
  95
  96   | ArgOf    LetRhsFlag         -- An arbitrary strict context: the argument
  97                                 --      of a strict function, or a primitive-arg fn
  98                                 --      or a PrimOp
  99                                 -- No DupFlag, because we never duplicate it
 100              OutType            -- arg_ty: type of the argument itself
 101              OutType            -- cont_ty: the type of the expression being sought by the context
 102                                 --      f (error "foo") ==> coerce t (error "foo")
 103                                 -- when f is strict
 104                                 -- We need to know the type t, to which to coerce.
 105
 106              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
 107                                 -- The result expression in the OutExprStuff has type cont_ty
 108
 109 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
 110                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
 111
 112 instance Outputable LetRhsFlag where
 113   ppr AnArg = ptext SLIT("arg")
 114   ppr AnRhs = ptext SLIT("rhs")
 115
 116 instance Outputable SimplCont where
 117   ppr (Stop ty is_rhs _)             = ptext SLIT("Stop") <> brackets (ppr is_rhs) <+> ppr ty
 118   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
 119   ppr (ArgOf _ _ _ _)                = ptext SLIT("ArgOf...")
 120   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 121                                        (nest 4 (ppr alts)) $$ ppr cont
 122   ppr (CoerceIt co cont)             = (ptext SLIT("CoerceIt") <+> ppr co) $$ ppr cont
 123
 124 data DupFlag = OkToDup | NoDup
 125
 126 instance Outputable DupFlag where
 127   ppr OkToDup = ptext SLIT("ok")
 128   ppr NoDup   = ptext SLIT("nodup")
 129
 130
 131
 132 -------------------
 133 mkBoringStop :: OutType -> SimplCont
 134 mkBoringStop ty = Stop ty AnArg False
 135
 136 mkLazyArgStop :: OutType -> Bool -> SimplCont
 137 mkLazyArgStop ty has_rules = Stop ty AnArg (canUpdateInPlace ty || has_rules)
 138
 139 mkRhsStop :: OutType -> SimplCont
 140 mkRhsStop ty = Stop ty AnRhs (canUpdateInPlace ty)
 141
 142 contIsRhs :: SimplCont -> Bool
 143 contIsRhs (Stop _ AnRhs _)    = True
 144 contIsRhs (ArgOf AnRhs _ _ _) = True
 145 contIsRhs other               = False
 146
 147 contIsRhsOrArg (Stop _ _ _)    = True
 148 contIsRhsOrArg (ArgOf _ _ _ _) = True
 149 contIsRhsOrArg other           = False
 150
 151 -------------------
 152 contIsDupable :: SimplCont -> Bool
 153 contIsDupable (Stop _ _ _)               = True
 154 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 155 contIsDupable (Select   OkToDup _ _ _ _) = True
 156 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 157 contIsDupable other                      = False
 158
 159 -------------------
 160 discardableCont :: SimplCont -> Bool
 161 discardableCont (Stop _ _ _)        = False
 162 discardableCont (CoerceIt _ cont)   = discardableCont cont
 163 discardableCont other               = True
 164
 165 discardCont :: Type             -- The type expected
 166             -> SimplCont        -- A continuation, expecting the previous type
 167             -> SimplCont        -- Replace the continuation with a suitable coerce
 168 discardCont from_ty cont = case cont of
 169                      Stop to_ty is_rhs _ -> cont
 170                      other               -> CoerceIt co (mkBoringStop to_ty)
 171                  where
 172                    co      = mkUnsafeCoercion from_ty to_ty
 173                    to_ty   = contResultType cont
 174
 175 -------------------
 176 contResultType :: SimplCont -> OutType
 177 contResultType (Stop to_ty _ _)      = to_ty
 178 contResultType (ArgOf _ _ to_ty _)   = to_ty
 179 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 180 contResultType (CoerceIt _ cont)     = contResultType cont
 181 contResultType (Select _ _ _ _ cont) = contResultType cont
 182
 183 -------------------
 184 countValArgs :: SimplCont -> Int
 185 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 186 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 187 countValArgs other                         = 0
 188
 189 countArgs :: SimplCont -> Int
 190 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 191 countArgs other                   = 0
 192
 193 -------------------
 194 pushContArgs ::[OutArg] -> SimplCont -> SimplCont
 195 -- Pushes args with the specified environment
 196 pushContArgs []           cont = cont
 197 pushContArgs (arg : args) cont = ApplyTo NoDup arg Nothing (pushContArgs args cont)
 198 \end{code}
 199
 200
 201 \begin{code}
 202 getContArgs :: SwitchChecker
 203             -> OutId -> SimplCont
 204             -> ([(InExpr, Maybe SimplEnv, Bool)],       -- Arguments; the Bool is true for strict args
 205                 SimplCont)                              -- Remaining continuation
 206 -- getContArgs id k = (args, k', inl)
 207 --      args are the leading ApplyTo items in k
 208 --      (i.e. outermost comes first)
 209 --      augmented with demand info from the functionn
 210 getContArgs chkr fun orig_cont
 211   = let
 212                 -- Ignore strictness info if the no-case-of-case
 213                 -- flag is on.  Strictness changes evaluation order
 214                 -- and that can change full laziness
 215         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 216                 | otherwise                    = computed_stricts
 217     in
 218     go [] stricts orig_cont
 219   where
 220     ----------------------------
 221
 222         -- Type argument
 223     go acc ss (ApplyTo _ arg@(Type _) se cont)
 224         = go ((arg,se,False) : acc) ss cont
 225                 -- NB: don't bother to instantiate the function type
 226
 227         -- Value argument
 228     go acc (s:ss) (ApplyTo _ arg se cont)
 229         = go ((arg,se,s) : acc) ss cont
 230
 231         -- We're run out of arguments, or else we've run out of demands
 232         -- The latter only happens if the result is guaranteed bottom
 233         -- This is the case for
 234         --      * case (error "hello") of { ... }
 235         --      * (error "Hello") arg
 236         --      * f (error "Hello") where f is strict
 237         --      etc
 238         -- Then, especially in the first of these cases, we'd like to discard
 239         -- the continuation, leaving just the bottoming expression.  But the
 240         -- type might not be right, so we may have to add a coerce.
 241
 242     go acc ss cont
 243         | null ss && discardableCont cont = (args, discardCont hole_ty cont)
 244         | otherwise                       = (args, cont)
 245         where
 246           args = reverse acc
 247           hole_ty = applyTypeToArgs (Var fun) (idType fun)
 248                                     [substExpr_mb se arg | (arg,se,_) <- args]
 249           substExpr_mb Nothing   arg = arg
 250           substExpr_mb (Just se) arg = substExpr se arg
 251
 252     ----------------------------
 253     vanilla_stricts, computed_stricts :: [Bool]
 254     vanilla_stricts  = repeat False
 255     computed_stricts = zipWith (||) fun_stricts arg_stricts
 256
 257     ----------------------------
 258     (val_arg_tys, res_ty) = splitFunTys (dropForAlls (idType fun))
 259     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 260         -- These argument types are used as a cheap and cheerful way to find
 261         -- unboxed arguments, which must be strict.  But it's an InType
 262         -- and so there might be a type variable where we expect a function
 263         -- type (the substitution hasn't happened yet).  And we don't bother
 264         -- doing the type applications for a polymorphic function.
 265         -- Hence the splitFunTys*IgnoringForAlls*
 266
 267     ----------------------------
 268         -- If fun_stricts is finite, it means the function returns bottom
 269         -- after that number of value args have been consumed
 270         -- Otherwise it's infinite, extended with False
 271     fun_stricts
 272       = case splitStrictSig (idNewStrictness fun) of
 273           (demands, result_info)
 274                 | not (demands `lengthExceeds` countValArgs orig_cont)
 275                 ->      -- Enough args, use the strictness given.
 276                         -- For bottoming functions we used to pretend that the arg
 277                         -- is lazy, so that we don't treat the arg as an
 278                         -- interesting context.  This avoids substituting
 279                         -- top-level bindings for (say) strings into
 280                         -- calls to error.  But now we are more careful about
 281                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 282                    if isBotRes result_info then
 283                         map isStrictDmd demands         -- Finite => result is bottom
 284                    else
 285                         map isStrictDmd demands ++ vanilla_stricts
 286
 287           other -> vanilla_stricts      -- Not enough args, or no strictness
 288
 289 -------------------
 290 interestingArg :: OutExpr -> Bool
 291         -- An argument is interesting if it has *some* structure
 292         -- We are here trying to avoid unfolding a function that
 293         -- is applied only to variables that have no unfolding
 294         -- (i.e. they are probably lambda bound): f x y z
 295         -- There is little point in inlining f here.
 296 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 297                                         -- Was: isValueUnfolding (idUnfolding v')
 298                                         -- But that seems over-pessimistic
 299                                  || isDataConWorkId v
 300                                         -- This accounts for an argument like
 301                                         -- () or [], which is definitely interesting
 302 interestingArg (Type _)          = False
 303 interestingArg (App fn (Type _)) = interestingArg fn
 304 interestingArg (Note _ a)        = interestingArg a
 305 interestingArg other             = True
 306         -- Consider     let x = 3 in f x
 307         -- The substitution will contain (x -> ContEx 3), and we want to
 308         -- to say that x is an interesting argument.
 309         -- But consider also (\x. f x y) y
 310         -- The substitution will contain (x -> ContEx y), and we want to say
 311         -- that x is not interesting (assuming y has no unfolding)
 312 \end{code}
 313
 314 Comment about interestingCallContext
 315 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 316 We want to avoid inlining an expression where there can't possibly be
 317 any gain, such as in an argument position.  Hence, if the continuation
 318 is interesting (eg. a case scrutinee, application etc.) then we
 319 inline, otherwise we don't.
 320
 321 Previously some_benefit used to return True only if the variable was
 322 applied to some value arguments.  This didn't work:
 323
 324         let x = _coerce_ (T Int) Int (I# 3) in
 325         case _coerce_ Int (T Int) x of
 326                 I# y -> ....
 327
 328 we want to inline x, but can't see that it's a constructor in a case
 329 scrutinee position, and some_benefit is False.
 330
 331 Another example:
 332
 333 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 334
 335 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 336
 337 we'd really like to inline dMonadST here, but we *don't* want to
 338 inline if the case expression is just
 339
 340         case x of y { DEFAULT -> ... }
 341
 342 since we can just eliminate this case instead (x is in WHNF).  Similar
 343 applies when x is bound to a lambda expression.  Hence
 344 contIsInteresting looks for case expressions with just a single
 345 default case.
 346
 347 \begin{code}
 348 interestingCallContext :: Bool          -- False <=> no args at all
 349                        -> Bool          -- False <=> no value args
 350                        -> SimplCont -> Bool
 351         -- The "lone-variable" case is important.  I spent ages
 352         -- messing about with unsatisfactory varaints, but this is nice.
 353         -- The idea is that if a variable appear all alone
 354         --      as an arg of lazy fn, or rhs    Stop
 355         --      as scrutinee of a case          Select
 356         --      as arg of a strict fn           ArgOf
 357         -- then we should not inline it (unless there is some other reason,
 358         -- e.g. is is the sole occurrence).  We achieve this by making
 359         -- interestingCallContext return False for a lone variable.
 360         --
 361         -- Why?  At least in the case-scrutinee situation, turning
 362         --      let x = (a,b) in case x of y -> ...
 363         -- into
 364         --      let x = (a,b) in case (a,b) of y -> ...
 365         -- and thence to
 366         --      let x = (a,b) in let y = (a,b) in ...
 367         -- is bad if the binding for x will remain.
 368         --
 369         -- Another example: I discovered that strings
 370         -- were getting inlined straight back into applications of 'error'
 371         -- because the latter is strict.
 372         --      s = "foo"
 373         --      f = \x -> ...(error s)...
 374
 375         -- Fundamentally such contexts should not ecourage inlining because
 376         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 377         -- so there's no gain.
 378         --
 379         -- However, even a type application or coercion isn't a lone variable.
 380         -- Consider
 381         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 382         -- We had better inline that sucker!  The case won't see through it.
 383         --
 384         -- For now, I'm treating treating a variable applied to types
 385         -- in a *lazy* context "lone". The motivating example was
 386         --      f = /\a. \x. BIG
 387         --      g = /\a. \y.  h (f a)
 388         -- There's no advantage in inlining f here, and perhaps
 389         -- a significant disadvantage.  Hence some_val_args in the Stop case
 390
 391 interestingCallContext some_args some_val_args cont
 392   = interesting cont
 393   where
 394     interesting (Select {})              = some_args
 395     interesting (ApplyTo {})             = True -- Can happen if we have (coerce t (f x)) y
 396                                                 -- Perhaps True is a bit over-keen, but I've
 397                                                 -- seen (coerce f) x, where f has an INLINE prag,
 398                                                 -- So we have to give some motivaiton for inlining it
 399     interesting (ArgOf {})               = some_val_args
 400     interesting (Stop ty _ interesting)  = some_val_args && interesting
 401     interesting (CoerceIt _ cont)        = interesting cont
 402         -- If this call is the arg of a strict function, the context
 403         -- is a bit interesting.  If we inline here, we may get useful
 404         -- evaluation information to avoid repeated evals: e.g.
 405         --      x + (y * z)
 406         -- Here the contIsInteresting makes the '*' keener to inline,
 407         -- which in turn exposes a constructor which makes the '+' inline.
 408         -- Assuming that +,* aren't small enough to inline regardless.
 409         --
 410         -- It's also very important to inline in a strict context for things
 411         -- like
 412         --              foldr k z (f x)
 413         -- Here, the context of (f x) is strict, and if f's unfolding is
 414         -- a build it's *great* to inline it here.  So we must ensure that
 415         -- the context for (f x) is not totally uninteresting.
 416
 417
 418 -------------------
 419 interestingArgContext :: Id -> SimplCont -> Bool
 420 -- If the argument has form (f x y), where x,y are boring,
 421 -- and f is marked INLINE, then we don't want to inline f.
 422 -- But if the context of the argument is
 423 --      g (f x y)
 424 -- where g has rules, then we *do* want to inline f, in case it
 425 -- exposes a rule that might fire.  Similarly, if the context is
 426 --      h (g (f x x))
 427 -- where h has rules, then we do want to inline f.
 428 -- The interesting_arg_ctxt flag makes this happen; if it's
 429 -- set, the inliner gets just enough keener to inline f
 430 -- regardless of how boring f's arguments are, if it's marked INLINE
 431 --
 432 -- The alternative would be to *always* inline an INLINE function,
 433 -- regardless of how boring its context is; but that seems overkill
 434 -- For example, it'd mean that wrapper functions were always inlined
 435 interestingArgContext fn cont
 436   = idHasRules fn || go cont
 437   where
 438     go (Select {})            = False
 439     go (ApplyTo {})           = False
 440     go (ArgOf {})             = True
 441     go (CoerceIt _ c)         = go c
 442     go (Stop _ _ interesting) = interesting
 443
 444 -------------------
 445 canUpdateInPlace :: Type -> Bool
 446 -- Consider   let x = <wurble> in ...
 447 -- If <wurble> returns an explicit constructor, we might be able
 448 -- to do update in place.  So we treat even a thunk RHS context
 449 -- as interesting if update in place is possible.  We approximate
 450 -- this by seeing if the type has a single constructor with a
 451 -- small arity.  But arity zero isn't good -- we share the single copy
 452 -- for that case, so no point in sharing.
 453
 454 canUpdateInPlace ty
 455   | not opt_UF_UpdateInPlace = False
 456   | otherwise
 457   = case splitTyConApp_maybe ty of
 458         Nothing         -> False
 459         Just (tycon, _) -> case tyConDataCons_maybe tycon of
 460                                 Just [dc]  -> arity == 1 || arity == 2
 461                                            where
 462                                               arity = dataConRepArity dc
 463                                 other -> False
 464 \end{code}
 465
 466
 467
 468 %************************************************************************
 469 %*                                                                      *
 470 \subsection{Decisions about inlining}
 471 %*                                                                      *
 472 %************************************************************************
 473
 474 Inlining is controlled partly by the SimplifierMode switch.  This has two
 475 settings:
 476
 477         SimplGently     (a) Simplifying before specialiser/full laziness
 478                         (b) Simplifiying inside INLINE pragma
 479                         (c) Simplifying the LHS of a rule
 480                         (d) Simplifying a GHCi expression or Template
 481                                 Haskell splice
 482
 483         SimplPhase n    Used at all other times
 484
 485 The key thing about SimplGently is that it does no call-site inlining.
 486 Before full laziness we must be careful not to inline wrappers,
 487 because doing so inhibits floating
 488     e.g. ...(case f x of ...)...
 489     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 490     ==> ...(case x of I# x# -> case fw x# of ...)...
 491 and now the redex (f x) isn't floatable any more.
 492
 493 The no-inlining thing is also important for Template Haskell.  You might be
 494 compiling in one-shot mode with -O2; but when TH compiles a splice before
 495 running it, we don't want to use -O2.  Indeed, we don't want to inline
 496 anything, because the byte-code interpreter might get confused about
 497 unboxed tuples and suchlike.
 498
 499 INLINE pragmas
 500 ~~~~~~~~~~~~~~
 501 SimplGently is also used as the mode to simplify inside an InlineMe note.
 502
 503 \begin{code}
 504 inlineMode :: SimplifierMode
 505 inlineMode = SimplGently
 506 \end{code}
 507
 508 It really is important to switch off inlinings inside such
 509 expressions.  Consider the following example
 510
 511         let f = \pq -> BIG
 512         in
 513         let g = \y -> f y y
 514             {-# INLINE g #-}
 515         in ...g...g...g...g...g...
 516
 517 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 518 and thence copied multiple times when g is inlined.
 519
 520
 521 This function may be inlinined in other modules, so we
 522 don't want to remove (by inlining) calls to functions that have
 523 specialisations, or that may have transformation rules in an importing
 524 scope.
 525
 526 E.g.    {-# INLINE f #-}
 527                 f x = ...g...
 528
 529 and suppose that g is strict *and* has specialisations.  If we inline
 530 g's wrapper, we deny f the chance of getting the specialised version
 531 of g when f is inlined at some call site (perhaps in some other
 532 module).
 533
 534 It's also important not to inline a worker back into a wrapper.
 535 A wrapper looks like
 536         wraper = inline_me (\x -> ...worker... )
 537 Normally, the inline_me prevents the worker getting inlined into
 538 the wrapper (initially, the worker's only call site!).  But,
 539 if the wrapper is sure to be called, the strictness analyser will
 540 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 541 continuation.  That's why the keep_inline predicate returns True for
 542 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 543 inline-me note under these circumstances.
 544
 545 Note that the result is that we do very little simplification
 546 inside an InlineMe.
 547
 548         all xs = foldr (&&) True xs
 549         any p = all . map p  {-# INLINE any #-}
 550
 551 Problem: any won't get deforested, and so if it's exported and the
 552 importer doesn't use the inlining, (eg passes it as an arg) then we
 553 won't get deforestation at all.  We havn't solved this problem yet!
 554
 555
 556 preInlineUnconditionally
 557 ~~~~~~~~~~~~~~~~~~~~~~~~
 558 @preInlineUnconditionally@ examines a bndr to see if it is used just
 559 once in a completely safe way, so that it is safe to discard the
 560 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 561 big the RHS might be.  If this is the case we don't simplify the RHS
 562 first, but just inline it un-simplified.
 563
 564 This is much better than first simplifying a perhaps-huge RHS and then
 565 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 566 better.  Consider
 567
 568         x1 = e1
 569         x2 = e2[x1]
 570         x3 = e3[x2]
 571         ...etc...
 572         xN = eN[xN-1]
 573
 574 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 575 This can happen with cascades of functions too:
 576
 577         f1 = \x1.e1
 578         f2 = \xs.e2[f1]
 579         f3 = \xs.e3[f3]
 580         ...etc...
 581
 582 THE MAIN INVARIANT is this:
 583
 584         ----  preInlineUnconditionally invariant -----
 585    IF preInlineUnconditionally chooses to inline x = <rhs>
 586    THEN doing the inlining should not change the occurrence
 587         info for the free vars of <rhs>
 588         ----------------------------------------------
 589
 590 For example, it's tempting to look at trivial binding like
 591         x = y
 592 and inline it unconditionally.  But suppose x is used many times,
 593 but this is the unique occurrence of y.  Then inlining x would change
 594 y's occurrence info, which breaks the invariant.  It matters: y
 595 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
 596
 597
 598 Evne RHSs labelled InlineMe aren't caught here, because there might be
 599 no benefit from inlining at the call site.
 600
 601 [Sept 01] Don't unconditionally inline a top-level thing, because that
 602 can simply make a static thing into something built dynamically.  E.g.
 603         x = (a,b)
 604         main = \s -> h x
 605
 606 [Remember that we treat \s as a one-shot lambda.]  No point in
 607 inlining x unless there is something interesting about the call site.
 608
 609 But watch out: if you aren't careful, some useful foldr/build fusion
 610 can be lost (most notably in spectral/hartel/parstof) because the
 611 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 612 deal, in fact, but losing the fusion can be.  But the right thing here
 613 seems to be to do a callSiteInline based on the fact that there is
 614 something interesting about the call site (it's strict).  Hmm.  That
 615 seems a bit fragile.
 616
 617 Conclusion: inline top level things gaily until Phase 0 (the last
 618 phase), at which point don't.
 619
 620 \begin{code}
 621 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
 622 preInlineUnconditionally env top_lvl bndr rhs
 623   | not active             = False
 624   | opt_SimplNoPreInlining = False
 625   | otherwise = case idOccInfo bndr of
 626                   IAmDead                    -> True    -- Happens in ((\x.1) v)
 627                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
 628                   other                      -> False
 629   where
 630     phase = getMode env
 631     active = case phase of
 632                    SimplGently  -> isAlwaysActive prag
 633                    SimplPhase n -> isActive n prag
 634     prag = idInlinePragma bndr
 635
 636     try_once in_lam int_cxt     -- There's one textual occurrence
 637         | not in_lam = isNotTopLevel top_lvl || early_phase
 638         | otherwise  = int_cxt && canInlineInLam rhs
 639
 640 -- Be very careful before inlining inside a lambda, becuase (a) we must not
 641 -- invalidate occurrence information, and (b) we want to avoid pushing a
 642 -- single allocation (here) into multiple allocations (inside lambda).
 643 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
 644 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
 645 --      where
 646 --              is_cheap = exprIsCheap rhs
 647 --              ok = is_cheap && int_cxt
 648
 649         --      int_cxt         The context isn't totally boring
 650         -- E.g. let f = \ab.BIG in \y. map f xs
 651         --      Don't want to substitute for f, because then we allocate
 652         --      its closure every time the \y is called
 653         -- But: let f = \ab.BIG in \y. map (f y) xs
 654         --      Now we do want to substitute for f, even though it's not
 655         --      saturated, because we're going to allocate a closure for
 656         --      (f y) every time round the loop anyhow.
 657
 658         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
 659         -- so substituting rhs inside a lambda doesn't change the occ info.
 660         -- Sadly, not quite the same as exprIsHNF.
 661     canInlineInLam (Lit l)              = True
 662     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
 663     canInlineInLam (Note _ e)           = canInlineInLam e
 664     canInlineInLam _                    = False
 665
 666     early_phase = case phase of
 667                         SimplPhase 0 -> False
 668                         other        -> True
 669 -- If we don't have this early_phase test, consider
 670 --      x = length [1,2,3]
 671 -- The full laziness pass carefully floats all the cons cells to
 672 -- top level, and preInlineUnconditionally floats them all back in.
 673 -- Result is (a) static allocation replaced by dynamic allocation
 674 --           (b) many simplifier iterations because this tickles
 675 --               a related problem; only one inlining per pass
 676 --
 677 -- On the other hand, I have seen cases where top-level fusion is
 678 -- lost if we don't inline top level thing (e.g. string constants)
 679 -- Hence the test for phase zero (which is the phase for all the final
 680 -- simplifications).  Until phase zero we take no special notice of
 681 -- top level things, but then we become more leery about inlining
 682 -- them.
 683
 684 \end{code}
 685
 686 postInlineUnconditionally
 687 ~~~~~~~~~~~~~~~~~~~~~~~~~
 688 @postInlineUnconditionally@ decides whether to unconditionally inline
 689 a thing based on the form of its RHS; in particular if it has a
 690 trivial RHS.  If so, we can inline and discard the binding altogether.
 691
 692 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 693 only have *forward* references Hence, it's safe to discard the binding
 694
 695 NOTE: This isn't our last opportunity to inline.  We're at the binding
 696 site right now, and we'll get another opportunity when we get to the
 697 ocurrence(s)
 698
 699 Note that we do this unconditional inlining only for trival RHSs.
 700 Don't inline even WHNFs inside lambdas; doing so may simply increase
 701 allocation when the function is called. This isn't the last chance; see
 702 NOTE above.
 703
 704 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 705 Because we don't even want to inline them into the RHS of constructor
 706 arguments. See NOTE above
 707
 708 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 709 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 710 with both a and b marked NOINLINE.  But that seems incompatible with
 711 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 712 story for now.
 713
 714 \begin{code}
 715 postInlineUnconditionally
 716     :: SimplEnv -> TopLevelFlag
 717     -> InId             -- The binder (an OutId would be fine too)
 718     -> OccInfo          -- From the InId
 719     -> OutExpr
 720     -> Unfolding
 721     -> Bool
 722 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
 723   | not active             = False
 724   | isLoopBreaker occ_info = False      -- If it's a loop-breaker of any kind, dont' inline
 725                                         -- because it might be referred to "earlier"
 726   | isExportedId bndr      = False
 727   | exprIsTrivial rhs      = True
 728   | otherwise
 729   = case occ_info of
 730         -- The point of examining occ_info here is that for *non-values*
 731         -- that occur outside a lambda, the call-site inliner won't have
 732         -- a chance (becuase it doesn't know that the thing
 733         -- only occurs once).   The pre-inliner won't have gotten
 734         -- it either, if the thing occurs in more than one branch
 735         -- So the main target is things like
 736         --      let x = f y in
 737         --      case v of
 738         --         True  -> case x of ...
 739         --         False -> case x of ...
 740         -- I'm not sure how important this is in practice
 741       OneOcc in_lam one_br int_cxt      -- OneOcc => no work-duplication issue
 742         ->     smallEnoughToInline unfolding    -- Small enough to dup
 743                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
 744                         --
 745                         -- NB: Do NOT inline arbitrarily big things, even if one_br is True
 746                         -- Reason: doing so risks exponential behaviour.  We simplify a big
 747                         --         expression, inline it, and simplify it again.  But if the
 748                         --         very same thing happens in the big expression, we get
 749                         --         exponential cost!
 750                         -- PRINCIPLE: when we've already simplified an expression once,
 751                         -- make sure that we only inline it if it's reasonably small.
 752
 753            &&  ((isNotTopLevel top_lvl && not in_lam) ||
 754                         -- But outside a lambda, we want to be reasonably aggressive
 755                         -- about inlining into multiple branches of case
 756                         -- e.g. let x = <non-value>
 757                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... }
 758                         -- Inlining can be a big win if C3 is the hot-spot, even if
 759                         -- the uses in C1, C2 are not 'interesting'
 760                         -- An example that gets worse if you add int_cxt here is 'clausify'
 761
 762                 (isCheapUnfolding unfolding && int_cxt))
 763                         -- isCheap => acceptable work duplication; in_lam may be true
 764                         -- int_cxt to prevent us inlining inside a lambda without some
 765                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
 766
 767       IAmDead -> True   -- This happens; for example, the case_bndr during case of
 768                         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 769                         -- Here x isn't mentioned in the RHS, so we don't want to
 770                         -- create the (dead) let-binding  let x = (a,b) in ...
 771
 772       other -> False
 773
 774 -- Here's an example that we don't handle well:
 775 --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
 776 --      in \y. ....case f of {...} ....
 777 -- Here f is used just once, and duplicating the case work is fine (exprIsCheap).
 778 -- But
 779 -- * We can't preInlineUnconditionally because that woud invalidate
 780 --   the occ info for b.
 781 -- * We can't postInlineUnconditionally because the RHS is big, and
 782 --   that risks exponential behaviour
 783 -- * We can't call-site inline, because the rhs is big
 784 -- Alas!
 785
 786   where
 787     active = case getMode env of
 788                    SimplGently  -> isAlwaysActive prag
 789                    SimplPhase n -> isActive n prag
 790     prag = idInlinePragma bndr
 791
 792 activeInline :: SimplEnv -> OutId -> Bool
 793 activeInline env id
 794   = case getMode env of
 795       SimplGently -> False
 796         -- No inlining at all when doing gentle stuff,
 797         -- except for local things that occur once
 798         -- The reason is that too little clean-up happens if you
 799         -- don't inline use-once things.   Also a bit of inlining is *good* for
 800         -- full laziness; it can expose constant sub-expressions.
 801         -- Example in spectral/mandel/Mandel.hs, where the mandelset
 802         -- function gets a useful let-float if you inline windowToViewport
 803
 804         -- NB: we used to have a second exception, for data con wrappers.
 805         -- On the grounds that we use gentle mode for rule LHSs, and
 806         -- they match better when data con wrappers are inlined.
 807         -- But that only really applies to the trivial wrappers (like (:)),
 808         -- and they are now constructed as Compulsory unfoldings (in MkId)
 809         -- so they'll happen anyway.
 810
 811       SimplPhase n -> isActive n prag
 812   where
 813     prag = idInlinePragma id
 814
 815 activeRule :: SimplEnv -> Maybe (Activation -> Bool)
 816 -- Nothing => No rules at all
 817 activeRule env
 818   | opt_RulesOff = Nothing
 819   | otherwise
 820   = case getMode env of
 821         SimplGently  -> Just isAlwaysActive
 822                         -- Used to be Nothing (no rules in gentle mode)
 823                         -- Main motivation for changing is that I wanted
 824                         --      lift String ===> ...
 825                         -- to work in Template Haskell when simplifying
 826                         -- splices, so we get simpler code for literal strings
 827         SimplPhase n -> Just (isActive n)
 828 \end{code}
 829
 830
 831 %************************************************************************
 832 %*                                                                      *
 833 \subsection{Rebuilding a lambda}
 834 %*                                                                      *
 835 %************************************************************************
 836
 837 \begin{code}
 838 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
 839 \end{code}
 840
 841 Try three things
 842         a) eta reduction, if that gives a trivial expression
 843         b) eta expansion [only if there are some value lambdas]
 844         c) floating lets out through big lambdas
 845                 [only if all tyvar lambdas, and only if this lambda
 846                  is the RHS of a let]
 847
 848 \begin{code}
 849 mkLam env bndrs body cont
 850  = getDOptsSmpl  `thenSmpl` \dflags ->
 851    mkLam' dflags env bndrs body cont
 852  where
 853  mkLam' dflags env bndrs body cont
 854    | dopt Opt_DoEtaReduction dflags,
 855      Just etad_lam <- tryEtaReduce bndrs body
 856    = tick (EtaReduction (head bndrs))   `thenSmpl_`
 857      returnSmpl (emptyFloats env, etad_lam)
 858
 859    | dopt Opt_DoLambdaEtaExpansion dflags,
 860      any isRuntimeVar bndrs
 861    = tryEtaExpansion dflags body        `thenSmpl` \ body' ->
 862      returnSmpl (emptyFloats env, mkLams bndrs body')
 863
 864 {-      Sept 01: I'm experimenting with getting the
 865         full laziness pass to float out past big lambdsa
 866  | all isTyVar bndrs,   -- Only for big lambdas
 867    contIsRhs cont       -- Only try the rhs type-lambda floating
 868                         -- if this is indeed a right-hand side; otherwise
 869                         -- we end up floating the thing out, only for float-in
 870                         -- to float it right back in again!
 871  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 872    returnSmpl (floats, mkLams bndrs body')
 873 -}
 874
 875    | otherwise
 876    = returnSmpl (emptyFloats env, mkLams bndrs body)
 877 \end{code}
 878
 879
 880 %************************************************************************
 881 %*                                                                      *
 882 \subsection{Eta expansion and reduction}
 883 %*                                                                      *
 884 %************************************************************************
 885
 886 We try for eta reduction here, but *only* if we get all the
 887 way to an exprIsTrivial expression.
 888 We don't want to remove extra lambdas unless we are going
 889 to avoid allocating this thing altogether
 890
 891 \begin{code}
 892 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
 893 tryEtaReduce bndrs body
 894         -- We don't use CoreUtils.etaReduce, because we can be more
 895         -- efficient here:
 896         --  (a) we already have the binders
 897         --  (b) we can do the triviality test before computing the free vars
 898   = go (reverse bndrs) body
 899   where
 900     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 901     go []       fun           | ok_fun fun   = Just fun         -- Success!
 902     go _        _                            = Nothing          -- Failure!
 903
 904     ok_fun fun =  exprIsTrivial fun
 905                && not (any (`elemVarSet` (exprFreeVars fun)) bndrs)
 906                && (exprIsHNF fun || all ok_lam bndrs)
 907     ok_lam v = isTyVar v || isDictId v
 908         -- The exprIsHNF is because eta reduction is not
 909         -- valid in general:  \x. bot  /=  bot
 910         -- So we need to be sure that the "fun" is a value.
 911         --
 912         -- However, we always want to reduce (/\a -> f a) to f
 913         -- This came up in a RULE: foldr (build (/\a -> g a))
 914         --      did not match      foldr (build (/\b -> ...something complex...))
 915         -- The type checker can insert these eta-expanded versions,
 916         -- with both type and dictionary lambdas; hence the slightly
 917         -- ad-hoc isDictTy
 918
 919     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 920 \end{code}
 921
 922
 923         Try eta expansion for RHSs
 924
 925 We go for:
 926    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 927                                  (n >= 0)
 928
 929 where (in both cases)
 930
 931         * The xi can include type variables
 932
 933         * The yi are all value variables
 934
 935         * N is a NORMAL FORM (i.e. no redexes anywhere)
 936           wanting a suitable number of extra args.
 937
 938 We may have to sandwich some coerces between the lambdas
 939 to make the types work.   exprEtaExpandArity looks through coerces
 940 when computing arity; and etaExpand adds the coerces as necessary when
 941 actually computing the expansion.
 942
 943 \begin{code}
 944 tryEtaExpansion :: DynFlags -> OutExpr -> SimplM OutExpr
 945 -- There is at least one runtime binder in the binders
 946 tryEtaExpansion dflags body
 947   = getUniquesSmpl                      `thenSmpl` \ us ->
 948     returnSmpl (etaExpand fun_arity us body (exprType body))
 949   where
 950     fun_arity = exprEtaExpandArity dflags body
 951 \end{code}
 952
 953
 954 %************************************************************************
 955 %*                                                                      *
 956 \subsection{Floating lets out of big lambdas}
 957 %*                                                                      *
 958 %************************************************************************
 959
 960 tryRhsTyLam tries this transformation, when the big lambda appears as
 961 the RHS of a let(rec) binding:
 962
 963         /\abc -> let(rec) x = e in b
 964    ==>
 965         let(rec) x' = /\abc -> let x = x' a b c in e
 966         in
 967         /\abc -> let x = x' a b c in b
 968
 969 This is good because it can turn things like:
 970
 971         let f = /\a -> letrec g = ... g ... in g
 972 into
 973         letrec g' = /\a -> ... g' a ...
 974         in
 975         let f = /\ a -> g' a
 976
 977 which is better.  In effect, it means that big lambdas don't impede
 978 let-floating.
 979
 980 This optimisation is CRUCIAL in eliminating the junk introduced by
 981 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 982
 983 So far as the implementation is concerned:
 984
 985         Invariant: go F e = /\tvs -> F e
 986
 987         Equalities:
 988                 go F (Let x=e in b)
 989                 = Let x' = /\tvs -> F e
 990                   in
 991                   go G b
 992                 where
 993                     G = F . Let x = x' tvs
 994
 995                 go F (Letrec xi=ei in b)
 996                 = Letrec {xi' = /\tvs -> G ei}
 997                   in
 998                   go G b
 999                 where
1000                   G = F . Let {xi = xi' tvs}
1001
1002 [May 1999]  If we do this transformation *regardless* then we can
1003 end up with some pretty silly stuff.  For example,
1004
1005         let
1006             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
1007         in ..
1008 becomes
1009         let y1 = /\s -> r1
1010             y2 = /\s -> r2
1011             st = /\s -> ...[y1 s/x1, y2 s/x2]
1012         in ..
1013
1014 Unless the "..." is a WHNF there is really no point in doing this.
1015 Indeed it can make things worse.  Suppose x1 is used strictly,
1016 and is of the form
1017
1018         x1* = case f y of { (a,b) -> e }
1019
1020 If we abstract this wrt the tyvar we then can't do the case inline
1021 as we would normally do.
1022
1023
1024 \begin{code}
1025 {-      Trying to do this in full laziness
1026
1027 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
1028 -- Call ensures that all the binders are type variables
1029
1030 tryRhsTyLam env tyvars body             -- Only does something if there's a let
1031   |  not (all isTyVar tyvars)
1032   || not (worth_it body)                -- inside a type lambda,
1033   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
1034
1035   | otherwise
1036   = go env (\x -> x) body
1037
1038   where
1039     worth_it e@(Let _ _) = whnf_in_middle e
1040     worth_it e           = False
1041
1042     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
1043     whnf_in_middle (Let _ e) = whnf_in_middle e
1044     whnf_in_middle e         = exprIsCheap e
1045
1046     main_tyvar_set = mkVarSet tyvars
1047
1048     go env fn (Let bind@(NonRec var rhs) body)
1049       | exprIsTrivial rhs
1050       = go env (fn . Let bind) body
1051
1052     go env fn (Let (NonRec var rhs) body)
1053       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
1054         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env ->
1055         go env (fn . Let (mk_silly_bind var rhs')) body
1056
1057       where
1058
1059         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
1060                 -- Abstract only over the type variables free in the rhs
1061                 -- wrt which the new binding is abstracted.  But the naive
1062                 -- approach of abstract wrt the tyvars free in the Id's type
1063                 -- fails. Consider:
1064                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1065                 --                    x :: a     = fst t
1066                 --                in ...
1067                 -- Here, b isn't free in x's type, but we must nevertheless
1068                 -- abstract wrt b as well, because t's type mentions b.
1069                 -- Since t is floated too, we'd end up with the bogus:
1070                 --      poly_t = /\ a b -> (e1, e2)
1071                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1072                 -- So for now we adopt the even more naive approach of
1073                 -- abstracting wrt *all* the tyvars.  We'll see if that
1074                 -- gives rise to problems.   SLPJ June 98
1075
1076     go env fn (Let (Rec prs) body)
1077        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
1078          let
1079             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
1080             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
1081          in
1082          addAuxiliaryBind env (Rec pairs)               $ \ env ->
1083          go env gn body
1084        where
1085          (vars,rhss) = unzip prs
1086          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
1087                 -- See notes with tyvars_here above
1088
1089     go env fn body = returnSmpl (emptyFloats env, fn body)
1090
1091     mk_poly tyvars_here var
1092       = getUniqueSmpl           `thenSmpl` \ uniq ->
1093         let
1094             poly_name = setNameUnique (idName var) uniq         -- Keep same name
1095             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
1096             poly_id   = mkLocalId poly_name poly_ty
1097
1098                 -- In the olden days, it was crucial to copy the occInfo of the original var,
1099                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1100                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1101                 -- at already simplified code, so it doesn't matter
1102                 --
1103                 -- It's even right to retain single-occurrence or dead-var info:
1104                 -- Suppose we started with  /\a -> let x = E in B
1105                 -- where x occurs once in B. Then we transform to:
1106                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1107                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1108                 -- the occurrences of x' will be just the occurrences originally
1109                 -- pinned on x.
1110         in
1111         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
1112
1113     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
1114                 -- Suppose we start with:
1115                 --
1116                 --      x = /\ a -> let g = G in E
1117                 --
1118                 -- Then we'll float to get
1119                 --
1120                 --      x = let poly_g = /\ a -> G
1121                 --          in /\ a -> let g = poly_g a in E
1122                 --
1123                 -- But now the occurrence analyser will see just one occurrence
1124                 -- of poly_g, not inside a lambda, so the simplifier will
1125                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1126                 -- (I used to think that the "don't inline lone occurrences" stuff
1127                 --  would stop this happening, but since it's the *only* occurrence,
1128                 --  PreInlineUnconditionally kicks in first!)
1129                 --
1130                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1131                 --           to appear many times.  (NB: mkInlineMe eliminates
1132                 --           such notes on trivial RHSs, so do it manually.)
1133 -}
1134 \end{code}
1135
1136 %************************************************************************
1137 %*                                                                      *
1138 \subsection{Case absorption and identity-case elimination}
1139 %*                                                                      *
1140 %************************************************************************
1141
1142
1143 mkCase puts a case expression back together, trying various transformations first.
1144
1145 \begin{code}
1146 mkCase :: OutExpr -> OutId -> OutType
1147        -> [OutAlt]              -- Increasing order
1148        -> SimplM OutExpr
1149
1150 mkCase scrut case_bndr ty alts
1151   = getDOptsSmpl                        `thenSmpl` \dflags ->
1152     mkAlts dflags scrut case_bndr alts  `thenSmpl` \ better_alts ->
1153     mkCase1 scrut case_bndr ty better_alts
1154 \end{code}
1155
1156
1157 mkAlts tries these things:
1158
1159 1.  If several alternatives are identical, merge them into
1160     a single DEFAULT alternative.  I've occasionally seen this
1161     making a big difference:
1162
1163         case e of               =====>     case e of
1164           C _ -> f x                         D v -> ....v....
1165           D v -> ....v....                   DEFAULT -> f x
1166           DEFAULT -> f x
1167
1168    The point is that we merge common RHSs, at least for the DEFAULT case.
1169    [One could do something more elaborate but I've never seen it needed.]
1170    To avoid an expensive test, we just merge branches equal to the *first*
1171    alternative; this picks up the common cases
1172         a) all branches equal
1173         b) some branches equal to the DEFAULT (which occurs first)
1174
1175 2.  Case merging:
1176        case e of b {             ==>   case e of b {
1177          p1 -> rhs1                      p1 -> rhs1
1178          ...                             ...
1179          pm -> rhsm                      pm -> rhsm
1180          _  -> case b of b' {            pn -> let b'=b in rhsn
1181                      pn -> rhsn          ...
1182                      ...                 po -> let b'=b in rhso
1183                      po -> rhso          _  -> let b'=b in rhsd
1184                      _  -> rhsd
1185        }
1186
1187     which merges two cases in one case when -- the default alternative of
1188     the outer case scrutises the same variable as the outer case This
1189     transformation is called Case Merging.  It avoids that the same
1190     variable is scrutinised multiple times.
1191
1192
1193 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1194
1195         x | p `is` 1 -> e1
1196           | p `is` 2 -> e2
1197         ...etc...
1198
1199 where @is@ was something like
1200
1201         p `is` n = p /= (-1) && p == n
1202
1203 This gave rise to a horrible sequence of cases
1204
1205         case p of
1206           (-1) -> $j p
1207           1    -> e1
1208           DEFAULT -> $j p
1209
1210 and similarly in cascade for all the join points!
1211
1212
1213
1214 \begin{code}
1215 --------------------------------------------------
1216 --      1. Merge identical branches
1217 --------------------------------------------------
1218 mkAlts dflags scrut case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1219   | all isDeadBinder bndrs1,                    -- Remember the default
1220     length filtered_alts < length con_alts      -- alternative comes first
1221   = tick (AltMerge case_bndr)                   `thenSmpl_`
1222     returnSmpl better_alts
1223   where
1224     filtered_alts        = filter keep con_alts
1225     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1226     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
1227
1228
1229 --------------------------------------------------
1230 --      2.  Merge nested cases
1231 --------------------------------------------------
1232
1233 mkAlts dflags scrut outer_bndr outer_alts
1234   | dopt Opt_CaseMerge dflags,
1235     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
1236     Just (Case (Var scrut_var) inner_bndr _ inner_alts) <- maybe_outer_deflt,
1237     scruting_same_var scrut_var
1238   = let
1239         munged_inner_alts = [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts]
1240         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1241
1242         new_alts = mergeAlts outer_alts_without_deflt munged_inner_alts
1243                 -- The merge keeps the inner DEFAULT at the front, if there is one
1244                 -- and eliminates any inner_alts that are shadowed by the outer_alts
1245     in
1246     tick (CaseMerge outer_bndr)                         `thenSmpl_`
1247     returnSmpl new_alts
1248         -- Warning: don't call mkAlts recursively!
1249         -- Firstly, there's no point, because inner alts have already had
1250         -- mkCase applied to them, so they won't have a case in their default
1251         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1252         -- in munge_rhs may put a case into the DEFAULT branch!
1253   where
1254         -- We are scrutinising the same variable if it's
1255         -- the outer case-binder, or if the outer case scrutinises a variable
1256         -- (and it's the same).  Testing both allows us not to replace the
1257         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
1258     scruting_same_var = case scrut of
1259                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
1260                           other           -> \ v -> v == outer_bndr
1261
1262 ------------------------------------------------
1263 --      Catch-all
1264 ------------------------------------------------
1265
1266 mkAlts dflags scrut case_bndr other_alts = returnSmpl other_alts
1267 \end{code}
1268
1269
1270
1271 =================================================================================
1272
1273 mkCase1 tries these things
1274
1275 1.  Eliminate the case altogether if possible
1276
1277 2.  Case-identity:
1278
1279         case e of               ===> e
1280                 True  -> True;
1281                 False -> False
1282
1283     and similar friends.
1284
1285
1286 Start with a simple situation:
1287
1288         case x# of      ===>   e[x#/y#]
1289           y# -> e
1290
1291 (when x#, y# are of primitive type, of course).  We can't (in general)
1292 do this for algebraic cases, because we might turn bottom into
1293 non-bottom!
1294
1295 Actually, we generalise this idea to look for a case where we're
1296 scrutinising a variable, and we know that only the default case can
1297 match.  For example:
1298 \begin{verbatim}
1299         case x of
1300           0#    -> ...
1301           other -> ...(case x of
1302                          0#    -> ...
1303                          other -> ...) ...
1304 \end{code}
1305 Here the inner case can be eliminated.  This really only shows up in
1306 eliminating error-checking code.
1307
1308 We also make sure that we deal with this very common case:
1309
1310         case e of
1311           x -> ...x...
1312
1313 Here we are using the case as a strict let; if x is used only once
1314 then we want to inline it.  We have to be careful that this doesn't
1315 make the program terminate when it would have diverged before, so we
1316 check that
1317         - x is used strictly, or
1318         - e is already evaluated (it may so if e is a variable)
1319
1320 Lastly, we generalise the transformation to handle this:
1321
1322         case e of       ===> r
1323            True  -> r
1324            False -> r
1325
1326 We only do this for very cheaply compared r's (constructors, literals
1327 and variables).  If pedantic bottoms is on, we only do it when the
1328 scrutinee is a PrimOp which can't fail.
1329
1330 We do it *here*, looking at un-simplified alternatives, because we
1331 have to check that r doesn't mention the variables bound by the
1332 pattern in each alternative, so the binder-info is rather useful.
1333
1334 So the case-elimination algorithm is:
1335
1336         1. Eliminate alternatives which can't match
1337
1338         2. Check whether all the remaining alternatives
1339                 (a) do not mention in their rhs any of the variables bound in their pattern
1340            and  (b) have equal rhss
1341
1342         3. Check we can safely ditch the case:
1343                    * PedanticBottoms is off,
1344                 or * the scrutinee is an already-evaluated variable
1345                 or * the scrutinee is a primop which is ok for speculation
1346                         -- ie we want to preserve divide-by-zero errors, and
1347                         -- calls to error itself!
1348
1349                 or * [Prim cases] the scrutinee is a primitive variable
1350
1351                 or * [Alg cases] the scrutinee is a variable and
1352                      either * the rhs is the same variable
1353                         (eg case x of C a b -> x  ===>   x)
1354                      or     * there is only one alternative, the default alternative,
1355                                 and the binder is used strictly in its scope.
1356                                 [NB this is helped by the "use default binder where
1357                                  possible" transformation; see below.]
1358
1359
1360 If so, then we can replace the case with one of the rhss.
1361
1362 Further notes about case elimination
1363 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1364 Consider:       test :: Integer -> IO ()
1365                 test = print
1366
1367 Turns out that this compiles to:
1368     Print.test
1369       = \ eta :: Integer
1370           eta1 :: State# RealWorld ->
1371           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1372           case hPutStr stdout
1373                  (PrelNum.jtos eta ($w[] @ Char))
1374                  eta1
1375           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1376
1377 Notice the strange '<' which has no effect at all. This is a funny one.
1378 It started like this:
1379
1380 f x y = if x < 0 then jtos x
1381           else if y==0 then "" else jtos x
1382
1383 At a particular call site we have (f v 1).  So we inline to get
1384
1385         if v < 0 then jtos x
1386         else if 1==0 then "" else jtos x
1387
1388 Now simplify the 1==0 conditional:
1389
1390         if v<0 then jtos v else jtos v
1391
1392 Now common-up the two branches of the case:
1393
1394         case (v<0) of DEFAULT -> jtos v
1395
1396 Why don't we drop the case?  Because it's strict in v.  It's technically
1397 wrong to drop even unnecessary evaluations, and in practice they
1398 may be a result of 'seq' so we *definitely* don't want to drop those.
1399 I don't really know how to improve this situation.
1400
1401
1402 \begin{code}
1403 --------------------------------------------------
1404 --      0. Check for empty alternatives
1405 --------------------------------------------------
1406
1407 -- This isn't strictly an error.  It's possible that the simplifer might "see"
1408 -- that an inner case has no accessible alternatives before it "sees" that the
1409 -- entire branch of an outer case is inaccessible.  So we simply
1410 -- put an error case here insteadd
1411 mkCase1 scrut case_bndr ty []
1412   = pprTrace "mkCase1: null alts" (ppr case_bndr <+> ppr scrut) $
1413     return (mkApps (Var eRROR_ID)
1414                    [Type ty, Lit (mkStringLit "Impossible alternative")])
1415
1416 --------------------------------------------------
1417 --      1. Eliminate the case altogether if poss
1418 --------------------------------------------------
1419
1420 mkCase1 scrut case_bndr ty [(con,bndrs,rhs)]
1421   -- See if we can get rid of the case altogether
1422   -- See the extensive notes on case-elimination above
1423   -- mkCase made sure that if all the alternatives are equal,
1424   -- then there is now only one (DEFAULT) rhs
1425  |  all isDeadBinder bndrs,
1426
1427         -- Check that the scrutinee can be let-bound instead of case-bound
1428     exprOkForSpeculation scrut
1429                 -- OK not to evaluate it
1430                 -- This includes things like (==# a# b#)::Bool
1431                 -- so that we simplify
1432                 --      case ==# a# b# of { True -> x; False -> x }
1433                 -- to just
1434                 --      x
1435                 -- This particular example shows up in default methods for
1436                 -- comparision operations (e.g. in (>=) for Int.Int32)
1437         || exprIsHNF scrut                      -- It's already evaluated
1438         || var_demanded_later scrut             -- It'll be demanded later
1439
1440 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1441 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1442 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1443 --      its argument:  case x of { y -> dataToTag# y }
1444 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1445 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1446 --      other problems
1447 --      Also we don't want to discard 'seq's
1448   = tick (CaseElim case_bndr)                   `thenSmpl_`
1449     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1450
1451   where
1452         -- The case binder is going to be evaluated later,
1453         -- and the scrutinee is a simple variable
1454     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1455     var_demanded_later other   = False
1456
1457
1458 --------------------------------------------------
1459 --      2. Identity case
1460 --------------------------------------------------
1461
1462 mkCase1 scrut case_bndr ty alts -- Identity case
1463   | all identity_alt alts
1464   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1465     returnSmpl (re_cast scrut)
1466   where
1467     identity_alt (con, args, rhs) = de_cast rhs `cheapEqExpr` mk_id_rhs con args
1468
1469     mk_id_rhs (DataAlt con) args = mkConApp con (arg_tys ++ varsToCoreExprs args)
1470     mk_id_rhs (LitAlt lit)  _    = Lit lit
1471     mk_id_rhs DEFAULT       _    = Var case_bndr
1472
1473     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1474
1475         -- We've seen this:
1476         --      case e of x { _ -> x `cast` c }
1477         -- And we definitely want to eliminate this case, to give
1478         --      e `cast` c
1479         -- So we throw away the cast from the RHS, and reconstruct
1480         -- it at the other end.  All the RHS casts must be the same
1481         -- if (all identity_alt alts) holds.
1482         --
1483         -- Don't worry about nested casts, because the simplifier combines them
1484     de_cast (Cast e _) = e
1485     de_cast e          = e
1486
1487     re_cast scrut = case head alts of
1488                         (_,_,Cast _ co) -> Cast scrut co
1489                         other           -> scrut
1490
1491
1492
1493 --------------------------------------------------
1494 --      Catch-all
1495 --------------------------------------------------
1496 mkCase1 scrut bndr ty alts = returnSmpl (Case scrut bndr ty alts)
1497 \end{code}
1498
1499
1500 When adding auxiliary bindings for the case binder, it's worth checking if
1501 its dead, because it often is, and occasionally these mkCase transformations
1502 cascade rather nicely.
1503
1504 \begin{code}
1505 bindCaseBndr bndr rhs body
1506   | isDeadBinder bndr = body
1507   | otherwise         = bindNonRec bndr rhs body
1508 \end{code}