compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplEnv
  16 import SimplUtils       ( mkCase, mkLam,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkRhsStop, mkBoringStop,  mkLazyArgStop, pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType,
  21                           preInlineUnconditionally, postInlineUnconditionally,
  22                           interestingArgContext, inlineMode, activeInline, activeRule
  23                         )
  24 import Id               ( Id, idType, idInfo, idArity, isDataConWorkId,
  25                           idUnfolding, setIdUnfolding, isDeadBinder,
  26                           idNewDemandInfo, setIdInfo,
  27                           setIdOccInfo, zapLamIdInfo, setOneShotLambda
  28                         )
  29 import MkId             ( eRROR_ID )
  30 import Literal          ( mkStringLit )
  31 import IdInfo           ( OccInfo(..), isLoopBreaker,
  32                           setArityInfo, zapDemandInfo,
  33                           setUnfoldingInfo,
  34                           occInfo
  35                         )
  36 import NewDemand        ( isStrictDmd )
  37 import Unify            ( coreRefineTys, dataConCanMatch )
  38 import DataCon          ( DataCon, dataConTyCon, dataConRepStrictness, isVanillaDataCon,
  39                           dataConInstArgTys, dataConTyVars )
  40 import TyCon            ( tyConArity, isAlgTyCon, isNewTyCon, tyConDataCons_maybe )
  41 import CoreSyn
  42 import PprCore          ( pprParendExpr, pprCoreExpr )
  43 import CoreUnfold       ( mkUnfolding, callSiteInline )
  44 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  45                           exprIsConApp_maybe, mkPiTypes, findAlt,
  46                           exprType, exprIsHNF, findDefault, mergeAlts,
  47                           exprOkForSpeculation, exprArity,
  48                           mkCoerce, mkCoerce2, mkSCC, mkInlineMe, applyTypeToArg
  49                         )
  50 import Rules            ( lookupRule )
  51 import BasicTypes       ( isMarkedStrict )
  52 import CostCentre       ( currentCCS )
  53 import Type             ( TvSubstEnv, isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  54                           splitFunTy_maybe, splitFunTy, coreEqType, splitTyConApp_maybe,
  55                           isTyVarTy, mkTyVarTys
  56                         )
  57 import Var              ( tyVarKind, mkTyVar )
  58 import VarEnv           ( elemVarEnv, emptyVarEnv )
  59 import TysPrim          ( realWorldStatePrimTy )
  60 import PrelInfo         ( realWorldPrimId )
  61 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  62                           RecFlag(..), isNonRec
  63                         )
  64 import Name             ( mkSysTvName )
  65 import StaticFlags      ( opt_PprStyle_Debug )
  66 import OrdList
  67 import List             ( nub )
  68 import Maybes           ( orElse )
  69 import Outputable
  70 import Util             ( notNull, filterOut )
  71 \end{code}
  72
  73
  74 The guts of the simplifier is in this module, but the driver loop for
  75 the simplifier is in SimplCore.lhs.
  76
  77
  78 -----------------------------------------
  79         *** IMPORTANT NOTE ***
  80 -----------------------------------------
  81 The simplifier used to guarantee that the output had no shadowing, but
  82 it does not do so any more.   (Actually, it never did!)  The reason is
  83 documented with simplifyArgs.
  84
  85
  86 -----------------------------------------
  87         *** IMPORTANT NOTE ***
  88 -----------------------------------------
  89 Many parts of the simplifier return a bunch of "floats" as well as an
  90 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  91
  92 All "floats" are let-binds, not case-binds, but some non-rec lets may
  93 be unlifted (with RHS ok-for-speculation).
  94
  95
  96
  97 -----------------------------------------
  98         ORGANISATION OF FUNCTIONS
  99 -----------------------------------------
 100 simplTopBinds
 101   - simplify all top-level binders
 102   - for NonRec, call simplRecOrTopPair
 103   - for Rec,    call simplRecBind
 104
 105
 106         ------------------------------
 107 simplExpr (applied lambda)      ==> simplNonRecBind
 108 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 109 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 110
 111         ------------------------------
 112 simplRecBind    [binders already simplfied]
 113   - use simplRecOrTopPair on each pair in turn
 114
 115 simplRecOrTopPair [binder already simplified]
 116   Used for: recursive bindings (top level and nested)
 117             top-level non-recursive bindings
 118   Returns:
 119   - check for PreInlineUnconditionally
 120   - simplLazyBind
 121
 122 simplNonRecBind
 123   Used for: non-top-level non-recursive bindings
 124             beta reductions (which amount to the same thing)
 125   Because it can deal with strict arts, it takes a
 126         "thing-inside" and returns an expression
 127
 128   - check for PreInlineUnconditionally
 129   - simplify binder, including its IdInfo
 130   - if strict binding
 131         simplStrictArg
 132         mkAtomicArgs
 133         completeNonRecX
 134     else
 135         simplLazyBind
 136         addFloats
 137
 138 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 139   Used for: binding case-binder and constr args in a known-constructor case
 140   - check for PreInLineUnconditionally
 141   - simplify binder
 142   - completeNonRecX
 143
 144         ------------------------------
 145 simplLazyBind:  [binder already simplified, RHS not]
 146   Used for: recursive bindings (top level and nested)
 147             top-level non-recursive bindings
 148             non-top-level, but *lazy* non-recursive bindings
 149         [must not be strict or unboxed]
 150   Returns floats + an augmented environment, not an expression
 151   - substituteIdInfo and add result to in-scope
 152         [so that rules are available in rec rhs]
 153   - simplify rhs
 154   - mkAtomicArgs
 155   - float if exposes constructor or PAP
 156   - completeLazyBind
 157
 158
 159 completeNonRecX:        [binder and rhs both simplified]
 160   - if the the thing needs case binding (unlifted and not ok-for-spec)
 161         build a Case
 162    else
 163         completeLazyBind
 164         addFloats
 165
 166 completeLazyBind:       [given a simplified RHS]
 167         [used for both rec and non-rec bindings, top level and not]
 168   - try PostInlineUnconditionally
 169   - add unfolding [this is the only place we add an unfolding]
 170   - add arity
 171
 172
 173
 174 Right hand sides and arguments
 175 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 176 In many ways we want to treat
 177         (a) the right hand side of a let(rec), and
 178         (b) a function argument
 179 in the same way.  But not always!  In particular, we would
 180 like to leave these arguments exactly as they are, so they
 181 will match a RULE more easily.
 182
 183         f (g x, h x)
 184         g (+ x)
 185
 186 It's harder to make the rule match if we ANF-ise the constructor,
 187 or eta-expand the PAP:
 188
 189         f (let { a = g x; b = h x } in (a,b))
 190         g (\y. + x y)
 191
 192 On the other hand if we see the let-defns
 193
 194         p = (g x, h x)
 195         q = + x
 196
 197 then we *do* want to ANF-ise and eta-expand, so that p and q
 198 can be safely inlined.
 199
 200 Even floating lets out is a bit dubious.  For let RHS's we float lets
 201 out if that exposes a value, so that the value can be inlined more vigorously.
 202 For example
 203
 204         r = let x = e in (x,x)
 205
 206 Here, if we float the let out we'll expose a nice constructor. We did experiments
 207 that showed this to be a generally good thing.  But it was a bad thing to float
 208 lets out unconditionally, because that meant they got allocated more often.
 209
 210 For function arguments, there's less reason to expose a constructor (it won't
 211 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 212 So for the moment we don't float lets out of function arguments either.
 213
 214
 215 Eta expansion
 216 ~~~~~~~~~~~~~~
 217 For eta expansion, we want to catch things like
 218
 219         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 220
 221 If the \x was on the RHS of a let, we'd eta expand to bring the two
 222 lambdas together.  And in general that's a good thing to do.  Perhaps
 223 we should eta expand wherever we find a (value) lambda?  Then the eta
 224 expansion at a let RHS can concentrate solely on the PAP case.
 225
 226
 227 %************************************************************************
 228 %*                                                                      *
 229 \subsection{Bindings}
 230 %*                                                                      *
 231 %************************************************************************
 232
 233 \begin{code}
 234 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 235
 236 simplTopBinds env binds
 237   =     -- Put all the top-level binders into scope at the start
 238         -- so that if a transformation rule has unexpectedly brought
 239         -- anything into scope, then we don't get a complaint about that.
 240         -- It's rather as if the top-level binders were imported.
 241     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 242     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 243     freeTick SimplifierDone                     `thenSmpl_`
 244     returnSmpl (floatBinds floats)
 245   where
 246         -- We need to track the zapped top-level binders, because
 247         -- they should have their fragile IdInfo zapped (notably occurrence info)
 248         -- That's why we run down binds and bndrs' simultaneously.
 249     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 250     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 251     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 252                                       addFloats env floats              $ \env ->
 253                                       simpl_binds env binds (drop_bs bind bs)
 254
 255     drop_bs (NonRec _ _) (_ : bs) = bs
 256     drop_bs (Rec prs)    bs       = drop (length prs) bs
 257
 258     simpl_bind env bind bs
 259       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 260         if dopt Opt_D_dump_inlinings dflags then
 261            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 262         else
 263            simpl_bind1 env bind bs
 264
 265     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 266     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 267 \end{code}
 268
 269
 270 %************************************************************************
 271 %*                                                                      *
 272 \subsection{simplNonRec}
 273 %*                                                                      *
 274 %************************************************************************
 275
 276 simplNonRecBind is used for
 277   * non-top-level non-recursive lets in expressions
 278   * beta reduction
 279
 280 It takes
 281   * An unsimplified (binder, rhs) pair
 282   * The env for the RHS.  It may not be the same as the
 283         current env because the bind might occur via (\x.E) arg
 284
 285 It uses the CPS form because the binding might be strict, in which
 286 case we might discard the continuation:
 287         let x* = error "foo" in (...x...)
 288
 289 It needs to turn unlifted bindings into a @case@.  They can arise
 290 from, say:      (\x -> e) (4# + 3#)
 291
 292 \begin{code}
 293 simplNonRecBind :: SimplEnv
 294                 -> InId                                 -- Binder
 295                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 296                 -> OutType                              -- Type of thing computed by the context
 297                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 298                 -> SimplM FloatsWithExpr
 299 #ifdef DEBUG
 300 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 301   | isTyVar bndr
 302   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 303 #endif
 304
 305 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 306   = simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 307
 308 simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 309   | preInlineUnconditionally env NotTopLevel bndr rhs
 310   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 311     thing_inside (extendIdSubst env bndr (mkContEx rhs_se rhs))
 312
 313   | isStrictDmd (idNewDemandInfo bndr) || isStrictType bndr_ty  -- A strict let
 314   =     -- Don't use simplBinder because that doesn't keep
 315         -- fragile occurrence info in the substitution
 316     simplNonRecBndr env bndr                                    `thenSmpl` \ (env, bndr1) ->
 317     simplStrictArg AnRhs env rhs rhs_se (idType bndr1) cont_ty  $ \ env1 rhs1 ->
 318
 319         -- Now complete the binding and simplify the body
 320     let
 321         (env2,bndr2) = addLetIdInfo env1 bndr bndr1
 322     in
 323     if needsCaseBinding bndr_ty rhs1
 324     then
 325       thing_inside env2                                 `thenSmpl` \ (floats, body) ->
 326       returnSmpl (emptyFloats env2, Case rhs1 bndr2 (exprType body)
 327                                         [(DEFAULT, [], wrapFloats floats body)])
 328     else
 329       completeNonRecX env2 True {- strict -} bndr bndr2 rhs1 thing_inside
 330
 331   | otherwise                                                   -- Normal, lazy case
 332   =     -- Don't use simplBinder because that doesn't keep
 333         -- fragile occurrence info in the substitution
 334     simplNonRecBndr env bndr                            `thenSmpl` \ (env, bndr') ->
 335     simplLazyBind env NotTopLevel NonRecursive
 336                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 337     addFloats env floats thing_inside
 338
 339   where
 340     bndr_ty = idType bndr
 341 \end{code}
 342
 343 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 344 in knownCon.  It uses case-binding where necessary.
 345
 346 \begin{code}
 347 simplNonRecX :: SimplEnv
 348              -> InId            -- Old binder
 349              -> OutExpr         -- Simplified RHS
 350              -> (SimplEnv -> SimplM FloatsWithExpr)
 351              -> SimplM FloatsWithExpr
 352
 353 simplNonRecX env bndr new_rhs thing_inside
 354   | needsCaseBinding (idType bndr) new_rhs
 355         -- Make this test *before* the preInlineUnconditionally
 356         -- Consider     case I# (quotInt# x y) of
 357         --                I# v -> let w = J# v in ...
 358         -- If we gaily inline (quotInt# x y) for v, we end up building an
 359         -- extra thunk:
 360         --                let w = J# (quotInt# x y) in ...
 361         -- because quotInt# can fail.
 362   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 363     thing_inside env            `thenSmpl` \ (floats, body) ->
 364     let body' = wrapFloats floats body in
 365     returnSmpl (emptyFloats env, Case new_rhs bndr' (exprType body') [(DEFAULT, [], body')])
 366
 367 {- No, no, no!  Do not try preInlineUnconditionally
 368    Doing so risks exponential behaviour, because new_rhs has been simplified once already
 369    In the cases described by the folowing commment, postInlineUnconditionally will
 370    catch many of the relevant cases.
 371         -- This happens; for example, the case_bndr during case of
 372         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 373         -- Here x isn't mentioned in the RHS, so we don't want to
 374         -- create the (dead) let-binding  let x = (a,b) in ...
 375         --
 376         -- Similarly, single occurrences can be inlined vigourously
 377         -- e.g.  case (f x, g y) of (a,b) -> ....
 378         -- If a,b occur once we can avoid constructing the let binding for them.
 379   | preInlineUnconditionally env NotTopLevel bndr new_rhs
 380   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
 381 -}
 382
 383   | otherwise
 384   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 385     completeNonRecX env False {- Non-strict; pessimistic -}
 386                     bndr bndr' new_rhs thing_inside
 387
 388 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 389   = mkAtomicArgs is_strict
 390                  True {- OK to float unlifted -}
 391                  new_rhs                        `thenSmpl` \ (aux_binds, rhs2) ->
 392
 393         -- Make the arguments atomic if necessary,
 394         -- adding suitable bindings
 395     addAtomicBindsE env (fromOL aux_binds)      $ \ env ->
 396     completeLazyBind env NotTopLevel
 397                      old_bndr new_bndr rhs2     `thenSmpl` \ (floats, env) ->
 398     addFloats env floats thing_inside
 399 \end{code}
 400
 401
 402 %************************************************************************
 403 %*                                                                      *
 404 \subsection{Lazy bindings}
 405 %*                                                                      *
 406 %************************************************************************
 407
 408 simplRecBind is used for
 409         * recursive bindings only
 410
 411 \begin{code}
 412 simplRecBind :: SimplEnv -> TopLevelFlag
 413              -> [(InId, InExpr)] -> [OutId]
 414              -> SimplM (FloatsWith SimplEnv)
 415 simplRecBind env top_lvl pairs bndrs'
 416   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 417     returnSmpl (flattenFloats floats, env)
 418   where
 419     go env [] _ = returnSmpl (emptyFloats env, env)
 420
 421     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 422         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 423           addFloats env floats (\env -> go env pairs bndrs')
 424 \end{code}
 425
 426
 427 simplRecOrTopPair is used for
 428         * recursive bindings (whether top level or not)
 429         * top-level non-recursive bindings
 430
 431 It assumes the binder has already been simplified, but not its IdInfo.
 432
 433 \begin{code}
 434 simplRecOrTopPair :: SimplEnv
 435                   -> TopLevelFlag
 436                   -> InId -> OutId              -- Binder, both pre-and post simpl
 437                   -> InExpr                     -- The RHS and its environment
 438                   -> SimplM (FloatsWith SimplEnv)
 439
 440 simplRecOrTopPair env top_lvl bndr bndr' rhs
 441   | preInlineUnconditionally env top_lvl bndr rhs       -- Check for unconditional inline
 442   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 443     returnSmpl (emptyFloats env, extendIdSubst env bndr (mkContEx env rhs))
 444
 445   | otherwise
 446   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 447         -- May not actually be recursive, but it doesn't matter
 448 \end{code}
 449
 450
 451 simplLazyBind is used for
 452         * recursive bindings (whether top level or not)
 453         * top-level non-recursive bindings
 454         * non-top-level *lazy* non-recursive bindings
 455
 456 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 457 from SimplRecOrTopBind]
 458
 459 Nota bene:
 460     1. It assumes that the binder is *already* simplified,
 461        and is in scope, but not its IdInfo
 462
 463     2. It assumes that the binder type is lifted.
 464
 465     3. It does not check for pre-inline-unconditionallly;
 466        that should have been done already.
 467
 468 \begin{code}
 469 simplLazyBind :: SimplEnv
 470               -> TopLevelFlag -> RecFlag
 471               -> InId -> OutId          -- Binder, both pre-and post simpl
 472               -> InExpr -> SimplEnv     -- The RHS and its environment
 473               -> SimplM (FloatsWith SimplEnv)
 474
 475 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 476   = let
 477         (env1,bndr2)      = addLetIdInfo env bndr bndr1
 478         rhs_env           = setInScope rhs_se env1
 479         is_top_level      = isTopLevel top_lvl
 480         ok_float_unlifted = not is_top_level && isNonRec is_rec
 481         rhs_cont          = mkRhsStop (idType bndr2)
 482     in
 483         -- Simplify the RHS; note the mkRhsStop, which tells
 484         -- the simplifier that this is the RHS of a let.
 485     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 486
 487         -- If any of the floats can't be floated, give up now
 488         -- (The allLifted predicate says True for empty floats.)
 489     if (not ok_float_unlifted && not (allLifted floats)) then
 490         completeLazyBind env1 top_lvl bndr bndr2
 491                          (wrapFloats floats rhs1)
 492     else
 493
 494         -- ANF-ise a constructor or PAP rhs
 495     mkAtomicArgs False {- Not strict -}
 496                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 497
 498         -- If the result is a PAP, float the floats out, else wrap them
 499         -- By this time it's already been ANF-ised (if necessary)
 500     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 501         completeLazyBind env1 top_lvl bndr bndr2 rhs2
 502
 503     else if is_top_level || exprIsTrivial rhs2 || exprIsHNF rhs2 then
 504         --      WARNING: long dodgy argument coming up
 505         --      WANTED: a better way to do this
 506         --
 507         -- We can't use "exprIsCheap" instead of exprIsHNF,
 508         -- because that causes a strictness bug.
 509         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 510         -- The case expression is 'cheap', but it's wrong to transform to
 511         --         y* = E; x = case (scc y) of {...}
 512         -- Either we must be careful not to float demanded non-values, or
 513         -- we must use exprIsHNF for the test, which ensures that the
 514         -- thing is non-strict.  So exprIsHNF => bindings are non-strict
 515         -- I think.  The WARN below tests for this.
 516         --
 517         -- We use exprIsTrivial here because we want to reveal lone variables.
 518         -- E.g.  let { x = letrec { y = E } in y } in ...
 519         -- Here we definitely want to float the y=E defn.
 520         -- exprIsHNF definitely isn't right for that.
 521         --
 522         -- Again, the floated binding can't be strict; if it's recursive it'll
 523         -- be non-strict; if it's non-recursive it'd be inlined.
 524         --
 525         -- Note [SCC-and-exprIsTrivial]
 526         -- If we have
 527         --      y = let { x* = E } in scc "foo" x
 528         -- then we do *not* want to float out the x binding, because
 529         -- it's strict!  Fortunately, exprIsTrivial replies False to
 530         -- (scc "foo" x).
 531
 532                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 533                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 534                 -- to float it out?  Answer no, but it won't matter because
 535                 -- we only float if (a) arg' is a WHNF, or (b) it's going to top level
 536                 -- and so there can't be any 'will be demanded' bindings in the floats.
 537                 -- Hence the warning
 538         ASSERT2( is_top_level || not (any demanded_float (floatBinds floats)),
 539                  ppr (filter demanded_float (floatBinds floats)) )
 540
 541         tick LetFloatFromLet                    `thenSmpl_` (
 542         addFloats env1 floats                   $ \ env2 ->
 543         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 544         completeLazyBind env3 top_lvl bndr bndr2 rhs2)
 545
 546     else
 547         completeLazyBind env1 top_lvl bndr bndr2 (wrapFloats floats rhs1)
 548
 549 #ifdef DEBUG
 550 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 551                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 552 demanded_float (Rec _)      = False
 553 #endif
 554 \end{code}
 555
 556
 557 %************************************************************************
 558 %*                                                                      *
 559 \subsection{Completing a lazy binding}
 560 %*                                                                      *
 561 %************************************************************************
 562
 563 completeLazyBind
 564         * deals only with Ids, not TyVars
 565         * takes an already-simplified binder and RHS
 566         * is used for both recursive and non-recursive bindings
 567         * is used for both top-level and non-top-level bindings
 568
 569 It does the following:
 570   - tries discarding a dead binding
 571   - tries PostInlineUnconditionally
 572   - add unfolding [this is the only place we add an unfolding]
 573   - add arity
 574
 575 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 576         - top-level bindings (when let-to-case is impossible)
 577         - many situations where the "rhs" is known to be a WHNF
 578                 (so let-to-case is inappropriate).
 579
 580 \begin{code}
 581 completeLazyBind :: SimplEnv
 582                  -> TopLevelFlag        -- Flag stuck into unfolding
 583                  -> InId                -- Old binder
 584                  -> OutId               -- New binder
 585                  -> OutExpr             -- Simplified RHS
 586                  -> SimplM (FloatsWith SimplEnv)
 587 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 588 -- by extending the substitution (e.g. let x = y in ...)
 589 -- The new binding (if any) is returned as part of the floats.
 590 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 591 --     (as usual) use the in-scope-env from the floats
 592
 593 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 594   | postInlineUnconditionally env top_lvl new_bndr occ_info new_rhs unfolding
 595   =             -- Drop the binding
 596     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 597     returnSmpl (emptyFloats env, extendIdSubst env old_bndr (DoneEx new_rhs))
 598                 -- Use the substitution to make quite, quite sure that the substitution
 599                 -- will happen, since we are going to discard the binding
 600
 601   |  otherwise
 602   = let
 603                 -- Add arity info
 604         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 605
 606         -- Add the unfolding *only* for non-loop-breakers
 607         -- Making loop breakers not have an unfolding at all
 608         -- means that we can avoid tests in exprIsConApp, for example.
 609         -- This is important: if exprIsConApp says 'yes' for a recursive
 610         -- thing, then we can get into an infinite loop
 611
 612         -- If the unfolding is a value, the demand info may
 613         -- go pear-shaped, so we nuke it.  Example:
 614         --      let x = (a,b) in
 615         --      case x of (p,q) -> h p q x
 616         -- Here x is certainly demanded. But after we've nuked
 617         -- the case, we'll get just
 618         --      let x = (a,b) in h a b x
 619         -- and now x is not demanded (I'm assuming h is lazy)
 620         -- This really happens.  Similarly
 621         --      let f = \x -> e in ...f..f...
 622         -- After inling f at some of its call sites the original binding may
 623         -- (for example) be no longer strictly demanded.
 624         -- The solution here is a bit ad hoc...
 625         info_w_unf = new_bndr_info `setUnfoldingInfo` unfolding
 626         final_info | loop_breaker               = new_bndr_info
 627                    | isEvaldUnfolding unfolding = zapDemandInfo info_w_unf `orElse` info_w_unf
 628                    | otherwise                  = info_w_unf
 629
 630         final_id = new_bndr `setIdInfo` final_info
 631     in
 632                 -- These seqs forces the Id, and hence its IdInfo,
 633                 -- and hence any inner substitutions
 634     final_id                                    `seq`
 635     returnSmpl (unitFloat env final_id new_rhs, env)
 636
 637   where
 638     unfolding    = mkUnfolding (isTopLevel top_lvl) new_rhs
 639     loop_breaker = isLoopBreaker occ_info
 640     old_info     = idInfo old_bndr
 641     occ_info     = occInfo old_info
 642 \end{code}
 643
 644
 645
 646 %************************************************************************
 647 %*                                                                      *
 648 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 649 %*                                                                      *
 650 %************************************************************************
 651
 652 The reason for this OutExprStuff stuff is that we want to float *after*
 653 simplifying a RHS, not before.  If we do so naively we get quadratic
 654 behaviour as things float out.
 655
 656 To see why it's important to do it after, consider this (real) example:
 657
 658         let t = f x
 659         in fst t
 660 ==>
 661         let t = let a = e1
 662                     b = e2
 663                 in (a,b)
 664         in fst t
 665 ==>
 666         let a = e1
 667             b = e2
 668             t = (a,b)
 669         in
 670         a       -- Can't inline a this round, cos it appears twice
 671 ==>
 672         e1
 673
 674 Each of the ==> steps is a round of simplification.  We'd save a
 675 whole round if we float first.  This can cascade.  Consider
 676
 677         let f = g d
 678         in \x -> ...f...
 679 ==>
 680         let f = let d1 = ..d.. in \y -> e
 681         in \x -> ...f...
 682 ==>
 683         let d1 = ..d..
 684         in \x -> ...(\y ->e)...
 685
 686 Only in this second round can the \y be applied, and it
 687 might do the same again.
 688
 689
 690 \begin{code}
 691 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 692 simplExpr env expr = simplExprC env expr (mkBoringStop expr_ty')
 693                    where
 694                      expr_ty' = substTy env (exprType expr)
 695         -- The type in the Stop continuation, expr_ty', is usually not used
 696         -- It's only needed when discarding continuations after finding
 697         -- a function that returns bottom.
 698         -- Hence the lazy substitution
 699
 700
 701 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 702         -- Simplify an expression, given a continuation
 703 simplExprC env expr cont
 704   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 705     returnSmpl (wrapFloats floats expr)
 706
 707 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 708         -- Simplify an expression, returning floated binds
 709
 710 simplExprF env (Var v)          cont = simplVar env v cont
 711 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 712 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 713 simplExprF env (Note note expr) cont = simplNote env note expr cont
 714 simplExprF env (App fun arg)    cont = simplExprF env fun (ApplyTo NoDup arg (Just env) cont)
 715
 716 simplExprF env (Type ty) cont
 717   = ASSERT( contIsRhsOrArg cont )
 718     simplType env ty                    `thenSmpl` \ ty' ->
 719     rebuild env (Type ty') cont
 720
 721 simplExprF env (Case scrut bndr case_ty alts) cont
 722   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 723   =     -- Simplify the scrutinee with a Select continuation
 724     simplExprF env scrut (Select NoDup bndr alts env cont)
 725
 726   | otherwise
 727   =     -- If case-of-case is off, simply simplify the case expression
 728         -- in a vanilla Stop context, and rebuild the result around it
 729     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 730     rebuild env case_expr' cont
 731   where
 732     case_cont = Select NoDup bndr alts env (mkBoringStop case_ty')
 733     case_ty'  = substTy env case_ty     -- c.f. defn of simplExpr
 734
 735 simplExprF env (Let (Rec pairs) body) cont
 736   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 737         -- NB: bndrs' don't have unfoldings or rules
 738         -- We add them as we go down
 739
 740     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 741     addFloats env floats                        $ \ env ->
 742     simplExprF env body cont
 743
 744 -- A non-recursive let is dealt with by simplNonRecBind
 745 simplExprF env (Let (NonRec bndr rhs) body) cont
 746   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 747     simplExprF env body cont
 748
 749
 750 ---------------------------------
 751 simplType :: SimplEnv -> InType -> SimplM OutType
 752         -- Kept monadic just so we can do the seqType
 753 simplType env ty
 754   = seqType new_ty   `seq`   returnSmpl new_ty
 755   where
 756     new_ty = substTy env ty
 757 \end{code}
 758
 759
 760 %************************************************************************
 761 %*                                                                      *
 762 \subsection{Lambdas}
 763 %*                                                                      *
 764 %************************************************************************
 765
 766 \begin{code}
 767 simplLam env fun cont
 768   = go env fun cont
 769   where
 770     zap_it  = mkLamBndrZapper fun (countArgs cont)
 771     cont_ty = contResultType cont
 772
 773         -- Type-beta reduction
 774     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) mb_arg_se body_cont)
 775       = ASSERT( isTyVar bndr )
 776         do { tick (BetaReduction bndr)
 777            ; ty_arg' <- case mb_arg_se of
 778                           Just arg_se -> simplType (setInScope arg_se env) ty_arg
 779                           Nothing     -> return ty_arg
 780            ; go (extendTvSubst env bndr ty_arg') body body_cont }
 781
 782         -- Ordinary beta reduction
 783     go env (Lam bndr body) cont@(ApplyTo _ arg (Just arg_se) body_cont)
 784       = do { tick (BetaReduction bndr)
 785            ; simplNonRecBind env (zap_it bndr) arg arg_se cont_ty       $ \ env ->
 786              go env body body_cont }
 787
 788     go env (Lam bndr body) cont@(ApplyTo _ arg Nothing body_cont)
 789       = do { tick (BetaReduction bndr)
 790            ; simplNonRecX env (zap_it bndr) arg         $ \ env ->
 791              go env body body_cont }
 792
 793         -- Not enough args, so there are real lambdas left to put in the result
 794     go env lam@(Lam _ _) cont
 795       = do { (env, bndrs') <- simplLamBndrs env bndrs
 796            ; body' <- simplExpr env body
 797            ; (floats, new_lam) <- mkLam env bndrs' body' cont
 798            ; addFloats env floats               $ \ env ->
 799              rebuild env new_lam cont }
 800       where
 801         (bndrs,body) = collectBinders lam
 802
 803         -- Exactly enough args
 804     go env expr cont = simplExprF env expr cont
 805
 806 mkLamBndrZapper :: CoreExpr     -- Function
 807                 -> Int          -- Number of args supplied, *including* type args
 808                 -> Id -> Id     -- Use this to zap the binders
 809 mkLamBndrZapper fun n_args
 810   | n_args >= n_params fun = \b -> b            -- Enough args
 811   | otherwise              = \b -> zapLamIdInfo b
 812   where
 813         -- NB: we count all the args incl type args
 814         -- so we must count all the binders (incl type lambdas)
 815     n_params (Note _ e) = n_params e
 816     n_params (Lam b e)  = 1 + n_params e
 817     n_params other      = 0::Int
 818 \end{code}
 819
 820
 821 %************************************************************************
 822 %*                                                                      *
 823 \subsection{Notes}
 824 %*                                                                      *
 825 %************************************************************************
 826
 827 \begin{code}
 828 simplNote env (Coerce to from) body cont
 829   = let
 830         addCoerce s1 k1 cont    -- Drop redundant coerces.  This can happen if a polymoprhic
 831                                 -- (coerce a b e) is instantiated with a=ty1 b=ty2 and the
 832                                 -- two are the same. This happens a lot in Happy-generated parsers
 833           | s1 `coreEqType` k1 = cont
 834
 835         addCoerce s1 k1 (CoerceIt t1 cont)
 836                 --      coerce T1 S1 (coerce S1 K1 e)
 837                 -- ==>
 838                 --      e,                      if T1=K1
 839                 --      coerce T1 K1 e,         otherwise
 840                 --
 841                 -- For example, in the initial form of a worker
 842                 -- we may find  (coerce T (coerce S (\x.e))) y
 843                 -- and we'd like it to simplify to e[y/x] in one round
 844                 -- of simplification
 845           | t1 `coreEqType` k1  = cont                  -- The coerces cancel out
 846           | otherwise           = CoerceIt t1 cont      -- They don't cancel, but
 847                                                         -- the inner one is redundant
 848
 849         addCoerce t1t2 s1s2 (ApplyTo dup arg mb_arg_se cont)
 850           | not (isTypeArg arg),        -- This whole case only works for value args
 851                                         -- Could upgrade to have equiv thing for type apps too
 852             Just (s1, s2) <- splitFunTy_maybe s1s2
 853                 --      (coerce (T1->T2) (S1->S2) F) E
 854                 -- ===>
 855                 --      coerce T2 S2 (F (coerce S1 T1 E))
 856                 --
 857                 -- t1t2 must be a function type, T1->T2, because it's applied to something
 858                 -- but s1s2 might conceivably not be
 859                 --
 860                 -- When we build the ApplyTo we can't mix the out-types
 861                 -- with the InExpr in the argument, so we simply substitute
 862                 -- to make it all consistent.  It's a bit messy.
 863                 -- But it isn't a common case.
 864           = let
 865                 (t1,t2) = splitFunTy t1t2
 866                 new_arg = mkCoerce2 s1 t1 arg'
 867                 arg' = case mb_arg_se of
 868                           Nothing -> arg
 869                           Just arg_se -> substExpr (setInScope arg_se env) arg
 870             in
 871             ApplyTo dup new_arg Nothing (addCoerce t2 s2 cont)
 872
 873         addCoerce to' _ cont = CoerceIt to' cont
 874     in
 875     simplType env to            `thenSmpl` \ to' ->
 876     simplType env from          `thenSmpl` \ from' ->
 877     simplExprF env body (addCoerce to' from' cont)
 878
 879
 880 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 881 -- inlining.  All other CCCSs are mapped to currentCCS.
 882 simplNote env (SCC cc) e cont
 883   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 884     rebuild env (mkSCC cc e') cont
 885
 886 -- See notes with SimplMonad.inlineMode
 887 simplNote env InlineMe e cont
 888   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 889   =                             -- Don't inline inside an INLINE expression
 890     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 891     rebuild env (mkInlineMe e') cont
 892
 893   | otherwise   -- Dissolve the InlineMe note if there's
 894                 -- an interesting context of any kind to combine with
 895                 -- (even a type application -- anything except Stop)
 896   = simplExprF env e cont
 897
 898 simplNote env (CoreNote s) e cont
 899   = simplExpr env e    `thenSmpl` \ e' ->
 900     rebuild env (Note (CoreNote s) e') cont
 901 \end{code}
 902
 903
 904 %************************************************************************
 905 %*                                                                      *
 906 \subsection{Dealing with calls}
 907 %*                                                                      *
 908 %************************************************************************
 909
 910 \begin{code}
 911 simplVar env var cont
 912   = case substId env var of
 913         DoneEx e         -> simplExprF (zapSubstEnv env) e cont
 914         ContEx tvs ids e -> simplExprF (setSubstEnv env tvs ids) e cont
 915         DoneId var1 occ  -> completeCall (zapSubstEnv env) var1 occ cont
 916                 -- Note [zapSubstEnv]
 917                 -- The template is already simplified, so don't re-substitute.
 918                 -- This is VITAL.  Consider
 919                 --      let x = e in
 920                 --      let y = \z -> ...x... in
 921                 --      \ x -> ...y...
 922                 -- We'll clone the inner \x, adding x->x' in the id_subst
 923                 -- Then when we inline y, we must *not* replace x by x' in
 924                 -- the inlined copy!!
 925
 926 ---------------------------------------------------------
 927 --      Dealing with a call site
 928
 929 completeCall env var occ_info cont
 930   =     -- Simplify the arguments
 931     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 932     let
 933         chkr              = getSwitchChecker env
 934         (args, call_cont) = getContArgs chkr var cont
 935         fn_ty             = idType var
 936     in
 937     simplifyArgs env fn_ty (interestingArgContext var call_cont) args
 938                  (contResultType call_cont)     $ \ env args ->
 939
 940         -- Next, look for rules or specialisations that match
 941         --
 942         -- It's important to simplify the args first, because the rule-matcher
 943         -- doesn't do substitution as it goes.  We don't want to use subst_args
 944         -- (defined in the 'where') because that throws away useful occurrence info,
 945         -- and perhaps-very-important specialisations.
 946         --
 947         -- Some functions have specialisations *and* are strict; in this case,
 948         -- we don't want to inline the wrapper of the non-specialised thing; better
 949         -- to call the specialised thing instead.
 950         -- We used to use the black-listing mechanism to ensure that inlining of
 951         -- the wrapper didn't occur for things that have specialisations till a
 952         -- later phase, so but now we just try RULES first
 953         --
 954         -- You might think that we shouldn't apply rules for a loop breaker:
 955         -- doing so might give rise to an infinite loop, because a RULE is
 956         -- rather like an extra equation for the function:
 957         --      RULE:           f (g x) y = x+y
 958         --      Eqn:            f a     y = a-y
 959         --
 960         -- But it's too drastic to disable rules for loop breakers.
 961         -- Even the foldr/build rule would be disabled, because foldr
 962         -- is recursive, and hence a loop breaker:
 963         --      foldr k z (build g) = g k z
 964         -- So it's up to the programmer: rules can cause divergence
 965
 966     let
 967         in_scope   = getInScope env
 968         rules      = getRules env
 969         maybe_rule = case activeRule env of
 970                         Nothing     -> Nothing  -- No rules apply
 971                         Just act_fn -> lookupRule act_fn in_scope rules var args
 972     in
 973     case maybe_rule of {
 974         Just (rule_name, rule_rhs) ->
 975                 tick (RuleFired rule_name)                      `thenSmpl_`
 976                 (if dopt Opt_D_dump_inlinings dflags then
 977                    pprTrace "Rule fired" (vcat [
 978                         text "Rule:" <+> ftext rule_name,
 979                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 980                         text "After: " <+> pprCoreExpr rule_rhs,
 981                         text "Cont:  " <+> ppr call_cont])
 982                  else
 983                         id)             $
 984                 simplExprF env rule_rhs call_cont ;
 985
 986         Nothing ->              -- No rules
 987
 988         -- Next, look for an inlining
 989     let
 990         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
 991         interesting_cont = interestingCallContext (notNull args)
 992                                                   (notNull arg_infos)
 993                                                   call_cont
 994         active_inline = activeInline env var occ_info
 995         maybe_inline  = callSiteInline dflags active_inline occ_info
 996                                        var arg_infos interesting_cont
 997     in
 998     case maybe_inline of {
 999         Just unfolding          -- There is an inlining!
1000           ->  tick (UnfoldingDone var)          `thenSmpl_`
1001                 (if dopt Opt_D_dump_inlinings dflags then
1002                    pprTrace "Inlining done" (vcat [
1003                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
1004                         text "Inlined fn: " <+> ppr unfolding,
1005                         text "Cont:  " <+> ppr call_cont])
1006                  else
1007                         id)             $
1008               simplExprF env unfolding (pushContArgs args call_cont)
1009
1010         ;
1011         Nothing ->              -- No inlining!
1012
1013         -- Done
1014     rebuild env (mkApps (Var var) args) call_cont
1015     }}
1016 \end{code}
1017
1018 %************************************************************************
1019 %*                                                                      *
1020 \subsection{Arguments}
1021 %*                                                                      *
1022 %************************************************************************
1023
1024 \begin{code}
1025 ---------------------------------------------------------
1026 --      Simplifying the arguments of a call
1027
1028 simplifyArgs :: SimplEnv
1029              -> OutType                         -- Type of the function
1030              -> Bool                            -- True if the fn has RULES
1031              -> [(InExpr, Maybe SimplEnv, Bool)] -- Details of the arguments
1032              -> OutType                         -- Type of the continuation
1033              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1034              -> SimplM FloatsWithExpr
1035
1036 -- [CPS-like because of strict arguments]
1037
1038 -- Simplify the arguments to a call.
1039 -- This part of the simplifier may break the no-shadowing invariant
1040 -- Consider
1041 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1042 -- where f is strict in its second arg
1043 -- If we simplify the innermost one first we get (...(\a -> e)...)
1044 -- Simplifying the second arg makes us float the case out, so we end up with
1045 --      case y of (a,b) -> f (...(\a -> e)...) e'
1046 -- So the output does not have the no-shadowing invariant.  However, there is
1047 -- no danger of getting name-capture, because when the first arg was simplified
1048 -- we used an in-scope set that at least mentioned all the variables free in its
1049 -- static environment, and that is enough.
1050 --
1051 -- We can't just do innermost first, or we'd end up with a dual problem:
1052 --      case x of (a,b) -> f e (...(\a -> e')...)
1053 --
1054 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1055 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1056 -- continuations.  We have to keep the right in-scope set around; AND we have
1057 -- to get the effect that finding (error "foo") in a strict arg position will
1058 -- discard the entire application and replace it with (error "foo").  Getting
1059 -- all this at once is TOO HARD!
1060
1061 simplifyArgs env fn_ty has_rules args cont_ty thing_inside
1062   = go env fn_ty args thing_inside
1063   where
1064     go env fn_ty []         thing_inside = thing_inside env []
1065     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty has_rules arg cont_ty  $ \ env arg' ->
1066                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1067                                            thing_inside env (arg':args')
1068
1069 simplifyArg env fn_ty has_rules (arg, Nothing, _) cont_ty thing_inside
1070   = thing_inside env arg        -- Already simplified
1071
1072 simplifyArg env fn_ty has_rules (Type ty_arg, Just se, _) cont_ty thing_inside
1073   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1074     thing_inside env (Type new_ty_arg)
1075
1076 simplifyArg env fn_ty has_rules (val_arg, Just arg_se, is_strict) cont_ty thing_inside
1077   | is_strict
1078   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1079
1080   | otherwise   -- Lazy argument
1081                 -- DO NOT float anything outside, hence simplExprC
1082                 -- There is no benefit (unlike in a let-binding), and we'd
1083                 -- have to be very careful about bogus strictness through
1084                 -- floating a demanded let.
1085   = simplExprC (setInScope arg_se env) val_arg
1086                (mkLazyArgStop arg_ty has_rules)         `thenSmpl` \ arg1 ->
1087     thing_inside env arg1
1088   where
1089     arg_ty = funArgTy fn_ty
1090
1091
1092 simplStrictArg ::  LetRhsFlag
1093                 -> SimplEnv             -- The env of the call
1094                 -> InExpr -> SimplEnv   -- The arg plus its env
1095                 -> OutType              -- arg_ty: type of the argument
1096                 -> OutType              -- cont_ty: Type of thing computed by the context
1097                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1098                                         -- Takes an expression of type rhs_ty,
1099                                         -- returns an expression of type cont_ty
1100                                         -- The env passed to this continuation is the
1101                                         -- env of the call, plus any new in-scope variables
1102                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1103
1104 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1105   = simplExprF (setInScope arg_env call_env) arg
1106                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1107   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1108   --    to simplify the argument
1109   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1110 \end{code}
1111
1112
1113 %************************************************************************
1114 %*                                                                      *
1115 \subsection{mkAtomicArgs}
1116 %*                                                                      *
1117 %************************************************************************
1118
1119 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1120 constructor application and, if so, converts it to ANF, so that the
1121 resulting thing can be inlined more easily.  Thus
1122         x = (f a, g b)
1123 becomes
1124         t1 = f a
1125         t2 = g b
1126         x = (t1,t2)
1127
1128 There are three sorts of binding context, specified by the two
1129 boolean arguments
1130
1131 Strict
1132    OK-unlifted
1133
1134 N  N    Top-level or recursive                  Only bind args of lifted type
1135
1136 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1137                 but lazy                        unlifted-and-ok-for-speculation
1138
1139 Y  Y    Non-top-level, non-recursive,           Bind all args
1140                  and strict (demanded)
1141
1142
1143 For example, given
1144
1145         x = MkC (y div# z)
1146
1147 there is no point in transforming to
1148
1149         x = case (y div# z) of r -> MkC r
1150
1151 because the (y div# z) can't float out of the let. But if it was
1152 a *strict* let, then it would be a good thing to do.  Hence the
1153 context information.
1154
1155 \begin{code}
1156 mkAtomicArgs :: Bool    -- A strict binding
1157              -> Bool    -- OK to float unlifted args
1158              -> OutExpr
1159              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1160                         OutExpr)                  -- things that need case-binding,
1161                                                   -- if the strict-binding flag is on
1162
1163 mkAtomicArgs is_strict ok_float_unlifted rhs
1164   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1165     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1166   = go fun nilOL [] args        -- Have a go
1167
1168   | otherwise = bale_out        -- Give up
1169
1170   where
1171     bale_out = returnSmpl (nilOL, rhs)
1172
1173     go fun binds rev_args []
1174         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1175
1176     go fun binds rev_args (arg : args)
1177         | exprIsTrivial arg     -- Easy case
1178         = go fun binds (arg:rev_args) args
1179
1180         | not can_float_arg     -- Can't make this arg atomic
1181         = bale_out              -- ... so give up
1182
1183         | otherwise     -- Don't forget to do it recursively
1184                         -- E.g.  x = a:b:c:[]
1185         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1186            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1187            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1188               (Var arg_id : rev_args) args
1189         where
1190           arg_ty        = exprType arg
1191           can_float_arg =  is_strict
1192                         || not (isUnLiftedType arg_ty)
1193                         || (ok_float_unlifted && exprOkForSpeculation arg)
1194
1195
1196 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1197                -> (SimplEnv -> SimplM (FloatsWith a))
1198                -> SimplM (FloatsWith a)
1199 addAtomicBinds env []         thing_inside = thing_inside env
1200 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1201                                              addAtomicBinds env bs thing_inside
1202
1203 addAtomicBindsE :: SimplEnv -> [(OutId,OutExpr)]
1204                 -> (SimplEnv -> SimplM FloatsWithExpr)
1205                 -> SimplM FloatsWithExpr
1206 -- Same again, but this time we're in an expression context,
1207 -- and may need to do some case bindings
1208
1209 addAtomicBindsE env [] thing_inside
1210   = thing_inside env
1211 addAtomicBindsE env ((v,r):bs) thing_inside
1212   | needsCaseBinding (idType v) r
1213   = addAtomicBindsE (addNewInScopeIds env [v]) bs thing_inside  `thenSmpl` \ (floats, expr) ->
1214     WARN( exprIsTrivial expr, ppr v <+> pprCoreExpr expr )
1215     (let body = wrapFloats floats expr in
1216      returnSmpl (emptyFloats env, Case r v (exprType body) [(DEFAULT,[],body)]))
1217
1218   | otherwise
1219   = addAuxiliaryBind env (NonRec v r)   $ \ env ->
1220     addAtomicBindsE env bs thing_inside
1221 \end{code}
1222
1223
1224 %************************************************************************
1225 %*                                                                      *
1226 \subsection{The main rebuilder}
1227 %*                                                                      *
1228 %************************************************************************
1229
1230 \begin{code}
1231 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1232
1233 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1234 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1235 rebuild env expr (CoerceIt to_ty cont)        = rebuild env (mkCoerce to_ty expr) cont
1236 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1237 rebuild env expr (ApplyTo _ arg mb_se cont)   = rebuildApp  env expr arg mb_se cont
1238
1239 rebuildApp env fun arg mb_se cont
1240   = do  { arg' <- simplArg env arg mb_se
1241         ; rebuild env (App fun arg') cont }
1242
1243 simplArg :: SimplEnv -> CoreExpr -> Maybe SimplEnv -> SimplM CoreExpr
1244 simplArg env arg Nothing        = return arg    -- The arg is already simplified
1245 simplArg env arg (Just arg_env) = simplExpr (setInScope arg_env env) arg
1246
1247 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1248 \end{code}
1249
1250
1251 %************************************************************************
1252 %*                                                                      *
1253 \subsection{Functions dealing with a case}
1254 %*                                                                      *
1255 %************************************************************************
1256
1257 Blob of helper functions for the "case-of-something-else" situation.
1258
1259 \begin{code}
1260 ---------------------------------------------------------
1261 --      Eliminate the case if possible
1262
1263 rebuildCase :: SimplEnv
1264             -> OutExpr          -- Scrutinee
1265             -> InId             -- Case binder
1266             -> [InAlt]          -- Alternatives (inceasing order)
1267             -> SimplCont
1268             -> SimplM FloatsWithExpr
1269
1270 rebuildCase env scrut case_bndr alts cont
1271   | Just (con,args) <- exprIsConApp_maybe scrut
1272         -- Works when the scrutinee is a variable with a known unfolding
1273         -- as well as when it's an explicit constructor application
1274   = knownCon env (DataAlt con) args case_bndr alts cont
1275
1276   | Lit lit <- scrut    -- No need for same treatment as constructors
1277                         -- because literals are inlined more vigorously
1278   = knownCon env (LitAlt lit) [] case_bndr alts cont
1279
1280   | otherwise
1281   =     -- Prepare the continuation;
1282         -- The new subst_env is in place
1283     prepareCaseCont env alts cont       `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1284     addFloats env floats                $ \ env ->
1285
1286     let
1287         -- The case expression is annotated with the result type of the continuation
1288         -- This may differ from the type originally on the case.  For example
1289         --      case(T) (case(Int#) a of { True -> 1#; False -> 0# }) of
1290         --         a# -> <blob>
1291         -- ===>
1292         --      let j a# = <blob>
1293         --      in case(T) a of { True -> j 1#; False -> j 0# }
1294         -- Note that the case that scrutinises a now returns a T not an Int#
1295         res_ty' = contResultType dup_cont
1296     in
1297
1298         -- Deal with case binder
1299     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr') ->
1300
1301         -- Deal with the case alternatives
1302     simplAlts alt_env scrut case_bndr' alts dup_cont    `thenSmpl` \ alts' ->
1303
1304         -- Put the case back together
1305     mkCase scrut case_bndr' res_ty' alts'       `thenSmpl` \ case_expr ->
1306
1307         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1308         -- The case binder *not* scope over the whole returned case-expression
1309     rebuild env case_expr nondup_cont
1310 \end{code}
1311
1312 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1313 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1314 way, there's a chance that v will now only be used once, and hence
1315 inlined.
1316
1317 Note 1
1318 ~~~~~~
1319 There is a time we *don't* want to do that, namely when
1320 -fno-case-of-case is on.  This happens in the first simplifier pass,
1321 and enhances full laziness.  Here's the bad case:
1322         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1323 If we eliminate the inner case, we trap it inside the I# v -> arm,
1324 which might prevent some full laziness happening.  I've seen this
1325 in action in spectral/cichelli/Prog.hs:
1326          [(m,n) | m <- [1..max], n <- [1..max]]
1327 Hence the check for NoCaseOfCase.
1328
1329 Note 2
1330 ~~~~~~
1331 There is another situation when we don't want to do it.  If we have
1332
1333     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1334                    ...other cases .... }
1335
1336 We'll perform the binder-swap for the outer case, giving
1337
1338     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1339                    ...other cases .... }
1340
1341 But there is no point in doing it for the inner case, because w1 can't
1342 be inlined anyway.  Furthermore, doing the case-swapping involves
1343 zapping w2's occurrence info (see paragraphs that follow), and that
1344 forces us to bind w2 when doing case merging.  So we get
1345
1346     case x of w1 { A -> let w2 = w1 in e1
1347                    B -> let w2 = w1 in e2
1348                    ...other cases .... }
1349
1350 This is plain silly in the common case where w2 is dead.
1351
1352 Even so, I can't see a good way to implement this idea.  I tried
1353 not doing the binder-swap if the scrutinee was already evaluated
1354 but that failed big-time:
1355
1356         data T = MkT !Int
1357
1358         case v of w  { MkT x ->
1359         case x of x1 { I# y1 ->
1360         case x of x2 { I# y2 -> ...
1361
1362 Notice that because MkT is strict, x is marked "evaluated".  But to
1363 eliminate the last case, we must either make sure that x (as well as
1364 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1365 the binder-swap.  So this whole note is a no-op.
1366
1367 Note 3
1368 ~~~~~~
1369 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1370 any occurrence info (eg IAmDead) in the case binder, because the
1371 case-binder now effectively occurs whenever v does.  AND we have to do
1372 the same for the pattern-bound variables!  Example:
1373
1374         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1375
1376 Here, b and p are dead.  But when we move the argment inside the first
1377 case RHS, and eliminate the second case, we get
1378
1379         case x of { (a,b) -> a b }
1380
1381 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1382 happened.
1383
1384 Indeed, this can happen anytime the case binder isn't dead:
1385         case <any> of x { (a,b) ->
1386         case x of { (p,q) -> p } }
1387 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1388 The point is that we bring into the envt a binding
1389         let x = (a,b)
1390 after the outer case, and that makes (a,b) alive.  At least we do unless
1391 the case binder is guaranteed dead.
1392
1393 \begin{code}
1394 simplCaseBinder env (Var v) case_bndr
1395   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
1396
1397 -- Failed try [see Note 2 above]
1398 --     not (isEvaldUnfolding (idUnfolding v))
1399
1400   = simplBinder env (zap case_bndr)             `thenSmpl` \ (env, case_bndr') ->
1401     returnSmpl (modifyInScope env v case_bndr', case_bndr')
1402         -- We could extend the substitution instead, but it would be
1403         -- a hack because then the substitution wouldn't be idempotent
1404         -- any more (v is an OutId).  And this does just as well.
1405   where
1406     zap b = b `setIdOccInfo` NoOccInfo
1407
1408 simplCaseBinder env other_scrut case_bndr
1409   = simplBinder env case_bndr           `thenSmpl` \ (env, case_bndr') ->
1410     returnSmpl (env, case_bndr')
1411 \end{code}
1412
1413
1414 simplAlts does two things:
1415
1416 1.  Eliminate alternatives that cannot match, including the
1417     DEFAULT alternative.
1418
1419 2.  If the DEFAULT alternative can match only one possible constructor,
1420     then make that constructor explicit.
1421     e.g.
1422         case e of x { DEFAULT -> rhs }
1423      ===>
1424         case e of x { (a,b) -> rhs }
1425     where the type is a single constructor type.  This gives better code
1426     when rhs also scrutinises x or e.
1427
1428 Here "cannot match" includes knowledge from GADTs
1429
1430 It's a good idea do do this stuff before simplifying the alternatives, to
1431 avoid simplifying alternatives we know can't happen, and to come up with
1432 the list of constructors that are handled, to put into the IdInfo of the
1433 case binder, for use when simplifying the alternatives.
1434
1435 Eliminating the default alternative in (1) isn't so obvious, but it can
1436 happen:
1437
1438 data Colour = Red | Green | Blue
1439
1440 f x = case x of
1441         Red -> ..
1442         Green -> ..
1443         DEFAULT -> h x
1444
1445 h y = case y of
1446         Blue -> ..
1447         DEFAULT -> [ case y of ... ]
1448
1449 If we inline h into f, the default case of the inlined h can't happen.
1450 If we don't notice this, we may end up filtering out *all* the cases
1451 of the inner case y, which give us nowhere to go!
1452
1453
1454 \begin{code}
1455 simplAlts :: SimplEnv
1456           -> OutExpr
1457           -> OutId                      -- Case binder
1458           -> [InAlt] -> SimplCont
1459           -> SimplM [OutAlt]            -- Includes the continuation
1460
1461 simplAlts env scrut case_bndr' alts cont'
1462   = do  { mb_alts      <- mapSmpl (simplAlt env imposs_cons case_bndr' cont') alts_wo_default
1463         ; default_alts <- simplDefault env case_bndr' imposs_deflt_cons cont' maybe_deflt
1464         ; return (mergeAlts default_alts [alt' | Just (_, alt') <- mb_alts]) }
1465         -- We need the mergeAlts in case the new default_alt
1466         -- has turned into a constructor alternative.
1467   where
1468     (alts_wo_default, maybe_deflt) = findDefault alts
1469     imposs_cons = case scrut of
1470                     Var v -> otherCons (idUnfolding v)
1471                     other -> []
1472
1473         -- "imposs_deflt_cons" are handled either by the context,
1474         -- OR by a branch in this case expression. (Don't include DEFAULT!!)
1475     imposs_deflt_cons = nub (imposs_cons ++ [con | (con,_,_) <- alts_wo_default])
1476
1477 simplDefault :: SimplEnv
1478              -> OutId           -- Case binder; need just for its type. Note that as an
1479                                 --   OutId, it has maximum information; this is important.
1480                                 --   Test simpl013 is an example
1481              -> [AltCon]        -- These cons can't happen when matching the default
1482              -> SimplCont
1483              -> Maybe InExpr
1484              -> SimplM [OutAlt] -- One branch or none; we use a list because it's what
1485                                 --   mergeAlts expects
1486
1487
1488 simplDefault env case_bndr' imposs_cons cont Nothing
1489   = return []   -- No default branch
1490 simplDefault env case_bndr' imposs_cons cont (Just rhs)
1491   |     -- This branch handles the case where we are
1492         -- scrutinisng an algebraic data type
1493     Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr'),
1494     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1495     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1496                                 --      case x of { DEFAULT -> e }
1497                                 -- and we don't want to fill in a default for them!
1498     Just all_cons <- tyConDataCons_maybe tycon,
1499     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1500                                 -- which GHC allows, then the case expression will have at most a default
1501                                 -- alternative.  We don't want to eliminate that alternative, because the
1502                                 -- invariant is that there's always one alternative.  It's more convenient
1503                                 -- to leave
1504                                 --      case x of { DEFAULT -> e }
1505                                 -- as it is, rather than transform it to
1506                                 --      error "case cant match"
1507                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1508                                 -- not worth wasting code on.
1509
1510     let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1511         poss_data_cons   = filterOut (`elem` imposs_data_cons) all_cons
1512         gadt_imposs      | all isTyVarTy inst_tys = []
1513                          | otherwise = filter (cant_match inst_tys) poss_data_cons
1514         final_poss       = filterOut (`elem` gadt_imposs) poss_data_cons
1515
1516   = case final_poss of
1517         []    -> returnSmpl []  -- Eliminate the default alternative
1518                                 -- altogether if it can't match
1519
1520         [con] ->        -- It matches exactly one constructor, so fill it in
1521                  do { con_alt <- mkDataConAlt case_bndr' con inst_tys rhs
1522                     ; Just (_, alt') <- simplAlt env [] case_bndr' cont con_alt
1523                         -- The simplAlt must succeed with Just because we have
1524                         -- already filtered out construtors that can't match
1525                     ; return [alt'] }
1526
1527         two_or_more -> simplify_default (map DataAlt gadt_imposs ++ imposs_cons)
1528
1529   | otherwise
1530   = simplify_default imposs_cons
1531   where
1532     cant_match tys data_con = not (dataConCanMatch data_con tys)
1533
1534     simplify_default imposs_cons
1535         = do { let env' = mk_rhs_env env case_bndr' (mkOtherCon imposs_cons)
1536                 -- Record the constructors that the case-binder *can't* be.
1537              ; rhs' <- simplExprC env' rhs cont
1538              ; return [(DEFAULT, [], rhs')] }
1539
1540 mkDataConAlt :: Id -> DataCon -> [OutType] -> InExpr -> SimplM InAlt
1541 -- Make a data-constructor alternative to replace the DEFAULT case
1542 -- NB: there's something a bit bogus here, because we put OutTypes into an InAlt
1543 mkDataConAlt case_bndr con tys rhs
1544   = do  { tick (FillInCaseDefault case_bndr)
1545         ; args <- mk_args con tys
1546         ; return (DataAlt con, args, rhs) }
1547   where
1548     mk_args con inst_tys
1549       = do { (tv_bndrs, inst_tys') <- mk_tv_bndrs con inst_tys
1550            ; let arg_tys = dataConInstArgTys con inst_tys'
1551            ; arg_ids <- mapM (newId FSLIT("a")) arg_tys
1552            ; returnSmpl (tv_bndrs ++ arg_ids) }
1553
1554     mk_tv_bndrs con inst_tys
1555       | isVanillaDataCon con
1556       = return ([], inst_tys)
1557       | otherwise
1558       = do { tv_uniqs <- getUniquesSmpl
1559            ; let new_tvs    = zipWith mk tv_uniqs (dataConTyVars con)
1560                  mk uniq tv = mkTyVar (mkSysTvName uniq FSLIT("t")) (tyVarKind tv)
1561            ; return (new_tvs, mkTyVarTys new_tvs) }
1562
1563 simplAlt :: SimplEnv
1564          -> [AltCon]    -- These constructors can't be present when
1565                         -- matching this alternative
1566          -> OutId       -- The case binder
1567          -> SimplCont
1568          -> InAlt
1569          -> SimplM (Maybe (TvSubstEnv, OutAlt))
1570
1571 -- Simplify an alternative, returning the type refinement for the
1572 -- alternative, if the alternative does any refinement at all
1573 -- Nothing => the alternative is inaccessible
1574
1575 simplAlt env imposs_cons case_bndr' cont' (con, bndrs, rhs)
1576   | con `elem` imposs_cons      -- This case can't match
1577   = return Nothing
1578
1579 simplAlt env handled_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1580         -- TURGID DUPLICATION, needed only for the simplAlt call
1581         -- in mkDupableAlt.  Clean this up when moving to FC
1582   = ASSERT( null bndrs )
1583     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1584     returnSmpl (Just (emptyVarEnv, (DEFAULT, [], rhs')))
1585   where
1586     env' = mk_rhs_env env case_bndr' (mkOtherCon handled_cons)
1587         -- Record the constructors that the case-binder *can't* be.
1588
1589 simplAlt env handled_cons case_bndr' cont' (LitAlt lit, bndrs, rhs)
1590   = ASSERT( null bndrs )
1591     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1592     returnSmpl (Just (emptyVarEnv, (LitAlt lit, [], rhs')))
1593   where
1594     env' = mk_rhs_env env case_bndr' (mkUnfolding False (Lit lit))
1595
1596 simplAlt env handled_cons case_bndr' cont' (DataAlt con, vs, rhs)
1597   | isVanillaDataCon con
1598   =     -- Deal with the pattern-bound variables
1599         -- Mark the ones that are in ! positions in the data constructor
1600         -- as certainly-evaluated.
1601         -- NB: it happens that simplBinders does *not* erase the OtherCon
1602         --     form of unfolding, so it's ok to add this info before
1603         --     doing simplBinders
1604     simplBinders env (add_evals con vs)         `thenSmpl` \ (env, vs') ->
1605
1606                 -- Bind the case-binder to (con args)
1607     let unf       = mkUnfolding False (mkConApp con con_args)
1608         inst_tys' = tyConAppArgs (idType case_bndr')
1609         con_args  = map Type inst_tys' ++ map varToCoreExpr vs'
1610         env'      = mk_rhs_env env case_bndr' unf
1611     in
1612     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1613     returnSmpl (Just (emptyVarEnv, (DataAlt con, vs', rhs')))
1614
1615   | otherwise   -- GADT case
1616   = let
1617         (tvs,ids) = span isTyVar vs
1618     in
1619     simplBinders env tvs                        `thenSmpl` \ (env1, tvs') ->
1620     case coreRefineTys con tvs' (idType case_bndr') of {
1621         Nothing         -- Inaccessible
1622             | opt_PprStyle_Debug        -- Hack: if debugging is on, generate an error case
1623                                         --       so we can see it
1624             ->  let rhs' = mkApps (Var eRROR_ID)
1625                                 [Type (substTy env (exprType rhs)),
1626                                  Lit (mkStringLit "Impossible alternative (GADT)")]
1627                 in
1628                 simplBinders env1 ids           `thenSmpl` \ (env2, ids') ->
1629                 returnSmpl (Just (emptyVarEnv, (DataAlt con, tvs' ++ ids', rhs')))
1630
1631             | otherwise -- Filter out the inaccessible branch
1632             -> return Nothing ;
1633
1634         Just refine@(tv_subst_env, _) ->        -- The normal case
1635
1636     let
1637         env2 = refineSimplEnv env1 refine
1638         -- Simplify the Ids in the refined environment, so their types
1639         -- reflect the refinement.  Usually this doesn't matter, but it helps
1640         -- in mkDupableAlt, when we want to float a lambda that uses these binders
1641         -- Furthermore, it means the binders contain maximal type information
1642     in
1643     simplBinders env2 (add_evals con ids)       `thenSmpl` \ (env3, ids') ->
1644     let unf        = mkUnfolding False con_app
1645         con_app    = mkConApp con con_args
1646         con_args   = map varToCoreExpr vs'      -- NB: no inst_tys'
1647         env_w_unf  = mk_rhs_env env3 case_bndr' unf
1648         vs'        = tvs' ++ ids'
1649     in
1650     simplExprC env_w_unf rhs cont'      `thenSmpl` \ rhs' ->
1651     returnSmpl (Just (tv_subst_env, (DataAlt con, vs', rhs'))) }
1652
1653   where
1654         -- add_evals records the evaluated-ness of the bound variables of
1655         -- a case pattern.  This is *important*.  Consider
1656         --      data T = T !Int !Int
1657         --
1658         --      case x of { T a b -> T (a+1) b }
1659         --
1660         -- We really must record that b is already evaluated so that we don't
1661         -- go and re-evaluate it when constructing the result.
1662     add_evals dc vs = cat_evals dc vs (dataConRepStrictness dc)
1663
1664     cat_evals dc vs strs
1665         = go vs strs
1666         where
1667           go [] [] = []
1668           go (v:vs) strs | isTyVar v = v : go vs strs
1669           go (v:vs) (str:strs)
1670             | isMarkedStrict str = evald_v  : go vs strs
1671             | otherwise          = zapped_v : go vs strs
1672             where
1673               zapped_v = zap_occ_info v
1674               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
1675           go _ _ = pprPanic "cat_evals" (ppr dc $$ ppr vs $$ ppr strs)
1676
1677         -- If the case binder is alive, then we add the unfolding
1678         --      case_bndr = C vs
1679         -- to the envt; so vs are now very much alive
1680     zap_occ_info | isDeadBinder case_bndr' = \id -> id
1681                  | otherwise               = \id -> id `setIdOccInfo` NoOccInfo
1682
1683 mk_rhs_env env case_bndr' case_bndr_unf
1684   = modifyInScope env case_bndr' (case_bndr' `setIdUnfolding` case_bndr_unf)
1685 \end{code}
1686
1687
1688 %************************************************************************
1689 %*                                                                      *
1690 \subsection{Known constructor}
1691 %*                                                                      *
1692 %************************************************************************
1693
1694 We are a bit careful with occurrence info.  Here's an example
1695
1696         (\x* -> case x of (a*, b) -> f a) (h v, e)
1697
1698 where the * means "occurs once".  This effectively becomes
1699         case (h v, e) of (a*, b) -> f a)
1700 and then
1701         let a* = h v; b = e in f a
1702 and then
1703         f (h v)
1704
1705 All this should happen in one sweep.
1706
1707 \begin{code}
1708 knownCon :: SimplEnv -> AltCon -> [OutExpr]
1709          -> InId -> [InAlt] -> SimplCont
1710          -> SimplM FloatsWithExpr
1711
1712 knownCon env con args bndr alts cont
1713   = tick (KnownBranch bndr)     `thenSmpl_`
1714     case findAlt con alts of
1715         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1716                                   simplNonRecX env bndr scrut   $ \ env ->
1717                                         -- This might give rise to a binding with non-atomic args
1718                                         -- like x = Node (f x) (g x)
1719                                         -- but no harm will be done
1720                                   simplExprF env rhs cont
1721                                 where
1722                                   scrut = case con of
1723                                             LitAlt lit -> Lit lit
1724                                             DataAlt dc -> mkConApp dc args
1725
1726         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1727                                   simplNonRecX env bndr (Lit lit)       $ \ env ->
1728                                   simplExprF env rhs cont
1729
1730         (DataAlt dc, bs, rhs)
1731                 -> ASSERT( n_drop_tys + length bs == length args )
1732                    bind_args env bs (drop n_drop_tys args)      $ \ env ->
1733                    let
1734                         con_app  = mkConApp dc (take n_drop_tys args ++ con_args)
1735                         con_args = [substExpr env (varToCoreExpr b) | b <- bs]
1736                                         -- args are aready OutExprs, but bs are InIds
1737                    in
1738                    simplNonRecX env bndr con_app                $ \ env ->
1739                    simplExprF env rhs cont
1740                 where
1741                    n_drop_tys | isVanillaDataCon dc = tyConArity (dataConTyCon dc)
1742                               | otherwise           = 0
1743                         -- Vanilla data constructors lack type arguments in the pattern
1744
1745 -- Ugh!
1746 bind_args env [] _ thing_inside = thing_inside env
1747
1748 bind_args env (b:bs) (Type ty : args) thing_inside
1749   = ASSERT( isTyVar b )
1750     bind_args (extendTvSubst env b ty) bs args thing_inside
1751
1752 bind_args env (b:bs) (arg : args) thing_inside
1753   = ASSERT( isId b )
1754     simplNonRecX env b arg      $ \ env ->
1755     bind_args env bs args thing_inside
1756 \end{code}
1757
1758
1759 %************************************************************************
1760 %*                                                                      *
1761 \subsection{Duplicating continuations}
1762 %*                                                                      *
1763 %************************************************************************
1764
1765 \begin{code}
1766 prepareCaseCont :: SimplEnv
1767                 -> [InAlt] -> SimplCont
1768                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1769                         -- Return a duplicatable continuation, a non-duplicable part
1770                         -- plus some extra bindings (that scope over the entire
1771                         -- continunation)
1772
1773         -- No need to make it duplicatable if there's only one alternative
1774 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1775 prepareCaseCont env alts  cont = mkDupableCont env cont
1776 \end{code}
1777
1778 \begin{code}
1779 mkDupableCont :: SimplEnv -> SimplCont
1780               -> SimplM (FloatsWith (SimplCont, SimplCont))
1781
1782 mkDupableCont env cont
1783   | contIsDupable cont
1784   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1785
1786 mkDupableCont env (CoerceIt ty cont)
1787   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1788     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1789
1790 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1791   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1792         -- Do *not* duplicate an ArgOf continuation
1793         -- Because ArgOf continuations are opaque, we gain nothing by
1794         -- propagating them into the expressions, and we do lose a lot.
1795         -- Here's an example:
1796         --      && (case x of { T -> F; F -> T }) E
1797         -- Now, && is strict so we end up simplifying the case with
1798         -- an ArgOf continuation.  If we let-bind it, we get
1799         --
1800         --      let $j = \v -> && v E
1801         --      in simplExpr (case x of { T -> F; F -> T })
1802         --                   (ArgOf (\r -> $j r)
1803         -- And after simplifying more we get
1804         --
1805         --      let $j = \v -> && v E
1806         --      in case of { T -> $j F; F -> $j T }
1807         -- Which is a Very Bad Thing
1808         --
1809         -- The desire not to duplicate is the entire reason that
1810         -- mkDupableCont returns a pair of continuations.
1811         --
1812         -- The original plan had:
1813         -- e.g.         (...strict-fn...) [...hole...]
1814         --      ==>
1815         --              let $j = \a -> ...strict-fn...
1816         --              in $j [...hole...]
1817
1818 mkDupableCont env (ApplyTo _ arg mb_se cont)
1819   =     -- e.g.         [...hole...] (...arg...)
1820         --      ==>
1821         --              let a = ...arg...
1822         --              in [...hole...] a
1823     do  { (floats, (dup_cont, nondup_cont)) <- mkDupableCont env cont
1824         ; addFloats env floats $ \ env -> do
1825         { arg1 <- simplArg env arg mb_se
1826         ; (floats2, arg2) <- mkDupableArg env arg1
1827         ; return (floats2, (ApplyTo OkToDup arg2 Nothing dup_cont, nondup_cont)) }}
1828
1829 mkDupableCont env (Select _ case_bndr alts se cont)
1830   =     -- e.g.         (case [...hole...] of { pi -> ei })
1831         --      ===>
1832         --              let ji = \xij -> ei
1833         --              in case [...hole...] of { pi -> ji xij }
1834     do  { tick (CaseOfCase case_bndr)
1835         ; let alt_env = setInScope se env
1836         ; (floats1, (dup_cont, nondup_cont)) <- mkDupableCont alt_env cont
1837                 -- NB: call mkDupableCont here, *not* prepareCaseCont
1838                 -- We must make a duplicable continuation, whereas prepareCaseCont
1839                 -- doesn't when there is a single case branch
1840         ; addFloats alt_env floats1     $ \ alt_env -> do
1841
1842         { (alt_env, case_bndr') <- simplBinder alt_env case_bndr
1843                 -- NB: simplBinder does not zap deadness occ-info, so
1844                 -- a dead case_bndr' will still advertise its deadness
1845                 -- This is really important because in
1846                 --      case e of b { (# a,b #) -> ... }
1847                 -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1848                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1849                 -- In the new alts we build, we have the new case binder, so it must retain
1850                 -- its deadness.
1851
1852         ; (floats2, alts') <- mkDupableAlts alt_env case_bndr' alts dup_cont
1853         ; return (floats2, (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1854                                    (mkBoringStop (contResultType dup_cont)),
1855                             nondup_cont))
1856         }}
1857
1858 mkDupableArg :: SimplEnv -> OutExpr -> SimplM (FloatsWith OutExpr)
1859 -- Let-bind the thing if necessary
1860 mkDupableArg env arg
1861   | exprIsDupable arg
1862   = return (emptyFloats env, arg)
1863   | otherwise
1864   = do  { arg_id <- newId FSLIT("a") (exprType arg)
1865         ; tick (CaseOfCase arg_id)
1866                 -- Want to tick here so that we go round again,
1867                 -- and maybe copy or inline the code.
1868                 -- Not strictly CaseOfCase, but never mind
1869         ; return (unitFloat env arg_id arg, Var arg_id) }
1870         -- What if the arg should be case-bound?
1871         -- This has been this way for a long time, so I'll leave it,
1872         -- but I can't convince myself that it's right.
1873
1874 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1875               -> SimplM (FloatsWith [InAlt])
1876 -- Absorbs the continuation into the new alternatives
1877
1878 mkDupableAlts env case_bndr' alts dupable_cont
1879   = go env alts
1880   where
1881     go env [] = returnSmpl (emptyFloats env, [])
1882     go env (alt:alts)
1883         = do { (floats1, mb_alt') <- mkDupableAlt env case_bndr' dupable_cont alt
1884              ; addFloats env floats1    $ \ env -> do
1885              { (floats2, alts') <- go env alts
1886              ; returnSmpl (floats2, case mb_alt' of
1887                                         Just alt' -> alt' : alts'
1888                                         Nothing   -> alts'
1889                           )}}
1890
1891 mkDupableAlt env case_bndr' cont alt
1892   = simplAlt env [] case_bndr' cont alt         `thenSmpl` \ mb_stuff ->
1893     case mb_stuff of {
1894         Nothing -> returnSmpl (emptyFloats env, Nothing) ;
1895
1896         Just (reft, (con, bndrs', rhs')) ->
1897         -- Safe to say that there are no handled-cons for the DEFAULT case
1898
1899     if exprIsDupable rhs' then
1900         returnSmpl (emptyFloats env, Just (con, bndrs', rhs'))
1901         -- It is worth checking for a small RHS because otherwise we
1902         -- get extra let bindings that may cause an extra iteration of the simplifier to
1903         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1904         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1905         -- iterations because the version with the let bindings looked big, and so wasn't
1906         -- inlined, but after the join points had been inlined it looked smaller, and so
1907         -- was inlined.
1908         --
1909         -- NB: we have to check the size of rhs', not rhs.
1910         -- Duplicating a small InAlt might invalidate occurrence information
1911         -- However, if it *is* dupable, we return the *un* simplified alternative,
1912         -- because otherwise we'd need to pair it up with an empty subst-env....
1913         -- but we only have one env shared between all the alts.
1914         -- (Remember we must zap the subst-env before re-simplifying something).
1915         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1916
1917     else
1918     let
1919         rhs_ty'     = exprType rhs'
1920         used_bndrs' = filter abstract_over (case_bndr' : bndrs')
1921         abstract_over bndr
1922           | isTyVar bndr = not (bndr `elemVarEnv` reft)
1923                 -- Don't abstract over tyvar binders which are refined away
1924                 -- See Note [Refinement] below
1925           | otherwise    = not (isDeadBinder bndr)
1926                 -- The deadness info on the new Ids is preserved by simplBinders
1927     in
1928         -- If we try to lift a primitive-typed something out
1929         -- for let-binding-purposes, we will *caseify* it (!),
1930         -- with potentially-disastrous strictness results.  So
1931         -- instead we turn it into a function: \v -> e
1932         -- where v::State# RealWorld#.  The value passed to this function
1933         -- is realworld#, which generates (almost) no code.
1934
1935         -- There's a slight infelicity here: we pass the overall
1936         -- case_bndr to all the join points if it's used in *any* RHS,
1937         -- because we don't know its usage in each RHS separately
1938
1939         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1940         -- we make the join point into a function whenever used_bndrs'
1941         -- is empty.  This makes the join-point more CPR friendly.
1942         -- Consider:    let j = if .. then I# 3 else I# 4
1943         --              in case .. of { A -> j; B -> j; C -> ... }
1944         --
1945         -- Now CPR doesn't w/w j because it's a thunk, so
1946         -- that means that the enclosing function can't w/w either,
1947         -- which is a lose.  Here's the example that happened in practice:
1948         --      kgmod :: Int -> Int -> Int
1949         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1950         --                  then 78
1951         --                  else 5
1952         --
1953         -- I have seen a case alternative like this:
1954         --      True -> \v -> ...
1955         -- It's a bit silly to add the realWorld dummy arg in this case, making
1956         --      $j = \s v -> ...
1957         --         True -> $j s
1958         -- (the \v alone is enough to make CPR happy) but I think it's rare
1959
1960     ( if not (any isId used_bndrs')
1961         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
1962              returnSmpl ([rw_id], [Var realWorldPrimId])
1963         else
1964              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs')
1965     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
1966
1967         -- See comment about "$j" name above
1968     newId FSLIT("$j") (mkPiTypes final_bndrs' rhs_ty')  `thenSmpl` \ join_bndr ->
1969         -- Notice the funky mkPiTypes.  If the contructor has existentials
1970         -- it's possible that the join point will be abstracted over
1971         -- type varaibles as well as term variables.
1972         --  Example:  Suppose we have
1973         --      data T = forall t.  C [t]
1974         --  Then faced with
1975         --      case (case e of ...) of
1976         --          C t xs::[t] -> rhs
1977         --  We get the join point
1978         --      let j :: forall t. [t] -> ...
1979         --          j = /\t \xs::[t] -> rhs
1980         --      in
1981         --      case (case e of ...) of
1982         --          C t xs::[t] -> j t xs
1983     let
1984         -- We make the lambdas into one-shot-lambdas.  The
1985         -- join point is sure to be applied at most once, and doing so
1986         -- prevents the body of the join point being floated out by
1987         -- the full laziness pass
1988         really_final_bndrs     = map one_shot final_bndrs'
1989         one_shot v | isId v    = setOneShotLambda v
1990                    | otherwise = v
1991         join_rhs  = mkLams really_final_bndrs rhs'
1992         join_call = mkApps (Var join_bndr) final_args
1993     in
1994     returnSmpl (unitFloat env join_bndr join_rhs, Just (con, bndrs', join_call)) }
1995 \end{code}
1996
1997 Note [Refinement]
1998 ~~~~~~~~~~~~~~~~~
1999 Consider
2000         data T a where
2001           MkT :: a -> b -> T a
2002
2003         f = /\a. \(w::a).
2004            case (case ...) of
2005                   MkT a' b (p::a') (q::b) -> [p,w]
2006
2007 The danger is that we'll make a join point
2008
2009         j a' p = [p,w]
2010
2011 and that's ill-typed, because (p::a') but (w::a).
2012
2013 Solution so far: don't abstract over a', because the type refinement
2014 maps [a' -> a] .  Ultimately that won't work when real refinement goes on.
2015
2016 Then we must abstract over any refined free variables.  Hmm.  Maybe we
2017 could just abstract over *all* free variables, thereby lambda-lifting
2018 the join point?   We should try this.