compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags
  12 import SimplMonad
  13 import Type hiding      ( substTy, extendTvSubst )
  14 import SimplEnv
  15 import SimplUtils
  16 import MkId             ( rUNTIME_ERROR_ID )
  17 import Id
  18 import Var
  19 import IdInfo
  20 import Coercion
  21 import FamInstEnv       ( topNormaliseType )
  22 import DataCon          ( dataConRepStrictness, dataConUnivTyVars )
  23 import CoreSyn
  24 import NewDemand        ( isStrictDmd )
  25 import PprCore          ( pprParendExpr, pprCoreExpr )
  26 import CoreUnfold       ( mkUnfolding, callSiteInline, CallCtxt(..) )
  27 import CoreUtils
  28 import Rules            ( lookupRule, getRules )
  29 import BasicTypes       ( isMarkedStrict )
  30 import CostCentre       ( currentCCS )
  31 import TysPrim          ( realWorldStatePrimTy )
  32 import PrelInfo         ( realWorldPrimId )
  33 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  34                           RecFlag(..), isNonRuleLoopBreaker )
  35 import Maybes           ( orElse )
  36 import Data.List        ( mapAccumL )
  37 import Outputable
  38 import FastString
  39 \end{code}
  40
  41
  42 The guts of the simplifier is in this module, but the driver loop for
  43 the simplifier is in SimplCore.lhs.
  44
  45
  46 -----------------------------------------
  47         *** IMPORTANT NOTE ***
  48 -----------------------------------------
  49 The simplifier used to guarantee that the output had no shadowing, but
  50 it does not do so any more.   (Actually, it never did!)  The reason is
  51 documented with simplifyArgs.
  52
  53
  54 -----------------------------------------
  55         *** IMPORTANT NOTE ***
  56 -----------------------------------------
  57 Many parts of the simplifier return a bunch of "floats" as well as an
  58 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  59
  60 All "floats" are let-binds, not case-binds, but some non-rec lets may
  61 be unlifted (with RHS ok-for-speculation).
  62
  63
  64
  65 -----------------------------------------
  66         ORGANISATION OF FUNCTIONS
  67 -----------------------------------------
  68 simplTopBinds
  69   - simplify all top-level binders
  70   - for NonRec, call simplRecOrTopPair
  71   - for Rec,    call simplRecBind
  72
  73
  74         ------------------------------
  75 simplExpr (applied lambda)      ==> simplNonRecBind
  76 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
  77 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
  78
  79         ------------------------------
  80 simplRecBind    [binders already simplfied]
  81   - use simplRecOrTopPair on each pair in turn
  82
  83 simplRecOrTopPair [binder already simplified]
  84   Used for: recursive bindings (top level and nested)
  85             top-level non-recursive bindings
  86   Returns:
  87   - check for PreInlineUnconditionally
  88   - simplLazyBind
  89
  90 simplNonRecBind
  91   Used for: non-top-level non-recursive bindings
  92             beta reductions (which amount to the same thing)
  93   Because it can deal with strict arts, it takes a
  94         "thing-inside" and returns an expression
  95
  96   - check for PreInlineUnconditionally
  97   - simplify binder, including its IdInfo
  98   - if strict binding
  99         simplStrictArg
 100         mkAtomicArgs
 101         completeNonRecX
 102     else
 103         simplLazyBind
 104         addFloats
 105
 106 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 107   Used for: binding case-binder and constr args in a known-constructor case
 108   - check for PreInLineUnconditionally
 109   - simplify binder
 110   - completeNonRecX
 111
 112         ------------------------------
 113 simplLazyBind:  [binder already simplified, RHS not]
 114   Used for: recursive bindings (top level and nested)
 115             top-level non-recursive bindings
 116             non-top-level, but *lazy* non-recursive bindings
 117         [must not be strict or unboxed]
 118   Returns floats + an augmented environment, not an expression
 119   - substituteIdInfo and add result to in-scope
 120         [so that rules are available in rec rhs]
 121   - simplify rhs
 122   - mkAtomicArgs
 123   - float if exposes constructor or PAP
 124   - completeBind
 125
 126
 127 completeNonRecX:        [binder and rhs both simplified]
 128   - if the the thing needs case binding (unlifted and not ok-for-spec)
 129         build a Case
 130    else
 131         completeBind
 132         addFloats
 133
 134 completeBind:   [given a simplified RHS]
 135         [used for both rec and non-rec bindings, top level and not]
 136   - try PostInlineUnconditionally
 137   - add unfolding [this is the only place we add an unfolding]
 138   - add arity
 139
 140
 141
 142 Right hand sides and arguments
 143 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 144 In many ways we want to treat
 145         (a) the right hand side of a let(rec), and
 146         (b) a function argument
 147 in the same way.  But not always!  In particular, we would
 148 like to leave these arguments exactly as they are, so they
 149 will match a RULE more easily.
 150
 151         f (g x, h x)
 152         g (+ x)
 153
 154 It's harder to make the rule match if we ANF-ise the constructor,
 155 or eta-expand the PAP:
 156
 157         f (let { a = g x; b = h x } in (a,b))
 158         g (\y. + x y)
 159
 160 On the other hand if we see the let-defns
 161
 162         p = (g x, h x)
 163         q = + x
 164
 165 then we *do* want to ANF-ise and eta-expand, so that p and q
 166 can be safely inlined.
 167
 168 Even floating lets out is a bit dubious.  For let RHS's we float lets
 169 out if that exposes a value, so that the value can be inlined more vigorously.
 170 For example
 171
 172         r = let x = e in (x,x)
 173
 174 Here, if we float the let out we'll expose a nice constructor. We did experiments
 175 that showed this to be a generally good thing.  But it was a bad thing to float
 176 lets out unconditionally, because that meant they got allocated more often.
 177
 178 For function arguments, there's less reason to expose a constructor (it won't
 179 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 180 So for the moment we don't float lets out of function arguments either.
 181
 182
 183 Eta expansion
 184 ~~~~~~~~~~~~~~
 185 For eta expansion, we want to catch things like
 186
 187         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 188
 189 If the \x was on the RHS of a let, we'd eta expand to bring the two
 190 lambdas together.  And in general that's a good thing to do.  Perhaps
 191 we should eta expand wherever we find a (value) lambda?  Then the eta
 192 expansion at a let RHS can concentrate solely on the PAP case.
 193
 194
 195 %************************************************************************
 196 %*                                                                      *
 197 \subsection{Bindings}
 198 %*                                                                      *
 199 %************************************************************************
 200
 201 \begin{code}
 202 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 203
 204 simplTopBinds env0 binds0
 205   = do  {       -- Put all the top-level binders into scope at the start
 206                 -- so that if a transformation rule has unexpectedly brought
 207                 -- anything into scope, then we don't get a complaint about that.
 208                 -- It's rather as if the top-level binders were imported.
 209         ; env1 <- simplRecBndrs env0 (bindersOfBinds binds0)
 210         ; dflags <- getDOptsSmpl
 211         ; let dump_flag = dopt Opt_D_dump_inlinings dflags ||
 212                           dopt Opt_D_dump_rule_firings dflags
 213         ; env2 <- simpl_binds dump_flag env1 binds0
 214         ; freeTick SimplifierDone
 215         ; return (getFloats env2) }
 216   where
 217         -- We need to track the zapped top-level binders, because
 218         -- they should have their fragile IdInfo zapped (notably occurrence info)
 219         -- That's why we run down binds and bndrs' simultaneously.
 220         --
 221         -- The dump-flag emits a trace for each top-level binding, which
 222         -- helps to locate the tracing for inlining and rule firing
 223     simpl_binds :: Bool -> SimplEnv -> [InBind] -> SimplM SimplEnv
 224     simpl_binds _    env []           = return env
 225     simpl_binds dump env (bind:binds) = do { env' <- trace_bind dump bind $
 226                                                      simpl_bind env bind
 227                                            ; simpl_binds dump env' binds }
 228
 229     trace_bind True  bind = pprTrace "SimplBind" (ppr (bindersOf bind))
 230     trace_bind False _    = \x -> x
 231
 232     simpl_bind env (Rec pairs)  = simplRecBind      env  TopLevel pairs
 233     simpl_bind env (NonRec b r) = simplRecOrTopPair env' TopLevel b b' r
 234         where
 235           (env', b') = addBndrRules env b (lookupRecBndr env b)
 236 \end{code}
 237
 238
 239 %************************************************************************
 240 %*                                                                      *
 241 \subsection{Lazy bindings}
 242 %*                                                                      *
 243 %************************************************************************
 244
 245 simplRecBind is used for
 246         * recursive bindings only
 247
 248 \begin{code}
 249 simplRecBind :: SimplEnv -> TopLevelFlag
 250              -> [(InId, InExpr)]
 251              -> SimplM SimplEnv
 252 simplRecBind env0 top_lvl pairs0
 253   = do  { let (env_with_info, triples) = mapAccumL add_rules env0 pairs0
 254         ; env1 <- go (zapFloats env_with_info) triples
 255         ; return (env0 `addRecFloats` env1) }
 256         -- addFloats adds the floats from env1,
 257         -- _and_ updates env0 with the in-scope set from env1
 258   where
 259     add_rules :: SimplEnv -> (InBndr,InExpr) -> (SimplEnv, (InBndr, OutBndr, InExpr))
 260         -- Add the (substituted) rules to the binder
 261     add_rules env (bndr, rhs) = (env', (bndr, bndr', rhs))
 262         where
 263           (env', bndr') = addBndrRules env bndr (lookupRecBndr env bndr)
 264
 265     go env [] = return env
 266
 267     go env ((old_bndr, new_bndr, rhs) : pairs)
 268         = do { env' <- simplRecOrTopPair env top_lvl old_bndr new_bndr rhs
 269              ; go env' pairs }
 270 \end{code}
 271
 272 simplOrTopPair is used for
 273         * recursive bindings (whether top level or not)
 274         * top-level non-recursive bindings
 275
 276 It assumes the binder has already been simplified, but not its IdInfo.
 277
 278 \begin{code}
 279 simplRecOrTopPair :: SimplEnv
 280                   -> TopLevelFlag
 281                   -> InId -> OutBndr -> InExpr  -- Binder and rhs
 282                   -> SimplM SimplEnv    -- Returns an env that includes the binding
 283
 284 simplRecOrTopPair env top_lvl old_bndr new_bndr rhs
 285   | preInlineUnconditionally env top_lvl old_bndr rhs   -- Check for unconditional inline
 286   = do  { tick (PreInlineUnconditionally old_bndr)
 287         ; return (extendIdSubst env old_bndr (mkContEx env rhs)) }
 288
 289   | otherwise
 290   = simplLazyBind env top_lvl Recursive old_bndr new_bndr rhs env
 291         -- May not actually be recursive, but it doesn't matter
 292 \end{code}
 293
 294
 295 simplLazyBind is used for
 296   * [simplRecOrTopPair] recursive bindings (whether top level or not)
 297   * [simplRecOrTopPair] top-level non-recursive bindings
 298   * [simplNonRecE]      non-top-level *lazy* non-recursive bindings
 299
 300 Nota bene:
 301     1. It assumes that the binder is *already* simplified,
 302        and is in scope, and its IdInfo too, except unfolding
 303
 304     2. It assumes that the binder type is lifted.
 305
 306     3. It does not check for pre-inline-unconditionallly;
 307        that should have been done already.
 308
 309 \begin{code}
 310 simplLazyBind :: SimplEnv
 311               -> TopLevelFlag -> RecFlag
 312               -> InId -> OutId          -- Binder, both pre-and post simpl
 313                                         -- The OutId has IdInfo, except arity, unfolding
 314               -> InExpr -> SimplEnv     -- The RHS and its environment
 315               -> SimplM SimplEnv
 316
 317 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 318   = do  { let   rhs_env     = rhs_se `setInScope` env
 319                 (tvs, body) = case collectTyBinders rhs of
 320                                 (tvs, body) | not_lam body -> (tvs,body)
 321                                             | otherwise    -> ([], rhs)
 322                 not_lam (Lam _ _) = False
 323                 not_lam _         = True
 324                         -- Do not do the "abstract tyyvar" thing if there's
 325                         -- a lambda inside, becuase it defeats eta-reduction
 326                         --    f = /\a. \x. g a x
 327                         -- should eta-reduce
 328
 329         ; (body_env, tvs') <- simplBinders rhs_env tvs
 330                 -- See Note [Floating and type abstraction] in SimplUtils
 331
 332         -- Simplify the RHS
 333         ; (body_env1, body1) <- simplExprF body_env body mkBoringStop
 334
 335         -- ANF-ise a constructor or PAP rhs
 336         ; (body_env2, body2) <- prepareRhs body_env1 body1
 337
 338         ; (env', rhs')
 339             <-  if not (doFloatFromRhs top_lvl is_rec False body2 body_env2)
 340                 then                            -- No floating, just wrap up!
 341                      do { rhs' <- mkLam tvs' (wrapFloats body_env2 body2)
 342                         ; return (env, rhs') }
 343
 344                 else if null tvs then           -- Simple floating
 345                      do { tick LetFloatFromLet
 346                         ; return (addFloats env body_env2, body2) }
 347
 348                 else                            -- Do type-abstraction first
 349                      do { tick LetFloatFromLet
 350                         ; (poly_binds, body3) <- abstractFloats tvs' body_env2 body2
 351                         ; rhs' <- mkLam tvs' body3
 352                         ; let env' = foldl (addPolyBind top_lvl) env poly_binds
 353                         ; return (env', rhs') }
 354
 355         ; completeBind env' top_lvl bndr bndr1 rhs' }
 356 \end{code}
 357
 358 A specialised variant of simplNonRec used when the RHS is already simplified,
 359 notably in knownCon.  It uses case-binding where necessary.
 360
 361 \begin{code}
 362 simplNonRecX :: SimplEnv
 363              -> InId            -- Old binder
 364              -> OutExpr         -- Simplified RHS
 365              -> SimplM SimplEnv
 366
 367 simplNonRecX env bndr new_rhs
 368   = do  { (env', bndr') <- simplBinder env bndr
 369         ; completeNonRecX env' (isStrictId bndr) bndr bndr' new_rhs }
 370
 371 completeNonRecX :: SimplEnv
 372                 -> Bool
 373                 -> InId                 -- Old binder
 374                 -> OutId                -- New binder
 375                 -> OutExpr              -- Simplified RHS
 376                 -> SimplM SimplEnv
 377
 378 completeNonRecX env is_strict old_bndr new_bndr new_rhs
 379   = do  { (env1, rhs1) <- prepareRhs (zapFloats env) new_rhs
 380         ; (env2, rhs2) <-
 381                 if doFloatFromRhs NotTopLevel NonRecursive is_strict rhs1 env1
 382                 then do { tick LetFloatFromLet
 383                         ; return (addFloats env env1, rhs1) }   -- Add the floats to the main env
 384                 else return (env, wrapFloats env1 rhs1)         -- Wrap the floats around the RHS
 385         ; completeBind env2 NotTopLevel old_bndr new_bndr rhs2 }
 386 \end{code}
 387
 388 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
 389    Doing so risks exponential behaviour, because new_rhs has been simplified once already
 390    In the cases described by the folowing commment, postInlineUnconditionally will
 391    catch many of the relevant cases.
 392         -- This happens; for example, the case_bndr during case of
 393         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 394         -- Here x isn't mentioned in the RHS, so we don't want to
 395         -- create the (dead) let-binding  let x = (a,b) in ...
 396         --
 397         -- Similarly, single occurrences can be inlined vigourously
 398         -- e.g.  case (f x, g y) of (a,b) -> ....
 399         -- If a,b occur once we can avoid constructing the let binding for them.
 400
 401    Furthermore in the case-binding case preInlineUnconditionally risks extra thunks
 402         -- Consider     case I# (quotInt# x y) of
 403         --                I# v -> let w = J# v in ...
 404         -- If we gaily inline (quotInt# x y) for v, we end up building an
 405         -- extra thunk:
 406         --                let w = J# (quotInt# x y) in ...
 407         -- because quotInt# can fail.
 408
 409   | preInlineUnconditionally env NotTopLevel bndr new_rhs
 410   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
 411 -}
 412
 413 ----------------------------------
 414 prepareRhs takes a putative RHS, checks whether it's a PAP or
 415 constructor application and, if so, converts it to ANF, so that the
 416 resulting thing can be inlined more easily.  Thus
 417         x = (f a, g b)
 418 becomes
 419         t1 = f a
 420         t2 = g b
 421         x = (t1,t2)
 422
 423 We also want to deal well cases like this
 424         v = (f e1 `cast` co) e2
 425 Here we want to make e1,e2 trivial and get
 426         x1 = e1; x2 = e2; v = (f x1 `cast` co) v2
 427 That's what the 'go' loop in prepareRhs does
 428
 429 \begin{code}
 430 prepareRhs :: SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
 431 -- Adds new floats to the env iff that allows us to return a good RHS
 432 prepareRhs env (Cast rhs co)    -- Note [Float coercions]
 433   | (ty1, _ty2) <- coercionKind co       -- Do *not* do this if rhs has an unlifted type
 434   , not (isUnLiftedType ty1)            -- see Note [Float coercions (unlifted)]
 435   = do  { (env', rhs') <- makeTrivial env rhs
 436         ; return (env', Cast rhs' co) }
 437
 438 prepareRhs env0 rhs0
 439   = do  { (_is_val, env1, rhs1) <- go 0 env0 rhs0
 440         ; return (env1, rhs1) }
 441   where
 442     go n_val_args env (Cast rhs co)
 443         = do { (is_val, env', rhs') <- go n_val_args env rhs
 444              ; return (is_val, env', Cast rhs' co) }
 445     go n_val_args env (App fun (Type ty))
 446         = do { (is_val, env', rhs') <- go n_val_args env fun
 447              ; return (is_val, env', App rhs' (Type ty)) }
 448     go n_val_args env (App fun arg)
 449         = do { (is_val, env', fun') <- go (n_val_args+1) env fun
 450              ; case is_val of
 451                 True -> do { (env'', arg') <- makeTrivial env' arg
 452                            ; return (True, env'', App fun' arg') }
 453                 False -> return (False, env, App fun arg) }
 454     go n_val_args env (Var fun)
 455         = return (is_val, env, Var fun)
 456         where
 457           is_val = n_val_args > 0       -- There is at least one arg
 458                                         -- ...and the fun a constructor or PAP
 459                  && (isDataConWorkId fun || n_val_args < idArity fun)
 460     go _ env other
 461         = return (False, env, other)
 462 \end{code}
 463
 464
 465 Note [Float coercions]
 466 ~~~~~~~~~~~~~~~~~~~~~~
 467 When we find the binding
 468         x = e `cast` co
 469 we'd like to transform it to
 470         x' = e
 471         x = x `cast` co         -- A trivial binding
 472 There's a chance that e will be a constructor application or function, or something
 473 like that, so moving the coerion to the usage site may well cancel the coersions
 474 and lead to further optimisation.  Example:
 475
 476      data family T a :: *
 477      data instance T Int = T Int
 478
 479      foo :: Int -> Int -> Int
 480      foo m n = ...
 481         where
 482           x = T m
 483           go 0 = 0
 484           go n = case x of { T m -> go (n-m) }
 485                 -- This case should optimise
 486
 487 Note [Float coercions (unlifted)]
 488 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 489 BUT don't do [Float coercions] if 'e' has an unlifted type.
 490 This *can* happen:
 491
 492      foo :: Int = (error (# Int,Int #) "urk")
 493                   `cast` CoUnsafe (# Int,Int #) Int
 494
 495 If do the makeTrivial thing to the error call, we'll get
 496     foo = case error (# Int,Int #) "urk" of v -> v `cast` ...
 497 But 'v' isn't in scope!
 498
 499 These strange casts can happen as a result of case-of-case
 500         bar = case (case x of { T -> (# 2,3 #); F -> error "urk" }) of
 501                 (# p,q #) -> p+q
 502
 503
 504 \begin{code}
 505 makeTrivial :: SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
 506 -- Binds the expression to a variable, if it's not trivial, returning the variable
 507 makeTrivial env expr
 508   | exprIsTrivial expr
 509   = return (env, expr)
 510   | otherwise           -- See Note [Take care] below
 511   = do  { var <- newId (fsLit "a") (exprType expr)
 512         ; env' <- completeNonRecX env False var var expr
 513         ; return (env', substExpr env' (Var var)) }
 514 \end{code}
 515
 516
 517 %************************************************************************
 518 %*                                                                      *
 519 \subsection{Completing a lazy binding}
 520 %*                                                                      *
 521 %************************************************************************
 522
 523 completeBind
 524   * deals only with Ids, not TyVars
 525   * takes an already-simplified binder and RHS
 526   * is used for both recursive and non-recursive bindings
 527   * is used for both top-level and non-top-level bindings
 528
 529 It does the following:
 530   - tries discarding a dead binding
 531   - tries PostInlineUnconditionally
 532   - add unfolding [this is the only place we add an unfolding]
 533   - add arity
 534
 535 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 536   - top-level bindings (when let-to-case is impossible)
 537   - many situations where the "rhs" is known to be a WHNF
 538                 (so let-to-case is inappropriate).
 539
 540 Nor does it do the atomic-argument thing
 541
 542 \begin{code}
 543 completeBind :: SimplEnv
 544              -> TopLevelFlag            -- Flag stuck into unfolding
 545              -> InId                    -- Old binder
 546              -> OutId -> OutExpr        -- New binder and RHS
 547              -> SimplM SimplEnv
 548 -- completeBind may choose to do its work
 549 --      * by extending the substitution (e.g. let x = y in ...)
 550 --      * or by adding to the floats in the envt
 551
 552 completeBind env top_lvl old_bndr new_bndr new_rhs
 553   | postInlineUnconditionally env top_lvl new_bndr occ_info new_rhs unfolding
 554                 -- Inline and discard the binding
 555   = do  { tick (PostInlineUnconditionally old_bndr)
 556         ; -- pprTrace "postInlineUnconditionally" (ppr old_bndr <+> ppr new_bndr <+> ppr new_rhs) $
 557           return (extendIdSubst env old_bndr (DoneEx new_rhs)) }
 558         -- Use the substitution to make quite, quite sure that the
 559         -- substitution will happen, since we are going to discard the binding
 560
 561   | otherwise
 562   = return (addNonRecWithUnf env new_bndr new_rhs unfolding wkr)
 563   where
 564     unfolding | omit_unfolding = NoUnfolding
 565               | otherwise      = mkUnfolding  (isTopLevel top_lvl) new_rhs
 566     old_info    = idInfo old_bndr
 567     occ_info    = occInfo old_info
 568     wkr         = substWorker env (workerInfo old_info)
 569     omit_unfolding = isNonRuleLoopBreaker occ_info
 570                    --       or not (activeInline env old_bndr)
 571                    -- Do *not* trim the unfolding in SimplGently, else
 572                    -- the specialiser can't see it!
 573
 574 -----------------
 575 addPolyBind :: TopLevelFlag -> SimplEnv -> OutBind -> SimplEnv
 576 -- Add a new binding to the environment, complete with its unfolding
 577 -- but *do not* do postInlineUnconditionally, because we have already
 578 -- processed some of the scope of the binding
 579 -- We still want the unfolding though.  Consider
 580 --      let
 581 --            x = /\a. let y = ... in Just y
 582 --      in body
 583 -- Then we float the y-binding out (via abstractFloats and addPolyBind)
 584 -- but 'x' may well then be inlined in 'body' in which case we'd like the
 585 -- opportunity to inline 'y' too.
 586
 587 addPolyBind top_lvl env (NonRec poly_id rhs)
 588   = addNonRecWithUnf env poly_id rhs unfolding NoWorker
 589   where
 590     unfolding | not (activeInline env poly_id) = NoUnfolding
 591               | otherwise                      = mkUnfolding (isTopLevel top_lvl) rhs
 592                 -- addNonRecWithInfo adds the new binding in the
 593                 -- proper way (ie complete with unfolding etc),
 594                 -- and extends the in-scope set
 595
 596 addPolyBind _ env bind@(Rec _) = extendFloats env bind
 597                 -- Hack: letrecs are more awkward, so we extend "by steam"
 598                 -- without adding unfoldings etc.  At worst this leads to
 599                 -- more simplifier iterations
 600
 601 -----------------
 602 addNonRecWithUnf :: SimplEnv
 603                   -> OutId -> OutExpr        -- New binder and RHS
 604                   -> Unfolding -> WorkerInfo -- and unfolding
 605                   -> SimplEnv
 606 -- Add suitable IdInfo to the Id, add the binding to the floats, and extend the in-scope set
 607 addNonRecWithUnf env new_bndr rhs unfolding wkr
 608   = ASSERT( isId new_bndr )
 609     final_id `seq`      -- This seq forces the Id, and hence its IdInfo,
 610                         -- and hence any inner substitutions
 611     addNonRec env final_id rhs
 612         -- The addNonRec adds it to the in-scope set too
 613   where
 614         --      Arity info
 615         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity rhs
 616
 617         --      Unfolding info
 618         -- Add the unfolding *only* for non-loop-breakers
 619         -- Making loop breakers not have an unfolding at all
 620         -- means that we can avoid tests in exprIsConApp, for example.
 621         -- This is important: if exprIsConApp says 'yes' for a recursive
 622         -- thing, then we can get into an infinite loop
 623
 624         --      Demand info
 625         -- If the unfolding is a value, the demand info may
 626         -- go pear-shaped, so we nuke it.  Example:
 627         --      let x = (a,b) in
 628         --      case x of (p,q) -> h p q x
 629         -- Here x is certainly demanded. But after we've nuked
 630         -- the case, we'll get just
 631         --      let x = (a,b) in h a b x
 632         -- and now x is not demanded (I'm assuming h is lazy)
 633         -- This really happens.  Similarly
 634         --      let f = \x -> e in ...f..f...
 635         -- After inlining f at some of its call sites the original binding may
 636         -- (for example) be no longer strictly demanded.
 637         -- The solution here is a bit ad hoc...
 638         info_w_unf = new_bndr_info `setUnfoldingInfo` unfolding
 639                                    `setWorkerInfo`    wkr
 640
 641         final_info | isEvaldUnfolding unfolding = zapDemandInfo info_w_unf `orElse` info_w_unf
 642                    | otherwise                  = info_w_unf
 643
 644         final_id = new_bndr `setIdInfo` final_info
 645 \end{code}
 646
 647
 648
 649 %************************************************************************
 650 %*                                                                      *
 651 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 652 %*                                                                      *
 653 %************************************************************************
 654
 655 The reason for this OutExprStuff stuff is that we want to float *after*
 656 simplifying a RHS, not before.  If we do so naively we get quadratic
 657 behaviour as things float out.
 658
 659 To see why it's important to do it after, consider this (real) example:
 660
 661         let t = f x
 662         in fst t
 663 ==>
 664         let t = let a = e1
 665                     b = e2
 666                 in (a,b)
 667         in fst t
 668 ==>
 669         let a = e1
 670             b = e2
 671             t = (a,b)
 672         in
 673         a       -- Can't inline a this round, cos it appears twice
 674 ==>
 675         e1
 676
 677 Each of the ==> steps is a round of simplification.  We'd save a
 678 whole round if we float first.  This can cascade.  Consider
 679
 680         let f = g d
 681         in \x -> ...f...
 682 ==>
 683         let f = let d1 = ..d.. in \y -> e
 684         in \x -> ...f...
 685 ==>
 686         let d1 = ..d..
 687         in \x -> ...(\y ->e)...
 688
 689 Only in this second round can the \y be applied, and it
 690 might do the same again.
 691
 692
 693 \begin{code}
 694 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 695 simplExpr env expr = simplExprC env expr mkBoringStop
 696
 697 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 698         -- Simplify an expression, given a continuation
 699 simplExprC env expr cont
 700   = -- pprTrace "simplExprC" (ppr expr $$ ppr cont {- $$ ppr (seIdSubst env) -} $$ ppr (seFloats env) ) $
 701     do  { (env', expr') <- simplExprF (zapFloats env) expr cont
 702         ; -- pprTrace "simplExprC ret" (ppr expr $$ ppr expr') $
 703           -- pprTrace "simplExprC ret3" (ppr (seInScope env')) $
 704           -- pprTrace "simplExprC ret4" (ppr (seFloats env')) $
 705           return (wrapFloats env' expr') }
 706
 707 --------------------------------------------------
 708 simplExprF :: SimplEnv -> InExpr -> SimplCont
 709            -> SimplM (SimplEnv, OutExpr)
 710
 711 simplExprF env e cont
 712   = -- pprTrace "simplExprF" (ppr e $$ ppr cont $$ ppr (seTvSubst env) $$ ppr (seIdSubst env) {- $$ ppr (seFloats env) -} ) $
 713     simplExprF' env e cont
 714
 715 simplExprF' :: SimplEnv -> InExpr -> SimplCont
 716             -> SimplM (SimplEnv, OutExpr)
 717 simplExprF' env (Var v)        cont = simplVar env v cont
 718 simplExprF' env (Lit lit)      cont = rebuild env (Lit lit) cont
 719 simplExprF' env (Note n expr)  cont = simplNote env n expr cont
 720 simplExprF' env (Cast body co) cont = simplCast env body co cont
 721 simplExprF' env (App fun arg)  cont = simplExprF env fun $
 722                                       ApplyTo NoDup arg env cont
 723
 724 simplExprF' env expr@(Lam _ _) cont
 725   = simplLam env (map zap bndrs) body cont
 726         -- The main issue here is under-saturated lambdas
 727         --   (\x1. \x2. e) arg1
 728         -- Here x1 might have "occurs-once" occ-info, because occ-info
 729         -- is computed assuming that a group of lambdas is applied
 730         -- all at once.  If there are too few args, we must zap the
 731         -- occ-info.
 732   where
 733     n_args   = countArgs cont
 734     n_params = length bndrs
 735     (bndrs, body) = collectBinders expr
 736     zap | n_args >= n_params = \b -> b
 737         | otherwise          = \b -> if isTyVar b then b
 738                                      else zapLamIdInfo b
 739         -- NB: we count all the args incl type args
 740         -- so we must count all the binders (incl type lambdas)
 741
 742 simplExprF' env (Type ty) cont
 743   = ASSERT( contIsRhsOrArg cont )
 744     do  { ty' <- simplType env ty
 745         ; rebuild env (Type ty') cont }
 746
 747 simplExprF' env (Case scrut bndr _ alts) cont
 748   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 749   =     -- Simplify the scrutinee with a Select continuation
 750     simplExprF env scrut (Select NoDup bndr alts env cont)
 751
 752   | otherwise
 753   =     -- If case-of-case is off, simply simplify the case expression
 754         -- in a vanilla Stop context, and rebuild the result around it
 755     do  { case_expr' <- simplExprC env scrut case_cont
 756         ; rebuild env case_expr' cont }
 757   where
 758     case_cont = Select NoDup bndr alts env mkBoringStop
 759
 760 simplExprF' env (Let (Rec pairs) body) cont
 761   = do  { env' <- simplRecBndrs env (map fst pairs)
 762                 -- NB: bndrs' don't have unfoldings or rules
 763                 -- We add them as we go down
 764
 765         ; env'' <- simplRecBind env' NotTopLevel pairs
 766         ; simplExprF env'' body cont }
 767
 768 simplExprF' env (Let (NonRec bndr rhs) body) cont
 769   = simplNonRecE env bndr (rhs, env) ([], body) cont
 770
 771 ---------------------------------
 772 simplType :: SimplEnv -> InType -> SimplM OutType
 773         -- Kept monadic just so we can do the seqType
 774 simplType env ty
 775   = -- pprTrace "simplType" (ppr ty $$ ppr (seTvSubst env)) $
 776     seqType new_ty   `seq`   return new_ty
 777   where
 778     new_ty = substTy env ty
 779 \end{code}
 780
 781
 782 %************************************************************************
 783 %*                                                                      *
 784 \subsection{The main rebuilder}
 785 %*                                                                      *
 786 %************************************************************************
 787
 788 \begin{code}
 789 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM (SimplEnv, OutExpr)
 790 -- At this point the substitution in the SimplEnv should be irrelevant
 791 -- only the in-scope set and floats should matter
 792 rebuild env expr cont0
 793   = -- pprTrace "rebuild" (ppr expr $$ ppr cont0 $$ ppr (seFloats env)) $
 794     case cont0 of
 795       Stop {}                      -> return (env, expr)
 796       CoerceIt co cont             -> rebuild env (mkCoerce co expr) cont
 797       Select _ bndr alts se cont   -> rebuildCase (se `setFloats` env) expr bndr alts cont
 798       StrictArg fun _ info cont    -> rebuildCall env (fun `App` expr) info cont
 799       StrictBind b bs body se cont -> do { env' <- simplNonRecX (se `setFloats` env) b expr
 800                                          ; simplLam env' bs body cont }
 801       ApplyTo _ arg se cont        -> do { arg' <- simplExpr (se `setInScope` env) arg
 802                                          ; rebuild env (App expr arg') cont }
 803 \end{code}
 804
 805
 806 %************************************************************************
 807 %*                                                                      *
 808 \subsection{Lambdas}
 809 %*                                                                      *
 810 %************************************************************************
 811
 812 \begin{code}
 813 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont
 814           -> SimplM (SimplEnv, OutExpr)
 815 simplCast env body co0 cont0
 816   = do  { co1 <- simplType env co0
 817         ; simplExprF env body (addCoerce co1 cont0) }
 818   where
 819        addCoerce co cont = add_coerce co (coercionKind co) cont
 820
 821        add_coerce _co (s1, k1) cont     -- co :: ty~ty
 822          | s1 `coreEqType` k1 = cont    -- is a no-op
 823
 824        add_coerce co1 (s1, _k2) (CoerceIt co2 cont)
 825          | (_l1, t1) <- coercionKind co2
 826                 --      e |> (g1 :: S1~L) |> (g2 :: L~T1)
 827                 -- ==>
 828                 --      e,                       if T1=T2
 829                 --      e |> (g1 . g2 :: T1~T2)  otherwise
 830                 --
 831                 -- For example, in the initial form of a worker
 832                 -- we may find  (coerce T (coerce S (\x.e))) y
 833                 -- and we'd like it to simplify to e[y/x] in one round
 834                 -- of simplification
 835          , s1 `coreEqType` t1  = cont            -- The coerces cancel out
 836          | otherwise           = CoerceIt (mkTransCoercion co1 co2) cont
 837
 838        add_coerce co (s1s2, _t1t2) (ApplyTo dup (Type arg_ty) arg_se cont)
 839                 -- (f |> g) ty  --->   (f ty) |> (g @ ty)
 840                 -- This implements the PushT rule from the paper
 841          | Just (tyvar,_) <- splitForAllTy_maybe s1s2
 842          , not (isCoVar tyvar)
 843          = ApplyTo dup (Type ty') (zapSubstEnv env) (addCoerce (mkInstCoercion co ty') cont)
 844          where
 845            ty' = substTy (arg_se `setInScope` env) arg_ty
 846
 847         -- ToDo: the PushC rule is not implemented at all
 848
 849        add_coerce co (s1s2, _t1t2) (ApplyTo dup arg arg_se cont)
 850          | not (isTypeArg arg)  -- This implements the Push rule from the paper
 851          , isFunTy s1s2   -- t1t2 must be a function type, becuase it's applied
 852                 --      (e |> (g :: s1s2 ~ t1->t2)) f
 853                 -- ===>
 854                 --      (e (f |> (arg g :: t1~s1))
 855                 --      |> (res g :: s2->t2)
 856                 --
 857                 -- t1t2 must be a function type, t1->t2, because it's applied
 858                 -- to something but s1s2 might conceivably not be
 859                 --
 860                 -- When we build the ApplyTo we can't mix the out-types
 861                 -- with the InExpr in the argument, so we simply substitute
 862                 -- to make it all consistent.  It's a bit messy.
 863                 -- But it isn't a common case.
 864                 --
 865                 -- Example of use: Trac #995
 866          = ApplyTo dup new_arg (zapSubstEnv env) (addCoerce co2 cont)
 867          where
 868            -- we split coercion t1->t2 ~ s1->s2 into t1 ~ s1 and
 869            -- t2 ~ s2 with left and right on the curried form:
 870            --    (->) t1 t2 ~ (->) s1 s2
 871            [co1, co2] = decomposeCo 2 co
 872            new_arg    = mkCoerce (mkSymCoercion co1) arg'
 873            arg'       = substExpr (arg_se `setInScope` env) arg
 874
 875        add_coerce co _ cont = CoerceIt co cont
 876 \end{code}
 877
 878
 879 %************************************************************************
 880 %*                                                                      *
 881 \subsection{Lambdas}
 882 %*                                                                      *
 883 %************************************************************************
 884
 885 \begin{code}
 886 simplLam :: SimplEnv -> [InId] -> InExpr -> SimplCont
 887          -> SimplM (SimplEnv, OutExpr)
 888
 889 simplLam env [] body cont = simplExprF env body cont
 890
 891         -- Beta reduction
 892 simplLam env (bndr:bndrs) body (ApplyTo _ arg arg_se cont)
 893   = do  { tick (BetaReduction bndr)
 894         ; simplNonRecE env bndr (arg, arg_se) (bndrs, body) cont }
 895
 896         -- Not enough args, so there are real lambdas left to put in the result
 897 simplLam env bndrs body cont
 898   = do  { (env', bndrs') <- simplLamBndrs env bndrs
 899         ; body' <- simplExpr env' body
 900         ; new_lam <- mkLam bndrs' body'
 901         ; rebuild env' new_lam cont }
 902
 903 ------------------
 904 simplNonRecE :: SimplEnv
 905              -> InId                    -- The binder
 906              -> (InExpr, SimplEnv)      -- Rhs of binding (or arg of lambda)
 907              -> ([InBndr], InExpr)      -- Body of the let/lambda
 908                                         --      \xs.e
 909              -> SimplCont
 910              -> SimplM (SimplEnv, OutExpr)
 911
 912 -- simplNonRecE is used for
 913 --  * non-top-level non-recursive lets in expressions
 914 --  * beta reduction
 915 --
 916 -- It deals with strict bindings, via the StrictBind continuation,
 917 -- which may abort the whole process
 918 --
 919 -- The "body" of the binding comes as a pair of ([InId],InExpr)
 920 -- representing a lambda; so we recurse back to simplLam
 921 -- Why?  Because of the binder-occ-info-zapping done before
 922 --       the call to simplLam in simplExprF (Lam ...)
 923
 924         -- First deal with type applications and type lets
 925         --   (/\a. e) (Type ty)   and   (let a = Type ty in e)
 926 simplNonRecE env bndr (Type ty_arg, rhs_se) (bndrs, body) cont
 927   = ASSERT( isTyVar bndr )
 928     do  { ty_arg' <- simplType (rhs_se `setInScope` env) ty_arg
 929         ; simplLam (extendTvSubst env bndr ty_arg') bndrs body cont }
 930
 931 simplNonRecE env bndr (rhs, rhs_se) (bndrs, body) cont
 932   | preInlineUnconditionally env NotTopLevel bndr rhs
 933   = do  { tick (PreInlineUnconditionally bndr)
 934         ; simplLam (extendIdSubst env bndr (mkContEx rhs_se rhs)) bndrs body cont }
 935
 936   | isStrictId bndr
 937   = do  { simplExprF (rhs_se `setFloats` env) rhs
 938                      (StrictBind bndr bndrs body env cont) }
 939
 940   | otherwise
 941   = ASSERT( not (isTyVar bndr) )
 942     do  { (env1, bndr1) <- simplNonRecBndr env bndr
 943         ; let (env2, bndr2) = addBndrRules env1 bndr bndr1
 944         ; env3 <- simplLazyBind env2 NotTopLevel NonRecursive bndr bndr2 rhs rhs_se
 945         ; simplLam env3 bndrs body cont }
 946 \end{code}
 947
 948
 949 %************************************************************************
 950 %*                                                                      *
 951 \subsection{Notes}
 952 %*                                                                      *
 953 %************************************************************************
 954
 955 \begin{code}
 956 -- Hack alert: we only distinguish subsumed cost centre stacks for the
 957 -- purposes of inlining.  All other CCCSs are mapped to currentCCS.
 958 simplNote :: SimplEnv -> Note -> CoreExpr -> SimplCont
 959           -> SimplM (SimplEnv, OutExpr)
 960 simplNote env (SCC cc) e cont
 961   = do  { e' <- simplExpr (setEnclosingCC env currentCCS) e
 962         ; rebuild env (mkSCC cc e') cont }
 963
 964 -- See notes with SimplMonad.inlineMode
 965 simplNote env InlineMe e cont
 966   | Just (inside, outside) <- splitInlineCont cont  -- Boring boring continuation; see notes above
 967   = do  {                       -- Don't inline inside an INLINE expression
 968           e' <- simplExprC (setMode inlineMode env) e inside
 969         ; rebuild env (mkInlineMe e') outside }
 970
 971   | otherwise   -- Dissolve the InlineMe note if there's
 972                 -- an interesting context of any kind to combine with
 973                 -- (even a type application -- anything except Stop)
 974   = simplExprF env e cont
 975
 976 simplNote env (CoreNote s) e cont = do
 977     e' <- simplExpr env e
 978     rebuild env (Note (CoreNote s) e') cont
 979 \end{code}
 980
 981
 982 %************************************************************************
 983 %*                                                                      *
 984 \subsection{Dealing with calls}
 985 %*                                                                      *
 986 %************************************************************************
 987
 988 \begin{code}
 989 simplVar :: SimplEnv -> Id -> SimplCont -> SimplM (SimplEnv, OutExpr)
 990 simplVar env var cont
 991   = case substId env var of
 992         DoneEx e         -> simplExprF (zapSubstEnv env) e cont
 993         ContEx tvs ids e -> simplExprF (setSubstEnv env tvs ids) e cont
 994         DoneId var1      -> completeCall (zapSubstEnv env) var1 cont
 995                 -- Note [zapSubstEnv]
 996                 -- The template is already simplified, so don't re-substitute.
 997                 -- This is VITAL.  Consider
 998                 --      let x = e in
 999                 --      let y = \z -> ...x... in
1000                 --      \ x -> ...y...
1001                 -- We'll clone the inner \x, adding x->x' in the id_subst
1002                 -- Then when we inline y, we must *not* replace x by x' in
1003                 -- the inlined copy!!
1004
1005 ---------------------------------------------------------
1006 --      Dealing with a call site
1007
1008 completeCall :: SimplEnv -> Id -> SimplCont -> SimplM (SimplEnv, OutExpr)
1009 completeCall env var cont
1010   = do  { dflags <- getDOptsSmpl
1011         ; let   (args,call_cont) = contArgs cont
1012                 -- The args are OutExprs, obtained by *lazily* substituting
1013                 -- in the args found in cont.  These args are only examined
1014                 -- to limited depth (unless a rule fires).  But we must do
1015                 -- the substitution; rule matching on un-simplified args would
1016                 -- be bogus
1017
1018         ------------- First try rules ----------------
1019         -- Do this before trying inlining.  Some functions have
1020         -- rules *and* are strict; in this case, we don't want to
1021         -- inline the wrapper of the non-specialised thing; better
1022         -- to call the specialised thing instead.
1023         --
1024         -- We used to use the black-listing mechanism to ensure that inlining of
1025         -- the wrapper didn't occur for things that have specialisations till a
1026         -- later phase, so but now we just try RULES first
1027         --
1028         -- Note [Rules for recursive functions]
1029         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1030         -- You might think that we shouldn't apply rules for a loop breaker:
1031         -- doing so might give rise to an infinite loop, because a RULE is
1032         -- rather like an extra equation for the function:
1033         --      RULE:           f (g x) y = x+y
1034         --      Eqn:            f a     y = a-y
1035         --
1036         -- But it's too drastic to disable rules for loop breakers.
1037         -- Even the foldr/build rule would be disabled, because foldr
1038         -- is recursive, and hence a loop breaker:
1039         --      foldr k z (build g) = g k z
1040         -- So it's up to the programmer: rules can cause divergence
1041         ; rule_base <- getSimplRules
1042         ; let   in_scope   = getInScope env
1043                 rules      = getRules rule_base var
1044                 maybe_rule = case activeRule dflags env of
1045                                 Nothing     -> Nothing  -- No rules apply
1046                                 Just act_fn -> lookupRule act_fn in_scope
1047                                                           var args rules
1048         ; case maybe_rule of {
1049             Just (rule, rule_rhs) -> do
1050                 tick (RuleFired (ru_name rule))
1051                 (if dopt Opt_D_dump_rule_firings dflags then
1052                    pprTrace "Rule fired" (vcat [
1053                         text "Rule:" <+> ftext (ru_name rule),
1054                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
1055                         text "After: " <+> pprCoreExpr rule_rhs,
1056                         text "Cont:  " <+> ppr call_cont])
1057                  else
1058                         id)             $
1059                  simplExprF env rule_rhs (dropArgs (ruleArity rule) cont)
1060                  -- The ruleArity says how many args the rule consumed
1061
1062           ; Nothing -> do       -- No rules
1063
1064         ------------- Next try inlining ----------------
1065         { let   arg_infos = [interestingArg arg | arg <- args, isValArg arg]
1066                 n_val_args = length arg_infos
1067                 interesting_cont = interestingCallContext call_cont
1068                 active_inline = activeInline env var
1069                 maybe_inline  = callSiteInline dflags active_inline var
1070                                                (null args) arg_infos interesting_cont
1071         ; case maybe_inline of {
1072             Just unfolding      -- There is an inlining!
1073               ->  do { tick (UnfoldingDone var)
1074                      ; (if dopt Opt_D_dump_inlinings dflags then
1075                            pprTrace ("Inlining done" ++ showSDoc (ppr var)) (vcat [
1076                                 text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
1077                                 text "Inlined fn: " <+> nest 2 (ppr unfolding),
1078                                 text "Cont:  " <+> ppr call_cont])
1079                          else
1080                                 id)
1081                        simplExprF env unfolding cont }
1082
1083             ; Nothing ->                -- No inlining!
1084
1085         ------------- No inlining! ----------------
1086         -- Next, look for rules or specialisations that match
1087         --
1088         rebuildCall env (Var var)
1089                     (mkArgInfo var n_val_args call_cont) cont
1090     }}}}
1091
1092 rebuildCall :: SimplEnv
1093             -> OutExpr       -- Function
1094             -> ArgInfo
1095             -> SimplCont
1096             -> SimplM (SimplEnv, OutExpr)
1097 rebuildCall env fun (ArgInfo { ai_strs = [] }) cont
1098   -- When we run out of strictness args, it means
1099   -- that the call is definitely bottom; see SimplUtils.mkArgInfo
1100   -- Then we want to discard the entire strict continuation.  E.g.
1101   --    * case (error "hello") of { ... }
1102   --    * (error "Hello") arg
1103   --    * f (error "Hello") where f is strict
1104   --    etc
1105   -- Then, especially in the first of these cases, we'd like to discard
1106   -- the continuation, leaving just the bottoming expression.  But the
1107   -- type might not be right, so we may have to add a coerce.
1108   | not (contIsTrivial cont)     -- Only do this if there is a non-trivial
1109   = return (env, mk_coerce fun)  -- contination to discard, else we do it
1110   where                          -- again and again!
1111     fun_ty  = exprType fun
1112     cont_ty = contResultType env fun_ty cont
1113     co      = mkUnsafeCoercion fun_ty cont_ty
1114     mk_coerce expr | cont_ty `coreEqType` fun_ty = expr
1115                    | otherwise = mkCoerce co expr
1116
1117 rebuildCall env fun info (ApplyTo _ (Type arg_ty) se cont)
1118   = do  { ty' <- simplType (se `setInScope` env) arg_ty
1119         ; rebuildCall env (fun `App` Type ty') info cont }
1120
1121 rebuildCall env fun
1122            (ArgInfo { ai_rules = has_rules, ai_strs = str:strs, ai_discs = disc:discs })
1123            (ApplyTo _ arg arg_se cont)
1124   | str                 -- Strict argument
1125   = -- pprTrace "Strict Arg" (ppr arg $$ ppr (seIdSubst env) $$ ppr (seInScope env)) $
1126     simplExprF (arg_se `setFloats` env) arg
1127                (StrictArg fun cci arg_info' cont)
1128                 -- Note [Shadowing]
1129
1130   | otherwise                           -- Lazy argument
1131         -- DO NOT float anything outside, hence simplExprC
1132         -- There is no benefit (unlike in a let-binding), and we'd
1133         -- have to be very careful about bogus strictness through
1134         -- floating a demanded let.
1135   = do  { arg' <- simplExprC (arg_se `setInScope` env) arg
1136                              (mkLazyArgStop cci)
1137         ; rebuildCall env (fun `App` arg') arg_info' cont }
1138   where
1139     arg_info' = ArgInfo { ai_rules = has_rules, ai_strs = strs, ai_discs = discs }
1140     cci | has_rules || disc > 0 = ArgCtxt has_rules disc  -- Be keener here
1141         | otherwise             = BoringCtxt              -- Nothing interesting
1142
1143 rebuildCall env fun _ cont
1144   = rebuild env fun cont
1145 \end{code}
1146
1147 Note [Shadowing]
1148 ~~~~~~~~~~~~~~~~
1149 This part of the simplifier may break the no-shadowing invariant
1150 Consider
1151         f (...(\a -> e)...) (case y of (a,b) -> e')
1152 where f is strict in its second arg
1153 If we simplify the innermost one first we get (...(\a -> e)...)
1154 Simplifying the second arg makes us float the case out, so we end up with
1155         case y of (a,b) -> f (...(\a -> e)...) e'
1156 So the output does not have the no-shadowing invariant.  However, there is
1157 no danger of getting name-capture, because when the first arg was simplified
1158 we used an in-scope set that at least mentioned all the variables free in its
1159 static environment, and that is enough.
1160
1161 We can't just do innermost first, or we'd end up with a dual problem:
1162         case x of (a,b) -> f e (...(\a -> e')...)
1163
1164 I spent hours trying to recover the no-shadowing invariant, but I just could
1165 not think of an elegant way to do it.  The simplifier is already knee-deep in
1166 continuations.  We have to keep the right in-scope set around; AND we have
1167 to get the effect that finding (error "foo") in a strict arg position will
1168 discard the entire application and replace it with (error "foo").  Getting
1169 all this at once is TOO HARD!
1170
1171 %************************************************************************
1172 %*                                                                      *
1173                 Rebuilding a cse expression
1174 %*                                                                      *
1175 %************************************************************************
1176
1177 Blob of helper functions for the "case-of-something-else" situation.
1178
1179 \begin{code}
1180 ---------------------------------------------------------
1181 --      Eliminate the case if possible
1182
1183 rebuildCase :: SimplEnv
1184             -> OutExpr          -- Scrutinee
1185             -> InId             -- Case binder
1186             -> [InAlt]          -- Alternatives (inceasing order)
1187             -> SimplCont
1188             -> SimplM (SimplEnv, OutExpr)
1189
1190 --------------------------------------------------
1191 --      1. Eliminate the case if there's a known constructor
1192 --------------------------------------------------
1193
1194 rebuildCase env scrut case_bndr alts cont
1195   | Just (con,args) <- exprIsConApp_maybe scrut
1196         -- Works when the scrutinee is a variable with a known unfolding
1197         -- as well as when it's an explicit constructor application
1198   = knownCon env scrut (DataAlt con) args case_bndr alts cont
1199
1200   | Lit lit <- scrut    -- No need for same treatment as constructors
1201                         -- because literals are inlined more vigorously
1202   = knownCon env scrut (LitAlt lit) [] case_bndr alts cont
1203
1204
1205 --------------------------------------------------
1206 --      2. Eliminate the case if scrutinee is evaluated
1207 --------------------------------------------------
1208
1209 rebuildCase env scrut case_bndr [(_, bndrs, rhs)] cont
1210   -- See if we can get rid of the case altogether
1211   -- See the extensive notes on case-elimination above
1212   -- mkCase made sure that if all the alternatives are equal,
1213   -- then there is now only one (DEFAULT) rhs
1214  | all isDeadBinder bndrs       -- bndrs are [InId]
1215
1216         -- Check that the scrutinee can be let-bound instead of case-bound
1217  , exprOkForSpeculation scrut
1218                 -- OK not to evaluate it
1219                 -- This includes things like (==# a# b#)::Bool
1220                 -- so that we simplify
1221                 --      case ==# a# b# of { True -> x; False -> x }
1222                 -- to just
1223                 --      x
1224                 -- This particular example shows up in default methods for
1225                 -- comparision operations (e.g. in (>=) for Int.Int32)
1226         || exprIsHNF scrut                      -- It's already evaluated
1227         || var_demanded_later scrut             -- It'll be demanded later
1228
1229 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1230 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1231 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1232 --      its argument:  case x of { y -> dataToTag# y }
1233 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1234 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1235 --      other problems
1236 --      Also we don't want to discard 'seq's
1237   = do  { tick (CaseElim case_bndr)
1238         ; env' <- simplNonRecX env case_bndr scrut
1239         ; simplExprF env' rhs cont }
1240   where
1241         -- The case binder is going to be evaluated later,
1242         -- and the scrutinee is a simple variable
1243     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1244                                  && not (isTickBoxOp v)
1245                                     -- ugly hack; covering this case is what
1246                                     -- exprOkForSpeculation was intended for.
1247     var_demanded_later _       = False
1248
1249
1250 --------------------------------------------------
1251 --      3. Catch-all case
1252 --------------------------------------------------
1253
1254 rebuildCase env scrut case_bndr alts cont
1255   = do  {       -- Prepare the continuation;
1256                 -- The new subst_env is in place
1257           (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
1258
1259         -- Simplify the alternatives
1260         ; (scrut', case_bndr', alts') <- simplAlts env' scrut case_bndr alts dup_cont
1261
1262         -- Check for empty alternatives
1263         ; if null alts' then
1264                 -- This isn't strictly an error, although it is unusual.
1265                 -- It's possible that the simplifer might "see" that
1266                 -- an inner case has no accessible alternatives before
1267                 -- it "sees" that the entire branch of an outer case is
1268                 -- inaccessible.  So we simply put an error case here instead.
1269             pprTrace "mkCase: null alts" (ppr case_bndr <+> ppr scrut) $
1270             let res_ty' = contResultType env' (substTy env' (coreAltsType alts)) dup_cont
1271                 lit = mkStringLit "Impossible alternative"
1272             in return (env', mkApps (Var rUNTIME_ERROR_ID) [Type res_ty', lit])
1273
1274           else do
1275         { case_expr <- mkCase scrut' case_bndr' alts'
1276
1277         -- Notice that rebuild gets the in-scope set from env, not alt_env
1278         -- The case binder *not* scope over the whole returned case-expression
1279         ; rebuild env' case_expr nodup_cont } }
1280 \end{code}
1281
1282 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1283 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1284 way, there's a chance that v will now only be used once, and hence
1285 inlined.
1286
1287 Note [no-case-of-case]
1288 ~~~~~~~~~~~~~~~~~~~~~~
1289 We *used* to suppress the binder-swap in case expressoins when
1290 -fno-case-of-case is on.  Old remarks:
1291     "This happens in the first simplifier pass,
1292     and enhances full laziness.  Here's the bad case:
1293             f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1294     If we eliminate the inner case, we trap it inside the I# v -> arm,
1295     which might prevent some full laziness happening.  I've seen this
1296     in action in spectral/cichelli/Prog.hs:
1297              [(m,n) | m <- [1..max], n <- [1..max]]
1298     Hence the check for NoCaseOfCase."
1299 However, now the full-laziness pass itself reverses the binder-swap, so this
1300 check is no longer necessary.
1301
1302 Note [Suppressing the case binder-swap]
1303 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1304 There is another situation when it might make sense to suppress the
1305 case-expression binde-swap. If we have
1306
1307     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1308                    ...other cases .... }
1309
1310 We'll perform the binder-swap for the outer case, giving
1311
1312     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1313                    ...other cases .... }
1314
1315 But there is no point in doing it for the inner case, because w1 can't
1316 be inlined anyway.  Furthermore, doing the case-swapping involves
1317 zapping w2's occurrence info (see paragraphs that follow), and that
1318 forces us to bind w2 when doing case merging.  So we get
1319
1320     case x of w1 { A -> let w2 = w1 in e1
1321                    B -> let w2 = w1 in e2
1322                    ...other cases .... }
1323
1324 This is plain silly in the common case where w2 is dead.
1325
1326 Even so, I can't see a good way to implement this idea.  I tried
1327 not doing the binder-swap if the scrutinee was already evaluated
1328 but that failed big-time:
1329
1330         data T = MkT !Int
1331
1332         case v of w  { MkT x ->
1333         case x of x1 { I# y1 ->
1334         case x of x2 { I# y2 -> ...
1335
1336 Notice that because MkT is strict, x is marked "evaluated".  But to
1337 eliminate the last case, we must either make sure that x (as well as
1338 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1339 the binder-swap.  So this whole note is a no-op.
1340
1341 Note [zapOccInfo]
1342 ~~~~~~~~~~~~~~~~~
1343 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1344 any occurrence info (eg IAmDead) in the case binder, because the
1345 case-binder now effectively occurs whenever v does.  AND we have to do
1346 the same for the pattern-bound variables!  Example:
1347
1348         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1349
1350 Here, b and p are dead.  But when we move the argment inside the first
1351 case RHS, and eliminate the second case, we get
1352
1353         case x of { (a,b) -> a b }
1354
1355 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1356 happened.
1357
1358 Indeed, this can happen anytime the case binder isn't dead:
1359         case <any> of x { (a,b) ->
1360         case x of { (p,q) -> p } }
1361 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1362 The point is that we bring into the envt a binding
1363         let x = (a,b)
1364 after the outer case, and that makes (a,b) alive.  At least we do unless
1365 the case binder is guaranteed dead.
1366
1367 Note [Case of cast]
1368 ~~~~~~~~~~~~~~~~~~~
1369 Consider        case (v `cast` co) of x { I# ->
1370                 ... (case (v `cast` co) of {...}) ...
1371 We'd like to eliminate the inner case.  We can get this neatly by
1372 arranging that inside the outer case we add the unfolding
1373         v |-> x `cast` (sym co)
1374 to v.  Then we should inline v at the inner case, cancel the casts, and away we go
1375
1376 Note [Improving seq]
1377 ~~~~~~~~~~~~~~~~~~~
1378 Consider
1379         type family F :: * -> *
1380         type instance F Int = Int
1381
1382         ... case e of x { DEFAULT -> rhs } ...
1383
1384 where x::F Int.  Then we'd like to rewrite (F Int) to Int, getting
1385
1386         case e `cast` co of x'::Int
1387            I# x# -> let x = x' `cast` sym co
1388                     in rhs
1389
1390 so that 'rhs' can take advantage of the form of x'.  Notice that Note
1391 [Case of cast] may then apply to the result.
1392
1393 This showed up in Roman's experiments.  Example:
1394   foo :: F Int -> Int -> Int
1395   foo t n = t `seq` bar n
1396      where
1397        bar 0 = 0
1398        bar n = bar (n - case t of TI i -> i)
1399 Here we'd like to avoid repeated evaluating t inside the loop, by
1400 taking advantage of the `seq`.
1401
1402 At one point I did transformation in LiberateCase, but it's more robust here.
1403 (Otherwise, there's a danger that we'll simply drop the 'seq' altogether, before
1404 LiberateCase gets to see it.)
1405
1406 Note [Case elimination]
1407 ~~~~~~~~~~~~~~~~~~~~~~~
1408 The case-elimination transformation discards redundant case expressions.
1409 Start with a simple situation:
1410
1411         case x# of      ===>   e[x#/y#]
1412           y# -> e
1413
1414 (when x#, y# are of primitive type, of course).  We can't (in general)
1415 do this for algebraic cases, because we might turn bottom into
1416 non-bottom!
1417
1418 The code in SimplUtils.prepareAlts has the effect of generalise this
1419 idea to look for a case where we're scrutinising a variable, and we
1420 know that only the default case can match.  For example:
1421
1422         case x of
1423           0#      -> ...
1424           DEFAULT -> ...(case x of
1425                          0#      -> ...
1426                          DEFAULT -> ...) ...
1427
1428 Here the inner case is first trimmed to have only one alternative, the
1429 DEFAULT, after which it's an instance of the previous case.  This
1430 really only shows up in eliminating error-checking code.
1431
1432 We also make sure that we deal with this very common case:
1433
1434         case e of
1435           x -> ...x...
1436
1437 Here we are using the case as a strict let; if x is used only once
1438 then we want to inline it.  We have to be careful that this doesn't
1439 make the program terminate when it would have diverged before, so we
1440 check that
1441         - e is already evaluated (it may so if e is a variable)
1442         - x is used strictly, or
1443
1444 Lastly, the code in SimplUtils.mkCase combines identical RHSs.  So
1445
1446         case e of       ===> case e of DEFAULT -> r
1447            True  -> r
1448            False -> r
1449
1450 Now again the case may be elminated by the CaseElim transformation.
1451
1452
1453 Further notes about case elimination
1454 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1455 Consider:       test :: Integer -> IO ()
1456                 test = print
1457
1458 Turns out that this compiles to:
1459     Print.test
1460       = \ eta :: Integer
1461           eta1 :: State# RealWorld ->
1462           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1463           case hPutStr stdout
1464                  (PrelNum.jtos eta ($w[] @ Char))
1465                  eta1
1466           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1467
1468 Notice the strange '<' which has no effect at all. This is a funny one.
1469 It started like this:
1470
1471 f x y = if x < 0 then jtos x
1472           else if y==0 then "" else jtos x
1473
1474 At a particular call site we have (f v 1).  So we inline to get
1475
1476         if v < 0 then jtos x
1477         else if 1==0 then "" else jtos x
1478
1479 Now simplify the 1==0 conditional:
1480
1481         if v<0 then jtos v else jtos v
1482
1483 Now common-up the two branches of the case:
1484
1485         case (v<0) of DEFAULT -> jtos v
1486
1487 Why don't we drop the case?  Because it's strict in v.  It's technically
1488 wrong to drop even unnecessary evaluations, and in practice they
1489 may be a result of 'seq' so we *definitely* don't want to drop those.
1490 I don't really know how to improve this situation.
1491
1492
1493 \begin{code}
1494 simplCaseBinder :: SimplEnv -> OutExpr -> OutId -> [InAlt]
1495                 -> SimplM (SimplEnv, OutExpr, OutId)
1496 simplCaseBinder env0 scrut0 case_bndr0 alts
1497   = do  { (env1, case_bndr1) <- simplBinder env0 case_bndr0
1498
1499         ; fam_envs <- getFamEnvs
1500         ; (env2, scrut2, case_bndr2) <- improve_seq fam_envs env1 scrut0
1501                                                 case_bndr0 case_bndr1 alts
1502                         -- Note [Improving seq]
1503
1504         ; let (env3, case_bndr3) = improve_case_bndr env2 scrut2 case_bndr2
1505                         -- Note [Case of cast]
1506
1507         ; return (env3, scrut2, case_bndr3) }
1508   where
1509
1510     improve_seq fam_envs env scrut case_bndr case_bndr1 [(DEFAULT,_,_)]
1511         | Just (co, ty2) <- topNormaliseType fam_envs (idType case_bndr1)
1512         =  do { case_bndr2 <- newId (fsLit "nt") ty2
1513               ; let rhs  = DoneEx (Var case_bndr2 `Cast` mkSymCoercion co)
1514                     env2 = extendIdSubst env case_bndr rhs
1515               ; return (env2, scrut `Cast` co, case_bndr2) }
1516
1517     improve_seq _ env scrut _ case_bndr1 _
1518         = return (env, scrut, case_bndr1)
1519
1520
1521     improve_case_bndr env scrut case_bndr
1522         -- See Note [no-case-of-case]
1523         --  | switchIsOn (getSwitchChecker env) NoCaseOfCase
1524         --  = (env, case_bndr)
1525
1526         | otherwise     -- Failed try; see Note [Suppressing the case binder-swap]
1527                         --     not (isEvaldUnfolding (idUnfolding v))
1528         = case scrut of
1529             Var v -> (modifyInScope env1 v case_bndr', case_bndr')
1530                 -- Note about using modifyInScope for v here
1531                 -- We could extend the substitution instead, but it would be
1532                 -- a hack because then the substitution wouldn't be idempotent
1533                 -- any more (v is an OutId).  And this does just as well.
1534
1535             Cast (Var v) co -> (addBinderUnfolding env1 v rhs, case_bndr')
1536                             where
1537                                 rhs = Cast (Var case_bndr') (mkSymCoercion co)
1538
1539             _ -> (env, case_bndr)
1540         where
1541           case_bndr' = zapOccInfo case_bndr
1542           env1       = modifyInScope env case_bndr case_bndr'
1543
1544
1545 zapOccInfo :: InId -> InId      -- See Note [zapOccInfo]
1546 zapOccInfo b = b `setIdOccInfo` NoOccInfo
1547 \end{code}
1548
1549
1550 simplAlts does two things:
1551
1552 1.  Eliminate alternatives that cannot match, including the
1553     DEFAULT alternative.
1554
1555 2.  If the DEFAULT alternative can match only one possible constructor,
1556     then make that constructor explicit.
1557     e.g.
1558         case e of x { DEFAULT -> rhs }
1559      ===>
1560         case e of x { (a,b) -> rhs }
1561     where the type is a single constructor type.  This gives better code
1562     when rhs also scrutinises x or e.
1563
1564 Here "cannot match" includes knowledge from GADTs
1565
1566 It's a good idea do do this stuff before simplifying the alternatives, to
1567 avoid simplifying alternatives we know can't happen, and to come up with
1568 the list of constructors that are handled, to put into the IdInfo of the
1569 case binder, for use when simplifying the alternatives.
1570
1571 Eliminating the default alternative in (1) isn't so obvious, but it can
1572 happen:
1573
1574 data Colour = Red | Green | Blue
1575
1576 f x = case x of
1577         Red -> ..
1578         Green -> ..
1579         DEFAULT -> h x
1580
1581 h y = case y of
1582         Blue -> ..
1583         DEFAULT -> [ case y of ... ]
1584
1585 If we inline h into f, the default case of the inlined h can't happen.
1586 If we don't notice this, we may end up filtering out *all* the cases
1587 of the inner case y, which give us nowhere to go!
1588
1589
1590 \begin{code}
1591 simplAlts :: SimplEnv
1592           -> OutExpr
1593           -> InId                       -- Case binder
1594           -> [InAlt]                    -- Non-empty
1595           -> SimplCont
1596           -> SimplM (OutExpr, OutId, [OutAlt])  -- Includes the continuation
1597 -- Like simplExpr, this just returns the simplified alternatives;
1598 -- it not return an environment
1599
1600 simplAlts env scrut case_bndr alts cont'
1601   = -- pprTrace "simplAlts" (ppr alts $$ ppr (seIdSubst env)) $
1602     do  { let alt_env = zapFloats env
1603         ; (alt_env', scrut', case_bndr') <- simplCaseBinder alt_env scrut case_bndr alts
1604
1605         ; (imposs_deflt_cons, in_alts) <- prepareAlts alt_env' scrut case_bndr' alts
1606
1607         ; alts' <- mapM (simplAlt alt_env' imposs_deflt_cons case_bndr' cont') in_alts
1608         ; return (scrut', case_bndr', alts') }
1609
1610 ------------------------------------
1611 simplAlt :: SimplEnv
1612          -> [AltCon]    -- These constructors can't be present when
1613                         -- matching the DEFAULT alternative
1614          -> OutId       -- The case binder
1615          -> SimplCont
1616          -> InAlt
1617          -> SimplM OutAlt
1618
1619 simplAlt env imposs_deflt_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1620   = ASSERT( null bndrs )
1621     do  { let env' = addBinderOtherCon env case_bndr' imposs_deflt_cons
1622                 -- Record the constructors that the case-binder *can't* be.
1623         ; rhs' <- simplExprC env' rhs cont'
1624         ; return (DEFAULT, [], rhs') }
1625
1626 simplAlt env _ case_bndr' cont' (LitAlt lit, bndrs, rhs)
1627   = ASSERT( null bndrs )
1628     do  { let env' = addBinderUnfolding env case_bndr' (Lit lit)
1629         ; rhs' <- simplExprC env' rhs cont'
1630         ; return (LitAlt lit, [], rhs') }
1631
1632 simplAlt env _ case_bndr' cont' (DataAlt con, vs, rhs)
1633   = do  {       -- Deal with the pattern-bound variables
1634                 -- Mark the ones that are in ! positions in the
1635                 -- data constructor as certainly-evaluated.
1636                 -- NB: simplLamBinders preserves this eval info
1637           let vs_with_evals = add_evals (dataConRepStrictness con)
1638         ; (env', vs') <- simplLamBndrs env vs_with_evals
1639
1640                 -- Bind the case-binder to (con args)
1641         ; let inst_tys' = tyConAppArgs (idType case_bndr')
1642               con_args  = map Type inst_tys' ++ varsToCoreExprs vs'
1643               env''     = addBinderUnfolding env' case_bndr'
1644                                              (mkConApp con con_args)
1645
1646         ; rhs' <- simplExprC env'' rhs cont'
1647         ; return (DataAlt con, vs', rhs') }
1648   where
1649         -- add_evals records the evaluated-ness of the bound variables of
1650         -- a case pattern.  This is *important*.  Consider
1651         --      data T = T !Int !Int
1652         --
1653         --      case x of { T a b -> T (a+1) b }
1654         --
1655         -- We really must record that b is already evaluated so that we don't
1656         -- go and re-evaluate it when constructing the result.
1657         -- See Note [Data-con worker strictness] in MkId.lhs
1658     add_evals the_strs
1659         = go vs the_strs
1660         where
1661           go [] [] = []
1662           go (v:vs') strs | isTyVar v = v : go vs' strs
1663           go (v:vs') (str:strs)
1664             | isMarkedStrict str = evald_v  : go vs' strs
1665             | otherwise          = zapped_v : go vs' strs
1666             where
1667               zapped_v = zap_occ_info v
1668               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
1669           go _ _ = pprPanic "cat_evals" (ppr con $$ ppr vs $$ ppr the_strs)
1670
1671         -- zap_occ_info: if the case binder is alive, then we add the unfolding
1672         --      case_bndr = C vs
1673         -- to the envt; so vs are now very much alive
1674         -- Note [Aug06] I can't see why this actually matters, but it's neater
1675         --        case e of t { (a,b) -> ...(case t of (p,q) -> p)... }
1676         --   ==>  case e of t { (a,b) -> ...(a)... }
1677         -- Look, Ma, a is alive now.
1678     zap_occ_info | isDeadBinder case_bndr' = \ident -> ident
1679                  | otherwise               = zapOccInfo
1680
1681 addBinderUnfolding :: SimplEnv -> Id -> CoreExpr -> SimplEnv
1682 addBinderUnfolding env bndr rhs
1683   = modifyInScope env bndr (bndr `setIdUnfolding` mkUnfolding False rhs)
1684
1685 addBinderOtherCon :: SimplEnv -> Id -> [AltCon] -> SimplEnv
1686 addBinderOtherCon env bndr cons
1687   = modifyInScope env bndr (bndr `setIdUnfolding` mkOtherCon cons)
1688 \end{code}
1689
1690
1691 %************************************************************************
1692 %*                                                                      *
1693 \subsection{Known constructor}
1694 %*                                                                      *
1695 %************************************************************************
1696
1697 We are a bit careful with occurrence info.  Here's an example
1698
1699         (\x* -> case x of (a*, b) -> f a) (h v, e)
1700
1701 where the * means "occurs once".  This effectively becomes
1702         case (h v, e) of (a*, b) -> f a)
1703 and then
1704         let a* = h v; b = e in f a
1705 and then
1706         f (h v)
1707
1708 All this should happen in one sweep.
1709
1710 \begin{code}
1711 knownCon :: SimplEnv -> OutExpr -> AltCon
1712          -> [OutExpr]           -- Args *including* the universal args
1713          -> InId -> [InAlt] -> SimplCont
1714          -> SimplM (SimplEnv, OutExpr)
1715
1716 knownCon env scrut con args bndr alts cont
1717   = do  { tick (KnownBranch bndr)
1718         ; knownAlt env scrut args bndr (findAlt con alts) cont }
1719
1720 knownAlt :: SimplEnv -> OutExpr -> [OutExpr]
1721          -> InId -> (AltCon, [CoreBndr], InExpr) -> SimplCont
1722          -> SimplM (SimplEnv, OutExpr)
1723 knownAlt env scrut _ bndr (DEFAULT, bs, rhs) cont
1724   = ASSERT( null bs )
1725     do  { env' <- simplNonRecX env bndr scrut
1726                 -- This might give rise to a binding with non-atomic args
1727                 -- like x = Node (f x) (g x)
1728                 -- but simplNonRecX will atomic-ify it
1729         ; simplExprF env' rhs cont }
1730
1731 knownAlt env scrut _ bndr (LitAlt _, bs, rhs) cont
1732   = ASSERT( null bs )
1733     do  { env' <- simplNonRecX env bndr scrut
1734         ; simplExprF env' rhs cont }
1735
1736 knownAlt env scrut the_args bndr (DataAlt dc, bs, rhs) cont
1737   = do  { let dead_bndr  = isDeadBinder bndr    -- bndr is an InId
1738               n_drop_tys = length (dataConUnivTyVars dc)
1739         ; env' <- bind_args env dead_bndr bs (drop n_drop_tys the_args)
1740         ; let
1741                 -- It's useful to bind bndr to scrut, rather than to a fresh
1742                 -- binding      x = Con arg1 .. argn
1743                 -- because very often the scrut is a variable, so we avoid
1744                 -- creating, and then subsequently eliminating, a let-binding
1745                 -- BUT, if scrut is a not a variable, we must be careful
1746                 -- about duplicating the arg redexes; in that case, make
1747                 -- a new con-app from the args
1748                 bndr_rhs  = case scrut of
1749                                 Var _ -> scrut
1750                                 _     -> con_app
1751                 con_app = mkConApp dc (take n_drop_tys the_args ++ con_args)
1752                 con_args = [substExpr env' (varToCoreExpr b) | b <- bs]
1753                                 -- args are aready OutExprs, but bs are InIds
1754
1755         ; env'' <- simplNonRecX env' bndr bndr_rhs
1756         ; -- pprTrace "knownCon2" (ppr bs $$ ppr rhs $$ ppr (seIdSubst env'')) $
1757           simplExprF env'' rhs cont }
1758   where
1759     -- Ugh!
1760     bind_args env' _ [] _  = return env'
1761
1762     bind_args env' dead_bndr (b:bs') (Type ty : args)
1763       = ASSERT( isTyVar b )
1764         bind_args (extendTvSubst env' b ty) dead_bndr bs' args
1765
1766     bind_args env' dead_bndr (b:bs') (arg : args)
1767       = ASSERT( isId b )
1768         do { let b' = if dead_bndr then b else zapOccInfo b
1769              -- Note that the binder might be "dead", because it doesn't
1770              -- occur in the RHS; and simplNonRecX may therefore discard
1771              -- it via postInlineUnconditionally.
1772              -- Nevertheless we must keep it if the case-binder is alive,
1773              -- because it may be used in the con_app.  See Note [zapOccInfo]
1774            ; env'' <- simplNonRecX env' b' arg
1775            ; bind_args env'' dead_bndr bs' args }
1776
1777     bind_args _ _ _ _ =
1778       pprPanic "bind_args" $ ppr dc $$ ppr bs $$ ppr the_args $$
1779                              text "scrut:" <+> ppr scrut
1780 \end{code}
1781
1782
1783 %************************************************************************
1784 %*                                                                      *
1785 \subsection{Duplicating continuations}
1786 %*                                                                      *
1787 %************************************************************************
1788
1789 \begin{code}
1790 prepareCaseCont :: SimplEnv
1791                 -> [InAlt] -> SimplCont
1792                 -> SimplM (SimplEnv, SimplCont,SimplCont)
1793                         -- Return a duplicatable continuation, a non-duplicable part
1794                         -- plus some extra bindings (that scope over the entire
1795                         -- continunation)
1796
1797         -- No need to make it duplicatable if there's only one alternative
1798 prepareCaseCont env [_] cont = return (env, cont, mkBoringStop)
1799 prepareCaseCont env _   cont = mkDupableCont env cont
1800 \end{code}
1801
1802 \begin{code}
1803 mkDupableCont :: SimplEnv -> SimplCont
1804               -> SimplM (SimplEnv, SimplCont, SimplCont)
1805
1806 mkDupableCont env cont
1807   | contIsDupable cont
1808   = return (env, cont, mkBoringStop)
1809
1810 mkDupableCont _   (Stop {}) = panic "mkDupableCont"     -- Handled by previous eqn
1811
1812 mkDupableCont env (CoerceIt ty cont)
1813   = do  { (env', dup, nodup) <- mkDupableCont env cont
1814         ; return (env', CoerceIt ty dup, nodup) }
1815
1816 mkDupableCont env cont@(StrictBind {})
1817   =  return (env, mkBoringStop, cont)
1818         -- See Note [Duplicating strict continuations]
1819
1820 mkDupableCont env cont@(StrictArg {})
1821   =  return (env, mkBoringStop, cont)
1822         -- See Note [Duplicating strict continuations]
1823
1824 mkDupableCont env (ApplyTo _ arg se cont)
1825   =     -- e.g.         [...hole...] (...arg...)
1826         --      ==>
1827         --              let a = ...arg...
1828         --              in [...hole...] a
1829     do  { (env', dup_cont, nodup_cont) <- mkDupableCont env cont
1830         ; arg' <- simplExpr (se `setInScope` env') arg
1831         ; (env'', arg'') <- makeTrivial env' arg'
1832         ; let app_cont = ApplyTo OkToDup arg'' (zapSubstEnv env') dup_cont
1833         ; return (env'', app_cont, nodup_cont) }
1834
1835 mkDupableCont env cont@(Select _ case_bndr [(_, bs, _rhs)] _ _)
1836 --  See Note [Single-alternative case]
1837 --  | not (exprIsDupable rhs && contIsDupable case_cont)
1838 --  | not (isDeadBinder case_bndr)
1839   | all isDeadBinder bs  -- InIds
1840     && not (isUnLiftedType (idType case_bndr))
1841     -- Note [Single-alternative-unlifted]
1842   = return (env, mkBoringStop, cont)
1843
1844 mkDupableCont env (Select _ case_bndr alts se cont)
1845   =     -- e.g.         (case [...hole...] of { pi -> ei })
1846         --      ===>
1847         --              let ji = \xij -> ei
1848         --              in case [...hole...] of { pi -> ji xij }
1849     do  { tick (CaseOfCase case_bndr)
1850         ; (env', dup_cont, nodup_cont) <- mkDupableCont env cont
1851                 -- NB: call mkDupableCont here, *not* prepareCaseCont
1852                 -- We must make a duplicable continuation, whereas prepareCaseCont
1853                 -- doesn't when there is a single case branch
1854
1855         ; let alt_env = se `setInScope` env'
1856         ; (alt_env', case_bndr') <- simplBinder alt_env case_bndr
1857         ; alts' <- mapM (simplAlt alt_env' [] case_bndr' dup_cont) alts
1858         -- Safe to say that there are no handled-cons for the DEFAULT case
1859                 -- NB: simplBinder does not zap deadness occ-info, so
1860                 -- a dead case_bndr' will still advertise its deadness
1861                 -- This is really important because in
1862                 --      case e of b { (# p,q #) -> ... }
1863                 -- b is always dead, and indeed we are not allowed to bind b to (# p,q #),
1864                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1865                 -- In the new alts we build, we have the new case binder, so it must retain
1866                 -- its deadness.
1867         -- NB: we don't use alt_env further; it has the substEnv for
1868         --     the alternatives, and we don't want that
1869
1870         ; (env'', alts'') <- mkDupableAlts env' case_bndr' alts'
1871         ; return (env'',  -- Note [Duplicated env]
1872                   Select OkToDup case_bndr' alts'' (zapSubstEnv env'') mkBoringStop,
1873                   nodup_cont) }
1874
1875
1876 mkDupableAlts :: SimplEnv -> OutId -> [InAlt]
1877               -> SimplM (SimplEnv, [InAlt])
1878 -- Absorbs the continuation into the new alternatives
1879
1880 mkDupableAlts env case_bndr' the_alts
1881   = go env the_alts
1882   where
1883     go env0 [] = return (env0, [])
1884     go env0 (alt:alts)
1885         = do { (env1, alt') <- mkDupableAlt env0 case_bndr' alt
1886              ; (env2, alts') <- go env1 alts
1887              ; return (env2, alt' : alts' ) }
1888
1889 mkDupableAlt :: SimplEnv -> OutId -> (AltCon, [CoreBndr], CoreExpr)
1890               -> SimplM (SimplEnv, (AltCon, [CoreBndr], CoreExpr))
1891 mkDupableAlt env case_bndr' (con, bndrs', rhs')
1892   | exprIsDupable rhs'  -- Note [Small alternative rhs]
1893   = return (env, (con, bndrs', rhs'))
1894   | otherwise
1895   = do  { let rhs_ty'     = exprType rhs'
1896               used_bndrs' = filter abstract_over (case_bndr' : bndrs')
1897               abstract_over bndr
1898                   | isTyVar bndr = True -- Abstract over all type variables just in case
1899                   | otherwise    = not (isDeadBinder bndr)
1900                         -- The deadness info on the new Ids is preserved by simplBinders
1901
1902         ; (final_bndrs', final_args)    -- Note [Join point abstraction]
1903                 <- if (any isId used_bndrs')
1904                    then return (used_bndrs', varsToCoreExprs used_bndrs')
1905                     else do { rw_id <- newId (fsLit "w") realWorldStatePrimTy
1906                             ; return ([rw_id], [Var realWorldPrimId]) }
1907
1908         ; join_bndr <- newId (fsLit "$j") (mkPiTypes final_bndrs' rhs_ty')
1909                 -- Note [Funky mkPiTypes]
1910
1911         ; let   -- We make the lambdas into one-shot-lambdas.  The
1912                 -- join point is sure to be applied at most once, and doing so
1913                 -- prevents the body of the join point being floated out by
1914                 -- the full laziness pass
1915                 really_final_bndrs     = map one_shot final_bndrs'
1916                 one_shot v | isId v    = setOneShotLambda v
1917                            | otherwise = v
1918                 join_rhs  = mkLams really_final_bndrs rhs'
1919                 join_call = mkApps (Var join_bndr) final_args
1920
1921         ; return (addPolyBind NotTopLevel env (NonRec join_bndr join_rhs), (con, bndrs', join_call)) }
1922                 -- See Note [Duplicated env]
1923 \end{code}
1924
1925 Note [Duplicated env]
1926 ~~~~~~~~~~~~~~~~~~~~~
1927 Some of the alternatives are simplified, but have not been turned into a join point
1928 So they *must* have an zapped subst-env.  So we can't use completeNonRecX to
1929 bind the join point, because it might to do PostInlineUnconditionally, and
1930 we'd lose that when zapping the subst-env.  We could have a per-alt subst-env,
1931 but zapping it (as we do in mkDupableCont, the Select case) is safe, and
1932 at worst delays the join-point inlining.
1933
1934 Note [Small alterantive rhs]
1935 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1936 It is worth checking for a small RHS because otherwise we
1937 get extra let bindings that may cause an extra iteration of the simplifier to
1938 inline back in place.  Quite often the rhs is just a variable or constructor.
1939 The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1940 iterations because the version with the let bindings looked big, and so wasn't
1941 inlined, but after the join points had been inlined it looked smaller, and so
1942 was inlined.
1943
1944 NB: we have to check the size of rhs', not rhs.
1945 Duplicating a small InAlt might invalidate occurrence information
1946 However, if it *is* dupable, we return the *un* simplified alternative,
1947 because otherwise we'd need to pair it up with an empty subst-env....
1948 but we only have one env shared between all the alts.
1949 (Remember we must zap the subst-env before re-simplifying something).
1950 Rather than do this we simply agree to re-simplify the original (small) thing later.
1951
1952 Note [Funky mkPiTypes]
1953 ~~~~~~~~~~~~~~~~~~~~~~
1954 Notice the funky mkPiTypes.  If the contructor has existentials
1955 it's possible that the join point will be abstracted over
1956 type varaibles as well as term variables.
1957  Example:  Suppose we have
1958         data T = forall t.  C [t]
1959  Then faced with
1960         case (case e of ...) of
1961             C t xs::[t] -> rhs
1962  We get the join point
1963         let j :: forall t. [t] -> ...
1964             j = /\t \xs::[t] -> rhs
1965         in
1966         case (case e of ...) of
1967             C t xs::[t] -> j t xs
1968
1969 Note [Join point abstaction]
1970 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1971 If we try to lift a primitive-typed something out
1972 for let-binding-purposes, we will *caseify* it (!),
1973 with potentially-disastrous strictness results.  So
1974 instead we turn it into a function: \v -> e
1975 where v::State# RealWorld#.  The value passed to this function
1976 is realworld#, which generates (almost) no code.
1977
1978 There's a slight infelicity here: we pass the overall
1979 case_bndr to all the join points if it's used in *any* RHS,
1980 because we don't know its usage in each RHS separately
1981
1982 We used to say "&& isUnLiftedType rhs_ty'" here, but now
1983 we make the join point into a function whenever used_bndrs'
1984 is empty.  This makes the join-point more CPR friendly.
1985 Consider:       let j = if .. then I# 3 else I# 4
1986                 in case .. of { A -> j; B -> j; C -> ... }
1987
1988 Now CPR doesn't w/w j because it's a thunk, so
1989 that means that the enclosing function can't w/w either,
1990 which is a lose.  Here's the example that happened in practice:
1991         kgmod :: Int -> Int -> Int
1992         kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1993                     then 78
1994                     else 5
1995
1996 I have seen a case alternative like this:
1997         True -> \v -> ...
1998 It's a bit silly to add the realWorld dummy arg in this case, making
1999         $j = \s v -> ...
2000            True -> $j s
2001 (the \v alone is enough to make CPR happy) but I think it's rare
2002
2003 Note [Duplicating strict continuations]
2004 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2005 Do *not* duplicate StrictBind and StritArg continuations.  We gain
2006 nothing by propagating them into the expressions, and we do lose a
2007 lot.  Here's an example:
2008         && (case x of { T -> F; F -> T }) E
2009 Now, && is strict so we end up simplifying the case with
2010 an ArgOf continuation.  If we let-bind it, we get
2011
2012         let $j = \v -> && v E
2013         in simplExpr (case x of { T -> F; F -> T })
2014                      (ArgOf (\r -> $j r)
2015 And after simplifying more we get
2016
2017         let $j = \v -> && v E
2018         in case x of { T -> $j F; F -> $j T }
2019 Which is a Very Bad Thing
2020
2021 The desire not to duplicate is the entire reason that
2022 mkDupableCont returns a pair of continuations.
2023
2024 The original plan had:
2025 e.g.    (...strict-fn...) [...hole...]
2026         ==>
2027                 let $j = \a -> ...strict-fn...
2028                 in $j [...hole...]
2029
2030 Note [Single-alternative cases]
2031 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2032 This case is just like the ArgOf case.  Here's an example:
2033         data T a = MkT !a
2034         ...(MkT (abs x))...
2035 Then we get
2036         case (case x of I# x' ->
2037               case x' <# 0# of
2038                 True  -> I# (negate# x')
2039                 False -> I# x') of y {
2040           DEFAULT -> MkT y
2041 Because the (case x) has only one alternative, we'll transform to
2042         case x of I# x' ->
2043         case (case x' <# 0# of
2044                 True  -> I# (negate# x')
2045                 False -> I# x') of y {
2046           DEFAULT -> MkT y
2047 But now we do *NOT* want to make a join point etc, giving
2048         case x of I# x' ->
2049         let $j = \y -> MkT y
2050         in case x' <# 0# of
2051                 True  -> $j (I# (negate# x'))
2052                 False -> $j (I# x')
2053 In this case the $j will inline again, but suppose there was a big
2054 strict computation enclosing the orginal call to MkT.  Then, it won't
2055 "see" the MkT any more, because it's big and won't get duplicated.
2056 And, what is worse, nothing was gained by the case-of-case transform.
2057
2058 When should use this case of mkDupableCont?
2059 However, matching on *any* single-alternative case is a *disaster*;
2060   e.g.  case (case ....) of (a,b) -> (# a,b #)
2061   We must push the outer case into the inner one!
2062 Other choices:
2063
2064    * Match [(DEFAULT,_,_)], but in the common case of Int,
2065      the alternative-filling-in code turned the outer case into
2066                 case (...) of y { I# _ -> MkT y }
2067
2068    * Match on single alternative plus (not (isDeadBinder case_bndr))
2069      Rationale: pushing the case inwards won't eliminate the construction.
2070      But there's a risk of
2071                 case (...) of y { (a,b) -> let z=(a,b) in ... }
2072      Now y looks dead, but it'll come alive again.  Still, this
2073      seems like the best option at the moment.
2074
2075    * Match on single alternative plus (all (isDeadBinder bndrs))
2076      Rationale: this is essentially  seq.
2077
2078    * Match when the rhs is *not* duplicable, and hence would lead to a
2079      join point.  This catches the disaster-case above.  We can test
2080      the *un-simplified* rhs, which is fine.  It might get bigger or
2081      smaller after simplification; if it gets smaller, this case might
2082      fire next time round.  NB also that we must test contIsDupable
2083      case_cont *btoo, because case_cont might be big!
2084
2085      HOWEVER: I found that this version doesn't work well, because
2086      we can get         let x = case (...) of { small } in ...case x...
2087      When x is inlined into its full context, we find that it was a bad
2088      idea to have pushed the outer case inside the (...) case.
2089
2090 Note [Single-alternative-unlifted]
2091 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2092 Here's another single-alternative where we really want to do case-of-case:
2093
2094 data Mk1 = Mk1 Int#
2095 data Mk1 = Mk2 Int#
2096
2097 M1.f =
2098     \r [x_s74 y_s6X]
2099         case
2100             case y_s6X of tpl_s7m {
2101               M1.Mk1 ipv_s70 -> ipv_s70;
2102               M1.Mk2 ipv_s72 -> ipv_s72;
2103             }
2104         of
2105         wild_s7c
2106         { __DEFAULT ->
2107               case
2108                   case x_s74 of tpl_s7n {
2109                     M1.Mk1 ipv_s77 -> ipv_s77;
2110                     M1.Mk2 ipv_s79 -> ipv_s79;
2111                   }
2112               of
2113               wild1_s7b
2114               { __DEFAULT -> ==# [wild1_s7b wild_s7c];
2115               };
2116         };
2117
2118 So the outer case is doing *nothing at all*, other than serving as a
2119 join-point.  In this case we really want to do case-of-case and decide
2120 whether to use a real join point or just duplicate the continuation.
2121
2122 Hence: check whether the case binder's type is unlifted, because then
2123 the outer case is *not* a seq.