compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplEnv
  16 import SimplUtils       ( mkCase, mkLam,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkRhsStop, mkBoringStop,  mkLazyArgStop, pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType,
  21                           preInlineUnconditionally, postInlineUnconditionally,
  22                           interestingArgContext, inlineMode, activeInline, activeRule
  23                         )
  24 import Id               ( Id, idType, idInfo, idArity, isDataConWorkId,
  25                           idUnfolding, setIdUnfolding, isDeadBinder,
  26                           idNewDemandInfo, setIdInfo,
  27                           setIdOccInfo, zapLamIdInfo, setOneShotLambda
  28                         )
  29 import MkId             ( eRROR_ID )
  30 import Literal          ( mkStringLit )
  31 import IdInfo           ( OccInfo(..), isLoopBreaker,
  32                           setArityInfo, zapDemandInfo,
  33                           setUnfoldingInfo,
  34                           occInfo
  35                         )
  36 import NewDemand        ( isStrictDmd )
  37 import Unify            ( coreRefineTys, dataConCanMatch )
  38 import DataCon          ( DataCon, dataConTyCon, dataConRepStrictness, isVanillaDataCon,
  39                           dataConInstArgTys, dataConTyVars )
  40 import TyCon            ( tyConArity, isAlgTyCon, isNewTyCon, tyConDataCons_maybe )
  41 import CoreSyn
  42 import PprCore          ( pprParendExpr, pprCoreExpr )
  43 import CoreUnfold       ( mkUnfolding, callSiteInline )
  44 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  45                           exprIsConApp_maybe, mkPiTypes, findAlt,
  46                           exprType, exprIsHNF, findDefault, mergeAlts,
  47                           exprOkForSpeculation, exprArity,
  48                           mkCoerce, mkCoerce2, mkSCC, mkInlineMe, applyTypeToArg
  49                         )
  50 import Rules            ( lookupRule )
  51 import BasicTypes       ( isMarkedStrict )
  52 import CostCentre       ( currentCCS )
  53 import Type             ( TvSubstEnv, isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  54                           splitFunTy_maybe, splitFunTy, coreEqType, splitTyConApp_maybe,
  55                           isTyVarTy, mkTyVarTys
  56                         )
  57 import Var              ( tyVarKind, mkTyVar )
  58 import VarEnv           ( elemVarEnv, emptyVarEnv )
  59 import TysPrim          ( realWorldStatePrimTy )
  60 import PrelInfo         ( realWorldPrimId )
  61 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  62                           RecFlag(..), isNonRec
  63                         )
  64 import Name             ( mkSysTvName )
  65 import StaticFlags      ( opt_PprStyle_Debug )
  66 import OrdList
  67 import List             ( nub )
  68 import Maybes           ( orElse )
  69 import Outputable
  70 import Util             ( notNull, filterOut )
  71 \end{code}
  72
  73
  74 The guts of the simplifier is in this module, but the driver loop for
  75 the simplifier is in SimplCore.lhs.
  76
  77
  78 -----------------------------------------
  79         *** IMPORTANT NOTE ***
  80 -----------------------------------------
  81 The simplifier used to guarantee that the output had no shadowing, but
  82 it does not do so any more.   (Actually, it never did!)  The reason is
  83 documented with simplifyArgs.
  84
  85
  86 -----------------------------------------
  87         *** IMPORTANT NOTE ***
  88 -----------------------------------------
  89 Many parts of the simplifier return a bunch of "floats" as well as an
  90 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  91
  92 All "floats" are let-binds, not case-binds, but some non-rec lets may
  93 be unlifted (with RHS ok-for-speculation).
  94
  95
  96
  97 -----------------------------------------
  98         ORGANISATION OF FUNCTIONS
  99 -----------------------------------------
 100 simplTopBinds
 101   - simplify all top-level binders
 102   - for NonRec, call simplRecOrTopPair
 103   - for Rec,    call simplRecBind
 104
 105
 106         ------------------------------
 107 simplExpr (applied lambda)      ==> simplNonRecBind
 108 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 109 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 110
 111         ------------------------------
 112 simplRecBind    [binders already simplfied]
 113   - use simplRecOrTopPair on each pair in turn
 114
 115 simplRecOrTopPair [binder already simplified]
 116   Used for: recursive bindings (top level and nested)
 117             top-level non-recursive bindings
 118   Returns:
 119   - check for PreInlineUnconditionally
 120   - simplLazyBind
 121
 122 simplNonRecBind
 123   Used for: non-top-level non-recursive bindings
 124             beta reductions (which amount to the same thing)
 125   Because it can deal with strict arts, it takes a
 126         "thing-inside" and returns an expression
 127
 128   - check for PreInlineUnconditionally
 129   - simplify binder, including its IdInfo
 130   - if strict binding
 131         simplStrictArg
 132         mkAtomicArgs
 133         completeNonRecX
 134     else
 135         simplLazyBind
 136         addFloats
 137
 138 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 139   Used for: binding case-binder and constr args in a known-constructor case
 140   - check for PreInLineUnconditionally
 141   - simplify binder
 142   - completeNonRecX
 143
 144         ------------------------------
 145 simplLazyBind:  [binder already simplified, RHS not]
 146   Used for: recursive bindings (top level and nested)
 147             top-level non-recursive bindings
 148             non-top-level, but *lazy* non-recursive bindings
 149         [must not be strict or unboxed]
 150   Returns floats + an augmented environment, not an expression
 151   - substituteIdInfo and add result to in-scope
 152         [so that rules are available in rec rhs]
 153   - simplify rhs
 154   - mkAtomicArgs
 155   - float if exposes constructor or PAP
 156   - completeLazyBind
 157
 158
 159 completeNonRecX:        [binder and rhs both simplified]
 160   - if the the thing needs case binding (unlifted and not ok-for-spec)
 161         build a Case
 162    else
 163         completeLazyBind
 164         addFloats
 165
 166 completeLazyBind:       [given a simplified RHS]
 167         [used for both rec and non-rec bindings, top level and not]
 168   - try PostInlineUnconditionally
 169   - add unfolding [this is the only place we add an unfolding]
 170   - add arity
 171
 172
 173
 174 Right hand sides and arguments
 175 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 176 In many ways we want to treat
 177         (a) the right hand side of a let(rec), and
 178         (b) a function argument
 179 in the same way.  But not always!  In particular, we would
 180 like to leave these arguments exactly as they are, so they
 181 will match a RULE more easily.
 182
 183         f (g x, h x)
 184         g (+ x)
 185
 186 It's harder to make the rule match if we ANF-ise the constructor,
 187 or eta-expand the PAP:
 188
 189         f (let { a = g x; b = h x } in (a,b))
 190         g (\y. + x y)
 191
 192 On the other hand if we see the let-defns
 193
 194         p = (g x, h x)
 195         q = + x
 196
 197 then we *do* want to ANF-ise and eta-expand, so that p and q
 198 can be safely inlined.
 199
 200 Even floating lets out is a bit dubious.  For let RHS's we float lets
 201 out if that exposes a value, so that the value can be inlined more vigorously.
 202 For example
 203
 204         r = let x = e in (x,x)
 205
 206 Here, if we float the let out we'll expose a nice constructor. We did experiments
 207 that showed this to be a generally good thing.  But it was a bad thing to float
 208 lets out unconditionally, because that meant they got allocated more often.
 209
 210 For function arguments, there's less reason to expose a constructor (it won't
 211 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 212 So for the moment we don't float lets out of function arguments either.
 213
 214
 215 Eta expansion
 216 ~~~~~~~~~~~~~~
 217 For eta expansion, we want to catch things like
 218
 219         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 220
 221 If the \x was on the RHS of a let, we'd eta expand to bring the two
 222 lambdas together.  And in general that's a good thing to do.  Perhaps
 223 we should eta expand wherever we find a (value) lambda?  Then the eta
 224 expansion at a let RHS can concentrate solely on the PAP case.
 225
 226
 227 %************************************************************************
 228 %*                                                                      *
 229 \subsection{Bindings}
 230 %*                                                                      *
 231 %************************************************************************
 232
 233 \begin{code}
 234 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 235
 236 simplTopBinds env binds
 237   =     -- Put all the top-level binders into scope at the start
 238         -- so that if a transformation rule has unexpectedly brought
 239         -- anything into scope, then we don't get a complaint about that.
 240         -- It's rather as if the top-level binders were imported.
 241     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 242     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 243     freeTick SimplifierDone                     `thenSmpl_`
 244     returnSmpl (floatBinds floats)
 245   where
 246         -- We need to track the zapped top-level binders, because
 247         -- they should have their fragile IdInfo zapped (notably occurrence info)
 248         -- That's why we run down binds and bndrs' simultaneously.
 249     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 250     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 251     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 252                                       addFloats env floats              $ \env ->
 253                                       simpl_binds env binds (drop_bs bind bs)
 254
 255     drop_bs (NonRec _ _) (_ : bs) = bs
 256     drop_bs (Rec prs)    bs       = drop (length prs) bs
 257
 258     simpl_bind env bind bs
 259       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 260         if dopt Opt_D_dump_inlinings dflags then
 261            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 262         else
 263            simpl_bind1 env bind bs
 264
 265     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 266     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 267 \end{code}
 268
 269
 270 %************************************************************************
 271 %*                                                                      *
 272 \subsection{simplNonRec}
 273 %*                                                                      *
 274 %************************************************************************
 275
 276 simplNonRecBind is used for
 277   * non-top-level non-recursive lets in expressions
 278   * beta reduction
 279
 280 It takes
 281   * An unsimplified (binder, rhs) pair
 282   * The env for the RHS.  It may not be the same as the
 283         current env because the bind might occur via (\x.E) arg
 284
 285 It uses the CPS form because the binding might be strict, in which
 286 case we might discard the continuation:
 287         let x* = error "foo" in (...x...)
 288
 289 It needs to turn unlifted bindings into a @case@.  They can arise
 290 from, say:      (\x -> e) (4# + 3#)
 291
 292 \begin{code}
 293 simplNonRecBind :: SimplEnv
 294                 -> InId                                 -- Binder
 295                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 296                 -> OutType                              -- Type of thing computed by the context
 297                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 298                 -> SimplM FloatsWithExpr
 299 #ifdef DEBUG
 300 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 301   | isTyVar bndr
 302   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 303 #endif
 304
 305 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 306   = simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 307
 308 simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 309   | preInlineUnconditionally env NotTopLevel bndr rhs
 310   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 311     thing_inside (extendIdSubst env bndr (mkContEx rhs_se rhs))
 312
 313   | isStrictDmd (idNewDemandInfo bndr) || isStrictType bndr_ty  -- A strict let
 314   =     -- Don't use simplBinder because that doesn't keep
 315         -- fragile occurrence info in the substitution
 316     simplNonRecBndr env bndr                                    `thenSmpl` \ (env, bndr1) ->
 317     simplStrictArg AnRhs env rhs rhs_se (idType bndr1) cont_ty  $ \ env1 rhs1 ->
 318
 319         -- Now complete the binding and simplify the body
 320     let
 321         (env2,bndr2) = addLetIdInfo env1 bndr bndr1
 322     in
 323     if needsCaseBinding bndr_ty rhs1
 324     then
 325       thing_inside env2                                 `thenSmpl` \ (floats, body) ->
 326       returnSmpl (emptyFloats env2, Case rhs1 bndr2 (exprType body)
 327                                         [(DEFAULT, [], wrapFloats floats body)])
 328     else
 329       completeNonRecX env2 True {- strict -} bndr bndr2 rhs1 thing_inside
 330
 331   | otherwise                                                   -- Normal, lazy case
 332   =     -- Don't use simplBinder because that doesn't keep
 333         -- fragile occurrence info in the substitution
 334     simplNonRecBndr env bndr                            `thenSmpl` \ (env, bndr') ->
 335     simplLazyBind env NotTopLevel NonRecursive
 336                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 337     addFloats env floats thing_inside
 338
 339   where
 340     bndr_ty = idType bndr
 341 \end{code}
 342
 343 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 344 in knownCon.  It uses case-binding where necessary.
 345
 346 \begin{code}
 347 simplNonRecX :: SimplEnv
 348              -> InId            -- Old binder
 349              -> OutExpr         -- Simplified RHS
 350              -> (SimplEnv -> SimplM FloatsWithExpr)
 351              -> SimplM FloatsWithExpr
 352
 353 simplNonRecX env bndr new_rhs thing_inside
 354   | needsCaseBinding (idType bndr) new_rhs
 355         -- Make this test *before* the preInlineUnconditionally
 356         -- Consider     case I# (quotInt# x y) of
 357         --                I# v -> let w = J# v in ...
 358         -- If we gaily inline (quotInt# x y) for v, we end up building an
 359         -- extra thunk:
 360         --                let w = J# (quotInt# x y) in ...
 361         -- because quotInt# can fail.
 362   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 363     thing_inside env            `thenSmpl` \ (floats, body) ->
 364     let body' = wrapFloats floats body in
 365     returnSmpl (emptyFloats env, Case new_rhs bndr' (exprType body') [(DEFAULT, [], body')])
 366
 367 {- No, no, no!  Do not try preInlineUnconditionally
 368   | preInlineUnconditionally env NotTopLevel bndr new_rhs
 369         -- This happens; for example, the case_bndr during case of
 370         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 371         -- Here x isn't mentioned in the RHS, so we don't want to
 372         -- create the (dead) let-binding  let x = (a,b) in ...
 373         --
 374         -- Similarly, single occurrences can be inlined vigourously
 375         -- e.g.  case (f x, g y) of (a,b) -> ....
 376         -- If a,b occur once we can avoid constructing the let binding for them.
 377   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
 378 -}
 379
 380   | otherwise
 381   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 382     completeNonRecX env False {- Non-strict; pessimistic -}
 383                     bndr bndr' new_rhs thing_inside
 384
 385 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 386   = mkAtomicArgs is_strict
 387                  True {- OK to float unlifted -}
 388                  new_rhs                        `thenSmpl` \ (aux_binds, rhs2) ->
 389
 390         -- Make the arguments atomic if necessary,
 391         -- adding suitable bindings
 392     addAtomicBindsE env (fromOL aux_binds)      $ \ env ->
 393     completeLazyBind env NotTopLevel
 394                      old_bndr new_bndr rhs2     `thenSmpl` \ (floats, env) ->
 395     addFloats env floats thing_inside
 396 \end{code}
 397
 398
 399 %************************************************************************
 400 %*                                                                      *
 401 \subsection{Lazy bindings}
 402 %*                                                                      *
 403 %************************************************************************
 404
 405 simplRecBind is used for
 406         * recursive bindings only
 407
 408 \begin{code}
 409 simplRecBind :: SimplEnv -> TopLevelFlag
 410              -> [(InId, InExpr)] -> [OutId]
 411              -> SimplM (FloatsWith SimplEnv)
 412 simplRecBind env top_lvl pairs bndrs'
 413   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 414     returnSmpl (flattenFloats floats, env)
 415   where
 416     go env [] _ = returnSmpl (emptyFloats env, env)
 417
 418     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 419         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 420           addFloats env floats (\env -> go env pairs bndrs')
 421 \end{code}
 422
 423
 424 simplRecOrTopPair is used for
 425         * recursive bindings (whether top level or not)
 426         * top-level non-recursive bindings
 427
 428 It assumes the binder has already been simplified, but not its IdInfo.
 429
 430 \begin{code}
 431 simplRecOrTopPair :: SimplEnv
 432                   -> TopLevelFlag
 433                   -> InId -> OutId              -- Binder, both pre-and post simpl
 434                   -> InExpr                     -- The RHS and its environment
 435                   -> SimplM (FloatsWith SimplEnv)
 436
 437 simplRecOrTopPair env top_lvl bndr bndr' rhs
 438   | preInlineUnconditionally env top_lvl bndr rhs       -- Check for unconditional inline
 439   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 440     returnSmpl (emptyFloats env, extendIdSubst env bndr (mkContEx env rhs))
 441
 442   | otherwise
 443   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 444         -- May not actually be recursive, but it doesn't matter
 445 \end{code}
 446
 447
 448 simplLazyBind is used for
 449         * recursive bindings (whether top level or not)
 450         * top-level non-recursive bindings
 451         * non-top-level *lazy* non-recursive bindings
 452
 453 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 454 from SimplRecOrTopBind]
 455
 456 Nota bene:
 457     1. It assumes that the binder is *already* simplified,
 458        and is in scope, but not its IdInfo
 459
 460     2. It assumes that the binder type is lifted.
 461
 462     3. It does not check for pre-inline-unconditionallly;
 463        that should have been done already.
 464
 465 \begin{code}
 466 simplLazyBind :: SimplEnv
 467               -> TopLevelFlag -> RecFlag
 468               -> InId -> OutId          -- Binder, both pre-and post simpl
 469               -> InExpr -> SimplEnv     -- The RHS and its environment
 470               -> SimplM (FloatsWith SimplEnv)
 471
 472 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 473   = let
 474         (env1,bndr2)      = addLetIdInfo env bndr bndr1
 475         rhs_env           = setInScope rhs_se env1
 476         is_top_level      = isTopLevel top_lvl
 477         ok_float_unlifted = not is_top_level && isNonRec is_rec
 478         rhs_cont          = mkRhsStop (idType bndr2)
 479     in
 480         -- Simplify the RHS; note the mkRhsStop, which tells
 481         -- the simplifier that this is the RHS of a let.
 482     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 483
 484         -- If any of the floats can't be floated, give up now
 485         -- (The allLifted predicate says True for empty floats.)
 486     if (not ok_float_unlifted && not (allLifted floats)) then
 487         completeLazyBind env1 top_lvl bndr bndr2
 488                          (wrapFloats floats rhs1)
 489     else
 490
 491         -- ANF-ise a constructor or PAP rhs
 492     mkAtomicArgs False {- Not strict -}
 493                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 494
 495         -- If the result is a PAP, float the floats out, else wrap them
 496         -- By this time it's already been ANF-ised (if necessary)
 497     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 498         completeLazyBind env1 top_lvl bndr bndr2 rhs2
 499
 500     else if is_top_level || exprIsTrivial rhs2 || exprIsHNF rhs2 then
 501         --      WARNING: long dodgy argument coming up
 502         --      WANTED: a better way to do this
 503         --
 504         -- We can't use "exprIsCheap" instead of exprIsHNF,
 505         -- because that causes a strictness bug.
 506         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 507         -- The case expression is 'cheap', but it's wrong to transform to
 508         --         y* = E; x = case (scc y) of {...}
 509         -- Either we must be careful not to float demanded non-values, or
 510         -- we must use exprIsHNF for the test, which ensures that the
 511         -- thing is non-strict.  So exprIsHNF => bindings are non-strict
 512         -- I think.  The WARN below tests for this.
 513         --
 514         -- We use exprIsTrivial here because we want to reveal lone variables.
 515         -- E.g.  let { x = letrec { y = E } in y } in ...
 516         -- Here we definitely want to float the y=E defn.
 517         -- exprIsHNF definitely isn't right for that.
 518         --
 519         -- Again, the floated binding can't be strict; if it's recursive it'll
 520         -- be non-strict; if it's non-recursive it'd be inlined.
 521         --
 522         -- Note [SCC-and-exprIsTrivial]
 523         -- If we have
 524         --      y = let { x* = E } in scc "foo" x
 525         -- then we do *not* want to float out the x binding, because
 526         -- it's strict!  Fortunately, exprIsTrivial replies False to
 527         -- (scc "foo" x).
 528
 529                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 530                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 531                 -- to float it out?  Answer no, but it won't matter because
 532                 -- we only float if (a) arg' is a WHNF, or (b) it's going to top level
 533                 -- and so there can't be any 'will be demanded' bindings in the floats.
 534                 -- Hence the warning
 535         ASSERT2( is_top_level || not (any demanded_float (floatBinds floats)),
 536                  ppr (filter demanded_float (floatBinds floats)) )
 537
 538         tick LetFloatFromLet                    `thenSmpl_` (
 539         addFloats env1 floats                   $ \ env2 ->
 540         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 541         completeLazyBind env3 top_lvl bndr bndr2 rhs2)
 542
 543     else
 544         completeLazyBind env1 top_lvl bndr bndr2 (wrapFloats floats rhs1)
 545
 546 #ifdef DEBUG
 547 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 548                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 549 demanded_float (Rec _)      = False
 550 #endif
 551 \end{code}
 552
 553
 554 %************************************************************************
 555 %*                                                                      *
 556 \subsection{Completing a lazy binding}
 557 %*                                                                      *
 558 %************************************************************************
 559
 560 completeLazyBind
 561         * deals only with Ids, not TyVars
 562         * takes an already-simplified binder and RHS
 563         * is used for both recursive and non-recursive bindings
 564         * is used for both top-level and non-top-level bindings
 565
 566 It does the following:
 567   - tries discarding a dead binding
 568   - tries PostInlineUnconditionally
 569   - add unfolding [this is the only place we add an unfolding]
 570   - add arity
 571
 572 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 573         - top-level bindings (when let-to-case is impossible)
 574         - many situations where the "rhs" is known to be a WHNF
 575                 (so let-to-case is inappropriate).
 576
 577 \begin{code}
 578 completeLazyBind :: SimplEnv
 579                  -> TopLevelFlag        -- Flag stuck into unfolding
 580                  -> InId                -- Old binder
 581                  -> OutId               -- New binder
 582                  -> OutExpr             -- Simplified RHS
 583                  -> SimplM (FloatsWith SimplEnv)
 584 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 585 -- by extending the substitution (e.g. let x = y in ...)
 586 -- The new binding (if any) is returned as part of the floats.
 587 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 588 --     (as usual) use the in-scope-env from the floats
 589
 590 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 591   | postInlineUnconditionally env top_lvl new_bndr occ_info new_rhs unfolding
 592   =             -- Drop the binding
 593     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 594     returnSmpl (emptyFloats env, extendIdSubst env old_bndr (DoneEx new_rhs))
 595                 -- Use the substitution to make quite, quite sure that the substitution
 596                 -- will happen, since we are going to discard the binding
 597
 598   |  otherwise
 599   = let
 600                 -- Add arity info
 601         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 602
 603         -- Add the unfolding *only* for non-loop-breakers
 604         -- Making loop breakers not have an unfolding at all
 605         -- means that we can avoid tests in exprIsConApp, for example.
 606         -- This is important: if exprIsConApp says 'yes' for a recursive
 607         -- thing, then we can get into an infinite loop
 608
 609         -- If the unfolding is a value, the demand info may
 610         -- go pear-shaped, so we nuke it.  Example:
 611         --      let x = (a,b) in
 612         --      case x of (p,q) -> h p q x
 613         -- Here x is certainly demanded. But after we've nuked
 614         -- the case, we'll get just
 615         --      let x = (a,b) in h a b x
 616         -- and now x is not demanded (I'm assuming h is lazy)
 617         -- This really happens.  Similarly
 618         --      let f = \x -> e in ...f..f...
 619         -- After inling f at some of its call sites the original binding may
 620         -- (for example) be no longer strictly demanded.
 621         -- The solution here is a bit ad hoc...
 622         info_w_unf = new_bndr_info `setUnfoldingInfo` unfolding
 623         final_info | loop_breaker               = new_bndr_info
 624                    | isEvaldUnfolding unfolding = zapDemandInfo info_w_unf `orElse` info_w_unf
 625                    | otherwise                  = info_w_unf
 626
 627         final_id = new_bndr `setIdInfo` final_info
 628     in
 629                 -- These seqs forces the Id, and hence its IdInfo,
 630                 -- and hence any inner substitutions
 631     final_id                                    `seq`
 632     returnSmpl (unitFloat env final_id new_rhs, env)
 633
 634   where
 635     unfolding    = mkUnfolding (isTopLevel top_lvl) new_rhs
 636     loop_breaker = isLoopBreaker occ_info
 637     old_info     = idInfo old_bndr
 638     occ_info     = occInfo old_info
 639 \end{code}
 640
 641
 642
 643 %************************************************************************
 644 %*                                                                      *
 645 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 646 %*                                                                      *
 647 %************************************************************************
 648
 649 The reason for this OutExprStuff stuff is that we want to float *after*
 650 simplifying a RHS, not before.  If we do so naively we get quadratic
 651 behaviour as things float out.
 652
 653 To see why it's important to do it after, consider this (real) example:
 654
 655         let t = f x
 656         in fst t
 657 ==>
 658         let t = let a = e1
 659                     b = e2
 660                 in (a,b)
 661         in fst t
 662 ==>
 663         let a = e1
 664             b = e2
 665             t = (a,b)
 666         in
 667         a       -- Can't inline a this round, cos it appears twice
 668 ==>
 669         e1
 670
 671 Each of the ==> steps is a round of simplification.  We'd save a
 672 whole round if we float first.  This can cascade.  Consider
 673
 674         let f = g d
 675         in \x -> ...f...
 676 ==>
 677         let f = let d1 = ..d.. in \y -> e
 678         in \x -> ...f...
 679 ==>
 680         let d1 = ..d..
 681         in \x -> ...(\y ->e)...
 682
 683 Only in this second round can the \y be applied, and it
 684 might do the same again.
 685
 686
 687 \begin{code}
 688 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 689 simplExpr env expr = simplExprC env expr (mkBoringStop expr_ty')
 690                    where
 691                      expr_ty' = substTy env (exprType expr)
 692         -- The type in the Stop continuation, expr_ty', is usually not used
 693         -- It's only needed when discarding continuations after finding
 694         -- a function that returns bottom.
 695         -- Hence the lazy substitution
 696
 697
 698 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 699         -- Simplify an expression, given a continuation
 700 simplExprC env expr cont
 701   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 702     returnSmpl (wrapFloats floats expr)
 703
 704 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 705         -- Simplify an expression, returning floated binds
 706
 707 simplExprF env (Var v)          cont = simplVar env v cont
 708 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 709 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 710 simplExprF env (Note note expr) cont = simplNote env note expr cont
 711 simplExprF env (App fun arg)    cont = simplExprF env fun (ApplyTo NoDup arg env cont)
 712
 713 simplExprF env (Type ty) cont
 714   = ASSERT( contIsRhsOrArg cont )
 715     simplType env ty                    `thenSmpl` \ ty' ->
 716     rebuild env (Type ty') cont
 717
 718 simplExprF env (Case scrut bndr case_ty alts) cont
 719   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 720   =     -- Simplify the scrutinee with a Select continuation
 721     simplExprF env scrut (Select NoDup bndr alts env cont)
 722
 723   | otherwise
 724   =     -- If case-of-case is off, simply simplify the case expression
 725         -- in a vanilla Stop context, and rebuild the result around it
 726     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 727     rebuild env case_expr' cont
 728   where
 729     case_cont = Select NoDup bndr alts env (mkBoringStop case_ty')
 730     case_ty'  = substTy env case_ty     -- c.f. defn of simplExpr
 731
 732 simplExprF env (Let (Rec pairs) body) cont
 733   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 734         -- NB: bndrs' don't have unfoldings or rules
 735         -- We add them as we go down
 736
 737     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 738     addFloats env floats                        $ \ env ->
 739     simplExprF env body cont
 740
 741 -- A non-recursive let is dealt with by simplNonRecBind
 742 simplExprF env (Let (NonRec bndr rhs) body) cont
 743   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 744     simplExprF env body cont
 745
 746
 747 ---------------------------------
 748 simplType :: SimplEnv -> InType -> SimplM OutType
 749         -- Kept monadic just so we can do the seqType
 750 simplType env ty
 751   = seqType new_ty   `seq`   returnSmpl new_ty
 752   where
 753     new_ty = substTy env ty
 754 \end{code}
 755
 756
 757 %************************************************************************
 758 %*                                                                      *
 759 \subsection{Lambdas}
 760 %*                                                                      *
 761 %************************************************************************
 762
 763 \begin{code}
 764 simplLam env fun cont
 765   = go env fun cont
 766   where
 767     zap_it  = mkLamBndrZapper fun (countArgs cont)
 768     cont_ty = contResultType cont
 769
 770         -- Type-beta reduction
 771     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) arg_se body_cont)
 772       = ASSERT( isTyVar bndr )
 773         tick (BetaReduction bndr)                       `thenSmpl_`
 774         simplType (setInScope arg_se env) ty_arg        `thenSmpl` \ ty_arg' ->
 775         go (extendTvSubst env bndr ty_arg') body body_cont
 776
 777         -- Ordinary beta reduction
 778     go env (Lam bndr body) cont@(ApplyTo _ arg arg_se body_cont)
 779       = tick (BetaReduction bndr)                               `thenSmpl_`
 780         simplNonRecBind env (zap_it bndr) arg arg_se cont_ty    $ \ env ->
 781         go env body body_cont
 782
 783         -- Not enough args, so there are real lambdas left to put in the result
 784     go env lam@(Lam _ _) cont
 785       = simplLamBndrs env bndrs         `thenSmpl` \ (env, bndrs') ->
 786         simplExpr env body              `thenSmpl` \ body' ->
 787         mkLam env bndrs' body' cont     `thenSmpl` \ (floats, new_lam) ->
 788         addFloats env floats            $ \ env ->
 789         rebuild env new_lam cont
 790       where
 791         (bndrs,body) = collectBinders lam
 792
 793         -- Exactly enough args
 794     go env expr cont = simplExprF env expr cont
 795
 796 mkLamBndrZapper :: CoreExpr     -- Function
 797                 -> Int          -- Number of args supplied, *including* type args
 798                 -> Id -> Id     -- Use this to zap the binders
 799 mkLamBndrZapper fun n_args
 800   | n_args >= n_params fun = \b -> b            -- Enough args
 801   | otherwise              = \b -> zapLamIdInfo b
 802   where
 803         -- NB: we count all the args incl type args
 804         -- so we must count all the binders (incl type lambdas)
 805     n_params (Note _ e) = n_params e
 806     n_params (Lam b e)  = 1 + n_params e
 807     n_params other      = 0::Int
 808 \end{code}
 809
 810
 811 %************************************************************************
 812 %*                                                                      *
 813 \subsection{Notes}
 814 %*                                                                      *
 815 %************************************************************************
 816
 817 \begin{code}
 818 simplNote env (Coerce to from) body cont
 819   = let
 820         addCoerce s1 k1 cont    -- Drop redundant coerces.  This can happen if a polymoprhic
 821                                 -- (coerce a b e) is instantiated with a=ty1 b=ty2 and the
 822                                 -- two are the same. This happens a lot in Happy-generated parsers
 823           | s1 `coreEqType` k1 = cont
 824
 825         addCoerce s1 k1 (CoerceIt t1 cont)
 826                 --      coerce T1 S1 (coerce S1 K1 e)
 827                 -- ==>
 828                 --      e,                      if T1=K1
 829                 --      coerce T1 K1 e,         otherwise
 830                 --
 831                 -- For example, in the initial form of a worker
 832                 -- we may find  (coerce T (coerce S (\x.e))) y
 833                 -- and we'd like it to simplify to e[y/x] in one round
 834                 -- of simplification
 835           | t1 `coreEqType` k1  = cont                  -- The coerces cancel out
 836           | otherwise           = CoerceIt t1 cont      -- They don't cancel, but
 837                                                         -- the inner one is redundant
 838
 839         addCoerce t1t2 s1s2 (ApplyTo dup arg arg_se cont)
 840           | not (isTypeArg arg),        -- This whole case only works for value args
 841                                         -- Could upgrade to have equiv thing for type apps too
 842             Just (s1, s2) <- splitFunTy_maybe s1s2
 843                 --      (coerce (T1->T2) (S1->S2) F) E
 844                 -- ===>
 845                 --      coerce T2 S2 (F (coerce S1 T1 E))
 846                 --
 847                 -- t1t2 must be a function type, T1->T2, because it's applied to something
 848                 -- but s1s2 might conceivably not be
 849                 --
 850                 -- When we build the ApplyTo we can't mix the out-types
 851                 -- with the InExpr in the argument, so we simply substitute
 852                 -- to make it all consistent.  It's a bit messy.
 853                 -- But it isn't a common case.
 854           = let
 855                 (t1,t2) = splitFunTy t1t2
 856                 new_arg = mkCoerce2 s1 t1 (substExpr arg_env arg)
 857                 arg_env = setInScope arg_se env
 858             in
 859             ApplyTo dup new_arg (zapSubstEnv env) (addCoerce t2 s2 cont)
 860
 861         addCoerce to' _ cont = CoerceIt to' cont
 862     in
 863     simplType env to            `thenSmpl` \ to' ->
 864     simplType env from          `thenSmpl` \ from' ->
 865     simplExprF env body (addCoerce to' from' cont)
 866
 867
 868 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 869 -- inlining.  All other CCCSs are mapped to currentCCS.
 870 simplNote env (SCC cc) e cont
 871   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 872     rebuild env (mkSCC cc e') cont
 873
 874 -- See notes with SimplMonad.inlineMode
 875 simplNote env InlineMe e cont
 876   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 877   =                             -- Don't inline inside an INLINE expression
 878     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 879     rebuild env (mkInlineMe e') cont
 880
 881   | otherwise   -- Dissolve the InlineMe note if there's
 882                 -- an interesting context of any kind to combine with
 883                 -- (even a type application -- anything except Stop)
 884   = simplExprF env e cont
 885
 886 simplNote env (CoreNote s) e cont
 887   = simplExpr env e    `thenSmpl` \ e' ->
 888     rebuild env (Note (CoreNote s) e') cont
 889 \end{code}
 890
 891
 892 %************************************************************************
 893 %*                                                                      *
 894 \subsection{Dealing with calls}
 895 %*                                                                      *
 896 %************************************************************************
 897
 898 \begin{code}
 899 simplVar env var cont
 900   = case substId env var of
 901         DoneEx e         -> simplExprF (zapSubstEnv env) e cont
 902         ContEx tvs ids e -> simplExprF (setSubstEnv env tvs ids) e cont
 903         DoneId var1 occ  -> completeCall (zapSubstEnv env) var1 occ cont
 904                 -- Note [zapSubstEnv]
 905                 -- The template is already simplified, so don't re-substitute.
 906                 -- This is VITAL.  Consider
 907                 --      let x = e in
 908                 --      let y = \z -> ...x... in
 909                 --      \ x -> ...y...
 910                 -- We'll clone the inner \x, adding x->x' in the id_subst
 911                 -- Then when we inline y, we must *not* replace x by x' in
 912                 -- the inlined copy!!
 913
 914 ---------------------------------------------------------
 915 --      Dealing with a call site
 916
 917 completeCall env var occ_info cont
 918   =     -- Simplify the arguments
 919     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 920     let
 921         chkr              = getSwitchChecker env
 922         (args, call_cont) = getContArgs chkr var cont
 923         fn_ty             = idType var
 924     in
 925     simplifyArgs env fn_ty (interestingArgContext var call_cont) args
 926                  (contResultType call_cont)     $ \ env args ->
 927
 928         -- Next, look for rules or specialisations that match
 929         --
 930         -- It's important to simplify the args first, because the rule-matcher
 931         -- doesn't do substitution as it goes.  We don't want to use subst_args
 932         -- (defined in the 'where') because that throws away useful occurrence info,
 933         -- and perhaps-very-important specialisations.
 934         --
 935         -- Some functions have specialisations *and* are strict; in this case,
 936         -- we don't want to inline the wrapper of the non-specialised thing; better
 937         -- to call the specialised thing instead.
 938         -- We used to use the black-listing mechanism to ensure that inlining of
 939         -- the wrapper didn't occur for things that have specialisations till a
 940         -- later phase, so but now we just try RULES first
 941         --
 942         -- You might think that we shouldn't apply rules for a loop breaker:
 943         -- doing so might give rise to an infinite loop, because a RULE is
 944         -- rather like an extra equation for the function:
 945         --      RULE:           f (g x) y = x+y
 946         --      Eqn:            f a     y = a-y
 947         --
 948         -- But it's too drastic to disable rules for loop breakers.
 949         -- Even the foldr/build rule would be disabled, because foldr
 950         -- is recursive, and hence a loop breaker:
 951         --      foldr k z (build g) = g k z
 952         -- So it's up to the programmer: rules can cause divergence
 953
 954     let
 955         in_scope   = getInScope env
 956         rules      = getRules env
 957         maybe_rule = case activeRule env of
 958                         Nothing     -> Nothing  -- No rules apply
 959                         Just act_fn -> lookupRule act_fn in_scope rules var args
 960     in
 961     case maybe_rule of {
 962         Just (rule_name, rule_rhs) ->
 963                 tick (RuleFired rule_name)                      `thenSmpl_`
 964                 (if dopt Opt_D_dump_inlinings dflags then
 965                    pprTrace "Rule fired" (vcat [
 966                         text "Rule:" <+> ftext rule_name,
 967                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 968                         text "After: " <+> pprCoreExpr rule_rhs,
 969                         text "Cont:  " <+> ppr call_cont])
 970                  else
 971                         id)             $
 972                 simplExprF env rule_rhs call_cont ;
 973
 974         Nothing ->              -- No rules
 975
 976         -- Next, look for an inlining
 977     let
 978         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
 979         interesting_cont = interestingCallContext (notNull args)
 980                                                   (notNull arg_infos)
 981                                                   call_cont
 982         active_inline = activeInline env var occ_info
 983         maybe_inline  = callSiteInline dflags active_inline occ_info
 984                                        var arg_infos interesting_cont
 985     in
 986     case maybe_inline of {
 987         Just unfolding          -- There is an inlining!
 988           ->  tick (UnfoldingDone var)          `thenSmpl_`
 989                 (if dopt Opt_D_dump_inlinings dflags then
 990                    pprTrace "Inlining done" (vcat [
 991                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 992                         text "Inlined fn: " <+> ppr unfolding,
 993                         text "Cont:  " <+> ppr call_cont])
 994                  else
 995                         id)             $
 996               makeThatCall env var unfolding args call_cont
 997
 998         ;
 999         Nothing ->              -- No inlining!
1000
1001         -- Done
1002     rebuild env (mkApps (Var var) args) call_cont
1003     }}
1004
1005 makeThatCall :: SimplEnv
1006              -> Id
1007              -> InExpr          -- Inlined function rhs
1008              -> [OutExpr]       -- Arguments, already simplified
1009              -> SimplCont       -- After the call
1010              -> SimplM FloatsWithExpr
1011 -- Similar to simplLam, but this time
1012 -- the arguments are already simplified
1013 makeThatCall orig_env var fun@(Lam _ _) args cont
1014   = go orig_env fun args
1015   where
1016     zap_it = mkLamBndrZapper fun (length args)
1017
1018         -- Type-beta reduction
1019     go env (Lam bndr body) (Type ty_arg : args)
1020       = ASSERT( isTyVar bndr )
1021         tick (BetaReduction bndr)                       `thenSmpl_`
1022         go (extendTvSubst env bndr ty_arg) body args
1023
1024         -- Ordinary beta reduction
1025     go env (Lam bndr body) (arg : args)
1026       = tick (BetaReduction bndr)                       `thenSmpl_`
1027         simplNonRecX env (zap_it bndr) arg              $ \ env ->
1028         go env body args
1029
1030         -- Not enough args, so there are real lambdas left to put in the result
1031     go env fun args
1032       = simplExprF env fun (pushContArgs orig_env args cont)
1033         -- NB: orig_env; the correct environment to capture with
1034         -- the arguments.... env has been augmented with substitutions
1035         -- from the beta reductions.
1036
1037 makeThatCall env var fun args cont
1038   = simplExprF env fun (pushContArgs env args cont)
1039 \end{code}
1040
1041
1042 %************************************************************************
1043 %*                                                                      *
1044 \subsection{Arguments}
1045 %*                                                                      *
1046 %************************************************************************
1047
1048 \begin{code}
1049 ---------------------------------------------------------
1050 --      Simplifying the arguments of a call
1051
1052 simplifyArgs :: SimplEnv
1053              -> OutType                         -- Type of the function
1054              -> Bool                            -- True if the fn has RULES
1055              -> [(InExpr, SimplEnv, Bool)]      -- Details of the arguments
1056              -> OutType                         -- Type of the continuation
1057              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1058              -> SimplM FloatsWithExpr
1059
1060 -- [CPS-like because of strict arguments]
1061
1062 -- Simplify the arguments to a call.
1063 -- This part of the simplifier may break the no-shadowing invariant
1064 -- Consider
1065 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1066 -- where f is strict in its second arg
1067 -- If we simplify the innermost one first we get (...(\a -> e)...)
1068 -- Simplifying the second arg makes us float the case out, so we end up with
1069 --      case y of (a,b) -> f (...(\a -> e)...) e'
1070 -- So the output does not have the no-shadowing invariant.  However, there is
1071 -- no danger of getting name-capture, because when the first arg was simplified
1072 -- we used an in-scope set that at least mentioned all the variables free in its
1073 -- static environment, and that is enough.
1074 --
1075 -- We can't just do innermost first, or we'd end up with a dual problem:
1076 --      case x of (a,b) -> f e (...(\a -> e')...)
1077 --
1078 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1079 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1080 -- continuations.  We have to keep the right in-scope set around; AND we have
1081 -- to get the effect that finding (error "foo") in a strict arg position will
1082 -- discard the entire application and replace it with (error "foo").  Getting
1083 -- all this at once is TOO HARD!
1084
1085 simplifyArgs env fn_ty has_rules args cont_ty thing_inside
1086   = go env fn_ty args thing_inside
1087   where
1088     go env fn_ty []         thing_inside = thing_inside env []
1089     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty has_rules arg cont_ty  $ \ env arg' ->
1090                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1091                                            thing_inside env (arg':args')
1092
1093 simplifyArg env fn_ty has_rules (Type ty_arg, se, _) cont_ty thing_inside
1094   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1095     thing_inside env (Type new_ty_arg)
1096
1097 simplifyArg env fn_ty has_rules (val_arg, arg_se, is_strict) cont_ty thing_inside
1098   | is_strict
1099   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1100
1101   | otherwise   -- Lazy argument
1102                 -- DO NOT float anything outside, hence simplExprC
1103                 -- There is no benefit (unlike in a let-binding), and we'd
1104                 -- have to be very careful about bogus strictness through
1105                 -- floating a demanded let.
1106   = simplExprC (setInScope arg_se env) val_arg
1107                (mkLazyArgStop arg_ty has_rules)         `thenSmpl` \ arg1 ->
1108     thing_inside env arg1
1109   where
1110     arg_ty = funArgTy fn_ty
1111
1112
1113 simplStrictArg ::  LetRhsFlag
1114                 -> SimplEnv             -- The env of the call
1115                 -> InExpr -> SimplEnv   -- The arg plus its env
1116                 -> OutType              -- arg_ty: type of the argument
1117                 -> OutType              -- cont_ty: Type of thing computed by the context
1118                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1119                                         -- Takes an expression of type rhs_ty,
1120                                         -- returns an expression of type cont_ty
1121                                         -- The env passed to this continuation is the
1122                                         -- env of the call, plus any new in-scope variables
1123                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1124
1125 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1126   = simplExprF (setInScope arg_env call_env) arg
1127                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1128   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1129   --    to simplify the argument
1130   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1131 \end{code}
1132
1133
1134 %************************************************************************
1135 %*                                                                      *
1136 \subsection{mkAtomicArgs}
1137 %*                                                                      *
1138 %************************************************************************
1139
1140 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1141 constructor application and, if so, converts it to ANF, so that the
1142 resulting thing can be inlined more easily.  Thus
1143         x = (f a, g b)
1144 becomes
1145         t1 = f a
1146         t2 = g b
1147         x = (t1,t2)
1148
1149 There are three sorts of binding context, specified by the two
1150 boolean arguments
1151
1152 Strict
1153    OK-unlifted
1154
1155 N  N    Top-level or recursive                  Only bind args of lifted type
1156
1157 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1158                 but lazy                        unlifted-and-ok-for-speculation
1159
1160 Y  Y    Non-top-level, non-recursive,           Bind all args
1161                  and strict (demanded)
1162
1163
1164 For example, given
1165
1166         x = MkC (y div# z)
1167
1168 there is no point in transforming to
1169
1170         x = case (y div# z) of r -> MkC r
1171
1172 because the (y div# z) can't float out of the let. But if it was
1173 a *strict* let, then it would be a good thing to do.  Hence the
1174 context information.
1175
1176 \begin{code}
1177 mkAtomicArgs :: Bool    -- A strict binding
1178              -> Bool    -- OK to float unlifted args
1179              -> OutExpr
1180              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1181                         OutExpr)                  -- things that need case-binding,
1182                                                   -- if the strict-binding flag is on
1183
1184 mkAtomicArgs is_strict ok_float_unlifted rhs
1185   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1186     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1187   = go fun nilOL [] args        -- Have a go
1188
1189   | otherwise = bale_out        -- Give up
1190
1191   where
1192     bale_out = returnSmpl (nilOL, rhs)
1193
1194     go fun binds rev_args []
1195         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1196
1197     go fun binds rev_args (arg : args)
1198         | exprIsTrivial arg     -- Easy case
1199         = go fun binds (arg:rev_args) args
1200
1201         | not can_float_arg     -- Can't make this arg atomic
1202         = bale_out              -- ... so give up
1203
1204         | otherwise     -- Don't forget to do it recursively
1205                         -- E.g.  x = a:b:c:[]
1206         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1207            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1208            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1209               (Var arg_id : rev_args) args
1210         where
1211           arg_ty        = exprType arg
1212           can_float_arg =  is_strict
1213                         || not (isUnLiftedType arg_ty)
1214                         || (ok_float_unlifted && exprOkForSpeculation arg)
1215
1216
1217 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1218                -> (SimplEnv -> SimplM (FloatsWith a))
1219                -> SimplM (FloatsWith a)
1220 addAtomicBinds env []         thing_inside = thing_inside env
1221 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1222                                              addAtomicBinds env bs thing_inside
1223
1224 addAtomicBindsE :: SimplEnv -> [(OutId,OutExpr)]
1225                 -> (SimplEnv -> SimplM FloatsWithExpr)
1226                 -> SimplM FloatsWithExpr
1227 -- Same again, but this time we're in an expression context,
1228 -- and may need to do some case bindings
1229
1230 addAtomicBindsE env [] thing_inside
1231   = thing_inside env
1232 addAtomicBindsE env ((v,r):bs) thing_inside
1233   | needsCaseBinding (idType v) r
1234   = addAtomicBindsE (addNewInScopeIds env [v]) bs thing_inside  `thenSmpl` \ (floats, expr) ->
1235     WARN( exprIsTrivial expr, ppr v <+> pprCoreExpr expr )
1236     (let body = wrapFloats floats expr in
1237      returnSmpl (emptyFloats env, Case r v (exprType body) [(DEFAULT,[],body)]))
1238
1239   | otherwise
1240   = addAuxiliaryBind env (NonRec v r)   $ \ env ->
1241     addAtomicBindsE env bs thing_inside
1242 \end{code}
1243
1244
1245 %************************************************************************
1246 %*                                                                      *
1247 \subsection{The main rebuilder}
1248 %*                                                                      *
1249 %************************************************************************
1250
1251 \begin{code}
1252 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1253
1254 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1255 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1256 rebuild env expr (CoerceIt to_ty cont)        = rebuild env (mkCoerce to_ty expr) cont
1257 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1258 rebuild env expr (ApplyTo _ arg se cont)      = rebuildApp  (setInScope se env) expr arg cont
1259
1260 rebuildApp env fun arg cont
1261   = simplExpr env arg   `thenSmpl` \ arg' ->
1262     rebuild env (App fun arg') cont
1263
1264 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1265 \end{code}
1266
1267
1268 %************************************************************************
1269 %*                                                                      *
1270 \subsection{Functions dealing with a case}
1271 %*                                                                      *
1272 %************************************************************************
1273
1274 Blob of helper functions for the "case-of-something-else" situation.
1275
1276 \begin{code}
1277 ---------------------------------------------------------
1278 --      Eliminate the case if possible
1279
1280 rebuildCase :: SimplEnv
1281             -> OutExpr          -- Scrutinee
1282             -> InId             -- Case binder
1283             -> [InAlt]          -- Alternatives (inceasing order)
1284             -> SimplCont
1285             -> SimplM FloatsWithExpr
1286
1287 rebuildCase env scrut case_bndr alts cont
1288   | Just (con,args) <- exprIsConApp_maybe scrut
1289         -- Works when the scrutinee is a variable with a known unfolding
1290         -- as well as when it's an explicit constructor application
1291   = knownCon env (DataAlt con) args case_bndr alts cont
1292
1293   | Lit lit <- scrut    -- No need for same treatment as constructors
1294                         -- because literals are inlined more vigorously
1295   = knownCon env (LitAlt lit) [] case_bndr alts cont
1296
1297   | otherwise
1298   =     -- Prepare the continuation;
1299         -- The new subst_env is in place
1300     prepareCaseCont env alts cont       `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1301     addFloats env floats                $ \ env ->
1302
1303     let
1304         -- The case expression is annotated with the result type of the continuation
1305         -- This may differ from the type originally on the case.  For example
1306         --      case(T) (case(Int#) a of { True -> 1#; False -> 0# }) of
1307         --         a# -> <blob>
1308         -- ===>
1309         --      let j a# = <blob>
1310         --      in case(T) a of { True -> j 1#; False -> j 0# }
1311         -- Note that the case that scrutinises a now returns a T not an Int#
1312         res_ty' = contResultType dup_cont
1313     in
1314
1315         -- Deal with case binder
1316     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr') ->
1317
1318         -- Deal with the case alternatives
1319     simplAlts alt_env scrut case_bndr' alts dup_cont    `thenSmpl` \ alts' ->
1320
1321         -- Put the case back together
1322     mkCase scrut case_bndr' res_ty' alts'       `thenSmpl` \ case_expr ->
1323
1324         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1325         -- The case binder *not* scope over the whole returned case-expression
1326     rebuild env case_expr nondup_cont
1327 \end{code}
1328
1329 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1330 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1331 way, there's a chance that v will now only be used once, and hence
1332 inlined.
1333
1334 Note 1
1335 ~~~~~~
1336 There is a time we *don't* want to do that, namely when
1337 -fno-case-of-case is on.  This happens in the first simplifier pass,
1338 and enhances full laziness.  Here's the bad case:
1339         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1340 If we eliminate the inner case, we trap it inside the I# v -> arm,
1341 which might prevent some full laziness happening.  I've seen this
1342 in action in spectral/cichelli/Prog.hs:
1343          [(m,n) | m <- [1..max], n <- [1..max]]
1344 Hence the check for NoCaseOfCase.
1345
1346 Note 2
1347 ~~~~~~
1348 There is another situation when we don't want to do it.  If we have
1349
1350     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1351                    ...other cases .... }
1352
1353 We'll perform the binder-swap for the outer case, giving
1354
1355     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1356                    ...other cases .... }
1357
1358 But there is no point in doing it for the inner case, because w1 can't
1359 be inlined anyway.  Furthermore, doing the case-swapping involves
1360 zapping w2's occurrence info (see paragraphs that follow), and that
1361 forces us to bind w2 when doing case merging.  So we get
1362
1363     case x of w1 { A -> let w2 = w1 in e1
1364                    B -> let w2 = w1 in e2
1365                    ...other cases .... }
1366
1367 This is plain silly in the common case where w2 is dead.
1368
1369 Even so, I can't see a good way to implement this idea.  I tried
1370 not doing the binder-swap if the scrutinee was already evaluated
1371 but that failed big-time:
1372
1373         data T = MkT !Int
1374
1375         case v of w  { MkT x ->
1376         case x of x1 { I# y1 ->
1377         case x of x2 { I# y2 -> ...
1378
1379 Notice that because MkT is strict, x is marked "evaluated".  But to
1380 eliminate the last case, we must either make sure that x (as well as
1381 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1382 the binder-swap.  So this whole note is a no-op.
1383
1384 Note 3
1385 ~~~~~~
1386 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1387 any occurrence info (eg IAmDead) in the case binder, because the
1388 case-binder now effectively occurs whenever v does.  AND we have to do
1389 the same for the pattern-bound variables!  Example:
1390
1391         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1392
1393 Here, b and p are dead.  But when we move the argment inside the first
1394 case RHS, and eliminate the second case, we get
1395
1396         case x of { (a,b) -> a b }
1397
1398 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1399 happened.
1400
1401 Indeed, this can happen anytime the case binder isn't dead:
1402         case <any> of x { (a,b) ->
1403         case x of { (p,q) -> p } }
1404 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1405 The point is that we bring into the envt a binding
1406         let x = (a,b)
1407 after the outer case, and that makes (a,b) alive.  At least we do unless
1408 the case binder is guaranteed dead.
1409
1410 \begin{code}
1411 simplCaseBinder env (Var v) case_bndr
1412   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
1413
1414 -- Failed try [see Note 2 above]
1415 --     not (isEvaldUnfolding (idUnfolding v))
1416
1417   = simplBinder env (zap case_bndr)             `thenSmpl` \ (env, case_bndr') ->
1418     returnSmpl (modifyInScope env v case_bndr', case_bndr')
1419         -- We could extend the substitution instead, but it would be
1420         -- a hack because then the substitution wouldn't be idempotent
1421         -- any more (v is an OutId).  And this does just as well.
1422   where
1423     zap b = b `setIdOccInfo` NoOccInfo
1424
1425 simplCaseBinder env other_scrut case_bndr
1426   = simplBinder env case_bndr           `thenSmpl` \ (env, case_bndr') ->
1427     returnSmpl (env, case_bndr')
1428 \end{code}
1429
1430
1431 simplAlts does two things:
1432
1433 1.  Eliminate alternatives that cannot match, including the
1434     DEFAULT alternative.
1435
1436 2.  If the DEFAULT alternative can match only one possible constructor,
1437     then make that constructor explicit.
1438     e.g.
1439         case e of x { DEFAULT -> rhs }
1440      ===>
1441         case e of x { (a,b) -> rhs }
1442     where the type is a single constructor type.  This gives better code
1443     when rhs also scrutinises x or e.
1444
1445 Here "cannot match" includes knowledge from GADTs
1446
1447 It's a good idea do do this stuff before simplifying the alternatives, to
1448 avoid simplifying alternatives we know can't happen, and to come up with
1449 the list of constructors that are handled, to put into the IdInfo of the
1450 case binder, for use when simplifying the alternatives.
1451
1452 Eliminating the default alternative in (1) isn't so obvious, but it can
1453 happen:
1454
1455 data Colour = Red | Green | Blue
1456
1457 f x = case x of
1458         Red -> ..
1459         Green -> ..
1460         DEFAULT -> h x
1461
1462 h y = case y of
1463         Blue -> ..
1464         DEFAULT -> [ case y of ... ]
1465
1466 If we inline h into f, the default case of the inlined h can't happen.
1467 If we don't notice this, we may end up filtering out *all* the cases
1468 of the inner case y, which give us nowhere to go!
1469
1470
1471 \begin{code}
1472 simplAlts :: SimplEnv
1473           -> OutExpr
1474           -> OutId                      -- Case binder
1475           -> [InAlt] -> SimplCont
1476           -> SimplM [OutAlt]            -- Includes the continuation
1477
1478 simplAlts env scrut case_bndr' alts cont'
1479   = do  { mb_alts      <- mapSmpl (simplAlt env imposs_cons case_bndr' cont') alts_wo_default
1480         ; default_alts <- simplDefault env case_bndr' imposs_deflt_cons cont' maybe_deflt
1481         ; return (mergeAlts default_alts [alt' | Just (_, alt') <- mb_alts]) }
1482         -- We need the mergeAlts in case the new default_alt
1483         -- has turned into a constructor alternative.
1484   where
1485     (alts_wo_default, maybe_deflt) = findDefault alts
1486     imposs_cons = case scrut of
1487                     Var v -> otherCons (idUnfolding v)
1488                     other -> []
1489
1490         -- "imposs_deflt_cons" are handled either by the context,
1491         -- OR by a branch in this case expression. (Don't include DEFAULT!!)
1492     imposs_deflt_cons = nub (imposs_cons ++ [con | (con,_,_) <- alts_wo_default])
1493
1494 simplDefault :: SimplEnv
1495              -> OutId           -- Case binder; need just for its type. Note that as an
1496                                 --   OutId, it has maximum information; this is important.
1497                                 --   Test simpl013 is an example
1498              -> [AltCon]        -- These cons can't happen when matching the default
1499              -> SimplCont
1500              -> Maybe InExpr
1501              -> SimplM [OutAlt] -- One branch or none; we use a list because it's what
1502                                 --   mergeAlts expects
1503
1504
1505 simplDefault env case_bndr' imposs_cons cont Nothing
1506   = return []   -- No default branch
1507 simplDefault env case_bndr' imposs_cons cont (Just rhs)
1508   |     -- This branch handles the case where we are
1509         -- scrutinisng an algebraic data type
1510     Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr'),
1511     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1512     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1513                                 --      case x of { DEFAULT -> e }
1514                                 -- and we don't want to fill in a default for them!
1515     Just all_cons <- tyConDataCons_maybe tycon,
1516     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1517                                 -- which GHC allows, then the case expression will have at most a default
1518                                 -- alternative.  We don't want to eliminate that alternative, because the
1519                                 -- invariant is that there's always one alternative.  It's more convenient
1520                                 -- to leave
1521                                 --      case x of { DEFAULT -> e }
1522                                 -- as it is, rather than transform it to
1523                                 --      error "case cant match"
1524                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1525                                 -- not worth wasting code on.
1526
1527     let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1528         poss_data_cons   = filterOut (`elem` imposs_data_cons) all_cons
1529         gadt_imposs      | all isTyVarTy inst_tys = []
1530                          | otherwise = filter (cant_match inst_tys) poss_data_cons
1531         final_poss       = filterOut (`elem` gadt_imposs) poss_data_cons
1532
1533   = case final_poss of
1534         []    -> returnSmpl []  -- Eliminate the default alternative
1535                                 -- altogether if it can't match
1536
1537         [con] ->        -- It matches exactly one constructor, so fill it in
1538                  do { con_alt <- mkDataConAlt case_bndr' con inst_tys rhs
1539                     ; Just (_, alt') <- simplAlt env [] case_bndr' cont con_alt
1540                         -- The simplAlt must succeed with Just because we have
1541                         -- already filtered out construtors that can't match
1542                     ; return [alt'] }
1543
1544         two_or_more -> simplify_default (map DataAlt gadt_imposs ++ imposs_cons)
1545
1546   | otherwise
1547   = simplify_default imposs_cons
1548   where
1549     cant_match tys data_con = not (dataConCanMatch data_con tys)
1550
1551     simplify_default imposs_cons
1552         = do { let env' = mk_rhs_env env case_bndr' (mkOtherCon imposs_cons)
1553                 -- Record the constructors that the case-binder *can't* be.
1554              ; rhs' <- simplExprC env' rhs cont
1555              ; return [(DEFAULT, [], rhs')] }
1556
1557 mkDataConAlt :: Id -> DataCon -> [OutType] -> InExpr -> SimplM InAlt
1558 -- Make a data-constructor alternative to replace the DEFAULT case
1559 -- NB: there's something a bit bogus here, because we put OutTypes into an InAlt
1560 mkDataConAlt case_bndr con tys rhs
1561   = do  { tick (FillInCaseDefault case_bndr)
1562         ; args <- mk_args con tys
1563         ; return (DataAlt con, args, rhs) }
1564   where
1565     mk_args con inst_tys
1566       = do { (tv_bndrs, inst_tys') <- mk_tv_bndrs con inst_tys
1567            ; let arg_tys = dataConInstArgTys con inst_tys'
1568            ; arg_ids <- mapM (newId FSLIT("a")) arg_tys
1569            ; returnSmpl (tv_bndrs ++ arg_ids) }
1570
1571     mk_tv_bndrs con inst_tys
1572       | isVanillaDataCon con
1573       = return ([], inst_tys)
1574       | otherwise
1575       = do { tv_uniqs <- getUniquesSmpl
1576            ; let new_tvs    = zipWith mk tv_uniqs (dataConTyVars con)
1577                  mk uniq tv = mkTyVar (mkSysTvName uniq FSLIT("t")) (tyVarKind tv)
1578            ; return (new_tvs, mkTyVarTys new_tvs) }
1579
1580 simplAlt :: SimplEnv
1581          -> [AltCon]    -- These constructors can't be present when
1582                         -- matching this alternative
1583          -> OutId       -- The case binder
1584          -> SimplCont
1585          -> InAlt
1586          -> SimplM (Maybe (TvSubstEnv, OutAlt))
1587
1588 -- Simplify an alternative, returning the type refinement for the
1589 -- alternative, if the alternative does any refinement at all
1590 -- Nothing => the alternative is inaccessible
1591
1592 simplAlt env imposs_cons case_bndr' cont' (con, bndrs, rhs)
1593   | con `elem` imposs_cons      -- This case can't match
1594   = return Nothing
1595
1596 simplAlt env handled_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1597         -- TURGID DUPLICATION, needed only for the simplAlt call
1598         -- in mkDupableAlt.  Clean this up when moving to FC
1599   = ASSERT( null bndrs )
1600     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1601     returnSmpl (Just (emptyVarEnv, (DEFAULT, [], rhs')))
1602   where
1603     env' = mk_rhs_env env case_bndr' (mkOtherCon handled_cons)
1604         -- Record the constructors that the case-binder *can't* be.
1605
1606 simplAlt env handled_cons case_bndr' cont' (LitAlt lit, bndrs, rhs)
1607   = ASSERT( null bndrs )
1608     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1609     returnSmpl (Just (emptyVarEnv, (LitAlt lit, [], rhs')))
1610   where
1611     env' = mk_rhs_env env case_bndr' (mkUnfolding False (Lit lit))
1612
1613 simplAlt env handled_cons case_bndr' cont' (DataAlt con, vs, rhs)
1614   | isVanillaDataCon con
1615   =     -- Deal with the pattern-bound variables
1616         -- Mark the ones that are in ! positions in the data constructor
1617         -- as certainly-evaluated.
1618         -- NB: it happens that simplBinders does *not* erase the OtherCon
1619         --     form of unfolding, so it's ok to add this info before
1620         --     doing simplBinders
1621     simplBinders env (add_evals con vs)         `thenSmpl` \ (env, vs') ->
1622
1623                 -- Bind the case-binder to (con args)
1624     let unf       = mkUnfolding False (mkConApp con con_args)
1625         inst_tys' = tyConAppArgs (idType case_bndr')
1626         con_args  = map Type inst_tys' ++ map varToCoreExpr vs'
1627         env'      = mk_rhs_env env case_bndr' unf
1628     in
1629     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1630     returnSmpl (Just (emptyVarEnv, (DataAlt con, vs', rhs')))
1631
1632   | otherwise   -- GADT case
1633   = let
1634         (tvs,ids) = span isTyVar vs
1635     in
1636     simplBinders env tvs                        `thenSmpl` \ (env1, tvs') ->
1637     case coreRefineTys con tvs' (idType case_bndr') of {
1638         Nothing         -- Inaccessible
1639             | opt_PprStyle_Debug        -- Hack: if debugging is on, generate an error case
1640                                         --       so we can see it
1641             ->  let rhs' = mkApps (Var eRROR_ID)
1642                                 [Type (substTy env (exprType rhs)),
1643                                  Lit (mkStringLit "Impossible alternative (GADT)")]
1644                 in
1645                 simplBinders env1 ids           `thenSmpl` \ (env2, ids') ->
1646                 returnSmpl (Just (emptyVarEnv, (DataAlt con, tvs' ++ ids', rhs')))
1647
1648             | otherwise -- Filter out the inaccessible branch
1649             -> return Nothing ;
1650
1651         Just refine@(tv_subst_env, _) ->        -- The normal case
1652
1653     let
1654         env2 = refineSimplEnv env1 refine
1655         -- Simplify the Ids in the refined environment, so their types
1656         -- reflect the refinement.  Usually this doesn't matter, but it helps
1657         -- in mkDupableAlt, when we want to float a lambda that uses these binders
1658         -- Furthermore, it means the binders contain maximal type information
1659     in
1660     simplBinders env2 (add_evals con ids)       `thenSmpl` \ (env3, ids') ->
1661     let unf        = mkUnfolding False con_app
1662         con_app    = mkConApp con con_args
1663         con_args   = map varToCoreExpr vs'      -- NB: no inst_tys'
1664         env_w_unf  = mk_rhs_env env3 case_bndr' unf
1665         vs'        = tvs' ++ ids'
1666     in
1667     simplExprC env_w_unf rhs cont'      `thenSmpl` \ rhs' ->
1668     returnSmpl (Just (tv_subst_env, (DataAlt con, vs', rhs'))) }
1669
1670   where
1671         -- add_evals records the evaluated-ness of the bound variables of
1672         -- a case pattern.  This is *important*.  Consider
1673         --      data T = T !Int !Int
1674         --
1675         --      case x of { T a b -> T (a+1) b }
1676         --
1677         -- We really must record that b is already evaluated so that we don't
1678         -- go and re-evaluate it when constructing the result.
1679     add_evals dc vs = cat_evals dc vs (dataConRepStrictness dc)
1680
1681     cat_evals dc vs strs
1682         = go vs strs
1683         where
1684           go [] [] = []
1685           go (v:vs) strs | isTyVar v = v : go vs strs
1686           go (v:vs) (str:strs)
1687             | isMarkedStrict str = evald_v  : go vs strs
1688             | otherwise          = zapped_v : go vs strs
1689             where
1690               zapped_v = zap_occ_info v
1691               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
1692           go _ _ = pprPanic "cat_evals" (ppr dc $$ ppr vs $$ ppr strs)
1693
1694         -- If the case binder is alive, then we add the unfolding
1695         --      case_bndr = C vs
1696         -- to the envt; so vs are now very much alive
1697     zap_occ_info | isDeadBinder case_bndr' = \id -> id
1698                  | otherwise               = \id -> id `setIdOccInfo` NoOccInfo
1699
1700 mk_rhs_env env case_bndr' case_bndr_unf
1701   = modifyInScope env case_bndr' (case_bndr' `setIdUnfolding` case_bndr_unf)
1702 \end{code}
1703
1704
1705 %************************************************************************
1706 %*                                                                      *
1707 \subsection{Known constructor}
1708 %*                                                                      *
1709 %************************************************************************
1710
1711 We are a bit careful with occurrence info.  Here's an example
1712
1713         (\x* -> case x of (a*, b) -> f a) (h v, e)
1714
1715 where the * means "occurs once".  This effectively becomes
1716         case (h v, e) of (a*, b) -> f a)
1717 and then
1718         let a* = h v; b = e in f a
1719 and then
1720         f (h v)
1721
1722 All this should happen in one sweep.
1723
1724 \begin{code}
1725 knownCon :: SimplEnv -> AltCon -> [OutExpr]
1726          -> InId -> [InAlt] -> SimplCont
1727          -> SimplM FloatsWithExpr
1728
1729 knownCon env con args bndr alts cont
1730   = tick (KnownBranch bndr)     `thenSmpl_`
1731     case findAlt con alts of
1732         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1733                                   simplNonRecX env bndr scrut   $ \ env ->
1734                                         -- This might give rise to a binding with non-atomic args
1735                                         -- like x = Node (f x) (g x)
1736                                         -- but no harm will be done
1737                                   simplExprF env rhs cont
1738                                 where
1739                                   scrut = case con of
1740                                             LitAlt lit -> Lit lit
1741                                             DataAlt dc -> mkConApp dc args
1742
1743         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1744                                   simplNonRecX env bndr (Lit lit)       $ \ env ->
1745                                   simplExprF env rhs cont
1746
1747         (DataAlt dc, bs, rhs)
1748                 -> ASSERT( n_drop_tys + length bs == length args )
1749                    bind_args env bs (drop n_drop_tys args)      $ \ env ->
1750                    let
1751                         con_app  = mkConApp dc (take n_drop_tys args ++ con_args)
1752                         con_args = [substExpr env (varToCoreExpr b) | b <- bs]
1753                                         -- args are aready OutExprs, but bs are InIds
1754                    in
1755                    simplNonRecX env bndr con_app                $ \ env ->
1756                    simplExprF env rhs cont
1757                 where
1758                    n_drop_tys | isVanillaDataCon dc = tyConArity (dataConTyCon dc)
1759                               | otherwise           = 0
1760                         -- Vanilla data constructors lack type arguments in the pattern
1761
1762 -- Ugh!
1763 bind_args env [] _ thing_inside = thing_inside env
1764
1765 bind_args env (b:bs) (Type ty : args) thing_inside
1766   = ASSERT( isTyVar b )
1767     bind_args (extendTvSubst env b ty) bs args thing_inside
1768
1769 bind_args env (b:bs) (arg : args) thing_inside
1770   = ASSERT( isId b )
1771     simplNonRecX env b arg      $ \ env ->
1772     bind_args env bs args thing_inside
1773 \end{code}
1774
1775
1776 %************************************************************************
1777 %*                                                                      *
1778 \subsection{Duplicating continuations}
1779 %*                                                                      *
1780 %************************************************************************
1781
1782 \begin{code}
1783 prepareCaseCont :: SimplEnv
1784                 -> [InAlt] -> SimplCont
1785                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1786                         -- Return a duplicatable continuation, a non-duplicable part
1787                         -- plus some extra bindings (that scope over the entire
1788                         -- continunation)
1789
1790         -- No need to make it duplicatable if there's only one alternative
1791 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1792 prepareCaseCont env alts  cont = mkDupableCont env cont
1793 \end{code}
1794
1795 \begin{code}
1796 mkDupableCont :: SimplEnv -> SimplCont
1797               -> SimplM (FloatsWith (SimplCont, SimplCont))
1798
1799 mkDupableCont env cont
1800   | contIsDupable cont
1801   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1802
1803 mkDupableCont env (CoerceIt ty cont)
1804   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1805     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1806
1807 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1808   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1809         -- Do *not* duplicate an ArgOf continuation
1810         -- Because ArgOf continuations are opaque, we gain nothing by
1811         -- propagating them into the expressions, and we do lose a lot.
1812         -- Here's an example:
1813         --      && (case x of { T -> F; F -> T }) E
1814         -- Now, && is strict so we end up simplifying the case with
1815         -- an ArgOf continuation.  If we let-bind it, we get
1816         --
1817         --      let $j = \v -> && v E
1818         --      in simplExpr (case x of { T -> F; F -> T })
1819         --                   (ArgOf (\r -> $j r)
1820         -- And after simplifying more we get
1821         --
1822         --      let $j = \v -> && v E
1823         --      in case of { T -> $j F; F -> $j T }
1824         -- Which is a Very Bad Thing
1825         --
1826         -- The desire not to duplicate is the entire reason that
1827         -- mkDupableCont returns a pair of continuations.
1828         --
1829         -- The original plan had:
1830         -- e.g.         (...strict-fn...) [...hole...]
1831         --      ==>
1832         --              let $j = \a -> ...strict-fn...
1833         --              in $j [...hole...]
1834
1835 mkDupableCont env (ApplyTo _ arg se cont)
1836   =     -- e.g.         [...hole...] (...arg...)
1837         --      ==>
1838         --              let a = ...arg...
1839         --              in [...hole...] a
1840     do  { (floats, (dup_cont, nondup_cont)) <- mkDupableCont env cont
1841         ; addFloats env floats $ \ env -> do
1842         { arg1 <- simplExpr (setInScope se env) arg
1843         ; (floats2, arg2) <- mkDupableArg env arg1
1844         ; return (floats2, (ApplyTo OkToDup arg2 (zapSubstEnv se) dup_cont, nondup_cont)) }}
1845
1846 mkDupableCont env (Select _ case_bndr alts se cont)
1847   =     -- e.g.         (case [...hole...] of { pi -> ei })
1848         --      ===>
1849         --              let ji = \xij -> ei
1850         --              in case [...hole...] of { pi -> ji xij }
1851     do  { tick (CaseOfCase case_bndr)
1852         ; let alt_env = setInScope se env
1853         ; (floats1, (dup_cont, nondup_cont)) <- mkDupableCont alt_env cont
1854                 -- NB: call mkDupableCont here, *not* prepareCaseCont
1855                 -- We must make a duplicable continuation, whereas prepareCaseCont
1856                 -- doesn't when there is a single case branch
1857         ; addFloats alt_env floats1     $ \ alt_env -> do
1858
1859         { (alt_env, case_bndr') <- simplBinder alt_env case_bndr
1860                 -- NB: simplBinder does not zap deadness occ-info, so
1861                 -- a dead case_bndr' will still advertise its deadness
1862                 -- This is really important because in
1863                 --      case e of b { (# a,b #) -> ... }
1864                 -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1865                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1866                 -- In the new alts we build, we have the new case binder, so it must retain
1867                 -- its deadness.
1868
1869         ; (floats2, alts') <- mkDupableAlts alt_env case_bndr' alts dup_cont
1870         ; return (floats2, (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1871                                    (mkBoringStop (contResultType dup_cont)),
1872                             nondup_cont))
1873         }}
1874
1875 mkDupableArg :: SimplEnv -> OutExpr -> SimplM (FloatsWith OutExpr)
1876 -- Let-bind the thing if necessary
1877 mkDupableArg env arg
1878   | exprIsDupable arg
1879   = return (emptyFloats env, arg)
1880   | otherwise
1881   = do  { arg_id <- newId FSLIT("a") (exprType arg)
1882         ; tick (CaseOfCase arg_id)
1883                 -- Want to tick here so that we go round again,
1884                 -- and maybe copy or inline the code.
1885                 -- Not strictly CaseOfCase, but never mind
1886         ; return (unitFloat env arg_id arg, Var arg_id) }
1887         -- What if the arg should be case-bound?
1888         -- This has been this way for a long time, so I'll leave it,
1889         -- but I can't convince myself that it's right.
1890
1891 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1892               -> SimplM (FloatsWith [InAlt])
1893 -- Absorbs the continuation into the new alternatives
1894
1895 mkDupableAlts env case_bndr' alts dupable_cont
1896   = go env alts
1897   where
1898     go env [] = returnSmpl (emptyFloats env, [])
1899     go env (alt:alts)
1900         = do { (floats1, mb_alt') <- mkDupableAlt env case_bndr' dupable_cont alt
1901              ; addFloats env floats1    $ \ env -> do
1902              { (floats2, alts') <- go env alts
1903              ; returnSmpl (floats2, case mb_alt' of
1904                                         Just alt' -> alt' : alts'
1905                                         Nothing   -> alts'
1906                           )}}
1907
1908 mkDupableAlt env case_bndr' cont alt
1909   = simplAlt env [] case_bndr' cont alt         `thenSmpl` \ mb_stuff ->
1910     case mb_stuff of {
1911         Nothing -> returnSmpl (emptyFloats env, Nothing) ;
1912
1913         Just (reft, (con, bndrs', rhs')) ->
1914         -- Safe to say that there are no handled-cons for the DEFAULT case
1915
1916     if exprIsDupable rhs' then
1917         returnSmpl (emptyFloats env, Just (con, bndrs', rhs'))
1918         -- It is worth checking for a small RHS because otherwise we
1919         -- get extra let bindings that may cause an extra iteration of the simplifier to
1920         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1921         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1922         -- iterations because the version with the let bindings looked big, and so wasn't
1923         -- inlined, but after the join points had been inlined it looked smaller, and so
1924         -- was inlined.
1925         --
1926         -- NB: we have to check the size of rhs', not rhs.
1927         -- Duplicating a small InAlt might invalidate occurrence information
1928         -- However, if it *is* dupable, we return the *un* simplified alternative,
1929         -- because otherwise we'd need to pair it up with an empty subst-env....
1930         -- but we only have one env shared between all the alts.
1931         -- (Remember we must zap the subst-env before re-simplifying something).
1932         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1933
1934     else
1935     let
1936         rhs_ty'     = exprType rhs'
1937         used_bndrs' = filter abstract_over (case_bndr' : bndrs')
1938         abstract_over bndr
1939           | isTyVar bndr = not (bndr `elemVarEnv` reft)
1940                 -- Don't abstract over tyvar binders which are refined away
1941                 -- See Note [Refinement] below
1942           | otherwise    = not (isDeadBinder bndr)
1943                 -- The deadness info on the new Ids is preserved by simplBinders
1944     in
1945         -- If we try to lift a primitive-typed something out
1946         -- for let-binding-purposes, we will *caseify* it (!),
1947         -- with potentially-disastrous strictness results.  So
1948         -- instead we turn it into a function: \v -> e
1949         -- where v::State# RealWorld#.  The value passed to this function
1950         -- is realworld#, which generates (almost) no code.
1951
1952         -- There's a slight infelicity here: we pass the overall
1953         -- case_bndr to all the join points if it's used in *any* RHS,
1954         -- because we don't know its usage in each RHS separately
1955
1956         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1957         -- we make the join point into a function whenever used_bndrs'
1958         -- is empty.  This makes the join-point more CPR friendly.
1959         -- Consider:    let j = if .. then I# 3 else I# 4
1960         --              in case .. of { A -> j; B -> j; C -> ... }
1961         --
1962         -- Now CPR doesn't w/w j because it's a thunk, so
1963         -- that means that the enclosing function can't w/w either,
1964         -- which is a lose.  Here's the example that happened in practice:
1965         --      kgmod :: Int -> Int -> Int
1966         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1967         --                  then 78
1968         --                  else 5
1969         --
1970         -- I have seen a case alternative like this:
1971         --      True -> \v -> ...
1972         -- It's a bit silly to add the realWorld dummy arg in this case, making
1973         --      $j = \s v -> ...
1974         --         True -> $j s
1975         -- (the \v alone is enough to make CPR happy) but I think it's rare
1976
1977     ( if not (any isId used_bndrs')
1978         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
1979              returnSmpl ([rw_id], [Var realWorldPrimId])
1980         else
1981              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs')
1982     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
1983
1984         -- See comment about "$j" name above
1985     newId FSLIT("$j") (mkPiTypes final_bndrs' rhs_ty')  `thenSmpl` \ join_bndr ->
1986         -- Notice the funky mkPiTypes.  If the contructor has existentials
1987         -- it's possible that the join point will be abstracted over
1988         -- type varaibles as well as term variables.
1989         --  Example:  Suppose we have
1990         --      data T = forall t.  C [t]
1991         --  Then faced with
1992         --      case (case e of ...) of
1993         --          C t xs::[t] -> rhs
1994         --  We get the join point
1995         --      let j :: forall t. [t] -> ...
1996         --          j = /\t \xs::[t] -> rhs
1997         --      in
1998         --      case (case e of ...) of
1999         --          C t xs::[t] -> j t xs
2000     let
2001         -- We make the lambdas into one-shot-lambdas.  The
2002         -- join point is sure to be applied at most once, and doing so
2003         -- prevents the body of the join point being floated out by
2004         -- the full laziness pass
2005         really_final_bndrs     = map one_shot final_bndrs'
2006         one_shot v | isId v    = setOneShotLambda v
2007                    | otherwise = v
2008         join_rhs  = mkLams really_final_bndrs rhs'
2009         join_call = mkApps (Var join_bndr) final_args
2010     in
2011     returnSmpl (unitFloat env join_bndr join_rhs, Just (con, bndrs', join_call)) }
2012 \end{code}
2013
2014 Note [Refinement]
2015 ~~~~~~~~~~~~~~~~~
2016 Consider
2017         data T a where
2018           MkT :: a -> b -> T a
2019
2020         f = /\a. \(w::a).
2021            case (case ...) of
2022                   MkT a' b (p::a') (q::b) -> [p,w]
2023
2024 The danger is that we'll make a join point
2025
2026         j a' p = [p,w]
2027
2028 and that's ill-typed, because (p::a') but (w::a).
2029
2030 Solution so far: don't abstract over a', because the type refinement
2031 maps [a' -> a] .  Ultimately that won't work when real refinement goes on.
2032
2033 Then we must abstract over any refined free variables.  Hmm.  Maybe we
2034 could just abstract over *all* free variables, thereby lambda-lifting
2035 the join point?   We should try this.