compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplEnv
  16 import SimplUtils       ( mkCase, mkLam,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkRhsStop, mkBoringStop,  mkLazyArgStop, pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType,
  21                           preInlineUnconditionally, postInlineUnconditionally,
  22                           interestingArgContext, inlineMode, activeInline, activeRule
  23                         )
  24 import Id               ( Id, idType, idInfo, idArity, isDataConWorkId,
  25                           idUnfolding, setIdUnfolding, isDeadBinder,
  26                           idNewDemandInfo, setIdInfo,
  27                           setIdOccInfo, zapLamIdInfo, setOneShotLambda
  28                         )
  29 import IdInfo           ( OccInfo(..), setArityInfo, zapDemandInfo,
  30                           setUnfoldingInfo, occInfo
  31                         )
  32 import NewDemand        ( isStrictDmd )
  33 import TcGadt           ( dataConCanMatch )
  34 import DataCon          ( dataConTyCon, dataConRepStrictness )
  35 import TyCon            ( tyConArity, isAlgTyCon, isNewTyCon, tyConDataCons_maybe )
  36 import CoreSyn
  37 import PprCore          ( pprParendExpr, pprCoreExpr )
  38 import CoreUnfold       ( mkUnfolding, callSiteInline )
  39 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  40                           exprIsConApp_maybe, mkPiTypes, findAlt,
  41                           exprType, exprIsHNF, findDefault, mergeAlts,
  42                           exprOkForSpeculation, exprArity,
  43                           mkCoerce, mkSCC, mkInlineMe, applyTypeToArg,
  44                           dataConRepInstPat
  45                         )
  46 import Rules            ( lookupRule )
  47 import BasicTypes       ( isMarkedStrict )
  48 import CostCentre       ( currentCCS )
  49 import Type             ( TvSubstEnv, isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  50                           coreEqType, splitTyConApp_maybe,
  51                           isTyVarTy, isFunTy, tcEqType
  52                         )
  53 import Coercion         ( Coercion, coercionKind,
  54                           mkTransCoercion, mkSymCoercion, splitCoercionKind_maybe, decomposeCo  )
  55 import VarEnv           ( elemVarEnv, emptyVarEnv )
  56 import TysPrim          ( realWorldStatePrimTy )
  57 import PrelInfo         ( realWorldPrimId )
  58 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  59                           RecFlag(..), isNonRec, isNonRuleLoopBreaker
  60                         )
  61 import OrdList
  62 import List             ( nub )
  63 import Maybes           ( orElse )
  64 import Outputable
  65 import Util             ( notNull, filterOut )
  66 \end{code}
  67
  68
  69 The guts of the simplifier is in this module, but the driver loop for
  70 the simplifier is in SimplCore.lhs.
  71
  72
  73 -----------------------------------------
  74         *** IMPORTANT NOTE ***
  75 -----------------------------------------
  76 The simplifier used to guarantee that the output had no shadowing, but
  77 it does not do so any more.   (Actually, it never did!)  The reason is
  78 documented with simplifyArgs.
  79
  80
  81 -----------------------------------------
  82         *** IMPORTANT NOTE ***
  83 -----------------------------------------
  84 Many parts of the simplifier return a bunch of "floats" as well as an
  85 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  86
  87 All "floats" are let-binds, not case-binds, but some non-rec lets may
  88 be unlifted (with RHS ok-for-speculation).
  89
  90
  91
  92 -----------------------------------------
  93         ORGANISATION OF FUNCTIONS
  94 -----------------------------------------
  95 simplTopBinds
  96   - simplify all top-level binders
  97   - for NonRec, call simplRecOrTopPair
  98   - for Rec,    call simplRecBind
  99
 100
 101         ------------------------------
 102 simplExpr (applied lambda)      ==> simplNonRecBind
 103 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 104 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 105
 106         ------------------------------
 107 simplRecBind    [binders already simplfied]
 108   - use simplRecOrTopPair on each pair in turn
 109
 110 simplRecOrTopPair [binder already simplified]
 111   Used for: recursive bindings (top level and nested)
 112             top-level non-recursive bindings
 113   Returns:
 114   - check for PreInlineUnconditionally
 115   - simplLazyBind
 116
 117 simplNonRecBind
 118   Used for: non-top-level non-recursive bindings
 119             beta reductions (which amount to the same thing)
 120   Because it can deal with strict arts, it takes a
 121         "thing-inside" and returns an expression
 122
 123   - check for PreInlineUnconditionally
 124   - simplify binder, including its IdInfo
 125   - if strict binding
 126         simplStrictArg
 127         mkAtomicArgs
 128         completeNonRecX
 129     else
 130         simplLazyBind
 131         addFloats
 132
 133 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 134   Used for: binding case-binder and constr args in a known-constructor case
 135   - check for PreInLineUnconditionally
 136   - simplify binder
 137   - completeNonRecX
 138
 139         ------------------------------
 140 simplLazyBind:  [binder already simplified, RHS not]
 141   Used for: recursive bindings (top level and nested)
 142             top-level non-recursive bindings
 143             non-top-level, but *lazy* non-recursive bindings
 144         [must not be strict or unboxed]
 145   Returns floats + an augmented environment, not an expression
 146   - substituteIdInfo and add result to in-scope
 147         [so that rules are available in rec rhs]
 148   - simplify rhs
 149   - mkAtomicArgs
 150   - float if exposes constructor or PAP
 151   - completeLazyBind
 152
 153
 154 completeNonRecX:        [binder and rhs both simplified]
 155   - if the the thing needs case binding (unlifted and not ok-for-spec)
 156         build a Case
 157    else
 158         completeLazyBind
 159         addFloats
 160
 161 completeLazyBind:       [given a simplified RHS]
 162         [used for both rec and non-rec bindings, top level and not]
 163   - try PostInlineUnconditionally
 164   - add unfolding [this is the only place we add an unfolding]
 165   - add arity
 166
 167
 168
 169 Right hand sides and arguments
 170 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 171 In many ways we want to treat
 172         (a) the right hand side of a let(rec), and
 173         (b) a function argument
 174 in the same way.  But not always!  In particular, we would
 175 like to leave these arguments exactly as they are, so they
 176 will match a RULE more easily.
 177
 178         f (g x, h x)
 179         g (+ x)
 180
 181 It's harder to make the rule match if we ANF-ise the constructor,
 182 or eta-expand the PAP:
 183
 184         f (let { a = g x; b = h x } in (a,b))
 185         g (\y. + x y)
 186
 187 On the other hand if we see the let-defns
 188
 189         p = (g x, h x)
 190         q = + x
 191
 192 then we *do* want to ANF-ise and eta-expand, so that p and q
 193 can be safely inlined.
 194
 195 Even floating lets out is a bit dubious.  For let RHS's we float lets
 196 out if that exposes a value, so that the value can be inlined more vigorously.
 197 For example
 198
 199         r = let x = e in (x,x)
 200
 201 Here, if we float the let out we'll expose a nice constructor. We did experiments
 202 that showed this to be a generally good thing.  But it was a bad thing to float
 203 lets out unconditionally, because that meant they got allocated more often.
 204
 205 For function arguments, there's less reason to expose a constructor (it won't
 206 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 207 So for the moment we don't float lets out of function arguments either.
 208
 209
 210 Eta expansion
 211 ~~~~~~~~~~~~~~
 212 For eta expansion, we want to catch things like
 213
 214         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 215
 216 If the \x was on the RHS of a let, we'd eta expand to bring the two
 217 lambdas together.  And in general that's a good thing to do.  Perhaps
 218 we should eta expand wherever we find a (value) lambda?  Then the eta
 219 expansion at a let RHS can concentrate solely on the PAP case.
 220
 221
 222 %************************************************************************
 223 %*                                                                      *
 224 \subsection{Bindings}
 225 %*                                                                      *
 226 %************************************************************************
 227
 228 \begin{code}
 229 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 230
 231 simplTopBinds env binds
 232   =     -- Put all the top-level binders into scope at the start
 233         -- so that if a transformation rule has unexpectedly brought
 234         -- anything into scope, then we don't get a complaint about that.
 235         -- It's rather as if the top-level binders were imported.
 236     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 237     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 238     freeTick SimplifierDone                     `thenSmpl_`
 239     returnSmpl (floatBinds floats)
 240   where
 241         -- We need to track the zapped top-level binders, because
 242         -- they should have their fragile IdInfo zapped (notably occurrence info)
 243         -- That's why we run down binds and bndrs' simultaneously.
 244     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 245     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 246     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 247                                       addFloats env floats              $ \env ->
 248                                       simpl_binds env binds (drop_bs bind bs)
 249
 250     drop_bs (NonRec _ _) (_ : bs) = bs
 251     drop_bs (Rec prs)    bs       = drop (length prs) bs
 252
 253     simpl_bind env bind bs
 254       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 255         if dopt Opt_D_dump_inlinings dflags then
 256            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 257         else
 258            simpl_bind1 env bind bs
 259
 260     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 261     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 262 \end{code}
 263
 264
 265 %************************************************************************
 266 %*                                                                      *
 267 \subsection{simplNonRec}
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 simplNonRecBind is used for
 272   * non-top-level non-recursive lets in expressions
 273   * beta reduction
 274
 275 It takes
 276   * An unsimplified (binder, rhs) pair
 277   * The env for the RHS.  It may not be the same as the
 278         current env because the bind might occur via (\x.E) arg
 279
 280 It uses the CPS form because the binding might be strict, in which
 281 case we might discard the continuation:
 282         let x* = error "foo" in (...x...)
 283
 284 It needs to turn unlifted bindings into a @case@.  They can arise
 285 from, say:      (\x -> e) (4# + 3#)
 286
 287 \begin{code}
 288 simplNonRecBind :: SimplEnv
 289                 -> InId                                 -- Binder
 290                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 291                 -> OutType                              -- Type of thing computed by the context
 292                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 293                 -> SimplM FloatsWithExpr
 294 #ifdef DEBUG
 295 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 296   | isTyVar bndr
 297   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 298 #endif
 299
 300 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 301   = simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 302
 303 simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 304   | preInlineUnconditionally env NotTopLevel bndr rhs
 305   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 306     thing_inside (extendIdSubst env bndr (mkContEx rhs_se rhs))
 307
 308   | isStrictDmd (idNewDemandInfo bndr) || isStrictType bndr_ty  -- A strict let
 309   =     -- Don't use simplBinder because that doesn't keep
 310         -- fragile occurrence info in the substitution
 311     simplNonRecBndr env bndr                                    `thenSmpl` \ (env, bndr1) ->
 312     simplStrictArg AnRhs env rhs rhs_se (idType bndr1) cont_ty  $ \ env1 rhs1 ->
 313
 314         -- Now complete the binding and simplify the body
 315     let
 316         (env2,bndr2) = addLetIdInfo env1 bndr bndr1
 317     in
 318     completeNonRecX env2 True {- strict -} bndr bndr2 rhs1 thing_inside
 319
 320   | otherwise                                                   -- Normal, lazy case
 321   =     -- Don't use simplBinder because that doesn't keep
 322         -- fragile occurrence info in the substitution
 323     simplNonRecBndr env bndr                            `thenSmpl` \ (env, bndr') ->
 324     simplLazyBind env NotTopLevel NonRecursive
 325                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 326     addFloats env floats thing_inside
 327
 328   where
 329     bndr_ty = idType bndr
 330 \end{code}
 331
 332 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 333 in knownCon.  It uses case-binding where necessary.
 334
 335 \begin{code}
 336 simplNonRecX :: SimplEnv
 337              -> InId            -- Old binder
 338              -> OutExpr         -- Simplified RHS
 339              -> (SimplEnv -> SimplM FloatsWithExpr)
 340              -> SimplM FloatsWithExpr
 341
 342 simplNonRecX env bndr new_rhs thing_inside
 343   = do  { (env, bndr') <- simplBinder env bndr
 344         ; completeNonRecX env False {- Non-strict; pessimistic -}
 345                           bndr bndr' new_rhs thing_inside }
 346
 347
 348 completeNonRecX :: SimplEnv
 349                 -> Bool                 -- Strict binding
 350                 -> InId                 -- Old binder
 351                 -> OutId                -- New binder
 352                 -> OutExpr              -- Simplified RHS
 353                 -> (SimplEnv -> SimplM FloatsWithExpr)
 354                 -> SimplM FloatsWithExpr
 355
 356 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 357   | needsCaseBinding (idType new_bndr) new_rhs
 358         -- Make this test *before* the preInlineUnconditionally
 359         -- Consider     case I# (quotInt# x y) of
 360         --                I# v -> let w = J# v in ...
 361         -- If we gaily inline (quotInt# x y) for v, we end up building an
 362         -- extra thunk:
 363         --                let w = J# (quotInt# x y) in ...
 364         -- because quotInt# can fail.
 365   = do  { (floats, body) <- thing_inside env
 366         ; let body' = wrapFloats floats body
 367         ; return (emptyFloats env, Case new_rhs new_bndr (exprType body)
 368                                         [(DEFAULT, [], body')]) }
 369
 370   | otherwise
 371   =     -- Make the arguments atomic if necessary,
 372         -- adding suitable bindings
 373     mkAtomicArgsE env is_strict new_rhs         $ \ env new_rhs ->
 374     completeLazyBind env NotTopLevel
 375                      old_bndr new_bndr new_rhs  `thenSmpl` \ (floats, env) ->
 376     addFloats env floats thing_inside
 377
 378 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
 379    Doing so risks exponential behaviour, because new_rhs has been simplified once already
 380    In the cases described by the folowing commment, postInlineUnconditionally will
 381    catch many of the relevant cases.
 382         -- This happens; for example, the case_bndr during case of
 383         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 384         -- Here x isn't mentioned in the RHS, so we don't want to
 385         -- create the (dead) let-binding  let x = (a,b) in ...
 386         --
 387         -- Similarly, single occurrences can be inlined vigourously
 388         -- e.g.  case (f x, g y) of (a,b) -> ....
 389         -- If a,b occur once we can avoid constructing the let binding for them.
 390   | preInlineUnconditionally env NotTopLevel bndr new_rhs
 391   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
 392
 393   -- NB: completeLazyBind uses postInlineUnconditionally; no need to do that here
 394 -}
 395 \end{code}
 396
 397
 398 %************************************************************************
 399 %*                                                                      *
 400 \subsection{Lazy bindings}
 401 %*                                                                      *
 402 %************************************************************************
 403
 404 simplRecBind is used for
 405         * recursive bindings only
 406
 407 \begin{code}
 408 simplRecBind :: SimplEnv -> TopLevelFlag
 409              -> [(InId, InExpr)] -> [OutId]
 410              -> SimplM (FloatsWith SimplEnv)
 411 simplRecBind env top_lvl pairs bndrs'
 412   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 413     returnSmpl (flattenFloats floats, env)
 414   where
 415     go env [] _ = returnSmpl (emptyFloats env, env)
 416
 417     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 418         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 419           addFloats env floats (\env -> go env pairs bndrs')
 420 \end{code}
 421
 422
 423 simplRecOrTopPair is used for
 424         * recursive bindings (whether top level or not)
 425         * top-level non-recursive bindings
 426
 427 It assumes the binder has already been simplified, but not its IdInfo.
 428
 429 \begin{code}
 430 simplRecOrTopPair :: SimplEnv
 431                   -> TopLevelFlag
 432                   -> InId -> OutId              -- Binder, both pre-and post simpl
 433                   -> InExpr                     -- The RHS and its environment
 434                   -> SimplM (FloatsWith SimplEnv)
 435
 436 simplRecOrTopPair env top_lvl bndr bndr' rhs
 437   | preInlineUnconditionally env top_lvl bndr rhs       -- Check for unconditional inline
 438   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 439     returnSmpl (emptyFloats env, extendIdSubst env bndr (mkContEx env rhs))
 440
 441   | otherwise
 442   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 443         -- May not actually be recursive, but it doesn't matter
 444 \end{code}
 445
 446
 447 simplLazyBind is used for
 448         * recursive bindings (whether top level or not)
 449         * top-level non-recursive bindings
 450         * non-top-level *lazy* non-recursive bindings
 451
 452 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 453 from SimplRecOrTopBind]
 454
 455 Nota bene:
 456     1. It assumes that the binder is *already* simplified,
 457        and is in scope, but not its IdInfo
 458
 459     2. It assumes that the binder type is lifted.
 460
 461     3. It does not check for pre-inline-unconditionallly;
 462        that should have been done already.
 463
 464 \begin{code}
 465 simplLazyBind :: SimplEnv
 466               -> TopLevelFlag -> RecFlag
 467               -> InId -> OutId          -- Binder, both pre-and post simpl
 468               -> InExpr -> SimplEnv     -- The RHS and its environment
 469               -> SimplM (FloatsWith SimplEnv)
 470
 471 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 472   = let
 473         (env1,bndr2)      = addLetIdInfo env bndr bndr1
 474         rhs_env           = setInScope rhs_se env1
 475         is_top_level      = isTopLevel top_lvl
 476         ok_float_unlifted = not is_top_level && isNonRec is_rec
 477         rhs_cont          = mkRhsStop (idType bndr2)
 478     in
 479         -- Simplify the RHS; note the mkRhsStop, which tells
 480         -- the simplifier that this is the RHS of a let.
 481     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 482
 483         -- If any of the floats can't be floated, give up now
 484         -- (The allLifted predicate says True for empty floats.)
 485     if (not ok_float_unlifted && not (allLifted floats)) then
 486         completeLazyBind env1 top_lvl bndr bndr2
 487                          (wrapFloats floats rhs1)
 488     else
 489
 490         -- ANF-ise a constructor or PAP rhs
 491     mkAtomicArgs False {- Not strict -}
 492                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 493
 494         -- If the result is a PAP, float the floats out, else wrap them
 495         -- By this time it's already been ANF-ised (if necessary)
 496     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 497         completeLazyBind env1 top_lvl bndr bndr2 rhs2
 498
 499     else if is_top_level || exprIsTrivial rhs2 || exprIsHNF rhs2 then
 500         --      WARNING: long dodgy argument coming up
 501         --      WANTED: a better way to do this
 502         --
 503         -- We can't use "exprIsCheap" instead of exprIsHNF,
 504         -- because that causes a strictness bug.
 505         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 506         -- The case expression is 'cheap', but it's wrong to transform to
 507         --         y* = E; x = case (scc y) of {...}
 508         -- Either we must be careful not to float demanded non-values, or
 509         -- we must use exprIsHNF for the test, which ensures that the
 510         -- thing is non-strict.  So exprIsHNF => bindings are non-strict
 511         -- I think.  The WARN below tests for this.
 512         --
 513         -- We use exprIsTrivial here because we want to reveal lone variables.
 514         -- E.g.  let { x = letrec { y = E } in y } in ...
 515         -- Here we definitely want to float the y=E defn.
 516         -- exprIsHNF definitely isn't right for that.
 517         --
 518         -- Again, the floated binding can't be strict; if it's recursive it'll
 519         -- be non-strict; if it's non-recursive it'd be inlined.
 520         --
 521         -- Note [SCC-and-exprIsTrivial]
 522         -- If we have
 523         --      y = let { x* = E } in scc "foo" x
 524         -- then we do *not* want to float out the x binding, because
 525         -- it's strict!  Fortunately, exprIsTrivial replies False to
 526         -- (scc "foo" x).
 527
 528                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 529                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 530                 -- to float it out?  Answer no, but it won't matter because
 531                 -- we only float if (a) arg' is a WHNF, or (b) it's going to top level
 532                 -- and so there can't be any 'will be demanded' bindings in the floats.
 533                 -- Hence the warning
 534         WARN( not (is_top_level || not (any demanded_float (floatBinds floats))),
 535               ppr (filter demanded_float (floatBinds floats)) )
 536
 537         tick LetFloatFromLet                    `thenSmpl_` (
 538         addFloats env1 floats                   $ \ env2 ->
 539         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 540         completeLazyBind env3 top_lvl bndr bndr2 rhs2)
 541
 542     else
 543         completeLazyBind env1 top_lvl bndr bndr2 (wrapFloats floats rhs1)
 544
 545 #ifdef DEBUG
 546 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 547                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 548 demanded_float (Rec _)      = False
 549 #endif
 550 \end{code}
 551
 552
 553 %************************************************************************
 554 %*                                                                      *
 555 \subsection{Completing a lazy binding}
 556 %*                                                                      *
 557 %************************************************************************
 558
 559 completeLazyBind
 560         * deals only with Ids, not TyVars
 561         * takes an already-simplified binder and RHS
 562         * is used for both recursive and non-recursive bindings
 563         * is used for both top-level and non-top-level bindings
 564
 565 It does the following:
 566   - tries discarding a dead binding
 567   - tries PostInlineUnconditionally
 568   - add unfolding [this is the only place we add an unfolding]
 569   - add arity
 570
 571 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 572         - top-level bindings (when let-to-case is impossible)
 573         - many situations where the "rhs" is known to be a WHNF
 574                 (so let-to-case is inappropriate).
 575
 576 \begin{code}
 577 completeLazyBind :: SimplEnv
 578                  -> TopLevelFlag        -- Flag stuck into unfolding
 579                  -> InId                -- Old binder
 580                  -> OutId               -- New binder
 581                  -> OutExpr             -- Simplified RHS
 582                  -> SimplM (FloatsWith SimplEnv)
 583 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 584 -- by extending the substitution (e.g. let x = y in ...)
 585 -- The new binding (if any) is returned as part of the floats.
 586 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 587 --     (as usual) use the in-scope-env from the floats
 588
 589 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 590   | postInlineUnconditionally env top_lvl new_bndr occ_info new_rhs unfolding
 591   =             -- Drop the binding
 592     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 593     -- pprTrace "Inline unconditionally" (ppr old_bndr <+> ppr new_bndr <+> ppr new_rhs) $
 594     returnSmpl (emptyFloats env, extendIdSubst env old_bndr (DoneEx new_rhs))
 595                 -- Use the substitution to make quite, quite sure that the substitution
 596                 -- will happen, since we are going to discard the binding
 597
 598   |  otherwise
 599   = let
 600         --      Arity info
 601         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 602
 603         --      Unfolding info
 604         -- Add the unfolding *only* for non-loop-breakers
 605         -- Making loop breakers not have an unfolding at all
 606         -- means that we can avoid tests in exprIsConApp, for example.
 607         -- This is important: if exprIsConApp says 'yes' for a recursive
 608         -- thing, then we can get into an infinite loop
 609
 610         --      Demand info
 611         -- If the unfolding is a value, the demand info may
 612         -- go pear-shaped, so we nuke it.  Example:
 613         --      let x = (a,b) in
 614         --      case x of (p,q) -> h p q x
 615         -- Here x is certainly demanded. But after we've nuked
 616         -- the case, we'll get just
 617         --      let x = (a,b) in h a b x
 618         -- and now x is not demanded (I'm assuming h is lazy)
 619         -- This really happens.  Similarly
 620         --      let f = \x -> e in ...f..f...
 621         -- After inling f at some of its call sites the original binding may
 622         -- (for example) be no longer strictly demanded.
 623         -- The solution here is a bit ad hoc...
 624         info_w_unf = new_bndr_info `setUnfoldingInfo` unfolding
 625         final_info | loop_breaker               = new_bndr_info
 626                    | isEvaldUnfolding unfolding = zapDemandInfo info_w_unf `orElse` info_w_unf
 627                    | otherwise                  = info_w_unf
 628
 629         final_id = new_bndr `setIdInfo` final_info
 630     in
 631                 -- These seqs forces the Id, and hence its IdInfo,
 632                 -- and hence any inner substitutions
 633     final_id                                    `seq`
 634     -- pprTrace "Binding" (ppr final_id <+> ppr unfolding) $
 635     returnSmpl (unitFloat env final_id new_rhs, env)
 636   where
 637     unfolding    = mkUnfolding (isTopLevel top_lvl) new_rhs
 638     loop_breaker = isNonRuleLoopBreaker occ_info
 639     old_info     = idInfo old_bndr
 640     occ_info     = occInfo old_info
 641 \end{code}
 642
 643
 644
 645 %************************************************************************
 646 %*                                                                      *
 647 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 648 %*                                                                      *
 649 %************************************************************************
 650
 651 The reason for this OutExprStuff stuff is that we want to float *after*
 652 simplifying a RHS, not before.  If we do so naively we get quadratic
 653 behaviour as things float out.
 654
 655 To see why it's important to do it after, consider this (real) example:
 656
 657         let t = f x
 658         in fst t
 659 ==>
 660         let t = let a = e1
 661                     b = e2
 662                 in (a,b)
 663         in fst t
 664 ==>
 665         let a = e1
 666             b = e2
 667             t = (a,b)
 668         in
 669         a       -- Can't inline a this round, cos it appears twice
 670 ==>
 671         e1
 672
 673 Each of the ==> steps is a round of simplification.  We'd save a
 674 whole round if we float first.  This can cascade.  Consider
 675
 676         let f = g d
 677         in \x -> ...f...
 678 ==>
 679         let f = let d1 = ..d.. in \y -> e
 680         in \x -> ...f...
 681 ==>
 682         let d1 = ..d..
 683         in \x -> ...(\y ->e)...
 684
 685 Only in this second round can the \y be applied, and it
 686 might do the same again.
 687
 688
 689 \begin{code}
 690 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 691 simplExpr env expr = simplExprC env expr (mkBoringStop expr_ty')
 692                    where
 693                      expr_ty' = substTy env (exprType expr)
 694         -- The type in the Stop continuation, expr_ty', is usually not used
 695         -- It's only needed when discarding continuations after finding
 696         -- a function that returns bottom.
 697         -- Hence the lazy substitution
 698
 699
 700 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 701         -- Simplify an expression, given a continuation
 702 simplExprC env expr cont
 703   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 704     returnSmpl (wrapFloats floats expr)
 705
 706 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 707         -- Simplify an expression, returning floated binds
 708
 709 simplExprF env (Var v)          cont = simplVar env v cont
 710 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 711 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 712 simplExprF env (Note note expr) cont = simplNote env note expr cont
 713 simplExprF env (Cast body co)   cont = simplCast env body co cont
 714 simplExprF env (App fun arg)    cont = simplExprF env fun
 715                                          (ApplyTo NoDup arg (Just env) cont)
 716
 717 simplExprF env (Type ty) cont
 718   = ASSERT( contIsRhsOrArg cont )
 719     simplType env ty                    `thenSmpl` \ ty' ->
 720     rebuild env (Type ty') cont
 721
 722 simplExprF env (Case scrut bndr case_ty alts) cont
 723   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 724   =     -- Simplify the scrutinee with a Select continuation
 725     simplExprF env scrut (Select NoDup bndr alts env cont)
 726
 727   | otherwise
 728   =     -- If case-of-case is off, simply simplify the case expression
 729         -- in a vanilla Stop context, and rebuild the result around it
 730     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 731     rebuild env case_expr' cont
 732   where
 733     case_cont = Select NoDup bndr alts env (mkBoringStop case_ty')
 734     case_ty'  = substTy env case_ty     -- c.f. defn of simplExpr
 735
 736 simplExprF env (Let (Rec pairs) body) cont
 737   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 738         -- NB: bndrs' don't have unfoldings or rules
 739         -- We add them as we go down
 740
 741     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 742     addFloats env floats                        $ \ env ->
 743     simplExprF env body cont
 744
 745 -- A non-recursive let is dealt with by simplNonRecBind
 746 simplExprF env (Let (NonRec bndr rhs) body) cont
 747   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 748     simplExprF env body cont
 749
 750
 751 ---------------------------------
 752 simplType :: SimplEnv -> InType -> SimplM OutType
 753         -- Kept monadic just so we can do the seqType
 754 simplType env ty
 755   = seqType new_ty   `seq`   returnSmpl new_ty
 756   where
 757     new_ty = substTy env ty
 758 \end{code}
 759
 760
 761 %************************************************************************
 762 %*                                                                      *
 763 \subsection{Lambdas}
 764 %*                                                                      *
 765 %************************************************************************
 766
 767 \begin{code}
 768 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont -> SimplM FloatsWithExpr
 769 simplCast env body co cont
 770   = let
 771        addCoerce co cont
 772          | (s1, k1) <- coercionKind co
 773          , s1 `tcEqType` k1 = cont
 774        addCoerce co1 (CoerceIt co2 cont)
 775          | (s1, k1) <- coercionKind co1
 776          , (l1, t1) <- coercionKind co2
 777                 --      coerce T1 S1 (coerce S1 K1 e)
 778                 -- ==>
 779                 --      e,                      if T1=K1
 780                 --      coerce T1 K1 e,         otherwise
 781                 --
 782                 -- For example, in the initial form of a worker
 783                 -- we may find  (coerce T (coerce S (\x.e))) y
 784                 -- and we'd like it to simplify to e[y/x] in one round
 785                 -- of simplification
 786          , s1 `coreEqType` t1  = cont            -- The coerces cancel out
 787          | otherwise           = CoerceIt (mkTransCoercion co1 co2) cont
 788
 789        addCoerce co (ApplyTo dup arg arg_se cont)
 790          | not (isTypeArg arg)    -- This whole case only works for value args
 791                                 -- Could upgrade to have equiv thing for type apps too
 792          , Just (s1s2, t1t2) <- splitCoercionKind_maybe co
 793          , isFunTy s1s2
 794                 -- co : s1s2 :=: t1t2
 795                 --      (coerce (T1->T2) (S1->S2) F) E
 796                 -- ===>
 797                 --      coerce T2 S2 (F (coerce S1 T1 E))
 798                 --
 799                 -- t1t2 must be a function type, T1->T2, because it's applied
 800                 -- to something but s1s2 might conceivably not be
 801                 --
 802                 -- When we build the ApplyTo we can't mix the out-types
 803                 -- with the InExpr in the argument, so we simply substitute
 804                 -- to make it all consistent.  It's a bit messy.
 805                 -- But it isn't a common case.
 806          = result
 807          where
 808            -- we split coercion t1->t2 :=: s1->s2 into t1 :=: s1 and
 809            -- t2 :=: s2 with left and right on the curried form:
 810            --    (->) t1 t2 :=: (->) s1 s2
 811            [co1, co2] = decomposeCo 2 co
 812            new_arg    = mkCoerce (mkSymCoercion co1) arg'
 813            arg'       = case arg_se of
 814                           Nothing     -> arg
 815                           Just arg_se -> substExpr (setInScope arg_se env) arg
 816            result     = ApplyTo dup new_arg (Just $ zapSubstEnv env)
 817                                 (addCoerce co2 cont)
 818        addCoerce co cont = CoerceIt co cont
 819     in
 820     simplType env co            `thenSmpl` \ co' ->
 821     simplExprF env body (addCoerce co' cont)
 822 \end{code}
 823
 824 %************************************************************************
 825 %*                                                                      *
 826 \subsection{Lambdas}
 827 %*                                                                      *
 828 %************************************************************************
 829
 830 \begin{code}
 831 simplLam env fun cont
 832   = go env fun cont
 833   where
 834     zap_it  = mkLamBndrZapper fun (countArgs cont)
 835     cont_ty = contResultType cont
 836
 837         -- Type-beta reduction
 838     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) mb_arg_se body_cont)
 839       = ASSERT( isTyVar bndr )
 840         do { tick (BetaReduction bndr)
 841            ; ty_arg' <- case mb_arg_se of
 842                           Just arg_se -> simplType (setInScope arg_se env) ty_arg
 843                           Nothing     -> return ty_arg
 844            ; go (extendTvSubst env bndr ty_arg') body body_cont }
 845
 846         -- Ordinary beta reduction
 847     go env (Lam bndr body) cont@(ApplyTo _ arg (Just arg_se) body_cont)
 848       = do { tick (BetaReduction bndr)
 849            ; simplNonRecBind env (zap_it bndr) arg arg_se cont_ty       $ \ env ->
 850              go env body body_cont }
 851
 852     go env (Lam bndr body) cont@(ApplyTo _ arg Nothing body_cont)
 853       = do { tick (BetaReduction bndr)
 854            ; simplNonRecX env (zap_it bndr) arg         $ \ env ->
 855              go env body body_cont }
 856
 857         -- Not enough args, so there are real lambdas left to put in the result
 858     go env lam@(Lam _ _) cont
 859       = do { (env, bndrs') <- simplLamBndrs env bndrs
 860            ; body' <- simplExpr env body
 861            ; (floats, new_lam) <- mkLam env bndrs' body' cont
 862            ; addFloats env floats               $ \ env ->
 863              rebuild env new_lam cont }
 864       where
 865         (bndrs,body) = collectBinders lam
 866
 867         -- Exactly enough args
 868     go env expr cont = simplExprF env expr cont
 869
 870 mkLamBndrZapper :: CoreExpr     -- Function
 871                 -> Int          -- Number of args supplied, *including* type args
 872                 -> Id -> Id     -- Use this to zap the binders
 873 mkLamBndrZapper fun n_args
 874   | n_args >= n_params fun = \b -> b            -- Enough args
 875   | otherwise              = \b -> zapLamIdInfo b
 876   where
 877         -- NB: we count all the args incl type args
 878         -- so we must count all the binders (incl type lambdas)
 879     n_params (Note _ e) = n_params e
 880     n_params (Lam b e)  = 1 + n_params e
 881     n_params other      = 0::Int
 882 \end{code}
 883
 884
 885 %************************************************************************
 886 %*                                                                      *
 887 \subsection{Notes}
 888 %*                                                                      *
 889 %************************************************************************
 890
 891 \begin{code}
 892
 893
 894 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 895 -- inlining.  All other CCCSs are mapped to currentCCS.
 896 simplNote env (SCC cc) e cont
 897   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 898     rebuild env (mkSCC cc e') cont
 899
 900 -- See notes with SimplMonad.inlineMode
 901 simplNote env InlineMe e cont
 902   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 903   =                             -- Don't inline inside an INLINE expression
 904     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 905     rebuild env (mkInlineMe e') cont
 906
 907   | otherwise   -- Dissolve the InlineMe note if there's
 908                 -- an interesting context of any kind to combine with
 909                 -- (even a type application -- anything except Stop)
 910   = simplExprF env e cont
 911
 912 simplNote env (CoreNote s) e cont
 913   = simplExpr env e    `thenSmpl` \ e' ->
 914     rebuild env (Note (CoreNote s) e') cont
 915 \end{code}
 916
 917
 918 %************************************************************************
 919 %*                                                                      *
 920 \subsection{Dealing with calls}
 921 %*                                                                      *
 922 %************************************************************************
 923
 924 \begin{code}
 925 simplVar env var cont
 926   = case substId env var of
 927         DoneEx e         -> simplExprF (zapSubstEnv env) e cont
 928         ContEx tvs ids e -> simplExprF (setSubstEnv env tvs ids) e cont
 929         DoneId var1      -> completeCall (zapSubstEnv env) var1 cont
 930                 -- Note [zapSubstEnv]
 931                 -- The template is already simplified, so don't re-substitute.
 932                 -- This is VITAL.  Consider
 933                 --      let x = e in
 934                 --      let y = \z -> ...x... in
 935                 --      \ x -> ...y...
 936                 -- We'll clone the inner \x, adding x->x' in the id_subst
 937                 -- Then when we inline y, we must *not* replace x by x' in
 938                 -- the inlined copy!!
 939
 940 ---------------------------------------------------------
 941 --      Dealing with a call site
 942
 943 completeCall env var cont
 944   =     -- Simplify the arguments
 945     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 946     let
 947         chkr              = getSwitchChecker env
 948         (args, call_cont) = getContArgs chkr var cont
 949         fn_ty             = idType var
 950     in
 951     simplifyArgs env fn_ty (interestingArgContext var call_cont) args
 952                  (contResultType call_cont)     $ \ env args ->
 953
 954         -- Next, look for rules or specialisations that match
 955         --
 956         -- It's important to simplify the args first, because the rule-matcher
 957         -- doesn't do substitution as it goes.  We don't want to use subst_args
 958         -- (defined in the 'where') because that throws away useful occurrence info,
 959         -- and perhaps-very-important specialisations.
 960         --
 961         -- Some functions have specialisations *and* are strict; in this case,
 962         -- we don't want to inline the wrapper of the non-specialised thing; better
 963         -- to call the specialised thing instead.
 964         -- We used to use the black-listing mechanism to ensure that inlining of
 965         -- the wrapper didn't occur for things that have specialisations till a
 966         -- later phase, so but now we just try RULES first
 967         --
 968         -- You might think that we shouldn't apply rules for a loop breaker:
 969         -- doing so might give rise to an infinite loop, because a RULE is
 970         -- rather like an extra equation for the function:
 971         --      RULE:           f (g x) y = x+y
 972         --      Eqn:            f a     y = a-y
 973         --
 974         -- But it's too drastic to disable rules for loop breakers.
 975         -- Even the foldr/build rule would be disabled, because foldr
 976         -- is recursive, and hence a loop breaker:
 977         --      foldr k z (build g) = g k z
 978         -- So it's up to the programmer: rules can cause divergence
 979
 980     let
 981         in_scope   = getInScope env
 982         rules      = getRules env
 983         maybe_rule = case activeRule env of
 984                         Nothing     -> Nothing  -- No rules apply
 985                         Just act_fn -> lookupRule act_fn in_scope rules var args
 986     in
 987     case maybe_rule of {
 988         Just (rule_name, rule_rhs) ->
 989                 tick (RuleFired rule_name)                      `thenSmpl_`
 990                 (if dopt Opt_D_dump_inlinings dflags then
 991                    pprTrace "Rule fired" (vcat [
 992                         text "Rule:" <+> ftext rule_name,
 993                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 994                         text "After: " <+> pprCoreExpr rule_rhs,
 995                         text "Cont:  " <+> ppr call_cont])
 996                  else
 997                         id)             $
 998                 simplExprF env rule_rhs call_cont ;
 999
1000         Nothing ->              -- No rules
1001
1002         -- Next, look for an inlining
1003     let
1004         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
1005         interesting_cont = interestingCallContext (notNull args)
1006                                                   (notNull arg_infos)
1007                                                   call_cont
1008         active_inline = activeInline env var
1009         maybe_inline  = callSiteInline dflags active_inline
1010                                        var arg_infos interesting_cont
1011     in
1012     case maybe_inline of {
1013         Just unfolding          -- There is an inlining!
1014           ->  tick (UnfoldingDone var)          `thenSmpl_`
1015                 (if dopt Opt_D_dump_inlinings dflags then
1016                    pprTrace "Inlining done" (vcat [
1017                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
1018                         text "Inlined fn: " <+> ppr unfolding,
1019                         text "Cont:  " <+> ppr call_cont])
1020                  else
1021                         id)             $
1022               simplExprF env unfolding (pushContArgs args call_cont)
1023
1024         ;
1025         Nothing ->              -- No inlining!
1026
1027         -- Done
1028     rebuild env (mkApps (Var var) args) call_cont
1029     }}
1030 \end{code}
1031
1032 %************************************************************************
1033 %*                                                                      *
1034 \subsection{Arguments}
1035 %*                                                                      *
1036 %************************************************************************
1037
1038 \begin{code}
1039 ---------------------------------------------------------
1040 --      Simplifying the arguments of a call
1041
1042 simplifyArgs :: SimplEnv
1043              -> OutType                         -- Type of the function
1044              -> Bool                            -- True if the fn has RULES
1045              -> [(InExpr, Maybe SimplEnv, Bool)] -- Details of the arguments
1046              -> OutType                         -- Type of the continuation
1047              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1048              -> SimplM FloatsWithExpr
1049
1050 -- [CPS-like because of strict arguments]
1051
1052 -- Simplify the arguments to a call.
1053 -- This part of the simplifier may break the no-shadowing invariant
1054 -- Consider
1055 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1056 -- where f is strict in its second arg
1057 -- If we simplify the innermost one first we get (...(\a -> e)...)
1058 -- Simplifying the second arg makes us float the case out, so we end up with
1059 --      case y of (a,b) -> f (...(\a -> e)...) e'
1060 -- So the output does not have the no-shadowing invariant.  However, there is
1061 -- no danger of getting name-capture, because when the first arg was simplified
1062 -- we used an in-scope set that at least mentioned all the variables free in its
1063 -- static environment, and that is enough.
1064 --
1065 -- We can't just do innermost first, or we'd end up with a dual problem:
1066 --      case x of (a,b) -> f e (...(\a -> e')...)
1067 --
1068 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1069 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1070 -- continuations.  We have to keep the right in-scope set around; AND we have
1071 -- to get the effect that finding (error "foo") in a strict arg position will
1072 -- discard the entire application and replace it with (error "foo").  Getting
1073 -- all this at once is TOO HARD!
1074
1075 simplifyArgs env fn_ty has_rules args cont_ty thing_inside
1076   = go env fn_ty args thing_inside
1077   where
1078     go env fn_ty []         thing_inside = thing_inside env []
1079     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty has_rules arg cont_ty  $ \ env arg' ->
1080                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1081                                            thing_inside env (arg':args')
1082
1083 simplifyArg env fn_ty has_rules (arg, Nothing, _) cont_ty thing_inside
1084   = thing_inside env arg        -- Already simplified
1085
1086 simplifyArg env fn_ty has_rules (Type ty_arg, Just se, _) cont_ty thing_inside
1087   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1088     thing_inside env (Type new_ty_arg)
1089
1090 simplifyArg env fn_ty has_rules (val_arg, Just arg_se, is_strict) cont_ty thing_inside
1091   | is_strict
1092   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1093
1094   | otherwise   -- Lazy argument
1095                 -- DO NOT float anything outside, hence simplExprC
1096                 -- There is no benefit (unlike in a let-binding), and we'd
1097                 -- have to be very careful about bogus strictness through
1098                 -- floating a demanded let.
1099   = simplExprC (setInScope arg_se env) val_arg
1100                (mkLazyArgStop arg_ty has_rules)         `thenSmpl` \ arg1 ->
1101     thing_inside env arg1
1102   where
1103     arg_ty = funArgTy fn_ty
1104
1105
1106 simplStrictArg ::  LetRhsFlag
1107                 -> SimplEnv             -- The env of the call
1108                 -> InExpr -> SimplEnv   -- The arg plus its env
1109                 -> OutType              -- arg_ty: type of the argument
1110                 -> OutType              -- cont_ty: Type of thing computed by the context
1111                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1112                                         -- Takes an expression of type rhs_ty,
1113                                         -- returns an expression of type cont_ty
1114                                         -- The env passed to this continuation is the
1115                                         -- env of the call, plus any new in-scope variables
1116                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1117
1118 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1119   = simplExprF (setInScope arg_env call_env) arg
1120                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1121   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1122   --    to simplify the argument
1123   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1124 \end{code}
1125
1126
1127 %************************************************************************
1128 %*                                                                      *
1129 \subsection{mkAtomicArgs}
1130 %*                                                                      *
1131 %************************************************************************
1132
1133 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1134 constructor application and, if so, converts it to ANF, so that the
1135 resulting thing can be inlined more easily.  Thus
1136         x = (f a, g b)
1137 becomes
1138         t1 = f a
1139         t2 = g b
1140         x = (t1,t2)
1141
1142 There are three sorts of binding context, specified by the two
1143 boolean arguments
1144
1145 Strict
1146    OK-unlifted
1147
1148 N  N    Top-level or recursive                  Only bind args of lifted type
1149
1150 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1151                 but lazy                        unlifted-and-ok-for-speculation
1152
1153 Y  Y    Non-top-level, non-recursive,           Bind all args
1154                  and strict (demanded)
1155
1156
1157 For example, given
1158
1159         x = MkC (y div# z)
1160
1161 there is no point in transforming to
1162
1163         x = case (y div# z) of r -> MkC r
1164
1165 because the (y div# z) can't float out of the let. But if it was
1166 a *strict* let, then it would be a good thing to do.  Hence the
1167 context information.
1168
1169 \begin{code}
1170 mkAtomicArgsE :: SimplEnv
1171               -> Bool   -- A strict binding
1172               -> OutExpr                                                -- The rhs
1173               -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1174               -> SimplM FloatsWithExpr
1175
1176 mkAtomicArgsE env is_strict rhs thing_inside
1177   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1178     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1179   = go env (Var fun) args
1180
1181   | otherwise = thing_inside env rhs
1182
1183   where
1184     go env fun [] = thing_inside env fun
1185
1186     go env fun (arg : args)
1187         |  exprIsTrivial arg    -- Easy case
1188         || no_float_arg         -- Can't make it atomic
1189         = go env (App fun arg) args
1190
1191         | otherwise
1192         = do { arg_id <- newId FSLIT("a") arg_ty
1193              ; completeNonRecX env False {- pessimistic -} arg_id arg_id arg $ \env ->
1194                go env (App fun (Var arg_id)) args }
1195         where
1196           arg_ty = exprType arg
1197           no_float_arg = not is_strict && (isUnLiftedType arg_ty) && not (exprOkForSpeculation arg)
1198
1199
1200 -- Old code: consider rewriting to be more like mkAtomicArgsE
1201
1202 mkAtomicArgs :: Bool    -- A strict binding
1203              -> Bool    -- OK to float unlifted args
1204              -> OutExpr
1205              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1206                         OutExpr)                  -- things that need case-binding,
1207                                                   -- if the strict-binding flag is on
1208
1209 mkAtomicArgs is_strict ok_float_unlifted rhs
1210   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1211     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1212   = go fun nilOL [] args        -- Have a go
1213
1214   | otherwise = bale_out        -- Give up
1215
1216   where
1217     bale_out = returnSmpl (nilOL, rhs)
1218
1219     go fun binds rev_args []
1220         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1221
1222     go fun binds rev_args (arg : args)
1223         | exprIsTrivial arg     -- Easy case
1224         = go fun binds (arg:rev_args) args
1225
1226         | not can_float_arg     -- Can't make this arg atomic
1227         = bale_out              -- ... so give up
1228
1229         | otherwise     -- Don't forget to do it recursively
1230                         -- E.g.  x = a:b:c:[]
1231         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1232            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1233            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1234               (Var arg_id : rev_args) args
1235         where
1236           arg_ty        = exprType arg
1237           can_float_arg =  is_strict
1238                         || not (isUnLiftedType arg_ty)
1239                         || (ok_float_unlifted && exprOkForSpeculation arg)
1240
1241
1242 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1243                -> (SimplEnv -> SimplM (FloatsWith a))
1244                -> SimplM (FloatsWith a)
1245 addAtomicBinds env []         thing_inside = thing_inside env
1246 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1247                                              addAtomicBinds env bs thing_inside
1248 \end{code}
1249
1250
1251 %************************************************************************
1252 %*                                                                      *
1253 \subsection{The main rebuilder}
1254 %*                                                                      *
1255 %************************************************************************
1256
1257 \begin{code}
1258 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1259
1260 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1261 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1262 rebuild env expr (CoerceIt co cont)           = rebuild env (mkCoerce co expr) cont
1263 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1264 rebuild env expr (ApplyTo _ arg mb_se cont)   = rebuildApp  env expr arg mb_se cont
1265
1266 rebuildApp env fun arg mb_se cont
1267   = do  { arg' <- simplArg env arg mb_se
1268         ; rebuild env (App fun arg') cont }
1269
1270 simplArg :: SimplEnv -> CoreExpr -> Maybe SimplEnv -> SimplM CoreExpr
1271 simplArg env arg Nothing        = return arg    -- The arg is already simplified
1272 simplArg env arg (Just arg_env) = simplExpr (setInScope arg_env env) arg
1273
1274 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1275 \end{code}
1276
1277
1278 %************************************************************************
1279 %*                                                                      *
1280 \subsection{Functions dealing with a case}
1281 %*                                                                      *
1282 %************************************************************************
1283
1284 Blob of helper functions for the "case-of-something-else" situation.
1285
1286 \begin{code}
1287 ---------------------------------------------------------
1288 --      Eliminate the case if possible
1289
1290 rebuildCase :: SimplEnv
1291             -> OutExpr          -- Scrutinee
1292             -> InId             -- Case binder
1293             -> [InAlt]          -- Alternatives (inceasing order)
1294             -> SimplCont
1295             -> SimplM FloatsWithExpr
1296
1297 rebuildCase env scrut case_bndr alts cont
1298   | Just (con,args) <- exprIsConApp_maybe scrut
1299         -- Works when the scrutinee is a variable with a known unfolding
1300         -- as well as when it's an explicit constructor application
1301   = knownCon env scrut (DataAlt con) args case_bndr alts cont
1302
1303   | Lit lit <- scrut    -- No need for same treatment as constructors
1304                         -- because literals are inlined more vigorously
1305   = knownCon env scrut (LitAlt lit) [] case_bndr alts cont
1306
1307   | otherwise
1308   =     -- Prepare the continuation;
1309         -- The new subst_env is in place
1310     prepareCaseCont env alts cont       `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1311     addFloats env floats                $ \ env ->
1312
1313     let
1314         -- The case expression is annotated with the result type of the continuation
1315         -- This may differ from the type originally on the case.  For example
1316         --      case(T) (case(Int#) a of { True -> 1#; False -> 0# }) of
1317         --         a# -> <blob>
1318         -- ===>
1319         --      let j a# = <blob>
1320         --      in case(T) a of { True -> j 1#; False -> j 0# }
1321         -- Note that the case that scrutinises a now returns a T not an Int#
1322         res_ty' = contResultType dup_cont
1323     in
1324
1325         -- Deal with case binder
1326     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr') ->
1327
1328         -- Deal with the case alternatives
1329     simplAlts alt_env scrut case_bndr' alts dup_cont    `thenSmpl` \ alts' ->
1330
1331         -- Put the case back together
1332     mkCase scrut case_bndr' res_ty' alts'       `thenSmpl` \ case_expr ->
1333
1334         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1335         -- The case binder *not* scope over the whole returned case-expression
1336     rebuild env case_expr nondup_cont
1337 \end{code}
1338
1339 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1340 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1341 way, there's a chance that v will now only be used once, and hence
1342 inlined.
1343
1344 Note [no-case-of-case]
1345 ~~~~~~~~~~~~~~~~~~~~~~
1346 There is a time we *don't* want to do that, namely when
1347 -fno-case-of-case is on.  This happens in the first simplifier pass,
1348 and enhances full laziness.  Here's the bad case:
1349         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1350 If we eliminate the inner case, we trap it inside the I# v -> arm,
1351 which might prevent some full laziness happening.  I've seen this
1352 in action in spectral/cichelli/Prog.hs:
1353          [(m,n) | m <- [1..max], n <- [1..max]]
1354 Hence the check for NoCaseOfCase.
1355
1356 Note [Case of cast]
1357 ~~~~~~~~~~~~~~~~~~~
1358 Consider        case (v `cast` co) of x { I# ->
1359                 ... (case (v `cast` co) of {...}) ...
1360 We'd like to eliminate the inner case.  We can get this neatly by
1361 arranging that inside the outer case we add the unfolding
1362         v |-> x `cast` (sym co)
1363 to v.  Then we should inline v at the inner case, cancel the casts, and away we go
1364
1365 Note 2
1366 ~~~~~~
1367 There is another situation when we don't want to do it.  If we have
1368
1369     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1370                    ...other cases .... }
1371
1372 We'll perform the binder-swap for the outer case, giving
1373
1374     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1375                    ...other cases .... }
1376
1377 But there is no point in doing it for the inner case, because w1 can't
1378 be inlined anyway.  Furthermore, doing the case-swapping involves
1379 zapping w2's occurrence info (see paragraphs that follow), and that
1380 forces us to bind w2 when doing case merging.  So we get
1381
1382     case x of w1 { A -> let w2 = w1 in e1
1383                    B -> let w2 = w1 in e2
1384                    ...other cases .... }
1385
1386 This is plain silly in the common case where w2 is dead.
1387
1388 Even so, I can't see a good way to implement this idea.  I tried
1389 not doing the binder-swap if the scrutinee was already evaluated
1390 but that failed big-time:
1391
1392         data T = MkT !Int
1393
1394         case v of w  { MkT x ->
1395         case x of x1 { I# y1 ->
1396         case x of x2 { I# y2 -> ...
1397
1398 Notice that because MkT is strict, x is marked "evaluated".  But to
1399 eliminate the last case, we must either make sure that x (as well as
1400 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1401 the binder-swap.  So this whole note is a no-op.
1402
1403 Note [zapOccInfo]
1404 ~~~~~~~~~~~~~~~~~
1405 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1406 any occurrence info (eg IAmDead) in the case binder, because the
1407 case-binder now effectively occurs whenever v does.  AND we have to do
1408 the same for the pattern-bound variables!  Example:
1409
1410         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1411
1412 Here, b and p are dead.  But when we move the argment inside the first
1413 case RHS, and eliminate the second case, we get
1414
1415         case x of { (a,b) -> a b }
1416
1417 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1418 happened.
1419
1420 Indeed, this can happen anytime the case binder isn't dead:
1421         case <any> of x { (a,b) ->
1422         case x of { (p,q) -> p } }
1423 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1424 The point is that we bring into the envt a binding
1425         let x = (a,b)
1426 after the outer case, and that makes (a,b) alive.  At least we do unless
1427 the case binder is guaranteed dead.
1428
1429 \begin{code}
1430 simplCaseBinder env scrut case_bndr
1431   | switchIsOn (getSwitchChecker env) NoCaseOfCase
1432         -- See Note [no-case-of-case]
1433   = do  { (env, case_bndr') <- simplBinder env case_bndr
1434         ; return (env, case_bndr') }
1435
1436 simplCaseBinder env (Var v) case_bndr
1437 -- Failed try [see Note 2 above]
1438 --     not (isEvaldUnfolding (idUnfolding v))
1439   = do  { (env, case_bndr') <- simplBinder env (zapOccInfo case_bndr)
1440         ; return (modifyInScope env v case_bndr', case_bndr') }
1441         -- We could extend the substitution instead, but it would be
1442         -- a hack because then the substitution wouldn't be idempotent
1443         -- any more (v is an OutId).  And this does just as well.
1444
1445 simplCaseBinder env (Cast (Var v) co) case_bndr         -- Note [Case of cast]
1446   = do  { (env, case_bndr') <- simplBinder env (zapOccInfo case_bndr)
1447         ; let rhs = Cast (Var case_bndr') (mkSymCoercion co)
1448         ; return (addBinderUnfolding env v rhs, case_bndr') }
1449
1450 simplCaseBinder env other_scrut case_bndr
1451   = do  { (env, case_bndr') <- simplBinder env case_bndr
1452         ; return (env, case_bndr') }
1453
1454 zapOccInfo :: InId -> InId      -- See Note [zapOccInfo]
1455 zapOccInfo b = b `setIdOccInfo` NoOccInfo
1456 \end{code}
1457
1458
1459 simplAlts does two things:
1460
1461 1.  Eliminate alternatives that cannot match, including the
1462     DEFAULT alternative.
1463
1464 2.  If the DEFAULT alternative can match only one possible constructor,
1465     then make that constructor explicit.
1466     e.g.
1467         case e of x { DEFAULT -> rhs }
1468      ===>
1469         case e of x { (a,b) -> rhs }
1470     where the type is a single constructor type.  This gives better code
1471     when rhs also scrutinises x or e.
1472
1473 Here "cannot match" includes knowledge from GADTs
1474
1475 It's a good idea do do this stuff before simplifying the alternatives, to
1476 avoid simplifying alternatives we know can't happen, and to come up with
1477 the list of constructors that are handled, to put into the IdInfo of the
1478 case binder, for use when simplifying the alternatives.
1479
1480 Eliminating the default alternative in (1) isn't so obvious, but it can
1481 happen:
1482
1483 data Colour = Red | Green | Blue
1484
1485 f x = case x of
1486         Red -> ..
1487         Green -> ..
1488         DEFAULT -> h x
1489
1490 h y = case y of
1491         Blue -> ..
1492         DEFAULT -> [ case y of ... ]
1493
1494 If we inline h into f, the default case of the inlined h can't happen.
1495 If we don't notice this, we may end up filtering out *all* the cases
1496 of the inner case y, which give us nowhere to go!
1497
1498
1499 \begin{code}
1500 simplAlts :: SimplEnv
1501           -> OutExpr
1502           -> OutId                      -- Case binder
1503           -> [InAlt] -> SimplCont
1504           -> SimplM [OutAlt]            -- Includes the continuation
1505
1506 simplAlts env scrut case_bndr' alts cont'
1507   = do  { mb_alts      <- mapSmpl (simplAlt env imposs_cons case_bndr' cont') alts_wo_default
1508         ; default_alts <- simplDefault env case_bndr' imposs_deflt_cons cont' maybe_deflt
1509         ; return (mergeAlts default_alts [alt' | Just (_, alt') <- mb_alts]) }
1510         -- We need the mergeAlts in case the new default_alt
1511         -- has turned into a constructor alternative.
1512   where
1513     (alts_wo_default, maybe_deflt) = findDefault alts
1514     imposs_cons = case scrut of
1515                     Var v -> otherCons (idUnfolding v)
1516                     other -> []
1517
1518         -- "imposs_deflt_cons" are handled either by the context,
1519         -- OR by a branch in this case expression. (Don't include DEFAULT!!)
1520     imposs_deflt_cons = nub (imposs_cons ++ [con | (con,_,_) <- alts_wo_default])
1521
1522 simplDefault :: SimplEnv
1523              -> OutId           -- Case binder; need just for its type. Note that as an
1524                                 --   OutId, it has maximum information; this is important.
1525                                 --   Test simpl013 is an example
1526              -> [AltCon]        -- These cons can't happen when matching the default
1527              -> SimplCont
1528              -> Maybe InExpr
1529              -> SimplM [OutAlt] -- One branch or none; we use a list because it's what
1530                                 --   mergeAlts expects
1531
1532
1533 simplDefault env case_bndr' imposs_cons cont Nothing
1534   = return []   -- No default branch
1535
1536 simplDefault env case_bndr' imposs_cons cont (Just rhs)
1537   |     -- This branch handles the case where we are
1538         -- scrutinisng an algebraic data type
1539     Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr'),
1540     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1541     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1542                                 --      case x of { DEFAULT -> e }
1543                                 -- and we don't want to fill in a default for them!
1544     Just all_cons <- tyConDataCons_maybe tycon,
1545     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1546                                 -- which GHC allows, then the case expression will have at most a default
1547                                 -- alternative.  We don't want to eliminate that alternative, because the
1548                                 -- invariant is that there's always one alternative.  It's more convenient
1549                                 -- to leave
1550                                 --      case x of { DEFAULT -> e }
1551                                 -- as it is, rather than transform it to
1552                                 --      error "case cant match"
1553                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1554                                 -- not worth wasting code on.
1555
1556     let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1557         poss_data_cons   = filterOut (`elem` imposs_data_cons) all_cons
1558         gadt_imposs      | all isTyVarTy inst_tys = []
1559                          | otherwise = filter (cant_match inst_tys) poss_data_cons
1560         final_poss       = filterOut (`elem` gadt_imposs) poss_data_cons
1561
1562   = case final_poss of
1563         []    -> returnSmpl []  -- Eliminate the default alternative
1564                                 -- altogether if it can't match
1565
1566         [con] ->        -- It matches exactly one constructor, so fill it in
1567                  do { tick (FillInCaseDefault case_bndr')
1568                     ; us <- getUniquesSmpl
1569                     ; let (ex_tvs, co_tvs, arg_ids) =
1570                               dataConRepInstPat us con inst_tys
1571                     ; let con_alt = (DataAlt con, ex_tvs ++ co_tvs ++ arg_ids, rhs)
1572                     ; Just (_, alt') <- simplAlt env [] case_bndr' cont con_alt
1573                         -- The simplAlt must succeed with Just because we have
1574                         -- already filtered out construtors that can't match
1575                     ; return [alt'] }
1576
1577         two_or_more -> simplify_default (map DataAlt gadt_imposs ++ imposs_cons)
1578
1579   | otherwise
1580   = simplify_default imposs_cons
1581   where
1582     cant_match tys data_con = not (dataConCanMatch data_con tys)
1583
1584     simplify_default imposs_cons
1585         = do { let env' = addBinderOtherCon env case_bndr' imposs_cons
1586                 -- Record the constructors that the case-binder *can't* be.
1587              ; rhs' <- simplExprC env' rhs cont
1588              ; return [(DEFAULT, [], rhs')] }
1589
1590 simplAlt :: SimplEnv
1591          -> [AltCon]    -- These constructors can't be present when
1592                         -- matching this alternative
1593          -> OutId       -- The case binder
1594          -> SimplCont
1595          -> InAlt
1596          -> SimplM (Maybe (TvSubstEnv, OutAlt))
1597
1598 -- Simplify an alternative, returning the type refinement for the
1599 -- alternative, if the alternative does any refinement at all
1600 -- Nothing => the alternative is inaccessible
1601
1602 simplAlt env imposs_cons case_bndr' cont' (con, bndrs, rhs)
1603   | con `elem` imposs_cons      -- This case can't match
1604   = return Nothing
1605
1606 simplAlt env handled_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1607         -- TURGID DUPLICATION, needed only for the simplAlt call
1608         -- in mkDupableAlt.  Clean this up when moving to FC
1609   = ASSERT( null bndrs )
1610     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1611     returnSmpl (Just (emptyVarEnv, (DEFAULT, [], rhs')))
1612   where
1613     env' = addBinderOtherCon env case_bndr' handled_cons
1614         -- Record the constructors that the case-binder *can't* be.
1615
1616 simplAlt env handled_cons case_bndr' cont' (LitAlt lit, bndrs, rhs)
1617   = ASSERT( null bndrs )
1618     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1619     returnSmpl (Just (emptyVarEnv, (LitAlt lit, [], rhs')))
1620   where
1621     env' = addBinderUnfolding env case_bndr' (Lit lit)
1622
1623 simplAlt env handled_cons case_bndr' cont' (DataAlt con, vs, rhs)
1624   =     -- Deal with the pattern-bound variables
1625         -- Mark the ones that are in ! positions in the data constructor
1626         -- as certainly-evaluated.
1627         -- NB: it happens that simplBinders does *not* erase the OtherCon
1628         --     form of unfolding, so it's ok to add this info before
1629         --     doing simplBinders
1630     simplBinders env (add_evals con vs)         `thenSmpl` \ (env, vs') ->
1631
1632                 -- Bind the case-binder to (con args)
1633     let inst_tys' = tyConAppArgs (idType case_bndr')
1634         con_args  = map Type inst_tys' ++ varsToCoreExprs vs'
1635         env'      = addBinderUnfolding env case_bndr' (mkConApp con con_args)
1636     in
1637     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1638     returnSmpl (Just (emptyVarEnv, (DataAlt con, vs', rhs')))
1639   where
1640         -- add_evals records the evaluated-ness of the bound variables of
1641         -- a case pattern.  This is *important*.  Consider
1642         --      data T = T !Int !Int
1643         --
1644         --      case x of { T a b -> T (a+1) b }
1645         --
1646         -- We really must record that b is already evaluated so that we don't
1647         -- go and re-evaluate it when constructing the result.
1648     add_evals dc vs = cat_evals dc vs (dataConRepStrictness dc)
1649
1650     cat_evals dc vs strs
1651         = go vs strs
1652         where
1653           go [] [] = []
1654           go (v:vs) strs | isTyVar v = v : go vs strs
1655           go (v:vs) (str:strs)
1656             | isMarkedStrict str = evald_v  : go vs strs
1657             | otherwise          = zapped_v : go vs strs
1658             where
1659               zapped_v = zap_occ_info v
1660               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
1661           go _ _ = pprPanic "cat_evals" (ppr dc $$ ppr vs $$ ppr strs)
1662
1663         -- If the case binder is alive, then we add the unfolding
1664         --      case_bndr = C vs
1665         -- to the envt; so vs are now very much alive
1666         -- Note [Aug06] I can't see why this actually matters
1667     zap_occ_info | isDeadBinder case_bndr' = \id -> id
1668                  | otherwise               = zapOccInfo
1669
1670 addBinderUnfolding :: SimplEnv -> Id -> CoreExpr -> SimplEnv
1671 addBinderUnfolding env bndr rhs
1672   = modifyInScope env bndr (bndr `setIdUnfolding` mkUnfolding False rhs)
1673
1674 addBinderOtherCon :: SimplEnv -> Id -> [AltCon] -> SimplEnv
1675 addBinderOtherCon env bndr cons
1676   = modifyInScope env bndr (bndr `setIdUnfolding` mkOtherCon cons)
1677 \end{code}
1678
1679
1680 %************************************************************************
1681 %*                                                                      *
1682 \subsection{Known constructor}
1683 %*                                                                      *
1684 %************************************************************************
1685
1686 We are a bit careful with occurrence info.  Here's an example
1687
1688         (\x* -> case x of (a*, b) -> f a) (h v, e)
1689
1690 where the * means "occurs once".  This effectively becomes
1691         case (h v, e) of (a*, b) -> f a)
1692 and then
1693         let a* = h v; b = e in f a
1694 and then
1695         f (h v)
1696
1697 All this should happen in one sweep.
1698
1699 \begin{code}
1700 knownCon :: SimplEnv -> OutExpr -> AltCon -> [OutExpr]
1701          -> InId -> [InAlt] -> SimplCont
1702          -> SimplM FloatsWithExpr
1703
1704 knownCon env scrut con args bndr alts cont
1705   = tick (KnownBranch bndr)             `thenSmpl_`
1706     case findAlt con alts of
1707         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1708                                   simplNonRecX env bndr scrut   $ \ env ->
1709                                 -- This might give rise to a binding with non-atomic args
1710                                 -- like x = Node (f x) (g x)
1711                                 -- but simplNonRecX will atomic-ify it
1712                                   simplExprF env rhs cont
1713
1714         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1715                                   simplNonRecX env bndr scrut   $ \ env ->
1716                                   simplExprF env rhs cont
1717
1718         (DataAlt dc, bs, rhs)
1719                 -> -- ASSERT( n_drop_tys + length bs == length args )
1720                    bind_args env dead_bndr bs (drop n_drop_tys args)    $ \ env ->
1721                    let
1722                         -- It's useful to bind bndr to scrut, rather than to a fresh
1723                         -- binding      x = Con arg1 .. argn
1724                         -- because very often the scrut is a variable, so we avoid
1725                         -- creating, and then subsequently eliminating, a let-binding
1726                         -- BUT, if scrut is a not a variable, we must be careful
1727                         -- about duplicating the arg redexes; in that case, make
1728                         -- a new con-app from the args
1729                         bndr_rhs  = case scrut of
1730                                         Var v -> scrut
1731                                         other -> con_app
1732                         con_app = mkConApp dc (take n_drop_tys args ++ con_args)
1733                         con_args = [substExpr env (varToCoreExpr b) | b <- bs]
1734                                         -- args are aready OutExprs, but bs are InIds
1735                    in
1736                    simplNonRecX env bndr bndr_rhs               $ \ env ->
1737                    simplExprF env rhs cont
1738                 where
1739                    dead_bndr  = isDeadBinder bndr
1740                    n_drop_tys = tyConArity (dataConTyCon dc)
1741
1742 -- Ugh!
1743 bind_args env dead_bndr [] _ thing_inside = thing_inside env
1744
1745 bind_args env dead_bndr (b:bs) (Type ty : args) thing_inside
1746   = ASSERT( isTyVar b )
1747     bind_args (extendTvSubst env b ty) dead_bndr bs args thing_inside
1748
1749 bind_args env dead_bndr (b:bs) (arg : args) thing_inside
1750   = ASSERT( isId b )
1751     let
1752         b' = if dead_bndr then b else zapOccInfo b
1753                 -- Note that the binder might be "dead", because it doesn't occur
1754                 -- in the RHS; and simplNonRecX may therefore discard it via postInlineUnconditionally
1755                 -- Nevertheless we must keep it if the case-binder is alive, because it may
1756                 -- be used in the con_app.  See Note [zapOccInfo]
1757     in
1758     simplNonRecX env b' arg     $ \ env ->
1759     bind_args env dead_bndr bs args thing_inside
1760 \end{code}
1761
1762
1763 %************************************************************************
1764 %*                                                                      *
1765 \subsection{Duplicating continuations}
1766 %*                                                                      *
1767 %************************************************************************
1768
1769 \begin{code}
1770 prepareCaseCont :: SimplEnv
1771                 -> [InAlt] -> SimplCont
1772                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1773                         -- Return a duplicatable continuation, a non-duplicable part
1774                         -- plus some extra bindings (that scope over the entire
1775                         -- continunation)
1776
1777         -- No need to make it duplicatable if there's only one alternative
1778 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1779 prepareCaseCont env alts  cont = mkDupableCont env cont
1780 \end{code}
1781
1782 \begin{code}
1783 mkDupableCont :: SimplEnv -> SimplCont
1784               -> SimplM (FloatsWith (SimplCont, SimplCont))
1785
1786 mkDupableCont env cont
1787   | contIsDupable cont
1788   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1789
1790 mkDupableCont env (CoerceIt ty cont)
1791   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1792     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1793
1794 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1795   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1796         -- Do *not* duplicate an ArgOf continuation
1797         -- Because ArgOf continuations are opaque, we gain nothing by
1798         -- propagating them into the expressions, and we do lose a lot.
1799         -- Here's an example:
1800         --      && (case x of { T -> F; F -> T }) E
1801         -- Now, && is strict so we end up simplifying the case with
1802         -- an ArgOf continuation.  If we let-bind it, we get
1803         --
1804         --      let $j = \v -> && v E
1805         --      in simplExpr (case x of { T -> F; F -> T })
1806         --                   (ArgOf (\r -> $j r)
1807         -- And after simplifying more we get
1808         --
1809         --      let $j = \v -> && v E
1810         --      in case of { T -> $j F; F -> $j T }
1811         -- Which is a Very Bad Thing
1812         --
1813         -- The desire not to duplicate is the entire reason that
1814         -- mkDupableCont returns a pair of continuations.
1815         --
1816         -- The original plan had:
1817         -- e.g.         (...strict-fn...) [...hole...]
1818         --      ==>
1819         --              let $j = \a -> ...strict-fn...
1820         --              in $j [...hole...]
1821
1822 mkDupableCont env (ApplyTo _ arg mb_se cont)
1823   =     -- e.g.         [...hole...] (...arg...)
1824         --      ==>
1825         --              let a = ...arg...
1826         --              in [...hole...] a
1827     do  { (floats, (dup_cont, nondup_cont)) <- mkDupableCont env cont
1828         ; addFloats env floats $ \ env -> do
1829         { arg1 <- simplArg env arg mb_se
1830         ; (floats2, arg2) <- mkDupableArg env arg1
1831         ; return (floats2, (ApplyTo OkToDup arg2 Nothing dup_cont, nondup_cont)) }}
1832
1833 mkDupableCont env cont@(Select _ case_bndr [(_,bs,rhs)] se case_cont)
1834 --   | not (exprIsDupable rhs && contIsDupable case_cont)       -- See notes below
1835 --  | not (isDeadBinder case_bndr)
1836   | all isDeadBinder bs
1837   = returnSmpl (emptyFloats env, (mkBoringStop scrut_ty, cont))
1838   where
1839     scrut_ty = substTy se (idType case_bndr)
1840
1841 {-      Note [Single-alternative cases]
1842         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1843 This case is just like the ArgOf case.  Here's an example:
1844         data T a = MkT !a
1845         ...(MkT (abs x))...
1846 Then we get
1847         case (case x of I# x' ->
1848               case x' <# 0# of
1849                 True  -> I# (negate# x')
1850                 False -> I# x') of y {
1851           DEFAULT -> MkT y
1852 Because the (case x) has only one alternative, we'll transform to
1853         case x of I# x' ->
1854         case (case x' <# 0# of
1855                 True  -> I# (negate# x')
1856                 False -> I# x') of y {
1857           DEFAULT -> MkT y
1858 But now we do *NOT* want to make a join point etc, giving
1859         case x of I# x' ->
1860         let $j = \y -> MkT y
1861         in case x' <# 0# of
1862                 True  -> $j (I# (negate# x'))
1863                 False -> $j (I# x')
1864 In this case the $j will inline again, but suppose there was a big
1865 strict computation enclosing the orginal call to MkT.  Then, it won't
1866 "see" the MkT any more, because it's big and won't get duplicated.
1867 And, what is worse, nothing was gained by the case-of-case transform.
1868
1869 When should use this case of mkDupableCont?
1870 However, matching on *any* single-alternative case is a *disaster*;
1871   e.g.  case (case ....) of (a,b) -> (# a,b #)
1872   We must push the outer case into the inner one!
1873 Other choices:
1874
1875    * Match [(DEFAULT,_,_)], but in the common case of Int,
1876      the alternative-filling-in code turned the outer case into
1877                 case (...) of y { I# _ -> MkT y }
1878
1879    * Match on single alternative plus (not (isDeadBinder case_bndr))
1880      Rationale: pushing the case inwards won't eliminate the construction.
1881      But there's a risk of
1882                 case (...) of y { (a,b) -> let z=(a,b) in ... }
1883      Now y looks dead, but it'll come alive again.  Still, this
1884      seems like the best option at the moment.
1885
1886    * Match on single alternative plus (all (isDeadBinder bndrs))
1887      Rationale: this is essentially  seq.
1888
1889    * Match when the rhs is *not* duplicable, and hence would lead to a
1890      join point.  This catches the disaster-case above.  We can test
1891      the *un-simplified* rhs, which is fine.  It might get bigger or
1892      smaller after simplification; if it gets smaller, this case might
1893      fire next time round.  NB also that we must test contIsDupable
1894      case_cont *btoo, because case_cont might be big!
1895
1896      HOWEVER: I found that this version doesn't work well, because
1897      we can get         let x = case (...) of { small } in ...case x...
1898      When x is inlined into its full context, we find that it was a bad
1899      idea to have pushed the outer case inside the (...) case.
1900 -}
1901
1902 mkDupableCont env (Select _ case_bndr alts se cont)
1903   =     -- e.g.         (case [...hole...] of { pi -> ei })
1904         --      ===>
1905         --              let ji = \xij -> ei
1906         --              in case [...hole...] of { pi -> ji xij }
1907     do  { tick (CaseOfCase case_bndr)
1908         ; let alt_env = setInScope se env
1909         ; (floats1, (dup_cont, nondup_cont)) <- mkDupableCont alt_env cont
1910                 -- NB: call mkDupableCont here, *not* prepareCaseCont
1911                 -- We must make a duplicable continuation, whereas prepareCaseCont
1912                 -- doesn't when there is a single case branch
1913         ; addFloats alt_env floats1     $ \ alt_env -> do
1914
1915         { (alt_env, case_bndr') <- simplBinder alt_env case_bndr
1916                 -- NB: simplBinder does not zap deadness occ-info, so
1917                 -- a dead case_bndr' will still advertise its deadness
1918                 -- This is really important because in
1919                 --      case e of b { (# a,b #) -> ... }
1920                 -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1921                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1922                 -- In the new alts we build, we have the new case binder, so it must retain
1923                 -- its deadness.
1924
1925         ; (floats2, alts') <- mkDupableAlts alt_env case_bndr' alts dup_cont
1926         ; return (floats2, (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1927                                    (mkBoringStop (contResultType dup_cont)),
1928                             nondup_cont))
1929         }}
1930
1931 mkDupableArg :: SimplEnv -> OutExpr -> SimplM (FloatsWith OutExpr)
1932 -- Let-bind the thing if necessary
1933 mkDupableArg env arg
1934   | exprIsDupable arg
1935   = return (emptyFloats env, arg)
1936   | otherwise
1937   = do  { arg_id <- newId FSLIT("a") (exprType arg)
1938         ; tick (CaseOfCase arg_id)
1939                 -- Want to tick here so that we go round again,
1940                 -- and maybe copy or inline the code.
1941                 -- Not strictly CaseOfCase, but never mind
1942         ; return (unitFloat env arg_id arg, Var arg_id) }
1943         -- What if the arg should be case-bound?
1944         -- This has been this way for a long time, so I'll leave it,
1945         -- but I can't convince myself that it's right.
1946
1947 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1948               -> SimplM (FloatsWith [InAlt])
1949 -- Absorbs the continuation into the new alternatives
1950
1951 mkDupableAlts env case_bndr' alts dupable_cont
1952   = go env alts
1953   where
1954     go env [] = returnSmpl (emptyFloats env, [])
1955     go env (alt:alts)
1956         = do { (floats1, mb_alt') <- mkDupableAlt env case_bndr' dupable_cont alt
1957              ; addFloats env floats1    $ \ env -> do
1958              { (floats2, alts') <- go env alts
1959              ; returnSmpl (floats2, case mb_alt' of
1960                                         Just alt' -> alt' : alts'
1961                                         Nothing   -> alts'
1962                           )}}
1963
1964 mkDupableAlt env case_bndr' cont alt
1965   = simplAlt env [] case_bndr' cont alt         `thenSmpl` \ mb_stuff ->
1966     case mb_stuff of {
1967         Nothing -> returnSmpl (emptyFloats env, Nothing) ;
1968
1969         Just (reft, (con, bndrs', rhs')) ->
1970         -- Safe to say that there are no handled-cons for the DEFAULT case
1971
1972     if exprIsDupable rhs' then
1973         returnSmpl (emptyFloats env, Just (con, bndrs', rhs'))
1974         -- It is worth checking for a small RHS because otherwise we
1975         -- get extra let bindings that may cause an extra iteration of the simplifier to
1976         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1977         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1978         -- iterations because the version with the let bindings looked big, and so wasn't
1979         -- inlined, but after the join points had been inlined it looked smaller, and so
1980         -- was inlined.
1981         --
1982         -- NB: we have to check the size of rhs', not rhs.
1983         -- Duplicating a small InAlt might invalidate occurrence information
1984         -- However, if it *is* dupable, we return the *un* simplified alternative,
1985         -- because otherwise we'd need to pair it up with an empty subst-env....
1986         -- but we only have one env shared between all the alts.
1987         -- (Remember we must zap the subst-env before re-simplifying something).
1988         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1989
1990     else
1991     let
1992         rhs_ty'     = exprType rhs'
1993         used_bndrs' = filter abstract_over (case_bndr' : bndrs')
1994         abstract_over bndr
1995           | isTyVar bndr = not (bndr `elemVarEnv` reft)
1996                 -- Don't abstract over tyvar binders which are refined away
1997                 -- See Note [Refinement] below
1998           | otherwise    = not (isDeadBinder bndr)
1999                 -- The deadness info on the new Ids is preserved by simplBinders
2000     in
2001         -- If we try to lift a primitive-typed something out
2002         -- for let-binding-purposes, we will *caseify* it (!),
2003         -- with potentially-disastrous strictness results.  So
2004         -- instead we turn it into a function: \v -> e
2005         -- where v::State# RealWorld#.  The value passed to this function
2006         -- is realworld#, which generates (almost) no code.
2007
2008         -- There's a slight infelicity here: we pass the overall
2009         -- case_bndr to all the join points if it's used in *any* RHS,
2010         -- because we don't know its usage in each RHS separately
2011
2012         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
2013         -- we make the join point into a function whenever used_bndrs'
2014         -- is empty.  This makes the join-point more CPR friendly.
2015         -- Consider:    let j = if .. then I# 3 else I# 4
2016         --              in case .. of { A -> j; B -> j; C -> ... }
2017         --
2018         -- Now CPR doesn't w/w j because it's a thunk, so
2019         -- that means that the enclosing function can't w/w either,
2020         -- which is a lose.  Here's the example that happened in practice:
2021         --      kgmod :: Int -> Int -> Int
2022         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2023         --                  then 78
2024         --                  else 5
2025         --
2026         -- I have seen a case alternative like this:
2027         --      True -> \v -> ...
2028         -- It's a bit silly to add the realWorld dummy arg in this case, making
2029         --      $j = \s v -> ...
2030         --         True -> $j s
2031         -- (the \v alone is enough to make CPR happy) but I think it's rare
2032
2033     ( if not (any isId used_bndrs')
2034         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
2035              returnSmpl ([rw_id], [Var realWorldPrimId])
2036         else
2037              returnSmpl (used_bndrs', varsToCoreExprs used_bndrs')
2038     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
2039
2040         -- See comment about "$j" name above
2041     newId FSLIT("$j") (mkPiTypes final_bndrs' rhs_ty')  `thenSmpl` \ join_bndr ->
2042         -- Notice the funky mkPiTypes.  If the contructor has existentials
2043         -- it's possible that the join point will be abstracted over
2044         -- type varaibles as well as term variables.
2045         --  Example:  Suppose we have
2046         --      data T = forall t.  C [t]
2047         --  Then faced with
2048         --      case (case e of ...) of
2049         --          C t xs::[t] -> rhs
2050         --  We get the join point
2051         --      let j :: forall t. [t] -> ...
2052         --          j = /\t \xs::[t] -> rhs
2053         --      in
2054         --      case (case e of ...) of
2055         --          C t xs::[t] -> j t xs
2056     let
2057         -- We make the lambdas into one-shot-lambdas.  The
2058         -- join point is sure to be applied at most once, and doing so
2059         -- prevents the body of the join point being floated out by
2060         -- the full laziness pass
2061         really_final_bndrs     = map one_shot final_bndrs'
2062         one_shot v | isId v    = setOneShotLambda v
2063                    | otherwise = v
2064         join_rhs  = mkLams really_final_bndrs rhs'
2065         join_call = mkApps (Var join_bndr) final_args
2066     in
2067     returnSmpl (unitFloat env join_bndr join_rhs, Just (con, bndrs', join_call)) }
2068 \end{code}
2069
2070 Note [Refinement]
2071 ~~~~~~~~~~~~~~~~~
2072 Consider
2073         data T a where
2074           MkT :: a -> b -> T a
2075
2076         f = /\a. \(w::a).
2077            case (case ...) of
2078                   MkT a' b (p::a') (q::b) -> [p,w]
2079
2080 The danger is that we'll make a join point
2081
2082         j a' p = [p,w]
2083
2084 and that's ill-typed, because (p::a') but (w::a).
2085
2086 Solution so far: don't abstract over a', because the type refinement
2087 maps [a' -> a] .  Ultimately that won't work when real refinement goes on.
2088
2089 Then we must abstract over any refined free variables.  Hmm.  Maybe we
2090 could just abstract over *all* free variables, thereby lambda-lifting
2091 the join point?   We should try this.