compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplEnv
  16 import SimplUtils       ( mkCase, mkLam,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkRhsStop, mkBoringStop,  mkLazyArgStop, pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType,
  21                           preInlineUnconditionally, postInlineUnconditionally,
  22                           interestingArgContext, inlineMode, activeInline, activeRule
  23                         )
  24 import Id               ( Id, idType, idInfo, idArity, isDataConWorkId,
  25                           idUnfolding, setIdUnfolding, isDeadBinder,
  26                           idNewDemandInfo, setIdInfo,
  27                           setIdOccInfo, zapLamIdInfo, setOneShotLambda
  28                         )
  29 import IdInfo           ( OccInfo(..), isLoopBreaker,
  30                           setArityInfo, zapDemandInfo,
  31                           setUnfoldingInfo,
  32                           occInfo
  33                         )
  34 import NewDemand        ( isStrictDmd )
  35 import TcGadt           ( dataConCanMatch )
  36 import DataCon          ( dataConTyCon, dataConRepStrictness )
  37 import TyCon            ( tyConArity, isAlgTyCon, isNewTyCon, tyConDataCons_maybe )
  38 import CoreSyn
  39 import PprCore          ( pprParendExpr, pprCoreExpr )
  40 import CoreUnfold       ( mkUnfolding, callSiteInline )
  41 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  42                           exprIsConApp_maybe, mkPiTypes, findAlt,
  43                           exprType, exprIsHNF, findDefault, mergeAlts,
  44                           exprOkForSpeculation, exprArity,
  45                           mkCoerce, mkSCC, mkInlineMe, applyTypeToArg,
  46                           dataConRepInstPat
  47                         )
  48 import Rules            ( lookupRule )
  49 import BasicTypes       ( isMarkedStrict )
  50 import CostCentre       ( currentCCS )
  51 import Type             ( TvSubstEnv, isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  52                           coreEqType, splitTyConApp_maybe,
  53                           isTyVarTy, isFunTy, tcEqType
  54                         )
  55 import Coercion         ( Coercion, coercionKind,
  56                           mkTransCoercion, mkSymCoercion, splitCoercionKind_maybe, decomposeCo  )
  57 import VarEnv           ( elemVarEnv, emptyVarEnv )
  58 import TysPrim          ( realWorldStatePrimTy )
  59 import PrelInfo         ( realWorldPrimId )
  60 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  61                           RecFlag(..), isNonRec
  62                         )
  63 import OrdList
  64 import List             ( nub )
  65 import Maybes           ( orElse )
  66 import Outputable
  67 import Util             ( notNull, filterOut )
  68 \end{code}
  69
  70
  71 The guts of the simplifier is in this module, but the driver loop for
  72 the simplifier is in SimplCore.lhs.
  73
  74
  75 -----------------------------------------
  76         *** IMPORTANT NOTE ***
  77 -----------------------------------------
  78 The simplifier used to guarantee that the output had no shadowing, but
  79 it does not do so any more.   (Actually, it never did!)  The reason is
  80 documented with simplifyArgs.
  81
  82
  83 -----------------------------------------
  84         *** IMPORTANT NOTE ***
  85 -----------------------------------------
  86 Many parts of the simplifier return a bunch of "floats" as well as an
  87 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  88
  89 All "floats" are let-binds, not case-binds, but some non-rec lets may
  90 be unlifted (with RHS ok-for-speculation).
  91
  92
  93
  94 -----------------------------------------
  95         ORGANISATION OF FUNCTIONS
  96 -----------------------------------------
  97 simplTopBinds
  98   - simplify all top-level binders
  99   - for NonRec, call simplRecOrTopPair
 100   - for Rec,    call simplRecBind
 101
 102
 103         ------------------------------
 104 simplExpr (applied lambda)      ==> simplNonRecBind
 105 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 106 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 107
 108         ------------------------------
 109 simplRecBind    [binders already simplfied]
 110   - use simplRecOrTopPair on each pair in turn
 111
 112 simplRecOrTopPair [binder already simplified]
 113   Used for: recursive bindings (top level and nested)
 114             top-level non-recursive bindings
 115   Returns:
 116   - check for PreInlineUnconditionally
 117   - simplLazyBind
 118
 119 simplNonRecBind
 120   Used for: non-top-level non-recursive bindings
 121             beta reductions (which amount to the same thing)
 122   Because it can deal with strict arts, it takes a
 123         "thing-inside" and returns an expression
 124
 125   - check for PreInlineUnconditionally
 126   - simplify binder, including its IdInfo
 127   - if strict binding
 128         simplStrictArg
 129         mkAtomicArgs
 130         completeNonRecX
 131     else
 132         simplLazyBind
 133         addFloats
 134
 135 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 136   Used for: binding case-binder and constr args in a known-constructor case
 137   - check for PreInLineUnconditionally
 138   - simplify binder
 139   - completeNonRecX
 140
 141         ------------------------------
 142 simplLazyBind:  [binder already simplified, RHS not]
 143   Used for: recursive bindings (top level and nested)
 144             top-level non-recursive bindings
 145             non-top-level, but *lazy* non-recursive bindings
 146         [must not be strict or unboxed]
 147   Returns floats + an augmented environment, not an expression
 148   - substituteIdInfo and add result to in-scope
 149         [so that rules are available in rec rhs]
 150   - simplify rhs
 151   - mkAtomicArgs
 152   - float if exposes constructor or PAP
 153   - completeLazyBind
 154
 155
 156 completeNonRecX:        [binder and rhs both simplified]
 157   - if the the thing needs case binding (unlifted and not ok-for-spec)
 158         build a Case
 159    else
 160         completeLazyBind
 161         addFloats
 162
 163 completeLazyBind:       [given a simplified RHS]
 164         [used for both rec and non-rec bindings, top level and not]
 165   - try PostInlineUnconditionally
 166   - add unfolding [this is the only place we add an unfolding]
 167   - add arity
 168
 169
 170
 171 Right hand sides and arguments
 172 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 173 In many ways we want to treat
 174         (a) the right hand side of a let(rec), and
 175         (b) a function argument
 176 in the same way.  But not always!  In particular, we would
 177 like to leave these arguments exactly as they are, so they
 178 will match a RULE more easily.
 179
 180         f (g x, h x)
 181         g (+ x)
 182
 183 It's harder to make the rule match if we ANF-ise the constructor,
 184 or eta-expand the PAP:
 185
 186         f (let { a = g x; b = h x } in (a,b))
 187         g (\y. + x y)
 188
 189 On the other hand if we see the let-defns
 190
 191         p = (g x, h x)
 192         q = + x
 193
 194 then we *do* want to ANF-ise and eta-expand, so that p and q
 195 can be safely inlined.
 196
 197 Even floating lets out is a bit dubious.  For let RHS's we float lets
 198 out if that exposes a value, so that the value can be inlined more vigorously.
 199 For example
 200
 201         r = let x = e in (x,x)
 202
 203 Here, if we float the let out we'll expose a nice constructor. We did experiments
 204 that showed this to be a generally good thing.  But it was a bad thing to float
 205 lets out unconditionally, because that meant they got allocated more often.
 206
 207 For function arguments, there's less reason to expose a constructor (it won't
 208 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 209 So for the moment we don't float lets out of function arguments either.
 210
 211
 212 Eta expansion
 213 ~~~~~~~~~~~~~~
 214 For eta expansion, we want to catch things like
 215
 216         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 217
 218 If the \x was on the RHS of a let, we'd eta expand to bring the two
 219 lambdas together.  And in general that's a good thing to do.  Perhaps
 220 we should eta expand wherever we find a (value) lambda?  Then the eta
 221 expansion at a let RHS can concentrate solely on the PAP case.
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226 \subsection{Bindings}
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 \begin{code}
 231 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 232
 233 simplTopBinds env binds
 234   =     -- Put all the top-level binders into scope at the start
 235         -- so that if a transformation rule has unexpectedly brought
 236         -- anything into scope, then we don't get a complaint about that.
 237         -- It's rather as if the top-level binders were imported.
 238     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 239     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 240     freeTick SimplifierDone                     `thenSmpl_`
 241     returnSmpl (floatBinds floats)
 242   where
 243         -- We need to track the zapped top-level binders, because
 244         -- they should have their fragile IdInfo zapped (notably occurrence info)
 245         -- That's why we run down binds and bndrs' simultaneously.
 246     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 247     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 248     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 249                                       addFloats env floats              $ \env ->
 250                                       simpl_binds env binds (drop_bs bind bs)
 251
 252     drop_bs (NonRec _ _) (_ : bs) = bs
 253     drop_bs (Rec prs)    bs       = drop (length prs) bs
 254
 255     simpl_bind env bind bs
 256       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 257         if dopt Opt_D_dump_inlinings dflags then
 258            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 259         else
 260            simpl_bind1 env bind bs
 261
 262     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 263     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 264 \end{code}
 265
 266
 267 %************************************************************************
 268 %*                                                                      *
 269 \subsection{simplNonRec}
 270 %*                                                                      *
 271 %************************************************************************
 272
 273 simplNonRecBind is used for
 274   * non-top-level non-recursive lets in expressions
 275   * beta reduction
 276
 277 It takes
 278   * An unsimplified (binder, rhs) pair
 279   * The env for the RHS.  It may not be the same as the
 280         current env because the bind might occur via (\x.E) arg
 281
 282 It uses the CPS form because the binding might be strict, in which
 283 case we might discard the continuation:
 284         let x* = error "foo" in (...x...)
 285
 286 It needs to turn unlifted bindings into a @case@.  They can arise
 287 from, say:      (\x -> e) (4# + 3#)
 288
 289 \begin{code}
 290 simplNonRecBind :: SimplEnv
 291                 -> InId                                 -- Binder
 292                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 293                 -> OutType                              -- Type of thing computed by the context
 294                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 295                 -> SimplM FloatsWithExpr
 296 #ifdef DEBUG
 297 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 298   | isTyVar bndr
 299   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 300 #endif
 301
 302 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 303   = simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 304
 305 simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 306   | preInlineUnconditionally env NotTopLevel bndr rhs
 307   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 308     thing_inside (extendIdSubst env bndr (mkContEx rhs_se rhs))
 309
 310   | isStrictDmd (idNewDemandInfo bndr) || isStrictType bndr_ty  -- A strict let
 311   =     -- Don't use simplBinder because that doesn't keep
 312         -- fragile occurrence info in the substitution
 313     simplNonRecBndr env bndr                                    `thenSmpl` \ (env, bndr1) ->
 314     simplStrictArg AnRhs env rhs rhs_se (idType bndr1) cont_ty  $ \ env1 rhs1 ->
 315
 316         -- Now complete the binding and simplify the body
 317     let
 318         (env2,bndr2) = addLetIdInfo env1 bndr bndr1
 319     in
 320     completeNonRecX env2 True {- strict -} bndr bndr2 rhs1 thing_inside
 321
 322   | otherwise                                                   -- Normal, lazy case
 323   =     -- Don't use simplBinder because that doesn't keep
 324         -- fragile occurrence info in the substitution
 325     simplNonRecBndr env bndr                            `thenSmpl` \ (env, bndr') ->
 326     simplLazyBind env NotTopLevel NonRecursive
 327                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 328     addFloats env floats thing_inside
 329
 330   where
 331     bndr_ty = idType bndr
 332 \end{code}
 333
 334 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 335 in knownCon.  It uses case-binding where necessary.
 336
 337 \begin{code}
 338 simplNonRecX :: SimplEnv
 339              -> InId            -- Old binder
 340              -> OutExpr         -- Simplified RHS
 341              -> (SimplEnv -> SimplM FloatsWithExpr)
 342              -> SimplM FloatsWithExpr
 343
 344 simplNonRecX env bndr new_rhs thing_inside
 345   = do  { (env, bndr') <- simplBinder env bndr
 346         ; completeNonRecX env False {- Non-strict; pessimistic -}
 347                           bndr bndr' new_rhs thing_inside }
 348
 349
 350 completeNonRecX :: SimplEnv
 351                 -> Bool                 -- Strict binding
 352                 -> InId                 -- Old binder
 353                 -> OutId                -- New binder
 354                 -> OutExpr              -- Simplified RHS
 355                 -> (SimplEnv -> SimplM FloatsWithExpr)
 356                 -> SimplM FloatsWithExpr
 357
 358 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 359   | needsCaseBinding (idType new_bndr) new_rhs
 360         -- Make this test *before* the preInlineUnconditionally
 361         -- Consider     case I# (quotInt# x y) of
 362         --                I# v -> let w = J# v in ...
 363         -- If we gaily inline (quotInt# x y) for v, we end up building an
 364         -- extra thunk:
 365         --                let w = J# (quotInt# x y) in ...
 366         -- because quotInt# can fail.
 367   = do  { (floats, body) <- thing_inside env
 368         ; let body' = wrapFloats floats body
 369         ; return (emptyFloats env, Case new_rhs new_bndr (exprType body)
 370                                         [(DEFAULT, [], body')]) }
 371
 372   | otherwise
 373   =     -- Make the arguments atomic if necessary,
 374         -- adding suitable bindings
 375     -- pprTrace "completeNonRecX" (ppr new_bndr <+> ppr new_rhs) $
 376     mkAtomicArgsE env is_strict new_rhs         $ \ env new_rhs ->
 377     completeLazyBind env NotTopLevel
 378                      old_bndr new_bndr new_rhs  `thenSmpl` \ (floats, env) ->
 379     addFloats env floats thing_inside
 380
 381 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
 382    Doing so risks exponential behaviour, because new_rhs has been simplified once already
 383    In the cases described by the folowing commment, postInlineUnconditionally will
 384    catch many of the relevant cases.
 385         -- This happens; for example, the case_bndr during case of
 386         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 387         -- Here x isn't mentioned in the RHS, so we don't want to
 388         -- create the (dead) let-binding  let x = (a,b) in ...
 389         --
 390         -- Similarly, single occurrences can be inlined vigourously
 391         -- e.g.  case (f x, g y) of (a,b) -> ....
 392         -- If a,b occur once we can avoid constructing the let binding for them.
 393   | preInlineUnconditionally env NotTopLevel bndr new_rhs
 394   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
 395
 396   -- NB: completeLazyBind uses postInlineUnconditionally; no need to do that here
 397 -}
 398 \end{code}
 399
 400
 401 %************************************************************************
 402 %*                                                                      *
 403 \subsection{Lazy bindings}
 404 %*                                                                      *
 405 %************************************************************************
 406
 407 simplRecBind is used for
 408         * recursive bindings only
 409
 410 \begin{code}
 411 simplRecBind :: SimplEnv -> TopLevelFlag
 412              -> [(InId, InExpr)] -> [OutId]
 413              -> SimplM (FloatsWith SimplEnv)
 414 simplRecBind env top_lvl pairs bndrs'
 415   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 416     returnSmpl (flattenFloats floats, env)
 417   where
 418     go env [] _ = returnSmpl (emptyFloats env, env)
 419
 420     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 421         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 422           addFloats env floats (\env -> go env pairs bndrs')
 423 \end{code}
 424
 425
 426 simplRecOrTopPair is used for
 427         * recursive bindings (whether top level or not)
 428         * top-level non-recursive bindings
 429
 430 It assumes the binder has already been simplified, but not its IdInfo.
 431
 432 \begin{code}
 433 simplRecOrTopPair :: SimplEnv
 434                   -> TopLevelFlag
 435                   -> InId -> OutId              -- Binder, both pre-and post simpl
 436                   -> InExpr                     -- The RHS and its environment
 437                   -> SimplM (FloatsWith SimplEnv)
 438
 439 simplRecOrTopPair env top_lvl bndr bndr' rhs
 440   | preInlineUnconditionally env top_lvl bndr rhs       -- Check for unconditional inline
 441   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 442     returnSmpl (emptyFloats env, extendIdSubst env bndr (mkContEx env rhs))
 443
 444   | otherwise
 445   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 446         -- May not actually be recursive, but it doesn't matter
 447 \end{code}
 448
 449
 450 simplLazyBind is used for
 451         * recursive bindings (whether top level or not)
 452         * top-level non-recursive bindings
 453         * non-top-level *lazy* non-recursive bindings
 454
 455 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 456 from SimplRecOrTopBind]
 457
 458 Nota bene:
 459     1. It assumes that the binder is *already* simplified,
 460        and is in scope, but not its IdInfo
 461
 462     2. It assumes that the binder type is lifted.
 463
 464     3. It does not check for pre-inline-unconditionallly;
 465        that should have been done already.
 466
 467 \begin{code}
 468 simplLazyBind :: SimplEnv
 469               -> TopLevelFlag -> RecFlag
 470               -> InId -> OutId          -- Binder, both pre-and post simpl
 471               -> InExpr -> SimplEnv     -- The RHS and its environment
 472               -> SimplM (FloatsWith SimplEnv)
 473
 474 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 475   = let
 476         (env1,bndr2)      = addLetIdInfo env bndr bndr1
 477         rhs_env           = setInScope rhs_se env1
 478         is_top_level      = isTopLevel top_lvl
 479         ok_float_unlifted = not is_top_level && isNonRec is_rec
 480         rhs_cont          = mkRhsStop (idType bndr2)
 481     in
 482         -- Simplify the RHS; note the mkRhsStop, which tells
 483         -- the simplifier that this is the RHS of a let.
 484     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 485
 486         -- If any of the floats can't be floated, give up now
 487         -- (The allLifted predicate says True for empty floats.)
 488     if (not ok_float_unlifted && not (allLifted floats)) then
 489         completeLazyBind env1 top_lvl bndr bndr2
 490                          (wrapFloats floats rhs1)
 491     else
 492
 493         -- ANF-ise a constructor or PAP rhs
 494     mkAtomicArgs False {- Not strict -}
 495                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 496
 497         -- If the result is a PAP, float the floats out, else wrap them
 498         -- By this time it's already been ANF-ised (if necessary)
 499     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 500         completeLazyBind env1 top_lvl bndr bndr2 rhs2
 501
 502     else if is_top_level || exprIsTrivial rhs2 || exprIsHNF rhs2 then
 503         --      WARNING: long dodgy argument coming up
 504         --      WANTED: a better way to do this
 505         --
 506         -- We can't use "exprIsCheap" instead of exprIsHNF,
 507         -- because that causes a strictness bug.
 508         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 509         -- The case expression is 'cheap', but it's wrong to transform to
 510         --         y* = E; x = case (scc y) of {...}
 511         -- Either we must be careful not to float demanded non-values, or
 512         -- we must use exprIsHNF for the test, which ensures that the
 513         -- thing is non-strict.  So exprIsHNF => bindings are non-strict
 514         -- I think.  The WARN below tests for this.
 515         --
 516         -- We use exprIsTrivial here because we want to reveal lone variables.
 517         -- E.g.  let { x = letrec { y = E } in y } in ...
 518         -- Here we definitely want to float the y=E defn.
 519         -- exprIsHNF definitely isn't right for that.
 520         --
 521         -- Again, the floated binding can't be strict; if it's recursive it'll
 522         -- be non-strict; if it's non-recursive it'd be inlined.
 523         --
 524         -- Note [SCC-and-exprIsTrivial]
 525         -- If we have
 526         --      y = let { x* = E } in scc "foo" x
 527         -- then we do *not* want to float out the x binding, because
 528         -- it's strict!  Fortunately, exprIsTrivial replies False to
 529         -- (scc "foo" x).
 530
 531                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 532                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 533                 -- to float it out?  Answer no, but it won't matter because
 534                 -- we only float if (a) arg' is a WHNF, or (b) it's going to top level
 535                 -- and so there can't be any 'will be demanded' bindings in the floats.
 536                 -- Hence the warning
 537         WARN( not (is_top_level || not (any demanded_float (floatBinds floats))),
 538               ppr (filter demanded_float (floatBinds floats)) )
 539
 540         tick LetFloatFromLet                    `thenSmpl_` (
 541         addFloats env1 floats                   $ \ env2 ->
 542         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 543         completeLazyBind env3 top_lvl bndr bndr2 rhs2)
 544
 545     else
 546         completeLazyBind env1 top_lvl bndr bndr2 (wrapFloats floats rhs1)
 547
 548 #ifdef DEBUG
 549 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 550                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 551 demanded_float (Rec _)      = False
 552 #endif
 553 \end{code}
 554
 555
 556 %************************************************************************
 557 %*                                                                      *
 558 \subsection{Completing a lazy binding}
 559 %*                                                                      *
 560 %************************************************************************
 561
 562 completeLazyBind
 563         * deals only with Ids, not TyVars
 564         * takes an already-simplified binder and RHS
 565         * is used for both recursive and non-recursive bindings
 566         * is used for both top-level and non-top-level bindings
 567
 568 It does the following:
 569   - tries discarding a dead binding
 570   - tries PostInlineUnconditionally
 571   - add unfolding [this is the only place we add an unfolding]
 572   - add arity
 573
 574 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 575         - top-level bindings (when let-to-case is impossible)
 576         - many situations where the "rhs" is known to be a WHNF
 577                 (so let-to-case is inappropriate).
 578
 579 \begin{code}
 580 completeLazyBind :: SimplEnv
 581                  -> TopLevelFlag        -- Flag stuck into unfolding
 582                  -> InId                -- Old binder
 583                  -> OutId               -- New binder
 584                  -> OutExpr             -- Simplified RHS
 585                  -> SimplM (FloatsWith SimplEnv)
 586 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 587 -- by extending the substitution (e.g. let x = y in ...)
 588 -- The new binding (if any) is returned as part of the floats.
 589 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 590 --     (as usual) use the in-scope-env from the floats
 591
 592 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 593   | postInlineUnconditionally env top_lvl new_bndr occ_info new_rhs unfolding
 594   =             -- Drop the binding
 595     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 596     -- pprTrace "Inline unconditionally" (ppr old_bndr <+> ppr new_bndr <+> ppr new_rhs) $
 597     returnSmpl (emptyFloats env, extendIdSubst env old_bndr (DoneEx new_rhs))
 598                 -- Use the substitution to make quite, quite sure that the substitution
 599                 -- will happen, since we are going to discard the binding
 600
 601   |  otherwise
 602   = let
 603                 -- Add arity info
 604         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 605
 606         -- Add the unfolding *only* for non-loop-breakers
 607         -- Making loop breakers not have an unfolding at all
 608         -- means that we can avoid tests in exprIsConApp, for example.
 609         -- This is important: if exprIsConApp says 'yes' for a recursive
 610         -- thing, then we can get into an infinite loop
 611         -- If the unfolding is a value, the demand info may
 612         -- go pear-shaped, so we nuke it.  Example:
 613         --      let x = (a,b) in
 614         --      case x of (p,q) -> h p q x
 615         -- Here x is certainly demanded. But after we've nuked
 616         -- the case, we'll get just
 617         --      let x = (a,b) in h a b x
 618         -- and now x is not demanded (I'm assuming h is lazy)
 619         -- This really happens.  Similarly
 620         --      let f = \x -> e in ...f..f...
 621         -- After inling f at some of its call sites the original binding may
 622         -- (for example) be no longer strictly demanded.
 623         -- The solution here is a bit ad hoc...
 624         info_w_unf = new_bndr_info `setUnfoldingInfo` unfolding
 625         final_info | loop_breaker               = new_bndr_info
 626                    | isEvaldUnfolding unfolding = zapDemandInfo info_w_unf `orElse` info_w_unf
 627                    | otherwise                  = info_w_unf
 628
 629         final_id = new_bndr `setIdInfo` final_info
 630     in
 631                 -- These seqs forces the Id, and hence its IdInfo,
 632                 -- and hence any inner substitutions
 633     final_id                                    `seq`
 634     -- pprTrace "Binding" (ppr final_id <+> ppr unfolding) $
 635     returnSmpl (unitFloat env final_id new_rhs, env)
 636
 637   where
 638     unfolding    = mkUnfolding (isTopLevel top_lvl) new_rhs
 639     loop_breaker = isLoopBreaker occ_info
 640     old_info     = idInfo old_bndr
 641     occ_info     = occInfo old_info
 642 \end{code}
 643
 644
 645
 646 %************************************************************************
 647 %*                                                                      *
 648 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 649 %*                                                                      *
 650 %************************************************************************
 651
 652 The reason for this OutExprStuff stuff is that we want to float *after*
 653 simplifying a RHS, not before.  If we do so naively we get quadratic
 654 behaviour as things float out.
 655
 656 To see why it's important to do it after, consider this (real) example:
 657
 658         let t = f x
 659         in fst t
 660 ==>
 661         let t = let a = e1
 662                     b = e2
 663                 in (a,b)
 664         in fst t
 665 ==>
 666         let a = e1
 667             b = e2
 668             t = (a,b)
 669         in
 670         a       -- Can't inline a this round, cos it appears twice
 671 ==>
 672         e1
 673
 674 Each of the ==> steps is a round of simplification.  We'd save a
 675 whole round if we float first.  This can cascade.  Consider
 676
 677         let f = g d
 678         in \x -> ...f...
 679 ==>
 680         let f = let d1 = ..d.. in \y -> e
 681         in \x -> ...f...
 682 ==>
 683         let d1 = ..d..
 684         in \x -> ...(\y ->e)...
 685
 686 Only in this second round can the \y be applied, and it
 687 might do the same again.
 688
 689
 690 \begin{code}
 691 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 692 simplExpr env expr = simplExprC env expr (mkBoringStop expr_ty')
 693                    where
 694                      expr_ty' = substTy env (exprType expr)
 695         -- The type in the Stop continuation, expr_ty', is usually not used
 696         -- It's only needed when discarding continuations after finding
 697         -- a function that returns bottom.
 698         -- Hence the lazy substitution
 699
 700
 701 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 702         -- Simplify an expression, given a continuation
 703 simplExprC env expr cont
 704   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 705     returnSmpl (wrapFloats floats expr)
 706
 707 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 708         -- Simplify an expression, returning floated binds
 709
 710 simplExprF env (Var v)          cont = simplVar env v cont
 711 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 712 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 713 simplExprF env (Note note expr) cont = simplNote env note expr cont
 714 simplExprF env (Cast body co)   cont = simplCast env body co cont
 715 simplExprF env (App fun arg)    cont = simplExprF env fun
 716                                          (ApplyTo NoDup arg (Just env) cont)
 717
 718 simplExprF env (Type ty) cont
 719   = ASSERT( contIsRhsOrArg cont )
 720     simplType env ty                    `thenSmpl` \ ty' ->
 721     rebuild env (Type ty') cont
 722
 723 simplExprF env (Case scrut bndr case_ty alts) cont
 724   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 725   =     -- Simplify the scrutinee with a Select continuation
 726     simplExprF env scrut (Select NoDup bndr alts env cont)
 727
 728   | otherwise
 729   =     -- If case-of-case is off, simply simplify the case expression
 730         -- in a vanilla Stop context, and rebuild the result around it
 731     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 732     rebuild env case_expr' cont
 733   where
 734     case_cont = Select NoDup bndr alts env (mkBoringStop case_ty')
 735     case_ty'  = substTy env case_ty     -- c.f. defn of simplExpr
 736
 737 simplExprF env (Let (Rec pairs) body) cont
 738   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 739         -- NB: bndrs' don't have unfoldings or rules
 740         -- We add them as we go down
 741
 742     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 743     addFloats env floats                        $ \ env ->
 744     simplExprF env body cont
 745
 746 -- A non-recursive let is dealt with by simplNonRecBind
 747 simplExprF env (Let (NonRec bndr rhs) body) cont
 748   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 749     simplExprF env body cont
 750
 751
 752 ---------------------------------
 753 simplType :: SimplEnv -> InType -> SimplM OutType
 754         -- Kept monadic just so we can do the seqType
 755 simplType env ty
 756   = seqType new_ty   `seq`   returnSmpl new_ty
 757   where
 758     new_ty = substTy env ty
 759 \end{code}
 760
 761
 762 %************************************************************************
 763 %*                                                                      *
 764 \subsection{Lambdas}
 765 %*                                                                      *
 766 %************************************************************************
 767
 768 \begin{code}
 769 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont -> SimplM FloatsWithExpr
 770 simplCast env body co cont
 771   = let
 772        addCoerce co cont
 773          | (s1, k1) <- coercionKind co
 774          , s1 `tcEqType` k1 = cont
 775        addCoerce co1 (CoerceIt co2 cont)
 776          | (s1, k1) <- coercionKind co1
 777          , (l1, t1) <- coercionKind co2
 778                 --      coerce T1 S1 (coerce S1 K1 e)
 779                 -- ==>
 780                 --      e,                      if T1=K1
 781                 --      coerce T1 K1 e,         otherwise
 782                 --
 783                 -- For example, in the initial form of a worker
 784                 -- we may find  (coerce T (coerce S (\x.e))) y
 785                 -- and we'd like it to simplify to e[y/x] in one round
 786                 -- of simplification
 787          , s1 `coreEqType` t1  = cont            -- The coerces cancel out
 788          | otherwise           = CoerceIt (mkTransCoercion co1 co2) cont
 789
 790        addCoerce co (ApplyTo dup arg arg_se cont)
 791          | not (isTypeArg arg)    -- This whole case only works for value args
 792                                 -- Could upgrade to have equiv thing for type apps too
 793          , Just (s1s2, t1t2) <- splitCoercionKind_maybe co
 794          , isFunTy s1s2
 795                 -- co : s1s2 :=: t1t2
 796                 --      (coerce (T1->T2) (S1->S2) F) E
 797                 -- ===>
 798                 --      coerce T2 S2 (F (coerce S1 T1 E))
 799                 --
 800                 -- t1t2 must be a function type, T1->T2, because it's applied
 801                 -- to something but s1s2 might conceivably not be
 802                 --
 803                 -- When we build the ApplyTo we can't mix the out-types
 804                 -- with the InExpr in the argument, so we simply substitute
 805                 -- to make it all consistent.  It's a bit messy.
 806                 -- But it isn't a common case.
 807          = result
 808          where
 809            -- we split coercion t1->t2 :=: s1->s2 into t1 :=: s1 and
 810            -- t2 :=: s2 with left and right on the curried form:
 811            --    (->) t1 t2 :=: (->) s1 s2
 812            [co1, co2] = decomposeCo 2 co
 813            new_arg    = mkCoerce (mkSymCoercion co1) arg'
 814            arg'       = case arg_se of
 815                           Nothing     -> arg
 816                           Just arg_se -> substExpr (setInScope arg_se env) arg
 817            result     = ApplyTo dup new_arg (Just $ zapSubstEnv env)
 818                                 (addCoerce co2 cont)
 819        addCoerce co cont = CoerceIt co cont
 820     in
 821     simplType env co            `thenSmpl` \ co' ->
 822     simplExprF env body (addCoerce co' cont)
 823 \end{code}
 824
 825 %************************************************************************
 826 %*                                                                      *
 827 \subsection{Lambdas}
 828 %*                                                                      *
 829 %************************************************************************
 830
 831 \begin{code}
 832 simplLam env fun cont
 833   = go env fun cont
 834   where
 835     zap_it  = mkLamBndrZapper fun (countArgs cont)
 836     cont_ty = contResultType cont
 837
 838         -- Type-beta reduction
 839     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) mb_arg_se body_cont)
 840       = ASSERT( isTyVar bndr )
 841         do { tick (BetaReduction bndr)
 842            ; ty_arg' <- case mb_arg_se of
 843                           Just arg_se -> simplType (setInScope arg_se env) ty_arg
 844                           Nothing     -> return ty_arg
 845            ; go (extendTvSubst env bndr ty_arg') body body_cont }
 846
 847         -- Ordinary beta reduction
 848     go env (Lam bndr body) cont@(ApplyTo _ arg (Just arg_se) body_cont)
 849       = do { tick (BetaReduction bndr)
 850            ; simplNonRecBind env (zap_it bndr) arg arg_se cont_ty       $ \ env ->
 851              go env body body_cont }
 852
 853     go env (Lam bndr body) cont@(ApplyTo _ arg Nothing body_cont)
 854       = do { tick (BetaReduction bndr)
 855            ; simplNonRecX env (zap_it bndr) arg         $ \ env ->
 856              go env body body_cont }
 857
 858         -- Not enough args, so there are real lambdas left to put in the result
 859     go env lam@(Lam _ _) cont
 860       = do { (env, bndrs') <- simplLamBndrs env bndrs
 861            ; body' <- simplExpr env body
 862            ; (floats, new_lam) <- mkLam env bndrs' body' cont
 863            ; addFloats env floats               $ \ env ->
 864              rebuild env new_lam cont }
 865       where
 866         (bndrs,body) = collectBinders lam
 867
 868         -- Exactly enough args
 869     go env expr cont = simplExprF env expr cont
 870
 871 mkLamBndrZapper :: CoreExpr     -- Function
 872                 -> Int          -- Number of args supplied, *including* type args
 873                 -> Id -> Id     -- Use this to zap the binders
 874 mkLamBndrZapper fun n_args
 875   | n_args >= n_params fun = \b -> b            -- Enough args
 876   | otherwise              = \b -> zapLamIdInfo b
 877   where
 878         -- NB: we count all the args incl type args
 879         -- so we must count all the binders (incl type lambdas)
 880     n_params (Note _ e) = n_params e
 881     n_params (Lam b e)  = 1 + n_params e
 882     n_params other      = 0::Int
 883 \end{code}
 884
 885
 886 %************************************************************************
 887 %*                                                                      *
 888 \subsection{Notes}
 889 %*                                                                      *
 890 %************************************************************************
 891
 892 \begin{code}
 893
 894
 895 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 896 -- inlining.  All other CCCSs are mapped to currentCCS.
 897 simplNote env (SCC cc) e cont
 898   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 899     rebuild env (mkSCC cc e') cont
 900
 901 -- See notes with SimplMonad.inlineMode
 902 simplNote env InlineMe e cont
 903   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 904   =                             -- Don't inline inside an INLINE expression
 905     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 906     rebuild env (mkInlineMe e') cont
 907
 908   | otherwise   -- Dissolve the InlineMe note if there's
 909                 -- an interesting context of any kind to combine with
 910                 -- (even a type application -- anything except Stop)
 911   = simplExprF env e cont
 912
 913 simplNote env (CoreNote s) e cont
 914   = simplExpr env e    `thenSmpl` \ e' ->
 915     rebuild env (Note (CoreNote s) e') cont
 916 \end{code}
 917
 918
 919 %************************************************************************
 920 %*                                                                      *
 921 \subsection{Dealing with calls}
 922 %*                                                                      *
 923 %************************************************************************
 924
 925 \begin{code}
 926 simplVar env var cont
 927   = case substId env var of
 928         DoneEx e         -> simplExprF (zapSubstEnv env) e cont
 929         ContEx tvs ids e -> simplExprF (setSubstEnv env tvs ids) e cont
 930         DoneId var1 occ  -> completeCall (zapSubstEnv env) var1 occ cont
 931                 -- Note [zapSubstEnv]
 932                 -- The template is already simplified, so don't re-substitute.
 933                 -- This is VITAL.  Consider
 934                 --      let x = e in
 935                 --      let y = \z -> ...x... in
 936                 --      \ x -> ...y...
 937                 -- We'll clone the inner \x, adding x->x' in the id_subst
 938                 -- Then when we inline y, we must *not* replace x by x' in
 939                 -- the inlined copy!!
 940
 941 ---------------------------------------------------------
 942 --      Dealing with a call site
 943
 944 completeCall env var occ_info cont
 945   =     -- Simplify the arguments
 946     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 947     let
 948         chkr              = getSwitchChecker env
 949         (args, call_cont) = getContArgs chkr var cont
 950         fn_ty             = idType var
 951     in
 952     simplifyArgs env fn_ty (interestingArgContext var call_cont) args
 953                  (contResultType call_cont)     $ \ env args ->
 954
 955         -- Next, look for rules or specialisations that match
 956         --
 957         -- It's important to simplify the args first, because the rule-matcher
 958         -- doesn't do substitution as it goes.  We don't want to use subst_args
 959         -- (defined in the 'where') because that throws away useful occurrence info,
 960         -- and perhaps-very-important specialisations.
 961         --
 962         -- Some functions have specialisations *and* are strict; in this case,
 963         -- we don't want to inline the wrapper of the non-specialised thing; better
 964         -- to call the specialised thing instead.
 965         -- We used to use the black-listing mechanism to ensure that inlining of
 966         -- the wrapper didn't occur for things that have specialisations till a
 967         -- later phase, so but now we just try RULES first
 968         --
 969         -- You might think that we shouldn't apply rules for a loop breaker:
 970         -- doing so might give rise to an infinite loop, because a RULE is
 971         -- rather like an extra equation for the function:
 972         --      RULE:           f (g x) y = x+y
 973         --      Eqn:            f a     y = a-y
 974         --
 975         -- But it's too drastic to disable rules for loop breakers.
 976         -- Even the foldr/build rule would be disabled, because foldr
 977         -- is recursive, and hence a loop breaker:
 978         --      foldr k z (build g) = g k z
 979         -- So it's up to the programmer: rules can cause divergence
 980
 981     let
 982         in_scope   = getInScope env
 983         rules      = getRules env
 984         maybe_rule = case activeRule env of
 985                         Nothing     -> Nothing  -- No rules apply
 986                         Just act_fn -> lookupRule act_fn in_scope rules var args
 987     in
 988     case maybe_rule of {
 989         Just (rule_name, rule_rhs) ->
 990                 tick (RuleFired rule_name)                      `thenSmpl_`
 991                 (if dopt Opt_D_dump_inlinings dflags then
 992                    pprTrace "Rule fired" (vcat [
 993                         text "Rule:" <+> ftext rule_name,
 994                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 995                         text "After: " <+> pprCoreExpr rule_rhs,
 996                         text "Cont:  " <+> ppr call_cont])
 997                  else
 998                         id)             $
 999                 simplExprF env rule_rhs call_cont ;
1000
1001         Nothing ->              -- No rules
1002
1003         -- Next, look for an inlining
1004     let
1005         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
1006         interesting_cont = interestingCallContext (notNull args)
1007                                                   (notNull arg_infos)
1008                                                   call_cont
1009         active_inline = activeInline env var occ_info
1010         maybe_inline  = callSiteInline dflags active_inline occ_info
1011                                        var arg_infos interesting_cont
1012     in
1013     case maybe_inline of {
1014         Just unfolding          -- There is an inlining!
1015           ->  tick (UnfoldingDone var)          `thenSmpl_`
1016                 (if dopt Opt_D_dump_inlinings dflags then
1017                    pprTrace "Inlining done" (vcat [
1018                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
1019                         text "Inlined fn: " <+> ppr unfolding,
1020                         text "Cont:  " <+> ppr call_cont])
1021                  else
1022                         id)             $
1023               simplExprF env unfolding (pushContArgs args call_cont)
1024
1025         ;
1026         Nothing ->              -- No inlining!
1027
1028         -- Done
1029     rebuild env (mkApps (Var var) args) call_cont
1030     }}
1031 \end{code}
1032
1033 %************************************************************************
1034 %*                                                                      *
1035 \subsection{Arguments}
1036 %*                                                                      *
1037 %************************************************************************
1038
1039 \begin{code}
1040 ---------------------------------------------------------
1041 --      Simplifying the arguments of a call
1042
1043 simplifyArgs :: SimplEnv
1044              -> OutType                         -- Type of the function
1045              -> Bool                            -- True if the fn has RULES
1046              -> [(InExpr, Maybe SimplEnv, Bool)] -- Details of the arguments
1047              -> OutType                         -- Type of the continuation
1048              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1049              -> SimplM FloatsWithExpr
1050
1051 -- [CPS-like because of strict arguments]
1052
1053 -- Simplify the arguments to a call.
1054 -- This part of the simplifier may break the no-shadowing invariant
1055 -- Consider
1056 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1057 -- where f is strict in its second arg
1058 -- If we simplify the innermost one first we get (...(\a -> e)...)
1059 -- Simplifying the second arg makes us float the case out, so we end up with
1060 --      case y of (a,b) -> f (...(\a -> e)...) e'
1061 -- So the output does not have the no-shadowing invariant.  However, there is
1062 -- no danger of getting name-capture, because when the first arg was simplified
1063 -- we used an in-scope set that at least mentioned all the variables free in its
1064 -- static environment, and that is enough.
1065 --
1066 -- We can't just do innermost first, or we'd end up with a dual problem:
1067 --      case x of (a,b) -> f e (...(\a -> e')...)
1068 --
1069 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1070 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1071 -- continuations.  We have to keep the right in-scope set around; AND we have
1072 -- to get the effect that finding (error "foo") in a strict arg position will
1073 -- discard the entire application and replace it with (error "foo").  Getting
1074 -- all this at once is TOO HARD!
1075
1076 simplifyArgs env fn_ty has_rules args cont_ty thing_inside
1077   = go env fn_ty args thing_inside
1078   where
1079     go env fn_ty []         thing_inside = thing_inside env []
1080     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty has_rules arg cont_ty  $ \ env arg' ->
1081                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1082                                            thing_inside env (arg':args')
1083
1084 simplifyArg env fn_ty has_rules (arg, Nothing, _) cont_ty thing_inside
1085   = thing_inside env arg        -- Already simplified
1086
1087 simplifyArg env fn_ty has_rules (Type ty_arg, Just se, _) cont_ty thing_inside
1088   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1089     thing_inside env (Type new_ty_arg)
1090
1091 simplifyArg env fn_ty has_rules (val_arg, Just arg_se, is_strict) cont_ty thing_inside
1092   | is_strict
1093   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1094
1095   | otherwise   -- Lazy argument
1096                 -- DO NOT float anything outside, hence simplExprC
1097                 -- There is no benefit (unlike in a let-binding), and we'd
1098                 -- have to be very careful about bogus strictness through
1099                 -- floating a demanded let.
1100   = simplExprC (setInScope arg_se env) val_arg
1101                (mkLazyArgStop arg_ty has_rules)         `thenSmpl` \ arg1 ->
1102     thing_inside env arg1
1103   where
1104     arg_ty = funArgTy fn_ty
1105
1106
1107 simplStrictArg ::  LetRhsFlag
1108                 -> SimplEnv             -- The env of the call
1109                 -> InExpr -> SimplEnv   -- The arg plus its env
1110                 -> OutType              -- arg_ty: type of the argument
1111                 -> OutType              -- cont_ty: Type of thing computed by the context
1112                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1113                                         -- Takes an expression of type rhs_ty,
1114                                         -- returns an expression of type cont_ty
1115                                         -- The env passed to this continuation is the
1116                                         -- env of the call, plus any new in-scope variables
1117                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1118
1119 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1120   = simplExprF (setInScope arg_env call_env) arg
1121                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1122   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1123   --    to simplify the argument
1124   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1125 \end{code}
1126
1127
1128 %************************************************************************
1129 %*                                                                      *
1130 \subsection{mkAtomicArgs}
1131 %*                                                                      *
1132 %************************************************************************
1133
1134 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1135 constructor application and, if so, converts it to ANF, so that the
1136 resulting thing can be inlined more easily.  Thus
1137         x = (f a, g b)
1138 becomes
1139         t1 = f a
1140         t2 = g b
1141         x = (t1,t2)
1142
1143 There are three sorts of binding context, specified by the two
1144 boolean arguments
1145
1146 Strict
1147    OK-unlifted
1148
1149 N  N    Top-level or recursive                  Only bind args of lifted type
1150
1151 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1152                 but lazy                        unlifted-and-ok-for-speculation
1153
1154 Y  Y    Non-top-level, non-recursive,           Bind all args
1155                  and strict (demanded)
1156
1157
1158 For example, given
1159
1160         x = MkC (y div# z)
1161
1162 there is no point in transforming to
1163
1164         x = case (y div# z) of r -> MkC r
1165
1166 because the (y div# z) can't float out of the let. But if it was
1167 a *strict* let, then it would be a good thing to do.  Hence the
1168 context information.
1169
1170 \begin{code}
1171 mkAtomicArgsE :: SimplEnv
1172               -> Bool   -- A strict binding
1173               -> OutExpr                                                -- The rhs
1174               -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1175               -> SimplM FloatsWithExpr
1176
1177 mkAtomicArgsE env is_strict rhs thing_inside
1178   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1179     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1180   = go env (Var fun) args
1181
1182   | otherwise = thing_inside env rhs
1183
1184   where
1185     go env fun [] = thing_inside env fun
1186
1187     go env fun (arg : args)
1188         |  exprIsTrivial arg    -- Easy case
1189         || no_float_arg         -- Can't make it atomic
1190         = go env (App fun arg) args
1191
1192         | otherwise
1193         = do { arg_id <- newId FSLIT("a") arg_ty
1194              ; completeNonRecX env False {- pessimistic -} arg_id arg_id arg $ \env ->
1195                go env (App fun (Var arg_id)) args }
1196         where
1197           arg_ty = exprType arg
1198           no_float_arg = not is_strict && (isUnLiftedType arg_ty) && not (exprOkForSpeculation arg)
1199
1200
1201 -- Old code: consider rewriting to be more like mkAtomicArgsE
1202
1203 mkAtomicArgs :: Bool    -- A strict binding
1204              -> Bool    -- OK to float unlifted args
1205              -> OutExpr
1206              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1207                         OutExpr)                  -- things that need case-binding,
1208                                                   -- if the strict-binding flag is on
1209
1210 mkAtomicArgs is_strict ok_float_unlifted rhs
1211   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1212     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1213   = go fun nilOL [] args        -- Have a go
1214
1215   | otherwise = bale_out        -- Give up
1216
1217   where
1218     bale_out = returnSmpl (nilOL, rhs)
1219
1220     go fun binds rev_args []
1221         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1222
1223     go fun binds rev_args (arg : args)
1224         | exprIsTrivial arg     -- Easy case
1225         = go fun binds (arg:rev_args) args
1226
1227         | not can_float_arg     -- Can't make this arg atomic
1228         = bale_out              -- ... so give up
1229
1230         | otherwise     -- Don't forget to do it recursively
1231                         -- E.g.  x = a:b:c:[]
1232         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1233            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1234            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1235               (Var arg_id : rev_args) args
1236         where
1237           arg_ty        = exprType arg
1238           can_float_arg =  is_strict
1239                         || not (isUnLiftedType arg_ty)
1240                         || (ok_float_unlifted && exprOkForSpeculation arg)
1241
1242
1243 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1244                -> (SimplEnv -> SimplM (FloatsWith a))
1245                -> SimplM (FloatsWith a)
1246 addAtomicBinds env []         thing_inside = thing_inside env
1247 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1248                                              addAtomicBinds env bs thing_inside
1249 \end{code}
1250
1251
1252 %************************************************************************
1253 %*                                                                      *
1254 \subsection{The main rebuilder}
1255 %*                                                                      *
1256 %************************************************************************
1257
1258 \begin{code}
1259 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1260
1261 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1262 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1263 rebuild env expr (CoerceIt co cont)           = rebuild env (mkCoerce co expr) cont
1264 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1265 rebuild env expr (ApplyTo _ arg mb_se cont)   = rebuildApp  env expr arg mb_se cont
1266
1267 rebuildApp env fun arg mb_se cont
1268   = do  { arg' <- simplArg env arg mb_se
1269         ; rebuild env (App fun arg') cont }
1270
1271 simplArg :: SimplEnv -> CoreExpr -> Maybe SimplEnv -> SimplM CoreExpr
1272 simplArg env arg Nothing        = return arg    -- The arg is already simplified
1273 simplArg env arg (Just arg_env) = simplExpr (setInScope arg_env env) arg
1274
1275 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1276 \end{code}
1277
1278
1279 %************************************************************************
1280 %*                                                                      *
1281 \subsection{Functions dealing with a case}
1282 %*                                                                      *
1283 %************************************************************************
1284
1285 Blob of helper functions for the "case-of-something-else" situation.
1286
1287 \begin{code}
1288 ---------------------------------------------------------
1289 --      Eliminate the case if possible
1290
1291 rebuildCase :: SimplEnv
1292             -> OutExpr          -- Scrutinee
1293             -> InId             -- Case binder
1294             -> [InAlt]          -- Alternatives (inceasing order)
1295             -> SimplCont
1296             -> SimplM FloatsWithExpr
1297
1298 rebuildCase env scrut case_bndr alts cont
1299   | Just (con,args) <- exprIsConApp_maybe scrut
1300         -- Works when the scrutinee is a variable with a known unfolding
1301         -- as well as when it's an explicit constructor application
1302   = knownCon env scrut (DataAlt con) args case_bndr alts cont
1303
1304   | Lit lit <- scrut    -- No need for same treatment as constructors
1305                         -- because literals are inlined more vigorously
1306   = knownCon env scrut (LitAlt lit) [] case_bndr alts cont
1307
1308   | otherwise
1309   =     -- Prepare the continuation;
1310         -- The new subst_env is in place
1311     prepareCaseCont env alts cont       `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1312     addFloats env floats                $ \ env ->
1313
1314     let
1315         -- The case expression is annotated with the result type of the continuation
1316         -- This may differ from the type originally on the case.  For example
1317         --      case(T) (case(Int#) a of { True -> 1#; False -> 0# }) of
1318         --         a# -> <blob>
1319         -- ===>
1320         --      let j a# = <blob>
1321         --      in case(T) a of { True -> j 1#; False -> j 0# }
1322         -- Note that the case that scrutinises a now returns a T not an Int#
1323         res_ty' = contResultType dup_cont
1324     in
1325
1326         -- Deal with case binder
1327     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr') ->
1328
1329         -- Deal with the case alternatives
1330     simplAlts alt_env scrut case_bndr' alts dup_cont    `thenSmpl` \ alts' ->
1331
1332         -- Put the case back together
1333     mkCase scrut case_bndr' res_ty' alts'       `thenSmpl` \ case_expr ->
1334
1335         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1336         -- The case binder *not* scope over the whole returned case-expression
1337     rebuild env case_expr nondup_cont
1338 \end{code}
1339
1340 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1341 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1342 way, there's a chance that v will now only be used once, and hence
1343 inlined.
1344
1345 Note 1
1346 ~~~~~~
1347 There is a time we *don't* want to do that, namely when
1348 -fno-case-of-case is on.  This happens in the first simplifier pass,
1349 and enhances full laziness.  Here's the bad case:
1350         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1351 If we eliminate the inner case, we trap it inside the I# v -> arm,
1352 which might prevent some full laziness happening.  I've seen this
1353 in action in spectral/cichelli/Prog.hs:
1354          [(m,n) | m <- [1..max], n <- [1..max]]
1355 Hence the check for NoCaseOfCase.
1356
1357 Note 2
1358 ~~~~~~
1359 There is another situation when we don't want to do it.  If we have
1360
1361     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1362                    ...other cases .... }
1363
1364 We'll perform the binder-swap for the outer case, giving
1365
1366     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1367                    ...other cases .... }
1368
1369 But there is no point in doing it for the inner case, because w1 can't
1370 be inlined anyway.  Furthermore, doing the case-swapping involves
1371 zapping w2's occurrence info (see paragraphs that follow), and that
1372 forces us to bind w2 when doing case merging.  So we get
1373
1374     case x of w1 { A -> let w2 = w1 in e1
1375                    B -> let w2 = w1 in e2
1376                    ...other cases .... }
1377
1378 This is plain silly in the common case where w2 is dead.
1379
1380 Even so, I can't see a good way to implement this idea.  I tried
1381 not doing the binder-swap if the scrutinee was already evaluated
1382 but that failed big-time:
1383
1384         data T = MkT !Int
1385
1386         case v of w  { MkT x ->
1387         case x of x1 { I# y1 ->
1388         case x of x2 { I# y2 -> ...
1389
1390 Notice that because MkT is strict, x is marked "evaluated".  But to
1391 eliminate the last case, we must either make sure that x (as well as
1392 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1393 the binder-swap.  So this whole note is a no-op.
1394
1395 Note 3
1396 ~~~~~~
1397 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1398 any occurrence info (eg IAmDead) in the case binder, because the
1399 case-binder now effectively occurs whenever v does.  AND we have to do
1400 the same for the pattern-bound variables!  Example:
1401
1402         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1403
1404 Here, b and p are dead.  But when we move the argment inside the first
1405 case RHS, and eliminate the second case, we get
1406
1407         case x of { (a,b) -> a b }
1408
1409 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1410 happened.
1411
1412 Indeed, this can happen anytime the case binder isn't dead:
1413         case <any> of x { (a,b) ->
1414         case x of { (p,q) -> p } }
1415 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1416 The point is that we bring into the envt a binding
1417         let x = (a,b)
1418 after the outer case, and that makes (a,b) alive.  At least we do unless
1419 the case binder is guaranteed dead.
1420
1421 \begin{code}
1422 simplCaseBinder env (Var v) case_bndr
1423   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
1424
1425 -- Failed try [see Note 2 above]
1426 --     not (isEvaldUnfolding (idUnfolding v))
1427
1428   = simplBinder env (zapOccInfo case_bndr)              `thenSmpl` \ (env, case_bndr') ->
1429     returnSmpl (modifyInScope env v case_bndr', case_bndr')
1430         -- We could extend the substitution instead, but it would be
1431         -- a hack because then the substitution wouldn't be idempotent
1432         -- any more (v is an OutId).  And this does just as well.
1433
1434 simplCaseBinder env other_scrut case_bndr
1435   = simplBinder env case_bndr           `thenSmpl` \ (env, case_bndr') ->
1436     returnSmpl (env, case_bndr')
1437
1438 zapOccInfo :: InId -> InId
1439 zapOccInfo b = b `setIdOccInfo` NoOccInfo
1440 \end{code}
1441
1442
1443 simplAlts does two things:
1444
1445 1.  Eliminate alternatives that cannot match, including the
1446     DEFAULT alternative.
1447
1448 2.  If the DEFAULT alternative can match only one possible constructor,
1449     then make that constructor explicit.
1450     e.g.
1451         case e of x { DEFAULT -> rhs }
1452      ===>
1453         case e of x { (a,b) -> rhs }
1454     where the type is a single constructor type.  This gives better code
1455     when rhs also scrutinises x or e.
1456
1457 Here "cannot match" includes knowledge from GADTs
1458
1459 It's a good idea do do this stuff before simplifying the alternatives, to
1460 avoid simplifying alternatives we know can't happen, and to come up with
1461 the list of constructors that are handled, to put into the IdInfo of the
1462 case binder, for use when simplifying the alternatives.
1463
1464 Eliminating the default alternative in (1) isn't so obvious, but it can
1465 happen:
1466
1467 data Colour = Red | Green | Blue
1468
1469 f x = case x of
1470         Red -> ..
1471         Green -> ..
1472         DEFAULT -> h x
1473
1474 h y = case y of
1475         Blue -> ..
1476         DEFAULT -> [ case y of ... ]
1477
1478 If we inline h into f, the default case of the inlined h can't happen.
1479 If we don't notice this, we may end up filtering out *all* the cases
1480 of the inner case y, which give us nowhere to go!
1481
1482
1483 \begin{code}
1484 simplAlts :: SimplEnv
1485           -> OutExpr
1486           -> OutId                      -- Case binder
1487           -> [InAlt] -> SimplCont
1488           -> SimplM [OutAlt]            -- Includes the continuation
1489
1490 simplAlts env scrut case_bndr' alts cont'
1491   = do  { mb_alts      <- mapSmpl (simplAlt env imposs_cons case_bndr' cont') alts_wo_default
1492         ; default_alts <- simplDefault env case_bndr' imposs_deflt_cons cont' maybe_deflt
1493         ; return (mergeAlts default_alts [alt' | Just (_, alt') <- mb_alts]) }
1494         -- We need the mergeAlts in case the new default_alt
1495         -- has turned into a constructor alternative.
1496   where
1497     (alts_wo_default, maybe_deflt) = findDefault alts
1498     imposs_cons = case scrut of
1499                     Var v -> otherCons (idUnfolding v)
1500                     other -> []
1501
1502         -- "imposs_deflt_cons" are handled either by the context,
1503         -- OR by a branch in this case expression. (Don't include DEFAULT!!)
1504     imposs_deflt_cons = nub (imposs_cons ++ [con | (con,_,_) <- alts_wo_default])
1505
1506 simplDefault :: SimplEnv
1507              -> OutId           -- Case binder; need just for its type. Note that as an
1508                                 --   OutId, it has maximum information; this is important.
1509                                 --   Test simpl013 is an example
1510              -> [AltCon]        -- These cons can't happen when matching the default
1511              -> SimplCont
1512              -> Maybe InExpr
1513              -> SimplM [OutAlt] -- One branch or none; we use a list because it's what
1514                                 --   mergeAlts expects
1515
1516
1517 simplDefault env case_bndr' imposs_cons cont Nothing
1518   = return []   -- No default branch
1519
1520 simplDefault env case_bndr' imposs_cons cont (Just rhs)
1521   |     -- This branch handles the case where we are
1522         -- scrutinisng an algebraic data type
1523     Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr'),
1524     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1525     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1526                                 --      case x of { DEFAULT -> e }
1527                                 -- and we don't want to fill in a default for them!
1528     Just all_cons <- tyConDataCons_maybe tycon,
1529     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1530                                 -- which GHC allows, then the case expression will have at most a default
1531                                 -- alternative.  We don't want to eliminate that alternative, because the
1532                                 -- invariant is that there's always one alternative.  It's more convenient
1533                                 -- to leave
1534                                 --      case x of { DEFAULT -> e }
1535                                 -- as it is, rather than transform it to
1536                                 --      error "case cant match"
1537                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1538                                 -- not worth wasting code on.
1539
1540     let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1541         poss_data_cons   = filterOut (`elem` imposs_data_cons) all_cons
1542         gadt_imposs      | all isTyVarTy inst_tys = []
1543                          | otherwise = filter (cant_match inst_tys) poss_data_cons
1544         final_poss       = filterOut (`elem` gadt_imposs) poss_data_cons
1545
1546   = case final_poss of
1547         []    -> returnSmpl []  -- Eliminate the default alternative
1548                                 -- altogether if it can't match
1549
1550         [con] ->        -- It matches exactly one constructor, so fill it in
1551                  do { tick (FillInCaseDefault case_bndr')
1552                     ; us <- getUniquesSmpl
1553                     ; let (ex_tvs, co_tvs, arg_ids) =
1554                               dataConRepInstPat us con inst_tys
1555                     ; let con_alt = (DataAlt con, ex_tvs ++ co_tvs ++ arg_ids, rhs)
1556                     ; Just (_, alt') <- simplAlt env [] case_bndr' cont con_alt
1557                         -- The simplAlt must succeed with Just because we have
1558                         -- already filtered out construtors that can't match
1559                     ; return [alt'] }
1560
1561         two_or_more -> simplify_default (map DataAlt gadt_imposs ++ imposs_cons)
1562
1563   | otherwise
1564   = simplify_default imposs_cons
1565   where
1566     cant_match tys data_con = not (dataConCanMatch data_con tys)
1567
1568     simplify_default imposs_cons
1569         = do { let env' = mk_rhs_env env case_bndr' (mkOtherCon imposs_cons)
1570                 -- Record the constructors that the case-binder *can't* be.
1571              ; rhs' <- simplExprC env' rhs cont
1572              ; return [(DEFAULT, [], rhs')] }
1573
1574 simplAlt :: SimplEnv
1575          -> [AltCon]    -- These constructors can't be present when
1576                         -- matching this alternative
1577          -> OutId       -- The case binder
1578          -> SimplCont
1579          -> InAlt
1580          -> SimplM (Maybe (TvSubstEnv, OutAlt))
1581
1582 -- Simplify an alternative, returning the type refinement for the
1583 -- alternative, if the alternative does any refinement at all
1584 -- Nothing => the alternative is inaccessible
1585
1586 simplAlt env imposs_cons case_bndr' cont' (con, bndrs, rhs)
1587   | con `elem` imposs_cons      -- This case can't match
1588   = return Nothing
1589
1590 simplAlt env handled_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1591         -- TURGID DUPLICATION, needed only for the simplAlt call
1592         -- in mkDupableAlt.  Clean this up when moving to FC
1593   = ASSERT( null bndrs )
1594     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1595     returnSmpl (Just (emptyVarEnv, (DEFAULT, [], rhs')))
1596   where
1597     env' = mk_rhs_env env case_bndr' (mkOtherCon handled_cons)
1598         -- Record the constructors that the case-binder *can't* be.
1599
1600 simplAlt env handled_cons case_bndr' cont' (LitAlt lit, bndrs, rhs)
1601   = ASSERT( null bndrs )
1602     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1603     returnSmpl (Just (emptyVarEnv, (LitAlt lit, [], rhs')))
1604   where
1605     env' = mk_rhs_env env case_bndr' (mkUnfolding False (Lit lit))
1606
1607 simplAlt env handled_cons case_bndr' cont' (DataAlt con, vs, rhs)
1608   =     -- Deal with the pattern-bound variables
1609         -- Mark the ones that are in ! positions in the data constructor
1610         -- as certainly-evaluated.
1611         -- NB: it happens that simplBinders does *not* erase the OtherCon
1612         --     form of unfolding, so it's ok to add this info before
1613         --     doing simplBinders
1614     simplBinders env (add_evals con vs)         `thenSmpl` \ (env, vs') ->
1615
1616                 -- Bind the case-binder to (con args)
1617     let unf       = mkUnfolding False (mkConApp con con_args)
1618         inst_tys' = tyConAppArgs (idType case_bndr')
1619         con_args  = map Type inst_tys' ++ varsToCoreExprs vs'
1620         env'      = mk_rhs_env env case_bndr' unf
1621     in
1622     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1623     returnSmpl (Just (emptyVarEnv, (DataAlt con, vs', rhs')))
1624   where
1625         -- add_evals records the evaluated-ness of the bound variables of
1626         -- a case pattern.  This is *important*.  Consider
1627         --      data T = T !Int !Int
1628         --
1629         --      case x of { T a b -> T (a+1) b }
1630         --
1631         -- We really must record that b is already evaluated so that we don't
1632         -- go and re-evaluate it when constructing the result.
1633     add_evals dc vs = cat_evals dc vs (dataConRepStrictness dc)
1634
1635     cat_evals dc vs strs
1636         = go vs strs
1637         where
1638           go [] [] = []
1639           go (v:vs) strs | isTyVar v = v : go vs strs
1640           go (v:vs) (str:strs)
1641             | isMarkedStrict str = evald_v  : go vs strs
1642             | otherwise          = zapped_v : go vs strs
1643             where
1644               zapped_v = zap_occ_info v
1645               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
1646           go _ _ = pprPanic "cat_evals" (ppr dc $$ ppr vs $$ ppr strs)
1647
1648         -- If the case binder is alive, then we add the unfolding
1649         --      case_bndr = C vs
1650         -- to the envt; so vs are now very much alive
1651         -- Note [Aug06] I can't see why this actually matters
1652     zap_occ_info | isDeadBinder case_bndr' = \id -> id
1653                  | otherwise               = zapOccInfo
1654
1655 mk_rhs_env env case_bndr' case_bndr_unf
1656   = modifyInScope env case_bndr' (case_bndr' `setIdUnfolding` case_bndr_unf)
1657 \end{code}
1658
1659
1660 %************************************************************************
1661 %*                                                                      *
1662 \subsection{Known constructor}
1663 %*                                                                      *
1664 %************************************************************************
1665
1666 We are a bit careful with occurrence info.  Here's an example
1667
1668         (\x* -> case x of (a*, b) -> f a) (h v, e)
1669
1670 where the * means "occurs once".  This effectively becomes
1671         case (h v, e) of (a*, b) -> f a)
1672 and then
1673         let a* = h v; b = e in f a
1674 and then
1675         f (h v)
1676
1677 All this should happen in one sweep.
1678
1679 \begin{code}
1680 knownCon :: SimplEnv -> OutExpr -> AltCon -> [OutExpr]
1681          -> InId -> [InAlt] -> SimplCont
1682          -> SimplM FloatsWithExpr
1683
1684 knownCon env scrut con args bndr alts cont
1685   = tick (KnownBranch bndr)             `thenSmpl_`
1686     case findAlt con alts of
1687         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1688                                   simplNonRecX env bndr scrut   $ \ env ->
1689                                 -- This might give rise to a binding with non-atomic args
1690                                 -- like x = Node (f x) (g x)
1691                                 -- but simplNonRecX will atomic-ify it
1692                                   simplExprF env rhs cont
1693
1694         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1695                                   simplNonRecX env bndr scrut   $ \ env ->
1696                                   simplExprF env rhs cont
1697
1698         (DataAlt dc, bs, rhs)
1699                 -> -- ASSERT( n_drop_tys + length bs == length args )
1700                    bind_args env dead_bndr bs (drop n_drop_tys args)    $ \ env ->
1701                    let
1702                         -- It's useful to bind bndr to scrut, rather than to a fresh
1703                         -- binding      x = Con arg1 .. argn
1704                         -- because very often the scrut is a variable, so we avoid
1705                         -- creating, and then subsequently eliminating, a let-binding
1706                         -- BUT, if scrut is a not a variable, we must be careful
1707                         -- about duplicating the arg redexes; in that case, make
1708                         -- a new con-app from the args
1709                         bndr_rhs  = case scrut of
1710                                         Var v -> scrut
1711                                         other -> con_app
1712                         con_app = mkConApp dc (take n_drop_tys args ++ con_args)
1713                         con_args = [substExpr env (varToCoreExpr b) | b <- bs]
1714                                         -- args are aready OutExprs, but bs are InIds
1715                    in
1716                    simplNonRecX env bndr bndr_rhs               $ \ env ->
1717                    simplExprF env rhs cont
1718                 where
1719                    dead_bndr  = isDeadBinder bndr
1720                    n_drop_tys = tyConArity (dataConTyCon dc)
1721
1722 -- Ugh!
1723 bind_args env dead_bndr [] _ thing_inside = thing_inside env
1724
1725 bind_args env dead_bndr (b:bs) (Type ty : args) thing_inside
1726   = ASSERT( isTyVar b )
1727     bind_args (extendTvSubst env b ty) dead_bndr bs args thing_inside
1728
1729 bind_args env dead_bndr (b:bs) (arg : args) thing_inside
1730   = ASSERT( isId b )
1731     let
1732         b' = if dead_bndr then b else zapOccInfo b
1733                 -- Note that the binder might be "dead", because it doesn't occur
1734                 -- in the RHS; and simplNonRecX may therefore discard it via postInlineUnconditionally
1735                 -- Nevertheless we must keep it if the case-binder is alive, because it may
1736                 -- be used in teh con_app
1737     in
1738     simplNonRecX env b' arg     $ \ env ->
1739     bind_args env dead_bndr bs args thing_inside
1740 \end{code}
1741
1742
1743 %************************************************************************
1744 %*                                                                      *
1745 \subsection{Duplicating continuations}
1746 %*                                                                      *
1747 %************************************************************************
1748
1749 \begin{code}
1750 prepareCaseCont :: SimplEnv
1751                 -> [InAlt] -> SimplCont
1752                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1753                         -- Return a duplicatable continuation, a non-duplicable part
1754                         -- plus some extra bindings (that scope over the entire
1755                         -- continunation)
1756
1757         -- No need to make it duplicatable if there's only one alternative
1758 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1759 prepareCaseCont env alts  cont = mkDupableCont env cont
1760 \end{code}
1761
1762 \begin{code}
1763 mkDupableCont :: SimplEnv -> SimplCont
1764               -> SimplM (FloatsWith (SimplCont, SimplCont))
1765
1766 mkDupableCont env cont
1767   | contIsDupable cont
1768   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1769
1770 mkDupableCont env (CoerceIt ty cont)
1771   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1772     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1773
1774 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1775   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1776         -- Do *not* duplicate an ArgOf continuation
1777         -- Because ArgOf continuations are opaque, we gain nothing by
1778         -- propagating them into the expressions, and we do lose a lot.
1779         -- Here's an example:
1780         --      && (case x of { T -> F; F -> T }) E
1781         -- Now, && is strict so we end up simplifying the case with
1782         -- an ArgOf continuation.  If we let-bind it, we get
1783         --
1784         --      let $j = \v -> && v E
1785         --      in simplExpr (case x of { T -> F; F -> T })
1786         --                   (ArgOf (\r -> $j r)
1787         -- And after simplifying more we get
1788         --
1789         --      let $j = \v -> && v E
1790         --      in case of { T -> $j F; F -> $j T }
1791         -- Which is a Very Bad Thing
1792         --
1793         -- The desire not to duplicate is the entire reason that
1794         -- mkDupableCont returns a pair of continuations.
1795         --
1796         -- The original plan had:
1797         -- e.g.         (...strict-fn...) [...hole...]
1798         --      ==>
1799         --              let $j = \a -> ...strict-fn...
1800         --              in $j [...hole...]
1801
1802 mkDupableCont env (ApplyTo _ arg mb_se cont)
1803   =     -- e.g.         [...hole...] (...arg...)
1804         --      ==>
1805         --              let a = ...arg...
1806         --              in [...hole...] a
1807     do  { (floats, (dup_cont, nondup_cont)) <- mkDupableCont env cont
1808         ; addFloats env floats $ \ env -> do
1809         { arg1 <- simplArg env arg mb_se
1810         ; (floats2, arg2) <- mkDupableArg env arg1
1811         ; return (floats2, (ApplyTo OkToDup arg2 Nothing dup_cont, nondup_cont)) }}
1812
1813 mkDupableCont env cont@(Select _ case_bndr [(_,bs,rhs)] se case_cont)
1814 --   | not (exprIsDupable rhs && contIsDupable case_cont)       -- See notes below
1815 --  | not (isDeadBinder case_bndr)
1816   | all isDeadBinder bs
1817   = returnSmpl (emptyFloats env, (mkBoringStop scrut_ty, cont))
1818   where
1819     scrut_ty = substTy se (idType case_bndr)
1820
1821 {-      Note [Single-alternative cases]
1822         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1823 This case is just like the ArgOf case.  Here's an example:
1824         data T a = MkT !a
1825         ...(MkT (abs x))...
1826 Then we get
1827         case (case x of I# x' ->
1828               case x' <# 0# of
1829                 True  -> I# (negate# x')
1830                 False -> I# x') of y {
1831           DEFAULT -> MkT y
1832 Because the (case x) has only one alternative, we'll transform to
1833         case x of I# x' ->
1834         case (case x' <# 0# of
1835                 True  -> I# (negate# x')
1836                 False -> I# x') of y {
1837           DEFAULT -> MkT y
1838 But now we do *NOT* want to make a join point etc, giving
1839         case x of I# x' ->
1840         let $j = \y -> MkT y
1841         in case x' <# 0# of
1842                 True  -> $j (I# (negate# x'))
1843                 False -> $j (I# x')
1844 In this case the $j will inline again, but suppose there was a big
1845 strict computation enclosing the orginal call to MkT.  Then, it won't
1846 "see" the MkT any more, because it's big and won't get duplicated.
1847 And, what is worse, nothing was gained by the case-of-case transform.
1848
1849 When should use this case of mkDupableCont?
1850 However, matching on *any* single-alternative case is a *disaster*;
1851   e.g.  case (case ....) of (a,b) -> (# a,b #)
1852   We must push the outer case into the inner one!
1853 Other choices:
1854
1855    * Match [(DEFAULT,_,_)], but in the common case of Int,
1856      the alternative-filling-in code turned the outer case into
1857                 case (...) of y { I# _ -> MkT y }
1858
1859    * Match on single alternative plus (not (isDeadBinder case_bndr))
1860      Rationale: pushing the case inwards won't eliminate the construction.
1861      But there's a risk of
1862                 case (...) of y { (a,b) -> let z=(a,b) in ... }
1863      Now y looks dead, but it'll come alive again.  Still, this
1864      seems like the best option at the moment.
1865
1866    * Match on single alternative plus (all (isDeadBinder bndrs))
1867      Rationale: this is essentially  seq.
1868
1869    * Match when the rhs is *not* duplicable, and hence would lead to a
1870      join point.  This catches the disaster-case above.  We can test
1871      the *un-simplified* rhs, which is fine.  It might get bigger or
1872      smaller after simplification; if it gets smaller, this case might
1873      fire next time round.  NB also that we must test contIsDupable
1874      case_cont *btoo, because case_cont might be big!
1875
1876      HOWEVER: I found that this version doesn't work well, because
1877      we can get         let x = case (...) of { small } in ...case x...
1878      When x is inlined into its full context, we find that it was a bad
1879      idea to have pushed the outer case inside the (...) case.
1880 -}
1881
1882 mkDupableCont env (Select _ case_bndr alts se cont)
1883   =     -- e.g.         (case [...hole...] of { pi -> ei })
1884         --      ===>
1885         --              let ji = \xij -> ei
1886         --              in case [...hole...] of { pi -> ji xij }
1887     do  { tick (CaseOfCase case_bndr)
1888         ; let alt_env = setInScope se env
1889         ; (floats1, (dup_cont, nondup_cont)) <- mkDupableCont alt_env cont
1890                 -- NB: call mkDupableCont here, *not* prepareCaseCont
1891                 -- We must make a duplicable continuation, whereas prepareCaseCont
1892                 -- doesn't when there is a single case branch
1893         ; addFloats alt_env floats1     $ \ alt_env -> do
1894
1895         { (alt_env, case_bndr') <- simplBinder alt_env case_bndr
1896                 -- NB: simplBinder does not zap deadness occ-info, so
1897                 -- a dead case_bndr' will still advertise its deadness
1898                 -- This is really important because in
1899                 --      case e of b { (# a,b #) -> ... }
1900                 -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1901                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1902                 -- In the new alts we build, we have the new case binder, so it must retain
1903                 -- its deadness.
1904
1905         ; (floats2, alts') <- mkDupableAlts alt_env case_bndr' alts dup_cont
1906         ; return (floats2, (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1907                                    (mkBoringStop (contResultType dup_cont)),
1908                             nondup_cont))
1909         }}
1910
1911 mkDupableArg :: SimplEnv -> OutExpr -> SimplM (FloatsWith OutExpr)
1912 -- Let-bind the thing if necessary
1913 mkDupableArg env arg
1914   | exprIsDupable arg
1915   = return (emptyFloats env, arg)
1916   | otherwise
1917   = do  { arg_id <- newId FSLIT("a") (exprType arg)
1918         ; tick (CaseOfCase arg_id)
1919                 -- Want to tick here so that we go round again,
1920                 -- and maybe copy or inline the code.
1921                 -- Not strictly CaseOfCase, but never mind
1922         ; return (unitFloat env arg_id arg, Var arg_id) }
1923         -- What if the arg should be case-bound?
1924         -- This has been this way for a long time, so I'll leave it,
1925         -- but I can't convince myself that it's right.
1926
1927 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1928               -> SimplM (FloatsWith [InAlt])
1929 -- Absorbs the continuation into the new alternatives
1930
1931 mkDupableAlts env case_bndr' alts dupable_cont
1932   = go env alts
1933   where
1934     go env [] = returnSmpl (emptyFloats env, [])
1935     go env (alt:alts)
1936         = do { (floats1, mb_alt') <- mkDupableAlt env case_bndr' dupable_cont alt
1937              ; addFloats env floats1    $ \ env -> do
1938              { (floats2, alts') <- go env alts
1939              ; returnSmpl (floats2, case mb_alt' of
1940                                         Just alt' -> alt' : alts'
1941                                         Nothing   -> alts'
1942                           )}}
1943
1944 mkDupableAlt env case_bndr' cont alt
1945   = simplAlt env [] case_bndr' cont alt         `thenSmpl` \ mb_stuff ->
1946     case mb_stuff of {
1947         Nothing -> returnSmpl (emptyFloats env, Nothing) ;
1948
1949         Just (reft, (con, bndrs', rhs')) ->
1950         -- Safe to say that there are no handled-cons for the DEFAULT case
1951
1952     if exprIsDupable rhs' then
1953         returnSmpl (emptyFloats env, Just (con, bndrs', rhs'))
1954         -- It is worth checking for a small RHS because otherwise we
1955         -- get extra let bindings that may cause an extra iteration of the simplifier to
1956         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1957         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1958         -- iterations because the version with the let bindings looked big, and so wasn't
1959         -- inlined, but after the join points had been inlined it looked smaller, and so
1960         -- was inlined.
1961         --
1962         -- NB: we have to check the size of rhs', not rhs.
1963         -- Duplicating a small InAlt might invalidate occurrence information
1964         -- However, if it *is* dupable, we return the *un* simplified alternative,
1965         -- because otherwise we'd need to pair it up with an empty subst-env....
1966         -- but we only have one env shared between all the alts.
1967         -- (Remember we must zap the subst-env before re-simplifying something).
1968         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1969
1970     else
1971     let
1972         rhs_ty'     = exprType rhs'
1973         used_bndrs' = filter abstract_over (case_bndr' : bndrs')
1974         abstract_over bndr
1975           | isTyVar bndr = not (bndr `elemVarEnv` reft)
1976                 -- Don't abstract over tyvar binders which are refined away
1977                 -- See Note [Refinement] below
1978           | otherwise    = not (isDeadBinder bndr)
1979                 -- The deadness info on the new Ids is preserved by simplBinders
1980     in
1981         -- If we try to lift a primitive-typed something out
1982         -- for let-binding-purposes, we will *caseify* it (!),
1983         -- with potentially-disastrous strictness results.  So
1984         -- instead we turn it into a function: \v -> e
1985         -- where v::State# RealWorld#.  The value passed to this function
1986         -- is realworld#, which generates (almost) no code.
1987
1988         -- There's a slight infelicity here: we pass the overall
1989         -- case_bndr to all the join points if it's used in *any* RHS,
1990         -- because we don't know its usage in each RHS separately
1991
1992         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1993         -- we make the join point into a function whenever used_bndrs'
1994         -- is empty.  This makes the join-point more CPR friendly.
1995         -- Consider:    let j = if .. then I# 3 else I# 4
1996         --              in case .. of { A -> j; B -> j; C -> ... }
1997         --
1998         -- Now CPR doesn't w/w j because it's a thunk, so
1999         -- that means that the enclosing function can't w/w either,
2000         -- which is a lose.  Here's the example that happened in practice:
2001         --      kgmod :: Int -> Int -> Int
2002         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2003         --                  then 78
2004         --                  else 5
2005         --
2006         -- I have seen a case alternative like this:
2007         --      True -> \v -> ...
2008         -- It's a bit silly to add the realWorld dummy arg in this case, making
2009         --      $j = \s v -> ...
2010         --         True -> $j s
2011         -- (the \v alone is enough to make CPR happy) but I think it's rare
2012
2013     ( if not (any isId used_bndrs')
2014         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
2015              returnSmpl ([rw_id], [Var realWorldPrimId])
2016         else
2017              returnSmpl (used_bndrs', varsToCoreExprs used_bndrs')
2018     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
2019
2020         -- See comment about "$j" name above
2021     newId FSLIT("$j") (mkPiTypes final_bndrs' rhs_ty')  `thenSmpl` \ join_bndr ->
2022         -- Notice the funky mkPiTypes.  If the contructor has existentials
2023         -- it's possible that the join point will be abstracted over
2024         -- type varaibles as well as term variables.
2025         --  Example:  Suppose we have
2026         --      data T = forall t.  C [t]
2027         --  Then faced with
2028         --      case (case e of ...) of
2029         --          C t xs::[t] -> rhs
2030         --  We get the join point
2031         --      let j :: forall t. [t] -> ...
2032         --          j = /\t \xs::[t] -> rhs
2033         --      in
2034         --      case (case e of ...) of
2035         --          C t xs::[t] -> j t xs
2036     let
2037         -- We make the lambdas into one-shot-lambdas.  The
2038         -- join point is sure to be applied at most once, and doing so
2039         -- prevents the body of the join point being floated out by
2040         -- the full laziness pass
2041         really_final_bndrs     = map one_shot final_bndrs'
2042         one_shot v | isId v    = setOneShotLambda v
2043                    | otherwise = v
2044         join_rhs  = mkLams really_final_bndrs rhs'
2045         join_call = mkApps (Var join_bndr) final_args
2046     in
2047     returnSmpl (unitFloat env join_bndr join_rhs, Just (con, bndrs', join_call)) }
2048 \end{code}
2049
2050 Note [Refinement]
2051 ~~~~~~~~~~~~~~~~~
2052 Consider
2053         data T a where
2054           MkT :: a -> b -> T a
2055
2056         f = /\a. \(w::a).
2057            case (case ...) of
2058                   MkT a' b (p::a') (q::b) -> [p,w]
2059
2060 The danger is that we'll make a join point
2061
2062         j a' p = [p,w]
2063
2064 and that's ill-typed, because (p::a') but (w::a).
2065
2066 Solution so far: don't abstract over a', because the type refinement
2067 maps [a' -> a] .  Ultimately that won't work when real refinement goes on.
2068
2069 Then we must abstract over any refined free variables.  Hmm.  Maybe we
2070 could just abstract over *all* free variables, thereby lambda-lifting
2071 the join point?   We should try this.