compiler/specialise/Rules.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[CoreRules]{Transformation rules}
   5
   6 \begin{code}
   7 module Rules (
   8         RuleBase, emptyRuleBase, mkRuleBase, extendRuleBaseList,
   9         unionRuleBase, pprRuleBase, ruleCheckProgram,
  10
  11         mkSpecInfo, extendSpecInfo, addSpecInfo,
  12         rulesOfBinds, addIdSpecialisations,
  13
  14         matchN,
  15
  16         lookupRule, mkLocalRule, roughTopNames
  17     ) where
  18
  19 #include "HsVersions.h"
  20
  21 import CoreSyn          -- All of it
  22 import OccurAnal        ( occurAnalyseExpr )
  23 import CoreFVs          ( exprFreeVars, exprsFreeVars, bindFreeVars, rulesRhsFreeVars )
  24 import CoreUnfold       ( isCheapUnfolding, unfoldingTemplate )
  25 import CoreUtils        ( tcEqExprX )
  26 import PprCore          ( pprRules )
  27 import Type             ( TvSubstEnv )
  28 import Coercion         ( coercionKind )
  29 import TcType           ( tcSplitTyConApp_maybe )
  30 import CoreTidy         ( tidyRules )
  31 import Id               ( Id, idUnfolding, isLocalId, isGlobalId, idName,
  32                           idSpecialisation, idCoreRules, setIdSpecialisation )
  33 import IdInfo           ( SpecInfo( SpecInfo ) )
  34 import Var              ( Var )
  35 import VarEnv           ( IdEnv, InScopeSet, emptyTidyEnv,
  36                           emptyInScopeSet, mkInScopeSet,
  37                           emptyVarEnv, lookupVarEnv, extendVarEnv,
  38                           nukeRnEnvL, mkRnEnv2, rnOccR, rnOccL, inRnEnvR,
  39                           rnBndrR, rnBndr2, rnBndrL, rnBndrs2,
  40                           rnInScope, extendRnInScopeList, lookupRnInScope )
  41 import VarSet
  42 import Name             ( Name, NamedThing(..), nameOccName )
  43 import NameEnv
  44 import Unify            ( ruleMatchTyX, MatchEnv(..) )
  45 import BasicTypes       ( Activation, CompilerPhase, isActive )
  46 import Outputable
  47 import FastString
  48 import Maybes
  49 import OrdList
  50 import Bag
  51 import Util
  52 import List hiding( mapAccumL ) -- Also defined in Util
  53 \end{code}
  54
  55
  56 %************************************************************************
  57 %*                                                                      *
  58 \subsection[specialisation-IdInfo]{Specialisation info about an @Id@}
  59 %*                                                                      *
  60 %************************************************************************
  61
  62 A @CoreRule@ holds details of one rule for an @Id@, which
  63 includes its specialisations.
  64
  65 For example, if a rule for @f@ contains the mapping:
  66 \begin{verbatim}
  67         forall a b d. [Type (List a), Type b, Var d]  ===>  f' a b
  68 \end{verbatim}
  69 then when we find an application of f to matching types, we simply replace
  70 it by the matching RHS:
  71 \begin{verbatim}
  72         f (List Int) Bool dict ===>  f' Int Bool
  73 \end{verbatim}
  74 All the stuff about how many dictionaries to discard, and what types
  75 to apply the specialised function to, are handled by the fact that the
  76 Rule contains a template for the result of the specialisation.
  77
  78 There is one more exciting case, which is dealt with in exactly the same
  79 way.  If the specialised value is unboxed then it is lifted at its
  80 definition site and unlifted at its uses.  For example:
  81
  82         pi :: forall a. Num a => a
  83
  84 might have a specialisation
  85
  86         [Int#] ===>  (case pi' of Lift pi# -> pi#)
  87
  88 where pi' :: Lift Int# is the specialised version of pi.
  89
  90 \begin{code}
  91 mkLocalRule :: RuleName -> Activation
  92             -> Name -> [CoreBndr] -> [CoreExpr] -> CoreExpr -> CoreRule
  93 -- Used to make CoreRule for an Id defined in this module
  94 mkLocalRule name act fn bndrs args rhs
  95   = Rule { ru_name = name, ru_fn = fn, ru_act = act,
  96            ru_bndrs = bndrs, ru_args = args,
  97            ru_rhs = rhs, ru_rough = roughTopNames args,
  98            ru_orph = Just (nameOccName fn), ru_local = True }
  99
 100 --------------
 101 roughTopNames :: [CoreExpr] -> [Maybe Name]
 102 roughTopNames args = map roughTopName args
 103
 104 roughTopName :: CoreExpr -> Maybe Name
 105 -- Find the "top" free name of an expression
 106 -- a) the function in an App chain (if a GlobalId)
 107 -- b) the TyCon in a type
 108 -- This is used for the fast-match-check for rules;
 109 --      if the top names don't match, the rest can't
 110 roughTopName (Type ty) = case tcSplitTyConApp_maybe ty of
 111                           Just (tc,_) -> Just (getName tc)
 112                           Nothing     -> Nothing
 113 roughTopName (App f a) = roughTopName f
 114 roughTopName (Var f) | isGlobalId f = Just (idName f)
 115                      | otherwise    = Nothing
 116 roughTopName other = Nothing
 117
 118 ruleCantMatch :: [Maybe Name] -> [Maybe Name] -> Bool
 119 -- (ruleCantMatch tpl actual) returns True only if 'actual'
 120 -- definitely can't match 'tpl' by instantiating 'tpl'.
 121 -- It's only a one-way match; unlike instance matching we
 122 -- don't consider unification
 123 --
 124 -- Notice that there is no case
 125 --      ruleCantMatch (Just n1 : ts) (Nothing : as) = True
 126 -- Reason: a local variable 'v' in the actuals might
 127 --         have an unfolding which is a global.
 128 --         This quite often happens with case scrutinees.
 129 ruleCantMatch (Just n1 : ts) (Just n2 : as) = n1 /= n2 || ruleCantMatch ts as
 130 ruleCantMatch (t       : ts) (a       : as) = ruleCantMatch ts as
 131 ruleCantMatch ts             as             = False
 132 \end{code}
 133
 134
 135 %************************************************************************
 136 %*                                                                      *
 137                 SpecInfo: the rules in an IdInfo
 138 %*                                                                      *
 139 %************************************************************************
 140
 141 \begin{code}
 142 mkSpecInfo :: [CoreRule] -> SpecInfo
 143 mkSpecInfo rules = SpecInfo rules (rulesRhsFreeVars rules)
 144
 145 extendSpecInfo :: SpecInfo -> [CoreRule] -> SpecInfo
 146 extendSpecInfo (SpecInfo rs1 fvs1) rs2
 147   = SpecInfo (rs2 ++ rs1) (rulesRhsFreeVars rs2 `unionVarSet` fvs1)
 148
 149 addSpecInfo :: SpecInfo -> SpecInfo -> SpecInfo
 150 addSpecInfo (SpecInfo rs1 fvs1) (SpecInfo rs2 fvs2)
 151   = SpecInfo (rs1 ++ rs2) (fvs1 `unionVarSet` fvs2)
 152
 153 addIdSpecialisations :: Id -> [CoreRule] -> Id
 154 addIdSpecialisations id rules
 155   = setIdSpecialisation id $
 156     extendSpecInfo (idSpecialisation id) rules
 157
 158 rulesOfBinds :: [CoreBind] -> [CoreRule]
 159 rulesOfBinds binds = concatMap (concatMap idCoreRules . bindersOf) binds
 160 \end{code}
 161
 162
 163 %************************************************************************
 164 %*                                                                      *
 165                 RuleBase
 166 %*                                                                      *
 167 %************************************************************************
 168
 169 \begin{code}
 170 type RuleBase = NameEnv [CoreRule]
 171         -- Maps (the name of) an Id to its rules
 172         -- The rules are are unordered;
 173         -- we sort out any overlaps on lookup
 174
 175 emptyRuleBase = emptyNameEnv
 176
 177 mkRuleBase :: [CoreRule] -> RuleBase
 178 mkRuleBase rules = extendRuleBaseList emptyRuleBase rules
 179
 180 extendRuleBaseList :: RuleBase -> [CoreRule] -> RuleBase
 181 extendRuleBaseList rule_base new_guys
 182   = foldl extendRuleBase rule_base new_guys
 183
 184 unionRuleBase :: RuleBase -> RuleBase -> RuleBase
 185 unionRuleBase rb1 rb2 = plusNameEnv_C (++) rb1 rb2
 186
 187 extendRuleBase :: RuleBase -> CoreRule -> RuleBase
 188 extendRuleBase rule_base rule
 189   = extendNameEnv_Acc (:) singleton rule_base (ruleIdName rule) rule
 190
 191 pprRuleBase :: RuleBase -> SDoc
 192 pprRuleBase rules = vcat [ pprRules (tidyRules emptyTidyEnv rs)
 193                          | rs <- nameEnvElts rules ]
 194 \end{code}
 195
 196
 197 %************************************************************************
 198 %*                                                                      *
 199 \subsection{Matching}
 200 %*                                                                      *
 201 %************************************************************************
 202
 203 \begin{code}
 204 lookupRule :: (Activation -> Bool) -> InScopeSet
 205            -> RuleBase  -- Imported rules
 206            -> Id -> [CoreExpr] -> Maybe (CoreRule, CoreExpr)
 207 lookupRule is_active in_scope rule_base fn args
 208   = matchRules is_active in_scope fn args rules
 209   where
 210         -- The rules for an Id come from two places:
 211         --      (a) the ones it is born with (idCoreRules fn)
 212         --      (b) rules added in subsequent modules (extra_rules)
 213         -- PrimOps, for example, are born with a bunch of rules under (a)
 214     rules = extra_rules ++ idCoreRules fn
 215     extra_rules | isLocalId fn = []
 216                 | otherwise    = lookupNameEnv rule_base (idName fn) `orElse` []
 217
 218 matchRules :: (Activation -> Bool) -> InScopeSet
 219            -> Id -> [CoreExpr]
 220            -> [CoreRule] -> Maybe (CoreRule, CoreExpr)
 221 -- See comments on matchRule
 222 matchRules is_active in_scope fn args rules
 223   = -- pprTrace "matchRules" (ppr fn <+> ppr rules) $
 224     case go [] rules of
 225         []     -> Nothing
 226         (m:ms) -> Just (findBest (fn,args) m ms)
 227   where
 228     rough_args = map roughTopName args
 229
 230     go :: [(CoreRule,CoreExpr)] -> [CoreRule] -> [(CoreRule,CoreExpr)]
 231     go ms []           = ms
 232     go ms (r:rs) = case (matchRule is_active in_scope args rough_args r) of
 233                         Just e  -> go ((r,e):ms) rs
 234                         Nothing -> -- pprTrace "match failed" (ppr r $$ ppr args $$
 235                                    --   ppr [(arg_id, unfoldingTemplate unf) | Var arg_id <- args, let unf = idUnfolding arg_id, isCheapUnfolding unf] )
 236                                    go ms         rs
 237
 238 findBest :: (Id, [CoreExpr])
 239          -> (CoreRule,CoreExpr) -> [(CoreRule,CoreExpr)] -> (CoreRule,CoreExpr)
 240 -- All these pairs matched the expression
 241 -- Return the pair the the most specific rule
 242 -- The (fn,args) is just for overlap reporting
 243
 244 findBest target (rule,ans)   [] = (rule,ans)
 245 findBest target (rule1,ans1) ((rule2,ans2):prs)
 246   | rule1 `isMoreSpecific` rule2 = findBest target (rule1,ans1) prs
 247   | rule2 `isMoreSpecific` rule1 = findBest target (rule2,ans2) prs
 248 #ifdef DEBUG
 249   | otherwise = pprTrace "Rules.findBest: rule overlap (Rule 1 wins)"
 250                          (vcat [ptext SLIT("Expression to match:") <+> ppr fn <+> sep (map ppr args),
 251                                 ptext SLIT("Rule 1:") <+> ppr rule1,
 252                                 ptext SLIT("Rule 2:") <+> ppr rule2]) $
 253                 findBest target (rule1,ans1) prs
 254 #else
 255   | otherwise = findBest target (rule1,ans1) prs
 256 #endif
 257   where
 258     (fn,args) = target
 259
 260 isMoreSpecific :: CoreRule -> CoreRule -> Bool
 261 isMoreSpecific (BuiltinRule {}) r2 = True
 262 isMoreSpecific r1 (BuiltinRule {}) = False
 263 isMoreSpecific (Rule { ru_bndrs = bndrs1, ru_args = args1 })
 264                (Rule { ru_bndrs = bndrs2, ru_args = args2 })
 265   = isJust (matchN in_scope bndrs2 args2 args1)
 266   where
 267    in_scope = mkInScopeSet (mkVarSet bndrs1)
 268         -- Actually we should probably include the free vars
 269         -- of rule1's args, but I can't be bothered
 270
 271 noBlackList :: Activation -> Bool
 272 noBlackList act = False         -- Nothing is black listed
 273
 274 matchRule :: (Activation -> Bool) -> InScopeSet
 275           -> [CoreExpr] -> [Maybe Name]
 276           -> CoreRule -> Maybe CoreExpr
 277
 278 -- If (matchRule rule args) returns Just (name,rhs)
 279 -- then (f args) matches the rule, and the corresponding
 280 -- rewritten RHS is rhs
 281 --
 282 -- The bndrs and rhs is occurrence-analysed
 283 --
 284 --      Example
 285 --
 286 -- The rule
 287 --      forall f g x. map f (map g x) ==> map (f . g) x
 288 -- is stored
 289 --      CoreRule "map/map"
 290 --               [f,g,x]                -- tpl_vars
 291 --               [f,map g x]            -- tpl_args
 292 --               map (f.g) x)           -- rhs
 293 --
 294 -- Then the call: matchRule the_rule [e1,map e2 e3]
 295 --        = Just ("map/map", (\f,g,x -> rhs) e1 e2 e3)
 296 --
 297 -- Any 'surplus' arguments in the input are simply put on the end
 298 -- of the output.
 299
 300 matchRule is_active in_scope args rough_args
 301           (BuiltinRule { ru_name = name, ru_try = match_fn })
 302   = case match_fn args of
 303         Just expr -> Just expr
 304         Nothing   -> Nothing
 305
 306 matchRule is_active in_scope args rough_args
 307           (Rule { ru_name = rn, ru_act = act, ru_rough = tpl_tops,
 308                   ru_bndrs = tpl_vars, ru_args = tpl_args,
 309                   ru_rhs = rhs })
 310   | not (is_active act)               = Nothing
 311   | ruleCantMatch tpl_tops rough_args = Nothing
 312   | otherwise
 313   = case matchN in_scope tpl_vars tpl_args args of
 314         Nothing                -> Nothing
 315         Just (binds, tpl_vals) -> Just (mkLets binds $
 316                                         rule_fn `mkApps` tpl_vals)
 317   where
 318     rule_fn = occurAnalyseExpr (mkLams tpl_vars rhs)
 319         -- We could do this when putting things into the rulebase, I guess
 320 \end{code}
 321
 322 \begin{code}
 323 matchN  :: InScopeSet
 324         -> [Var]                -- Template tyvars
 325         -> [CoreExpr]           -- Template
 326         -> [CoreExpr]           -- Target; can have more elts than template
 327         -> Maybe ([CoreBind],   -- Bindings to wrap around the entire result
 328                   [CoreExpr])   -- What is substituted for each template var
 329
 330 matchN in_scope tmpl_vars tmpl_es target_es
 331   = do  { (tv_subst, id_subst, binds)
 332                 <- go init_menv emptySubstEnv tmpl_es target_es
 333         ; return (fromOL binds,
 334                   map (lookup_tmpl tv_subst id_subst) tmpl_vars') }
 335   where
 336     (init_rn_env, tmpl_vars') = mapAccumL rnBndrL (mkRnEnv2 in_scope) tmpl_vars
 337         -- See Note [Template binders]
 338
 339     init_menv = ME { me_tmpls = mkVarSet tmpl_vars', me_env = init_rn_env }
 340
 341     go menv subst []     es     = Just subst
 342     go menv subst ts     []     = Nothing       -- Fail if too few actual args
 343     go menv subst (t:ts) (e:es) = do { subst1 <- match menv subst t e
 344                                      ; go menv subst1 ts es }
 345
 346     lookup_tmpl :: TvSubstEnv -> IdSubstEnv -> Var -> CoreExpr
 347     lookup_tmpl tv_subst id_subst tmpl_var'
 348         | isTyVar tmpl_var' = case lookupVarEnv tv_subst tmpl_var' of
 349                                 Just ty         -> Type ty
 350                                 Nothing         -> unbound tmpl_var'
 351         | otherwise         = case lookupVarEnv id_subst tmpl_var' of
 352                                 Just e -> e
 353                                 other  -> unbound tmpl_var'
 354
 355     unbound var = pprPanic "Template variable unbound in rewrite rule" (ppr var)
 356 \end{code}
 357
 358 Note [Template binders]
 359 ~~~~~~~~~~~~~~~~~~~~~~~
 360 Consider the following match:
 361         Template:  forall x.  f x
 362         Taret:     f (x+1)
 363 This should succeed, because the template variable 'x' has nothing to do with
 364 the 'x' in the target.
 365
 366 To achive this, we use rnBndrL to rename the template variables if necessary;
 367 the renamed ones are the tmpl_vars'
 368
 369
 370         ---------------------------------------------
 371                 The inner workings of matching
 372         ---------------------------------------------
 373
 374 \begin{code}
 375 -- These two definitions are not the same as in Subst,
 376 -- but they simple and direct, and purely local to this module
 377 --
 378 -- * The domain of the TvSubstEnv and IdSubstEnv are the template
 379 --   variables passed into the match.
 380 --
 381 -- * The (OrdList CoreBind) in a SubstEnv are the bindings floated out
 382 --   from nested matches; see the Let case of match, below
 383 --
 384 type SubstEnv   = (TvSubstEnv, IdSubstEnv, OrdList CoreBind)
 385 type IdSubstEnv = IdEnv CoreExpr
 386
 387 emptySubstEnv :: SubstEnv
 388 emptySubstEnv = (emptyVarEnv, emptyVarEnv, nilOL)
 389
 390
 391 --      At one stage I tried to match even if there are more
 392 --      template args than real args.
 393
 394 --      I now think this is probably a bad idea.
 395 --      Should the template (map f xs) match (map g)?  I think not.
 396 --      For a start, in general eta expansion wastes work.
 397 --      SLPJ July 99
 398
 399
 400 match :: MatchEnv
 401       -> SubstEnv
 402       -> CoreExpr               -- Template
 403       -> CoreExpr               -- Target
 404       -> Maybe SubstEnv
 405
 406 -- See the notes with Unify.match, which matches types
 407 -- Everything is very similar for terms
 408
 409 -- Interesting examples:
 410 -- Consider matching
 411 --      \x->f      against    \f->f
 412 -- When we meet the lambdas we must remember to rename f to f' in the
 413 -- second expresion.  The RnEnv2 does that.
 414 --
 415 -- Consider matching
 416 --      forall a. \b->b    against   \a->3
 417 -- We must rename the \a.  Otherwise when we meet the lambdas we
 418 -- might substitute [a/b] in the template, and then erroneously
 419 -- succeed in matching what looks like the template variable 'a' against 3.
 420
 421 -- The Var case follows closely what happens in Unify.match
 422 match menv subst (Var v1) e2
 423   | Just subst <- match_var menv subst v1 e2
 424   = Just subst
 425
 426 -- Here is another important rule: if the term being matched is a
 427 -- variable, we expand it so long as its unfolding is a WHNF
 428 -- (Its occurrence information is not necessarily up to date,
 429 --  so we don't use it.)
 430 match menv subst e1 (Var v2)
 431   | isCheapUnfolding unfolding
 432   = match menv subst e1 (unfoldingTemplate unfolding)
 433   where
 434     rn_env    = me_env menv
 435     unfolding = idUnfolding (lookupRnInScope rn_env (rnOccR rn_env v2))
 436         -- Notice that we look up v2 in the in-scope set
 437         -- See Note [Lookup in-scope]
 438         -- Remember to apply any renaming first (hence rnOccR)
 439
 440 -- Matching a let-expression.  Consider
 441 --      RULE forall x.  f (g x) = <rhs>
 442 -- and target expression
 443 --      f (let { w=R } in g E))
 444 -- Then we'd like the rule to match, to generate
 445 --      let { w=R } in (\x. <rhs>) E
 446 -- In effect, we want to float the let-binding outward, to enable
 447 -- the match to happen.  This is the WHOLE REASON for accumulating
 448 -- bindings in the SubstEnv
 449 --
 450 -- We can only do this if
 451 --      (a) Widening the scope of w does not capture any variables
 452 --          We use a conservative test: w is not already in scope
 453 --      (b) The free variables of R are not bound by the part of the
 454 --          target expression outside the let binding; e.g.
 455 --              f (\v. let w = v+1 in g E)
 456 --          Here we obviously cannot float the let-binding for w.
 457
 458 match menv subst@(tv_subst, id_subst, binds) e1 (Let bind e2)
 459   | all freshly_bound bndrs,
 460     not (any locally_bound bind_fvs)
 461   = match (menv { me_env = rn_env' })
 462           (tv_subst, id_subst, binds `snocOL` bind)
 463           e1 e2
 464   where
 465     rn_env   = me_env menv
 466     bndrs    = bindersOf bind
 467     bind_fvs = varSetElems (bindFreeVars bind)
 468     freshly_bound x = not (x `rnInScope` rn_env)
 469     locally_bound x = inRnEnvR rn_env x
 470     rn_env' = extendRnInScopeList rn_env bndrs
 471
 472 match menv subst (Lit lit1) (Lit lit2)
 473   | lit1 == lit2
 474   = Just subst
 475
 476 match menv subst (App f1 a1) (App f2 a2)
 477   = do  { subst' <- match menv subst f1 f2
 478         ; match menv subst' a1 a2 }
 479
 480 match menv subst (Lam x1 e1) (Lam x2 e2)
 481   = match menv' subst e1 e2
 482   where
 483     menv' = menv { me_env = rnBndr2 (me_env menv) x1 x2 }
 484
 485 -- This rule does eta expansion
 486 --              (\x.M)  ~  N    iff     M  ~  N x
 487 -- It's important that this is *after* the let rule,
 488 -- so that      (\x.M)  ~  (let y = e in \y.N)
 489 -- does the let thing, and then gets the lam/lam rule above
 490 match menv subst (Lam x1 e1) e2
 491   = match menv' subst e1 (App e2 (varToCoreExpr new_x))
 492   where
 493     (rn_env', new_x) = rnBndrL (me_env menv) x1
 494     menv' = menv { me_env = rn_env' }
 495
 496 -- Eta expansion the other way
 497 --      M  ~  (\y.N)    iff   M y     ~  N
 498 match menv subst e1 (Lam x2 e2)
 499   = match menv' subst (App e1 (varToCoreExpr new_x)) e2
 500   where
 501     (rn_env', new_x) = rnBndrR (me_env menv) x2
 502     menv' = menv { me_env = rn_env' }
 503
 504 match menv subst (Case e1 x1 ty1 alts1) (Case e2 x2 ty2 alts2)
 505   = do  { subst1 <- match_ty menv subst ty1 ty2
 506         ; subst2 <- match menv subst1 e1 e2
 507         ; let menv' = menv { me_env = rnBndr2 (me_env menv) x1 x2 }
 508         ; match_alts menv' subst2 alts1 alts2   -- Alts are both sorted
 509         }
 510
 511 match menv subst (Type ty1) (Type ty2)
 512   = match_ty menv subst ty1 ty2
 513
 514 match menv subst (Cast e1 co1) (Cast e2 co2)
 515   | (from1, to1) <- coercionKind co1
 516   , (from2, to2) <- coercionKind co2
 517   = do  { subst1 <- match_ty menv subst  to1   to2
 518         ; subst2 <- match_ty menv subst1 from1 from2
 519         ; match menv subst2 e1 e2 }
 520
 521 {-      REMOVING OLD CODE: I think that the above handling for let is
 522                            better than the stuff here, which looks
 523                            pretty suspicious to me.  SLPJ Sept 06
 524 -- This is an interesting rule: we simply ignore lets in the
 525 -- term being matched against!  The unfolding inside it is (by assumption)
 526 -- already inside any occurrences of the bound variables, so we'll expand
 527 -- them when we encounter them.  This gives a chance of matching
 528 --      forall x,y.  f (g (x,y))
 529 -- against
 530 --      f (let v = (a,b) in g v)
 531
 532 match menv subst e1 (Let bind e2)
 533   = match (menv { me_env = rn_env' }) subst e1 e2
 534   where
 535     (rn_env', _bndrs') = mapAccumL rnBndrR (me_env menv) (bindersOf bind)
 536         -- It's important to do this renaming, so that the bndrs
 537         -- are brought into the local scope. For example:
 538         -- Matching
 539         --      forall f,x,xs. f (x:xs)
 540         --   against
 541         --      f (let y = e in (y:[]))
 542         -- We must not get success with x->y!  So we record that y is
 543         -- locally bound (with rnBndrR), and proceed.  The Var case
 544         -- will fail when trying to bind x->y
 545 -}
 546
 547 -- Everything else fails
 548 match menv subst e1 e2 = -- pprTrace "Failing at" ((text "e1:" <+> ppr e1) $$ (text "e2:" <+> ppr e2)) $
 549                          Nothing
 550
 551 ------------------------------------------
 552 match_var :: MatchEnv
 553           -> SubstEnv
 554           -> Var                -- Template
 555           -> CoreExpr           -- Target
 556           -> Maybe SubstEnv
 557 match_var menv subst@(tv_subst, id_subst, binds) v1 e2
 558   | v1' `elemVarSet` me_tmpls menv
 559   = case lookupVarEnv id_subst v1' of
 560         Nothing | any (inRnEnvR rn_env) (varSetElems (exprFreeVars e2))
 561                 -> Nothing      -- Occurs check failure
 562                 -- e.g. match forall a. (\x-> a x) against (\y. y y)
 563
 564                 | otherwise     -- No renaming to do on e2
 565                 -> Just (tv_subst, extendVarEnv id_subst v1' e2, binds)
 566
 567         Just e2' | tcEqExprX (nukeRnEnvL rn_env) e2' e2
 568                  -> Just subst
 569
 570                  | otherwise
 571                  -> Nothing
 572
 573   | otherwise   -- v1 is not a template variable; check for an exact match with e2
 574   = case e2 of
 575        Var v2 | v1' == rnOccR rn_env v2 -> Just subst
 576        other                            -> Nothing
 577
 578   where
 579     rn_env = me_env menv
 580     v1'    = rnOccL rn_env v1
 581         -- If the template is
 582         --      forall x. f x (\x -> x) = ...
 583         -- Then the x inside the lambda isn't the
 584         -- template x, so we must rename first!
 585
 586
 587 ------------------------------------------
 588 match_alts :: MatchEnv
 589       -> SubstEnv
 590       -> [CoreAlt]              -- Template
 591       -> [CoreAlt]              -- Target
 592       -> Maybe SubstEnv
 593 match_alts menv subst [] []
 594   = return subst
 595 match_alts menv subst ((c1,vs1,r1):alts1) ((c2,vs2,r2):alts2)
 596   | c1 == c2
 597   = do  { subst1 <- match menv' subst r1 r2
 598         ; match_alts menv subst1 alts1 alts2 }
 599   where
 600     menv' :: MatchEnv
 601     menv' = menv { me_env = rnBndrs2 (me_env menv) vs1 vs2 }
 602
 603 match_alts menv subst alts1 alts2
 604   = Nothing
 605 \end{code}
 606
 607 Matching Core types: use the matcher in TcType.
 608 Notice that we treat newtypes as opaque.  For example, suppose
 609 we have a specialised version of a function at a newtype, say
 610         newtype T = MkT Int
 611 We only want to replace (f T) with f', not (f Int).
 612
 613 \begin{code}
 614 ------------------------------------------
 615 match_ty menv (tv_subst, id_subst, binds) ty1 ty2
 616   = do  { tv_subst' <- Unify.ruleMatchTyX menv tv_subst ty1 ty2
 617         ; return (tv_subst', id_subst, binds) }
 618 \end{code}
 619
 620
 621 Note [Lookup in-scope]
 622 ~~~~~~~~~~~~~~~~~~~~~~
 623 Consider this example
 624         foo :: Int -> Maybe Int -> Int
 625         foo 0 (Just n) = n
 626         foo m (Just n) = foo (m-n) (Just n)
 627
 628 SpecConstr sees this fragment:
 629
 630         case w_smT of wild_Xf [Just A] {
 631           Data.Maybe.Nothing -> lvl_smf;
 632           Data.Maybe.Just n_acT [Just S(L)] ->
 633             case n_acT of wild1_ams [Just A] { GHC.Base.I# y_amr [Just L] ->
 634             $wfoo_smW (GHC.Prim.-# ds_Xmb y_amr) wild_Xf
 635             }};
 636
 637 and correctly generates the rule
 638
 639         RULES: "SC:$wfoo1" [0] __forall {y_amr [Just L] :: GHC.Prim.Int#
 640                                           sc_snn :: GHC.Prim.Int#}
 641           $wfoo_smW sc_snn (Data.Maybe.Just @ GHC.Base.Int (GHC.Base.I# y_amr))
 642           = $s$wfoo_sno y_amr sc_snn ;]
 643
 644 BUT we must ensure that this rule matches in the original function!
 645 Note that the call to $wfoo is
 646             $wfoo_smW (GHC.Prim.-# ds_Xmb y_amr) wild_Xf
 647
 648 During matching we expand wild_Xf to (Just n_acT).  But then we must also
 649 expand n_acT to (I# y_amr).  And we can only do that if we look up n_acT
 650 in the in-scope set, because in wild_Xf's unfolding it won't have an unfolding
 651 at all.
 652
 653 That is why the 'lookupRnInScope' call in the (Var v2) case of 'match'
 654 is so important.
 655
 656
 657 %************************************************************************
 658 %*                                                                      *
 659 \subsection{Checking a program for failing rule applications}
 660 %*                                                                      *
 661 %************************************************************************
 662
 663 -----------------------------------------------------
 664                         Game plan
 665 -----------------------------------------------------
 666
 667 We want to know what sites have rules that could have fired but didn't.
 668 This pass runs over the tree (without changing it) and reports such.
 669
 670 NB: we assume that this follows a run of the simplifier, so every Id
 671 occurrence (including occurrences of imported Ids) is decorated with
 672 all its (active) rules.  No need to construct a rule base or anything
 673 like that.
 674
 675 \begin{code}
 676 ruleCheckProgram :: CompilerPhase -> String -> [CoreBind] -> SDoc
 677 -- Report partial matches for rules beginning
 678 -- with the specified string
 679 ruleCheckProgram phase rule_pat binds
 680   | isEmptyBag results
 681   = text "Rule check results: no rule application sites"
 682   | otherwise
 683   = vcat [text "Rule check results:",
 684           line,
 685           vcat [ p $$ line | p <- bagToList results ]
 686          ]
 687   where
 688     results = unionManyBags (map (ruleCheckBind (phase, rule_pat)) binds)
 689     line = text (replicate 20 '-')
 690
 691 type RuleCheckEnv = (CompilerPhase, String)     -- Phase and Pattern
 692
 693 ruleCheckBind :: RuleCheckEnv -> CoreBind -> Bag SDoc
 694    -- The Bag returned has one SDoc for each call site found
 695 ruleCheckBind env (NonRec b r) = ruleCheck env r
 696 ruleCheckBind env (Rec prs)    = unionManyBags [ruleCheck env r | (b,r) <- prs]
 697
 698 ruleCheck :: RuleCheckEnv -> CoreExpr -> Bag SDoc
 699 ruleCheck env (Var v)       = emptyBag
 700 ruleCheck env (Lit l)       = emptyBag
 701 ruleCheck env (Type ty)     = emptyBag
 702 ruleCheck env (App f a)     = ruleCheckApp env (App f a) []
 703 ruleCheck env (Note n e)    = ruleCheck env e
 704 ruleCheck env (Cast e co)   = ruleCheck env e
 705 ruleCheck env (Let bd e)    = ruleCheckBind env bd `unionBags` ruleCheck env e
 706 ruleCheck env (Lam b e)     = ruleCheck env e
 707 ruleCheck env (Case e _ _ as) = ruleCheck env e `unionBags`
 708                                 unionManyBags [ruleCheck env r | (_,_,r) <- as]
 709
 710 ruleCheckApp env (App f a) as = ruleCheck env a `unionBags` ruleCheckApp env f (a:as)
 711 ruleCheckApp env (Var f) as   = ruleCheckFun env f as
 712 ruleCheckApp env other as     = ruleCheck env other
 713 \end{code}
 714
 715 \begin{code}
 716 ruleCheckFun :: RuleCheckEnv -> Id -> [CoreExpr] -> Bag SDoc
 717 -- Produce a report for all rules matching the predicate
 718 -- saying why it doesn't match the specified application
 719
 720 ruleCheckFun (phase, pat) fn args
 721   | null name_match_rules = emptyBag
 722   | otherwise             = unitBag (ruleAppCheck_help phase fn args name_match_rules)
 723   where
 724     name_match_rules = filter match (idCoreRules fn)
 725     match rule = pat `isPrefixOf` unpackFS (ruleName rule)
 726
 727 ruleAppCheck_help :: CompilerPhase -> Id -> [CoreExpr] -> [CoreRule] -> SDoc
 728 ruleAppCheck_help phase fn args rules
 729   =     -- The rules match the pattern, so we want to print something
 730     vcat [text "Expression:" <+> ppr (mkApps (Var fn) args),
 731           vcat (map check_rule rules)]
 732   where
 733     n_args = length args
 734     i_args = args `zip` [1::Int ..]
 735     rough_args = map roughTopName args
 736
 737     check_rule rule = rule_herald rule <> colon <+> rule_info rule
 738
 739     rule_herald (BuiltinRule { ru_name = name })
 740         = ptext SLIT("Builtin rule") <+> doubleQuotes (ftext name)
 741     rule_herald (Rule { ru_name = name })
 742         = ptext SLIT("Rule") <+> doubleQuotes (ftext name)
 743
 744     rule_info rule
 745         | Just _ <- matchRule noBlackList emptyInScopeSet args rough_args rule
 746         = text "matches (which is very peculiar!)"
 747
 748     rule_info (BuiltinRule {}) = text "does not match"
 749
 750     rule_info (Rule { ru_name = name, ru_act = act,
 751                       ru_bndrs = rule_bndrs, ru_args = rule_args})
 752         | not (isActive phase act)    = text "active only in later phase"
 753         | n_args < n_rule_args        = text "too few arguments"
 754         | n_mismatches == n_rule_args = text "no arguments match"
 755         | n_mismatches == 0           = text "all arguments match (considered individually), but rule as a whole does not"
 756         | otherwise                   = text "arguments" <+> ppr mismatches <+> text "do not match (1-indexing)"
 757         where
 758           n_rule_args  = length rule_args
 759           n_mismatches = length mismatches
 760           mismatches   = [i | (rule_arg, (arg,i)) <- rule_args `zip` i_args,
 761                               not (isJust (match_fn rule_arg arg))]
 762
 763           lhs_fvs = exprsFreeVars rule_args     -- Includes template tyvars
 764           match_fn rule_arg arg = match menv emptySubstEnv rule_arg arg
 765                 where
 766                   in_scope = lhs_fvs `unionVarSet` exprFreeVars arg
 767                   menv = ME { me_env   = mkRnEnv2 (mkInScopeSet in_scope)
 768                             , me_tmpls = mkVarSet rule_bndrs }
 769 \end{code}
 770