compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 -- The above warning supression flag is a temporary kludge.
   8 -- While working on this module you are encouraged to remove it and fix
   9 -- any warnings in the module. See
  10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  11 -- for details
  12
  13 module Specialise ( specProgram ) where
  14
  15 #include "HsVersions.h"
  16
  17 import Id               ( Id, idName, idType, mkUserLocal, idCoreRules,
  18                           idInlineActivation, setInlineActivation, setIdUnfolding,
  19                           isLocalId, idArity, setIdArity )
  20 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  21                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  22                           tcCmpType, isUnLiftedType
  23                         )
  24 import CoreSubst        ( Subst, mkEmptySubst, extendTvSubstList, lookupIdSubst,
  25                           substBndr, substBndrs, substTy, substInScope,
  26                           cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs,
  27                           extendIdSubst
  28                         )
  29 import CoreUnfold       ( mkUnfolding )
  30 import SimplUtils       ( interestingArg )
  31 import Var              ( DictId )
  32 import VarSet
  33 import VarEnv
  34 import CoreSyn
  35 import Rules
  36 import CoreUtils        ( exprIsTrivial, applyTypeToArgs, mkPiTypes )
  37 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  38 import UniqSupply       ( UniqSupply,
  39                           UniqSM, initUs_,
  40                           MonadUnique(..)
  41                         )
  42 import Name
  43 import MkId             ( voidArgId, realWorldPrimId )
  44 import FiniteMap
  45 import Maybes           ( catMaybes, isJust )
  46 import Bag
  47 import Util
  48 import Outputable
  49 import FastString
  50
  51 \end{code}
  52
  53 %************************************************************************
  54 %*                                                                      *
  55 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 These notes describe how we implement specialisation to eliminate
  60 overloading.
  61
  62 The specialisation pass works on Core
  63 syntax, complete with all the explicit dictionary application,
  64 abstraction and construction as added by the type checker.  The
  65 existing type checker remains largely as it is.
  66
  67 One important thought: the {\em types} passed to an overloaded
  68 function, and the {\em dictionaries} passed are mutually redundant.
  69 If the same function is applied to the same type(s) then it is sure to
  70 be applied to the same dictionary(s)---or rather to the same {\em
  71 values}.  (The arguments might look different but they will evaluate
  72 to the same value.)
  73
  74 Second important thought: we know that we can make progress by
  75 treating dictionary arguments as static and worth specialising on.  So
  76 we can do without binding-time analysis, and instead specialise on
  77 dictionary arguments and no others.
  78
  79 The basic idea
  80 ~~~~~~~~~~~~~~
  81 Suppose we have
  82
  83         let f = <f_rhs>
  84         in <body>
  85
  86 and suppose f is overloaded.
  87
  88 STEP 1: CALL-INSTANCE COLLECTION
  89
  90 We traverse <body>, accumulating all applications of f to types and
  91 dictionaries.
  92
  93 (Might there be partial applications, to just some of its types and
  94 dictionaries?  In principle yes, but in practice the type checker only
  95 builds applications of f to all its types and dictionaries, so partial
  96 applications could only arise as a result of transformation, and even
  97 then I think it's unlikely.  In any case, we simply don't accumulate such
  98 partial applications.)
  99
 100
 101 STEP 2: EQUIVALENCES
 102
 103 So now we have a collection of calls to f:
 104         f t1 t2 d1 d2
 105         f t3 t4 d3 d4
 106         ...
 107 Notice that f may take several type arguments.  To avoid ambiguity, we
 108 say that f is called at type t1/t2 and t3/t4.
 109
 110 We take equivalence classes using equality of the *types* (ignoring
 111 the dictionary args, which as mentioned previously are redundant).
 112
 113 STEP 3: SPECIALISATION
 114
 115 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 116 and create a local instance of f, defined thus:
 117
 118         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 119
 120 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 121 of simplification will now result.  However we don't actually *do* that
 122 simplification.  Rather, we leave it for the simplifier to do.  If we
 123 *did* do it, though, we'd get more call instances from the specialised
 124 RHS.  We can work out what they are by instantiating the call-instance
 125 set from f's RHS with the types t1, t2.
 126
 127 Add this new id to f's IdInfo, to record that f has a specialised version.
 128
 129 Before doing any of this, check that f's IdInfo doesn't already
 130 tell us about an existing instance of f at the required type/s.
 131 (This might happen if specialisation was applied more than once, or
 132 it might arise from user SPECIALIZE pragmas.)
 133
 134 Recursion
 135 ~~~~~~~~~
 136 Wait a minute!  What if f is recursive?  Then we can't just plug in
 137 its right-hand side, can we?
 138
 139 But it's ok.  The type checker *always* creates non-recursive definitions
 140 for overloaded recursive functions.  For example:
 141
 142         f x = f (x+x)           -- Yes I know its silly
 143
 144 becomes
 145
 146         f a (d::Num a) = let p = +.sel a d
 147                          in
 148                          letrec fl (y::a) = fl (p y y)
 149                          in
 150                          fl
 151
 152 We still have recusion for non-overloaded functions which we
 153 speciailise, but the recursive call should get specialised to the
 154 same recursive version.
 155
 156
 157 Polymorphism 1
 158 ~~~~~~~~~~~~~~
 159
 160 All this is crystal clear when the function is applied to *constant
 161 types*; that is, types which have no type variables inside.  But what if
 162 it is applied to non-constant types?  Suppose we find a call of f at type
 163 t1/t2.  There are two possibilities:
 164
 165 (a) The free type variables of t1, t2 are in scope at the definition point
 166 of f.  In this case there's no problem, we proceed just as before.  A common
 167 example is as follows.  Here's the Haskell:
 168
 169         g y = let f x = x+x
 170               in f y + f y
 171
 172 After typechecking we have
 173
 174         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 175                                 in +.sel a d (f a d y) (f a d y)
 176
 177 Notice that the call to f is at type type "a"; a non-constant type.
 178 Both calls to f are at the same type, so we can specialise to give:
 179
 180         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 181                                 in +.sel a d (f@a y) (f@a y)
 182
 183
 184 (b) The other case is when the type variables in the instance types
 185 are *not* in scope at the definition point of f.  The example we are
 186 working with above is a good case.  There are two instances of (+.sel a d),
 187 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 188 Yes, we can "common them up", a sort of limited common sub-expression deal.
 189 This would give:
 190
 191         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 192                                     f@a (x::a) = +.sel@a x x
 193                                 in +.sel@a (f@a y) (f@a y)
 194
 195 This can save work, and can't be spotted by the type checker, because
 196 the two instances of +.sel weren't originally at the same type.
 197
 198 Further notes on (b)
 199
 200 * There are quite a few variations here.  For example, the defn of
 201   +.sel could be floated ouside the \y, to attempt to gain laziness.
 202   It certainly mustn't be floated outside the \d because the d has to
 203   be in scope too.
 204
 205 * We don't want to inline f_rhs in this case, because
 206 that will duplicate code.  Just commoning up the call is the point.
 207
 208 * Nothing gets added to +.sel's IdInfo.
 209
 210 * Don't bother unless the equivalence class has more than one item!
 211
 212 Not clear whether this is all worth it.  It is of course OK to
 213 simply discard call-instances when passing a big lambda.
 214
 215 Polymorphism 2 -- Overloading
 216 ~~~~~~~~~~~~~~
 217 Consider a function whose most general type is
 218
 219         f :: forall a b. Ord a => [a] -> b -> b
 220
 221 There is really no point in making a version of g at Int/Int and another
 222 at Int/Bool, because it's only instancing the type variable "a" which
 223 buys us any efficiency. Since g is completely polymorphic in b there
 224 ain't much point in making separate versions of g for the different
 225 b types.
 226
 227 That suggests that we should identify which of g's type variables
 228 are constrained (like "a") and which are unconstrained (like "b").
 229 Then when taking equivalence classes in STEP 2, we ignore the type args
 230 corresponding to unconstrained type variable.  In STEP 3 we make
 231 polymorphic versions.  Thus:
 232
 233         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 234
 235 We do this.
 236
 237
 238 Dictionary floating
 239 ~~~~~~~~~~~~~~~~~~~
 240 Consider this
 241
 242         f a (d::Num a) = let g = ...
 243                          in
 244                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 245
 246 Here, g is only called at one type, but the dictionary isn't in scope at the
 247 definition point for g.  Usually the type checker would build a
 248 definition for d1 which enclosed g, but the transformation system
 249 might have moved d1's defn inward.  Solution: float dictionary bindings
 250 outwards along with call instances.
 251
 252 Consider
 253
 254         f x = let g p q = p==q
 255                   h r s = (r+s, g r s)
 256               in
 257               h x x
 258
 259
 260 Before specialisation, leaving out type abstractions we have
 261
 262         f df x = let g :: Eq a => a -> a -> Bool
 263                      g dg p q = == dg p q
 264                      h :: Num a => a -> a -> (a, Bool)
 265                      h dh r s = let deq = eqFromNum dh
 266                                 in (+ dh r s, g deq r s)
 267               in
 268               h df x x
 269
 270 After specialising h we get a specialised version of h, like this:
 271
 272                     h' r s = let deq = eqFromNum df
 273                              in (+ df r s, g deq r s)
 274
 275 But we can't naively make an instance for g from this, because deq is not in scope
 276 at the defn of g.  Instead, we have to float out the (new) defn of deq
 277 to widen its scope.  Notice that this floating can't be done in advance -- it only
 278 shows up when specialisation is done.
 279
 280 User SPECIALIZE pragmas
 281 ~~~~~~~~~~~~~~~~~~~~~~~
 282 Specialisation pragmas can be digested by the type checker, and implemented
 283 by adding extra definitions along with that of f, in the same way as before
 284
 285         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 286
 287 Indeed the pragmas *have* to be dealt with by the type checker, because
 288 only it knows how to build the dictionaries d1 and d2!  For example
 289
 290         g :: Ord a => [a] -> [a]
 291         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 292
 293 Here, the specialised version of g is an application of g's rhs to the
 294 Ord dictionary for (Tree Int), which only the type checker can conjure
 295 up.  There might not even *be* one, if (Tree Int) is not an instance of
 296 Ord!  (All the other specialision has suitable dictionaries to hand
 297 from actual calls.)
 298
 299 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 300 it is buried in a complex (as-yet-un-desugared) binding group.
 301 Maybe we should say
 302
 303         f@t1/t2 = f* t1 t2 d1 d2
 304
 305 where f* is the Id f with an IdInfo which says "inline me regardless!".
 306 Indeed all the specialisation could be done in this way.
 307 That in turn means that the simplifier has to be prepared to inline absolutely
 308 any in-scope let-bound thing.
 309
 310
 311 Again, the pragma should permit polymorphism in unconstrained variables:
 312
 313         h :: Ord a => [a] -> b -> b
 314         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 315
 316 We *insist* that all overloaded type variables are specialised to ground types,
 317 (and hence there can be no context inside a SPECIALIZE pragma).
 318 We *permit* unconstrained type variables to be specialised to
 319         - a ground type
 320         - or left as a polymorphic type variable
 321 but nothing in between.  So
 322
 323         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 324
 325 is *illegal*.  (It can be handled, but it adds complication, and gains the
 326 programmer nothing.)
 327
 328
 329 SPECIALISING INSTANCE DECLARATIONS
 330 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 331 Consider
 332
 333         instance Foo a => Foo [a] where
 334                 ...
 335         {-# SPECIALIZE instance Foo [Int] #-}
 336
 337 The original instance decl creates a dictionary-function
 338 definition:
 339
 340         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 341
 342 The SPECIALIZE pragma just makes a specialised copy, just as for
 343 ordinary function definitions:
 344
 345         dfun.Foo.List@Int :: Foo [Int]
 346         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 347
 348 The information about what instance of the dfun exist gets added to
 349 the dfun's IdInfo in the same way as a user-defined function too.
 350
 351
 352 Automatic instance decl specialisation?
 353 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 354 Can instance decls be specialised automatically?  It's tricky.
 355 We could collect call-instance information for each dfun, but
 356 then when we specialised their bodies we'd get new call-instances
 357 for ordinary functions; and when we specialised their bodies, we might get
 358 new call-instances of the dfuns, and so on.  This all arises because of
 359 the unrestricted mutual recursion between instance decls and value decls.
 360
 361 Still, there's no actual problem; it just means that we may not do all
 362 the specialisation we could theoretically do.
 363
 364 Furthermore, instance decls are usually exported and used non-locally,
 365 so we'll want to compile enough to get those specialisations done.
 366
 367 Lastly, there's no such thing as a local instance decl, so we can
 368 survive solely by spitting out *usage* information, and then reading that
 369 back in as a pragma when next compiling the file.  So for now,
 370 we only specialise instance decls in response to pragmas.
 371
 372
 373 SPITTING OUT USAGE INFORMATION
 374 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 375
 376 To spit out usage information we need to traverse the code collecting
 377 call-instance information for all imported (non-prelude?) functions
 378 and data types. Then we equivalence-class it and spit it out.
 379
 380 This is done at the top-level when all the call instances which escape
 381 must be for imported functions and data types.
 382
 383 *** Not currently done ***
 384
 385
 386 Partial specialisation by pragmas
 387 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 388 What about partial specialisation:
 389
 390         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 391         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 392
 393 or even
 394
 395         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 396
 397 Seems quite reasonable.  Similar things could be done with instance decls:
 398
 399         instance (Foo a, Foo b) => Foo (a,b) where
 400                 ...
 401         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 402         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 403
 404 Ho hum.  Things are complex enough without this.  I pass.
 405
 406
 407 Requirements for the simplifer
 408 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 409 The simplifier has to be able to take advantage of the specialisation.
 410
 411 * When the simplifier finds an application of a polymorphic f, it looks in
 412 f's IdInfo in case there is a suitable instance to call instead.  This converts
 413
 414         f t1 t2 d1 d2   ===>   f_t1_t2
 415
 416 Note that the dictionaries get eaten up too!
 417
 418 * Dictionary selection operations on constant dictionaries must be
 419   short-circuited:
 420
 421         +.sel Int d     ===>  +Int
 422
 423 The obvious way to do this is in the same way as other specialised
 424 calls: +.sel has inside it some IdInfo which tells that if it's applied
 425 to the type Int then it should eat a dictionary and transform to +Int.
 426
 427 In short, dictionary selectors need IdInfo inside them for constant
 428 methods.
 429
 430 * Exactly the same applies if a superclass dictionary is being
 431   extracted:
 432
 433         Eq.sel Int d   ===>   dEqInt
 434
 435 * Something similar applies to dictionary construction too.  Suppose
 436 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 437 one for (Eq [a]).  Then we want
 438
 439         dfun.Eq.List Int d      ===> dEq.List_Int
 440
 441 Where does the Eq [Int] dictionary come from?  It is built in
 442 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 443
 444 In short, dfun Ids need IdInfo with a specialisation for each
 445 constant instance of their instance declaration.
 446
 447 All this uses a single mechanism: the SpecEnv inside an Id
 448
 449
 450 What does the specialisation IdInfo look like?
 451 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 452
 453 The SpecEnv of an Id maps a list of types (the template) to an expression
 454
 455         [Type]  |->  Expr
 456
 457 For example, if f has this SpecInfo:
 458
 459         [Int, a]  ->  \d:Ord Int. f' a
 460
 461 it means that we can replace the call
 462
 463         f Int t  ===>  (\d. f' t)
 464
 465 This chucks one dictionary away and proceeds with the
 466 specialised version of f, namely f'.
 467
 468
 469 What can't be done this way?
 470 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 471 There is no way, post-typechecker, to get a dictionary for (say)
 472 Eq a from a dictionary for Eq [a].  So if we find
 473
 474         ==.sel [t] d
 475
 476 we can't transform to
 477
 478         eqList (==.sel t d')
 479
 480 where
 481         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 482
 483 Of course, we currently have no way to automatically derive
 484 eqList, nor to connect it to the Eq [a] instance decl, but you
 485 can imagine that it might somehow be possible.  Taking advantage
 486 of this is permanently ruled out.
 487
 488 Still, this is no great hardship, because we intend to eliminate
 489 overloading altogether anyway!
 490
 491 A note about non-tyvar dictionaries
 492 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 493 Some Ids have types like
 494
 495         forall a,b,c. Eq a -> Ord [a] -> tau
 496
 497 This seems curious at first, because we usually only have dictionary
 498 args whose types are of the form (C a) where a is a type variable.
 499 But this doesn't hold for the functions arising from instance decls,
 500 which sometimes get arguements with types of form (C (T a)) for some
 501 type constructor T.
 502
 503 Should we specialise wrt this compound-type dictionary?  We used to say
 504 "no", saying:
 505         "This is a heuristic judgement, as indeed is the fact that we
 506         specialise wrt only dictionaries.  We choose *not* to specialise
 507         wrt compound dictionaries because at the moment the only place
 508         they show up is in instance decls, where they are simply plugged
 509         into a returned dictionary.  So nothing is gained by specialising
 510         wrt them."
 511
 512 But it is simpler and more uniform to specialise wrt these dicts too;
 513 and in future GHC is likely to support full fledged type signatures
 514 like
 515         f :: Eq [(a,b)] => ...
 516
 517
 518 %************************************************************************
 519 %*                                                                      *
 520 \subsubsection{The new specialiser}
 521 %*                                                                      *
 522 %************************************************************************
 523
 524 Our basic game plan is this.  For let(rec) bound function
 525         f :: (C a, D c) => (a,b,c,d) -> Bool
 526
 527 * Find any specialised calls of f, (f ts ds), where
 528   ts are the type arguments t1 .. t4, and
 529   ds are the dictionary arguments d1 .. d2.
 530
 531 * Add a new definition for f1 (say):
 532
 533         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 534
 535   Note that we abstract over the unconstrained type arguments.
 536
 537 * Add the mapping
 538
 539         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 540
 541   to the specialisations of f.  This will be used by the
 542   simplifier to replace calls
 543                 (f t1 t2 t3 t4) da db
 544   by
 545                 (\d1 d1 -> f1 t2 t4) da db
 546
 547   All the stuff about how many dictionaries to discard, and what types
 548   to apply the specialised function to, are handled by the fact that the
 549   SpecEnv contains a template for the result of the specialisation.
 550
 551 We don't build *partial* specialisations for f.  For example:
 552
 553   f :: Eq a => a -> a -> Bool
 554   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 555
 556 Here, little is gained by making a specialised copy of f.
 557 There's a distinct danger that the specialised version would
 558 first build a dictionary for (Eq b, Eq c), and then select the (==)
 559 method from it!  Even if it didn't, not a great deal is saved.
 560
 561 We do, however, generate polymorphic, but not overloaded, specialisations:
 562
 563   f :: Eq a => [a] -> b -> b -> b
 564   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 565
 566 Hence, the invariant is this:
 567
 568         *** no specialised version is overloaded ***
 569
 570
 571 %************************************************************************
 572 %*                                                                      *
 573 \subsubsection{The exported function}
 574 %*                                                                      *
 575 %************************************************************************
 576
 577 \begin{code}
 578 specProgram :: UniqSupply -> [CoreBind] -> [CoreBind]
 579 specProgram us binds = initSM us (do (binds', uds') <- go binds
 580                                      return (dumpAllDictBinds uds' binds'))
 581   where
 582         -- We need to start with a Subst that knows all the things
 583         -- that are in scope, so that the substitution engine doesn't
 584         -- accidentally re-use a unique that's already in use
 585         -- Easiest thing is to do it all at once, as if all the top-level
 586         -- decls were mutually recursive
 587     top_subst       = mkEmptySubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 588
 589     go []           = return ([], emptyUDs)
 590     go (bind:binds) = do (binds', uds) <- go binds
 591                          (bind', uds') <- specBind top_subst bind uds
 592                          return (bind' ++ binds', uds')
 593 \end{code}
 594
 595 %************************************************************************
 596 %*                                                                      *
 597 \subsubsection{@specExpr@: the main function}
 598 %*                                                                      *
 599 %************************************************************************
 600
 601 \begin{code}
 602 specVar :: Subst -> Id -> CoreExpr
 603 specVar subst v = lookupIdSubst subst v
 604
 605 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 606 -- We carry a substitution down:
 607 --      a) we must clone any binding that might float outwards,
 608 --         to avoid name clashes
 609 --      b) we carry a type substitution to use when analysing
 610 --         the RHS of specialised bindings (no type-let!)
 611
 612 ---------------- First the easy cases --------------------
 613 specExpr subst (Type ty) = return (Type (substTy subst ty), emptyUDs)
 614 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
 615 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
 616 specExpr subst (Cast e co) = do
 617     (e', uds) <- specExpr subst e
 618     return ((Cast e' (substTy subst co)), uds)
 619 specExpr subst (Note note body) = do
 620     (body', uds) <- specExpr subst body
 621     return (Note (specNote subst note) body', uds)
 622
 623
 624 ---------------- Applications might generate a call instance --------------------
 625 specExpr subst expr@(App {})
 626   = go expr []
 627   where
 628     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
 629                                (fun', uds_app) <- go fun (arg':args)
 630                                return (App fun' arg', uds_arg `plusUDs` uds_app)
 631
 632     go (Var f)       args = case specVar subst f of
 633                                 Var f' -> return (Var f', mkCallUDs f' args)
 634                                 e'     -> return (e', emptyUDs) -- I don't expect this!
 635     go other         _    = specExpr subst other
 636
 637 ---------------- Lambda/case require dumping of usage details --------------------
 638 specExpr subst e@(Lam _ _) = do
 639     (body', uds) <- specExpr subst' body
 640     let (filtered_uds, body'') = dumpUDs bndrs' uds body'
 641     return (mkLams bndrs' body'', filtered_uds)
 642   where
 643     (bndrs, body) = collectBinders e
 644     (subst', bndrs') = substBndrs subst bndrs
 645         -- More efficient to collect a group of binders together all at once
 646         -- and we don't want to split a lambda group with dumped bindings
 647
 648 specExpr subst (Case scrut case_bndr ty alts) = do
 649     (scrut', uds_scrut) <- specExpr subst scrut
 650     (alts', uds_alts) <- mapAndCombineSM spec_alt alts
 651     return (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 652   where
 653     (subst_alt, case_bndr') = substBndr subst case_bndr
 654         -- No need to clone case binder; it can't float like a let(rec)
 655
 656     spec_alt (con, args, rhs) = do
 657           (rhs', uds) <- specExpr subst_rhs rhs
 658           let (uds', rhs'') = dumpUDs args uds rhs'
 659           return ((con, args', rhs''), uds')
 660         where
 661           (subst_rhs, args') = substBndrs subst_alt args
 662
 663 ---------------- Finally, let is the interesting case --------------------
 664 specExpr subst (Let bind body) = do
 665         -- Clone binders
 666     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
 667
 668         -- Deal with the body
 669     (body', body_uds) <- specExpr body_subst body
 670
 671         -- Deal with the bindings
 672     (binds', uds) <- specBind rhs_subst bind' body_uds
 673
 674         -- All done
 675     return (foldr Let body' binds', uds)
 676
 677 -- Must apply the type substitution to coerceions
 678 specNote :: Subst -> Note -> Note
 679 specNote _ note = note
 680 \end{code}
 681
 682 %************************************************************************
 683 %*                                                                      *
 684 \subsubsection{Dealing with a binding}
 685 %*                                                                      *
 686 %************************************************************************
 687
 688 \begin{code}
 689 specBind :: Subst                       -- Use this for RHSs
 690          -> CoreBind
 691          -> UsageDetails                -- Info on how the scope of the binding
 692          -> SpecM ([CoreBind],          -- New bindings
 693                    UsageDetails)        -- And info to pass upstream
 694
 695 specBind rhs_subst bind body_uds
 696   = do  { (bind', bind_uds) <- specBindItself rhs_subst bind (calls body_uds)
 697         ; return (finishSpecBind bind' bind_uds body_uds) }
 698
 699 finishSpecBind :: CoreBind -> UsageDetails -> UsageDetails -> ([CoreBind], UsageDetails)
 700 finishSpecBind bind
 701         (MkUD { dict_binds = rhs_dbs,  calls = rhs_calls,  ud_fvs = rhs_fvs })
 702         (MkUD { dict_binds = body_dbs, calls = body_calls, ud_fvs = body_fvs })
 703   | not (mkVarSet bndrs `intersectsVarSet` all_fvs)
 704                 -- Common case 1: the bound variables are not
 705                 --                mentioned in the dictionary bindings
 706   = ([bind], MkUD { dict_binds = body_dbs `unionBags` rhs_dbs
 707                         -- It's important that the `unionBags` is this way round,
 708                         -- because body_uds may bind dictionaries that are
 709                         -- used in the calls passed to specDefn.  So the
 710                         -- dictionary bindings in rhs_uds may mention
 711                         -- dictionaries bound in body_uds.
 712                   , calls  = all_calls
 713                   , ud_fvs = all_fvs })
 714
 715   | case bind of { NonRec {} -> True; Rec {} -> False }
 716                 -- Common case 2: no specialisation happened, and binding
 717                 --                is non-recursive.  But the binding may be
 718                 --                mentioned in body_dbs, so we should put it first
 719   = ([], MkUD { dict_binds = rhs_dbs `unionBags` ((bind, b_fvs) `consBag` body_dbs)
 720               , calls      = all_calls
 721               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 722
 723   | otherwise   -- General case: make a huge Rec (sigh)
 724   = ([], MkUD { dict_binds = unitBag (Rec all_db_prs, all_db_fvs)
 725               , calls      = all_calls
 726               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 727   where
 728     all_fvs = rhs_fvs `unionVarSet` body_fvs
 729     all_calls = zapCalls bndrs (rhs_calls `unionCalls` body_calls)
 730
 731     bndrs   = bindersOf bind
 732     b_fvs   = bind_fvs bind
 733
 734     (all_db_prs, all_db_fvs) = add (bind, b_fvs) $
 735                                foldrBag add ([], emptyVarSet) $
 736                                rhs_dbs `unionBags` body_dbs
 737     add (NonRec b r, b_fvs) (prs, fvs) = ((b,r)  : prs, b_fvs `unionVarSet` fvs)
 738     add (Rec b_prs,  b_fvs) (prs, fvs) = (b_prs ++ prs, b_fvs `unionVarSet` fvs)
 739
 740 ---------------------------
 741 specBindItself :: Subst -> CoreBind -> CallDetails -> SpecM (CoreBind, UsageDetails)
 742
 743 -- specBindItself deals with the RHS, specialising it according
 744 -- to the calls found in the body (if any)
 745 specBindItself rhs_subst (NonRec fn rhs) call_info
 746   = do { (rhs', rhs_uds) <- specExpr rhs_subst rhs           -- Do RHS of original fn
 747        ; (fn', spec_defns, spec_uds) <- specDefn rhs_subst call_info fn rhs
 748        ; if null spec_defns then
 749             return (NonRec fn rhs', rhs_uds)
 750          else
 751             return (Rec ((fn',rhs') : spec_defns), rhs_uds `plusUDs` spec_uds) }
 752                 -- bndr' mentions the spec_defns in its SpecEnv
 753                 -- Not sure why we couln't just put the spec_defns first
 754
 755 specBindItself rhs_subst (Rec pairs) call_info
 756        -- Note [Specialising a recursive group]
 757   = do { let (bndrs,rhss) = unzip pairs
 758        ; (rhss', rhs_uds) <- mapAndCombineSM (specExpr rhs_subst) rhss
 759        ; let all_calls = call_info `unionCalls` calls rhs_uds
 760        ; (bndrs1, spec_defns1, spec_uds1) <- specDefns rhs_subst all_calls pairs
 761
 762        ; if null spec_defns1 then   -- Common case: no specialisation
 763             return (Rec (bndrs `zip` rhss'), rhs_uds)
 764          else do                     -- Specialisation occurred; do it again
 765        { (bndrs2, spec_defns2, spec_uds2) <-
 766                   -- pprTrace "specB" (ppr bndrs $$ ppr rhs_uds) $
 767                   specDefns rhs_subst (calls spec_uds1) (bndrs1 `zip` rhss)
 768
 769        ; let all_defns = spec_defns1 ++ spec_defns2 ++ zip bndrs2 rhss'
 770
 771        ; return (Rec all_defns, rhs_uds `plusUDs` spec_uds1 `plusUDs` spec_uds2) } }
 772
 773
 774 ---------------------------
 775 specDefns :: Subst
 776          -> CallDetails                 -- Info on how it is used in its scope
 777          -> [(Id,CoreExpr)]             -- The things being bound and their un-processed RHS
 778          -> SpecM ([Id],                -- Original Ids with RULES added
 779                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 780                    UsageDetails)        -- Stuff to fling upwards from the specialised versions
 781
 782 -- Specialise a list of bindings (the contents of a Rec), but flowing usages
 783 -- upwards binding by binding.  Example: { f = ...g ...; g = ...f .... }
 784 -- Then if the input CallDetails has a specialised call for 'g', whose specialisation
 785 -- in turn generates a specialised call for 'f', we catch that in this one sweep.
 786 -- But not vice versa (it's a fixpoint problem).
 787
 788 specDefns _subst _call_info []
 789   = return ([], [], emptyUDs)
 790 specDefns subst call_info ((bndr,rhs):pairs)
 791   = do { (bndrs', spec_defns, spec_uds) <- specDefns subst call_info pairs
 792        ; let all_calls = call_info `unionCalls` calls spec_uds
 793        ; (bndr', spec_defns1, spec_uds1) <- specDefn subst all_calls bndr rhs
 794        ; return (bndr' : bndrs',
 795                  spec_defns1 ++ spec_defns,
 796                  spec_uds1 `plusUDs` spec_uds) }
 797
 798 ---------------------------
 799 specDefn :: Subst
 800          -> CallDetails                 -- Info on how it is used in its scope
 801          -> Id -> CoreExpr              -- The thing being bound and its un-processed RHS
 802          -> SpecM (Id,                  -- Original Id with added RULES
 803                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 804                    UsageDetails)        -- Stuff to fling upwards from the specialised versions
 805
 806 specDefn subst calls fn rhs
 807         -- The first case is the interesting one
 808   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 809   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 810   && notNull calls_for_me               -- And there are some calls to specialise
 811
 812 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 813 --      See Note [Inline specialisation] for why we do not
 814 --      switch off specialisation for inline functions
 815
 816   = do {       -- Make a specialised version for each call in calls_for_me
 817          stuff <- mapM spec_call calls_for_me
 818        ; let (spec_defns, spec_uds, spec_rules) = unzip3 (catMaybes stuff)
 819              fn' = addIdSpecialisations fn spec_rules
 820        ; return (fn', spec_defns, plusUDList spec_uds) }
 821
 822   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 823   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") <+> ppr fn )
 824           -- Note [Specialisation shape]
 825     return (fn, [], emptyUDs)
 826
 827   where
 828     fn_type            = idType fn
 829     fn_arity           = idArity fn
 830     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 831     n_tyvars           = length tyvars
 832     n_dicts            = length theta
 833     inline_act         = idInlineActivation fn
 834
 835         -- It's important that we "see past" any INLINE pragma
 836         -- else we'll fail to specialise an INLINE thing
 837     (inline_rhs, rhs_inside) = dropInline rhs
 838     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs_inside
 839
 840     rhs_dict_ids = take n_dicts rhs_ids
 841     body         = mkLams (drop n_dicts rhs_ids) rhs_body
 842                 -- Glue back on the non-dict lambdas
 843
 844     calls_for_me = case lookupFM calls fn of
 845                         Nothing -> []
 846                         Just cs -> fmToList cs
 847
 848     already_covered :: [CoreExpr] -> Bool
 849     already_covered args          -- Note [Specialisations already covered]
 850        = isJust (lookupRule (const True) (substInScope subst)
 851                             fn args (idCoreRules fn))
 852
 853     mk_ty_args :: [Maybe Type] -> [CoreExpr]
 854     mk_ty_args call_ts = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 855                where
 856                   mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 857                   mk_ty_arg _         (Just ty) = Type ty
 858
 859     ----------------------------------------------------------
 860         -- Specialise to one particular call pattern
 861     spec_call :: (CallKey, ([DictExpr], VarSet))  -- Call instance
 862               -> SpecM (Maybe ((Id,CoreExpr),     -- Specialised definition
 863                                UsageDetails,      -- Usage details from specialised body
 864                                CoreRule))         -- Info for the Id's SpecEnv
 865     spec_call (CallKey call_ts, (call_ds, _))
 866       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts )
 867
 868         -- Suppose f's defn is  f = /\ a b c -> \ d1 d2 -> rhs
 869         -- Supppose the call is for f [Just t1, Nothing, Just t3] [dx1, dx2]
 870
 871         -- Construct the new binding
 872         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b -> rhs)
 873         -- PLUS the usage-details
 874         --      { d1' = dx1; d2' = dx2 }
 875         -- where d1', d2' are cloned versions of d1,d2, with the type substitution
 876         -- applied.  These auxiliary bindings just avoid duplication of dx1, dx2
 877         --
 878         -- Note that the substitution is applied to the whole thing.
 879         -- This is convenient, but just slightly fragile.  Notably:
 880         --      * There had better be no name clashes in a/b/c
 881         do { let
 882                 -- poly_tyvars = [b] in the example above
 883                 -- spec_tyvars = [a,c]
 884                 -- ty_args     = [t1,b,t3]
 885                 poly_tyvars   = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 886                 spec_tv_binds = [(tv,ty) | (tv, Just ty) <- rhs_tyvars `zip` call_ts]
 887                 spec_ty_args  = map snd spec_tv_binds
 888                 ty_args       = mk_ty_args call_ts
 889                 rhs_subst     = extendTvSubstList subst spec_tv_binds
 890
 891            ; (rhs_subst1, inst_dict_ids) <- cloneDictBndrs rhs_subst rhs_dict_ids
 892                           -- Clone rhs_dicts, including instantiating their types
 893
 894            ; let (rhs_subst2, dx_binds) = bindAuxiliaryDicts rhs_subst1 $
 895                                           (my_zipEqual rhs_dict_ids inst_dict_ids call_ds)
 896                  inst_args = ty_args ++ map Var inst_dict_ids
 897
 898            ; if already_covered inst_args then
 899                 return Nothing
 900              else do
 901            {    -- Figure out the type of the specialised function
 902              let body_ty = applyTypeToArgs rhs fn_type inst_args
 903                  (lam_args, app_args)           -- Add a dummy argument if body_ty is unlifted
 904                    | isUnLiftedType body_ty     -- C.f. WwLib.mkWorkerArgs
 905                    = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 906                    | otherwise = (poly_tyvars, poly_tyvars)
 907                  spec_id_ty = mkPiTypes lam_args body_ty
 908
 909            ; spec_f <- newSpecIdSM fn spec_id_ty
 910            ; let spec_f_w_arity = setIdArity spec_f (max 0 (fn_arity - n_dicts))
 911                 -- Adding arity information just propagates it a bit faster
 912                 -- See Note [Arity decrease] in Simplify
 913
 914            ; (spec_rhs, rhs_uds) <- specExpr rhs_subst2 (mkLams lam_args body)
 915            ; let
 916                 -- The rule to put in the function's specialisation is:
 917                 --      forall b, d1',d2'.  f t1 b t3 d1' d2' = f1 b
 918                 rule_name = mkFastString ("SPEC " ++ showSDoc (ppr fn <+> ppr spec_ty_args))
 919                 spec_env_rule = mkLocalRule
 920                                   rule_name
 921                                   inline_act    -- Note [Auto-specialisation and RULES]
 922                                   (idName fn)
 923                                   (poly_tyvars ++ inst_dict_ids)
 924                                   inst_args
 925                                   (mkVarApps (Var spec_f_w_arity) app_args)
 926
 927                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 928                 final_uds = foldr addDictBind rhs_uds dx_binds
 929
 930                 spec_pr | inline_rhs = (spec_f_w_arity `setInlineActivation` inline_act, Note InlineMe spec_rhs)
 931                         | otherwise  = (spec_f_w_arity,                                  spec_rhs)
 932
 933            ; return (Just (spec_pr, final_uds, spec_env_rule)) } }
 934       where
 935         my_zipEqual xs ys zs
 936          | debugIsOn && not (equalLength xs ys && equalLength ys zs)
 937              = pprPanic "my_zipEqual" (vcat [ ppr xs, ppr ys
 938                                             , ppr fn <+> ppr call_ts
 939                                             , ppr (idType fn), ppr theta
 940                                             , ppr n_dicts, ppr rhs_dict_ids
 941                                             , ppr rhs])
 942          | otherwise = zip3 xs ys zs
 943
 944 bindAuxiliaryDicts
 945         :: Subst
 946         -> [(DictId,DictId,CoreExpr)]   -- (orig_dict, inst_dict, dx)
 947         -> (Subst,                      -- Substitute for all orig_dicts
 948             [(DictId, CoreExpr)])       -- Auxiliary bindings
 949 -- Bind any dictionary arguments to fresh names, to preserve sharing
 950 -- Substitution already substitutes orig_dict -> inst_dict
 951 bindAuxiliaryDicts subst triples = go subst [] triples
 952   where
 953     go subst binds []    = (subst, binds)
 954     go subst binds ((d, dx_id, dx) : pairs)
 955       | exprIsTrivial dx = go (extendIdSubst subst d dx) binds pairs
 956              -- No auxiliary binding necessary
 957       | otherwise        = go subst_w_unf ((dx_id,dx) : binds) pairs
 958       where
 959         dx_id1 = dx_id `setIdUnfolding` mkUnfolding False dx
 960         subst_w_unf = extendIdSubst subst d (Var dx_id1)
 961              -- Important!  We're going to substitute dx_id1 for d
 962              -- and we want it to look "interesting", else we won't gather *any*
 963              -- consequential calls. E.g.
 964              --     f d = ...g d....
 965              -- If we specialise f for a call (f (dfun dNumInt)), we'll get
 966              -- a consequent call (g d') with an auxiliary definition
 967              --     d' = df dNumInt
 968              -- We want that consequent call to look interesting
 969 \end{code}
 970
 971 Note [Specialising a recursive group]
 972 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 973 Consider
 974     let rec { f x = ...g x'...
 975             ; g y = ...f y'.... }
 976     in f 'a'
 977 Here we specialise 'f' at Char; but that is very likely to lead to
 978 a specialisation of 'g' at Char.  We must do the latter, else the
 979 whole point of specialisation is lost.
 980
 981 But we do not want to keep iterating to a fixpoint, because in the
 982 presence of polymorphic recursion we might generate an infinite number
 983 of specialisations.
 984
 985 So we use the following heuristic:
 986   * Arrange the rec block in dependency order, so far as possible
 987     (the occurrence analyser already does this)
 988
 989   * Specialise it much like a sequence of lets
 990
 991   * Then go through the block a second time, feeding call-info from
 992     the RHSs back in the bottom, as it were
 993
 994 In effect, the ordering maxmimises the effectiveness of each sweep,
 995 and we do just two sweeps.   This should catch almost every case of
 996 monomorphic recursion -- the exception could be a very knotted-up
 997 recursion with multiple cycles tied up together.
 998
 999 This plan is implemented in the Rec case of specBindItself.
1000
1001 Note [Specialisations already covered]
1002 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1003 We obviously don't want to generate two specialisations for the same
1004 argument pattern.  There are two wrinkles
1005
1006 1. We do the already-covered test in specDefn, not when we generate
1007 the CallInfo in mkCallUDs.  We used to test in the latter place, but
1008 we now iterate the specialiser somewhat, and the Id at the call site
1009 might therefore not have all the RULES that we can see in specDefn
1010
1011 2. What about two specialisations where the second is an *instance*
1012 of the first?  If the more specific one shows up first, we'll generate
1013 specialisations for both.  If the *less* specific one shows up first,
1014 we *don't* currently generate a specialisation for the more specific
1015 one.  (See the call to lookupRule in already_covered.)  Reasons:
1016   (a) lookupRule doesn't say which matches are exact (bad reason)
1017   (b) if the earlier specialisation is user-provided, it's
1018       far from clear that we should auto-specialise further
1019
1020 Note [Auto-specialisation and RULES]
1021 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1022 Consider:
1023    g :: Num a => a -> a
1024    g = ...
1025
1026    f :: (Int -> Int) -> Int
1027    f w = ...
1028    {-# RULE f g = 0 #-}
1029
1030 Suppose that auto-specialisation makes a specialised version of
1031 g::Int->Int That version won't appear in the LHS of the RULE for f.
1032 So if the specialisation rule fires too early, the rule for f may
1033 never fire.
1034
1035 It might be possible to add new rules, to "complete" the rewrite system.
1036 Thus when adding
1037         RULE forall d. g Int d = g_spec
1038 also add
1039         RULE f g_spec = 0
1040
1041 But that's a bit complicated.  For now we ask the programmer's help,
1042 by *copying the INLINE activation pragma* to the auto-specialised rule.
1043 So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule will also
1044 not be active until phase 2.
1045
1046
1047 Note [Specialisation shape]
1048 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1049 We only specialise a function if it has visible top-level lambdas
1050 corresponding to its overloading.  E.g. if
1051         f :: forall a. Eq a => ....
1052 then its body must look like
1053         f = /\a. \d. ...
1054
1055 Reason: when specialising the body for a call (f ty dexp), we want to
1056 substitute dexp for d, and pick up specialised calls in the body of f.
1057
1058 This doesn't always work.  One example I came across was this:
1059         newtype Gen a = MkGen{ unGen :: Int -> a }
1060
1061         choose :: Eq a => a -> Gen a
1062         choose n = MkGen (\r -> n)
1063
1064         oneof = choose (1::Int)
1065
1066 It's a silly exapmle, but we get
1067         choose = /\a. g `cast` co
1068 where choose doesn't have any dict arguments.  Thus far I have not
1069 tried to fix this (wait till there's a real example).
1070
1071
1072 Note [Inline specialisations]
1073 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1074 We transfer to the specialised function any INLINE stuff from the
1075 original.  This means (a) the Activation in the IdInfo, and (b) any
1076 InlineMe on the RHS.  We do not, however, transfer the RuleMatchInfo
1077 since we do not expect the specialisation to occur in rewrite rules.
1078
1079 This is a change (Jun06).  Previously the idea is that the point of
1080 inlining was precisely to specialise the function at its call site,
1081 and that's not so important for the specialised copies.  But
1082 *pragma-directed* specialisation now takes place in the
1083 typechecker/desugarer, with manually specified INLINEs.  The
1084 specialiation here is automatic.  It'd be very odd if a function
1085 marked INLINE was specialised (because of some local use), and then
1086 forever after (including importing modules) the specialised version
1087 wasn't INLINEd.  After all, the programmer said INLINE!
1088
1089 You might wonder why we don't just not specialise INLINE functions.
1090 It's because even INLINE functions are sometimes not inlined, when
1091 they aren't applied to interesting arguments.  But perhaps the type
1092 arguments alone are enough to specialise (even though the args are too
1093 boring to trigger inlining), and it's certainly better to call the
1094 specialised version.
1095
1096 A case in point is dictionary functions, which are current marked
1097 INLINE, but which are worth specialising.
1098
1099 \begin{code}
1100 dropInline :: CoreExpr -> (Bool, CoreExpr)
1101 dropInline (Note InlineMe rhs) = (True,  rhs)
1102 dropInline rhs                 = (False, rhs)
1103 \end{code}
1104
1105 %************************************************************************
1106 %*                                                                      *
1107 \subsubsection{UsageDetails and suchlike}
1108 %*                                                                      *
1109 %************************************************************************
1110
1111 \begin{code}
1112 data UsageDetails
1113   = MkUD {
1114         dict_binds :: !(Bag DictBind),
1115                         -- Floated dictionary bindings
1116                         -- The order is important;
1117                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1118                         -- (Remember, Bags preserve order in GHC.)
1119
1120         calls     :: !CallDetails,
1121
1122         ud_fvs :: !VarSet       -- A superset of the variables mentioned in
1123                                 -- either dict_binds or calls
1124     }
1125
1126 instance Outputable UsageDetails where
1127   ppr (MkUD { dict_binds = dbs, calls = calls, ud_fvs = fvs })
1128         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma
1129                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1130                  ptext (sLit "calls") <+> equals <+> ppr calls,
1131                  ptext (sLit "fvs")   <+> equals <+> ppr fvs]))
1132
1133 type DictBind = (CoreBind, VarSet)
1134         -- The set is the free vars of the binding
1135         -- both tyvars and dicts
1136
1137 type DictExpr = CoreExpr
1138
1139 emptyUDs :: UsageDetails
1140 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM, ud_fvs = emptyVarSet }
1141
1142 ------------------------------------------------------------
1143 type CallDetails  = FiniteMap Id CallInfo
1144 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1145
1146 -- CallInfo uses a FiniteMap, thereby ensuring that
1147 -- we record only one call instance for any key
1148 --
1149 -- The list of types and dictionaries is guaranteed to
1150 -- match the type of f
1151 type CallInfo = FiniteMap CallKey ([DictExpr], VarSet)
1152                         -- Range is dict args and the vars of the whole
1153                         -- call (including tyvars)
1154                         -- [*not* include the main id itself, of course]
1155
1156 instance Outputable CallKey where
1157   ppr (CallKey ts) = ppr ts
1158
1159 -- Type isn't an instance of Ord, so that we can control which
1160 -- instance we use.  That's tiresome here.  Oh well
1161 instance Eq CallKey where
1162   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1163
1164 instance Ord CallKey where
1165   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1166                 where
1167                   cmp Nothing   Nothing   = EQ
1168                   cmp Nothing   (Just _)  = LT
1169                   cmp (Just _)  Nothing   = GT
1170                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1171
1172 unionCalls :: CallDetails -> CallDetails -> CallDetails
1173 unionCalls c1 c2 = plusFM_C plusFM c1 c2
1174
1175 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1176 singleCall id tys dicts
1177   = MkUD {dict_binds = emptyBag,
1178           calls      = unitFM id (unitFM (CallKey tys) (dicts, call_fvs)),
1179           ud_fvs     = call_fvs }
1180   where
1181     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1182     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1183         -- The type args (tys) are guaranteed to be part of the dictionary
1184         -- types, because they are just the constrained types,
1185         -- and the dictionary is therefore sure to be bound
1186         -- inside the binding for any type variables free in the type;
1187         -- hence it's safe to neglect tyvars free in tys when making
1188         -- the free-var set for this call
1189         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1190         --
1191         -- We don't include the 'id' itself.
1192
1193 mkCallUDs :: Id -> [CoreExpr] -> UsageDetails
1194 mkCallUDs f args
1195   | not (isLocalId f)   -- Imported from elsewhere
1196   || null theta         -- Not overloaded
1197   || not (all isClassPred theta)
1198         -- Only specialise if all overloading is on class params.
1199         -- In ptic, with implicit params, the type args
1200         --  *don't* say what the value of the implicit param is!
1201   || not (spec_tys `lengthIs` n_tyvars)
1202   || not ( dicts   `lengthIs` n_dicts)
1203   || not (any interestingArg dicts)     -- Note [Interesting dictionary arguments]
1204   -- See also Note [Specialisations already covered]
1205   = -- pprTrace "mkCallUDs: discarding" (vcat [ppr f, ppr args, ppr n_tyvars, ppr n_dicts, ppr (map interestingArg dicts)])
1206     emptyUDs    -- Not overloaded, or no specialisation wanted
1207
1208   | otherwise
1209   = -- pprTrace "mkCallUDs: keeping" (vcat [ppr f, ppr args, ppr n_tyvars, ppr n_dicts, ppr (map interestingArg dicts)])
1210     singleCall f spec_tys dicts
1211   where
1212     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1213     constrained_tyvars = tyVarsOfTheta theta
1214     n_tyvars           = length tyvars
1215     n_dicts            = length theta
1216
1217     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1218     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1219
1220     mk_spec_ty tyvar ty
1221         | tyvar `elemVarSet` constrained_tyvars = Just ty
1222         | otherwise                             = Nothing
1223 \end{code}
1224
1225 Note [Interesting dictionary arguments]
1226 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1227 Consider this
1228          \a.\d:Eq a.  let f = ... in ...(f d)...
1229 There really is not much point in specialising f wrt the dictionary d,
1230 because the code for the specialised f is not improved at all, because
1231 d is lambda-bound.  We simply get junk specialisations.
1232
1233 We re-use the function SimplUtils.interestingArg function to determine
1234 what sort of dictionary arguments have *some* information in them.
1235
1236
1237 \begin{code}
1238 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1239 plusUDs (MkUD {dict_binds = db1, calls = calls1, ud_fvs = fvs1})
1240         (MkUD {dict_binds = db2, calls = calls2, ud_fvs = fvs2})
1241   = MkUD {dict_binds = d, calls = c, ud_fvs = fvs1 `unionVarSet` fvs2}
1242   where
1243     d = db1    `unionBags`   db2
1244     c = calls1 `unionCalls`  calls2
1245
1246 plusUDList :: [UsageDetails] -> UsageDetails
1247 plusUDList = foldr plusUDs emptyUDs
1248
1249 -- zapCalls deletes calls to ids from uds
1250 zapCalls :: [Id] -> CallDetails -> CallDetails
1251 zapCalls ids calls = delListFromFM calls ids
1252
1253 mkDB :: CoreBind -> DictBind
1254 mkDB bind = (bind, bind_fvs bind)
1255
1256 bind_fvs :: CoreBind -> VarSet
1257 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1258 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1259                            where
1260                              bndrs = map fst prs
1261                              rhs_fvs = unionVarSets (map pair_fvs prs)
1262
1263 pair_fvs :: (Id, CoreExpr) -> VarSet
1264 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1265         -- Don't forget variables mentioned in the
1266         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1267         -- Also tyvars mentioned in its type; they may not appear in the RHS
1268         --      type T a = Int
1269         --      x :: T a = 3
1270
1271 addDictBind :: (Id,CoreExpr) -> UsageDetails -> UsageDetails
1272 addDictBind (dict,rhs) uds
1273   = uds { dict_binds = db `consBag` dict_binds uds
1274         , ud_fvs = ud_fvs uds `unionVarSet` fvs }
1275   where
1276     db@(_, fvs) = mkDB (NonRec dict rhs)
1277
1278 dumpAllDictBinds :: UsageDetails -> [CoreBind] -> [CoreBind]
1279 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1280   = foldrBag add binds dbs
1281   where
1282     add (bind,_) binds = bind : binds
1283
1284 dumpUDs :: [CoreBndr]
1285         -> UsageDetails -> CoreExpr
1286         -> (UsageDetails, CoreExpr)
1287 dumpUDs bndrs (MkUD { dict_binds = orig_dbs
1288                     , calls = orig_calls
1289                     , ud_fvs = fvs}) body
1290   = (new_uds, foldrBag add_let body dump_dbs)
1291                 -- This may delete fewer variables
1292                 -- than in priciple possible
1293   where
1294     new_uds =
1295      MkUD { dict_binds = free_dbs
1296           , calls      = free_calls
1297           , ud_fvs     = fvs `minusVarSet` bndr_set}
1298
1299     bndr_set = mkVarSet bndrs
1300     add_let (bind,_) body = Let bind body
1301
1302     (free_dbs, dump_dbs, dump_set)
1303         = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1304                 -- Important that it's foldl not foldr;
1305                 -- we're accumulating the set of dumped ids in dump_set
1306
1307     free_calls = filterCalls dump_set orig_calls
1308
1309     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1310         | dump_idset `intersectsVarSet` fvs     -- Dump it
1311         = (free_dbs, dump_dbs `snocBag` db,
1312            extendVarSetList dump_idset (bindersOf bind))
1313
1314         | otherwise     -- Don't dump it
1315         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1316
1317 filterCalls :: VarSet -> CallDetails -> CallDetails
1318 -- Remove any calls that mention the variables
1319 filterCalls bs calls
1320   = mapFM (\_ cs -> filter_calls cs) $
1321     filterFM (\k _ -> not (k `elemVarSet` bs)) calls
1322   where
1323     filter_calls :: CallInfo -> CallInfo
1324     filter_calls = filterFM (\_ (_, fvs) -> not (fvs `intersectsVarSet` bs))
1325 \end{code}
1326
1327
1328 %************************************************************************
1329 %*                                                                      *
1330 \subsubsection{Boring helper functions}
1331 %*                                                                      *
1332 %************************************************************************
1333
1334 \begin{code}
1335 type SpecM a = UniqSM a
1336
1337 initSM :: UniqSupply -> SpecM a -> a
1338 initSM    = initUs_
1339
1340 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1341 mapAndCombineSM _ []     = return ([], emptyUDs)
1342 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1343                               (ys, uds2) <- mapAndCombineSM f xs
1344                               return (y:ys, uds1 `plusUDs` uds2)
1345
1346 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1347 -- Clone the binders of the bind; return new bind with the cloned binders
1348 -- Return the substitution to use for RHSs, and the one to use for the body
1349 cloneBindSM subst (NonRec bndr rhs) = do
1350     us <- getUniqueSupplyM
1351     let (subst', bndr') = cloneIdBndr subst us bndr
1352     return (subst, subst', NonRec bndr' rhs)
1353
1354 cloneBindSM subst (Rec pairs) = do
1355     us <- getUniqueSupplyM
1356     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1357     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1358
1359 cloneDictBndrs :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1360 cloneDictBndrs subst bndrs
1361   = do { us <- getUniqueSupplyM
1362        ; return (cloneIdBndrs subst us bndrs) }
1363
1364 newSpecIdSM :: Id -> Type -> SpecM Id
1365     -- Give the new Id a similar occurrence name to the old one
1366 newSpecIdSM old_id new_ty
1367   = do  { uniq <- getUniqueM
1368         ; let
1369             name    = idName old_id
1370             new_occ = mkSpecOcc (nameOccName name)
1371             new_id  = mkUserLocal new_occ uniq new_ty (getSrcSpan name)
1372         ; return new_id }
1373 \end{code}
1374
1375
1376                 Old (but interesting) stuff about unboxed bindings
1377                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1378
1379 What should we do when a value is specialised to a *strict* unboxed value?
1380
1381         map_*_* f (x:xs) = let h = f x
1382                                t = map f xs
1383                            in h:t
1384
1385 Could convert let to case:
1386
1387         map_*_Int# f (x:xs) = case f x of h# ->
1388                               let t = map f xs
1389                               in h#:t
1390
1391 This may be undesirable since it forces evaluation here, but the value
1392 may not be used in all branches of the body. In the general case this
1393 transformation is impossible since the mutual recursion in a letrec
1394 cannot be expressed as a case.
1395
1396 There is also a problem with top-level unboxed values, since our
1397 implementation cannot handle unboxed values at the top level.
1398
1399 Solution: Lift the binding of the unboxed value and extract it when it
1400 is used:
1401
1402         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1403                                   t = map f xs
1404                               in case h of
1405                                  _Lift h# -> h#:t
1406
1407 Now give it to the simplifier and the _Lifting will be optimised away.
1408
1409 The benfit is that we have given the specialised "unboxed" values a
1410 very simplep lifted semantics and then leave it up to the simplifier to
1411 optimise it --- knowing that the overheads will be removed in nearly
1412 all cases.
1413
1414 In particular, the value will only be evaluted in the branches of the
1415 program which use it, rather than being forced at the point where the
1416 value is bound. For example:
1417
1418         filtermap_*_* p f (x:xs)
1419           = let h = f x
1420                 t = ...
1421             in case p x of
1422                 True  -> h:t
1423                 False -> t
1424    ==>
1425         filtermap_*_Int# p f (x:xs)
1426           = let h = case (f x) of h# -> _Lift h#
1427                 t = ...
1428             in case p x of
1429                 True  -> case h of _Lift h#
1430                            -> h#:t
1431                 False -> t
1432
1433 The binding for h can still be inlined in the one branch and the
1434 _Lifting eliminated.
1435
1436
1437 Question: When won't the _Lifting be eliminated?
1438
1439 Answer: When they at the top-level (where it is necessary) or when
1440 inlining would duplicate work (or possibly code depending on
1441 options). However, the _Lifting will still be eliminated if the
1442 strictness analyser deems the lifted binding strict.
1443