compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 -- The above warning supression flag is a temporary kludge.
   8 -- While working on this module you are encouraged to remove it and fix
   9 -- any warnings in the module. See
  10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  11 -- for details
  12
  13 module Specialise ( specProgram ) where
  14
  15 #include "HsVersions.h"
  16
  17 import DynFlags ( DynFlags, DynFlag(..) )
  18 import Id               ( Id, idName, idType, mkUserLocal,
  19                           idInlinePragma, setInlinePragma )
  20 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  21                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  22                           tcCmpType, isUnLiftedType
  23                         )
  24 import CoreSubst        ( Subst, mkEmptySubst, extendTvSubstList, lookupIdSubst,
  25                           substBndr, substBndrs, substTy, substInScope,
  26                           cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs
  27                         )
  28 import VarSet
  29 import VarEnv
  30 import CoreSyn
  31 import Rules
  32 import CoreUtils        ( applyTypeToArgs, mkPiTypes )
  33 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  34 import CoreLint         ( showPass, endPass )
  35 import UniqSupply       ( UniqSupply,
  36                           UniqSM, initUs_,
  37                           MonadUnique(..)
  38                         )
  39 import Name
  40 import MkId             ( voidArgId, realWorldPrimId )
  41 import FiniteMap
  42 import Maybes           ( catMaybes, maybeToBool )
  43 import ErrUtils         ( dumpIfSet_dyn )
  44 import Bag
  45 import Util
  46 import Outputable
  47 import FastString
  48
  49 \end{code}
  50
  51 %************************************************************************
  52 %*                                                                      *
  53 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  54 %*                                                                      *
  55 %************************************************************************
  56
  57 These notes describe how we implement specialisation to eliminate
  58 overloading.
  59
  60 The specialisation pass works on Core
  61 syntax, complete with all the explicit dictionary application,
  62 abstraction and construction as added by the type checker.  The
  63 existing type checker remains largely as it is.
  64
  65 One important thought: the {\em types} passed to an overloaded
  66 function, and the {\em dictionaries} passed are mutually redundant.
  67 If the same function is applied to the same type(s) then it is sure to
  68 be applied to the same dictionary(s)---or rather to the same {\em
  69 values}.  (The arguments might look different but they will evaluate
  70 to the same value.)
  71
  72 Second important thought: we know that we can make progress by
  73 treating dictionary arguments as static and worth specialising on.  So
  74 we can do without binding-time analysis, and instead specialise on
  75 dictionary arguments and no others.
  76
  77 The basic idea
  78 ~~~~~~~~~~~~~~
  79 Suppose we have
  80
  81         let f = <f_rhs>
  82         in <body>
  83
  84 and suppose f is overloaded.
  85
  86 STEP 1: CALL-INSTANCE COLLECTION
  87
  88 We traverse <body>, accumulating all applications of f to types and
  89 dictionaries.
  90
  91 (Might there be partial applications, to just some of its types and
  92 dictionaries?  In principle yes, but in practice the type checker only
  93 builds applications of f to all its types and dictionaries, so partial
  94 applications could only arise as a result of transformation, and even
  95 then I think it's unlikely.  In any case, we simply don't accumulate such
  96 partial applications.)
  97
  98
  99 STEP 2: EQUIVALENCES
 100
 101 So now we have a collection of calls to f:
 102         f t1 t2 d1 d2
 103         f t3 t4 d3 d4
 104         ...
 105 Notice that f may take several type arguments.  To avoid ambiguity, we
 106 say that f is called at type t1/t2 and t3/t4.
 107
 108 We take equivalence classes using equality of the *types* (ignoring
 109 the dictionary args, which as mentioned previously are redundant).
 110
 111 STEP 3: SPECIALISATION
 112
 113 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 114 and create a local instance of f, defined thus:
 115
 116         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 117
 118 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 119 of simplification will now result.  However we don't actually *do* that
 120 simplification.  Rather, we leave it for the simplifier to do.  If we
 121 *did* do it, though, we'd get more call instances from the specialised
 122 RHS.  We can work out what they are by instantiating the call-instance
 123 set from f's RHS with the types t1, t2.
 124
 125 Add this new id to f's IdInfo, to record that f has a specialised version.
 126
 127 Before doing any of this, check that f's IdInfo doesn't already
 128 tell us about an existing instance of f at the required type/s.
 129 (This might happen if specialisation was applied more than once, or
 130 it might arise from user SPECIALIZE pragmas.)
 131
 132 Recursion
 133 ~~~~~~~~~
 134 Wait a minute!  What if f is recursive?  Then we can't just plug in
 135 its right-hand side, can we?
 136
 137 But it's ok.  The type checker *always* creates non-recursive definitions
 138 for overloaded recursive functions.  For example:
 139
 140         f x = f (x+x)           -- Yes I know its silly
 141
 142 becomes
 143
 144         f a (d::Num a) = let p = +.sel a d
 145                          in
 146                          letrec fl (y::a) = fl (p y y)
 147                          in
 148                          fl
 149
 150 We still have recusion for non-overloaded functions which we
 151 speciailise, but the recursive call should get specialised to the
 152 same recursive version.
 153
 154
 155 Polymorphism 1
 156 ~~~~~~~~~~~~~~
 157
 158 All this is crystal clear when the function is applied to *constant
 159 types*; that is, types which have no type variables inside.  But what if
 160 it is applied to non-constant types?  Suppose we find a call of f at type
 161 t1/t2.  There are two possibilities:
 162
 163 (a) The free type variables of t1, t2 are in scope at the definition point
 164 of f.  In this case there's no problem, we proceed just as before.  A common
 165 example is as follows.  Here's the Haskell:
 166
 167         g y = let f x = x+x
 168               in f y + f y
 169
 170 After typechecking we have
 171
 172         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 173                                 in +.sel a d (f a d y) (f a d y)
 174
 175 Notice that the call to f is at type type "a"; a non-constant type.
 176 Both calls to f are at the same type, so we can specialise to give:
 177
 178         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 179                                 in +.sel a d (f@a y) (f@a y)
 180
 181
 182 (b) The other case is when the type variables in the instance types
 183 are *not* in scope at the definition point of f.  The example we are
 184 working with above is a good case.  There are two instances of (+.sel a d),
 185 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 186 Yes, we can "common them up", a sort of limited common sub-expression deal.
 187 This would give:
 188
 189         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 190                                     f@a (x::a) = +.sel@a x x
 191                                 in +.sel@a (f@a y) (f@a y)
 192
 193 This can save work, and can't be spotted by the type checker, because
 194 the two instances of +.sel weren't originally at the same type.
 195
 196 Further notes on (b)
 197
 198 * There are quite a few variations here.  For example, the defn of
 199   +.sel could be floated ouside the \y, to attempt to gain laziness.
 200   It certainly mustn't be floated outside the \d because the d has to
 201   be in scope too.
 202
 203 * We don't want to inline f_rhs in this case, because
 204 that will duplicate code.  Just commoning up the call is the point.
 205
 206 * Nothing gets added to +.sel's IdInfo.
 207
 208 * Don't bother unless the equivalence class has more than one item!
 209
 210 Not clear whether this is all worth it.  It is of course OK to
 211 simply discard call-instances when passing a big lambda.
 212
 213 Polymorphism 2 -- Overloading
 214 ~~~~~~~~~~~~~~
 215 Consider a function whose most general type is
 216
 217         f :: forall a b. Ord a => [a] -> b -> b
 218
 219 There is really no point in making a version of g at Int/Int and another
 220 at Int/Bool, because it's only instancing the type variable "a" which
 221 buys us any efficiency. Since g is completely polymorphic in b there
 222 ain't much point in making separate versions of g for the different
 223 b types.
 224
 225 That suggests that we should identify which of g's type variables
 226 are constrained (like "a") and which are unconstrained (like "b").
 227 Then when taking equivalence classes in STEP 2, we ignore the type args
 228 corresponding to unconstrained type variable.  In STEP 3 we make
 229 polymorphic versions.  Thus:
 230
 231         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 232
 233 We do this.
 234
 235
 236 Dictionary floating
 237 ~~~~~~~~~~~~~~~~~~~
 238 Consider this
 239
 240         f a (d::Num a) = let g = ...
 241                          in
 242                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 243
 244 Here, g is only called at one type, but the dictionary isn't in scope at the
 245 definition point for g.  Usually the type checker would build a
 246 definition for d1 which enclosed g, but the transformation system
 247 might have moved d1's defn inward.  Solution: float dictionary bindings
 248 outwards along with call instances.
 249
 250 Consider
 251
 252         f x = let g p q = p==q
 253                   h r s = (r+s, g r s)
 254               in
 255               h x x
 256
 257
 258 Before specialisation, leaving out type abstractions we have
 259
 260         f df x = let g :: Eq a => a -> a -> Bool
 261                      g dg p q = == dg p q
 262                      h :: Num a => a -> a -> (a, Bool)
 263                      h dh r s = let deq = eqFromNum dh
 264                                 in (+ dh r s, g deq r s)
 265               in
 266               h df x x
 267
 268 After specialising h we get a specialised version of h, like this:
 269
 270                     h' r s = let deq = eqFromNum df
 271                              in (+ df r s, g deq r s)
 272
 273 But we can't naively make an instance for g from this, because deq is not in scope
 274 at the defn of g.  Instead, we have to float out the (new) defn of deq
 275 to widen its scope.  Notice that this floating can't be done in advance -- it only
 276 shows up when specialisation is done.
 277
 278 User SPECIALIZE pragmas
 279 ~~~~~~~~~~~~~~~~~~~~~~~
 280 Specialisation pragmas can be digested by the type checker, and implemented
 281 by adding extra definitions along with that of f, in the same way as before
 282
 283         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 284
 285 Indeed the pragmas *have* to be dealt with by the type checker, because
 286 only it knows how to build the dictionaries d1 and d2!  For example
 287
 288         g :: Ord a => [a] -> [a]
 289         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 290
 291 Here, the specialised version of g is an application of g's rhs to the
 292 Ord dictionary for (Tree Int), which only the type checker can conjure
 293 up.  There might not even *be* one, if (Tree Int) is not an instance of
 294 Ord!  (All the other specialision has suitable dictionaries to hand
 295 from actual calls.)
 296
 297 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 298 it is buried in a complex (as-yet-un-desugared) binding group.
 299 Maybe we should say
 300
 301         f@t1/t2 = f* t1 t2 d1 d2
 302
 303 where f* is the Id f with an IdInfo which says "inline me regardless!".
 304 Indeed all the specialisation could be done in this way.
 305 That in turn means that the simplifier has to be prepared to inline absolutely
 306 any in-scope let-bound thing.
 307
 308
 309 Again, the pragma should permit polymorphism in unconstrained variables:
 310
 311         h :: Ord a => [a] -> b -> b
 312         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 313
 314 We *insist* that all overloaded type variables are specialised to ground types,
 315 (and hence there can be no context inside a SPECIALIZE pragma).
 316 We *permit* unconstrained type variables to be specialised to
 317         - a ground type
 318         - or left as a polymorphic type variable
 319 but nothing in between.  So
 320
 321         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 322
 323 is *illegal*.  (It can be handled, but it adds complication, and gains the
 324 programmer nothing.)
 325
 326
 327 SPECIALISING INSTANCE DECLARATIONS
 328 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 329 Consider
 330
 331         instance Foo a => Foo [a] where
 332                 ...
 333         {-# SPECIALIZE instance Foo [Int] #-}
 334
 335 The original instance decl creates a dictionary-function
 336 definition:
 337
 338         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 339
 340 The SPECIALIZE pragma just makes a specialised copy, just as for
 341 ordinary function definitions:
 342
 343         dfun.Foo.List@Int :: Foo [Int]
 344         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 345
 346 The information about what instance of the dfun exist gets added to
 347 the dfun's IdInfo in the same way as a user-defined function too.
 348
 349
 350 Automatic instance decl specialisation?
 351 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 352 Can instance decls be specialised automatically?  It's tricky.
 353 We could collect call-instance information for each dfun, but
 354 then when we specialised their bodies we'd get new call-instances
 355 for ordinary functions; and when we specialised their bodies, we might get
 356 new call-instances of the dfuns, and so on.  This all arises because of
 357 the unrestricted mutual recursion between instance decls and value decls.
 358
 359 Still, there's no actual problem; it just means that we may not do all
 360 the specialisation we could theoretically do.
 361
 362 Furthermore, instance decls are usually exported and used non-locally,
 363 so we'll want to compile enough to get those specialisations done.
 364
 365 Lastly, there's no such thing as a local instance decl, so we can
 366 survive solely by spitting out *usage* information, and then reading that
 367 back in as a pragma when next compiling the file.  So for now,
 368 we only specialise instance decls in response to pragmas.
 369
 370
 371 SPITTING OUT USAGE INFORMATION
 372 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 373
 374 To spit out usage information we need to traverse the code collecting
 375 call-instance information for all imported (non-prelude?) functions
 376 and data types. Then we equivalence-class it and spit it out.
 377
 378 This is done at the top-level when all the call instances which escape
 379 must be for imported functions and data types.
 380
 381 *** Not currently done ***
 382
 383
 384 Partial specialisation by pragmas
 385 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 386 What about partial specialisation:
 387
 388         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 389         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 390
 391 or even
 392
 393         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 394
 395 Seems quite reasonable.  Similar things could be done with instance decls:
 396
 397         instance (Foo a, Foo b) => Foo (a,b) where
 398                 ...
 399         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 400         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 401
 402 Ho hum.  Things are complex enough without this.  I pass.
 403
 404
 405 Requirements for the simplifer
 406 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 407 The simplifier has to be able to take advantage of the specialisation.
 408
 409 * When the simplifier finds an application of a polymorphic f, it looks in
 410 f's IdInfo in case there is a suitable instance to call instead.  This converts
 411
 412         f t1 t2 d1 d2   ===>   f_t1_t2
 413
 414 Note that the dictionaries get eaten up too!
 415
 416 * Dictionary selection operations on constant dictionaries must be
 417   short-circuited:
 418
 419         +.sel Int d     ===>  +Int
 420
 421 The obvious way to do this is in the same way as other specialised
 422 calls: +.sel has inside it some IdInfo which tells that if it's applied
 423 to the type Int then it should eat a dictionary and transform to +Int.
 424
 425 In short, dictionary selectors need IdInfo inside them for constant
 426 methods.
 427
 428 * Exactly the same applies if a superclass dictionary is being
 429   extracted:
 430
 431         Eq.sel Int d   ===>   dEqInt
 432
 433 * Something similar applies to dictionary construction too.  Suppose
 434 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 435 one for (Eq [a]).  Then we want
 436
 437         dfun.Eq.List Int d      ===> dEq.List_Int
 438
 439 Where does the Eq [Int] dictionary come from?  It is built in
 440 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 441
 442 In short, dfun Ids need IdInfo with a specialisation for each
 443 constant instance of their instance declaration.
 444
 445 All this uses a single mechanism: the SpecEnv inside an Id
 446
 447
 448 What does the specialisation IdInfo look like?
 449 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 450
 451 The SpecEnv of an Id maps a list of types (the template) to an expression
 452
 453         [Type]  |->  Expr
 454
 455 For example, if f has this SpecInfo:
 456
 457         [Int, a]  ->  \d:Ord Int. f' a
 458
 459 it means that we can replace the call
 460
 461         f Int t  ===>  (\d. f' t)
 462
 463 This chucks one dictionary away and proceeds with the
 464 specialised version of f, namely f'.
 465
 466
 467 What can't be done this way?
 468 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 469 There is no way, post-typechecker, to get a dictionary for (say)
 470 Eq a from a dictionary for Eq [a].  So if we find
 471
 472         ==.sel [t] d
 473
 474 we can't transform to
 475
 476         eqList (==.sel t d')
 477
 478 where
 479         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 480
 481 Of course, we currently have no way to automatically derive
 482 eqList, nor to connect it to the Eq [a] instance decl, but you
 483 can imagine that it might somehow be possible.  Taking advantage
 484 of this is permanently ruled out.
 485
 486 Still, this is no great hardship, because we intend to eliminate
 487 overloading altogether anyway!
 488
 489
 490
 491 A note about non-tyvar dictionaries
 492 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 493 Some Ids have types like
 494
 495         forall a,b,c. Eq a -> Ord [a] -> tau
 496
 497 This seems curious at first, because we usually only have dictionary
 498 args whose types are of the form (C a) where a is a type variable.
 499 But this doesn't hold for the functions arising from instance decls,
 500 which sometimes get arguements with types of form (C (T a)) for some
 501 type constructor T.
 502
 503 Should we specialise wrt this compound-type dictionary?  We used to say
 504 "no", saying:
 505         "This is a heuristic judgement, as indeed is the fact that we
 506         specialise wrt only dictionaries.  We choose *not* to specialise
 507         wrt compound dictionaries because at the moment the only place
 508         they show up is in instance decls, where they are simply plugged
 509         into a returned dictionary.  So nothing is gained by specialising
 510         wrt them."
 511
 512 But it is simpler and more uniform to specialise wrt these dicts too;
 513 and in future GHC is likely to support full fledged type signatures
 514 like
 515         f ;: Eq [(a,b)] => ...
 516
 517
 518 %************************************************************************
 519 %*                                                                      *
 520 \subsubsection{The new specialiser}
 521 %*                                                                      *
 522 %************************************************************************
 523
 524 Our basic game plan is this.  For let(rec) bound function
 525         f :: (C a, D c) => (a,b,c,d) -> Bool
 526
 527 * Find any specialised calls of f, (f ts ds), where
 528   ts are the type arguments t1 .. t4, and
 529   ds are the dictionary arguments d1 .. d2.
 530
 531 * Add a new definition for f1 (say):
 532
 533         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 534
 535   Note that we abstract over the unconstrained type arguments.
 536
 537 * Add the mapping
 538
 539         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 540
 541   to the specialisations of f.  This will be used by the
 542   simplifier to replace calls
 543                 (f t1 t2 t3 t4) da db
 544   by
 545                 (\d1 d1 -> f1 t2 t4) da db
 546
 547   All the stuff about how many dictionaries to discard, and what types
 548   to apply the specialised function to, are handled by the fact that the
 549   SpecEnv contains a template for the result of the specialisation.
 550
 551 We don't build *partial* specialisations for f.  For example:
 552
 553   f :: Eq a => a -> a -> Bool
 554   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 555
 556 Here, little is gained by making a specialised copy of f.
 557 There's a distinct danger that the specialised version would
 558 first build a dictionary for (Eq b, Eq c), and then select the (==)
 559 method from it!  Even if it didn't, not a great deal is saved.
 560
 561 We do, however, generate polymorphic, but not overloaded, specialisations:
 562
 563   f :: Eq a => [a] -> b -> b -> b
 564   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 565
 566 Hence, the invariant is this:
 567
 568         *** no specialised version is overloaded ***
 569
 570
 571 %************************************************************************
 572 %*                                                                      *
 573 \subsubsection{The exported function}
 574 %*                                                                      *
 575 %************************************************************************
 576
 577 \begin{code}
 578 specProgram :: DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]
 579 specProgram dflags us binds = do
 580
 581         showPass dflags "Specialise"
 582
 583         let binds' = initSM us (do (binds', uds') <- go binds
 584                                    return (dumpAllDictBinds uds' binds'))
 585
 586         endPass dflags "Specialise" Opt_D_dump_spec binds'
 587
 588         dumpIfSet_dyn dflags Opt_D_dump_rules "Top-level specialisations"
 589                       (pprRulesForUser (rulesOfBinds binds'))
 590
 591         return binds'
 592   where
 593         -- We need to start with a Subst that knows all the things
 594         -- that are in scope, so that the substitution engine doesn't
 595         -- accidentally re-use a unique that's already in use
 596         -- Easiest thing is to do it all at once, as if all the top-level
 597         -- decls were mutually recursive
 598     top_subst       = mkEmptySubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 599
 600     go []           = return ([], emptyUDs)
 601     go (bind:binds) = do (binds', uds) <- go binds
 602                          (bind', uds') <- specBind top_subst bind uds
 603                          return (bind' ++ binds', uds')
 604 \end{code}
 605
 606 %************************************************************************
 607 %*                                                                      *
 608 \subsubsection{@specExpr@: the main function}
 609 %*                                                                      *
 610 %************************************************************************
 611
 612 \begin{code}
 613 specVar :: Subst -> Id -> CoreExpr
 614 specVar subst v = lookupIdSubst subst v
 615
 616 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 617 -- We carry a substitution down:
 618 --      a) we must clone any binding that might flaot outwards,
 619 --         to avoid name clashes
 620 --      b) we carry a type substitution to use when analysing
 621 --         the RHS of specialised bindings (no type-let!)
 622
 623 ---------------- First the easy cases --------------------
 624 specExpr subst (Type ty) = return (Type (substTy subst ty), emptyUDs)
 625 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
 626 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
 627 specExpr subst (Cast e co) = do
 628     (e', uds) <- specExpr subst e
 629     return ((Cast e' (substTy subst co)), uds)
 630 specExpr subst (Note note body) = do
 631     (body', uds) <- specExpr subst body
 632     return (Note (specNote subst note) body', uds)
 633
 634
 635 ---------------- Applications might generate a call instance --------------------
 636 specExpr subst expr@(App {})
 637   = go expr []
 638   where
 639     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
 640                                (fun', uds_app) <- go fun (arg':args)
 641                                return (App fun' arg', uds_arg `plusUDs` uds_app)
 642
 643     go (Var f)       args = case specVar subst f of
 644                                 Var f' -> return (Var f', mkCallUDs subst f' args)
 645                                 e'     -> return (e', emptyUDs) -- I don't expect this!
 646     go other         _    = specExpr subst other
 647
 648 ---------------- Lambda/case require dumping of usage details --------------------
 649 specExpr subst e@(Lam _ _) = do
 650     (body', uds) <- specExpr subst' body
 651     let (filtered_uds, body'') = dumpUDs bndrs' uds body'
 652     return (mkLams bndrs' body'', filtered_uds)
 653   where
 654     (bndrs, body) = collectBinders e
 655     (subst', bndrs') = substBndrs subst bndrs
 656         -- More efficient to collect a group of binders together all at once
 657         -- and we don't want to split a lambda group with dumped bindings
 658
 659 specExpr subst (Case scrut case_bndr ty alts) = do
 660     (scrut', uds_scrut) <- specExpr subst scrut
 661     (alts', uds_alts) <- mapAndCombineSM spec_alt alts
 662     return (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 663   where
 664     (subst_alt, case_bndr') = substBndr subst case_bndr
 665         -- No need to clone case binder; it can't float like a let(rec)
 666
 667     spec_alt (con, args, rhs) = do
 668           (rhs', uds) <- specExpr subst_rhs rhs
 669           let (uds', rhs'') = dumpUDs args uds rhs'
 670           return ((con, args', rhs''), uds')
 671         where
 672           (subst_rhs, args') = substBndrs subst_alt args
 673
 674 ---------------- Finally, let is the interesting case --------------------
 675 specExpr subst (Let bind body) = do
 676         -- Clone binders
 677     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
 678
 679         -- Deal with the body
 680     (body', body_uds) <- specExpr body_subst body
 681
 682         -- Deal with the bindings
 683     (binds', uds) <- specBind rhs_subst bind' body_uds
 684
 685         -- All done
 686     return (foldr Let body' binds', uds)
 687
 688 -- Must apply the type substitution to coerceions
 689 specNote :: Subst -> Note -> Note
 690 specNote _ note = note
 691 \end{code}
 692
 693 %************************************************************************
 694 %*                                                                      *
 695 \subsubsection{Dealing with a binding}
 696 %*                                                                      *
 697 %************************************************************************
 698
 699 \begin{code}
 700 specBind :: Subst                       -- Use this for RHSs
 701          -> CoreBind
 702          -> UsageDetails                -- Info on how the scope of the binding
 703          -> SpecM ([CoreBind],          -- New bindings
 704                    UsageDetails)        -- And info to pass upstream
 705
 706 specBind rhs_subst bind body_uds
 707   = do  { (bind', bind_uds) <- specBindItself rhs_subst bind (calls body_uds)
 708         ; return (finishSpecBind bind' bind_uds body_uds) }
 709
 710 finishSpecBind :: CoreBind -> UsageDetails -> UsageDetails -> ([CoreBind], UsageDetails)
 711 finishSpecBind bind
 712         (MkUD { dict_binds = rhs_dbs,  calls = rhs_calls,  ud_fvs = rhs_fvs })
 713         (MkUD { dict_binds = body_dbs, calls = body_calls, ud_fvs = body_fvs })
 714   | not (mkVarSet bndrs `intersectsVarSet` all_fvs)
 715                 -- Common case 1: the bound variables are not
 716                 --                mentioned in the dictionary bindings
 717   = ([bind], MkUD { dict_binds = body_dbs `unionBags` rhs_dbs
 718                         -- It's important that the `unionBags` is this way round,
 719                         -- because body_uds may bind dictionaries that are
 720                         -- used in the calls passed to specDefn.  So the
 721                         -- dictionary bindings in rhs_uds may mention
 722                         -- dictionaries bound in body_uds.
 723                   , calls  = all_calls
 724                   , ud_fvs = all_fvs })
 725
 726   | case bind of { NonRec {} -> True; Rec {} -> False }
 727                 -- Common case 2: no specialisation happened, and binding
 728                 --                is non-recursive.  But the binding may be
 729                 --                mentioned in body_dbs, so we should put it first
 730   = ([], MkUD { dict_binds = rhs_dbs `unionBags` ((bind, b_fvs) `consBag` body_dbs)
 731               , calls      = all_calls
 732               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 733
 734   | otherwise   -- General case: make a huge Rec (sigh)
 735   = ([], MkUD { dict_binds = unitBag (Rec all_db_prs, all_db_fvs)
 736               , calls      = all_calls
 737               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 738   where
 739     all_fvs = rhs_fvs `unionVarSet` body_fvs
 740     all_calls = zapCalls bndrs (rhs_calls `unionCalls` body_calls)
 741
 742     bndrs   = bindersOf bind
 743     b_fvs   = bind_fvs bind
 744
 745     (all_db_prs, all_db_fvs) = add (bind, b_fvs) $
 746                                foldrBag add ([], emptyVarSet) $
 747                                rhs_dbs `unionBags` body_dbs
 748     add (NonRec b r, b_fvs) (prs, fvs) = ((b,r)  : prs, b_fvs `unionVarSet` fvs)
 749     add (Rec b_prs,  b_fvs) (prs, fvs) = (b_prs ++ prs, b_fvs `unionVarSet` fvs)
 750
 751 specBindItself :: Subst -> CoreBind -> CallDetails -> SpecM (CoreBind, UsageDetails)
 752
 753 -- specBindItself deals with the RHS, specialising it according
 754 -- to the calls found in the body (if any)
 755 specBindItself rhs_subst (NonRec bndr rhs) call_info = do
 756     ((bndr',rhs'), spec_defns, spec_uds) <- specDefn rhs_subst call_info (bndr,rhs)
 757     let
 758         new_bind | null spec_defns = NonRec bndr' rhs'
 759                  | otherwise       = Rec ((bndr',rhs'):spec_defns)
 760                 -- bndr' mentions the spec_defns in its SpecEnv
 761                 -- Not sure why we couln't just put the spec_defns first
 762     return (new_bind, spec_uds)
 763
 764 specBindItself rhs_subst (Rec pairs) call_info = do
 765     stuff <- mapM (specDefn rhs_subst call_info) pairs
 766     let
 767         (pairs', spec_defns_s, spec_uds_s) = unzip3 stuff
 768         spec_defns = concat spec_defns_s
 769         spec_uds   = plusUDList spec_uds_s
 770         new_bind   = Rec (spec_defns ++ pairs')
 771     return (new_bind, spec_uds)
 772
 773
 774 specDefn :: Subst                       -- Subst to use for RHS
 775          -> CallDetails                 -- Info on how it is used in its scope
 776          -> (Id, CoreExpr)              -- The thing being bound and its un-processed RHS
 777          -> SpecM ((Id, CoreExpr),      -- The thing and its processed RHS
 778                                         --      the Id may now have specialisations attached
 779                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 780                    UsageDetails         -- Stuff to fling upwards from the RHS and its
 781             )                           --      specialised versions
 782
 783 specDefn subst calls (fn, rhs)
 784         -- The first case is the interesting one
 785   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 786   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 787   && notNull calls_for_me               -- And there are some calls to specialise
 788
 789 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 790 --      See Note [Inline specialisation] for why we do not
 791 --      switch off specialisation for inline functions = do
 792   = do
 793      -- Specialise the body of the function
 794     (rhs', rhs_uds) <- specExpr subst rhs
 795
 796       -- Make a specialised version for each call in calls_for_me
 797     stuff <- mapM spec_call calls_for_me
 798     let
 799         (spec_defns, spec_uds, spec_rules) = unzip3 stuff
 800
 801         fn' = addIdSpecialisations fn spec_rules
 802
 803     return ((fn',rhs'),
 804               spec_defns,
 805               rhs_uds `plusUDs` plusUDList spec_uds)
 806
 807   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 808   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") <+> ppr fn )
 809           -- Note [Specialisation shape]
 810     (do  { (rhs', rhs_uds) <- specExpr subst rhs
 811         ; return ((fn, rhs'), [], rhs_uds) })
 812
 813   where
 814     fn_type            = idType fn
 815     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 816     n_tyvars           = length tyvars
 817     n_dicts            = length theta
 818     inline_prag        = idInlinePragma fn
 819
 820         -- It's important that we "see past" any INLINE pragma
 821         -- else we'll fail to specialise an INLINE thing
 822     (inline_rhs, rhs_inside) = dropInline rhs
 823     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs_inside
 824
 825     rhs_dicts = take n_dicts rhs_ids
 826     body      = mkLams (drop n_dicts rhs_ids) rhs_body
 827                 -- Glue back on the non-dict lambdas
 828
 829     calls_for_me = case lookupFM calls fn of
 830                         Nothing -> []
 831                         Just cs -> fmToList cs
 832
 833     ----------------------------------------------------------
 834         -- Specialise to one particular call pattern
 835     spec_call :: (CallKey, ([DictExpr], VarSet))        -- Call instance
 836               -> SpecM ((Id,CoreExpr),                  -- Specialised definition
 837                         UsageDetails,                   -- Usage details from specialised body
 838                         CoreRule)                       -- Info for the Id's SpecEnv
 839     spec_call (CallKey call_ts, (call_ds, _))
 840       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts ) do
 841                 -- Calls are only recorded for properly-saturated applications
 842
 843         -- Suppose f's defn is  f = /\ a b c d -> \ d1 d2 -> rhs
 844         -- Supppose the call is for f [Just t1, Nothing, Just t3, Nothing] [dx1, dx2]
 845
 846         -- Construct the new binding
 847         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b d -> rhs)
 848         -- PLUS the usage-details
 849         --      { d1' = dx1; d2' = dx2 }
 850         -- where d1', d2' are cloned versions of d1,d2, with the type substitution applied.
 851         --
 852         -- Note that the substitution is applied to the whole thing.
 853         -- This is convenient, but just slightly fragile.  Notably:
 854         --      * There had better be no name clashes in a/b/c/d
 855         --
 856         let
 857                 -- poly_tyvars = [b,d] in the example above
 858                 -- spec_tyvars = [a,c]
 859                 -- ty_args     = [t1,b,t3,d]
 860            poly_tyvars = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 861            spec_tyvars = [tv | (tv, Just _)  <- rhs_tyvars `zip` call_ts]
 862            ty_args     = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 863                        where
 864                          mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 865                          mk_ty_arg _         (Just ty) = Type ty
 866
 867            spec_ty_args = [ty | Just ty <- call_ts]
 868            rhs_subst  = extendTvSubstList subst (spec_tyvars `zip` spec_ty_args)
 869
 870         (rhs_subst', rhs_dicts') <- cloneBinders rhs_subst rhs_dicts
 871         let
 872            inst_args = ty_args ++ map Var rhs_dicts'
 873
 874                 -- Figure out the type of the specialised function
 875            body_ty = applyTypeToArgs rhs fn_type inst_args
 876            (lam_args, app_args)                 -- Add a dummy argument if body_ty is unlifted
 877                 | isUnLiftedType body_ty        -- C.f. WwLib.mkWorkerArgs
 878                 = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 879                 | otherwise = (poly_tyvars, poly_tyvars)
 880            spec_id_ty = mkPiTypes lam_args body_ty
 881
 882         spec_f <- newIdSM fn spec_id_ty
 883         (spec_rhs, rhs_uds) <- specExpr rhs_subst' (mkLams lam_args body)
 884         let
 885                 -- The rule to put in the function's specialisation is:
 886                 --      forall b,d, d1',d2'.  f t1 b t3 d d1' d2' = f1 b d
 887            rule_name = mkFastString ("SPEC " ++ showSDoc (ppr fn <+> ppr spec_ty_args))
 888            spec_env_rule = mkLocalRule
 889                                 rule_name
 890                                 inline_prag     -- Note [Auto-specialisation and RULES]
 891                                 (idName fn)
 892                                 (poly_tyvars ++ rhs_dicts')
 893                                 inst_args
 894                                 (mkVarApps (Var spec_f) app_args)
 895
 896                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 897            final_uds = foldr addDictBind rhs_uds (my_zipEqual "spec_call" rhs_dicts' call_ds)
 898
 899            spec_pr | inline_rhs = (spec_f `setInlinePragma` inline_prag, Note InlineMe spec_rhs)
 900                    | otherwise  = (spec_f,                               spec_rhs)
 901
 902         return (spec_pr, final_uds, spec_env_rule)
 903
 904       where
 905         my_zipEqual doc xs ys
 906          | debugIsOn && not (equalLength xs ys)
 907              = pprPanic "my_zipEqual" (vcat
 908                                                 [ ppr xs, ppr ys
 909                                                 , ppr fn <+> ppr call_ts
 910                                                 , ppr (idType fn), ppr theta
 911                                                 , ppr n_dicts, ppr rhs_dicts
 912                                                 , ppr rhs])
 913          | otherwise               = zipEqual doc xs ys
 914 \end{code}
 915
 916 Note [Auto-specialisation and RULES]
 917 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 918 Consider:
 919    g :: Num a => a -> a
 920    g = ...
 921
 922    f :: (Int -> Int) -> Int
 923    f w = ...
 924    {-# RULE f g = 0 #-}
 925
 926 Suppose that auto-specialisation makes a specialised version of
 927 g::Int->Int That version won't appear in the LHS of the RULE for f.
 928 So if the specialisation rule fires too early, the rule for f may
 929 never fire.
 930
 931 It might be possible to add new rules, to "complete" the rewrite system.
 932 Thus when adding
 933         RULE forall d. g Int d = g_spec
 934 also add
 935         RULE f g_spec = 0
 936
 937 But that's a bit complicated.  For now we ask the programmer's help,
 938 by *copying the INLINE activation pragma* to the auto-specialised rule.
 939 So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule will also
 940 not be active until phase 2.
 941
 942
 943 Note [Specialisation shape]
 944 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 945 We only specialise a function if it has visible top-level lambdas
 946 corresponding to its overloading.  E.g. if
 947         f :: forall a. Eq a => ....
 948 then its body must look like
 949         f = /\a. \d. ...
 950
 951 Reason: when specialising the body for a call (f ty dexp), we want to
 952 substitute dexp for d, and pick up specialised calls in the body of f.
 953
 954 This doesn't always work.  One example I came across was htis:
 955         newtype Gen a = MkGen{ unGen :: Int -> a }
 956
 957         choose :: Eq a => a -> Gen a
 958         choose n = MkGen (\r -> n)
 959
 960         oneof = choose (1::Int)
 961
 962 It's a silly exapmle, but we get
 963         choose = /\a. g `cast` co
 964 where choose doesn't have any dict arguments.  Thus far I have not
 965 tried to fix this (wait till there's a real example).
 966
 967
 968 Note [Inline specialisations]
 969 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 970 We transfer to the specialised function any INLINE stuff from the
 971 original.  This means (a) the Activation in the IdInfo, and (b) any
 972 InlineMe on the RHS.
 973
 974 This is a change (Jun06).  Previously the idea is that the point of
 975 inlining was precisely to specialise the function at its call site,
 976 and that's not so important for the specialised copies.  But
 977 *pragma-directed* specialisation now takes place in the
 978 typechecker/desugarer, with manually specified INLINEs.  The
 979 specialiation here is automatic.  It'd be very odd if a function
 980 marked INLINE was specialised (because of some local use), and then
 981 forever after (including importing modules) the specialised version
 982 wasn't INLINEd.  After all, the programmer said INLINE!
 983
 984 You might wonder why we don't just not specialise INLINE functions.
 985 It's because even INLINE functions are sometimes not inlined, when
 986 they aren't applied to interesting arguments.  But perhaps the type
 987 arguments alone are enough to specialise (even though the args are too
 988 boring to trigger inlining), and it's certainly better to call the
 989 specialised version.
 990
 991 A case in point is dictionary functions, which are current marked
 992 INLINE, but which are worth specialising.
 993
 994 \begin{code}
 995 dropInline :: CoreExpr -> (Bool, CoreExpr)
 996 dropInline (Note InlineMe rhs) = (True,  rhs)
 997 dropInline rhs                 = (False, rhs)
 998 \end{code}
 999
1000 %************************************************************************
1001 %*                                                                      *
1002 \subsubsection{UsageDetails and suchlike}
1003 %*                                                                      *
1004 %************************************************************************
1005
1006 \begin{code}
1007 data UsageDetails
1008   = MkUD {
1009         dict_binds :: !(Bag DictBind),
1010                         -- Floated dictionary bindings
1011                         -- The order is important;
1012                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1013                         -- (Remember, Bags preserve order in GHC.)
1014
1015         calls     :: !CallDetails,
1016
1017         ud_fvs :: !VarSet       -- A superset of the variables mentioned in
1018                                 -- either dict_binds or calls
1019     }
1020
1021 instance Outputable UsageDetails where
1022   ppr (MkUD { dict_binds = dbs, calls = calls, ud_fvs = fvs })
1023         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma
1024                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1025                  ptext (sLit "calls") <+> equals <+> ppr calls,
1026                  ptext (sLit "fvs")   <+> equals <+> ppr fvs]))
1027
1028 type DictBind = (CoreBind, VarSet)
1029         -- The set is the free vars of the binding
1030         -- both tyvars and dicts
1031
1032 type DictExpr = CoreExpr
1033
1034 emptyUDs :: UsageDetails
1035 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM, ud_fvs = emptyVarSet }
1036
1037 ------------------------------------------------------------
1038 type CallDetails  = FiniteMap Id CallInfo
1039 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1040 type CallInfo     = FiniteMap CallKey
1041                               ([DictExpr], VarSet)              -- Dict args and the vars of the whole
1042                                                                 -- call (including tyvars)
1043                                                                 -- [*not* include the main id itself, of course]
1044         -- The finite maps eliminate duplicates
1045         -- The list of types and dictionaries is guaranteed to
1046         -- match the type of f
1047
1048 instance Outputable CallKey where
1049   ppr (CallKey ts) = ppr ts
1050
1051 -- Type isn't an instance of Ord, so that we can control which
1052 -- instance we use.  That's tiresome here.  Oh well
1053 instance Eq CallKey where
1054   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1055
1056 instance Ord CallKey where
1057   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1058                 where
1059                   cmp Nothing   Nothing   = EQ
1060                   cmp Nothing   (Just _)  = LT
1061                   cmp (Just _)  Nothing   = GT
1062                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1063
1064 unionCalls :: CallDetails -> CallDetails -> CallDetails
1065 unionCalls c1 c2 = plusFM_C plusFM c1 c2
1066
1067 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1068 singleCall id tys dicts
1069   = MkUD {dict_binds = emptyBag,
1070           calls      = unitFM id (unitFM (CallKey tys) (dicts, call_fvs)),
1071           ud_fvs     = call_fvs }
1072   where
1073     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1074     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1075         -- The type args (tys) are guaranteed to be part of the dictionary
1076         -- types, because they are just the constrained types,
1077         -- and the dictionary is therefore sure to be bound
1078         -- inside the binding for any type variables free in the type;
1079         -- hence it's safe to neglect tyvars free in tys when making
1080         -- the free-var set for this call
1081         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1082         --
1083         -- We don't include the 'id' itself.
1084
1085 mkCallUDs :: Subst -> Id -> [CoreExpr] -> UsageDetails
1086 mkCallUDs subst f args
1087   | null theta
1088   || not (all isClassPred theta)
1089         -- Only specialise if all overloading is on class params.
1090         -- In ptic, with implicit params, the type args
1091         --  *don't* say what the value of the implicit param is!
1092   || not (spec_tys `lengthIs` n_tyvars)
1093   || not ( dicts   `lengthIs` n_dicts)
1094   || maybeToBool (lookupRule (\_act -> True) (substInScope subst) emptyRuleBase f args)
1095         -- There's already a rule covering this call.  A typical case
1096         -- is where there's an explicit user-provided rule.  Then
1097         -- we don't want to create a specialised version
1098         -- of the function that overlaps.
1099   = emptyUDs    -- Not overloaded, or no specialisation wanted
1100
1101   | otherwise
1102   = singleCall f spec_tys dicts
1103   where
1104     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1105     constrained_tyvars = tyVarsOfTheta theta
1106     n_tyvars           = length tyvars
1107     n_dicts            = length theta
1108
1109     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1110     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1111
1112     mk_spec_ty tyvar ty
1113         | tyvar `elemVarSet` constrained_tyvars = Just ty
1114         | otherwise                             = Nothing
1115
1116 ------------------------------------------------------------
1117 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1118 plusUDs (MkUD {dict_binds = db1, calls = calls1, ud_fvs = fvs1})
1119         (MkUD {dict_binds = db2, calls = calls2, ud_fvs = fvs2})
1120   = MkUD {dict_binds = d, calls = c, ud_fvs = fvs1 `unionVarSet` fvs2}
1121   where
1122     d = db1    `unionBags`   db2
1123     c = calls1 `unionCalls`  calls2
1124
1125 plusUDList :: [UsageDetails] -> UsageDetails
1126 plusUDList = foldr plusUDs emptyUDs
1127
1128 -- zapCalls deletes calls to ids from uds
1129 zapCalls :: [Id] -> CallDetails -> CallDetails
1130 zapCalls ids calls = delListFromFM calls ids
1131
1132 mkDB :: CoreBind -> DictBind
1133 mkDB bind = (bind, bind_fvs bind)
1134
1135 bind_fvs :: CoreBind -> VarSet
1136 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1137 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1138                            where
1139                              bndrs = map fst prs
1140                              rhs_fvs = unionVarSets (map pair_fvs prs)
1141
1142 pair_fvs :: (Id, CoreExpr) -> VarSet
1143 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1144         -- Don't forget variables mentioned in the
1145         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1146         -- Also tyvars mentioned in its type; they may not appear in the RHS
1147         --      type T a = Int
1148         --      x :: T a = 3
1149
1150 addDictBind :: (Id,CoreExpr) -> UsageDetails -> UsageDetails
1151 addDictBind (dict,rhs) uds
1152   = uds { dict_binds = db `consBag` dict_binds uds
1153         , ud_fvs = ud_fvs uds `unionVarSet` fvs }
1154   where
1155     db@(_, fvs) = mkDB (NonRec dict rhs)
1156
1157 dumpAllDictBinds :: UsageDetails -> [CoreBind] -> [CoreBind]
1158 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1159   = foldrBag add binds dbs
1160   where
1161     add (bind,_) binds = bind : binds
1162
1163 dumpUDs :: [CoreBndr]
1164         -> UsageDetails -> CoreExpr
1165         -> (UsageDetails, CoreExpr)
1166 dumpUDs bndrs (MkUD { dict_binds = orig_dbs
1167                     , calls = orig_calls
1168                     , ud_fvs = fvs}) body
1169   = (new_uds, foldrBag add_let body dump_dbs)
1170                 -- This may delete fewer variables
1171                 -- than in priciple possible
1172   where
1173     new_uds =
1174      MkUD { dict_binds = free_dbs
1175           , calls      = free_calls
1176           , ud_fvs     = fvs `minusVarSet` bndr_set}
1177
1178     bndr_set = mkVarSet bndrs
1179     add_let (bind,_) body = Let bind body
1180
1181     (free_dbs, dump_dbs, dump_set)
1182         = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1183                 -- Important that it's foldl not foldr;
1184                 -- we're accumulating the set of dumped ids in dump_set
1185
1186     free_calls = filterCalls dump_set orig_calls
1187
1188     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1189         | dump_idset `intersectsVarSet` fvs     -- Dump it
1190         = (free_dbs, dump_dbs `snocBag` db,
1191            extendVarSetList dump_idset (bindersOf bind))
1192
1193         | otherwise     -- Don't dump it
1194         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1195
1196 filterCalls :: VarSet -> CallDetails -> CallDetails
1197 -- Remove any calls that mention the variables
1198 filterCalls bs calls
1199   = mapFM (\_ cs -> filter_calls cs) $
1200     filterFM (\k _ -> not (k `elemVarSet` bs)) calls
1201   where
1202     filter_calls :: CallInfo -> CallInfo
1203     filter_calls = filterFM (\_ (_, fvs) -> not (fvs `intersectsVarSet` bs))
1204 \end{code}
1205
1206
1207 %************************************************************************
1208 %*                                                                      *
1209 \subsubsection{Boring helper functions}
1210 %*                                                                      *
1211 %************************************************************************
1212
1213 \begin{code}
1214 type SpecM a = UniqSM a
1215
1216 initSM :: UniqSupply -> SpecM a -> a
1217 initSM    = initUs_
1218
1219 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1220 mapAndCombineSM _ []     = return ([], emptyUDs)
1221 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1222                               (ys, uds2) <- mapAndCombineSM f xs
1223                               return (y:ys, uds1 `plusUDs` uds2)
1224
1225 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1226 -- Clone the binders of the bind; return new bind with the cloned binders
1227 -- Return the substitution to use for RHSs, and the one to use for the body
1228 cloneBindSM subst (NonRec bndr rhs) = do
1229     us <- getUniqueSupplyM
1230     let (subst', bndr') = cloneIdBndr subst us bndr
1231     return (subst, subst', NonRec bndr' rhs)
1232
1233 cloneBindSM subst (Rec pairs) = do
1234     us <- getUniqueSupplyM
1235     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1236     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1237
1238 cloneBinders :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1239 cloneBinders subst bndrs = do
1240     us <- getUniqueSupplyM
1241     return (cloneIdBndrs subst us bndrs)
1242
1243 newIdSM :: Id -> Type -> SpecM Id
1244 newIdSM old_id new_ty = do
1245     uniq <- getUniqueM
1246     let
1247         -- Give the new Id a similar occurrence name to the old one
1248         name   = idName old_id
1249         new_id = mkUserLocal (mkSpecOcc (nameOccName name)) uniq new_ty (getSrcSpan name)
1250     return new_id
1251 \end{code}
1252
1253
1254                 Old (but interesting) stuff about unboxed bindings
1255                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1256
1257 What should we do when a value is specialised to a *strict* unboxed value?
1258
1259         map_*_* f (x:xs) = let h = f x
1260                                t = map f xs
1261                            in h:t
1262
1263 Could convert let to case:
1264
1265         map_*_Int# f (x:xs) = case f x of h# ->
1266                               let t = map f xs
1267                               in h#:t
1268
1269 This may be undesirable since it forces evaluation here, but the value
1270 may not be used in all branches of the body. In the general case this
1271 transformation is impossible since the mutual recursion in a letrec
1272 cannot be expressed as a case.
1273
1274 There is also a problem with top-level unboxed values, since our
1275 implementation cannot handle unboxed values at the top level.
1276
1277 Solution: Lift the binding of the unboxed value and extract it when it
1278 is used:
1279
1280         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1281                                   t = map f xs
1282                               in case h of
1283                                  _Lift h# -> h#:t
1284
1285 Now give it to the simplifier and the _Lifting will be optimised away.
1286
1287 The benfit is that we have given the specialised "unboxed" values a
1288 very simplep lifted semantics and then leave it up to the simplifier to
1289 optimise it --- knowing that the overheads will be removed in nearly
1290 all cases.
1291
1292 In particular, the value will only be evaluted in the branches of the
1293 program which use it, rather than being forced at the point where the
1294 value is bound. For example:
1295
1296         filtermap_*_* p f (x:xs)
1297           = let h = f x
1298                 t = ...
1299             in case p x of
1300                 True  -> h:t
1301                 False -> t
1302    ==>
1303         filtermap_*_Int# p f (x:xs)
1304           = let h = case (f x) of h# -> _Lift h#
1305                 t = ...
1306             in case p x of
1307                 True  -> case h of _Lift h#
1308                            -> h#:t
1309                 False -> t
1310
1311 The binding for h can still be inlined in the one branch and the
1312 _Lifting eliminated.
1313
1314
1315 Question: When won't the _Lifting be eliminated?
1316
1317 Answer: When they at the top-level (where it is necessary) or when
1318 inlining would duplicate work (or possibly code depending on
1319 options). However, the _Lifting will still be eliminated if the
1320 strictness analyser deems the lifted binding strict.
1321