compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 -- The above warning supression flag is a temporary kludge.
   8 -- While working on this module you are encouraged to remove it and fix
   9 -- any warnings in the module. See
  10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  11 -- for details
  12
  13 module Specialise ( specProgram ) where
  14
  15 #include "HsVersions.h"
  16
  17 import DynFlags ( DynFlags, DynFlag(..) )
  18 import Id               ( Id, idName, idType, mkUserLocal,
  19                           idInlinePragma, setInlinePragma )
  20 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  21                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  22                           tcCmpType, isUnLiftedType
  23                         )
  24 import CoreSubst        ( Subst, mkEmptySubst, extendTvSubstList, lookupIdSubst,
  25                           substBndr, substBndrs, substTy, substInScope,
  26                           cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs
  27                         )
  28 import SimplUtils       ( interestingArg )
  29 import VarSet
  30 import VarEnv
  31 import CoreSyn
  32 import Rules
  33 import CoreUtils        ( applyTypeToArgs, mkPiTypes )
  34 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  35 import CoreLint         ( showPass, endPass )
  36 import UniqSupply       ( UniqSupply,
  37                           UniqSM, initUs_,
  38                           MonadUnique(..)
  39                         )
  40 import Name
  41 import MkId             ( voidArgId, realWorldPrimId )
  42 import FiniteMap
  43 import Maybes           ( catMaybes, maybeToBool )
  44 import ErrUtils         ( dumpIfSet_dyn )
  45 import Bag
  46 import Util
  47 import Outputable
  48 import FastString
  49
  50 \end{code}
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 These notes describe how we implement specialisation to eliminate
  59 overloading.
  60
  61 The specialisation pass works on Core
  62 syntax, complete with all the explicit dictionary application,
  63 abstraction and construction as added by the type checker.  The
  64 existing type checker remains largely as it is.
  65
  66 One important thought: the {\em types} passed to an overloaded
  67 function, and the {\em dictionaries} passed are mutually redundant.
  68 If the same function is applied to the same type(s) then it is sure to
  69 be applied to the same dictionary(s)---or rather to the same {\em
  70 values}.  (The arguments might look different but they will evaluate
  71 to the same value.)
  72
  73 Second important thought: we know that we can make progress by
  74 treating dictionary arguments as static and worth specialising on.  So
  75 we can do without binding-time analysis, and instead specialise on
  76 dictionary arguments and no others.
  77
  78 The basic idea
  79 ~~~~~~~~~~~~~~
  80 Suppose we have
  81
  82         let f = <f_rhs>
  83         in <body>
  84
  85 and suppose f is overloaded.
  86
  87 STEP 1: CALL-INSTANCE COLLECTION
  88
  89 We traverse <body>, accumulating all applications of f to types and
  90 dictionaries.
  91
  92 (Might there be partial applications, to just some of its types and
  93 dictionaries?  In principle yes, but in practice the type checker only
  94 builds applications of f to all its types and dictionaries, so partial
  95 applications could only arise as a result of transformation, and even
  96 then I think it's unlikely.  In any case, we simply don't accumulate such
  97 partial applications.)
  98
  99
 100 STEP 2: EQUIVALENCES
 101
 102 So now we have a collection of calls to f:
 103         f t1 t2 d1 d2
 104         f t3 t4 d3 d4
 105         ...
 106 Notice that f may take several type arguments.  To avoid ambiguity, we
 107 say that f is called at type t1/t2 and t3/t4.
 108
 109 We take equivalence classes using equality of the *types* (ignoring
 110 the dictionary args, which as mentioned previously are redundant).
 111
 112 STEP 3: SPECIALISATION
 113
 114 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 115 and create a local instance of f, defined thus:
 116
 117         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 118
 119 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 120 of simplification will now result.  However we don't actually *do* that
 121 simplification.  Rather, we leave it for the simplifier to do.  If we
 122 *did* do it, though, we'd get more call instances from the specialised
 123 RHS.  We can work out what they are by instantiating the call-instance
 124 set from f's RHS with the types t1, t2.
 125
 126 Add this new id to f's IdInfo, to record that f has a specialised version.
 127
 128 Before doing any of this, check that f's IdInfo doesn't already
 129 tell us about an existing instance of f at the required type/s.
 130 (This might happen if specialisation was applied more than once, or
 131 it might arise from user SPECIALIZE pragmas.)
 132
 133 Recursion
 134 ~~~~~~~~~
 135 Wait a minute!  What if f is recursive?  Then we can't just plug in
 136 its right-hand side, can we?
 137
 138 But it's ok.  The type checker *always* creates non-recursive definitions
 139 for overloaded recursive functions.  For example:
 140
 141         f x = f (x+x)           -- Yes I know its silly
 142
 143 becomes
 144
 145         f a (d::Num a) = let p = +.sel a d
 146                          in
 147                          letrec fl (y::a) = fl (p y y)
 148                          in
 149                          fl
 150
 151 We still have recusion for non-overloaded functions which we
 152 speciailise, but the recursive call should get specialised to the
 153 same recursive version.
 154
 155
 156 Polymorphism 1
 157 ~~~~~~~~~~~~~~
 158
 159 All this is crystal clear when the function is applied to *constant
 160 types*; that is, types which have no type variables inside.  But what if
 161 it is applied to non-constant types?  Suppose we find a call of f at type
 162 t1/t2.  There are two possibilities:
 163
 164 (a) The free type variables of t1, t2 are in scope at the definition point
 165 of f.  In this case there's no problem, we proceed just as before.  A common
 166 example is as follows.  Here's the Haskell:
 167
 168         g y = let f x = x+x
 169               in f y + f y
 170
 171 After typechecking we have
 172
 173         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 174                                 in +.sel a d (f a d y) (f a d y)
 175
 176 Notice that the call to f is at type type "a"; a non-constant type.
 177 Both calls to f are at the same type, so we can specialise to give:
 178
 179         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 180                                 in +.sel a d (f@a y) (f@a y)
 181
 182
 183 (b) The other case is when the type variables in the instance types
 184 are *not* in scope at the definition point of f.  The example we are
 185 working with above is a good case.  There are two instances of (+.sel a d),
 186 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 187 Yes, we can "common them up", a sort of limited common sub-expression deal.
 188 This would give:
 189
 190         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 191                                     f@a (x::a) = +.sel@a x x
 192                                 in +.sel@a (f@a y) (f@a y)
 193
 194 This can save work, and can't be spotted by the type checker, because
 195 the two instances of +.sel weren't originally at the same type.
 196
 197 Further notes on (b)
 198
 199 * There are quite a few variations here.  For example, the defn of
 200   +.sel could be floated ouside the \y, to attempt to gain laziness.
 201   It certainly mustn't be floated outside the \d because the d has to
 202   be in scope too.
 203
 204 * We don't want to inline f_rhs in this case, because
 205 that will duplicate code.  Just commoning up the call is the point.
 206
 207 * Nothing gets added to +.sel's IdInfo.
 208
 209 * Don't bother unless the equivalence class has more than one item!
 210
 211 Not clear whether this is all worth it.  It is of course OK to
 212 simply discard call-instances when passing a big lambda.
 213
 214 Polymorphism 2 -- Overloading
 215 ~~~~~~~~~~~~~~
 216 Consider a function whose most general type is
 217
 218         f :: forall a b. Ord a => [a] -> b -> b
 219
 220 There is really no point in making a version of g at Int/Int and another
 221 at Int/Bool, because it's only instancing the type variable "a" which
 222 buys us any efficiency. Since g is completely polymorphic in b there
 223 ain't much point in making separate versions of g for the different
 224 b types.
 225
 226 That suggests that we should identify which of g's type variables
 227 are constrained (like "a") and which are unconstrained (like "b").
 228 Then when taking equivalence classes in STEP 2, we ignore the type args
 229 corresponding to unconstrained type variable.  In STEP 3 we make
 230 polymorphic versions.  Thus:
 231
 232         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 233
 234 We do this.
 235
 236
 237 Dictionary floating
 238 ~~~~~~~~~~~~~~~~~~~
 239 Consider this
 240
 241         f a (d::Num a) = let g = ...
 242                          in
 243                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 244
 245 Here, g is only called at one type, but the dictionary isn't in scope at the
 246 definition point for g.  Usually the type checker would build a
 247 definition for d1 which enclosed g, but the transformation system
 248 might have moved d1's defn inward.  Solution: float dictionary bindings
 249 outwards along with call instances.
 250
 251 Consider
 252
 253         f x = let g p q = p==q
 254                   h r s = (r+s, g r s)
 255               in
 256               h x x
 257
 258
 259 Before specialisation, leaving out type abstractions we have
 260
 261         f df x = let g :: Eq a => a -> a -> Bool
 262                      g dg p q = == dg p q
 263                      h :: Num a => a -> a -> (a, Bool)
 264                      h dh r s = let deq = eqFromNum dh
 265                                 in (+ dh r s, g deq r s)
 266               in
 267               h df x x
 268
 269 After specialising h we get a specialised version of h, like this:
 270
 271                     h' r s = let deq = eqFromNum df
 272                              in (+ df r s, g deq r s)
 273
 274 But we can't naively make an instance for g from this, because deq is not in scope
 275 at the defn of g.  Instead, we have to float out the (new) defn of deq
 276 to widen its scope.  Notice that this floating can't be done in advance -- it only
 277 shows up when specialisation is done.
 278
 279 User SPECIALIZE pragmas
 280 ~~~~~~~~~~~~~~~~~~~~~~~
 281 Specialisation pragmas can be digested by the type checker, and implemented
 282 by adding extra definitions along with that of f, in the same way as before
 283
 284         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 285
 286 Indeed the pragmas *have* to be dealt with by the type checker, because
 287 only it knows how to build the dictionaries d1 and d2!  For example
 288
 289         g :: Ord a => [a] -> [a]
 290         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 291
 292 Here, the specialised version of g is an application of g's rhs to the
 293 Ord dictionary for (Tree Int), which only the type checker can conjure
 294 up.  There might not even *be* one, if (Tree Int) is not an instance of
 295 Ord!  (All the other specialision has suitable dictionaries to hand
 296 from actual calls.)
 297
 298 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 299 it is buried in a complex (as-yet-un-desugared) binding group.
 300 Maybe we should say
 301
 302         f@t1/t2 = f* t1 t2 d1 d2
 303
 304 where f* is the Id f with an IdInfo which says "inline me regardless!".
 305 Indeed all the specialisation could be done in this way.
 306 That in turn means that the simplifier has to be prepared to inline absolutely
 307 any in-scope let-bound thing.
 308
 309
 310 Again, the pragma should permit polymorphism in unconstrained variables:
 311
 312         h :: Ord a => [a] -> b -> b
 313         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 314
 315 We *insist* that all overloaded type variables are specialised to ground types,
 316 (and hence there can be no context inside a SPECIALIZE pragma).
 317 We *permit* unconstrained type variables to be specialised to
 318         - a ground type
 319         - or left as a polymorphic type variable
 320 but nothing in between.  So
 321
 322         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 323
 324 is *illegal*.  (It can be handled, but it adds complication, and gains the
 325 programmer nothing.)
 326
 327
 328 SPECIALISING INSTANCE DECLARATIONS
 329 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 330 Consider
 331
 332         instance Foo a => Foo [a] where
 333                 ...
 334         {-# SPECIALIZE instance Foo [Int] #-}
 335
 336 The original instance decl creates a dictionary-function
 337 definition:
 338
 339         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 340
 341 The SPECIALIZE pragma just makes a specialised copy, just as for
 342 ordinary function definitions:
 343
 344         dfun.Foo.List@Int :: Foo [Int]
 345         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 346
 347 The information about what instance of the dfun exist gets added to
 348 the dfun's IdInfo in the same way as a user-defined function too.
 349
 350
 351 Automatic instance decl specialisation?
 352 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 353 Can instance decls be specialised automatically?  It's tricky.
 354 We could collect call-instance information for each dfun, but
 355 then when we specialised their bodies we'd get new call-instances
 356 for ordinary functions; and when we specialised their bodies, we might get
 357 new call-instances of the dfuns, and so on.  This all arises because of
 358 the unrestricted mutual recursion between instance decls and value decls.
 359
 360 Still, there's no actual problem; it just means that we may not do all
 361 the specialisation we could theoretically do.
 362
 363 Furthermore, instance decls are usually exported and used non-locally,
 364 so we'll want to compile enough to get those specialisations done.
 365
 366 Lastly, there's no such thing as a local instance decl, so we can
 367 survive solely by spitting out *usage* information, and then reading that
 368 back in as a pragma when next compiling the file.  So for now,
 369 we only specialise instance decls in response to pragmas.
 370
 371
 372 SPITTING OUT USAGE INFORMATION
 373 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 374
 375 To spit out usage information we need to traverse the code collecting
 376 call-instance information for all imported (non-prelude?) functions
 377 and data types. Then we equivalence-class it and spit it out.
 378
 379 This is done at the top-level when all the call instances which escape
 380 must be for imported functions and data types.
 381
 382 *** Not currently done ***
 383
 384
 385 Partial specialisation by pragmas
 386 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 387 What about partial specialisation:
 388
 389         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 390         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 391
 392 or even
 393
 394         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 395
 396 Seems quite reasonable.  Similar things could be done with instance decls:
 397
 398         instance (Foo a, Foo b) => Foo (a,b) where
 399                 ...
 400         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 401         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 402
 403 Ho hum.  Things are complex enough without this.  I pass.
 404
 405
 406 Requirements for the simplifer
 407 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 408 The simplifier has to be able to take advantage of the specialisation.
 409
 410 * When the simplifier finds an application of a polymorphic f, it looks in
 411 f's IdInfo in case there is a suitable instance to call instead.  This converts
 412
 413         f t1 t2 d1 d2   ===>   f_t1_t2
 414
 415 Note that the dictionaries get eaten up too!
 416
 417 * Dictionary selection operations on constant dictionaries must be
 418   short-circuited:
 419
 420         +.sel Int d     ===>  +Int
 421
 422 The obvious way to do this is in the same way as other specialised
 423 calls: +.sel has inside it some IdInfo which tells that if it's applied
 424 to the type Int then it should eat a dictionary and transform to +Int.
 425
 426 In short, dictionary selectors need IdInfo inside them for constant
 427 methods.
 428
 429 * Exactly the same applies if a superclass dictionary is being
 430   extracted:
 431
 432         Eq.sel Int d   ===>   dEqInt
 433
 434 * Something similar applies to dictionary construction too.  Suppose
 435 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 436 one for (Eq [a]).  Then we want
 437
 438         dfun.Eq.List Int d      ===> dEq.List_Int
 439
 440 Where does the Eq [Int] dictionary come from?  It is built in
 441 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 442
 443 In short, dfun Ids need IdInfo with a specialisation for each
 444 constant instance of their instance declaration.
 445
 446 All this uses a single mechanism: the SpecEnv inside an Id
 447
 448
 449 What does the specialisation IdInfo look like?
 450 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 451
 452 The SpecEnv of an Id maps a list of types (the template) to an expression
 453
 454         [Type]  |->  Expr
 455
 456 For example, if f has this SpecInfo:
 457
 458         [Int, a]  ->  \d:Ord Int. f' a
 459
 460 it means that we can replace the call
 461
 462         f Int t  ===>  (\d. f' t)
 463
 464 This chucks one dictionary away and proceeds with the
 465 specialised version of f, namely f'.
 466
 467
 468 What can't be done this way?
 469 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 470 There is no way, post-typechecker, to get a dictionary for (say)
 471 Eq a from a dictionary for Eq [a].  So if we find
 472
 473         ==.sel [t] d
 474
 475 we can't transform to
 476
 477         eqList (==.sel t d')
 478
 479 where
 480         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 481
 482 Of course, we currently have no way to automatically derive
 483 eqList, nor to connect it to the Eq [a] instance decl, but you
 484 can imagine that it might somehow be possible.  Taking advantage
 485 of this is permanently ruled out.
 486
 487 Still, this is no great hardship, because we intend to eliminate
 488 overloading altogether anyway!
 489
 490 A note about non-tyvar dictionaries
 491 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 492 Some Ids have types like
 493
 494         forall a,b,c. Eq a -> Ord [a] -> tau
 495
 496 This seems curious at first, because we usually only have dictionary
 497 args whose types are of the form (C a) where a is a type variable.
 498 But this doesn't hold for the functions arising from instance decls,
 499 which sometimes get arguements with types of form (C (T a)) for some
 500 type constructor T.
 501
 502 Should we specialise wrt this compound-type dictionary?  We used to say
 503 "no", saying:
 504         "This is a heuristic judgement, as indeed is the fact that we
 505         specialise wrt only dictionaries.  We choose *not* to specialise
 506         wrt compound dictionaries because at the moment the only place
 507         they show up is in instance decls, where they are simply plugged
 508         into a returned dictionary.  So nothing is gained by specialising
 509         wrt them."
 510
 511 But it is simpler and more uniform to specialise wrt these dicts too;
 512 and in future GHC is likely to support full fledged type signatures
 513 like
 514         f :: Eq [(a,b)] => ...
 515
 516
 517 %************************************************************************
 518 %*                                                                      *
 519 \subsubsection{The new specialiser}
 520 %*                                                                      *
 521 %************************************************************************
 522
 523 Our basic game plan is this.  For let(rec) bound function
 524         f :: (C a, D c) => (a,b,c,d) -> Bool
 525
 526 * Find any specialised calls of f, (f ts ds), where
 527   ts are the type arguments t1 .. t4, and
 528   ds are the dictionary arguments d1 .. d2.
 529
 530 * Add a new definition for f1 (say):
 531
 532         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 533
 534   Note that we abstract over the unconstrained type arguments.
 535
 536 * Add the mapping
 537
 538         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 539
 540   to the specialisations of f.  This will be used by the
 541   simplifier to replace calls
 542                 (f t1 t2 t3 t4) da db
 543   by
 544                 (\d1 d1 -> f1 t2 t4) da db
 545
 546   All the stuff about how many dictionaries to discard, and what types
 547   to apply the specialised function to, are handled by the fact that the
 548   SpecEnv contains a template for the result of the specialisation.
 549
 550 We don't build *partial* specialisations for f.  For example:
 551
 552   f :: Eq a => a -> a -> Bool
 553   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 554
 555 Here, little is gained by making a specialised copy of f.
 556 There's a distinct danger that the specialised version would
 557 first build a dictionary for (Eq b, Eq c), and then select the (==)
 558 method from it!  Even if it didn't, not a great deal is saved.
 559
 560 We do, however, generate polymorphic, but not overloaded, specialisations:
 561
 562   f :: Eq a => [a] -> b -> b -> b
 563   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 564
 565 Hence, the invariant is this:
 566
 567         *** no specialised version is overloaded ***
 568
 569
 570 %************************************************************************
 571 %*                                                                      *
 572 \subsubsection{The exported function}
 573 %*                                                                      *
 574 %************************************************************************
 575
 576 \begin{code}
 577 specProgram :: DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]
 578 specProgram dflags us binds = do
 579
 580         showPass dflags "Specialise"
 581
 582         let binds' = initSM us (do (binds', uds') <- go binds
 583                                    return (dumpAllDictBinds uds' binds'))
 584
 585         endPass dflags "Specialise" Opt_D_dump_spec binds'
 586
 587         dumpIfSet_dyn dflags Opt_D_dump_rules "Top-level specialisations"
 588                       (pprRulesForUser (rulesOfBinds binds'))
 589
 590         return binds'
 591   where
 592         -- We need to start with a Subst that knows all the things
 593         -- that are in scope, so that the substitution engine doesn't
 594         -- accidentally re-use a unique that's already in use
 595         -- Easiest thing is to do it all at once, as if all the top-level
 596         -- decls were mutually recursive
 597     top_subst       = mkEmptySubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 598
 599     go []           = return ([], emptyUDs)
 600     go (bind:binds) = do (binds', uds) <- go binds
 601                          (bind', uds') <- specBind top_subst bind uds
 602                          return (bind' ++ binds', uds')
 603 \end{code}
 604
 605 %************************************************************************
 606 %*                                                                      *
 607 \subsubsection{@specExpr@: the main function}
 608 %*                                                                      *
 609 %************************************************************************
 610
 611 \begin{code}
 612 specVar :: Subst -> Id -> CoreExpr
 613 specVar subst v = lookupIdSubst subst v
 614
 615 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 616 -- We carry a substitution down:
 617 --      a) we must clone any binding that might flaot outwards,
 618 --         to avoid name clashes
 619 --      b) we carry a type substitution to use when analysing
 620 --         the RHS of specialised bindings (no type-let!)
 621
 622 ---------------- First the easy cases --------------------
 623 specExpr subst (Type ty) = return (Type (substTy subst ty), emptyUDs)
 624 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
 625 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
 626 specExpr subst (Cast e co) = do
 627     (e', uds) <- specExpr subst e
 628     return ((Cast e' (substTy subst co)), uds)
 629 specExpr subst (Note note body) = do
 630     (body', uds) <- specExpr subst body
 631     return (Note (specNote subst note) body', uds)
 632
 633
 634 ---------------- Applications might generate a call instance --------------------
 635 specExpr subst expr@(App {})
 636   = go expr []
 637   where
 638     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
 639                                (fun', uds_app) <- go fun (arg':args)
 640                                return (App fun' arg', uds_arg `plusUDs` uds_app)
 641
 642     go (Var f)       args = case specVar subst f of
 643                                 Var f' -> return (Var f', mkCallUDs subst f' args)
 644                                 e'     -> return (e', emptyUDs) -- I don't expect this!
 645     go other         _    = specExpr subst other
 646
 647 ---------------- Lambda/case require dumping of usage details --------------------
 648 specExpr subst e@(Lam _ _) = do
 649     (body', uds) <- specExpr subst' body
 650     let (filtered_uds, body'') = dumpUDs bndrs' uds body'
 651     return (mkLams bndrs' body'', filtered_uds)
 652   where
 653     (bndrs, body) = collectBinders e
 654     (subst', bndrs') = substBndrs subst bndrs
 655         -- More efficient to collect a group of binders together all at once
 656         -- and we don't want to split a lambda group with dumped bindings
 657
 658 specExpr subst (Case scrut case_bndr ty alts) = do
 659     (scrut', uds_scrut) <- specExpr subst scrut
 660     (alts', uds_alts) <- mapAndCombineSM spec_alt alts
 661     return (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 662   where
 663     (subst_alt, case_bndr') = substBndr subst case_bndr
 664         -- No need to clone case binder; it can't float like a let(rec)
 665
 666     spec_alt (con, args, rhs) = do
 667           (rhs', uds) <- specExpr subst_rhs rhs
 668           let (uds', rhs'') = dumpUDs args uds rhs'
 669           return ((con, args', rhs''), uds')
 670         where
 671           (subst_rhs, args') = substBndrs subst_alt args
 672
 673 ---------------- Finally, let is the interesting case --------------------
 674 specExpr subst (Let bind body) = do
 675         -- Clone binders
 676     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
 677
 678         -- Deal with the body
 679     (body', body_uds) <- specExpr body_subst body
 680
 681         -- Deal with the bindings
 682     (binds', uds) <- specBind rhs_subst bind' body_uds
 683
 684         -- All done
 685     return (foldr Let body' binds', uds)
 686
 687 -- Must apply the type substitution to coerceions
 688 specNote :: Subst -> Note -> Note
 689 specNote _ note = note
 690 \end{code}
 691
 692 %************************************************************************
 693 %*                                                                      *
 694 \subsubsection{Dealing with a binding}
 695 %*                                                                      *
 696 %************************************************************************
 697
 698 \begin{code}
 699 specBind :: Subst                       -- Use this for RHSs
 700          -> CoreBind
 701          -> UsageDetails                -- Info on how the scope of the binding
 702          -> SpecM ([CoreBind],          -- New bindings
 703                    UsageDetails)        -- And info to pass upstream
 704
 705 specBind rhs_subst bind body_uds
 706   = do  { (bind', bind_uds) <- specBindItself rhs_subst bind (calls body_uds)
 707         ; return (finishSpecBind bind' bind_uds body_uds) }
 708
 709 finishSpecBind :: CoreBind -> UsageDetails -> UsageDetails -> ([CoreBind], UsageDetails)
 710 finishSpecBind bind
 711         (MkUD { dict_binds = rhs_dbs,  calls = rhs_calls,  ud_fvs = rhs_fvs })
 712         (MkUD { dict_binds = body_dbs, calls = body_calls, ud_fvs = body_fvs })
 713   | not (mkVarSet bndrs `intersectsVarSet` all_fvs)
 714                 -- Common case 1: the bound variables are not
 715                 --                mentioned in the dictionary bindings
 716   = ([bind], MkUD { dict_binds = body_dbs `unionBags` rhs_dbs
 717                         -- It's important that the `unionBags` is this way round,
 718                         -- because body_uds may bind dictionaries that are
 719                         -- used in the calls passed to specDefn.  So the
 720                         -- dictionary bindings in rhs_uds may mention
 721                         -- dictionaries bound in body_uds.
 722                   , calls  = all_calls
 723                   , ud_fvs = all_fvs })
 724
 725   | case bind of { NonRec {} -> True; Rec {} -> False }
 726                 -- Common case 2: no specialisation happened, and binding
 727                 --                is non-recursive.  But the binding may be
 728                 --                mentioned in body_dbs, so we should put it first
 729   = ([], MkUD { dict_binds = rhs_dbs `unionBags` ((bind, b_fvs) `consBag` body_dbs)
 730               , calls      = all_calls
 731               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 732
 733   | otherwise   -- General case: make a huge Rec (sigh)
 734   = ([], MkUD { dict_binds = unitBag (Rec all_db_prs, all_db_fvs)
 735               , calls      = all_calls
 736               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 737   where
 738     all_fvs = rhs_fvs `unionVarSet` body_fvs
 739     all_calls = zapCalls bndrs (rhs_calls `unionCalls` body_calls)
 740
 741     bndrs   = bindersOf bind
 742     b_fvs   = bind_fvs bind
 743
 744     (all_db_prs, all_db_fvs) = add (bind, b_fvs) $
 745                                foldrBag add ([], emptyVarSet) $
 746                                rhs_dbs `unionBags` body_dbs
 747     add (NonRec b r, b_fvs) (prs, fvs) = ((b,r)  : prs, b_fvs `unionVarSet` fvs)
 748     add (Rec b_prs,  b_fvs) (prs, fvs) = (b_prs ++ prs, b_fvs `unionVarSet` fvs)
 749
 750 specBindItself :: Subst -> CoreBind -> CallDetails -> SpecM (CoreBind, UsageDetails)
 751
 752 -- specBindItself deals with the RHS, specialising it according
 753 -- to the calls found in the body (if any)
 754 specBindItself rhs_subst (NonRec bndr rhs) call_info = do
 755     ((bndr',rhs'), spec_defns, spec_uds) <- specDefn rhs_subst call_info (bndr,rhs)
 756     let
 757         new_bind | null spec_defns = NonRec bndr' rhs'
 758                  | otherwise       = Rec ((bndr',rhs'):spec_defns)
 759                 -- bndr' mentions the spec_defns in its SpecEnv
 760                 -- Not sure why we couln't just put the spec_defns first
 761     return (new_bind, spec_uds)
 762
 763 specBindItself rhs_subst (Rec pairs) call_info = do
 764     stuff <- mapM (specDefn rhs_subst call_info) pairs
 765     let
 766         (pairs', spec_defns_s, spec_uds_s) = unzip3 stuff
 767         spec_defns = concat spec_defns_s
 768         spec_uds   = plusUDList spec_uds_s
 769         new_bind   = Rec (spec_defns ++ pairs')
 770     return (new_bind, spec_uds)
 771
 772
 773 specDefn :: Subst                       -- Subst to use for RHS
 774          -> CallDetails                 -- Info on how it is used in its scope
 775          -> (Id, CoreExpr)              -- The thing being bound and its un-processed RHS
 776          -> SpecM ((Id, CoreExpr),      -- The thing and its processed RHS
 777                                         --      the Id may now have specialisations attached
 778                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 779                    UsageDetails         -- Stuff to fling upwards from the RHS and its
 780             )                           --      specialised versions
 781
 782 specDefn subst calls (fn, rhs)
 783         -- The first case is the interesting one
 784   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 785   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 786   && notNull calls_for_me               -- And there are some calls to specialise
 787
 788 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 789 --      See Note [Inline specialisation] for why we do not
 790 --      switch off specialisation for inline functions = do
 791   = do
 792      -- Specialise the body of the function
 793     (rhs', rhs_uds) <- specExpr subst rhs
 794
 795       -- Make a specialised version for each call in calls_for_me
 796     stuff <- mapM spec_call calls_for_me
 797     let
 798         (spec_defns, spec_uds, spec_rules) = unzip3 stuff
 799
 800         fn' = addIdSpecialisations fn spec_rules
 801
 802     return ((fn',rhs'),
 803               spec_defns,
 804               rhs_uds `plusUDs` plusUDList spec_uds)
 805
 806   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 807   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") <+> ppr fn )
 808           -- Note [Specialisation shape]
 809     (do  { (rhs', rhs_uds) <- specExpr subst rhs
 810         ; return ((fn, rhs'), [], rhs_uds) })
 811
 812   where
 813     fn_type            = idType fn
 814     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 815     n_tyvars           = length tyvars
 816     n_dicts            = length theta
 817     inline_prag        = idInlinePragma fn
 818
 819         -- It's important that we "see past" any INLINE pragma
 820         -- else we'll fail to specialise an INLINE thing
 821     (inline_rhs, rhs_inside) = dropInline rhs
 822     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs_inside
 823
 824     rhs_dicts = take n_dicts rhs_ids
 825     body      = mkLams (drop n_dicts rhs_ids) rhs_body
 826                 -- Glue back on the non-dict lambdas
 827
 828     calls_for_me = case lookupFM calls fn of
 829                         Nothing -> []
 830                         Just cs -> fmToList cs
 831
 832     ----------------------------------------------------------
 833         -- Specialise to one particular call pattern
 834     spec_call :: (CallKey, ([DictExpr], VarSet))        -- Call instance
 835               -> SpecM ((Id,CoreExpr),                  -- Specialised definition
 836                         UsageDetails,                   -- Usage details from specialised body
 837                         CoreRule)                       -- Info for the Id's SpecEnv
 838     spec_call (CallKey call_ts, (call_ds, _))
 839       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts ) do
 840                 -- Calls are only recorded for properly-saturated applications
 841
 842         -- Suppose f's defn is  f = /\ a b c d -> \ d1 d2 -> rhs
 843         -- Supppose the call is for f [Just t1, Nothing, Just t3, Nothing] [dx1, dx2]
 844
 845         -- Construct the new binding
 846         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b d -> rhs)
 847         -- PLUS the usage-details
 848         --      { d1' = dx1; d2' = dx2 }
 849         -- where d1', d2' are cloned versions of d1,d2, with the type substitution applied.
 850         --
 851         -- Note that the substitution is applied to the whole thing.
 852         -- This is convenient, but just slightly fragile.  Notably:
 853         --      * There had better be no name clashes in a/b/c/d
 854         --
 855         let
 856                 -- poly_tyvars = [b,d] in the example above
 857                 -- spec_tyvars = [a,c]
 858                 -- ty_args     = [t1,b,t3,d]
 859            poly_tyvars = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 860            spec_tyvars = [tv | (tv, Just _)  <- rhs_tyvars `zip` call_ts]
 861            ty_args     = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 862                        where
 863                          mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 864                          mk_ty_arg _         (Just ty) = Type ty
 865
 866            spec_ty_args = [ty | Just ty <- call_ts]
 867            rhs_subst  = extendTvSubstList subst (spec_tyvars `zip` spec_ty_args)
 868
 869         (rhs_subst', rhs_dicts') <- cloneBinders rhs_subst rhs_dicts
 870         let
 871            inst_args = ty_args ++ map Var rhs_dicts'
 872
 873                 -- Figure out the type of the specialised function
 874            body_ty = applyTypeToArgs rhs fn_type inst_args
 875            (lam_args, app_args)                 -- Add a dummy argument if body_ty is unlifted
 876                 | isUnLiftedType body_ty        -- C.f. WwLib.mkWorkerArgs
 877                 = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 878                 | otherwise = (poly_tyvars, poly_tyvars)
 879            spec_id_ty = mkPiTypes lam_args body_ty
 880
 881         spec_f <- newIdSM fn spec_id_ty
 882         (spec_rhs, rhs_uds) <- specExpr rhs_subst' (mkLams lam_args body)
 883         let
 884                 -- The rule to put in the function's specialisation is:
 885                 --      forall b,d, d1',d2'.  f t1 b t3 d d1' d2' = f1 b d
 886            rule_name = mkFastString ("SPEC " ++ showSDoc (ppr fn <+> ppr spec_ty_args))
 887            spec_env_rule = mkLocalRule
 888                                 rule_name
 889                                 inline_prag     -- Note [Auto-specialisation and RULES]
 890                                 (idName fn)
 891                                 (poly_tyvars ++ rhs_dicts')
 892                                 inst_args
 893                                 (mkVarApps (Var spec_f) app_args)
 894
 895                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 896            final_uds = foldr addDictBind rhs_uds (my_zipEqual "spec_call" rhs_dicts' call_ds)
 897
 898            spec_pr | inline_rhs = (spec_f `setInlinePragma` inline_prag, Note InlineMe spec_rhs)
 899                    | otherwise  = (spec_f,                               spec_rhs)
 900
 901         return (spec_pr, final_uds, spec_env_rule)
 902
 903       where
 904         my_zipEqual doc xs ys
 905          | debugIsOn && not (equalLength xs ys)
 906              = pprPanic "my_zipEqual" (vcat
 907                                                 [ ppr xs, ppr ys
 908                                                 , ppr fn <+> ppr call_ts
 909                                                 , ppr (idType fn), ppr theta
 910                                                 , ppr n_dicts, ppr rhs_dicts
 911                                                 , ppr rhs])
 912          | otherwise               = zipEqual doc xs ys
 913 \end{code}
 914
 915 Note [Auto-specialisation and RULES]
 916 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 917 Consider:
 918    g :: Num a => a -> a
 919    g = ...
 920
 921    f :: (Int -> Int) -> Int
 922    f w = ...
 923    {-# RULE f g = 0 #-}
 924
 925 Suppose that auto-specialisation makes a specialised version of
 926 g::Int->Int That version won't appear in the LHS of the RULE for f.
 927 So if the specialisation rule fires too early, the rule for f may
 928 never fire.
 929
 930 It might be possible to add new rules, to "complete" the rewrite system.
 931 Thus when adding
 932         RULE forall d. g Int d = g_spec
 933 also add
 934         RULE f g_spec = 0
 935
 936 But that's a bit complicated.  For now we ask the programmer's help,
 937 by *copying the INLINE activation pragma* to the auto-specialised rule.
 938 So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule will also
 939 not be active until phase 2.
 940
 941
 942 Note [Specialisation shape]
 943 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 944 We only specialise a function if it has visible top-level lambdas
 945 corresponding to its overloading.  E.g. if
 946         f :: forall a. Eq a => ....
 947 then its body must look like
 948         f = /\a. \d. ...
 949
 950 Reason: when specialising the body for a call (f ty dexp), we want to
 951 substitute dexp for d, and pick up specialised calls in the body of f.
 952
 953 This doesn't always work.  One example I came across was htis:
 954         newtype Gen a = MkGen{ unGen :: Int -> a }
 955
 956         choose :: Eq a => a -> Gen a
 957         choose n = MkGen (\r -> n)
 958
 959         oneof = choose (1::Int)
 960
 961 It's a silly exapmle, but we get
 962         choose = /\a. g `cast` co
 963 where choose doesn't have any dict arguments.  Thus far I have not
 964 tried to fix this (wait till there's a real example).
 965
 966
 967 Note [Inline specialisations]
 968 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 969 We transfer to the specialised function any INLINE stuff from the
 970 original.  This means (a) the Activation in the IdInfo, and (b) any
 971 InlineMe on the RHS.
 972
 973 This is a change (Jun06).  Previously the idea is that the point of
 974 inlining was precisely to specialise the function at its call site,
 975 and that's not so important for the specialised copies.  But
 976 *pragma-directed* specialisation now takes place in the
 977 typechecker/desugarer, with manually specified INLINEs.  The
 978 specialiation here is automatic.  It'd be very odd if a function
 979 marked INLINE was specialised (because of some local use), and then
 980 forever after (including importing modules) the specialised version
 981 wasn't INLINEd.  After all, the programmer said INLINE!
 982
 983 You might wonder why we don't just not specialise INLINE functions.
 984 It's because even INLINE functions are sometimes not inlined, when
 985 they aren't applied to interesting arguments.  But perhaps the type
 986 arguments alone are enough to specialise (even though the args are too
 987 boring to trigger inlining), and it's certainly better to call the
 988 specialised version.
 989
 990 A case in point is dictionary functions, which are current marked
 991 INLINE, but which are worth specialising.
 992
 993 \begin{code}
 994 dropInline :: CoreExpr -> (Bool, CoreExpr)
 995 dropInline (Note InlineMe rhs) = (True,  rhs)
 996 dropInline rhs                 = (False, rhs)
 997 \end{code}
 998
 999 %************************************************************************
1000 %*                                                                      *
1001 \subsubsection{UsageDetails and suchlike}
1002 %*                                                                      *
1003 %************************************************************************
1004
1005 \begin{code}
1006 data UsageDetails
1007   = MkUD {
1008         dict_binds :: !(Bag DictBind),
1009                         -- Floated dictionary bindings
1010                         -- The order is important;
1011                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1012                         -- (Remember, Bags preserve order in GHC.)
1013
1014         calls     :: !CallDetails,
1015
1016         ud_fvs :: !VarSet       -- A superset of the variables mentioned in
1017                                 -- either dict_binds or calls
1018     }
1019
1020 instance Outputable UsageDetails where
1021   ppr (MkUD { dict_binds = dbs, calls = calls, ud_fvs = fvs })
1022         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma
1023                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1024                  ptext (sLit "calls") <+> equals <+> ppr calls,
1025                  ptext (sLit "fvs")   <+> equals <+> ppr fvs]))
1026
1027 type DictBind = (CoreBind, VarSet)
1028         -- The set is the free vars of the binding
1029         -- both tyvars and dicts
1030
1031 type DictExpr = CoreExpr
1032
1033 emptyUDs :: UsageDetails
1034 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM, ud_fvs = emptyVarSet }
1035
1036 ------------------------------------------------------------
1037 type CallDetails  = FiniteMap Id CallInfo
1038 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1039 type CallInfo     = FiniteMap CallKey
1040                               ([DictExpr], VarSet)              -- Dict args and the vars of the whole
1041                                                                 -- call (including tyvars)
1042                                                                 -- [*not* include the main id itself, of course]
1043         -- The finite maps eliminate duplicates
1044         -- The list of types and dictionaries is guaranteed to
1045         -- match the type of f
1046
1047 instance Outputable CallKey where
1048   ppr (CallKey ts) = ppr ts
1049
1050 -- Type isn't an instance of Ord, so that we can control which
1051 -- instance we use.  That's tiresome here.  Oh well
1052 instance Eq CallKey where
1053   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1054
1055 instance Ord CallKey where
1056   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1057                 where
1058                   cmp Nothing   Nothing   = EQ
1059                   cmp Nothing   (Just _)  = LT
1060                   cmp (Just _)  Nothing   = GT
1061                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1062
1063 unionCalls :: CallDetails -> CallDetails -> CallDetails
1064 unionCalls c1 c2 = plusFM_C plusFM c1 c2
1065
1066 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1067 singleCall id tys dicts
1068   = MkUD {dict_binds = emptyBag,
1069           calls      = unitFM id (unitFM (CallKey tys) (dicts, call_fvs)),
1070           ud_fvs     = call_fvs }
1071   where
1072     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1073     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1074         -- The type args (tys) are guaranteed to be part of the dictionary
1075         -- types, because they are just the constrained types,
1076         -- and the dictionary is therefore sure to be bound
1077         -- inside the binding for any type variables free in the type;
1078         -- hence it's safe to neglect tyvars free in tys when making
1079         -- the free-var set for this call
1080         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1081         --
1082         -- We don't include the 'id' itself.
1083
1084 mkCallUDs :: Subst -> Id -> [CoreExpr] -> UsageDetails
1085 mkCallUDs subst f args
1086   | null theta
1087   || not (all isClassPred theta)
1088         -- Only specialise if all overloading is on class params.
1089         -- In ptic, with implicit params, the type args
1090         --  *don't* say what the value of the implicit param is!
1091   || not (spec_tys `lengthIs` n_tyvars)
1092   || not ( dicts   `lengthIs` n_dicts)
1093   || not (any interestingArg dicts)     -- Note [Interesting dictionary arguments]
1094   || maybeToBool (lookupRule (\_act -> True) (substInScope subst) emptyRuleBase f args)
1095         -- There's already a rule covering this call.  A typical case
1096         -- is where there's an explicit user-provided rule.  Then
1097         -- we don't want to create a specialised version
1098         -- of the function that overlaps.
1099   = emptyUDs    -- Not overloaded, or no specialisation wanted
1100
1101   | otherwise
1102   = singleCall f spec_tys dicts
1103   where
1104     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1105     constrained_tyvars = tyVarsOfTheta theta
1106     n_tyvars           = length tyvars
1107     n_dicts            = length theta
1108
1109     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1110     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1111
1112     mk_spec_ty tyvar ty
1113         | tyvar `elemVarSet` constrained_tyvars = Just ty
1114         | otherwise                             = Nothing
1115 \end{code}
1116
1117 Note [Interesting dictionary arguments]
1118 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1119 Consider this
1120          \a.\d:Eq a.  let f = ... in ...(f d)...
1121 There really is not much point in specialising f wrt the dictionary d,
1122 because the code for the specialised f is not improved at all, because
1123 d is lambda-bound.  We simply get junk specialisations.
1124
1125 We re-use the function SimplUtils.interestingArg function to determine
1126 what sort of dictionary arguments have *some* information in them.
1127
1128
1129 \begin{code}
1130 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1131 plusUDs (MkUD {dict_binds = db1, calls = calls1, ud_fvs = fvs1})
1132         (MkUD {dict_binds = db2, calls = calls2, ud_fvs = fvs2})
1133   = MkUD {dict_binds = d, calls = c, ud_fvs = fvs1 `unionVarSet` fvs2}
1134   where
1135     d = db1    `unionBags`   db2
1136     c = calls1 `unionCalls`  calls2
1137
1138 plusUDList :: [UsageDetails] -> UsageDetails
1139 plusUDList = foldr plusUDs emptyUDs
1140
1141 -- zapCalls deletes calls to ids from uds
1142 zapCalls :: [Id] -> CallDetails -> CallDetails
1143 zapCalls ids calls = delListFromFM calls ids
1144
1145 mkDB :: CoreBind -> DictBind
1146 mkDB bind = (bind, bind_fvs bind)
1147
1148 bind_fvs :: CoreBind -> VarSet
1149 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1150 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1151                            where
1152                              bndrs = map fst prs
1153                              rhs_fvs = unionVarSets (map pair_fvs prs)
1154
1155 pair_fvs :: (Id, CoreExpr) -> VarSet
1156 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1157         -- Don't forget variables mentioned in the
1158         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1159         -- Also tyvars mentioned in its type; they may not appear in the RHS
1160         --      type T a = Int
1161         --      x :: T a = 3
1162
1163 addDictBind :: (Id,CoreExpr) -> UsageDetails -> UsageDetails
1164 addDictBind (dict,rhs) uds
1165   = uds { dict_binds = db `consBag` dict_binds uds
1166         , ud_fvs = ud_fvs uds `unionVarSet` fvs }
1167   where
1168     db@(_, fvs) = mkDB (NonRec dict rhs)
1169
1170 dumpAllDictBinds :: UsageDetails -> [CoreBind] -> [CoreBind]
1171 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1172   = foldrBag add binds dbs
1173   where
1174     add (bind,_) binds = bind : binds
1175
1176 dumpUDs :: [CoreBndr]
1177         -> UsageDetails -> CoreExpr
1178         -> (UsageDetails, CoreExpr)
1179 dumpUDs bndrs (MkUD { dict_binds = orig_dbs
1180                     , calls = orig_calls
1181                     , ud_fvs = fvs}) body
1182   = (new_uds, foldrBag add_let body dump_dbs)
1183                 -- This may delete fewer variables
1184                 -- than in priciple possible
1185   where
1186     new_uds =
1187      MkUD { dict_binds = free_dbs
1188           , calls      = free_calls
1189           , ud_fvs     = fvs `minusVarSet` bndr_set}
1190
1191     bndr_set = mkVarSet bndrs
1192     add_let (bind,_) body = Let bind body
1193
1194     (free_dbs, dump_dbs, dump_set)
1195         = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1196                 -- Important that it's foldl not foldr;
1197                 -- we're accumulating the set of dumped ids in dump_set
1198
1199     free_calls = filterCalls dump_set orig_calls
1200
1201     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1202         | dump_idset `intersectsVarSet` fvs     -- Dump it
1203         = (free_dbs, dump_dbs `snocBag` db,
1204            extendVarSetList dump_idset (bindersOf bind))
1205
1206         | otherwise     -- Don't dump it
1207         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1208
1209 filterCalls :: VarSet -> CallDetails -> CallDetails
1210 -- Remove any calls that mention the variables
1211 filterCalls bs calls
1212   = mapFM (\_ cs -> filter_calls cs) $
1213     filterFM (\k _ -> not (k `elemVarSet` bs)) calls
1214   where
1215     filter_calls :: CallInfo -> CallInfo
1216     filter_calls = filterFM (\_ (_, fvs) -> not (fvs `intersectsVarSet` bs))
1217 \end{code}
1218
1219
1220 %************************************************************************
1221 %*                                                                      *
1222 \subsubsection{Boring helper functions}
1223 %*                                                                      *
1224 %************************************************************************
1225
1226 \begin{code}
1227 type SpecM a = UniqSM a
1228
1229 initSM :: UniqSupply -> SpecM a -> a
1230 initSM    = initUs_
1231
1232 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1233 mapAndCombineSM _ []     = return ([], emptyUDs)
1234 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1235                               (ys, uds2) <- mapAndCombineSM f xs
1236                               return (y:ys, uds1 `plusUDs` uds2)
1237
1238 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1239 -- Clone the binders of the bind; return new bind with the cloned binders
1240 -- Return the substitution to use for RHSs, and the one to use for the body
1241 cloneBindSM subst (NonRec bndr rhs) = do
1242     us <- getUniqueSupplyM
1243     let (subst', bndr') = cloneIdBndr subst us bndr
1244     return (subst, subst', NonRec bndr' rhs)
1245
1246 cloneBindSM subst (Rec pairs) = do
1247     us <- getUniqueSupplyM
1248     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1249     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1250
1251 cloneBinders :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1252 cloneBinders subst bndrs = do
1253     us <- getUniqueSupplyM
1254     return (cloneIdBndrs subst us bndrs)
1255
1256 newIdSM :: Id -> Type -> SpecM Id
1257 newIdSM old_id new_ty = do
1258     uniq <- getUniqueM
1259     let
1260         -- Give the new Id a similar occurrence name to the old one
1261         name   = idName old_id
1262         new_id = mkUserLocal (mkSpecOcc (nameOccName name)) uniq new_ty (getSrcSpan name)
1263     return new_id
1264 \end{code}
1265
1266
1267                 Old (but interesting) stuff about unboxed bindings
1268                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1269
1270 What should we do when a value is specialised to a *strict* unboxed value?
1271
1272         map_*_* f (x:xs) = let h = f x
1273                                t = map f xs
1274                            in h:t
1275
1276 Could convert let to case:
1277
1278         map_*_Int# f (x:xs) = case f x of h# ->
1279                               let t = map f xs
1280                               in h#:t
1281
1282 This may be undesirable since it forces evaluation here, but the value
1283 may not be used in all branches of the body. In the general case this
1284 transformation is impossible since the mutual recursion in a letrec
1285 cannot be expressed as a case.
1286
1287 There is also a problem with top-level unboxed values, since our
1288 implementation cannot handle unboxed values at the top level.
1289
1290 Solution: Lift the binding of the unboxed value and extract it when it
1291 is used:
1292
1293         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1294                                   t = map f xs
1295                               in case h of
1296                                  _Lift h# -> h#:t
1297
1298 Now give it to the simplifier and the _Lifting will be optimised away.
1299
1300 The benfit is that we have given the specialised "unboxed" values a
1301 very simplep lifted semantics and then leave it up to the simplifier to
1302 optimise it --- knowing that the overheads will be removed in nearly
1303 all cases.
1304
1305 In particular, the value will only be evaluted in the branches of the
1306 program which use it, rather than being forced at the point where the
1307 value is bound. For example:
1308
1309         filtermap_*_* p f (x:xs)
1310           = let h = f x
1311                 t = ...
1312             in case p x of
1313                 True  -> h:t
1314                 False -> t
1315    ==>
1316         filtermap_*_Int# p f (x:xs)
1317           = let h = case (f x) of h# -> _Lift h#
1318                 t = ...
1319             in case p x of
1320                 True  -> case h of _Lift h#
1321                            -> h#:t
1322                 False -> t
1323
1324 The binding for h can still be inlined in the one branch and the
1325 _Lifting eliminated.
1326
1327
1328 Question: When won't the _Lifting be eliminated?
1329
1330 Answer: When they at the top-level (where it is necessary) or when
1331 inlining would duplicate work (or possibly code depending on
1332 options). However, the _Lifting will still be eliminated if the
1333 strictness analyser deems the lifted binding strict.
1334