compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 -- The above warning supression flag is a temporary kludge.
   8 -- While working on this module you are encouraged to remove it and fix
   9 -- any warnings in the module. See
  10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  11 -- for details
  12
  13 module Specialise ( specProgram ) where
  14
  15 #include "HsVersions.h"
  16
  17 import DynFlags ( DynFlags, DynFlag(..) )
  18 import Id               ( Id, idName, idType, mkUserLocal,
  19                           idInlinePragma, setInlinePragma )
  20 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  21                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  22                           tcCmpType, isUnLiftedType
  23                         )
  24 import CoreSubst        ( Subst, mkEmptySubst, extendTvSubstList, lookupIdSubst,
  25                           substBndr, substBndrs, substTy, substInScope,
  26                           cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs
  27                         )
  28 import VarSet
  29 import VarEnv
  30 import CoreSyn
  31 import CoreUtils        ( applyTypeToArgs, mkPiTypes )
  32 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  33 import CoreTidy         ( tidyRules )
  34 import CoreLint         ( showPass, endPass )
  35 import Rules            ( addIdSpecialisations, mkLocalRule, lookupRule, emptyRuleBase, rulesOfBinds )
  36 import PprCore          ( pprRules )
  37 import UniqSupply       ( UniqSupply,
  38                           UniqSM, initUs_,
  39                           MonadUnique(..)
  40                         )
  41 import Name
  42 import MkId             ( voidArgId, realWorldPrimId )
  43 import FiniteMap
  44 import Maybes           ( catMaybes, maybeToBool )
  45 import ErrUtils         ( dumpIfSet_dyn )
  46 import Bag
  47 import Util
  48 import Outputable
  49 import FastString
  50
  51 \end{code}
  52
  53 %************************************************************************
  54 %*                                                                      *
  55 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 These notes describe how we implement specialisation to eliminate
  60 overloading.
  61
  62 The specialisation pass works on Core
  63 syntax, complete with all the explicit dictionary application,
  64 abstraction and construction as added by the type checker.  The
  65 existing type checker remains largely as it is.
  66
  67 One important thought: the {\em types} passed to an overloaded
  68 function, and the {\em dictionaries} passed are mutually redundant.
  69 If the same function is applied to the same type(s) then it is sure to
  70 be applied to the same dictionary(s)---or rather to the same {\em
  71 values}.  (The arguments might look different but they will evaluate
  72 to the same value.)
  73
  74 Second important thought: we know that we can make progress by
  75 treating dictionary arguments as static and worth specialising on.  So
  76 we can do without binding-time analysis, and instead specialise on
  77 dictionary arguments and no others.
  78
  79 The basic idea
  80 ~~~~~~~~~~~~~~
  81 Suppose we have
  82
  83         let f = <f_rhs>
  84         in <body>
  85
  86 and suppose f is overloaded.
  87
  88 STEP 1: CALL-INSTANCE COLLECTION
  89
  90 We traverse <body>, accumulating all applications of f to types and
  91 dictionaries.
  92
  93 (Might there be partial applications, to just some of its types and
  94 dictionaries?  In principle yes, but in practice the type checker only
  95 builds applications of f to all its types and dictionaries, so partial
  96 applications could only arise as a result of transformation, and even
  97 then I think it's unlikely.  In any case, we simply don't accumulate such
  98 partial applications.)
  99
 100
 101 STEP 2: EQUIVALENCES
 102
 103 So now we have a collection of calls to f:
 104         f t1 t2 d1 d2
 105         f t3 t4 d3 d4
 106         ...
 107 Notice that f may take several type arguments.  To avoid ambiguity, we
 108 say that f is called at type t1/t2 and t3/t4.
 109
 110 We take equivalence classes using equality of the *types* (ignoring
 111 the dictionary args, which as mentioned previously are redundant).
 112
 113 STEP 3: SPECIALISATION
 114
 115 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 116 and create a local instance of f, defined thus:
 117
 118         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 119
 120 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 121 of simplification will now result.  However we don't actually *do* that
 122 simplification.  Rather, we leave it for the simplifier to do.  If we
 123 *did* do it, though, we'd get more call instances from the specialised
 124 RHS.  We can work out what they are by instantiating the call-instance
 125 set from f's RHS with the types t1, t2.
 126
 127 Add this new id to f's IdInfo, to record that f has a specialised version.
 128
 129 Before doing any of this, check that f's IdInfo doesn't already
 130 tell us about an existing instance of f at the required type/s.
 131 (This might happen if specialisation was applied more than once, or
 132 it might arise from user SPECIALIZE pragmas.)
 133
 134 Recursion
 135 ~~~~~~~~~
 136 Wait a minute!  What if f is recursive?  Then we can't just plug in
 137 its right-hand side, can we?
 138
 139 But it's ok.  The type checker *always* creates non-recursive definitions
 140 for overloaded recursive functions.  For example:
 141
 142         f x = f (x+x)           -- Yes I know its silly
 143
 144 becomes
 145
 146         f a (d::Num a) = let p = +.sel a d
 147                          in
 148                          letrec fl (y::a) = fl (p y y)
 149                          in
 150                          fl
 151
 152 We still have recusion for non-overloaded functions which we
 153 speciailise, but the recursive call should get specialised to the
 154 same recursive version.
 155
 156
 157 Polymorphism 1
 158 ~~~~~~~~~~~~~~
 159
 160 All this is crystal clear when the function is applied to *constant
 161 types*; that is, types which have no type variables inside.  But what if
 162 it is applied to non-constant types?  Suppose we find a call of f at type
 163 t1/t2.  There are two possibilities:
 164
 165 (a) The free type variables of t1, t2 are in scope at the definition point
 166 of f.  In this case there's no problem, we proceed just as before.  A common
 167 example is as follows.  Here's the Haskell:
 168
 169         g y = let f x = x+x
 170               in f y + f y
 171
 172 After typechecking we have
 173
 174         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 175                                 in +.sel a d (f a d y) (f a d y)
 176
 177 Notice that the call to f is at type type "a"; a non-constant type.
 178 Both calls to f are at the same type, so we can specialise to give:
 179
 180         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 181                                 in +.sel a d (f@a y) (f@a y)
 182
 183
 184 (b) The other case is when the type variables in the instance types
 185 are *not* in scope at the definition point of f.  The example we are
 186 working with above is a good case.  There are two instances of (+.sel a d),
 187 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 188 Yes, we can "common them up", a sort of limited common sub-expression deal.
 189 This would give:
 190
 191         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 192                                     f@a (x::a) = +.sel@a x x
 193                                 in +.sel@a (f@a y) (f@a y)
 194
 195 This can save work, and can't be spotted by the type checker, because
 196 the two instances of +.sel weren't originally at the same type.
 197
 198 Further notes on (b)
 199
 200 * There are quite a few variations here.  For example, the defn of
 201   +.sel could be floated ouside the \y, to attempt to gain laziness.
 202   It certainly mustn't be floated outside the \d because the d has to
 203   be in scope too.
 204
 205 * We don't want to inline f_rhs in this case, because
 206 that will duplicate code.  Just commoning up the call is the point.
 207
 208 * Nothing gets added to +.sel's IdInfo.
 209
 210 * Don't bother unless the equivalence class has more than one item!
 211
 212 Not clear whether this is all worth it.  It is of course OK to
 213 simply discard call-instances when passing a big lambda.
 214
 215 Polymorphism 2 -- Overloading
 216 ~~~~~~~~~~~~~~
 217 Consider a function whose most general type is
 218
 219         f :: forall a b. Ord a => [a] -> b -> b
 220
 221 There is really no point in making a version of g at Int/Int and another
 222 at Int/Bool, because it's only instancing the type variable "a" which
 223 buys us any efficiency. Since g is completely polymorphic in b there
 224 ain't much point in making separate versions of g for the different
 225 b types.
 226
 227 That suggests that we should identify which of g's type variables
 228 are constrained (like "a") and which are unconstrained (like "b").
 229 Then when taking equivalence classes in STEP 2, we ignore the type args
 230 corresponding to unconstrained type variable.  In STEP 3 we make
 231 polymorphic versions.  Thus:
 232
 233         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 234
 235 We do this.
 236
 237
 238 Dictionary floating
 239 ~~~~~~~~~~~~~~~~~~~
 240 Consider this
 241
 242         f a (d::Num a) = let g = ...
 243                          in
 244                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 245
 246 Here, g is only called at one type, but the dictionary isn't in scope at the
 247 definition point for g.  Usually the type checker would build a
 248 definition for d1 which enclosed g, but the transformation system
 249 might have moved d1's defn inward.  Solution: float dictionary bindings
 250 outwards along with call instances.
 251
 252 Consider
 253
 254         f x = let g p q = p==q
 255                   h r s = (r+s, g r s)
 256               in
 257               h x x
 258
 259
 260 Before specialisation, leaving out type abstractions we have
 261
 262         f df x = let g :: Eq a => a -> a -> Bool
 263                      g dg p q = == dg p q
 264                      h :: Num a => a -> a -> (a, Bool)
 265                      h dh r s = let deq = eqFromNum dh
 266                                 in (+ dh r s, g deq r s)
 267               in
 268               h df x x
 269
 270 After specialising h we get a specialised version of h, like this:
 271
 272                     h' r s = let deq = eqFromNum df
 273                              in (+ df r s, g deq r s)
 274
 275 But we can't naively make an instance for g from this, because deq is not in scope
 276 at the defn of g.  Instead, we have to float out the (new) defn of deq
 277 to widen its scope.  Notice that this floating can't be done in advance -- it only
 278 shows up when specialisation is done.
 279
 280 User SPECIALIZE pragmas
 281 ~~~~~~~~~~~~~~~~~~~~~~~
 282 Specialisation pragmas can be digested by the type checker, and implemented
 283 by adding extra definitions along with that of f, in the same way as before
 284
 285         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 286
 287 Indeed the pragmas *have* to be dealt with by the type checker, because
 288 only it knows how to build the dictionaries d1 and d2!  For example
 289
 290         g :: Ord a => [a] -> [a]
 291         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 292
 293 Here, the specialised version of g is an application of g's rhs to the
 294 Ord dictionary for (Tree Int), which only the type checker can conjure
 295 up.  There might not even *be* one, if (Tree Int) is not an instance of
 296 Ord!  (All the other specialision has suitable dictionaries to hand
 297 from actual calls.)
 298
 299 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 300 it is buried in a complex (as-yet-un-desugared) binding group.
 301 Maybe we should say
 302
 303         f@t1/t2 = f* t1 t2 d1 d2
 304
 305 where f* is the Id f with an IdInfo which says "inline me regardless!".
 306 Indeed all the specialisation could be done in this way.
 307 That in turn means that the simplifier has to be prepared to inline absolutely
 308 any in-scope let-bound thing.
 309
 310
 311 Again, the pragma should permit polymorphism in unconstrained variables:
 312
 313         h :: Ord a => [a] -> b -> b
 314         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 315
 316 We *insist* that all overloaded type variables are specialised to ground types,
 317 (and hence there can be no context inside a SPECIALIZE pragma).
 318 We *permit* unconstrained type variables to be specialised to
 319         - a ground type
 320         - or left as a polymorphic type variable
 321 but nothing in between.  So
 322
 323         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 324
 325 is *illegal*.  (It can be handled, but it adds complication, and gains the
 326 programmer nothing.)
 327
 328
 329 SPECIALISING INSTANCE DECLARATIONS
 330 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 331 Consider
 332
 333         instance Foo a => Foo [a] where
 334                 ...
 335         {-# SPECIALIZE instance Foo [Int] #-}
 336
 337 The original instance decl creates a dictionary-function
 338 definition:
 339
 340         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 341
 342 The SPECIALIZE pragma just makes a specialised copy, just as for
 343 ordinary function definitions:
 344
 345         dfun.Foo.List@Int :: Foo [Int]
 346         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 347
 348 The information about what instance of the dfun exist gets added to
 349 the dfun's IdInfo in the same way as a user-defined function too.
 350
 351
 352 Automatic instance decl specialisation?
 353 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 354 Can instance decls be specialised automatically?  It's tricky.
 355 We could collect call-instance information for each dfun, but
 356 then when we specialised their bodies we'd get new call-instances
 357 for ordinary functions; and when we specialised their bodies, we might get
 358 new call-instances of the dfuns, and so on.  This all arises because of
 359 the unrestricted mutual recursion between instance decls and value decls.
 360
 361 Still, there's no actual problem; it just means that we may not do all
 362 the specialisation we could theoretically do.
 363
 364 Furthermore, instance decls are usually exported and used non-locally,
 365 so we'll want to compile enough to get those specialisations done.
 366
 367 Lastly, there's no such thing as a local instance decl, so we can
 368 survive solely by spitting out *usage* information, and then reading that
 369 back in as a pragma when next compiling the file.  So for now,
 370 we only specialise instance decls in response to pragmas.
 371
 372
 373 SPITTING OUT USAGE INFORMATION
 374 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 375
 376 To spit out usage information we need to traverse the code collecting
 377 call-instance information for all imported (non-prelude?) functions
 378 and data types. Then we equivalence-class it and spit it out.
 379
 380 This is done at the top-level when all the call instances which escape
 381 must be for imported functions and data types.
 382
 383 *** Not currently done ***
 384
 385
 386 Partial specialisation by pragmas
 387 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 388 What about partial specialisation:
 389
 390         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 391         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 392
 393 or even
 394
 395         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 396
 397 Seems quite reasonable.  Similar things could be done with instance decls:
 398
 399         instance (Foo a, Foo b) => Foo (a,b) where
 400                 ...
 401         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 402         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 403
 404 Ho hum.  Things are complex enough without this.  I pass.
 405
 406
 407 Requirements for the simplifer
 408 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 409 The simplifier has to be able to take advantage of the specialisation.
 410
 411 * When the simplifier finds an application of a polymorphic f, it looks in
 412 f's IdInfo in case there is a suitable instance to call instead.  This converts
 413
 414         f t1 t2 d1 d2   ===>   f_t1_t2
 415
 416 Note that the dictionaries get eaten up too!
 417
 418 * Dictionary selection operations on constant dictionaries must be
 419   short-circuited:
 420
 421         +.sel Int d     ===>  +Int
 422
 423 The obvious way to do this is in the same way as other specialised
 424 calls: +.sel has inside it some IdInfo which tells that if it's applied
 425 to the type Int then it should eat a dictionary and transform to +Int.
 426
 427 In short, dictionary selectors need IdInfo inside them for constant
 428 methods.
 429
 430 * Exactly the same applies if a superclass dictionary is being
 431   extracted:
 432
 433         Eq.sel Int d   ===>   dEqInt
 434
 435 * Something similar applies to dictionary construction too.  Suppose
 436 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 437 one for (Eq [a]).  Then we want
 438
 439         dfun.Eq.List Int d      ===> dEq.List_Int
 440
 441 Where does the Eq [Int] dictionary come from?  It is built in
 442 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 443
 444 In short, dfun Ids need IdInfo with a specialisation for each
 445 constant instance of their instance declaration.
 446
 447 All this uses a single mechanism: the SpecEnv inside an Id
 448
 449
 450 What does the specialisation IdInfo look like?
 451 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 452
 453 The SpecEnv of an Id maps a list of types (the template) to an expression
 454
 455         [Type]  |->  Expr
 456
 457 For example, if f has this SpecInfo:
 458
 459         [Int, a]  ->  \d:Ord Int. f' a
 460
 461 it means that we can replace the call
 462
 463         f Int t  ===>  (\d. f' t)
 464
 465 This chucks one dictionary away and proceeds with the
 466 specialised version of f, namely f'.
 467
 468
 469 What can't be done this way?
 470 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 471 There is no way, post-typechecker, to get a dictionary for (say)
 472 Eq a from a dictionary for Eq [a].  So if we find
 473
 474         ==.sel [t] d
 475
 476 we can't transform to
 477
 478         eqList (==.sel t d')
 479
 480 where
 481         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 482
 483 Of course, we currently have no way to automatically derive
 484 eqList, nor to connect it to the Eq [a] instance decl, but you
 485 can imagine that it might somehow be possible.  Taking advantage
 486 of this is permanently ruled out.
 487
 488 Still, this is no great hardship, because we intend to eliminate
 489 overloading altogether anyway!
 490
 491
 492
 493 A note about non-tyvar dictionaries
 494 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 495 Some Ids have types like
 496
 497         forall a,b,c. Eq a -> Ord [a] -> tau
 498
 499 This seems curious at first, because we usually only have dictionary
 500 args whose types are of the form (C a) where a is a type variable.
 501 But this doesn't hold for the functions arising from instance decls,
 502 which sometimes get arguements with types of form (C (T a)) for some
 503 type constructor T.
 504
 505 Should we specialise wrt this compound-type dictionary?  We used to say
 506 "no", saying:
 507         "This is a heuristic judgement, as indeed is the fact that we
 508         specialise wrt only dictionaries.  We choose *not* to specialise
 509         wrt compound dictionaries because at the moment the only place
 510         they show up is in instance decls, where they are simply plugged
 511         into a returned dictionary.  So nothing is gained by specialising
 512         wrt them."
 513
 514 But it is simpler and more uniform to specialise wrt these dicts too;
 515 and in future GHC is likely to support full fledged type signatures
 516 like
 517         f ;: Eq [(a,b)] => ...
 518
 519
 520 %************************************************************************
 521 %*                                                                      *
 522 \subsubsection{The new specialiser}
 523 %*                                                                      *
 524 %************************************************************************
 525
 526 Our basic game plan is this.  For let(rec) bound function
 527         f :: (C a, D c) => (a,b,c,d) -> Bool
 528
 529 * Find any specialised calls of f, (f ts ds), where
 530   ts are the type arguments t1 .. t4, and
 531   ds are the dictionary arguments d1 .. d2.
 532
 533 * Add a new definition for f1 (say):
 534
 535         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 536
 537   Note that we abstract over the unconstrained type arguments.
 538
 539 * Add the mapping
 540
 541         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 542
 543   to the specialisations of f.  This will be used by the
 544   simplifier to replace calls
 545                 (f t1 t2 t3 t4) da db
 546   by
 547                 (\d1 d1 -> f1 t2 t4) da db
 548
 549   All the stuff about how many dictionaries to discard, and what types
 550   to apply the specialised function to, are handled by the fact that the
 551   SpecEnv contains a template for the result of the specialisation.
 552
 553 We don't build *partial* specialisations for f.  For example:
 554
 555   f :: Eq a => a -> a -> Bool
 556   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 557
 558 Here, little is gained by making a specialised copy of f.
 559 There's a distinct danger that the specialised version would
 560 first build a dictionary for (Eq b, Eq c), and then select the (==)
 561 method from it!  Even if it didn't, not a great deal is saved.
 562
 563 We do, however, generate polymorphic, but not overloaded, specialisations:
 564
 565   f :: Eq a => [a] -> b -> b -> b
 566   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 567
 568 Hence, the invariant is this:
 569
 570         *** no specialised version is overloaded ***
 571
 572
 573 %************************************************************************
 574 %*                                                                      *
 575 \subsubsection{The exported function}
 576 %*                                                                      *
 577 %************************************************************************
 578
 579 \begin{code}
 580 specProgram :: DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]
 581 specProgram dflags us binds = do
 582
 583         showPass dflags "Specialise"
 584
 585         let binds' = initSM us (do (binds', uds') <- go binds
 586                                    return (dumpAllDictBinds uds' binds'))
 587
 588         endPass dflags "Specialise" Opt_D_dump_spec binds'
 589
 590         dumpIfSet_dyn dflags Opt_D_dump_rules "Top-level specialisations"
 591                   (withPprStyle defaultUserStyle $
 592                    pprRules (tidyRules emptyTidyEnv (rulesOfBinds binds')))
 593
 594         return binds'
 595   where
 596         -- We need to start with a Subst that knows all the things
 597         -- that are in scope, so that the substitution engine doesn't
 598         -- accidentally re-use a unique that's already in use
 599         -- Easiest thing is to do it all at once, as if all the top-level
 600         -- decls were mutually recursive
 601     top_subst       = mkEmptySubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 602
 603     go []           = return ([], emptyUDs)
 604     go (bind:binds) = do (binds', uds) <- go binds
 605                          (bind', uds') <- specBind top_subst bind uds
 606                          return (bind' ++ binds', uds')
 607 \end{code}
 608
 609 %************************************************************************
 610 %*                                                                      *
 611 \subsubsection{@specExpr@: the main function}
 612 %*                                                                      *
 613 %************************************************************************
 614
 615 \begin{code}
 616 specVar :: Subst -> Id -> CoreExpr
 617 specVar subst v = lookupIdSubst subst v
 618
 619 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 620 -- We carry a substitution down:
 621 --      a) we must clone any binding that might flaot outwards,
 622 --         to avoid name clashes
 623 --      b) we carry a type substitution to use when analysing
 624 --         the RHS of specialised bindings (no type-let!)
 625
 626 ---------------- First the easy cases --------------------
 627 specExpr subst (Type ty) = return (Type (substTy subst ty), emptyUDs)
 628 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
 629 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
 630 specExpr subst (Cast e co) = do
 631     (e', uds) <- specExpr subst e
 632     return ((Cast e' (substTy subst co)), uds)
 633 specExpr subst (Note note body) = do
 634     (body', uds) <- specExpr subst body
 635     return (Note (specNote subst note) body', uds)
 636
 637
 638 ---------------- Applications might generate a call instance --------------------
 639 specExpr subst expr@(App {})
 640   = go expr []
 641   where
 642     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
 643                                (fun', uds_app) <- go fun (arg':args)
 644                                return (App fun' arg', uds_arg `plusUDs` uds_app)
 645
 646     go (Var f)       args = case specVar subst f of
 647                                 Var f' -> return (Var f', mkCallUDs subst f' args)
 648                                 e'     -> return (e', emptyUDs) -- I don't expect this!
 649     go other         _    = specExpr subst other
 650
 651 ---------------- Lambda/case require dumping of usage details --------------------
 652 specExpr subst e@(Lam _ _) = do
 653     (body', uds) <- specExpr subst' body
 654     let (filtered_uds, body'') = dumpUDs bndrs' uds body'
 655     return (mkLams bndrs' body'', filtered_uds)
 656   where
 657     (bndrs, body) = collectBinders e
 658     (subst', bndrs') = substBndrs subst bndrs
 659         -- More efficient to collect a group of binders together all at once
 660         -- and we don't want to split a lambda group with dumped bindings
 661
 662 specExpr subst (Case scrut case_bndr ty alts) = do
 663     (scrut', uds_scrut) <- specExpr subst scrut
 664     (alts', uds_alts) <- mapAndCombineSM spec_alt alts
 665     return (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 666   where
 667     (subst_alt, case_bndr') = substBndr subst case_bndr
 668         -- No need to clone case binder; it can't float like a let(rec)
 669
 670     spec_alt (con, args, rhs) = do
 671           (rhs', uds) <- specExpr subst_rhs rhs
 672           let (uds', rhs'') = dumpUDs args uds rhs'
 673           return ((con, args', rhs''), uds')
 674         where
 675           (subst_rhs, args') = substBndrs subst_alt args
 676
 677 ---------------- Finally, let is the interesting case --------------------
 678 specExpr subst (Let bind body) = do
 679         -- Clone binders
 680     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
 681
 682         -- Deal with the body
 683     (body', body_uds) <- specExpr body_subst body
 684
 685         -- Deal with the bindings
 686     (binds', uds) <- specBind rhs_subst bind' body_uds
 687
 688         -- All done
 689     return (foldr Let body' binds', uds)
 690
 691 -- Must apply the type substitution to coerceions
 692 specNote :: Subst -> Note -> Note
 693 specNote _ note = note
 694 \end{code}
 695
 696 %************************************************************************
 697 %*                                                                      *
 698 \subsubsection{Dealing with a binding}
 699 %*                                                                      *
 700 %************************************************************************
 701
 702 \begin{code}
 703 specBind :: Subst                       -- Use this for RHSs
 704          -> CoreBind
 705          -> UsageDetails                -- Info on how the scope of the binding
 706          -> SpecM ([CoreBind],          -- New bindings
 707                    UsageDetails)        -- And info to pass upstream
 708
 709 specBind rhs_subst bind body_uds
 710   = do  { (bind', bind_uds) <- specBindItself rhs_subst bind (calls body_uds)
 711         ; return (finishSpecBind bind' bind_uds body_uds) }
 712
 713 finishSpecBind :: CoreBind -> UsageDetails -> UsageDetails -> ([CoreBind], UsageDetails)
 714 finishSpecBind bind
 715         (MkUD { dict_binds = rhs_dbs,  calls = rhs_calls,  ud_fvs = rhs_fvs })
 716         (MkUD { dict_binds = body_dbs, calls = body_calls, ud_fvs = body_fvs })
 717   | not (mkVarSet bndrs `intersectsVarSet` all_fvs)
 718                 -- Common case 1: the bound variables are not
 719                 --                mentioned in the dictionary bindings
 720   = ([bind], MkUD { dict_binds = body_dbs `unionBags` rhs_dbs
 721                         -- It's important that the `unionBags` is this way round,
 722                         -- because body_uds may bind dictionaries that are
 723                         -- used in the calls passed to specDefn.  So the
 724                         -- dictionary bindings in rhs_uds may mention
 725                         -- dictionaries bound in body_uds.
 726                   , calls  = all_calls
 727                   , ud_fvs = all_fvs })
 728
 729   | case bind of { NonRec {} -> True; Rec {} -> False }
 730                 -- Common case 2: no specialisation happened, and binding
 731                 --                is non-recursive.  But the binding may be
 732                 --                mentioned in body_dbs, so we should put it first
 733   = ([], MkUD { dict_binds = rhs_dbs `unionBags` ((bind, b_fvs) `consBag` body_dbs)
 734               , calls      = all_calls
 735               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 736
 737   | otherwise   -- General case: make a huge Rec (sigh)
 738   = ([], MkUD { dict_binds = unitBag (Rec all_db_prs, all_db_fvs)
 739               , calls      = all_calls
 740               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 741   where
 742     all_fvs = rhs_fvs `unionVarSet` body_fvs
 743     all_calls = zapCalls bndrs (rhs_calls `unionCalls` body_calls)
 744
 745     bndrs   = bindersOf bind
 746     b_fvs   = bind_fvs bind
 747
 748     (all_db_prs, all_db_fvs) = add (bind, b_fvs) $
 749                                foldrBag add ([], emptyVarSet) $
 750                                rhs_dbs `unionBags` body_dbs
 751     add (NonRec b r, b_fvs) (prs, fvs) = ((b,r)  : prs, b_fvs `unionVarSet` fvs)
 752     add (Rec b_prs,  b_fvs) (prs, fvs) = (b_prs ++ prs, b_fvs `unionVarSet` fvs)
 753
 754 specBindItself :: Subst -> CoreBind -> CallDetails -> SpecM (CoreBind, UsageDetails)
 755
 756 -- specBindItself deals with the RHS, specialising it according
 757 -- to the calls found in the body (if any)
 758 specBindItself rhs_subst (NonRec bndr rhs) call_info = do
 759     ((bndr',rhs'), spec_defns, spec_uds) <- specDefn rhs_subst call_info (bndr,rhs)
 760     let
 761         new_bind | null spec_defns = NonRec bndr' rhs'
 762                  | otherwise       = Rec ((bndr',rhs'):spec_defns)
 763                 -- bndr' mentions the spec_defns in its SpecEnv
 764                 -- Not sure why we couln't just put the spec_defns first
 765     return (new_bind, spec_uds)
 766
 767 specBindItself rhs_subst (Rec pairs) call_info = do
 768     stuff <- mapM (specDefn rhs_subst call_info) pairs
 769     let
 770         (pairs', spec_defns_s, spec_uds_s) = unzip3 stuff
 771         spec_defns = concat spec_defns_s
 772         spec_uds   = plusUDList spec_uds_s
 773         new_bind   = Rec (spec_defns ++ pairs')
 774     return (new_bind, spec_uds)
 775
 776
 777 specDefn :: Subst                       -- Subst to use for RHS
 778          -> CallDetails                 -- Info on how it is used in its scope
 779          -> (Id, CoreExpr)              -- The thing being bound and its un-processed RHS
 780          -> SpecM ((Id, CoreExpr),      -- The thing and its processed RHS
 781                                         --      the Id may now have specialisations attached
 782                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 783                    UsageDetails         -- Stuff to fling upwards from the RHS and its
 784             )                           --      specialised versions
 785
 786 specDefn subst calls (fn, rhs)
 787         -- The first case is the interesting one
 788   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 789   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 790   && notNull calls_for_me               -- And there are some calls to specialise
 791
 792 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 793 --      See Note [Inline specialisation] for why we do not
 794 --      switch off specialisation for inline functions = do
 795   = do
 796      -- Specialise the body of the function
 797     (rhs', rhs_uds) <- specExpr subst rhs
 798
 799       -- Make a specialised version for each call in calls_for_me
 800     stuff <- mapM spec_call calls_for_me
 801     let
 802         (spec_defns, spec_uds, spec_rules) = unzip3 stuff
 803
 804         fn' = addIdSpecialisations fn spec_rules
 805
 806     return ((fn',rhs'),
 807               spec_defns,
 808               rhs_uds `plusUDs` plusUDList spec_uds)
 809
 810   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 811   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") <+> ppr fn )
 812           -- Note [Specialisation shape]
 813     (do  { (rhs', rhs_uds) <- specExpr subst rhs
 814         ; return ((fn, rhs'), [], rhs_uds) })
 815
 816   where
 817     fn_type            = idType fn
 818     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 819     n_tyvars           = length tyvars
 820     n_dicts            = length theta
 821     inline_prag        = idInlinePragma fn
 822
 823         -- It's important that we "see past" any INLINE pragma
 824         -- else we'll fail to specialise an INLINE thing
 825     (inline_rhs, rhs_inside) = dropInline rhs
 826     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs_inside
 827
 828     rhs_dicts = take n_dicts rhs_ids
 829     body      = mkLams (drop n_dicts rhs_ids) rhs_body
 830                 -- Glue back on the non-dict lambdas
 831
 832     calls_for_me = case lookupFM calls fn of
 833                         Nothing -> []
 834                         Just cs -> fmToList cs
 835
 836     ----------------------------------------------------------
 837         -- Specialise to one particular call pattern
 838     spec_call :: (CallKey, ([DictExpr], VarSet))        -- Call instance
 839               -> SpecM ((Id,CoreExpr),                  -- Specialised definition
 840                         UsageDetails,                   -- Usage details from specialised body
 841                         CoreRule)                       -- Info for the Id's SpecEnv
 842     spec_call (CallKey call_ts, (call_ds, _))
 843       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts ) do
 844                 -- Calls are only recorded for properly-saturated applications
 845
 846         -- Suppose f's defn is  f = /\ a b c d -> \ d1 d2 -> rhs
 847         -- Supppose the call is for f [Just t1, Nothing, Just t3, Nothing] [dx1, dx2]
 848
 849         -- Construct the new binding
 850         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b d -> rhs)
 851         -- PLUS the usage-details
 852         --      { d1' = dx1; d2' = dx2 }
 853         -- where d1', d2' are cloned versions of d1,d2, with the type substitution applied.
 854         --
 855         -- Note that the substitution is applied to the whole thing.
 856         -- This is convenient, but just slightly fragile.  Notably:
 857         --      * There had better be no name clashes in a/b/c/d
 858         --
 859         let
 860                 -- poly_tyvars = [b,d] in the example above
 861                 -- spec_tyvars = [a,c]
 862                 -- ty_args     = [t1,b,t3,d]
 863            poly_tyvars = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 864            spec_tyvars = [tv | (tv, Just _)  <- rhs_tyvars `zip` call_ts]
 865            ty_args     = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 866                        where
 867                          mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 868                          mk_ty_arg _         (Just ty) = Type ty
 869            rhs_subst  = extendTvSubstList subst (spec_tyvars `zip` [ty | Just ty <- call_ts])
 870
 871         (rhs_subst', rhs_dicts') <- cloneBinders rhs_subst rhs_dicts
 872         let
 873            inst_args = ty_args ++ map Var rhs_dicts'
 874
 875                 -- Figure out the type of the specialised function
 876            body_ty = applyTypeToArgs rhs fn_type inst_args
 877            (lam_args, app_args)                 -- Add a dummy argument if body_ty is unlifted
 878                 | isUnLiftedType body_ty        -- C.f. WwLib.mkWorkerArgs
 879                 = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 880                 | otherwise = (poly_tyvars, poly_tyvars)
 881            spec_id_ty = mkPiTypes lam_args body_ty
 882
 883         spec_f <- newIdSM fn spec_id_ty
 884         (spec_rhs, rhs_uds) <- specExpr rhs_subst' (mkLams lam_args body)
 885         let
 886                 -- The rule to put in the function's specialisation is:
 887                 --      forall b,d, d1',d2'.  f t1 b t3 d d1' d2' = f1 b d
 888            spec_env_rule = mkLocalRule (mkFastString ("SPEC " ++ showSDoc (ppr fn)))
 889                                 inline_prag     -- Note [Auto-specialisation and RULES]
 890                                 (idName fn)
 891                                 (poly_tyvars ++ rhs_dicts')
 892                                 inst_args
 893                                 (mkVarApps (Var spec_f) app_args)
 894
 895                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 896            final_uds = foldr addDictBind rhs_uds (my_zipEqual "spec_call" rhs_dicts' call_ds)
 897
 898            spec_pr | inline_rhs = (spec_f `setInlinePragma` inline_prag, Note InlineMe spec_rhs)
 899                    | otherwise  = (spec_f,                               spec_rhs)
 900
 901         return (spec_pr, final_uds, spec_env_rule)
 902
 903       where
 904         my_zipEqual doc xs ys
 905          | debugIsOn && not (equalLength xs ys)
 906              = pprPanic "my_zipEqual" (vcat
 907                                                 [ ppr xs, ppr ys
 908                                                 , ppr fn <+> ppr call_ts
 909                                                 , ppr (idType fn), ppr theta
 910                                                 , ppr n_dicts, ppr rhs_dicts
 911                                                 , ppr rhs])
 912          | otherwise               = zipEqual doc xs ys
 913 \end{code}
 914
 915 Note [Auto-specialisation and RULES]
 916 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 917 Consider:
 918    g :: Num a => a -> a
 919    g = ...
 920
 921    f :: (Int -> Int) -> Int
 922    f w = ...
 923    {-# RULE f g = 0 #-}
 924
 925 Suppose that auto-specialisation makes a specialised version of
 926 g::Int->Int That version won't appear in the LHS of the RULE for f.
 927 So if the specialisation rule fires too early, the rule for f may
 928 never fire.
 929
 930 It might be possible to add new rules, to "complete" the rewrite system.
 931 Thus when adding
 932         RULE forall d. g Int d = g_spec
 933 also add
 934         RULE f g_spec = 0
 935
 936 But that's a bit complicated.  For now we ask the programmer's help,
 937 by *copying the INLINE activation pragma* to the auto-specialised rule.
 938 So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule will also
 939 not be active until phase 2.
 940
 941
 942 Note [Specialisation shape]
 943 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 944 We only specialise a function if it has visible top-level lambdas
 945 corresponding to its overloading.  E.g. if
 946         f :: forall a. Eq a => ....
 947 then its body must look like
 948         f = /\a. \d. ...
 949
 950 Reason: when specialising the body for a call (f ty dexp), we want to
 951 substitute dexp for d, and pick up specialised calls in the body of f.
 952
 953 This doesn't always work.  One example I came across was htis:
 954         newtype Gen a = MkGen{ unGen :: Int -> a }
 955
 956         choose :: Eq a => a -> Gen a
 957         choose n = MkGen (\r -> n)
 958
 959         oneof = choose (1::Int)
 960
 961 It's a silly exapmle, but we get
 962         choose = /\a. g `cast` co
 963 where choose doesn't have any dict arguments.  Thus far I have not
 964 tried to fix this (wait till there's a real example).
 965
 966
 967 Note [Inline specialisations]
 968 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 969 We transfer to the specialised function any INLINE stuff from the
 970 original.  This means (a) the Activation in the IdInfo, and (b) any
 971 InlineMe on the RHS.
 972
 973 This is a change (Jun06).  Previously the idea is that the point of
 974 inlining was precisely to specialise the function at its call site,
 975 and that's not so important for the specialised copies.  But
 976 *pragma-directed* specialisation now takes place in the
 977 typechecker/desugarer, with manually specified INLINEs.  The
 978 specialiation here is automatic.  It'd be very odd if a function
 979 marked INLINE was specialised (because of some local use), and then
 980 forever after (including importing modules) the specialised version
 981 wasn't INLINEd.  After all, the programmer said INLINE!
 982
 983 You might wonder why we don't just not specialise INLINE functions.
 984 It's because even INLINE functions are sometimes not inlined, when
 985 they aren't applied to interesting arguments.  But perhaps the type
 986 arguments alone are enough to specialise (even though the args are too
 987 boring to trigger inlining), and it's certainly better to call the
 988 specialised version.
 989
 990 A case in point is dictionary functions, which are current marked
 991 INLINE, but which are worth specialising.
 992
 993 \begin{code}
 994 dropInline :: CoreExpr -> (Bool, CoreExpr)
 995 dropInline (Note InlineMe rhs) = (True,  rhs)
 996 dropInline rhs                 = (False, rhs)
 997 \end{code}
 998
 999 %************************************************************************
1000 %*                                                                      *
1001 \subsubsection{UsageDetails and suchlike}
1002 %*                                                                      *
1003 %************************************************************************
1004
1005 \begin{code}
1006 data UsageDetails
1007   = MkUD {
1008         dict_binds :: !(Bag DictBind),
1009                         -- Floated dictionary bindings
1010                         -- The order is important;
1011                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1012                         -- (Remember, Bags preserve order in GHC.)
1013
1014         calls     :: !CallDetails,
1015
1016         ud_fvs :: !VarSet       -- A superset of the variables mentioned in
1017                                 -- either dict_binds or calls
1018     }
1019
1020 instance Outputable UsageDetails where
1021   ppr (MkUD { dict_binds = dbs, calls = calls, ud_fvs = fvs })
1022         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma
1023                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1024                  ptext (sLit "calls") <+> equals <+> ppr calls,
1025                  ptext (sLit "fvs")   <+> equals <+> ppr fvs]))
1026
1027 type DictBind = (CoreBind, VarSet)
1028         -- The set is the free vars of the binding
1029         -- both tyvars and dicts
1030
1031 type DictExpr = CoreExpr
1032
1033 emptyUDs :: UsageDetails
1034 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM, ud_fvs = emptyVarSet }
1035
1036 ------------------------------------------------------------
1037 type CallDetails  = FiniteMap Id CallInfo
1038 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1039 type CallInfo     = FiniteMap CallKey
1040                               ([DictExpr], VarSet)              -- Dict args and the vars of the whole
1041                                                                 -- call (including tyvars)
1042                                                                 -- [*not* include the main id itself, of course]
1043         -- The finite maps eliminate duplicates
1044         -- The list of types and dictionaries is guaranteed to
1045         -- match the type of f
1046
1047 instance Outputable CallKey where
1048   ppr (CallKey ts) = ppr ts
1049
1050 -- Type isn't an instance of Ord, so that we can control which
1051 -- instance we use.  That's tiresome here.  Oh well
1052 instance Eq CallKey where
1053   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1054
1055 instance Ord CallKey where
1056   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1057                 where
1058                   cmp Nothing   Nothing   = EQ
1059                   cmp Nothing   (Just _)  = LT
1060                   cmp (Just _)  Nothing   = GT
1061                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1062
1063 unionCalls :: CallDetails -> CallDetails -> CallDetails
1064 unionCalls c1 c2 = plusFM_C plusFM c1 c2
1065
1066 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1067 singleCall id tys dicts
1068   = MkUD {dict_binds = emptyBag,
1069           calls      = unitFM id (unitFM (CallKey tys) (dicts, call_fvs)),
1070           ud_fvs     = call_fvs }
1071   where
1072     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1073     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1074         -- The type args (tys) are guaranteed to be part of the dictionary
1075         -- types, because they are just the constrained types,
1076         -- and the dictionary is therefore sure to be bound
1077         -- inside the binding for any type variables free in the type;
1078         -- hence it's safe to neglect tyvars free in tys when making
1079         -- the free-var set for this call
1080         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1081         --
1082         -- We don't include the 'id' itself.
1083
1084 mkCallUDs :: Subst -> Id -> [CoreExpr] -> UsageDetails
1085 mkCallUDs subst f args
1086   | null theta
1087   || not (all isClassPred theta)
1088         -- Only specialise if all overloading is on class params.
1089         -- In ptic, with implicit params, the type args
1090         --  *don't* say what the value of the implicit param is!
1091   || not (spec_tys `lengthIs` n_tyvars)
1092   || not ( dicts   `lengthIs` n_dicts)
1093   || maybeToBool (lookupRule (\_act -> True) (substInScope subst) emptyRuleBase f args)
1094         -- There's already a rule covering this call.  A typical case
1095         -- is where there's an explicit user-provided rule.  Then
1096         -- we don't want to create a specialised version
1097         -- of the function that overlaps.
1098   = emptyUDs    -- Not overloaded, or no specialisation wanted
1099
1100   | otherwise
1101   = singleCall f spec_tys dicts
1102   where
1103     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1104     constrained_tyvars = tyVarsOfTheta theta
1105     n_tyvars           = length tyvars
1106     n_dicts            = length theta
1107
1108     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1109     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1110
1111     mk_spec_ty tyvar ty
1112         | tyvar `elemVarSet` constrained_tyvars = Just ty
1113         | otherwise                             = Nothing
1114
1115 ------------------------------------------------------------
1116 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1117 plusUDs (MkUD {dict_binds = db1, calls = calls1, ud_fvs = fvs1})
1118         (MkUD {dict_binds = db2, calls = calls2, ud_fvs = fvs2})
1119   = MkUD {dict_binds = d, calls = c, ud_fvs = fvs1 `unionVarSet` fvs2}
1120   where
1121     d = db1    `unionBags`   db2
1122     c = calls1 `unionCalls`  calls2
1123
1124 plusUDList :: [UsageDetails] -> UsageDetails
1125 plusUDList = foldr plusUDs emptyUDs
1126
1127 -- zapCalls deletes calls to ids from uds
1128 zapCalls :: [Id] -> CallDetails -> CallDetails
1129 zapCalls ids calls = delListFromFM calls ids
1130
1131 mkDB :: CoreBind -> DictBind
1132 mkDB bind = (bind, bind_fvs bind)
1133
1134 bind_fvs :: CoreBind -> VarSet
1135 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1136 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1137                            where
1138                              bndrs = map fst prs
1139                              rhs_fvs = unionVarSets (map pair_fvs prs)
1140
1141 pair_fvs :: (Id, CoreExpr) -> VarSet
1142 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1143         -- Don't forget variables mentioned in the
1144         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1145         -- Also tyvars mentioned in its type; they may not appear in the RHS
1146         --      type T a = Int
1147         --      x :: T a = 3
1148
1149 addDictBind :: (Id,CoreExpr) -> UsageDetails -> UsageDetails
1150 addDictBind (dict,rhs) uds
1151   = uds { dict_binds = db `consBag` dict_binds uds
1152         , ud_fvs = ud_fvs uds `unionVarSet` fvs }
1153   where
1154     db@(_, fvs) = mkDB (NonRec dict rhs)
1155
1156 dumpAllDictBinds :: UsageDetails -> [CoreBind] -> [CoreBind]
1157 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1158   = foldrBag add binds dbs
1159   where
1160     add (bind,_) binds = bind : binds
1161
1162 dumpUDs :: [CoreBndr]
1163         -> UsageDetails -> CoreExpr
1164         -> (UsageDetails, CoreExpr)
1165 dumpUDs bndrs (MkUD { dict_binds = orig_dbs
1166                     , calls = orig_calls
1167                     , ud_fvs = fvs}) body
1168   = (new_uds, foldrBag add_let body dump_dbs)
1169                 -- This may delete fewer variables
1170                 -- than in priciple possible
1171   where
1172     new_uds =
1173      MkUD { dict_binds = free_dbs
1174           , calls      = free_calls
1175           , ud_fvs     = fvs `minusVarSet` bndr_set}
1176
1177     bndr_set = mkVarSet bndrs
1178     add_let (bind,_) body = Let bind body
1179
1180     (free_dbs, dump_dbs, dump_set)
1181         = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1182                 -- Important that it's foldl not foldr;
1183                 -- we're accumulating the set of dumped ids in dump_set
1184
1185     free_calls = filterCalls dump_set orig_calls
1186
1187     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1188         | dump_idset `intersectsVarSet` fvs     -- Dump it
1189         = (free_dbs, dump_dbs `snocBag` db,
1190            extendVarSetList dump_idset (bindersOf bind))
1191
1192         | otherwise     -- Don't dump it
1193         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1194
1195 filterCalls :: VarSet -> CallDetails -> CallDetails
1196 -- Remove any calls that mention the variables
1197 filterCalls bs calls
1198   = mapFM (\_ cs -> filter_calls cs) $
1199     filterFM (\k _ -> not (k `elemVarSet` bs)) calls
1200   where
1201     filter_calls :: CallInfo -> CallInfo
1202     filter_calls = filterFM (\_ (_, fvs) -> not (fvs `intersectsVarSet` bs))
1203 \end{code}
1204
1205
1206 %************************************************************************
1207 %*                                                                      *
1208 \subsubsection{Boring helper functions}
1209 %*                                                                      *
1210 %************************************************************************
1211
1212 \begin{code}
1213 type SpecM a = UniqSM a
1214
1215 initSM :: UniqSupply -> SpecM a -> a
1216 initSM    = initUs_
1217
1218 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1219 mapAndCombineSM _ []     = return ([], emptyUDs)
1220 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1221                               (ys, uds2) <- mapAndCombineSM f xs
1222                               return (y:ys, uds1 `plusUDs` uds2)
1223
1224 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1225 -- Clone the binders of the bind; return new bind with the cloned binders
1226 -- Return the substitution to use for RHSs, and the one to use for the body
1227 cloneBindSM subst (NonRec bndr rhs) = do
1228     us <- getUniqueSupplyM
1229     let (subst', bndr') = cloneIdBndr subst us bndr
1230     return (subst, subst', NonRec bndr' rhs)
1231
1232 cloneBindSM subst (Rec pairs) = do
1233     us <- getUniqueSupplyM
1234     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1235     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1236
1237 cloneBinders :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1238 cloneBinders subst bndrs = do
1239     us <- getUniqueSupplyM
1240     return (cloneIdBndrs subst us bndrs)
1241
1242 newIdSM :: Id -> Type -> SpecM Id
1243 newIdSM old_id new_ty = do
1244     uniq <- getUniqueM
1245     let
1246         -- Give the new Id a similar occurrence name to the old one
1247         name   = idName old_id
1248         new_id = mkUserLocal (mkSpecOcc (nameOccName name)) uniq new_ty (getSrcSpan name)
1249     return new_id
1250 \end{code}
1251
1252
1253                 Old (but interesting) stuff about unboxed bindings
1254                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1255
1256 What should we do when a value is specialised to a *strict* unboxed value?
1257
1258         map_*_* f (x:xs) = let h = f x
1259                                t = map f xs
1260                            in h:t
1261
1262 Could convert let to case:
1263
1264         map_*_Int# f (x:xs) = case f x of h# ->
1265                               let t = map f xs
1266                               in h#:t
1267
1268 This may be undesirable since it forces evaluation here, but the value
1269 may not be used in all branches of the body. In the general case this
1270 transformation is impossible since the mutual recursion in a letrec
1271 cannot be expressed as a case.
1272
1273 There is also a problem with top-level unboxed values, since our
1274 implementation cannot handle unboxed values at the top level.
1275
1276 Solution: Lift the binding of the unboxed value and extract it when it
1277 is used:
1278
1279         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1280                                   t = map f xs
1281                               in case h of
1282                                  _Lift h# -> h#:t
1283
1284 Now give it to the simplifier and the _Lifting will be optimised away.
1285
1286 The benfit is that we have given the specialised "unboxed" values a
1287 very simplep lifted semantics and then leave it up to the simplifier to
1288 optimise it --- knowing that the overheads will be removed in nearly
1289 all cases.
1290
1291 In particular, the value will only be evaluted in the branches of the
1292 program which use it, rather than being forced at the point where the
1293 value is bound. For example:
1294
1295         filtermap_*_* p f (x:xs)
1296           = let h = f x
1297                 t = ...
1298             in case p x of
1299                 True  -> h:t
1300                 False -> t
1301    ==>
1302         filtermap_*_Int# p f (x:xs)
1303           = let h = case (f x) of h# -> _Lift h#
1304                 t = ...
1305             in case p x of
1306                 True  -> case h of _Lift h#
1307                            -> h#:t
1308                 False -> t
1309
1310 The binding for h can still be inlined in the one branch and the
1311 _Lifting eliminated.
1312
1313
1314 Question: When won't the _Lifting be eliminated?
1315
1316 Answer: When they at the top-level (where it is necessary) or when
1317 inlining would duplicate work (or possibly code depending on
1318 options). However, the _Lifting will still be eliminated if the
1319 strictness analyser deems the lifted binding strict.
1320